| blob | 4a1f846bb8da0fcff85737e00b19a7afe4206744 |
1 dnl Autoconf settings for vlc
3 AC_COPYRIGHT([Copyright 1999-2017 VLC authors and VideoLAN])
5 AC_INIT(vlc, 3.0.0-git)
6 VERSION_MAJOR=3
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=git
12 PKGDIR="vlc"
13 AC_SUBST(PKGDIR)
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Vetinari"
17 COPYRIGHT_YEARS="1996-2017"
19 AC_CONFIG_SRCDIR(src/libvlc.c)
20 AC_CONFIG_AUX_DIR(autotools)
21 AC_CONFIG_MACRO_DIR(m4)
22 AC_CONFIG_LIBOBJ_DIR(compat)
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
28 AC_CONFIG_HEADERS([config.h])
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
33 dnl
34 dnl Directories
35 dnl
36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
37 dnl AC_SUBST(vlcincludedir)
38 vlcdatadir="\${datadir}/\${PKGDIR}"
39 AC_SUBST(vlcdatadir)
40 vlclibdir="\${libdir}/\${PKGDIR}"
41 AC_SUBST(vlclibdir)
43 dnl
44 dnl Check for tools
45 dnl
46 AC_PROG_CC_C99
47 AC_USE_SYSTEM_EXTENSIONS
48 VLC_PROG_CC_C11
49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
51 AH_TOP([
52 #ifndef _REENTRANT
53 # define _REENTRANT
54 #endif
55 ])
56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
60 AM_PROG_CC_C_O
61 AC_PROG_CXX
62 AC_PROG_CPP
63 AC_PROG_OBJC
64 _AM_DEPENDENCIES([OBJC])
65 AC_PROG_EGREP
66 AC_PROG_MAKE_SET
67 AC_PROG_INSTALL
68 AM_PROG_AS
70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
74 AS_IF([test "$BUILDCC" = "false"], [
75 AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
76 ])
78 dnl Check for compiler properties
79 AC_C_CONST
80 AC_C_INLINE
81 AC_C_RESTRICT
82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
84 dnl Extend the --help string at the current spot.
85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
87 dnl Allow binary package maintainer to pass a custom string to avoid
88 dnl cache problem
89 AC_ARG_WITH(binary-version,
90 AS_HELP_STRING([--with-binary-version=STRING],
91 [To avoid plugins cache problem between binary version]),[],[])
92 AS_IF([test -n "${with_binary_version}"],[
93 AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
94 [Binary specific version])
95 ])
97 dnl Prevent clang from accepting unknown flags with a mere warning
98 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
99 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
101 dnl
102 dnl Check the operating system
103 dnl
104 HAVE_WIN64="0"
105 HAVE_IOS="0"
106 HAVE_OSX="0"
107 HAVE_TVOS="0"
109 case "${host_os}" in
110 "")
111 SYS=unknown
112 ;;
113 linux*)
114 SYS=linux
115 ;;
116 bsdi*)
117 SYS=bsdi
118 CFLAGS="${CFLAGS} -pthread"
119 ;;
120 freebsd*)
121 SYS=freebsd
122 CFLAGS="${CFLAGS} -pthread"
123 CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
124 LDFLAGS="${LDFLAGS} -L/usr/local/lib"
125 ac_cv_ld_z_defs=no
126 ;;
127 openbsd*)
128 SYS=openbsd
129 CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
130 LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
131 ;;
132 netbsd*)
133 SYS=netbsd
134 ;;
135 dragonfly*)
136 SYS=dragonfly
137 ;;
138 darwin*)
140 dnl Force gcc "-arch" flag
141 ARCH_flag=""
142 case "${host}" in
143 i?86*)
144 ARCH_flag="-arch i386"
145 ;;
146 ppc64*)
147 ARCH_flag="-arch ppc64"
148 ;;
149 ppc*)
150 ARCH_flag="-arch ppc"
151 ;;
152 x86_64*)
153 ARCH_flag="-arch x86_64"
154 ;;
155 arm*)
156 ac_cv_c_bigendian="no"
157 ac_cv_c_attribute_packed="no"
158 ;;
159 esac
161 SYS=darwin
162 CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
163 CXX="${CXX} -stdlib=libc++ -std=c++11"
164 CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
165 CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
166 OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
167 LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
168 VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
169 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
171 AC_EGREP_CPP(yes,
172 [#import <TargetConditionals.h>
173 #if TARGET_OS_IPHONE
174 yes
175 #endif],
176 [HAVE_IOS="1"],
177 [HAVE_OSX="1"])
179 AC_EGREP_CPP(yes,
180 [#import <TargetConditionals.h>
181 #if TARGET_OS_TV
182 yes
183 #endif],
184 [HAVE_TVOS="1"
185 HAVE_IOS="0"
186 HAVE_OSX="0"
187 ],)
189 dnl Allow binaries created on Lion to run on earlier releases
190 AC_EGREP_CPP(yes,
191 [#import <Cocoa/Cocoa.h>
192 #ifdef MAC_OS_X_VERSION_10_7
193 yes
194 #endif],
195 [AC_MSG_RESULT([yes])
196 AC_LIBOBJ([getdelim])
197 AC_LIBOBJ([strndup])
198 AC_LIBOBJ([strnlen])],)
200 dnl
201 dnl Handle Mac OS X SDK flags
202 dnl
203 AC_ARG_WITH(macosx-sdk,
204 [AS_HELP_STRING([--with-macosx-sdk=DIR],
205 [compile using the SDK in DIR])])
206 if test "${with_macosx_sdk}" != "" ; then
207 test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
208 CPP="${CPP} -isysroot ${with_macosx_sdk}"
209 CC="${CC} -isysroot ${with_macosx_sdk}"
210 CXX="${CXX} -isysroot ${with_macosx_sdk}"
211 OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
212 LD="${LD} -syslibroot ${with_macosx_sdk}"
213 fi
214 AC_ARG_WITH(macosx-version-min,
215 [AS_HELP_STRING([--with-macosx-version-min=VERSION],
216 [compile for Mac OS X VERSION and above])])
217 if test "${with_macosx_version_min}" != "" ; then
218 CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
219 CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
220 CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
221 OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
222 LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
223 fi
224 ;;
225 *mingw32* | *cygwin* | *wince* | *mingwce*)
226 dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
227 dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
228 CXXFLAGS="${CXXFLAGS} -static-libgcc"
229 AC_CHECK_TOOL(WINDRES, windres, :)
230 AC_CHECK_TOOL(OBJCOPY, objcopy, :)
231 AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
232 AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
233 AH_TOP([#endif])
234 AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
235 AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
236 AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
237 AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
238 AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
239 AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
240 AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
241 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
242 AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
243 AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
244 AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
246 case "${host_os}" in
247 *mingw32*)
248 SYS=mingw32
249 ;;
250 *cygwin*)
251 dnl Check if we are using the mno-cygwin mode in which case we are
252 dnl actually dealing with a mingw32 compiler.
253 AC_EGREP_CPP(yes,
254 [#ifdef _WIN32
255 yes
256 #endif],
257 SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
258 ;;
259 esac
261 if test "${SYS}" = "mingw32"; then
262 # DEP, ASLR, NO SEH
263 LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
265 AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
266 ac_default_prefix="`pwd`/_win32"
267 DESTDIR="`pwd`/_win32/"
269 dnl
270 dnl NSIS/MSI Installer prefix and WIN64
271 dnl
272 case "${host}" in
273 amd64*|x86_64*)
274 HAVE_WIN64="1"
275 WINDOWS_ARCH="x64"
276 PROGRAMFILES="PROGRAMFILES64"
277 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
278 ;;
279 *)
280 WINDOWS_ARCH="x86"
281 PROGRAMFILES="PROGRAMFILES"
282 ;;
283 esac
284 AC_SUBST(WINDOWS_ARCH)
285 AC_SUBST(PROGRAMFILES)
287 fi
288 ;;
289 *nto*)
290 SYS=nto
291 ;;
292 solaris*)
293 SYS=solaris
294 ;;
295 hpux*)
296 SYS=hpux
297 ;;
298 *os2*)
299 SYS=os2
300 LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
301 AC_LIBOBJ([freeaddrinfo])
302 AC_LIBOBJ([gai_strerror])
303 ;;
304 *nacl*)
305 SYS=nacl
306 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
307 AC_LIBOBJ([sigwait])
308 AC_LIBOBJ([recvmsg])
309 AC_LIBOBJ([sendmsg])
310 ;;
311 *)
312 SYS="${host_os}"
313 ;;
314 esac
316 dnl WinRT
317 AC_ARG_ENABLE(winstore_app,
318 AS_HELP_STRING([--enable-winstore-app],
319 [Build targetted for Windows Store apps (default disabled)]))
321 vlc_winstore_app=0
322 AS_IF([test "${SYS}" = "mingw32"],[
323 LIBCOM="-lole32"
324 AS_IF([test "${enable_winstore_app}" = "yes"], [
325 vlc_winstore_app=1
326 LIBCOM=""
327 VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
328 AC_LIBOBJ([gai_strerror])
329 ],[])
330 AC_SUBST(LIBCOM)
331 ])
332 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
334 AM_CONDITIONAL(HAVE_LINUX, test "${SYS}" = "linux")
335 AM_CONDITIONAL(HAVE_OS2, test "${SYS}" = "os2")
337 AM_CONDITIONAL(HAVE_DARWIN, test "${SYS}" = "darwin")
338 AM_CONDITIONAL(HAVE_IOS, test "${HAVE_IOS}" = "1")
339 AM_CONDITIONAL(HAVE_OSX, test "${HAVE_OSX}" = "1")
340 AM_CONDITIONAL(HAVE_TVOS, test "${HAVE_TVOS}" = "1")
342 AM_CONDITIONAL(HAVE_NACL, test "${SYS}" = "nacl")
344 AM_CONDITIONAL(HAVE_WIN32, test "${SYS}" = "mingw32")
345 AM_CONDITIONAL(HAVE_WIN64, test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
346 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
347 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
349 dnl
350 dnl Sadly autoconf does not think about testing foo.exe when ask to test
351 dnl for program foo on win32
352 case "${build_os}" in
353 cygwin|msys|mingw32)
354 ac_executable_extensions=".exe"
355 BUILDEXEEXT=".exe"
356 ;;
357 os2*)
358 BUILDEXEEXT=".exe"
359 ;;
360 *)
361 ;;
362 esac
363 AC_SUBST(BUILDEXEEXT)
365 dnl Android is linux, but a bit different
366 AS_IF([test "$SYS" = linux],[
367 AC_MSG_CHECKING([for an Android system])
368 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
369 [[#ifndef __ANDROID__
370 # error Not Android
371 #endif
372 ]],[[;]])
373 ],[
374 HAVE_ANDROID="1"
375 AC_MSG_RESULT([yes])
376 ],[
377 AC_MSG_RESULT([no])
378 ])
379 ])
380 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
382 dnl Tizen (minimum SDK version: 2.3)
383 AS_IF([test "$SYS" = linux],[
384 AC_MSG_CHECKING([for Tizen])
385 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
386 [[#include <tizen.h>
387 ]],[[;]])
388 ],[
389 HAVE_TIZEN="1"
390 AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
391 AC_MSG_RESULT([yes])
392 ],[
393 AC_MSG_RESULT([no])
394 ])
395 ])
396 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
398 dnl
399 dnl Check for the contrib directory
400 dnl
401 AC_ARG_WITH(contrib,
402 [AS_HELP_STRING([--with-contrib[=DIR]],
403 [search for 3rd party libraries in DIR/include and DIR/lib])
404 ])
405 AC_MSG_CHECKING([for 3rd party libraries path])
406 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
407 CONTRIB_DIR="${srcdir}/contrib/${host}"
408 AS_IF([test ! -d "${CONTRIB_DIR}"], [
409 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
410 CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
411 AS_IF([test ! -d "${CONTRIB_DIR}"], [
412 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
413 CONTRIB_DIR=""
414 AC_MSG_RESULT([not found])
415 ])
416 ])
417 ], [
418 AS_IF([test "${with_contrib}" != "no"], [
419 CONTRIB_DIR="${with_contrib}"
420 ], [
421 CONTRIB_DIR=""
422 AC_MSG_RESULT([disabled])
423 ])
424 ])
425 AS_IF([test -n "${CONTRIB_DIR}"], [
426 AS_IF([test -d "${CONTRIB_DIR}/lib"],[
427 CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
428 ], [
429 echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
430 CONTRIB_DIR=""
431 AC_MSG_RESULT([not usable])
432 ])
434 ])
435 AS_IF([test -n "${CONTRIB_DIR}"], [
436 AC_MSG_RESULT([${CONTRIB_DIR}])
437 CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
438 CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
439 CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
440 OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
441 export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
442 LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
444 AS_IF([test -z "$LUAC"], [
445 dnl Old contribs mixed cross-tools and cross-compiled executables
446 AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
447 LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
448 ])
450 dnl Newer contribs follow usual name space rules
451 AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
452 LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
453 ])
454 ])
456 AS_IF([test "${SYS}" = "darwin"], [
457 export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
458 export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
459 ])
460 ], [
461 AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
462 AC_MSG_ERROR([Third party libraries not found!])
463 ])
464 ])
465 AC_SUBST(CONTRIB_DIR)
467 dnl Add extras/tools to the PATH
468 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
469 AS_IF([test -d "${TOOLS_DIR}"], [
470 TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
471 export PATH="${TOOLS_DIR}":$PATH
472 ])
474 dnl
475 dnl Libtool
476 dnl It's very bad, but our former custom system was worst
477 dnl -- Courmisch
478 dnl
480 dnl override platform specific check for dependent libraries
481 dnl otherwise libtool linking of shared libraries will
482 dnl fail on anything other than pass_all.
483 AC_CACHE_VAL(lt_cv_deplibs_check_method,
484 [lt_cv_deplibs_check_method=pass_all])
486 LT_INIT([dlopen win32-dll shared disable-static])
487 LT_LANG([C++])
488 LT_LANG([Windows Resource])
490 DOLT
492 lt_cv_deplibs_check_method=pass_all
494 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
495 AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
496 ])
498 dnl
499 dnl Gettext stuff
500 dnl
501 AM_GNU_GETTEXT_VERSION([0.19.8])
502 AM_GNU_GETTEXT([external], [need-formatstring-macros])
504 dnl
505 dnl Iconv stuff
506 dnl
507 AM_ICONV
509 dnl
510 dnl checks for mingw
511 AS_IF([test "${SYS}" = "mingw32"], [
513 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
514 #if !defined(__MINGW32__)
515 # error Not compiling with mingw
516 #endif
517 ])], [
519 dnl Check for broken versions of mingw-runtime compatability library
520 AC_MSG_CHECKING(for broken mingw-runtime)
521 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
522 #include <_mingw.h>
523 #if defined(__MINGW64_VERSION_MAJOR)
524 # if __MINGW64_VERSION_MAJOR < 3
525 # error Attempting to use mingw-runtime with broken vsnprintf support
526 # endif
527 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
528 # error Attempting to use mingw-runtime with broken vsnprintf support
529 #endif
530 ])], [
531 AC_MSG_RESULT([ok])
532 ], [
533 AC_MSG_RESULT([present])
534 AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
535 ])
537 dnl force use of mingw provided c99 *printf over msvcrt
538 CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
540 dnl Check for the need to include the mingwex lib for mingw32
541 VLC_SAVE_FLAGS
542 AC_CHECK_LIB(mingwex,opendir,
543 AC_CHECK_LIB(mingw32,opendir,,
544 [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
545 )
546 VLC_RESTORE_FLAGS
547 ], [
548 AC_MSG_RESULT([Not compiling with mingw])
549 ])
551 dnl Check for fnative-struct or mms-bitfields support for mingw32
552 VLC_SAVE_FLAGS
553 CFLAGS="${CFLAGS} -mms-bitfields"
554 CXXFLAGS="${CXXFLAGS} -mms-bitfields"
555 AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
556 [ac_cv_c_mms_bitfields],
557 [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
558 if test "${ac_cv_c_mms_bitfields}" = "no"; then
559 VLC_RESTORE_FLAGS
560 CFLAGS="${CFLAGS} -fnative-struct"
561 CXXFLAGS="${CXXFLAGS} -fnative-struct"
562 AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
563 [ac_cv_c_fnative_struct],
564 [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
565 "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
566 fi
567 ])
570 dnl
571 dnl Buggy glibc prevention. Purposedly not cached.
572 dnl See sourceware.org bugs 5058 and 5443.
573 dnl Ubuntu alone has 20 bug numbers for this...
574 dnl
575 AC_MSG_CHECKING(for buggy GNU/libc versions)
576 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
577 #include <limits.h>
578 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
579 && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
580 # error GNU/libc with dcgettext killer bug!
581 #endif
582 ])], [
583 AC_MSG_RESULT([not present])
584 ], [
585 AC_MSG_RESULT([found])
586 AS_IF([test "x${enable_nls}" != "xno"], [
587 AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
588 work-around for this. Check with your distribution vendor on how to update the
589 glibc run-time. Alternatively, build with --disable-nls.])
590 ])
591 ])
593 dnl Plugin compilation stuff
595 VLC_LIBRARY_SUFFIX
597 dnl Check for system libs needed
598 need_libc=false
600 dnl Check for usual libc functions
601 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime tdestroy uselocale])
602 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tfind timegm timespec_get strverscmp pathconf])
603 AC_REPLACE_FUNCS([gettimeofday])
604 AC_CHECK_FUNC(fdatasync,,
605 [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
606 ])
608 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
610 dnl mingw64 implements those as static inline, not functions with C linkage
611 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
612 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
613 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
614 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
616 dnl C11 static_assert()
617 AC_MSG_CHECKING([for static_assert in assert.h])
618 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
619 static_assert(1, "The impossible happened.");
620 ])], [
621 AC_MSG_RESULT([yes])
622 AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
623 ], [
624 AC_MSG_RESULT([no])
625 ])
627 # Windows CE does not have strcoll()
628 AC_FUNC_STRCOLL
630 dnl Check for non-standard system calls
631 case "$SYS" in
632 "linux")
633 AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity recvmmsg])
634 ;;
635 "mingw32")
636 AC_CHECK_FUNCS([_lock_file])
637 ;;
638 esac
640 AH_BOTTOM([#include <vlc_fixups.h>])
642 dnl Check for struct pollfd
643 AC_CHECK_TYPES([struct pollfd],,,
644 [#include <sys/types.h>
645 #if HAVE_POLL
646 # include <poll.h>
647 #elif defined (_WIN32)
648 # include <winsock2.h>
649 #endif
650 ])
652 dnl Check for struct timespec
653 AC_CHECK_TYPES([struct timespec],,,
654 [#include <time.h>])
656 dnl Check for max_align_t
657 AC_CHECK_TYPES([max_align_t],,,
658 [#include <stddef.h>])
660 dnl Checks for socket stuff
661 VLC_SAVE_FLAGS
662 SOCKET_LIBS=""
663 AC_SEARCH_LIBS(connect, [socket], [
664 AS_IF([test "$ac_cv_search_connect" != "none required"], [
665 SOCKET_LIBS="$ac_cv_search_connect"
666 ])
667 ], [
668 AS_IF([test "${SYS}" = "mingw32"], [
669 SOCKET_LIBS="-lws2_32"
670 ])
671 ])
673 AC_SEARCH_LIBS([inet_pton], [nsl], [
674 AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
675 SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
676 ])
677 ],, [${SOCKET_LIBS}])
679 LIBS="${LIBS} ${SOCKET_LIBS}"
680 AC_LINK_IFELSE([
681 AC_LANG_PROGRAM([#ifdef _WIN32
682 # if _WIN32_WINNT < 0x600
683 # error Needs vista+
684 # endif
685 #include <ws2tcpip.h>
686 #else
687 #include <sys/socket.h>
688 #include <arpa/inet.h>
689 #endif], [
690 char dst[[sizeof(struct in_addr)]];
691 inet_pton(AF_INET, "127.0.0.1", dst);
692 ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
693 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
694 VLC_RESTORE_FLAGS
695 AC_SUBST(SOCKET_LIBS)
697 dnl Check for socklen_t
698 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
699 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
700 ac_cv_type_socklen_t,
701 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
702 [#include <sys/types.h>
703 #ifdef _WIN32
704 # include <winsock2.h>
705 # include <ws2tcpip.h>
706 #else
707 # include <sys/socket.h>
708 #endif]], [[socklen_t len; len = 0;]])],
709 ac_cv_type_socklen_t=yes,
710 ac_cv_type_socklen_t=no)])
711 AS_IF([test "$ac_cv_type_socklen_t" = no],
712 [AC_DEFINE(socklen_t, int)])
714 dnl Check for struct sockaddr_storage
715 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
716 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
717 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
718 [AC_TRY_COMPILE(
719 [#include <sys/types.h>
720 #if defined( _WIN32 )
721 # include <winsock2.h>
722 #else
723 # include <sys/socket.h>
724 #endif], [struct sockaddr_storage addr;],
725 ac_cv_struct_sockaddr_storage=yes,
726 ac_cv_struct_sockaddr_storage=no)])
727 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
728 AC_DEFINE(sockaddr_storage, sockaddr)
729 AC_DEFINE(ss_family, sa_family)
730 ])
732 dnl FreeBSD has a gnugetopt library for this:
733 GNUGETOPT_LIBS=""
734 AC_CHECK_FUNC(getopt_long,, [
735 AC_CHECK_LIB([gnugetopt],[getopt_long], [
736 GNUGETOPT_LIBS="-lgnugetopt"
737 ])
738 ])
739 AC_SUBST(GNUGETOPT_LIBS)
741 AC_CHECK_LIB(m,cos,[
742 LIBM="-lm"
743 ], [
744 LIBM=""
745 ])
746 AC_SUBST(LIBM)
748 AC_CHECK_LIB(m,lrintf, [
749 AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
750 VLC_ADD_LIBS([skins2],[-lm])
751 ])
752 AC_CHECK_LIB(m,nanf,
753 AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
754 )
755 AC_CHECK_LIB(m,sincos, [
756 AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
757 ], [
758 AC_LIBOBJ([sincos])
759 ])
761 AC_MSG_CHECKING([_Thread_local support])
762 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
763 int main() {}])], [
764 AC_MSG_RESULT([ok])
765 AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
766 ],[ AC_MSG_RESULT([no])])
768 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
769 dnl check for its availability explicitely
770 AC_CHECK_HEADERS([threads.h])
772 dnl Check for dynamic plugins
773 LIBDL=""
774 have_dynamic_objects="no"
775 VLC_SAVE_FLAGS
776 AC_SEARCH_LIBS(dlsym, [dl svld], [
777 AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
778 LIBDL="$ac_cv_search_dlsym"
779 ])
780 have_dynamic_objects="yes"
781 ])
782 VLC_RESTORE_FLAGS
784 # Windows
785 AS_IF([test "${SYS}" = "mingw32"], [
786 LIBDL=""
787 have_dynamic_objects="yes" #assume we can use shared objects
788 ])
790 AS_IF([test "${enable_shared}" = "no"], [
791 have_dynamic_objects=no
792 ])
793 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
795 AC_SUBST(LIBDL)
797 dnl Check for thread library
798 LIBPTHREAD=""
799 AS_IF([test "${SYS}" != "mingw32"], [
800 VLC_SAVE_FLAGS
801 LIBS=""
802 AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
803 AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
804 LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
805 ])
806 ])
807 VLC_RESTORE_FLAGS
808 ])
809 AC_SUBST(LIBPTHREAD)
811 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
812 AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
813 LIBRT="$ac_cv_search_clock_nanosleep"
814 ])
815 ], [
816 AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
817 AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
818 LIBRT="$ac_cv_search_nanosleep"
819 ])
820 ])
821 ])
822 AC_SUBST(LIBRT)
824 dnl
825 dnl Check for headers
826 dnl
828 dnl POSIX
829 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
830 AC_CHECK_HEADERS([net/if.h], [], [],
831 [
832 #include <sys/types.h>
833 #include <sys/socket.h>
834 ])
835 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
836 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
838 dnl BSD
839 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
841 dnl GNU/Linux
842 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
844 dnl MacOS
845 AC_CHECK_HEADERS([xlocale.h])
847 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
848 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
849 AC_CHECK_TYPE(ssize_t,, [
850 AC_DEFINE(ssize_t, int)
851 ])
853 dnl It seems that autoconf detects pkg-config only during the first
854 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
855 dnl it is nested within a conditional block, so it was not working right.
856 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
857 AC_ARG_VAR(PKG_CONFIG_PATH,
858 [Paths where to find .pc not at the default location])
859 PKG_PROG_PKG_CONFIG()
861 dnl On some OS we need static linking
862 AS_IF([test -n "${PKG_CONFIG}" ],[
863 AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
864 PKG_CONFIG="${PKG_CONFIG} --static"
865 ])
866 ])
869 dnl
870 dnl Check for zlib.h and -lz along with system -lminizip if available
871 dnl
872 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
873 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
874 if test "${have_zlib}" = "yes"
875 then
876 VLC_ADD_LIBS([sap],[-lz])
877 PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
878 AC_CHECK_HEADERS([unzip.h], [
879 have_minizip=yes
880 MINIZIP_LIBS="-lminizip -lz"
881 ], [
882 have_minizip=no
883 ])
884 ])
885 fi
886 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
889 dnl
890 dnl Domain name i18n support via GNU libidn
891 dnl
892 PKG_CHECK_MODULES([IDN], [libidn], [
893 have_libidn="yes"
894 AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
895 ], [
896 have_libidn="no"
897 ])
900 dnl Check for dbus
901 AC_ARG_ENABLE(dbus,
902 [AS_HELP_STRING([--enable-dbus],
903 [compile D-Bus message bus support (default enabled)])])
904 have_dbus="no"
905 AS_IF([test "${enable_dbus}" != "no"], [
906 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
907 have_dbus="yes"
908 ], [
909 AS_IF([test -n "${enable_dbus}"], [
910 AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
911 ], [
912 AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
913 ])
914 ])
915 ])
916 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
919 dnl Check for systemd
920 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
921 have_systemd="yes"
922 ], [
923 AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
924 ])
925 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
928 EXTEND_HELP_STRING([Optimization options:])
929 dnl
930 dnl Compiler warnings
931 dnl
933 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CFLAGS])
934 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CXXFLAGS])
936 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local], [CFLAGS])
937 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
939 dnl
940 dnl Debugging mode
941 dnl
942 AC_ARG_ENABLE(debug,
943 [AS_HELP_STRING([--enable-debug],
944 [build with run-time assertions (default disabled)])],,
945 [enable_debug="no"])
946 AH_TEMPLATE(NDEBUG,
947 [Define to 1 if debug code should NOT be compiled])
948 AS_IF([test "${enable_debug}" != "no"], [
949 AC_CHECK_HEADERS([valgrind/valgrind.h])
950 ], [
951 AC_DEFINE(NDEBUG)
952 ])
954 dnl
955 dnl Profiling
956 dnl
957 AC_ARG_ENABLE(gprof,
958 [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
959 [enable_gprof="no"])
960 AS_IF([test "${enable_gprof}" != "no"], [
961 CFLAGS="${CFLAGS} -pg"
962 CXXFLAGS="${CXXFLAGS} -pg"
963 OBJCFLAGS="${OBJCFLAGS} -pg"
964 LDFLAGS="${LDFLAGS} -pg"
965 ])
967 AC_ARG_ENABLE(cprof,
968 [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
969 [enable_cprof="no"])
970 AS_IF([test "${enable_gprof}" != "no"], [
971 CFLAGS="${CFLAGS} -finstrument-functions"
972 CXXFLAGS="${CXXFLAGS} -finstrument-functions"
973 OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
974 LDFLAGS="${LDFLAGS} -finstrument-functions"
975 ])
977 dnl
978 dnl Test coverage
979 dnl
980 AC_ARG_ENABLE(coverage,
981 [AS_HELP_STRING([--enable-coverage],
982 [build for test coverage (default disabled)])],,
983 [enable_coverage="no"])
984 AS_IF([test "${enable_coverage}" != "no"], [
985 CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
986 CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
987 LDFLAGS="-lgcov ${LDFLAGS}"
988 ])
990 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
991 VLC_SAVE_FLAGS
992 CFLAGS="${CFLAGS} -fvisibility=hidden"
993 CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
994 OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
995 AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
996 [ac_cv_c_visibility_hidden], [
997 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
998 ac_cv_c_visibility_hidden=yes
999 ], [
1000 ac_cv_c_visibility_hidden=no
1001 ])
1002 ])
1003 AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1004 ])
1006 dnl
1007 dnl Sanitizer flags
1008 dnl
1009 AC_ARG_WITH([sanitizer],
1010 [AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1011 [build with sanitizer flags (default disabled)])],
1012 [],
1013 [with_sanitizer=no])
1015 AS_VAR_IF(with_sanitizer, no, [], [
1016 AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1017 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1018 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1019 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1020 ], [
1021 AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1022 ])
1023 AX_APPEND_FLAG([-g])
1024 AX_APPEND_FLAG([-g], [CXXFLAGS])
1026 AS_IF([test -z "${with_sanitizer##*address*}" ], [
1027 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer])
1028 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer], [CXXFLAGS])
1029 ])
1030 AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1031 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1032 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1033 ])
1034 AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1035 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1036 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1037 ])
1038 ])
1040 dnl
1041 dnl Enable/disable optimizations
1042 dnl
1043 AC_ARG_ENABLE(optimizations,
1044 [AS_HELP_STRING([--disable-optimizations],
1045 [disable compiler optimizations (default enabled)])],,
1046 [enable_optimizations="yes"])
1048 dnl Check for various optimization flags
1049 AS_IF([test "${enable_optimizations}" != "no"], [
1051 dnl -O3 only in production builds
1052 AS_IF([test "${enable_debug}" = "no"], [
1053 VLC_SAVE_FLAGS
1054 CFLAGS="${CFLAGS} -O3"
1055 CXXFLAGS="${CXXFLAGS} -O3"
1056 OBJCFLAGS="${OBJCFLAGS} -O3"
1057 AC_CACHE_CHECK([if $CC accepts -O3], [ac_cv_c_o3], [
1058 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1059 ac_cv_c_o3=yes
1060 ], [
1061 ac_cv_c_o3=no
1062 ])
1063 ])
1064 AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1065 ])
1067 dnl Check for fast maths
1068 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1069 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1071 AH_BOTTOM([
1072 #if defined(_MSC_VER) && !defined(__clang__)
1073 # pragma fenv_access(off)
1074 # pragma fp_contract(on)
1075 #elif defined(__GNUC__)
1076 /* Not supported so far */
1077 #else
1078 # pragma STDC FENV_ACCESS OFF
1079 # pragma STDC FP_CONTRACT ON
1080 #endif
1081 ])
1083 dnl Check for -funroll-loops
1084 VLC_SAVE_FLAGS
1085 CFLAGS="${CFLAGS} -funroll-loops"
1086 CXXFLAGS="${CXXFLAGS} -funroll-loops"
1087 OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1088 AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1089 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1090 ac_cv_c_unroll_loops=yes
1091 ], [
1092 ac_cv_c_unroll_loops=no
1093 ])
1094 ])
1095 AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1097 AS_IF([test "$enable_debug" = "no"], [
1098 dnl Check for -fomit-frame-pointer
1099 VLC_SAVE_FLAGS
1100 CFLAGS="${CFLAGS} -fomit-frame-pointer"
1101 CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1102 OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1103 AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1104 [ac_cv_c_omit_frame_pointer], [
1105 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1106 ac_cv_c_omit_frame_pointer=yes
1107 ], [
1108 ac_cv_c_omit_frame_pointer=no
1109 ])
1110 ])
1111 AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1112 ])
1113 ])
1115 VLC_SAVE_FLAGS
1116 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1117 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1118 AC_TRY_LINK([],, [
1119 ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1120 ], [
1121 ac_cv_ld_bsymbolic=""
1122 ])
1123 ])
1124 VLC_RESTORE_FLAGS
1125 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1126 AC_SUBST(SYMBOLIC_LDFLAGS)
1128 VLC_SAVE_FLAGS
1129 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1130 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1131 AC_TRY_LINK([],, [
1132 ac_cv_ld_z_defs="yes"
1133 ], [
1134 ac_cv_ld_z_defs="no"
1135 ])
1136 ])
1137 AS_IF([test "${ac_cv_ld_z_defs}" = "no" -o "${with_sanitizer}" != "no"], [VLC_RESTORE_FLAGS])
1139 dnl Check for __attribute__((packed))
1140 AC_CACHE_CHECK([for __attribute__((packed))],
1141 [ac_cv_c_attribute_packed],
1142 [ac_cv_c_attribute_packed=no
1143 AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1144 [ac_cv_c_attribute_packed=yes])])
1145 if test "${ac_cv_c_attribute_packed}" != "no"; then
1146 AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1147 fi
1149 dnl
1150 dnl Check the CPU
1151 dnl
1152 case "${host_cpu}" in
1153 "")
1154 ARCH=unknown
1155 ;;
1156 *)
1157 ARCH="${host_cpu}"
1158 ;;
1159 esac
1161 dnl Check for backtrace() support
1162 AC_CHECK_HEADERS(execinfo.h)
1163 AC_CHECK_FUNCS(backtrace)
1165 dnl
1166 dnl default modules
1167 dnl
1168 ALIASES="${ALIASES} cvlc rvlc"
1170 dnl
1171 dnl Accelerated modules
1172 dnl
1174 dnl Check for fully working MMX intrinsics
1175 dnl We need support for -mmmx, we need <mmintrin.h>, and we also need a
1176 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1177 AC_ARG_ENABLE(mmx,
1178 [AS_HELP_STRING([--disable-mmx],
1179 [disable MMX optimizations (default auto)])],,[
1180 case "${host_cpu}" in
1181 i?86|x86_64)
1182 enable_mmx="yes"
1183 ;;
1184 *)
1185 enable_mmx="no"
1186 ;;
1187 esac
1188 ])
1189 have_mmx="no"
1190 have_mmxext="no"
1191 AS_IF([test "${enable_mmx}" != "no"], [
1192 ARCH="${ARCH} mmx"
1193 VLC_SAVE_FLAGS
1194 CFLAGS="${CFLAGS} -mmmx"
1195 AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1196 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1197 [#include <mmintrin.h>
1198 #include <stdint.h>
1199 uint64_t frobzor;]], [
1200 [__m64 a, b, c;
1201 a = b = c = (__m64)frobzor;
1202 a = _mm_slli_pi16(a, 3);
1203 a = _mm_adds_pi16(a, b);
1204 c = _mm_srli_pi16(c, 8);
1205 c = _mm_slli_pi16(c, 3);
1206 b = _mm_adds_pi16(b, c);
1207 a = _mm_unpacklo_pi8(a, b);
1208 frobzor = (uint64_t)a;]])], [
1209 ac_cv_c_mmx_intrinsics=yes
1210 ], [
1211 ac_cv_c_mmx_intrinsics=no
1212 ])
1213 ])
1214 VLC_RESTORE_FLAGS
1215 AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1216 AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1217 ])
1219 VLC_SAVE_FLAGS
1220 CFLAGS="${CFLAGS} -mmmx"
1221 AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1222 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1223 void *p;
1224 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1225 ]])
1226 ], [
1227 ac_cv_mmx_inline=yes
1228 ], [
1229 ac_cv_mmx_inline=no
1230 ])
1231 ])
1232 AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1233 AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1234 have_mmx="yes"
1235 ])
1237 AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1238 [ac_cv_mmxext_inline], [
1239 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1240 void *p;
1241 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1242 ]])
1243 ], [
1244 ac_cv_mmxext_inline=yes
1245 ], [
1246 ac_cv_mmxext_inline=no
1247 ])
1248 ])
1249 VLC_RESTORE_FLAGS
1250 AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1251 AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1252 have_mmxext="yes"
1253 ])
1254 ])
1255 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1256 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1258 dnl Check for fully workin SSE2 intrinsics
1259 dnl We need support for -mmmx, we need <emmintrin.h>, and we also need a
1260 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1261 AC_ARG_ENABLE(sse,
1262 [AS_HELP_STRING([--disable-sse],
1263 [disable SSE (1-4) optimizations (default auto)])],, [
1264 case "${host_cpu}" in
1265 i?86|x86_64)
1266 enable_sse=yes
1267 ;;
1268 *)
1269 enable_sse=no
1270 ;;
1271 esac
1272 ])
1273 have_sse2="no"
1274 AS_IF([test "${enable_sse}" != "no"], [
1275 ARCH="${ARCH} sse sse2"
1277 VLC_SAVE_FLAGS
1278 CFLAGS="${CFLAGS} -msse2"
1279 AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1280 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1281 [#include <emmintrin.h>
1282 #include <stdint.h>
1283 uint64_t frobzor;]], [
1284 [__m128i a, b, c;
1285 a = b = c = _mm_set1_epi64((__m64)frobzor);
1286 a = _mm_slli_epi16(a, 3);
1287 a = _mm_adds_epi16(a, b);
1288 c = _mm_srli_epi16(c, 8);
1289 c = _mm_slli_epi16(c, 3);
1290 b = _mm_adds_epi16(b, c);
1291 a = _mm_unpacklo_epi8(a, b);
1292 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1293 ac_cv_c_sse2_intrinsics=yes
1294 ], [
1295 ac_cv_c_sse2_intrinsics=no
1296 ])
1297 ])
1298 VLC_RESTORE_FLAGS
1299 AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1300 AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1301 ])
1303 VLC_SAVE_FLAGS
1304 CFLAGS="${CFLAGS} -msse"
1305 AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1306 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1307 void *p;
1308 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1309 ]])
1310 ], [
1311 ac_cv_sse_inline=yes
1312 ], [
1313 ac_cv_sse_inline=no
1314 ])
1315 ])
1317 AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1318 AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1319 ])
1321 AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1322 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1323 void *p;
1324 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1325 ]])
1326 ], [
1327 ac_cv_sse2_inline=yes
1328 ], [
1329 ac_cv_sse2_inline=no
1330 ])
1331 ])
1332 AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1333 AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1334 have_sse2="yes"
1335 ])
1337 # SSE3
1338 AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1339 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1340 void *p;
1341 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1342 ]])
1343 ], [
1344 ac_cv_sse3_inline=yes
1345 ], [
1346 ac_cv_sse3_inline=no
1347 ])
1348 ])
1350 AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1351 AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1352 # SSSE3
1353 AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1354 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1355 void *p;
1356 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1357 ]])
1358 ], [
1359 ac_cv_ssse3_inline=yes
1360 ], [
1361 ac_cv_ssse3_inline=no
1362 ])
1363 ])
1365 AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1366 AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1368 # SSE4.1
1369 AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1370 [ac_cv_sse4_1_inline], [
1371 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1372 void *p;
1373 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1374 ]])
1375 ], [
1376 ac_cv_sse4_1_inline=yes
1377 ], [
1378 ac_cv_sse4_1_inline=no
1379 ])
1380 ])
1382 AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1383 AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1385 # SSE4.2
1386 AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1387 [ac_cv_sse4_2_inline], [
1388 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1389 void *p;
1390 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1391 ]])
1392 ], [
1393 ac_cv_sse4_2_inline=yes
1394 ], [
1395 ac_cv_sse4_2_inline=no
1396 ])
1397 ])
1399 AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1400 AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1402 # SSE4A
1403 AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1404 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1405 void *p;
1406 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1407 ]])
1408 ], [
1409 ac_cv_sse4a_inline=yes
1410 ], [
1411 ac_cv_sse4a_inline=no
1412 ])
1413 ])
1414 VLC_RESTORE_FLAGS
1415 AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1416 AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1417 ])
1418 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1420 VLC_SAVE_FLAGS
1421 CFLAGS="${CFLAGS} -mmmx"
1422 have_3dnow="no"
1423 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1424 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1425 void *p;
1426 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1427 ]])
1428 ], [
1429 ac_cv_3dnow_inline=yes
1430 ], [
1431 ac_cv_3dnow_inline=no
1432 ])
1433 ])
1434 VLC_RESTORE_FLAGS
1435 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1436 AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1437 [Define to 1 if 3D Now! inline assembly is available.])
1438 have_3dnow="yes"
1439 ])
1440 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1443 AC_ARG_ENABLE(neon,
1444 [AS_HELP_STRING([--disable-neon],
1445 [disable NEON optimizations (default auto)])],, [
1446 AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1447 ])
1448 AS_IF([test "${enable_neon}" != "no"], [
1449 VLC_SAVE_FLAGS
1450 CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1451 AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1452 AC_COMPILE_IFELSE([
1453 AC_LANG_PROGRAM(,[[
1454 asm volatile("vqmovun.s64 d0, q1":::"d0");
1455 ]])
1456 ], [
1457 ac_cv_arm_neon="yes"
1458 ], [
1459 ac_cv_arm_neon="no"
1460 ])
1461 ])
1462 VLC_RESTORE_FLAGS
1463 ])
1464 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1466 AC_ARG_ENABLE(arm64,
1467 [AS_HELP_STRING([--disable-arm64],
1468 [disable arm 64-bit optimizations (default auto)])],, [
1469 AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1470 ])
1471 AS_IF([test "${enable_arm64}" != "no"], [
1472 AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1473 AC_COMPILE_IFELSE([
1474 AC_LANG_PROGRAM(,[[
1475 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1476 ]])
1477 ], [
1478 ac_cv_arm64="yes"
1479 ], [
1480 ac_cv_arm64="no"
1481 ])
1482 ])
1483 ])
1484 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1487 AC_ARG_ENABLE(altivec,
1488 [AS_HELP_STRING([--disable-altivec],
1489 [disable AltiVec optimizations (default auto)])],, [
1490 AS_CASE("${host_cpu}", [powerpc*],
1491 [enable_altivec=yes], [enable_altivec=no])
1492 ])
1493 have_altivec="no"
1494 ALTIVEC_CFLAGS=""
1495 AS_IF([test "${enable_altivec}" = "yes"], [
1496 ARCH="${ARCH} altivec";
1497 VLC_SAVE_FLAGS
1498 AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1499 [ac_cv_altivec_inline],
1500 [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1501 ac_cv_altivec_inline="yes",
1502 [CFLAGS="${CFLAGS} -Wa,-maltivec"
1503 AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1504 [ac_cv_altivec_inline="-Wa,-maltivec"],
1505 ac_cv_altivec_inline=no)
1506 ])])
1507 VLC_RESTORE_FLAGS
1508 AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1509 AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1510 [Define to 1 if AltiVec inline assembly is available.])
1511 AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1512 ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1513 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1514 ])
1515 have_altivec="yes"
1516 ])
1518 VLC_SAVE_FLAGS
1519 AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1520 [ac_cv_c_altivec], [
1521 CFLAGS="${CFLAGS} -maltivec"
1522 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1523 [#include <altivec.h>]], [
1524 [vec_ld(0, (unsigned char *)0);]])], [
1525 ac_cv_c_altivec="-maltivec"
1526 ], [
1527 ac_cv_c_altivec="no"
1528 ])
1529 ])
1530 VLC_RESTORE_FLAGS
1531 AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1532 CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1533 AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1534 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1535 ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1536 VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1537 have_altivec="yes"
1538 ])
1539 AC_CHECK_HEADERS(altivec.h)
1541 VLC_SAVE_FLAGS
1542 LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1543 AC_CACHE_CHECK([if linker needs -framework vecLib],
1544 [ac_cv_ld_altivec],
1545 [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1546 VLC_RESTORE_FLAGS
1547 AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1548 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1549 ])
1550 ])
1551 AC_SUBST(ALTIVEC_CFLAGS)
1552 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1554 dnl
1555 dnl Memory usage
1556 dnl
1557 AC_ARG_ENABLE(optimize-memory,
1558 [AS_HELP_STRING([--enable-optimize-memory],
1559 [optimize memory usage over performance])])
1560 if test "${enable_optimize_memory}" = "yes"; then
1561 AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1562 fi
1564 dnl
1565 dnl Allow running as root (useful for people running on embedded platforms)
1566 dnl
1567 AC_ARG_ENABLE(run-as-root,
1568 [AS_HELP_STRING([--enable-run-as-root],
1569 [allow running VLC as root (default disabled)])])
1570 AS_IF([test "${enable_run_as_root}" = "yes"],[
1571 AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1572 [Define to 1 to allow running VLC as root (uid 0).])
1573 ])
1575 dnl
1576 dnl Stream output
1577 dnl
1578 AC_ARG_ENABLE(sout,
1579 [AS_HELP_STRING([--disable-sout],
1580 [disable streaming output (default enabled)])])
1581 AS_IF([test "${enable_sout}" != "no"], [
1582 AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1583 ])
1584 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1586 dnl Lua modules
1587 AC_ARG_ENABLE(lua,
1588 [AS_HELP_STRING([--disable-lua],
1589 [disable LUA scripting support (default enabled)])])
1590 if test "${enable_lua}" != "no"
1591 then
1592 PKG_CHECK_MODULES(LUA, lua5.2,
1593 [ have_lua=yes ],
1594 [
1595 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1597 PKG_CHECK_MODULES(LUA, lua5.1,
1598 [ have_lua=yes ],
1599 [
1600 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1601 PKG_CHECK_MODULES(LUA, lua >= 5.1,
1602 [ have_lua=yes ],
1603 [
1604 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1605 have_lua=yes
1606 AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1607 [],
1608 [ have_lua=no ] )
1609 AC_CHECK_LIB( lua5.2 , luaL_newstate,
1610 [LUA_LIBS="-llua5.2"],
1611 AC_CHECK_LIB( lua5.1 , luaL_newstate,
1612 [LUA_LIBS="-llua5.1"],
1613 AC_CHECK_LIB( lua51 , luaL_newstate,
1614 [LUA_LIBS="-llua51"],
1615 AC_CHECK_LIB( lua , luaL_newstate,
1616 [LUA_LIBS="-llua"],
1617 [ have_lua=no
1618 ], [-lm])
1619 )))
1620 ])
1621 ])
1622 ])
1623 if test "x${have_lua}" != "xyes" ; then
1624 AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1625 fi
1626 AC_ARG_VAR([LUAC], [LUA byte compiler])
1627 AS_IF([test -z "$LUAC"], [
1628 AC_CHECK_TOOL(LUAC, [luac], [false])
1629 ])
1630 AS_IF([test "${LUAC}" = "false"], [
1631 AC_MSG_ERROR([Could not find the LUA byte compiler.])
1632 ])
1633 AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1634 AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1635 ])
1636 fi
1637 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1640 dnl
1641 dnl VideoLAN manager
1642 dnl
1643 AC_ARG_ENABLE(vlm,
1644 [AS_HELP_STRING([--disable-vlm],
1645 [disable the stream manager (default enabled)])],,
1646 [enable_vlm="${enable_sout}"])
1647 AS_IF([test "${enable_vlm}" != "no"], [
1648 AS_IF([test "${enable_sout}" = "no"], [
1649 AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1650 ])
1651 AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1652 ])
1653 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1656 dnl
1657 dnl Addons manager storage and repositories modules
1658 dnl
1659 AC_ARG_ENABLE(addonmanagermodules,
1660 [AS_HELP_STRING([--disable-addonmanagermodules],
1661 [disable the addons manager modules (default enabled)])])
1662 if test "${enable_addonmanagermodules}" != "no"
1663 then
1664 AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1665 fi
1666 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1669 dnl
1670 dnl Input plugins
1671 dnl
1673 EXTEND_HELP_STRING([Input plugins:])
1675 dnl
1676 dnl libarchive access module
1677 dnl
1678 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1680 dnl
1681 dnl live555 input
1682 dnl
1683 AC_ARG_ENABLE(live555,
1684 [AS_HELP_STRING([--enable-live555],
1685 [enable RTSP input through live555 (default enabled)])])
1687 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1688 PKG_CHECK_MODULES(LIVE555, live555, [
1689 VLC_ADD_PLUGIN([live555])
1690 VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1691 VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1692 ], [
1693 AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1695 AC_LANG_PUSH(C++)
1696 VLC_SAVE_FLAGS
1698 dnl detect include paths
1699 AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1700 CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1701 ], [
1702 AS_IF([test "${SYS}" != "os2"], [
1703 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1704 CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1705 ], [
1706 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1707 CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1708 LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1709 ])
1710 ])
1712 dnl CPP Flags
1713 AS_IF([test "${SYS}" = "solaris"], [
1714 CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1715 ])
1716 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1717 LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1719 dnl version check
1720 AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1721 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1722 [#include <liveMedia_version.hh>
1723 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1724 # error BOOM
1725 #endif]])
1726 ], [
1727 ac_cv_live555="yes"
1728 ], [
1729 ac_cv_live555="no"
1730 ])
1731 ])
1733 AS_IF([test "$ac_cv_live555" = "no"], [
1734 AC_MSG_WARN([live555 is missing or its installed version is too old:
1735 Version 2011.12.23 or later is required to proceed.
1736 You can get an updated one from http://www.live555.com/liveMedia .])
1737 AS_IF([test -n "${enable_live555}"], [
1738 AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1739 ])
1740 ], [
1741 other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1742 other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1743 AS_IF([test "${SYS}" = "mingw32"], [
1744 # add ws2_32 for closesocket, select, recv
1745 other_libs="$other_libs -lws2_32"
1746 ])
1748 dnl We need to check for pic because live555 don't provide shared libs
1749 dnl and we want to build a plugins so we need -fPIC on some arch.
1750 VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1751 VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1752 AC_CHECK_LIB(liveMedia_pic, main, [
1753 VLC_ADD_PLUGIN([live555])
1754 VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1755 ],[
1756 AC_CHECK_LIB(liveMedia, main, [
1757 VLC_ADD_PLUGIN([live555])
1758 VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1759 ],[],[${other_libs}])
1760 ],[${other_libs_pic}])
1761 ])
1762 VLC_RESTORE_FLAGS
1763 AC_LANG_POP(C++)
1764 ])
1765 ])
1767 dnl
1768 dnl IIDC and DV FireWire input modules
1769 dnl
1770 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1771 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1773 dnl
1774 dnl - linsys modules: access module check for libzvbi
1775 dnl
1776 AC_ARG_ENABLE(linsys,
1777 [AS_HELP_STRING([--enable-linsys],
1778 [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1779 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1780 VLC_ADD_PLUGIN([linsys_hdsdi])
1781 PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1782 VLC_ADD_PLUGIN([linsys_sdi])
1783 ], [
1784 AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1785 ])
1786 ])
1788 dnl
1789 dnl dvdread module: check for libdvdread
1790 dnl
1791 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1793 dnl
1794 dnl libdvdnav plugin
1795 dnl
1796 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1797 AS_IF([test "${enable_dvdnav}" != "no"], [
1798 AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1799 AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1800 AC_MSG_RESULT(yes)
1801 AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1802 ],[
1803 AC_MSG_RESULT(no)
1804 ])
1805 ])
1807 dnl
1808 dnl Blu-ray Disc Support with libbluray
1809 dnl
1810 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1812 dnl
1813 dnl OpenCV wrapper and example filters
1814 dnl
1815 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1818 dnl
1819 dnl libsmbclient plugin
1820 dnl
1821 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1822 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" != "yes"], [ VLC_ADD_PLUGIN([smb]) ])
1824 dnl
1825 dnl liBDSM access module
1826 dnl
1827 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1829 dnl
1830 dnl sftp access support
1831 dnl
1832 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1834 dnl
1835 dnl nfs access support
1836 dnl
1837 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1839 dnl
1840 dnl Video4Linux 2
1841 dnl
1842 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1843 [disable Video4Linux version 2 (default auto)])])
1844 have_v4l2="no"
1845 AS_IF([test "$enable_v4l2" != "no"], [
1846 AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1847 have_v4l2="yes"
1848 ])
1849 ])
1850 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1852 dnl
1853 dnl special access module for Blackmagic SDI cards
1854 dnl
1855 AC_ARG_ENABLE(decklink,
1856 [AS_HELP_STRING([--disable-decklink],
1857 [disable Blackmagic DeckLink SDI input (default auto)])])
1858 AC_ARG_WITH(decklink_sdk,
1859 [AS_HELP_STRING[--with-decklink-sdk=DIR],
1860 [ location of Blackmagic DeckLink SDI SDK])])
1861 have_decklink=no
1862 if test "${enable_decklink}" != "no"
1863 then
1864 if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1865 then
1866 VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1867 fi
1868 VLC_SAVE_FLAGS
1869 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1870 AC_LANG_PUSH(C++)
1871 AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1872 have_decklink=yes
1873 ], [
1874 AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1875 ])
1876 AC_LANG_POP(C++)
1877 VLC_RESTORE_FLAGS
1878 fi
1879 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1882 dnl
1883 dnl Built-in CD-DA and VCD module
1884 dnl
1885 AC_ARG_ENABLE(vcd,
1886 [AS_HELP_STRING([--disable-vcd],
1887 [disable built-in VCD and CD-DA support (default enabled)])])
1889 AC_ARG_ENABLE(libcddb,
1890 [AS_HELP_STRING([--disable-libcddb],
1891 [disable CDDB for Audio CD (default enabled)])])
1893 if test "${enable_vcd}" != "no"
1894 then
1895 AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1896 AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1897 AC_MSG_RESULT(yes)
1898 VLC_ADD_PLUGIN([vcd cdda])
1899 ],[
1900 AC_MSG_RESULT(no)
1901 ])
1903 AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1904 AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1905 AC_MSG_RESULT(yes)
1906 VLC_ADD_PLUGIN([vcd cdda])
1907 AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1908 ],[
1909 AC_MSG_RESULT(no)
1910 ])
1912 AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1913 AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1914 AC_MSG_RESULT(yes)
1915 VLC_ADD_PLUGIN([vcd cdda])
1916 AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1917 ],[
1918 AC_MSG_RESULT(no)
1919 ])
1921 if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1922 then
1923 VLC_ADD_PLUGIN([vcd cdda])
1924 fi
1926 if test "$enable_libcddb" != "no"; then
1927 PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1928 HAVE_LIBCDDB=yes
1929 AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1930 VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1931 VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1932 ],:
1933 [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1934 HAVE_LIBCDDB=no])
1935 fi
1936 fi
1938 dnl
1939 dnl Linux DVB
1940 dnl
1941 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1942 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1943 [#include <linux/dvb/version.h>
1944 #if (DVB_API_VERSION < 5)
1945 # error Linux DVB API v3.2 and older are not supported.
1946 #endif
1947 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1948 # error Linux DVB API v5.0 is unsupported. Please update.
1949 #endif
1950 ]])], [
1951 ac_cv_linux_dvb_5_1=yes
1952 ], [
1953 ac_cv_linux_dvb_5_1=no
1954 ])])
1955 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1957 dnl
1958 dnl Screen capture module
1959 dnl
1960 AC_ARG_ENABLE(screen,
1961 [AS_HELP_STRING([--enable-screen],
1962 [disable screen capture (default enabled)])])
1963 if test "${enable_screen}" != "no"; then
1964 if test "${SYS}" = "darwin"; then
1965 AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1966 VLC_ADD_PLUGIN([screen])
1967 ])
1968 fi
1969 fi
1970 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1972 dnl
1973 dnl VNC/RFB access module
1974 dnl
1975 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1977 dnl RDP/Remote Desktop access module
1978 dnl
1979 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1981 dnl
1982 dnl Real RTSP plugin
1983 dnl
1984 AC_ARG_ENABLE(realrtsp,
1985 [ --enable-realrtsp Real RTSP module (default disabled)])
1986 if test "${enable_realrtsp}" = "yes"; then
1987 VLC_ADD_PLUGIN([access_realrtsp])
1988 fi
1990 dnl
1991 dnl QTKit
1992 AC_ARG_ENABLE(macosx-qtkit,
1993 [ --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
1994 if test "x${enable_macosx_qtkit}" != "xno" &&
1995 (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1996 then
1997 AC_CHECK_HEADERS(QTKit/QTKit.h, [
1998 VLC_ADD_PLUGIN([qtsound])
1999 ])
2000 fi
2002 dnl
2003 dnl AVFoundation
2004 AC_SUBST(have_avfoundation, ["no"])
2005 AC_ARG_ENABLE(macosx-avfoundation,
2006 [ --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2007 if test "x${enable_macosx_avfoundation}" != "xno" &&
2008 (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2009 then
2010 SAVED_LIBS="${LIBS}"
2011 LIBS="-framework AVFoundation"
2012 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2013 LIBS="${SAVED_LIBS}"
2014 if test "${have_avfoundation}" != "no"
2015 then
2016 VLC_ADD_PLUGIN([avcapture])
2017 fi
2018 fi
2019 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2021 dnl
2022 dnl DCP plugin (using asdcplib)
2023 dnl
2024 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2025 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2027 dnl
2028 dnl Demux plugins
2029 dnl
2031 EXTEND_HELP_STRING([Mux/Demux plugins:])
2033 dnl
2034 dnl libdvbpsi check for ts mux/demux
2035 dnl
2036 have_dvbpsi="no"
2037 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2038 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2041 dnl
2042 dnl GME demux plugin
2043 dnl
2044 AC_ARG_ENABLE(gme,
2045 [AS_HELP_STRING([--enable-gme],
2046 [use Game Music Emu (default auto)])])
2047 AS_IF([test "${enable_gme}" != "no"], [
2048 AC_CHECK_HEADER([gme/gme.h], [
2049 VLC_ADD_LIBS([gme], [-lgme])
2051 AC_CHECK_LIB([gme], [gme_identify_header], [
2052 VLC_ADD_PLUGIN([gme])
2053 ], [
2054 AC_CHECK_LIB([gme], [gme_identify_extension], [
2055 VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2056 VLC_ADD_PLUGIN([gme])
2057 ],, [-lstdc++ $LIBM])
2058 ])
2059 ], [
2060 AS_IF([test "x${enable_gme}" != "x"], [
2061 AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2062 ])
2063 ])
2064 ])
2067 dnl
2068 dnl SIDPlay plugin
2069 dnl
2070 AC_ARG_ENABLE(sid,
2071 [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2072 AS_IF([test "${enable_sid}" != "no"], [
2073 PKG_CHECK_MODULES(SID, [libsidplay2], [
2074 AC_LANG_PUSH(C++)
2075 oldCPPFLAGS="$CPPFLAGS"
2076 CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2077 AC_CHECK_HEADER([sidplay/builders/resid.h], [
2078 VLC_ADD_PLUGIN([sid])
2079 VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2080 VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2081 ], [
2082 AS_IF([test -n "${enable_sid}"],
2083 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2084 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2085 )
2086 ])
2087 CPPFLAGS="$oldCPPFLAGS"
2088 AC_LANG_POP(C++)
2089 ], [
2090 AS_IF([test "x${enable_sid}" = "xyes"],
2091 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2092 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2093 )
2094 ])
2095 ])
2098 dnl
2099 dnl ogg demux plugin
2100 dnl
2101 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2102 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2103 AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2104 ],[true])
2105 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2106 if test "${enable_sout}" != "no"; then
2107 dnl Check for libshout
2108 PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2109 fi
2111 dnl
2112 dnl matroska demux plugin
2113 dnl
2114 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2116 dnl
2117 dnl modplug demux plugin
2118 dnl
2119 AC_ARG_ENABLE(mod,
2120 [AS_HELP_STRING([--disable-mod],
2121 [do not use libmodplug (default auto)])])
2122 if test "${enable_mod}" != "no" ; then
2123 PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2124 VLC_ADD_PLUGIN([mod])
2125 VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2126 VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2127 VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2128 ],[
2129 AS_IF([test -n "${enable_mod}"],
2130 [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2131 [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2132 ])
2133 fi
2135 dnl
2136 dnl mpc demux plugin
2137 dnl
2138 AC_ARG_ENABLE(mpc,
2139 [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2140 if test "${enable_mpc}" != "no"
2141 then
2142 AC_CHECK_HEADERS([mpc/mpcdec.h], [
2143 VLC_ADD_PLUGIN([mpc])
2144 VLC_ADD_LIBS([mpc],[-lmpcdec])],
2145 [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2146 VLC_ADD_PLUGIN([mpc])
2147 VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2148 fi
2150 dnl
2151 dnl Codec plugins
2152 dnl
2154 EXTEND_HELP_STRING([Codec plugins:])
2156 dnl
2157 dnl wmafixed plugin
2158 dnl
2159 AC_ARG_ENABLE(wma-fixed,
2160 [ --enable-wma-fixed libwma-fixed module (default disabled)])
2161 if test "${enable_wma_fixed}" = "yes"
2162 then
2163 VLC_ADD_PLUGIN([wma_fixed])
2164 fi
2166 dnl
2167 dnl shine encoder plugin
2168 dnl
2169 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2172 dnl
2173 dnl openmax il codec plugin
2174 dnl
2175 AC_ARG_ENABLE(omxil,
2176 [ --enable-omxil openmax il codec module (default disabled)])
2177 if test "${enable_omxil}" = "yes"
2178 then
2179 VLC_ADD_PLUGIN([omxil])
2180 fi
2182 dnl
2183 dnl openmax il vout plugin
2184 dnl
2185 AC_ARG_ENABLE(omxil-vout,
2186 [ --enable-omxil-vout openmax il video output module (default disabled)])
2187 if test "${enable_omxil_vout}" = "yes"
2188 then
2189 VLC_ADD_PLUGIN([omxil_vout])
2190 fi
2192 dnl
2193 dnl raspberry pi openmax il configuration
2194 dnl
2195 AC_ARG_ENABLE(rpi-omxil,
2196 [ --enable-rpi-omxil openmax il configured for raspberry pi (default disabled)])
2197 if test "${enable_rpi_omxil}" = "yes"
2198 then
2199 VLC_ADD_PLUGIN([omxil omxil_vout])
2200 VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2201 fi
2203 dnl
2204 dnl CrystalHD codec plugin
2205 dnl
2206 AC_ARG_ENABLE(crystalhd,
2207 [ --enable-crystalhd crystalhd codec plugin (default auto)])
2208 if test "${enable_crystalhd}" != "no"; then
2209 AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2210 VLC_ADD_PLUGIN([crystalhd])
2211 VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2212 ],[
2213 if test "${SYS}" = "mingw32" ; then
2214 AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2215 VLC_ADD_PLUGIN([crystalhd])
2216 AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2217 VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2218 ])
2219 ],[
2220 AS_IF([test x"${enable_crystalhd}" = "xyes"],
2221 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2222 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2223 ],[#define __LINUX_USER__
2224 #include <libcrystalhd/bc_dts_types.h>
2225 ])
2226 fi
2227 ],[
2228 #include <libcrystalhd/bc_dts_types.h>
2229 ])
2230 fi
2232 dnl
2233 dnl mad plugin
2234 dnl
2235 have_mad="no"
2236 MAD_CFLAGS=""
2237 MAD_LIBS=""
2239 AC_ARG_WITH(mad, [ --with-mad=PATH path to libmad], [
2240 enable_mad="yes"
2241 ], [
2242 with_mad="no"
2243 ])
2244 AS_IF([test "${with_mad}" != "no"], [
2245 MAD_CFLAGS="-I${with_mad}/include"
2246 MAD_LIBS="-L${with_mad}/lib"
2247 ])
2249 AC_ARG_ENABLE(mad,
2250 [ --enable-mad libmad module (default enabled)])
2251 AS_IF([test "${enable_mad}" != "no"], [
2252 VLC_SAVE_FLAGS
2253 CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2254 LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2255 AC_CHECK_HEADERS(mad.h, [
2256 AC_CHECK_LIB(mad, mad_bit_init, [
2257 have_mad="yes"
2258 MAD_LIBS="${MAD_LIBS} -lmad"
2259 ])
2260 ])
2261 VLC_RESTORE_FLAGS
2262 AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2263 AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2264 ])
2265 ])
2266 AC_SUBST(MAD_CFLAGS)
2267 AC_SUBST(MAD_LIBS)
2268 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2270 dnl mpg123 plugin
2271 dnl
2272 dnl
2273 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2275 dnl
2276 dnl gstreamer stuff
2277 dnl
2278 AC_ARG_ENABLE(gst-decode,
2279 [ --enable-gst-decode GStreamer based decoding support (currently supports only video decoding) (default auto)])
2281 have_gst_decode="no"
2282 AS_IF([test "${enable_gst_decode}" != "no"], [
2283 PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2284 PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2285 have_gst_decode="yes"
2286 ], [
2287 AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2288 ])
2289 ], [
2290 AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2291 ])
2292 ])
2293 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2295 dnl
2296 dnl avcodec decoder/encoder plugin
2297 dnl
2298 AC_ARG_ENABLE(merge-ffmpeg,
2299 [ --enable-merge-ffmpeg merge FFmpeg-based plugins (default disabled)],, [
2300 enable_merge_ffmpeg="no"
2301 ])
2302 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2304 AC_MSG_CHECKING([for libavutil variant])
2305 PKG_CHECK_EXISTS([libavutil], [
2306 libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2307 libavutil_micro="${libavutil_version##*.}"
2308 AS_IF([test ${libavutil_micro} -le 99], [
2309 avfork="libav"
2310 ], [
2311 avfork="ffmpeg"
2312 ])
2313 ], [
2314 avfork="none"
2315 ])
2316 AC_MSG_RESULT([${avfork}])
2318 AC_ARG_ENABLE(avcodec,
2319 [ --enable-avcodec libavcodec codec (default enabled)])
2320 AS_IF([test "${enable_avcodec}" != "no"], [
2321 dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2322 case "${avfork}" in
2323 libav) av_codec_ver="57.16.0" ;;
2324 ffmpeg) av_codec_ver="57.37.100" ;;
2325 *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2326 esac
2327 PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2328 VLC_SAVE_FLAGS
2329 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2330 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2331 AC_CHECK_HEADERS(libavcodec/avcodec.h)
2332 AC_CHECK_HEADERS(libavutil/avutil.h)
2333 VLC_RESTORE_FLAGS
2334 have_avcodec="yes"
2335 ],[
2336 AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2337 ])
2338 ], [
2339 have_avcodec="no"
2340 ])
2341 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2343 dnl
2344 dnl libva needs avcodec
2345 dnl
2346 AC_ARG_ENABLE(libva,
2347 [ --enable-libva VAAPI GPU decoding support (libVA) (default auto)])
2349 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2350 AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2351 ])
2353 have_vaapi="no"
2354 have_vaapi_drm="no"
2355 have_vaapi_x11="no"
2356 have_vaapi_wl="no"
2357 AS_IF([test "${enable_libva}" != "no"], [
2358 PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2359 have_vaapi="yes"
2360 ], [
2361 AS_IF([test -n "${enable_libva}"], [
2362 AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2363 ], [
2364 AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2365 ])
2366 ])
2367 PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2368 have_vaapi_drm="yes"
2369 ], [
2370 AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2371 ])
2372 PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2373 have_vaapi_x11="yes"
2374 ], [
2375 AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2376 ])
2377 PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2378 have_vaapi_wl="yes"
2379 ], [
2380 AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2381 ])
2382 ])
2383 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2384 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2385 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2386 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2388 have_avcodec_vaapi="no"
2389 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2390 VLC_SAVE_FLAGS
2391 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2392 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2393 AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2394 AC_MSG_NOTICE([VA API acceleration activated])
2395 have_avcodec_vaapi="yes"
2396 ],[
2397 AS_IF([test -n "${enable_libva}"], [
2398 AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2399 ], [
2400 AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2401 ])
2402 ])
2403 VLC_RESTORE_FLAGS
2404 ])
2405 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2407 dnl
2408 dnl dxva2 needs avcodec
2409 dnl
2410 AC_ARG_ENABLE(dxva2,
2411 [ --enable-dxva2 DxVA2 GPU decoding support (default auto)])
2413 have_avcodec_dxva2="no"
2414 AS_IF([test "${enable_dxva2}" != "no"], [
2415 if test "${SYS}" = "mingw32"; then
2416 AS_IF([test "x${have_avcodec}" = "xyes"], [
2417 AC_CHECK_HEADERS(dxva2api.h,
2418 [
2419 AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2420 AC_MSG_NOTICE([DxVA2 acceleration activated])
2421 have_avcodec_dxva2="yes"
2422 ],[
2423 AS_IF([test "${enable_dxva2}" = "yes"],
2424 [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2425 [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2426 ], [#undef _WIN32_WINNT
2427 /* DXVA2 is only available in Vista and above */
2428 #define _WIN32_WINNT 0x600])
2429 ],[
2430 AS_IF([test "${enable_dxva2}" = "yes"],
2431 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2432 [AC_MSG_WARN([dxva2api.h not found])])
2433 ],[#include <d3d9.h>])
2434 ],[
2435 AS_IF([test "x${enable_dxva2}" != "x"], [
2436 AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2437 ])
2438 ])
2439 fi
2440 ])
2441 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2443 dnl
2444 dnl d3d11va needs avcodec
2445 dnl
2446 AC_ARG_ENABLE(d3d11va,
2447 [ --enable-d3d11va D3D11 GPU decoding support (default auto)])
2449 have_avcodec_d3d11va="no"
2450 AS_IF([test "${enable_d3d11va}" != "no"], [
2451 if test "${SYS}" = "mingw32"; then
2452 AS_IF([test "x${have_avcodec}" = "xyes"], [
2453 AC_CHECK_TYPES([ID3D11VideoDecoder],
2454 [
2455 AC_CHECK_HEADERS(dxva2api.h,
2456 [
2457 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2458 AC_MSG_NOTICE([D3D11 acceleration activated])
2459 AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2460 have_avcodec_d3d11va="yes"
2461 ],[
2462 AS_IF([test "${enable_d3d11va}" = "yes"],
2463 [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2464 [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2465 ], [#undef _WIN32_WINNT
2466 /* D3D11 is only available in Vista and above */
2467 #define _WIN32_WINNT 0x600])
2468 ],[
2469 AS_IF([test "${enable_d3d11va}" = "yes"],
2470 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2471 [AC_MSG_WARN([dxva2api.h not found])])
2472 ],[#include <d3d9.h>])
2473 ],[
2474 AS_IF([test "${enable_d3d11va}" = "yes"],
2475 [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2476 [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2477 ], [#include <d3d11.h>])
2478 ],[
2479 AS_IF([test "x${enable_d3d11va}" != "x"], [
2480 AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2481 ])
2482 ])
2483 fi
2484 ])
2485 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2487 dnl
2488 dnl DXGI debug
2489 dnl
2490 AC_CHECK_HEADERS(dxgidebug.h)
2492 dnl
2493 dnl avformat demuxer/muxer plugin
2494 dnl
2496 AC_ARG_ENABLE(avformat,
2497 [ --enable-avformat libavformat containers (default enabled)],, [
2498 enable_avformat="${have_avcodec}"
2499 ])
2500 have_avformat="no"
2501 AS_IF([test "${enable_avformat}" != "no"], [
2502 PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2503 have_avformat="yes"
2504 VLC_SAVE_FLAGS
2505 CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2506 CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2507 AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2508 AC_CHECK_HEADERS(libavcodec/avcodec.h)
2509 AC_CHECK_HEADERS(libavutil/avutil.h)
2510 AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2511 have_avformat="no"
2512 ])
2513 VLC_RESTORE_FLAGS
2514 ],[
2515 AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2516 ])
2517 ])
2518 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2520 dnl
2521 dnl swscale image scaling and conversion plugin
2522 dnl
2524 AC_ARG_ENABLE(swscale,
2525 AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2526 (default enabled)]))
2527 if test "${enable_swscale}" != "no"
2528 then
2529 PKG_CHECK_MODULES(SWSCALE,[libswscale],
2530 [
2531 VLC_SAVE_FLAGS
2532 CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2533 CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2534 AC_CHECK_HEADERS(libswscale/swscale.h)
2535 AC_CHECK_HEADERS(libavutil/avutil.h)
2536 VLC_ADD_PLUGIN([swscale])
2537 VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2538 VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2539 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2540 VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2541 ])
2542 VLC_RESTORE_FLAGS
2543 ],[
2544 AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2545 ])
2546 fi
2548 dnl
2549 dnl postproc plugin
2550 dnl
2552 AC_ARG_ENABLE(postproc,
2553 [ --enable-postproc libpostproc image post-processing (default auto)])
2554 if test "${enable_postproc}" != "no"
2555 then
2556 PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2557 [
2558 VLC_SAVE_FLAGS
2559 CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2560 CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2561 AC_CHECK_HEADERS(postproc/postprocess.h)
2562 VLC_ADD_PLUGIN([postproc])
2563 VLC_RESTORE_FLAGS
2564 ],[
2565 AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2566 ])
2567 fi
2569 dnl
2570 dnl faad decoder plugin
2571 dnl
2572 AC_ARG_ENABLE(faad,
2573 [ --enable-faad faad codec (default auto)])
2574 have_faad="no"
2575 AS_IF([test "${enable_faad}" != "no"], [
2576 AC_CHECK_HEADERS([neaacdec.h], [
2577 AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2579 AS_IF([test "${have_faad}" = "yes"], [
2580 VLC_ADD_PLUGIN([faad])
2581 VLC_ADD_LIBS([faad],[-lfaad])
2582 ], [
2583 AS_IF([test "${enable_faad}" = "yes"], [
2584 AC_MSG_ERROR([cannot find FAAD library])
2585 ], [
2586 AC_MSG_WARN([cannot find FAAD library])
2587 ])
2588 ])
2589 ])
2590 ])
2592 dnl
2593 dnl AOM decoder plugin
2594 dnl
2595 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec], [disabled])
2597 dnl
2598 dnl libvpx decoder plugin
2599 dnl
2600 AC_ARG_ENABLE(vpx,
2601 AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2602 AS_IF([test "${enable_vpx}" != "no"],[
2603 PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2604 VLC_ADD_PLUGIN([vpx])
2605 VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2606 VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2607 AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2608 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2609 ], [], [${VPX_LIBS}])
2610 AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2611 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2612 ], [], [${VPX_LIBS}])
2613 AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2614 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2615 ], [], [${VPX_LIBS}])
2616 AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2617 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2618 ], [], [${VPX_LIBS}])
2619 ], [
2620 AS_IF([test "${enable_vpx}" = "yes"],[
2621 AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2622 ])])
2623 ])
2625 dnl
2626 dnl twolame encoder plugin
2627 dnl
2628 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2630 dnl
2631 dnl fdk-aac encoder plugin
2632 dnl
2633 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2636 dnl
2637 dnl A52/AC3 decoder plugin
2638 dnl
2639 AC_ARG_ENABLE(a52,
2640 [ --enable-a52 A/52 support with liba52 (default enabled)])
2641 if test "${enable_a52}" != "no"
2642 then
2643 AC_ARG_WITH(a52,
2644 [ --with-a52=PATH a52 headers and libraries])
2645 if test -z "${with_a52}"
2646 then
2647 LDFLAGS_test=""
2648 CPPFLAGS_test=""
2649 else
2650 LDFLAGS_test="-L${with_a52}/lib"
2651 CPPFLAGS_test="-I${with_a52}/include"
2652 fi
2653 VLC_SAVE_FLAGS
2654 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2655 LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2656 AC_CHECK_HEADERS(a52dec/a52.h, [
2657 AC_CHECK_LIB(a52, a52_free, [
2658 VLC_ADD_PLUGIN([a52])
2659 VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2660 VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2661 ],[
2662 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2663 ], [$LIBM])
2664 ],[
2665 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2666 ])
2667 VLC_RESTORE_FLAGS
2668 fi
2670 dnl
2671 dnl DTS Coherent Acoustics decoder plugin
2672 dnl
2673 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2675 dnl
2676 dnl Flac plugin
2677 dnl
2678 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2680 dnl
2681 dnl Libmpeg2 plugin
2682 dnl
2683 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2685 dnl
2686 dnl Vorbis plugin
2687 dnl
2688 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2690 dnl
2691 dnl Tremor plugin
2692 dnl
2693 AC_ARG_ENABLE(tremor,
2694 [ --enable-tremor Tremor decoder support (default disabled)])
2695 if test "${enable_tremor}" = "yes"
2696 then
2697 AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2698 VLC_ADD_PLUGIN([tremor])
2699 ],[])
2700 fi
2702 dnl
2703 dnl Speex plugins
2704 dnl
2705 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2706 have_speexdsp="no"
2707 AS_IF([test "${enable_speex}" != "no"], [
2708 PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2709 have_speexdsp="yes"
2710 ], [
2711 AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2712 ])
2713 ])
2714 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2716 dnl
2717 dnl Opus plugin
2718 dnl
2719 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2721 dnl
2722 dnl Ambisonic channel mixer and binauralizer plugin
2723 dnl
2724 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2726 dnl
2727 dnl theora decoder plugin
2728 dnl
2729 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2731 dnl
2732 dnl OggSpots decoder plugin
2733 dnl
2734 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2736 dnl
2737 dnl Daala decoder plugin
2738 dnl
2739 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2741 dnl
2742 dnl schroedinger decoder plugin (for dirac format video)
2743 dnl
2744 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2746 dnl
2747 dnl PNG decoder module
2748 dnl
2749 AC_ARG_ENABLE(png,
2750 [ --enable-png PNG support (default enabled)])
2751 AS_IF([test "${enable_png}" != "no"], [
2752 AC_CHECK_HEADERS(png.h, [
2753 VLC_SAVE_FLAGS
2754 LDFLAGS="${LDFLAGS} -lz $LIBM"
2755 AC_CHECK_LIB(png, png_set_alpha_mode, [
2756 VLC_ADD_PLUGIN([png])
2757 ], [], [-lz $LIBM])
2758 VLC_RESTORE_FLAGS
2759 ])
2760 ])
2762 dnl
2763 dnl JPEG decoder module
2764 dnl
2765 AC_ARG_ENABLE(jpeg,
2766 [ --enable-jpeg JPEG support (default enabled)])
2767 AS_IF([test "${enable_jpeg}" != "no"], [
2768 AC_CHECK_HEADERS(jpeglib.h, [
2769 VLC_ADD_PLUGIN([jpeg])
2770 ])
2771 ])
2773 dnl
2774 dnl BPG decoder module
2775 dnl
2776 AC_ARG_ENABLE(bpg,
2777 [ --enable-bpg BPG support (default disabled)])
2778 AS_IF([test "${enable_bpg}" != "no"], [
2779 AC_CHECK_HEADERS(libbpg.h, [
2780 VLC_ADD_PLUGIN([bpg])
2781 ])
2782 ])
2784 dnl
2785 dnl H262 encoder plugin (lib262)
2786 dnl
2787 AC_ARG_ENABLE(x262,
2788 [ --enable-x262 H262 encoding support with static libx262 (default disabled)])
2789 if test "${enable_x262}" != "no"; then
2790 PKG_CHECK_MODULES(X262, x262, [
2791 VLC_ADD_PLUGIN([x262])
2792 VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2793 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2794 VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2795 ])
2796 VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2797 if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2798 VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2799 fi
2800 ], [
2801 if test "${enable_x262}" = "yes"; then
2802 AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2803 fi
2804 ])
2805 fi
2807 dnl x265 encoder
2808 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2810 dnl
2811 dnl H264 encoder plugin (10-bit lib264)
2812 dnl
2813 AC_ARG_ENABLE(x26410b,
2814 [ --enable-x26410b H264 10-bit encoding support with static libx264 (default disabled)])
2815 if test "${enable_x26410b}" != "no"; then
2816 PKG_CHECK_MODULES(X26410B, x26410b, [
2817 VLC_ADD_PLUGIN([x26410b])
2818 VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2819 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2820 VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2821 ])
2822 VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2823 if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2824 VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2825 fi
2826 ], [
2827 if test "${enable_x26410b}" = "yes"; then
2828 AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2829 fi
2830 ])
2831 fi
2834 dnl
2835 dnl H264 encoder plugin (using libx264)
2836 dnl
2837 AC_ARG_ENABLE(x264,
2838 [ --enable-x264 H264 encoding support with libx264 (default enabled)])
2839 if test "${enable_x264}" != "no"; then
2840 PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2841 VLC_ADD_PLUGIN([x264])
2842 VLC_ADD_LIBS([x264],[${X264_LIBS}])
2844 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2845 VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2846 ])
2848 VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2849 if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2850 VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2851 fi
2852 ],[
2853 if test "${enable_x264}" = "yes"; then
2854 AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2855 fi
2856 ])
2857 fi
2859 dnl
2860 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2861 dnl
2862 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2864 dnl
2865 dnl libfluidsynth (MIDI synthetizer) plugin
2866 dnl
2867 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2868 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2869 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2871 dnl
2872 dnl Teletext Modules
2873 dnl vbi decoder plugin (using libzbvi)
2874 dnl telx module
2875 dnl uncompatible
2876 dnl
2877 AC_ARG_ENABLE(zvbi,
2878 AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2879 libzvbi (default enabled)]))
2880 AC_ARG_ENABLE(telx,
2881 AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2882 zvbi) (default enabled if zvbi is absent)]))
2884 AS_IF( [test "${enable_zvbi}" != "no"],[
2885 PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2886 [
2887 VLC_ADD_PLUGIN([zvbi])
2888 AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2889 AS_IF( [test "${enable_telx}" = "yes"],[
2890 AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2891 ])
2892 ],[
2893 AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2894 ])
2895 ])
2896 AS_IF( [test "${enable_telx}" != "no" ],[
2897 VLC_ADD_PLUGIN([telx])
2898 ])
2900 dnl
2901 dnl libass subtitle rendering module
2902 dnl
2903 AC_ARG_ENABLE(libass,
2904 [ --enable-libass Subtitle support using libass (default enabled)])
2905 AS_IF( [test "${enable_libass}" != "no"], [
2906 PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2907 [
2908 VLC_ADD_PLUGIN([libass])
2910 AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2911 [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2912 VLC_ADD_LIBS([libass],[-lfontconfig])
2913 ])
2914 ],[
2915 AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2916 ])
2917 ])
2919 dnl
2920 dnl ARIB subtitles rendering module
2921 dnl
2922 AC_ARG_ENABLE(aribsub,
2923 [ --enable-aribsub ARIB Subtitles support (default enabled)])
2924 AS_IF( [test "${enable_aribsub}" != "no" ],[
2925 PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2926 have_aribb24="yes"
2927 VLC_ADD_PLUGIN([aribsub])
2928 VLC_ADD_LIBS([aribsub],[-laribb24])
2929 AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2930 ],[
2931 AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2932 have_aribb24="no"
2933 ])
2934 ])
2935 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2937 dnl
2938 dnl ARIB B25
2939 dnl
2940 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2942 dnl
2943 dnl kate decoder plugin
2944 dnl
2945 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2947 dnl
2948 dnl tiger rendering for kate decoder plugin
2949 dnl
2950 AC_ARG_ENABLE(tiger,
2951 [ --enable-tiger Tiger rendering library for Kate streams (default auto)])
2952 AS_IF([test "${enable_tiger}" != "no"], [
2953 PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2954 AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2955 AS_IF([test -n "${enable_tiger}"], [
2956 AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2957 ])
2958 ])
2959 ])
2962 dnl
2963 dnl Video plugins
2964 dnl
2966 EXTEND_HELP_STRING([Video plugins:])
2968 dnl
2969 dnl OpenGL
2970 dnl
2971 PKG_CHECK_MODULES([EGL], [egl], [
2972 have_egl="yes"
2973 ], [
2974 have_egl="no"
2975 ])
2976 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2978 have_gl="no"
2979 PKG_CHECK_MODULES([GL], [gl], [
2980 have_gl="yes"
2981 ], [
2982 AC_MSG_CHECKING([for OpenGL])
2983 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2984 #ifdef _WIN32
2985 # include <GL/glew.h>
2986 #endif
2987 #include <GL/gl.h>
2988 ]], [
2989 [int t0 = GL_TEXTURE0;]])
2990 ], [
2991 GL_CFLAGS=""
2992 have_gl="yes"
2993 AS_IF([test "${SYS}" != "mingw32"], [
2994 GL_LIBS="-lGL"
2995 ], [
2996 GL_LIBS="-lopengl32"
2997 ])
2998 ])
2999 AC_MSG_RESULT([${have_gl}])
3000 ])
3001 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3003 dnl OpenGL ES 2: depends on EGL 1.1
3004 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3006 dnl
3007 dnl Xlib
3008 dnl
3010 AC_PATH_XTRA()
3011 AC_CHECK_HEADERS(X11/Xlib.h)
3013 dnl
3014 dnl X C Bindings modules
3015 dnl
3016 AC_ARG_ENABLE(xcb,
3017 [ --enable-xcb X11 support with XCB (default enabled)],, [
3018 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3019 enable_xcb="yes"
3020 ], [
3021 enable_xcb="no"
3022 ])
3023 ])
3024 AC_ARG_ENABLE(xvideo,
3025 [ --enable-xvideo XVideo support (default enabled)],, [
3026 enable_xvideo="$enable_xcb"
3027 ])
3029 have_xcb="no"
3030 have_xcb_keysyms="no"
3031 have_xcb_randr="no"
3032 have_xcb_xvideo="no"
3033 AS_IF([test "${enable_xcb}" != "no"], [
3034 dnl libxcb
3035 PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3036 have_xcb="yes"
3037 PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3038 PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3039 PKG_CHECK_MODULES(XPROTO, [xproto])
3041 AS_IF([test "${enable_xvideo}" != "no"], [
3042 PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3043 ])
3045 PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3047 dnl xcb-utils
3048 PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3049 AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3050 ])
3051 ])
3052 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3053 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3054 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3055 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3058 dnl
3059 dnl VDPAU needs X11
3060 dnl
3061 AC_ARG_ENABLE(vdpau,
3062 [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3063 have_vdpau="no"
3064 AS_IF([test "${enable_vdpau}" != "no"], [
3065 PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3066 have_vdpau="yes"
3067 AS_IF([test "${no_x}" = "yes"], [
3068 AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3069 ])
3070 ], [
3071 AS_IF([test -n "${enable_vdpau}"], [
3072 AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3073 ])
3074 ])
3075 ])
3076 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3078 have_avcodec_vdpau="no"
3079 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3080 case "${avfork}" in
3081 libav) av_vdpau_ver="56.10.0" ;;
3082 ffmpeg) av_vdpau_ver="56.19.100" ;;
3083 esac
3084 PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3085 have_avcodec_vdpau="yes"
3086 AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3087 ], [
3088 AS_IF([test -n "${enable_vdpau}"], [
3089 AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3090 ], [
3091 AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3092 ])
3093 ])
3094 ])
3095 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3098 dnl
3099 dnl Wayland
3100 dnl
3101 AC_ARG_ENABLE(wayland,
3102 [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3103 have_wayland="no"
3104 have_wayland_egl="no"
3106 AS_IF([test "${enable_wayland}" != "no"], [
3107 PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3108 AC_MSG_CHECKING([for the Wayland protocols])
3109 PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3110 WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3111 AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3112 ], [
3113 AC_MSG_RESULT([not found])
3114 AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3115 ])
3117 AC_MSG_CHECKING([for the Wayland scanner])
3118 PKG_CHECK_EXISTS([wayland-scanner], [
3119 WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3120 AC_MSG_RESULT([${WAYLAND_SCANNER}])
3121 ], [
3122 AC_MSG_RESULT([not found])
3123 AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3124 ])
3126 have_wayland="yes"
3128 AS_IF([test "${have_egl}" = "yes"], [
3129 PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3130 have_wayland_egl="yes"
3131 ], [
3132 AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3133 ])
3134 ])
3135 ], [
3136 AS_IF([test -n "${enable_wayland}"], [
3137 AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3138 ])
3139 ])
3140 ])
3141 AC_SUBST([WAYLAND_PROTOCOLS])
3142 AC_SUBST([WAYLAND_SCANNER])
3143 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3144 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3147 dnl
3148 dnl SDL image decoder module
3149 dnl
3150 AC_ARG_ENABLE(sdl-image,
3151 [ --enable-sdl-image SDL image support (default enabled)])
3152 AS_IF([test "${enable_sdl_image}" != "no"],[
3153 PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3154 VLC_ADD_PLUGIN([sdl_image])
3155 ], [
3156 AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3157 ])
3158 ])
3160 dnl
3161 dnl freetype module
3162 dnl
3163 AC_ARG_ENABLE(freetype,
3164 [ --enable-freetype freetype support (default auto)])
3165 AC_ARG_ENABLE(fribidi,
3166 [ --enable-fribidi fribidi support (default auto)])
3167 AC_ARG_ENABLE(harfbuzz,
3168 [ --enable-harfbuzz harfbuzz support (default auto)])
3169 AC_ARG_ENABLE(fontconfig,
3170 [ --enable-fontconfig fontconfig support (default auto)])
3172 AC_ARG_WITH([default-font],
3173 AS_HELP_STRING([--with-default-font=PATH],
3174 [Path to the default font]),
3175 [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3176 "$withval", [Default font])])
3177 AC_ARG_WITH([default-monospace-font],
3178 AS_HELP_STRING([--with-default-monospace-font=PATH],
3179 [Path to the default font]),
3180 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3181 "$withval", [Default monospace font])])
3183 AC_ARG_WITH([default-font-family],
3184 AS_HELP_STRING([--with-default-font-family=NAME],
3185 [Path to the default font family]),
3186 [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3187 "$withval", [Default font family])])
3188 AC_ARG_WITH([default-monospace-font-family],
3189 AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3190 [Path to the default font family]),
3191 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3192 "$withval", [Default monospace font family])])
3194 have_freetype="no"
3195 have_fontconfig="no"
3196 have_fribidi="no"
3197 have_harfbuzz="no"
3199 if test "${enable_freetype}" != "no"; then
3200 PKG_CHECK_MODULES(FREETYPE, freetype2, [
3201 have_freetype="yes"
3202 VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3203 VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3205 dnl fontconfig support
3206 AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3207 PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3208 have_fontconfig="yes"
3209 ], [
3210 AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3211 ])
3212 ])
3214 dnl fribidi support
3215 if test "${enable_fribidi}" != "no"; then
3216 PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3217 have_fribidi="yes"
3218 VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3219 VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3220 ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3221 fi
3223 dnl harfbuzz support
3224 if test "${have_fribidi}" != "no"; then
3225 if test "${enable_harfbuzz}" != "no"; then
3226 PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3227 have_harfbuzz="yes"
3228 VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3229 VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3230 ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3231 fi
3232 fi
3233 ],[
3234 AS_IF([test -n "${enable_freetype}"],[
3235 AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3236 ])
3237 ])
3238 fi
3240 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3241 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3242 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3243 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3245 dnl
3246 dnl SAPI (text to Speech renderer for Windows)
3247 dnl
3248 AC_LANG_PUSH([C++])
3249 AC_CHECK_TYPES([ISpObjectToken],[
3250 have_sapi="yes"
3251 ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3252 [#include <windows.h>
3253 #include <sapi.h>
3254 #include <sphelper.h>])
3255 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3256 AC_LANG_POP([C++])
3258 dnl
3259 dnl SVG module (text rendering and image decoding)
3260 dnl
3261 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3262 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3264 dnl
3265 dnl Windows DirectX module
3266 dnl
3268 AC_ARG_ENABLE(directx,
3269 [AS_HELP_STRING([--enable-directx],
3270 [Microsoft DirectX support (default enabled on Windows)])],, [
3271 AS_IF([test "${SYS}" = "mingw32"], [
3272 enable_directx="yes"
3273 ], [
3274 enable_directx="no"
3275 ])
3276 ])
3277 AS_IF([test "${enable_directx}" != "no"], [
3278 dnl DirectDraw
3279 AC_CHECK_HEADERS(ddraw.h, [
3280 VLC_ADD_PLUGIN([directdraw])
3281 ])
3283 dnl OpenGL
3284 AC_CHECK_HEADERS(GL/wglew.h, [
3285 VLC_ADD_PLUGIN([glwin32 wgl])
3286 ],, [
3287 #include <windows.h>
3288 #include <GL/gl.h>
3289 ])
3291 dnl Direct3D11
3292 AC_CHECK_HEADERS(d3d11.h, [
3293 VLC_ADD_PLUGIN([direct3d11 direct3d11_deinterlace direct3d11_adjust])
3294 ])
3296 dnl Direct3D9
3297 AC_CHECK_HEADERS(d3d9.h, [
3298 VLC_ADD_PLUGIN([direct3d9])
3299 AC_CHECK_HEADERS(d3dx9effect.h)
3301 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3302 [[#define COBJMACROS
3303 #include <d3d9.h>
3304 #include <dxva2api.h>
3305 #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3306 # error dxva2 too old
3307 #endif
3308 ]],[[;]])
3309 ],[
3310 VLC_ADD_PLUGIN([direct3d9_deinterlace direct3d9_adjust])
3311 ],
3312 [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3314 ])
3315 ])
3317 dnl
3318 dnl Linux framebuffer module
3319 dnl
3320 AC_CHECK_HEADER([linux/fb.h], [
3321 VLC_ADD_PLUGIN([fb])
3322 ])
3325 dnl
3326 dnl AA plugin
3327 dnl
3328 AC_ARG_ENABLE(aa,
3329 [ --enable-aa aalib output (default disabled)])
3330 if test "${enable_aa}" = "yes"
3331 then
3332 AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3333 if test "${have_aa}" = "true"
3334 then
3335 VLC_ADD_PLUGIN([aa])
3336 fi
3337 fi
3339 dnl
3340 dnl libcaca plugin
3341 dnl
3342 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3344 dnl
3345 dnl OS/2 KVA plugin
3346 dnl
3347 AC_ARG_ENABLE(kva,
3348 [AS_HELP_STRING([--enable-kva],
3349 [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3350 AS_IF([test "$SYS" = "os2"], [
3351 enable_kva="yes"
3352 ])
3353 ])
3354 have_kva="no"
3355 KVA_LIBS=""
3356 AS_IF([test "$enable_kva" != "no"], [
3357 AC_CHECK_HEADERS([kva.h], [
3358 have_kva="yes"
3359 AC_CHECK_LIB(kva, main, [
3360 KVA_LIBS="-lkva"
3361 ])
3362 ])
3363 ])
3364 AC_SUBST(KVA_LIBS)
3365 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3367 dnl
3368 dnl MMAL plugin
3369 dnl
3370 AC_ARG_ENABLE(mmal,
3371 AS_HELP_STRING([--enable-mmal],
3372 [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3373 if test "${enable_mmal}" != "no"; then
3374 VLC_SAVE_FLAGS
3375 LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3376 CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3377 AC_CHECK_HEADERS(interface/mmal/mmal.h,
3378 [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3379 have_mmal="yes"
3380 VLC_ADD_PLUGIN([mmal])
3381 VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3382 VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3383 VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3384 AS_IF([test "${enable_mmal}" = "yes"],
3385 [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3386 [ AC_MSG_WARN([Cannot find bcm library...]) ])
3387 ],
3388 [])
3389 ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3390 [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3391 [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3392 VLC_RESTORE_FLAGS
3393 fi
3394 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3396 dnl
3397 dnl evas plugin
3398 dnl
3399 AC_ARG_ENABLE(evas,
3400 [AS_HELP_STRING([--enable-evas],
3401 [use evas output module (default disabled)])])
3402 have_evas="no"
3403 AS_IF([test "${enable_evas}" = "yes"], [
3404 PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3405 have_evas="yes"
3406 AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3407 ],[
3408 AS_IF([test "x${enable_evas}" != "x"], [
3409 AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3410 ])
3411 ])
3412 ])
3413 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3415 dnl
3416 dnl Audio plugins
3417 dnl
3419 EXTEND_HELP_STRING([Audio plugins:])
3421 dnl
3422 dnl Pulseaudio module
3423 dnl
3424 AC_ARG_ENABLE(pulse,
3425 [AS_HELP_STRING([--enable-pulse],
3426 [use the PulseAudio client library (default auto)])])
3427 have_pulse="no"
3428 AS_IF([test "${enable_pulse}" != "no"], [
3429 PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3430 have_pulse="yes"
3431 ], [
3432 AS_IF([test "x${enable_pulse}" != "x"], [
3433 AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3434 ])
3435 ])
3436 ])
3437 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3439 dnl
3440 dnl ALSA module
3441 dnl
3442 AC_ARG_ENABLE(alsa,
3443 [AS_HELP_STRING([--enable-alsa],
3444 [support the Advanced Linux Sound Architecture (default auto)])],, [
3445 AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3446 enable_alsa="yes"
3447 ])
3448 ])
3449 have_alsa="no"
3450 AS_IF([test "${enable_alsa}" != "no"], [
3451 PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3452 have_alsa="yes"
3453 ], [
3454 AS_IF([test "x${enable_alsa}" != "x"], [
3455 AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3456 ])
3457 ])
3458 ])
3459 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3461 dnl
3462 dnl Open Sound System module
3463 dnl
3464 AC_ARG_ENABLE(oss,
3465 [AS_HELP_STRING([--enable-oss],
3466 [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3467 AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3468 enable_oss="no"
3469 ])
3470 ])
3471 have_oss="no"
3472 OSS_LIBS=""
3473 AS_IF([test "$enable_oss" != "no"], [
3474 AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3475 have_oss="yes"
3476 AC_CHECK_LIB(ossaudio, main, [
3477 OSS_LIBS="-lossaudio"
3478 ])
3479 ])
3480 ])
3481 AC_SUBST(OSS_LIBS)
3482 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3484 dnl
3485 dnl OpenBSD sndio module
3486 dnl
3487 AC_ARG_ENABLE([sndio],
3488 [AS_HELP_STRING([--disable-sndio],
3489 [support the OpenBSD sndio (default auto)])],, [
3490 AS_IF([test "$SYS" = "openbsd"], [
3491 enable_sndio="yes"
3492 ])
3493 ])
3494 have_sndio="no"
3495 AS_IF([test "$enable_sndio" != "no"], [
3496 AC_CHECK_HEADER([sndio.h], [
3497 have_sndio="yes"
3498 ])
3499 ])
3500 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3502 dnl
3503 dnl Windows Audio Session plugin
3504 dnl
3505 AC_ARG_ENABLE([wasapi],
3506 [AS_HELP_STRING([--enable-wasapi],
3507 [use the Windows Audio Session API (default auto)])
3508 ])
3509 have_wasapi="no"
3510 AS_IF([test "$enable_wasapi" != "no"], [
3511 AC_CHECK_HEADER([audioclient.h], [
3512 have_wasapi="yes"
3513 ], [
3514 AS_IF([test "x${enable_wasapi}" != "x"], [
3515 AC_MSG_ERROR([Windows Audio Session API not found.])
3516 ])
3517 ])
3518 ])
3519 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3521 dnl
3522 dnl JACK modules
3523 dnl
3524 AC_ARG_ENABLE(jack,
3525 [AS_HELP_STRING([--disable-jack],
3526 [do not use jack (default auto)])])
3527 have_jack="no"
3528 AS_IF([test "${enable_jack}" != "no"], [
3529 PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3530 [ have_jack=yes ],
3531 [
3532 AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3534 PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3535 [ have_jack=yes ],
3536 [
3537 AS_IF([test -n "${enable_jack}"],
3538 [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3539 [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3540 ])
3541 ])
3542 ])
3543 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3545 dnl
3546 dnl OpenSLES Android
3547 dnl
3548 AC_ARG_ENABLE(opensles,
3549 [ --enable-opensles Android OpenSL ES audio module (default disabled)])
3550 if test "${HAVE_ANDROID}" = "1"; then
3551 if test "${enable_opensles}" = "yes"; then
3552 AC_CHECK_HEADERS(SLES/OpenSLES.h,
3553 [ VLC_ADD_PLUGIN([opensles_android]) ],
3554 [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3555 fi
3556 fi
3558 dnl
3559 dnl Tizen audio
3560 dnl
3561 AC_ARG_ENABLE(tizen_audio,
3562 [AS_HELP_STRING([--enable-tizen-audio],
3563 [Tizen audio module (default enabled on Tizen)])],, [
3564 AS_IF([test "$HAVE_TIZEN" = "1"], [
3565 enable_tizen_audio="yes"
3566 ])
3567 ])
3568 if test "${enable_tizen_audio}" = "yes"; then
3569 AC_CHECK_HEADERS(audio_io.h,
3570 [ VLC_ADD_PLUGIN([tizen_audio]) ],
3571 [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3572 fi
3574 dnl
3575 dnl libsamplerate plugin
3576 dnl
3577 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3579 dnl
3580 dnl soxr module
3581 dnl
3582 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3584 dnl
3585 dnl OS/2 KAI plugin
3586 dnl
3587 AC_ARG_ENABLE(kai,
3588 [AS_HELP_STRING([--enable-kai],
3589 [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3590 AS_IF([test "$SYS" = "os2"], [
3591 enable_kai="yes"
3592 ])
3593 ])
3594 have_kai="no"
3595 KAI_LIBS=""
3596 AS_IF([test "$enable_kai" != "no"], [
3597 AC_CHECK_HEADERS([kai.h], [
3598 have_kai="yes"
3599 AC_CHECK_LIB(kai, main, [
3600 KAI_LIBS="-lkai"
3601 ])
3602 ])
3603 ])
3604 AC_SUBST(KAI_LIBS)
3605 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3607 dnl
3608 dnl chromaprint audio track fingerprinter
3609 dnl
3610 m4_pushdef([libchromaprint_version], 0.6.0)
3611 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3612 VLC_ADD_PLUGIN([stream_out_chromaprint]),
3613 AS_IF([test "${enable_chromaprint}" = "yes"],
3614 [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3615 [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3616 ),
3617 [(Chromaprint based audio fingerprinter)],[auto])
3618 m4_popdef([libchromaprint_version])
3620 dnl
3621 dnl Chromecast streaming support
3622 dnl
3623 m4_pushdef([protobuf_lite_version], 2.5.0)
3624 AC_ARG_VAR(PROTOC, [protobuf compiler])
3625 AC_CHECK_PROGS(PROTOC, protoc, no)
3626 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3627 AS_IF([test "x${PROTOC}" != "xno"], [
3628 build_chromecast="yes"
3629 ], [
3630 AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3631 ])
3632 ], [
3633 AS_IF([test "${enable_chromecast}" = "yes"],
3634 AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3635 AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3636 )
3637 enable_chromecast="no"
3638 ], [(Chromecast streaming support)], [auto])
3639 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3640 m4_popdef([protobuf_lite_version])
3642 dnl
3643 dnl Interface plugins
3644 dnl
3646 EXTEND_HELP_STRING([Interface plugins:])
3648 dnl
3649 dnl QT
3650 dnl
3651 AC_ARG_ENABLE(qt, [
3652 AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3653 AS_IF([test "${SYS}" = "darwin"], [
3654 enable_qt="no"
3655 ])
3656 ])
3657 have_qt5_x11="no"
3658 AS_IF([test "${enable_qt}" != "no"], [
3659 PKG_CHECK_MODULES([QT], [Qt5Core >= 5.2.0 Qt5Widgets Qt5Gui], [
3660 PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3661 have_qt5_x11="yes"
3662 ],[
3663 AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3664 ])
3665 QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3666 QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3667 QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3668 AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3669 AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3670 AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3671 ], [
3672 PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.8.0],, [
3673 AS_IF([test -n "${enable_qt}"],[
3674 AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3675 ],[
3676 AC_MSG_WARN([${QT_PKG_ERRORS}.])
3677 ])
3678 enable_qt="no"
3679 ])
3680 QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3681 AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin"])
3682 AC_PATH_PROG(RCC, rcc, rcc, ["${QT_PATH}/bin"])
3683 AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin"])
3684 ])
3685 ])
3686 AS_IF([test "${enable_qt}" != "no"], [
3687 ALIASES="${ALIASES} qvlc"
3688 ])
3689 AC_SUBST(QT_VERSION)
3690 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3691 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3693 dnl
3694 dnl detect kde4-config patch (used for kde solids).
3695 dnl
3696 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3697 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3698 KDE4_CONFIG="kde4-config"
3699 ])
3701 dnl
3702 dnl Simple test for skins2 dependency
3703 dnl
3704 AS_IF([test "$enable_qt" = "no"], [
3705 AS_IF([test "${enable_skins2}" = "yes"], [
3706 AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3707 ], [
3708 enable_skins2="no"
3709 AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3710 ])
3711 ])
3713 dnl
3714 dnl Skins2 module
3715 dnl
3716 AC_ARG_ENABLE(skins2,
3717 [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3718 AS_IF([test "${enable_skins2}" != "no"], [
3719 have_skins_deps="yes"
3721 dnl Win32
3722 AS_IF([test "${SYS}" = "mingw32"], [
3723 VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3724 VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3725 dnl OS/2
3726 ], [test "${SYS}" = "os2"], [
3727 VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3728 dnl Linux/Unix
3729 ], [
3730 PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3731 PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3732 PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3733 VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3734 VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3735 ])
3737 dnl we need freetype
3738 AS_IF([test "${have_freetype}" != "yes"], [
3739 have_skins_deps="no"
3740 ])
3742 AS_IF([test "${have_skins_deps}" = "no"], [
3743 AS_IF([test "x${enable_skins2}" = "x"], [
3744 AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3745 ], [
3746 AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3747 ])
3748 enable_skins2="no"
3749 ], [
3750 ALIASES="${ALIASES} svlc"
3751 enable_skins2="yes"
3752 ])
3753 ])
3754 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3756 AC_ARG_ENABLE(libtar,
3757 [ --enable-libtar libtar support for skins2 (default auto)])
3758 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3759 AC_CHECK_HEADERS(libtar.h, [
3760 VLC_ADD_LIBS([skins2],[-ltar])
3761 ])
3762 ])
3764 dnl
3765 dnl MacOS X gui module
3766 dnl
3767 AC_ARG_ENABLE(macosx,
3768 [ --enable-macosx Mac OS X gui support (default enabled on Mac OS X)])
3769 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3770 then
3772 dnl
3773 dnl If possible, use xcrun to find the right ibtool
3774 dnl
3776 AC_PATH_PROG([XCRUN], [xcrun], [no])
3777 AS_IF([test ! "x${XCRUN}" = "xno"], [
3778 AC_MSG_CHECKING([for ibtool (using xcrun)])
3779 XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3780 AC_MSG_RESULT([${XIB}])
3781 ], [
3782 AC_MSG_WARN([Looking for tools without using xcrun])
3783 ])
3785 AS_IF([test "x${XIB}" = "xno"], [
3786 AC_PATH_PROG(XIB, [ibtool], [no])
3787 AS_IF([test "x${XIB}" = "xno"], [
3788 AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3789 ])
3790 ])
3791 fi
3792 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3794 dnl
3795 dnl MacOS X sparkle update support
3796 dnl
3797 AC_ARG_ENABLE(sparkle,
3798 [ --enable-sparkle Sparkle update support for OS X (default enabled on Mac OS X)])
3799 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3800 then
3801 if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3802 then
3803 AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3804 fi
3806 AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3807 fi
3808 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3810 dnl
3811 dnl MacOS X breakpad creash reporter support
3812 dnl
3813 AC_ARG_ENABLE(breakpad,
3814 [ --enable-breakpad Breakpad crash reporter support for OS X (default enabled on Mac OS X)])
3815 if test "x${enable_breakpad}" != "xno" -a "${HAVE_OSX}" = "1"
3816 then
3817 if test ! -d ${CONTRIB_DIR}/Breakpad.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework
3818 then
3819 AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3820 fi
3822 AC_DEFINE([HAVE_BREAKPAD], [1], [Define to 1 if breakpad is enabled.])
3823 fi
3824 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$enable_breakpad" != "no"])
3827 dnl
3828 dnl Minimal Mac OS X module
3829 dnl
3830 AC_ARG_ENABLE(minimal-macosx,
3831 [ --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3832 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3833 then
3834 VLC_ADD_PLUGIN([minimal_macosx])
3835 fi
3837 dnl
3838 dnl Mac OS X fancy dmg build tool
3839 dnl
3840 if test "${HAVE_OSX}" = "1"
3841 then
3842 AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3843 AS_IF([test "x${DMGBUILD}" = "xno"], [
3844 AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3845 ])
3846 fi
3847 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3849 dnl
3850 dnl VideoToolbox plugins
3851 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3852 VLC_ADD_PLUGIN([videotoolbox])
3853 VLC_ADD_PLUGIN([cvpx])
3854 ])
3856 dnl
3857 dnl ncurses module
3858 dnl
3859 AC_ARG_ENABLE(ncurses,
3860 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3861 have_ncurses="no"
3862 AS_IF([test "${enable_ncurses}" != "no"] ,[
3863 PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3864 have_ncurses="yes"
3865 ALIASES="${ALIASES} nvlc"
3866 ], [
3867 AS_IF([test -n "${enable_ncurses}"], [
3868 AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3869 ])
3870 ])
3871 ])
3872 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3874 dnl
3875 dnl Lirc plugin
3876 dnl
3877 AC_ARG_ENABLE(lirc,
3878 [ --enable-lirc lirc support (default disabled)])
3879 have_lirc="no"
3880 AS_IF([test "${enable_lirc}" = "yes"], [
3881 AC_CHECK_HEADER(lirc/lirc_client.h, [
3882 AC_CHECK_LIB(lirc_client, lirc_init, [
3883 have_lirc="yes"
3884 ])
3885 ])
3886 ])
3887 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3889 dnl
3890 dnl SRT plugin
3891 dnl
3892 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.0], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
3894 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3895 dnl
3896 dnl goom visualization plugin
3897 dnl
3898 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3900 dnl
3901 dnl libprojectM visualization plugin
3902 dnl
3903 AC_ARG_ENABLE(projectm,
3904 [ --enable-projectm projectM visualization plugin (default enabled)])
3905 AS_IF([test "${enable_projectm}" != "no"],
3906 [
3907 PKG_CHECK_MODULES(PROJECTM, libprojectM,
3908 [
3909 VLC_ADD_PLUGIN([projectm])
3910 PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3911 [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3912 [ AC_MSG_WARN( [Using libprojectM version 1] )
3913 ])
3914 ],[
3915 AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3916 ])
3917 ])
3919 dnl
3920 dnl Vovoid VSXu visualization plugin
3921 dnl
3922 AC_ARG_ENABLE(vsxu,
3923 [ --enable-vsxu Vovoid VSXu visualization plugin (default auto)])
3924 AS_IF([test "${enable_vsxu}" != "no"],
3925 [
3926 PKG_CHECK_MODULES(VSXU, libvsxu,
3927 [
3928 VLC_ADD_PLUGIN([vsxu])
3929 ],[
3930 AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3931 ])
3932 ])
3934 EXTEND_HELP_STRING([Service Discovery plugins:])
3935 dnl
3936 dnl Avahi-Zeroconf services discovery
3937 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3939 dnl
3940 dnl libudev services discovery
3941 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3943 dnl
3944 dnl MTP devices services discovery
3945 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3947 dnl
3948 dnl UPnP Plugin (Intel SDK)
3949 dnl
3950 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3952 dnl
3953 dnl mDNS using libmicrodns
3954 dnl
3955 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
3958 EXTEND_HELP_STRING([Misc options:])
3960 dnl
3961 dnl libxml2 module
3962 dnl
3963 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3966 dnl
3967 dnl libgcrypt
3968 dnl
3969 AC_ARG_ENABLE(libgcrypt,
3970 [ --disable-libgcrypt gcrypt support (default enabled)])
3971 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
3972 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
3974 # require libgcrypt >= 1.6.0
3975 AS_IF([test "${enable_libgcrypt}" != "no"], [
3976 AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
3977 VLC_SAVE_FLAGS
3978 CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
3979 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
3980 [#include <gcrypt.h>
3981 #if GCRYPT_VERSION_NUMBER < 0x010600
3982 #error
3983 #endif]])], [
3984 ac_cv_lib_gcrypt=yes
3985 ], [
3986 ac_cv_lib_gcrypt=no
3987 ])
3988 VLC_RESTORE_FLAGS
3989 ])
3991 AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
3992 AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
3993 ], [
3994 AS_IF([test "${enable_libgcrypt}" = "yes"], [
3995 AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
3996 ])
3997 ])
3998 ])
4000 AS_IF([test -z "$GCRYPT_LIBS"], [
4001 GCRYPT_LIBS="-lgcrypt -lgpg-error"
4002 ])
4004 AC_SUBST(GCRYPT_CFLAGS)
4005 AC_SUBST(GCRYPT_LIBS)
4006 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4008 dnl
4009 dnl TLS/SSL
4010 dnl
4011 AC_ARG_ENABLE(gnutls,
4012 [ --enable-gnutls GNU TLS TLS/SSL support (default enabled)])
4013 AS_IF([test "${enable_gnutls}" != "no"], [
4014 PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4015 VLC_ADD_PLUGIN([gnutls])
4016 ], [
4017 AS_IF([test -n "${enable_gnutls}"], [
4018 AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4019 ])
4020 ])
4021 ])
4024 dnl
4025 dnl Taglib plugin
4026 dnl
4027 AC_ARG_ENABLE(taglib,
4028 [AS_HELP_STRING([--disable-taglib],
4029 [do not use TagLib (default enabled)])])
4030 AS_IF([test "${enable_taglib}" != "no"], [
4031 PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4032 VLC_ADD_PLUGIN([taglib])
4033 ], [
4034 AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4035 ])
4037 dnl
4038 dnl libsecret
4039 dnl
4040 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4042 dnl
4043 dnl kwallet
4044 dnl
4045 AC_ARG_ENABLE(kwallet,
4046 [AS_HELP_STRING([--enable-kwallet],
4047 [use kwallet (via D-Bus) for keystore (default enabled)])])
4048 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4049 VLC_ADD_PLUGIN([kwallet])
4050 ])
4052 dnl
4053 dnl Developers helper modules (should be hidden from configure help)
4054 dnl
4055 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4056 AS_IF([test "${enable_devtools}" != "no"], [
4057 VLC_ADD_PLUGIN([accesstweaks])
4058 ])
4060 dnl
4061 dnl update checking system
4062 dnl
4063 AC_ARG_ENABLE(update-check,
4064 [ --enable-update-check update checking system (default disabled)])
4065 if test "${enable_update_check}" = "yes"
4066 then
4067 AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4068 AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4069 fi
4070 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4072 dnl
4073 dnl OS X notification plugin
4074 dnl
4075 AC_ARG_ENABLE(osx_notifications,
4076 [ --enable-osx-notifications osx notification plugin (default disabled)],,
4077 [enable_osx_notifications=no])
4078 AS_IF([test "${enable_osx_notifications}" != "no"], [
4079 if test -d ${CONTRIB_DIR}/Growl.framework -o -d ${CONTRIB_DIR}/Frameworks/Growl.framework
4080 then
4081 VLC_ADD_PLUGIN([osx_notifications])
4082 VLC_ADD_LIBS([osx_notifications], [-Wl,-framework,Growl,-framework,Foundation])
4083 VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4084 fi
4085 ])
4087 dnl
4088 dnl Libnotify notification plugin
4089 dnl
4090 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4092 dnl
4093 dnl Endianness check
4094 dnl
4095 AC_C_BIGENDIAN
4096 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4097 DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4098 ], [
4099 DEFS_BIGENDIAN=""
4100 ])
4101 AC_SUBST(DEFS_BIGENDIAN)
4103 dnl
4104 dnl Where to install KDE solid .desktop
4105 dnl
4106 AC_ARG_WITH(kde-solid,
4107 AS_HELP_STRING([--with-kde-solid=PATH],
4108 [KDE Solid actions directory (auto)]),, [
4110 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4111 with_kde_solid="yes"
4112 fi
4113 ])
4114 soliddatadir=""
4115 AS_IF([test "${with_kde_solid}" != "no"], [
4116 AS_IF([test "${with_kde_solid}" = "yes"], [
4117 kde4datadir="`${KDE4_CONFIG} --install data`"
4118 AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4119 soliddatadir="${kde4datadir}/solid/actions"
4120 ], [
4121 soliddatadir="${with_kde_solid}"
4122 ])
4123 ])
4124 AC_SUBST(soliddatadir)
4125 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4127 dnl
4128 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4129 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4130 dnl
4131 if test "${SYS}" = "mingw32"; then
4132 AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4133 fi
4135 EXTEND_HELP_STRING([Components:])
4137 dnl
4138 dnl the VLC binary
4139 dnl
4140 AC_ARG_ENABLE(vlc,
4141 [ --enable-vlc build the VLC media player (default enabled)])
4142 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4144 dnl
4145 dnl Stuff used by the program
4146 dnl
4147 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4148 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4149 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4150 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4151 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4152 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4153 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4154 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4155 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4156 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4157 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4158 AC_SUBST(COPYRIGHT_MESSAGE)
4159 AC_SUBST(VERSION_MESSAGE)
4160 AC_SUBST(VERSION_MAJOR)
4161 AC_SUBST(VERSION_MINOR)
4162 AC_SUBST(VERSION_REVISION)
4163 AC_SUBST(VERSION_EXTRA)
4164 AC_SUBST(COPYRIGHT_YEARS)
4165 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4166 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4167 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4168 dnl
4169 dnl Handle substvars that use $(top_srcdir)
4170 dnl
4171 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4173 dnl
4174 dnl Configuration is finished
4175 dnl
4176 AC_SUBST(SYS)
4177 AC_SUBST(ARCH)
4178 AC_SUBST(ALIASES)
4179 AC_SUBST(ASM)
4180 AC_SUBST(MOC)
4181 AC_SUBST(RCC)
4182 AC_SUBST(UIC)
4183 AC_SUBST(WINDRES)
4184 AC_SUBST(WINE_SDK_PATH)
4185 AC_SUBST(LIBEXT)
4186 AC_SUBST(AM_CPPFLAGS)
4187 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4188 AC_SUBST(FILE_LIBVLCCORE_DLL)
4189 AC_SUBST(FILE_LIBVLC_DLL)
4191 AC_CONFIG_FILES([
4192 Makefile
4193 doc/Makefile
4194 modules/Makefile
4195 m4/Makefile
4196 po/Makefile.in
4197 share/Makefile
4198 compat/Makefile
4199 src/Makefile
4200 lib/Makefile
4201 bin/Makefile
4202 test/Makefile
4203 modules/hw/mmal/Makefile
4204 share/vlc.appdata.xml.in
4205 ])
4207 AM_COND_IF([HAVE_WIN32], [
4208 AC_CONFIG_FILES([
4209 extras/package/win32/NSIS/spad.nsi
4210 extras/package/win32/NSIS/vlc.win32.nsi
4211 extras/package/win32/msi/config.wxi
4212 ])
4213 ])
4215 AM_COND_IF([HAVE_DARWIN], [
4216 AC_CONFIG_FILES([
4217 modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4218 share/macosx/Info.plist:share/Info.plist.in
4219 ])
4220 ])
4222 dnl Generate makefiles
4223 AC_OUTPUT
4225 dnl Do we have to use make or gmake ?
4226 if make --version 2>&1|grep -q GNU
4227 then
4228 # GNU make, all seems good
4229 MAKE=make
4230 else
4231 # Known GNU make alias (on BSD)
4232 MAKE=gmake
4233 fi
4234 dnl Shortcut to nice compile message
4235 if test -n $SHELL; then
4236 SHELL=${CONFIG_SHELL-/bin/sh}
4237 fi
4238 rm -f compile
4239 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4240 echo "#! $SHELL
4241 rm -f .error\$\$
4242 ERROR=0
4243 export PATH=\"$PATH\" LANG=C
4244 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4245 test -f .error\$\$ && ERROR=1
4246 rm -f .error\$\$
4247 exit \$ERROR" >compile
4248 chmod a+x compile
4250 echo "
4251 libvlc configuration
4252 --------------------
4253 version : ${VERSION}
4254 system : ${SYS}
4255 architecture : ${ARCH}
4256 optimizations : ${enable_optimizations}"
4257 if test "${enable_vlc}" != "no"; then
4258 echo "vlc aliases :${ALIASES}"
4259 else
4260 echo "build vlc executable : no"
4261 fi
4262 echo "
4263 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."