configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 2002-2013 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 2.1.0-git)
   6 VERSION_MAJOR=2
   7 VERSION_MINOR=1
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Rincewind"
  17 COPYRIGHT_YEARS="1996-2013"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AM_CONFIG_HEADER(config.h)
  29
  30 # Disable with "./configure --disable-silent-rules" or "make V=1"
  31 AM_SILENT_RULES([yes])
  32
  33 dnl Too many people are not aware of maintainer mode:
  34 dnl If you want to use it, you definitely know what you are doing, so
  35 dnl you can specify "--disable-maintainer-mode". But if you want the default
  36 dnl automake behavior, you've likely never heard of maintainer mode, so we
  37 dnl can't expect you to enable it manually.
  38 AS_IF([test "x${enable_maintainer_mode}" != "xno"],
  39     [enable_maintainer_mode="yes"])
  40 AM_MAINTAINER_MODE
  41
  42 dnl
  43 dnl Directories
  44 dnl
  45 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  46 dnl AC_SUBST(vlcincludedir)
  47 vlcdatadir="\${datadir}/\${PKGDIR}"
  48 AC_SUBST(vlcdatadir)
  49 vlclibdir="\${libdir}/\${PKGDIR}"
  50 AC_SUBST(vlclibdir)
  51
  52 dnl
  53 dnl Check for tools
  54 dnl
  55 AC_PROG_CC_C99
  56 AC_USE_SYSTEM_EXTENSIONS
  57 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  58 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  59 AC_DEFINE([_REENTRANT],, [Define to expose reentrant functions.])
  60 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  61 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  62 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  63
  64 AM_PROG_CC_C_O
  65 AC_PROG_CXX
  66 AC_PROG_CPP
  67 AC_PROG_OBJC
  68 _AM_DEPENDENCIES([OBJC])
  69 AC_PROG_EGREP
  70 AC_PROG_MAKE_SET
  71 AC_PROG_INSTALL
  72 AM_PROG_AS
  73
  74 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  75 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  76
  77 dnl Check for compiler properties
  78 AC_C_CONST
  79 AC_C_INLINE
  80 AC_C_RESTRICT
  81
  82 dnl Extend the --help string at the current spot.
  83 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  84
  85 dnl Allow binary package maintainer to pass a custom string to avoid
  86 dnl cache problem
  87 AC_ARG_WITH(binary-version,
  88     AS_HELP_STRING([--with-binary-version=STRING],
  89          [To avoid plugins cache problem between binary version]),[],[])
  90 AS_IF([test -n "${with_binary_version}"],[
  91     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  92          [Binary specific version])
  93 ])
  94
  95 dnl
  96 dnl  Check the operating system
  97 dnl
  98 HAVE_WIN64="0"
  99 case "${host_os}" in
 100   "")
 101     SYS=unknown
 102     ;;
 103   linux*)
 104     SYS=linux
 105     ;;
 106   bsdi*)
 107     SYS=bsdi
 108     CFLAGS="${CFLAGS} -pthread"
 109     VLC_ADD_LIBS([vcd cdda vcdx],[-ldvd])
 110     ;;
 111   freebsd*)
 112     SYS=freebsd
 113     CFLAGS="${CFLAGS} -pthread"
 114     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 115     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 116     ;;
 117   openbsd*)
 118     SYS=openbsd
 119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 120     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 121     ;;
 122   netbsd*)
 123     SYS=netbsd
 124     ;;
 125   dragonfly*)
 126     SYS=dragonfly
 127     ;;
 128   darwin*)
 129
 130     dnl Force gcc "-arch" flag
 131     ARCH_flag=""
 132     case "${host}" in
 133       i?86*)
 134         ARCH_flag="-arch i386"
 135       ;;
 136       ppc64*)
 137         ARCH_flag="-arch ppc64"
 138       ;;
 139       ppc*)
 140         ARCH_flag="-arch ppc"
 141       ;;
 142       x86_64*)
 143         ARCH_flag="-arch x86_64"
 144       ;;
 145       arm*)
 146         ARCH_flag="-arch armv7"
 147         ac_cv_c_bigendian="no"
 148         ac_cv_c_attribute_packed="no"
 149       ;;
 150     esac
 151
 152     SYS=darwin
 153     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 154     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 155     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 156     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu99 ${ARCH_flag}"
 157     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 158     VLC_ADD_LIBS([motion rotate], [-Wl,-framework,IOKit,-framework,CoreFoundation])
 159     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 160     VLC_ADD_LIBS([avcodec access_avio swscale postproc i420_rgb_mmx x264 x26410b],[-Wl,-read_only_relocs,suppress])
 161     VLC_ADD_CFLAGS([motion rotate],[-fconstant-cfstrings])
 162     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation])
 163
 164     dnl Allow binaries created on Lion to run on earlier releases
 165     AC_EGREP_CPP(yes,
 166            [#import <Cocoa/Cocoa.h>
 167             #ifdef MAC_OS_X_VERSION_10_7
 168             yes
 169             #endif],
 170             [AC_MSG_RESULT([yes])
 171             AC_LIBOBJ([getdelim])
 172             AC_LIBOBJ([strndup])
 173             AC_LIBOBJ([strnlen])],)
 174
 175     dnl
 176     dnl  Handle Mac OS X SDK flags
 177     dnl
 178     AC_ARG_WITH(macosx-sdk,
 179       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 180         [compile using the SDK in DIR])])
 181     if test "${with_macosx_sdk}" != "" ; then
 182         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 183         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 184         CC="${CC} -isysroot ${with_macosx_sdk}"
 185         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 186         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 187         LD="${LD} -syslibroot ${with_macosx_sdk}"
 188     fi
 189     AC_ARG_WITH(macosx-version-min,
 190       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 191         [compile for Mac OS X VERSION and above])])
 192     if test "${with_macosx_version_min}" != "" ; then
 193         MACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}
 194         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 195         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 196         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 197         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 198         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 199         CFLAGS="${CFLAGS} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"
 200         CXXFLAGS="${CXXFLAGS} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"
 201         OBJCFLAGS="${OBJCFLAGS} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"
 202         export MACOSX_DEPLOYMENT_TARGET
 203     fi
 204     ;;
 205   *mingw32* | *cygwin* | *wince* | *mingwce*)
 206     AC_CHECK_TOOL(WINDRES, windres, :)
 207     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 208     AC_DEFINE([_WIN32_WINNT], 0x0502, [Define to '0x0502' for Windows XP SP2 APIs.])
 209     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 210
 211     case "${host_os}" in
 212       *mingw32*)
 213         SYS=mingw32
 214         ;;
 215       *cygwin*)
 216         dnl Check if we are using the mno-cygwin mode in which case we are
 217         dnl actually dealing with a mingw32 compiler.
 218         AC_EGREP_CPP(yes,
 219             [#ifdef WIN32
 220              yes
 221              #endif],
 222             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 223         ;;
 224     esac
 225
 226     if test "${SYS}" = "mingw32"; then
 227         VLC_ADD_LIBS([libvlccore],[-lwinmm])
 228         VLC_ADD_LDFLAGS([vlc],[-mwindows])
 229         VLC_ADD_LIBS([win32text],[-lgdi32])
 230         VLC_ADD_LIBS([vcdx],[-lwinmm])
 231         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 232         ac_default_prefix="`pwd`/_win32"
 233         DESTDIR="`pwd`/_win32/"
 234
 235         dnl
 236         dnl NSIS Installer prefix and WIN64
 237         dnl
 238         case "${host}" in
 239             amd64*|x86_64*)
 240                 HAVE_WIN64="1"
 241                 PROGRAMFILES="PROGRAMFILES64"
 242             ;;
 243             *)
 244                 PROGRAMFILES="PROGRAMFILES"
 245             ;;
 246         esac
 247         AC_SUBST(PROGRAMFILES)
 248
 249     fi
 250     ;;
 251   *nto*)
 252     SYS=nto
 253     ;;
 254   solaris*)
 255     SYS=solaris
 256     ;;
 257   hpux*)
 258     SYS=hpux
 259     ;;
 260   symbian*)
 261     SYS=symbian
 262     ;;
 263   *os2*)
 264     SYS=os2
 265     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild"
 266     ;;
 267   *)
 268     SYS="${host_os}"
 269     ;;
 270 esac
 271 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 272 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 273 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 274 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 275 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
 276 AM_CONDITIONAL(HAVE_SYMBIAN, test "${SYS}" = "symbian")
 277
 278 dnl
 279 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 280 dnl for program foo on win32
 281 case "${build_os}" in
 282     cygwin|msys)
 283         ac_executable_extensions=".exe"
 284     ;;
 285     *)
 286     ;;
 287 esac
 288
 289 dnl Android is linux, but a bit different
 290 AS_IF([test "$SYS" = linux],[
 291     AC_MSG_CHECKING([for an Android system])
 292     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 293         [[#ifndef __ANDROID__
 294          # error Not Android
 295          #endif
 296         ]],[[;]])
 297     ],[
 298       HAVE_ANDROID="1"
 299       AC_MSG_RESULT([yes])
 300     ],[
 301       AC_MSG_RESULT([no])
 302     ])
 303 ])
 304 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 305
 306
 307 dnl
 308 dnl  Check for the contrib directory
 309 dnl
 310 AC_ARG_WITH(contrib,
 311   [AS_HELP_STRING([--with-contrib[=DIR]],
 312     [search for 3rd party libraries in DIR/include and DIR/lib])
 313 ])
 314 AC_MSG_CHECKING([for 3rd party libraries path])
 315 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 316   CONTRIB_DIR="${srcdir}/contrib/${host}"
 317   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 318     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 319     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 320     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 321       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 322       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
 323       AS_IF([test ! -d "${CONTRIB_DIR}"], [
 324         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 325         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
 326         AS_IF([test ! -d "${CONTRIB_DIR}"], [
 327           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 328           CONTRIB_DIR=""
 329           AC_MSG_RESULT([not found])
 330         ])
 331       ])
 332     ])
 333   ])
 334 ], [
 335   AS_IF([test "${with_contrib}" != "no"], [
 336     CONTRIB_DIR="${with_contrib}"
 337   ], [
 338     CONTRIB_DIR=""
 339     AC_MSG_RESULT([disabled])
 340   ])
 341 ])
 342 AS_IF([test -n "${CONTRIB_DIR}"], [
 343   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 344     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 345   ], [
 346     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 347     CONTRIB_DIR=""
 348     AC_MSG_RESULT([not usable])
 349   ])
 350
 351 ])
 352 AS_IF([test -n "${CONTRIB_DIR}"], [
 353   AC_MSG_RESULT([${CONTRIB_DIR}])
 354   export PATH=${CONTRIB_DIR}/bin:$PATH
 355   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 356   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 357   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 358   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
 359   AS_IF([test "$build" = "$host" -o "$PKG_CONFIG_LIBDIR"], [
 360     export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 361   ], [
 362     export PKG_CONFIG_LIBDIR="${CONTRIB_DIR}/lib/pkgconfig"
 363   ])
 364   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 365
 366   AS_IF([test "${SYS}" = "darwin"], [
 367     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 368     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 369   ])
 370 ], [
 371   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 372     AC_MSG_ERROR([Third party libraries not found!])
 373   ])
 374 ])
 375 AC_SUBST(CONTRIB_DIR)
 376
 377 dnl
 378 dnl  Libtool
 379 dnl  It's very bad, but our former custom system was worst
 380 dnl  -- Courmisch
 381 dnl
 382
 383 dnl override platform specific check for dependent libraries
 384 dnl otherwise libtool linking of shared libraries will
 385 dnl fail on anything other than pass_all.
 386 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 387     [lt_cv_deplibs_check_method=pass_all])
 388
 389 LT_INIT([dlopen win32-dll shared disable-static])
 390 LT_LANG([C++])
 391 LT_LANG([Windows Resource])
 392
 393 DOLT
 394
 395 m4_undefine([AC_DEPLIBS_CHECK_METHOD])
 396 m4_defun([AC_DEPLIBS_CHECK_METHOD],[])
 397
 398 lt_cv_deplibs_check_method=pass_all
 399
 400 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 401   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 402 ])
 403
 404 dnl
 405 dnl Gettext stuff
 406 dnl
 407 AM_GNU_GETTEXT_VERSION([0.18.1])
 408 AM_GNU_GETTEXT([external], [need-ngettext])
 409
 410 dnl
 411 dnl Iconv stuff
 412 dnl
 413 AM_ICONV
 414
 415 dnl
 416 dnl checks for mingw
 417 AS_IF([test "${SYS}" = "mingw32"], [
 418 dnl Check for broken versions of mingw-runtime compatability library
 419     AC_MSG_CHECKING(for broken mingw-runtime)
 420     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 421 #include <_mingw.h>
 422 #if defined(__MINGW64_VERSION_MAJOR)
 423 # if __MINGW64_VERSION_MAJOR < 3
 424 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
 425 # endif
 426 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 427 # error Attempting to use mingw-runtime with broken vsnprintf support
 428 #endif
 429     ])], [
 430         AC_MSG_RESULT([ok])
 431     ], [
 432         AC_MSG_RESULT([present])
 433         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 434     ])
 435     dnl force use of mingw provided c99 *printf over msvcrt
 436     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 437
 438 dnl Check for the need to include the mingwex lib for mingw32
 439     AC_CHECK_LIB(mingwex,opendir,
 440         AC_CHECK_LIB(mingw32,opendir,,
 441             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 442     )
 443
 444 dnl Check for fnative-struct or mms-bitfields support for mingw32
 445     VLC_SAVE_FLAGS
 446     CFLAGS="${CFLAGS} -mms-bitfields"
 447     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 448     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 449         [ac_cv_c_mms_bitfields],
 450         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 451     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 452         VLC_RESTORE_FLAGS
 453         CFLAGS="${CFLAGS} -fnative-struct"
 454         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 455         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 456             [ac_cv_c_fnative_struct],
 457             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 458         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 459     fi
 460 ])
 461
 462 dnl
 463 dnl Buggy glibc prevention. Purposedly not cached.
 464 dnl See sourceware.org bugs 5058 and 5443.
 465 dnl Ubuntu alone has 20 bug numbers for this...
 466 dnl
 467 AC_MSG_CHECKING(for buggy GNU/libc versions)
 468 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 469 #include <limits.h>
 470 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 471   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 472 # error GNU/libc with dcgettext killer bug!
 473 #endif
 474 ])], [
 475   AC_MSG_RESULT([not present])
 476 ], [
 477   AC_MSG_RESULT([found])
 478   AS_IF([test "x${enable_nls}" != "xno"], [
 479     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 480 work-around for this. Check with your distribution vendor on how to update the
 481 glibc run-time. Alternatively, build with --disable-nls.])
 482   ])
 483 ])
 484
 485 dnl Plugin compilation stuff
 486
 487 VLC_LIBRARY_SUFFIX
 488
 489 dnl Check for system libs needed
 490 need_libc=false
 491
 492 dnl Check for usual libc functions
 493 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
 494 AC_CHECK_FUNCS([daemon fcntl fstatvfs fork getenv getpwuid_r isatty lstat memalign mmap openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale])
 495 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir flockfile fsync getdelim getpid gmtime_r inet_pton lldiv localtime_r nrand48 poll posix_memalign rewind setenv strcasecmp strcasestr strdup strlcpy strncasecmp strndup strnlen strsep strtof strtok_r strtoll swab tdestroy strverscmp])
 496 AC_CHECK_FUNCS(fdatasync,,
 497   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 498 ])
 499
 500 dnl mingw64 implements those as static inline, not functions with C linkage
 501 AC_LINK_IFELSE([
 502     AC_LANG_PROGRAM([#include <stdio.h>], [
 503         char *c;
 504         if (asprintf(&c, "%s %d", "string", 1) == -1)
 505             c = NULL;
 506     ])],[AC_DEFINE([HAVE_ASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([asprintf])])
 507 AC_LINK_IFELSE([
 508     AC_LANG_PROGRAM([#include <stdio.h>
 509                      #include <stdarg.h>], [
 510         char *c;
 511         va_list ap;
 512         if (vasprintf(&c, "%s %d", ap) == -1)
 513             c = NULL;
 514     ])],[AC_DEFINE([HAVE_VASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([vasprintf])])
 515
 516 dnl C11 static_assert()
 517 AC_MSG_CHECKING([for static_assert in assert.h])
 518 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 519 static_assert(1, "The impossible happened.");
 520 ])], [
 521   AC_MSG_RESULT([yes])
 522   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 523 ], [
 524   AC_MSG_RESULT([no])
 525 ])
 526
 527 # Windows CE does not have strcoll()
 528 AC_FUNC_STRCOLL
 529
 530 dnl Check for non-standard system calls
 531 case "$SYS" in
 532   "linux")
 533     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
 534     ;;
 535   "mingw32")
 536     AC_CHECK_FUNCS([_lock_file])
 537     ;;
 538 esac
 539
 540 AH_BOTTOM([#include <vlc_fixups.h>])
 541
 542 dnl Check for struct pollfd
 543 AC_CHECK_TYPES([struct pollfd],,,
 544 [#include <sys/types.h>
 545 #if HAVE_POLL
 546 # include <poll.h>
 547 #elif defined (WIN32)
 548 # include <winsock2.h>
 549 #endif
 550 ])
 551
 552 dnl Checks for socket stuff
 553 VLC_SAVE_FLAGS
 554 SOCKET_LIBS=""
 555 AC_SEARCH_LIBS(connect, [socket], [
 556   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 557     SOCKET_LIBS="$ac_cv_search_connect"
 558   ])
 559 ], [
 560   AS_IF([test "${SYS}" = "mingw32"], [
 561     SOCKET_LIBS="-lws2_32"
 562   ])
 563 ])
 564
 565 AC_SEARCH_LIBS([getaddrinfo], [nsl], [
 566  AS_IF([test "$ac_cv_search_getaddrinfo" != "none required"], [
 567     SOCKET_LIBS="$ac_cv_search_getaddrinfo $SOCKET_LIBS"
 568   ])
 569 ],, [${SOCKET_LIBS}])
 570
 571 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 572 VLC_RESTORE_FLAGS
 573
 574 AS_IF([test -n "$SOCKET_LIBS"], [
 575   VLC_ADD_LIBS([access_http access_udp access_tcp access_ftp access_rtmp access_output_udp access_output_shout sap stream_out_standard stream_out_rtp stream_out_raop vod_rtsp rtp oldrc netsync gnutls flac ts audioscrobbler lua remoteosd zvbi audiobargraph_a],[${SOCKET_LIBS}])
 576 ])
 577 AC_SUBST(SOCKET_LIBS)
 578
 579 dnl Check for socklen_t
 580 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 581 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 582 ac_cv_type_socklen_t,
 583 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 584 [#include <sys/types.h>
 585 #ifdef WIN32
 586 # include <winsock2.h>
 587 # include <ws2tcpip.h>
 588 #else
 589 # include <sys/socket.h>
 590 #endif]], [[socklen_t len; len = 0;]])],
 591 ac_cv_type_socklen_t=yes,
 592 ac_cv_type_socklen_t=no)])
 593 AS_IF([test "$ac_cv_type_socklen_t" = no],
 594  [AC_DEFINE(socklen_t, int)])
 595
 596 dnl Check for struct sockaddr_storage
 597 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 598 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 599 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 600   [AC_TRY_COMPILE(
 601     [#include <sys/types.h>
 602      #if defined( WIN32 )
 603      # include <winsock2.h>
 604      #else
 605      # include <sys/socket.h>
 606      #endif], [struct sockaddr_storage addr;],
 607      ac_cv_struct_sockaddr_storage=yes,
 608      ac_cv_struct_sockaddr_storage=no)])
 609 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 610   AC_DEFINE(sockaddr_storage, sockaddr)
 611   AC_DEFINE(ss_family, sa_family)
 612 ])
 613
 614 dnl FreeBSD has a gnugetopt library for this:
 615 GNUGETOPT_LIBS=""
 616 AC_CHECK_FUNC(getopt_long,, [
 617   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 618     GNUGETOPT_LIBS="-lgnugetopt"
 619   ])
 620 ])
 621 AC_SUBST(GNUGETOPT_LIBS)
 622
 623 AC_CHECK_LIB(m,cos,[
 624   VLC_ADD_LIBS([adjust wave ripple psychedelic gradient a52tofloat32 dtstofloat32 x264 goom panoramix rotate noise grain scene kate flac lua chorus_flanger freetype avcodec access_avio swscale postproc i420_rgb faad twolame equalizer spatializer param_eq samplerate freetype mpc dmo quicktime qt4 compressor headphone_channel_mixer normvol audiobargraph_a speex opus mono colorthres extract ball access_imem hotkeys mosaic gaussianblur x26410b hqdn3d anaglyph oldrc ncurses],[-lm])
 625   LIBM="-lm"
 626 ], [
 627   LIBM=""
 628 ])
 629 AC_SUBST(LIBM)
 630
 631 AC_CHECK_LIB(m,lrintf, [
 632   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 633   VLC_ADD_LIBS([skins2],[-lm])
 634 ])
 635
 636 dnl Check for dynamic plugins
 637 LIBDL=""
 638 have_dynamic_objects="no"
 639 VLC_SAVE_FLAGS
 640 AC_SEARCH_LIBS(dlopen, [dl svld], [
 641   AS_IF([test "$ac_cv_search_dlopen" != "none required"], [
 642     LIBDL="$ac_cv_search_dlopen"
 643   ])
 644   have_dynamic_objects="yes"
 645 ])
 646 VLC_RESTORE_FLAGS
 647
 648 # Windows
 649 AS_IF([test "${SYS}" = "mingw32"], [
 650   LIBDL=""
 651   have_dynamic_objects="yes" #assume we can use shared objects
 652 ])
 653
 654 AS_IF([test "${enable_shared}" = "no"], [
 655   have_dynamic_objects=no
 656 ])
 657 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 658
 659 AC_SUBST(LIBDL)
 660 VLC_ADD_LIBS([lua],[$LIBDL])
 661
 662 dnl Check for thread library
 663 LIBPTHREAD=""
 664 AS_IF([test "${SYS}" != "mingw32"], [
 665   VLC_SAVE_FLAGS
 666   LIBS=""
 667   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 668     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 669       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 670     ])
 671   ])
 672   VLC_RESTORE_FLAGS
 673
 674   AC_CHECK_LIB(rt, clock_nanosleep, [
 675     VLC_ADD_LIBS([libvlccore],[-lrt])
 676   ], [
 677     AC_CHECK_FUNC(nanosleep,,[
 678       AC_CHECK_LIB(rt,nanosleep, [
 679         VLC_ADD_LIBS([libvlccore],[-lrt])
 680       ], [
 681         AC_CHECK_LIB(posix4,nanosleep, [
 682           VLC_ADD_LIBS([libvlccore],[-lposix4])
 683         ])
 684       ])
 685     ])
 686     dnl HP/UX port
 687     AC_CHECK_LIB(rt,sem_init, [VLC_ADD_LIBS([libvlccore],[-lrt])])
 688   ])
 689 ])
 690 AC_SUBST(LIBPTHREAD)
 691
 692 dnl Check for headers
 693 AC_CHECK_HEADERS([search.h])
 694 AC_CHECK_HEADERS(getopt.h locale.h xlocale.h)
 695 AC_CHECK_HEADERS([sys/time.h sys/ioctl.h])
 696 AC_CHECK_HEADERS([arpa/inet.h netinet/udplite.h sys/eventfd.h])
 697 AC_CHECK_HEADERS([net/if.h], [], [],
 698   [
 699     #include <sys/types.h>
 700     #include <sys/socket.h>
 701   ])
 702 AC_CHECK_HEADERS([sys/mount.h], [], [],
 703   [
 704     #include <sys/param.h>
 705   ])
 706
 707 if test "${SYS}" != "mingw32"; then
 708   AC_CHECK_HEADERS(machine/param.h sys/shm.h)
 709   AC_CHECK_HEADERS([linux/version.h linux/dccp.h scsi/scsi.h linux/magic.h])
 710   AC_CHECK_HEADERS(syslog.h mntent.h)
 711 fi # end "${SYS}" != "mingw32"
 712
 713 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 714 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 715 AC_CHECK_TYPE(ssize_t,, [
 716   AC_DEFINE(ssize_t, int)
 717 ])
 718
 719 dnl Check for threads library
 720 if test "${SYS}" != "mingw32"; then
 721   AC_CHECK_HEADERS(pthread.h)
 722 fi # end "${SYS}" != "mingw32"
 723
 724 dnl It seems that autoconf detects pkg-config only during the first
 725 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 726 dnl it is nested within a conditional block, so it was not working right.
 727 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 728 AC_ARG_VAR(PKG_CONFIG_PATH,
 729        [Paths where to find .pc not at the default location])
 730 PKG_PROG_PKG_CONFIG()
 731
 732 dnl On some OS we need static linking
 733 AS_IF([test -n "${PKG_CONFIG}" ],[
 734     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 735         PKG_CONFIG="${PKG_CONFIG} --static"
 736     ])
 737 ])
 738
 739
 740 dnl
 741 dnl Check for zlib.h and -lz along with system -lminizip if available
 742 dnl
 743 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 744 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 745 if test "${have_zlib}" = "yes"
 746 then
 747   VLC_ADD_LIBS([access_http skins2 sap unzip zip],[-lz])
 748   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 749     AC_CHECK_HEADERS([unzip.h], [
 750       have_minizip=yes
 751       MINIZIP_LIBS="-lminizip -lz"
 752     ], [
 753       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
 754       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/access/libunzip.la])
 755       have_minizip=no
 756     ])
 757   ])
 758   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
 759   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
 760 fi
 761 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 762
 763
 764 dnl
 765 dnl Domain name i18n support via GNU libidn
 766 dnl
 767 PKG_CHECK_MODULES([IDN], [libidn], [
 768   have_libidn="yes"
 769   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 770 ], [
 771   have_libidn="no"
 772 ])
 773
 774
 775 dnl Check for dbus
 776 AC_ARG_ENABLE(dbus,
 777   [AS_HELP_STRING([--enable-dbus],
 778     [compile D-Bus message bus support (default enabled)])])
 779 have_dbus="no"
 780 AS_IF([test "${enable_dbus}" != "no"], [
 781   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.0.0], [
 782     have_dbus="yes"
 783   ], [
 784     AS_IF([test -n "${enable_dbus}"], [
 785       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 786     ], [
 787       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 788     ])
 789   ])
 790 ])
 791 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 792
 793 dnl Check for ntohl, etc.
 794 VLC_SAVE_FLAGS
 795 CFLAGS="${CFLAGS} -Wall -Werror"
 796 AC_CACHE_CHECK([for ntohl in sys/param.h],
 797     [ac_cv_c_ntohl_sys_param_h],
 798     [     AC_TRY_COMPILE([#include <sys/param.h>],
 799         [int meuh; ntohl(meuh);],
 800         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 801 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 802     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 803 fi
 804 VLC_RESTORE_FLAGS
 805
 806 EXTEND_HELP_STRING([Optimization options:])
 807 dnl
 808 dnl  Compiler warnings
 809 dnl
 810
 811 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration])
 812 RDC_PROG_CC_FLAGS([-pipe])
 813 AC_LANG_PUSH([C++])
 814 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var])
 815 AC_LANG_POP([C++])
 816
 817 dnl
 818 dnl  Debugging mode
 819 dnl
 820 AC_ARG_ENABLE(debug,
 821   [AS_HELP_STRING([--enable-debug],
 822     [build with run-time assertions (default disabled)])],,
 823   [enable_debug="no"])
 824 AH_TEMPLATE(NDEBUG,
 825             [Define to 1 if debug code should NOT be compiled])
 826 AS_IF([test "${enable_debug}" != "no"], [
 827   AC_CHECK_HEADERS([valgrind/valgrind.h])
 828 ], [
 829   AC_DEFINE(NDEBUG)
 830 ])
 831
 832 dnl
 833 dnl  Profiling
 834 dnl
 835 AC_ARG_ENABLE(gprof,
 836   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 837   [enable_gprof="no"])
 838 AS_IF([test "${enable_gprof}" != "no"], [
 839   CFLAGS="${CFLAGS} -pg"
 840   CXXFLAGS="${CXXFLAGS} -pg"
 841   OBJCFLAGS="${OBJCFLAGS} -pg"
 842   LDFLAGS="${LDFLAGS} -pg"
 843 ])
 844
 845 AC_ARG_ENABLE(cprof,
 846   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 847   [enable_cprof="no"])
 848 AS_IF([test "${enable_gprof}" != "no"], [
 849   CFLAGS="${CFLAGS} -finstrument-functions"
 850   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 851   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 852   LDFLAGS="${LDFLAGS} -finstrument-functions"
 853 ])
 854
 855 dnl
 856 dnl  Test coverage
 857 dnl
 858 AC_ARG_ENABLE(coverage,
 859   [AS_HELP_STRING([--enable-coverage],
 860     [build for test coverage (default disabled)])],,
 861   [enable_coverage="no"])
 862 AS_IF([test "${enable_coverage}" != "no"], [
 863   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 864   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 865   LDFLAGS="-lgcov ${LDFLAGS}"
 866 ])
 867
 868 AS_IF([test "${SYS}" != "mingw32"], [
 869   VLC_SAVE_FLAGS
 870   CFLAGS="${CFLAGS} -fvisibility=hidden"
 871   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 872   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 873   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 874                  [ac_cv_c_visibility_hidden], [
 875     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 876       ac_cv_c_visibility_hidden=yes
 877     ], [
 878       ac_cv_c_visibility_hidden=no
 879     ])
 880   ])
 881   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
 882 ])
 883
 884
 885 dnl
 886 dnl  Enable/disable optimizations
 887 dnl
 888 AC_ARG_ENABLE(optimizations,
 889   [AS_HELP_STRING([--disable-optimizations],
 890     [disable compiler optimizations (default enabled)])],,
 891   [enable_optimizations="yes"])
 892
 893 dnl Check for various optimization flags
 894 AS_IF([test "${enable_optimizations}" != "no"], [
 895
 896   dnl -O4 and -O3 only in production builds
 897   AS_IF([test "{enable_debug}" = "no"], [
 898     VLC_SAVE_FLAGS
 899     CFLAGS="${CFLAGS} -O4"
 900     CXXFLAGS="${CXXFLAGS} -O4"
 901     OBJCFLAGS="${OBJCFLAGS} -O4"
 902     AC_CACHE_CHECK([if $CC accepts -O4], [ac_cv_c_o4], [
 903       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 904         ac_cv_c_o4=yes
 905       ], [
 906         ac_cv_c_o4=no
 907       ])
 908     ])
 909     AS_IF([test "${ac_cv_c_o4}" = "no"], [
 910       VLC_RESTORE_FLAGS
 911       CFLAGS="${CFLAGS} -O3"
 912       CXXFLAGS="${CXXFLAGS} -O3"
 913       OBJCFLAGS="${OBJCFLAGS} -O3"
 914       AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
 915         AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 916           ac_cv_c_o3=yes
 917         ], [
 918           ac_cv_c_o3=no
 919         ])
 920       ])
 921       AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
 922     ])
 923   ])
 924
 925   dnl Check for -ffast-math
 926   VLC_SAVE_FLAGS
 927   CFLAGS="${CFLAGS} -ffast-math"
 928   CXXFLAGS="${CXXFLAGS} -ffast-math"
 929   OBJCFLAGS="${OBJCFLAGS} -ffast-math"
 930   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
 931     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 932       ac_cv_c_fast_math=yes
 933     ], [
 934       ac_cv_c_fast_math=no
 935     ])
 936   ])
 937   AS_IF([test "${ac_cv_c_fast_math}" = "no"], [VLC_RESTORE_FLAGS])
 938   AH_BOTTOM([
 939 #ifndef __FAST_MATH__
 940 # pragma STDC FENV_ACCESS OFF
 941 # pragma STDC FP_CONTRACT ON
 942 #endif
 943 ])
 944
 945   dnl Check for -funroll-loops
 946   VLC_SAVE_FLAGS
 947   CFLAGS="${CFLAGS} -funroll-loops"
 948   CXXFLAGS="${CXXFLAGS} -funroll-loops"
 949   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
 950   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
 951     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 952       ac_cv_c_unroll_loops=yes
 953     ], [
 954       ac_cv_c_unroll_loops=no
 955     ])
 956   ])
 957   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
 958
 959   AS_IF([test "$enable_debug" = "no"], [
 960     dnl Check for -fomit-frame-pointer
 961     VLC_SAVE_FLAGS
 962     CFLAGS="${CFLAGS} -fomit-frame-pointer"
 963     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
 964     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
 965     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
 966       [ac_cv_c_omit_frame_pointer], [
 967       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 968         ac_cv_c_omit_frame_pointer=yes
 969       ], [
 970         ac_cv_c_omit_frame_pointer=no
 971       ])
 972     ])
 973     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
 974   ])
 975 ])
 976
 977 dnl Check for Darwin plugin linking flags
 978 AS_IF([test "${SYS}" = "darwin"], [
 979   VLC_SAVE_FLAGS
 980   CFLAGS="${CFLAGS} -bundle -undefined error"
 981   AC_CACHE_CHECK([if $CC accepts -bundle -undefined error],
 982     [ac_cv_ld_darwin], [
 983     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 984       ac_cv_ld_darwin=yes
 985     ], [
 986       ac_cv_ld_darwin=no
 987     ])
 988   ])
 989   AS_IF([test "${ac_cv_ld_darwin}" != "no"], [
 990     VLC_ADD_LDFLAGS([plugin],[-bundle -undefined error])
 991   ])
 992   VLC_RESTORE_FLAGS
 993 ])
 994
 995 dnl Checks for __attribute__(aligned()) directive
 996 VLC_SAVE_FLAGS
 997 CFLAGS="${CFLAGS} -Werror"
 998 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
 999     [ac_cv_c_attribute_aligned],
1000     [ac_cv_c_attribute_aligned=0
1001     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1002         AC_TRY_COMPILE([],
1003         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1004         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1005     done])
1006 VLC_RESTORE_FLAGS
1007 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1008     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1009         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1010 fi
1011
1012 dnl Check for __attribute__((packed))
1013 AC_CACHE_CHECK([for __attribute__((packed))],
1014   [ac_cv_c_attribute_packed],
1015   [ac_cv_c_attribute_packed=no
1016    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1017                     [ac_cv_c_attribute_packed=yes])])
1018 if test "${ac_cv_c_attribute_packed}" != "no"; then
1019   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1020 fi
1021
1022 dnl
1023 dnl  Check the CPU
1024 dnl
1025 case "${host_cpu}" in
1026   "")
1027     ARCH=unknown
1028     ;;
1029   *)
1030     ARCH="${host_cpu}"
1031     ;;
1032 esac
1033
1034 dnl Check for backtrace() support
1035 AC_CHECK_HEADERS(execinfo.h)
1036 AC_CHECK_FUNCS(backtrace)
1037
1038 dnl
1039 dnl  default modules
1040 dnl
1041 ALIASES="${ALIASES} cvlc rvlc"
1042
1043 dnl
1044 dnl  Accelerated modules
1045 dnl
1046
1047 dnl  Check for fully working MMX intrinsics
1048 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1049 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1050 AC_ARG_ENABLE(mmx,
1051   [AS_HELP_STRING([--disable-mmx],
1052     [disable MMX optimizations (default auto)])],,[
1053   case "${host_cpu}" in
1054     i?86|x86_64)
1055       enable_mmx="yes"
1056       ;;
1057     *)
1058       enable_mmx="no"
1059       ;;
1060   esac
1061 ])
1062 have_mmx="no"
1063 have_mmxext="no"
1064 AS_IF([test "${enable_mmx}" != "no"], [
1065   ARCH="${ARCH} mmx"
1066   VLC_SAVE_FLAGS
1067   CFLAGS="${CFLAGS} -mmmx"
1068   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1069     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1070 [#include <mmintrin.h>
1071 #include <stdint.h>
1072 uint64_t frobzor;]], [
1073 [__m64 a, b, c;
1074 a = b = c = (__m64)frobzor;
1075 a = _mm_slli_pi16(a, 3);
1076 a = _mm_adds_pi16(a, b);
1077 c = _mm_srli_pi16(c, 8);
1078 c = _mm_slli_pi16(c, 3);
1079 b = _mm_adds_pi16(b, c);
1080 a = _mm_unpacklo_pi8(a, b);
1081 frobzor = (uint64_t)a;]])], [
1082       ac_cv_c_mmx_intrinsics=yes
1083     ], [
1084       ac_cv_c_mmx_intrinsics=no
1085     ])
1086   ])
1087   VLC_RESTORE_FLAGS
1088   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1089     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1090   ])
1091
1092   VLC_SAVE_FLAGS
1093   CFLAGS="${CFLAGS} -mmmx"
1094   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1095     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1096 void *p;
1097 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1098 ]])
1099     ], [
1100       ac_cv_mmx_inline=yes
1101     ], [
1102       ac_cv_mmx_inline=no
1103     ])
1104   ])
1105   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1106     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1107     have_mmx="yes"
1108   ])
1109
1110   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1111                  [ac_cv_mmxext_inline], [
1112     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1113 void *p;
1114 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1115 ]])
1116     ], [
1117       ac_cv_mmxext_inline=yes
1118     ], [
1119       ac_cv_mmxext_inline=no
1120     ])
1121   ])
1122   VLC_RESTORE_FLAGS
1123   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1124     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1125     have_mmxext="yes"
1126   ])
1127 ])
1128 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1129 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1130
1131 dnl  Check for fully workin SSE2 intrinsics
1132 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1133 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1134 AC_ARG_ENABLE(sse,
1135   [AS_HELP_STRING([--disable-sse],
1136     [disable SSE (1-4) optimizations (default auto)])],, [
1137   case "${host_cpu}" in
1138     i?86|x86_64)
1139       enable_sse=yes
1140       ;;
1141     *)
1142       enable_sse=no
1143       ;;
1144   esac
1145 ])
1146 have_sse2="no"
1147 AS_IF([test "${enable_sse}" != "no"], [
1148   ARCH="${ARCH} sse sse2"
1149
1150   VLC_SAVE_FLAGS
1151   CFLAGS="${CFLAGS} -msse2"
1152   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1153     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1154 [#include <emmintrin.h>
1155 #include <stdint.h>
1156 uint64_t frobzor;]], [
1157 [__m128i a, b, c;
1158 a = b = c = _mm_set1_epi64((__m64)frobzor);
1159 a = _mm_slli_epi16(a, 3);
1160 a = _mm_adds_epi16(a, b);
1161 c = _mm_srli_epi16(c, 8);
1162 c = _mm_slli_epi16(c, 3);
1163 b = _mm_adds_epi16(b, c);
1164 a = _mm_unpacklo_epi8(a, b);
1165 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1166       ac_cv_c_sse2_intrinsics=yes
1167     ], [
1168       ac_cv_c_sse2_intrinsics=no
1169     ])
1170   ])
1171   VLC_RESTORE_FLAGS
1172   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1173     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1174   ])
1175
1176   VLC_SAVE_FLAGS
1177   CFLAGS="${CFLAGS} -msse"
1178   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1179     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1180 void *p;
1181 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1182 ]])
1183     ], [
1184       ac_cv_sse_inline=yes
1185     ], [
1186       ac_cv_sse_inline=no
1187     ])
1188   ])
1189
1190   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1191     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1192   ])
1193
1194   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1195     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1196 void *p;
1197 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1198 ]])
1199     ], [
1200       ac_cv_sse2_inline=yes
1201     ], [
1202       ac_cv_sse2_inline=no
1203     ])
1204   ])
1205   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1206     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1207     have_sse2="yes"
1208   ])
1209
1210   # SSE3
1211   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1212     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1213 void *p;
1214 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1215 ]])
1216     ], [
1217       ac_cv_sse3_inline=yes
1218     ], [
1219       ac_cv_sse3_inline=no
1220     ])
1221   ])
1222
1223   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1224     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1225   # SSSE3
1226   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1227     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1228 void *p;
1229 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1230 ]])
1231     ], [
1232       ac_cv_ssse3_inline=yes
1233     ], [
1234       ac_cv_ssse3_inline=no
1235     ])
1236   ])
1237
1238   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1239     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1240
1241   # SSE4.1
1242   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1243                  [ac_cv_sse4_1_inline], [
1244     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1245 void *p;
1246 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1247 ]])
1248     ], [
1249       ac_cv_sse4_1_inline=yes
1250     ], [
1251       ac_cv_sse4_1_inline=no
1252     ])
1253   ])
1254
1255   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1256     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1257
1258   # SSE4.2
1259   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1260                  [ac_cv_sse4_2_inline], [
1261     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1262 void *p;
1263 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1264 ]])
1265     ], [
1266       ac_cv_sse4_2_inline=yes
1267     ], [
1268       ac_cv_sse4_2_inline=no
1269     ])
1270   ])
1271
1272   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1273     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1274
1275   # SSE4A
1276   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1277     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1278 void *p;
1279 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1280 ]])
1281     ], [
1282       ac_cv_sse4a_inline=yes
1283     ], [
1284       ac_cv_sse4a_inline=no
1285     ])
1286   ])
1287   VLC_RESTORE_FLAGS
1288   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1289     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1290 ])
1291 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1292
1293 VLC_SAVE_FLAGS
1294 CFLAGS="${CFLAGS} -mmmx"
1295 have_3dnow="no"
1296 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1297   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1298 void *p;
1299 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1300 ]])
1301   ], [
1302     ac_cv_3dnow_inline=yes
1303   ], [
1304     ac_cv_3dnow_inline=no
1305   ])
1306 ])
1307 VLC_RESTORE_FLAGS
1308 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1309   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1310             [Define to 1 if 3D Now! inline assembly is available.])
1311   have_3dnow="yes"
1312 ])
1313 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1314
1315
1316 AC_ARG_ENABLE(neon,
1317   [AS_HELP_STRING([--disable-neon],
1318     [disable NEON optimizations (default auto)])],, [
1319   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1320 ])
1321 AS_IF([test "${enable_neon}" != "no"], [
1322   VLC_SAVE_FLAGS
1323   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1324   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1325     AC_COMPILE_IFELSE([
1326       AC_LANG_PROGRAM(,[[
1327 asm volatile("vqmovun.s64 d0, q1":::"d0");
1328 ]])
1329     ], [
1330       ac_cv_arm_neon="yes"
1331     ], [
1332       ac_cv_arm_neon="no"
1333     ])
1334   ])
1335   VLC_RESTORE_FLAGS
1336 ])
1337 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1338
1339
1340 AC_ARG_ENABLE(altivec,
1341   [AS_HELP_STRING([--disable-altivec],
1342     [disable AltiVec optimizations (default auto)])],, [
1343   AS_IF([test "${host_cpu}" = "powerpc"],
1344         [enable_altivec=yes], [enable_altivec=no])
1345 ])
1346 have_altivec="no"
1347 AS_IF([test "${enable_altivec}" = "yes"], [
1348   ARCH="${ARCH} altivec";
1349   VLC_SAVE_FLAGS
1350   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1351     [ac_cv_altivec_inline],
1352     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1353          ac_cv_altivec_inline="yes",
1354          [CFLAGS="${CFLAGS} -Wa,-m7400"
1355           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1356             [ac_cv_altivec_inline="-Wa,-m7400"],
1357             ac_cv_altivec_inline=no)
1358          ])])
1359   VLC_RESTORE_FLAGS
1360   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1361     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1362               [Define to 1 if AltiVec inline assembly is available.])
1363     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1364       VLC_ADD_CFLAGS([memcpyaltivec],[${ac_cv_altivec_inline}])
1365       VLC_ADD_CFLAGS([i420_yuy2_altivec],[${ac_cv_altivec_inline}])
1366       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1367     ])
1368     have_altivec="yes"
1369   ])
1370
1371 dnl The AltiVec C extensions
1372 dnl
1373 dnl There are several possible cases:
1374 dnl - OS X PPC, gcc 4.x: use -mpim-altivec -force_cpusubtype_ALL, don't
1375 dnl                      need <altivec.h>
1376 dnl - OS X PPC, gcc 3.x: need -faltivec, don't need <altivec.h>
1377 dnl - Linux PPC, gcc 3.4, 4.x: need <altivec.h> which requires -maltivec
1378 dnl - Linux PPC, gcc 3.3: need <altivec.h> and -maltivec -mabi=altivec
1379 dnl - Linux PPC, gcc 3.x: need <altivec.h> and -fvec
1380 dnl - Others: test should fail
1381   VLC_SAVE_FLAGS
1382   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1383   [ac_cv_c_altivec],
1384   [# OS X/PPC test (gcc 4.x)
1385    CFLAGS="${CFLAGS} -mpim-altivec -force_cpusubtype_ALL"
1386    AC_TRY_COMPILE([vector unsigned char foo;],
1387      [vec_ld(0, (unsigned char *)0);],
1388      [ac_cv_c_altivec="-mpim-altivec -force_cpusubtype_ALL"],
1389      [# OS X/PPC test (gcc 3.x)
1390       CFLAGS="${CFLAGS} -faltivec"
1391       AC_TRY_COMPILE([vector unsigned char foo;],
1392         [vec_ld(1 * sizeof(vector float), (unsigned char *)0);],
1393         [ac_cv_c_altivec="-faltivec"],
1394         dnl Below this are the Linux tests
1395         [# Linux/PPC test (gcc 4.x)
1396          CFLAGS="${CFLAGS} -maltivec"
1397          AC_TRY_COMPILE([#include <altivec.h>],
1398            [vec_ld(0, (unsigned char *)0);],
1399            [ac_cv_c_altivec="-maltivec"],
1400            [# Linux/PPC test (gcc 3.3)
1401             CFLAGS="${CFLAGS} -maltivec -mabi=altivec"
1402             AC_TRY_COMPILE([#include <altivec.h>],
1403               [vec_ld(0, (unsigned char *)0);],
1404               [ac_cv_c_altivec=""
1405                ac_cv_c_altivec_abi="-maltivec -mabi=altivec"],
1406               [# Linux/PPC test (gcc 3.3)
1407                CFLAGS="${CFLAGS} -fvec"
1408                AC_TRY_COMPILE([#include <altivec.h>],
1409                  [vec_ld(0, (unsigned char *)0);],
1410                  [ac_cv_c_altivec="-fvec"],
1411                  [ac_cv_c_altivec=no])
1412               ])
1413            ])
1414         ])
1415      ])
1416   ])
1417
1418   VLC_RESTORE_FLAGS
1419   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1420     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1421     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1422     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1423     VLC_ADD_CFLAGS([i420_yuy2_altivec memcpyaltivec deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1424     have_altivec="yes"
1425   ])
1426   AC_CHECK_HEADERS(altivec.h)
1427
1428   VLC_SAVE_FLAGS
1429   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1430   AC_CACHE_CHECK([if linker needs -framework vecLib],
1431     [ac_cv_ld_altivec],
1432     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1433   VLC_RESTORE_FLAGS
1434   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1435     VLC_ADD_LIBS([libvlccore memcpyaltivec],[-Wl,-framework,vecLib])
1436   ])
1437 ])
1438 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1439
1440 dnl
1441 dnl  Memory usage
1442 dnl
1443 AC_ARG_ENABLE(optimize-memory,
1444   [AS_HELP_STRING([--enable-optimize-memory],
1445     [optimize memory usage over performance])])
1446 if test "${enable_optimize_memory}" = "yes"; then
1447   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1448 fi
1449
1450 dnl
1451 dnl Allow running as root (useful for people running on embedded platforms)
1452 dnl
1453 AC_ARG_ENABLE(run-as-root,
1454   [AS_HELP_STRING([--enable-run-as-root],
1455     [allow running VLC as root (default disabled)])])
1456 AS_IF([test "${enable_run_as_root}" = "yes"],[
1457     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1458               [Define to 1 to allow running VLC as root (uid 0).])
1459 ])
1460
1461 dnl
1462 dnl Stream output
1463 dnl
1464 AC_ARG_ENABLE(sout,
1465   [AS_HELP_STRING([--disable-sout],
1466     [disable streaming output (default enabled)])])
1467 AS_IF([test "${enable_sout}" != "no"], [
1468   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1469 ])
1470 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1471
1472 dnl Lua modules
1473 AC_ARG_ENABLE(lua,
1474   [AS_HELP_STRING([--disable-lua],
1475     [disable LUA scripting support (default enabled)])])
1476 if test "${enable_lua}" != "no"
1477 then
1478   PKG_CHECK_MODULES(LUA, lua5.1,
1479     [ have_lua=yes ],
1480     [
1481     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1482     PKG_CHECK_MODULES(LUA, lua >= 5.1,
1483       [ have_lua=yes ],
1484       [
1485         AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1486         have_lua=yes
1487         AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1488           [],
1489           [ have_lua=no ] )
1490         AC_CHECK_LIB(  lua5.1 , luaL_newstate,
1491           [LUA_LIBS="-llua5.1"],
1492           AC_CHECK_LIB( lua51 , luaL_newstate,
1493             [LUA_LIBS="-llua51"],
1494             AC_CHECK_LIB( lua , luaL_newstate,
1495               [LUA_LIBS="-llua"],
1496               [ have_lua=no
1497               ], [-lm])
1498           )
1499         )
1500       ])
1501     ])
1502   if test "x${have_lua}" = "xyes" ;  then
1503      VLC_ADD_LIBS([lua],[$LUA_LIBS])
1504      VLC_ADD_CFLAGS([lua],[$LUA_CFLAGS])
1505   else
1506       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1507   fi
1508   AC_ARG_VAR([LUAC], [LUA byte compiler])
1509   AC_PATH_PROGS(LUAC,[${LUAC} luac], [false])
1510   AS_IF([test "${LUAC}" = "false"], [
1511     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1512   ])
1513 fi
1514 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1515
1516
1517 dnl
1518 dnl HTTP daemon
1519 dnl
1520 AC_ARG_ENABLE(httpd,
1521   [AS_HELP_STRING([--disable-httpd],
1522     [disable the built-in HTTP server (default enabled)])])
1523 if test "${enable_httpd}" != "no"
1524 then
1525   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1526 fi
1527 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1528
1529
1530 dnl
1531 dnl VideoLAN manager
1532 dnl
1533 AC_ARG_ENABLE(vlm,
1534   [AS_HELP_STRING([--disable-vlm],
1535     [disable the stream manager (default enabled)])],,
1536   [enable_vlm="${enable_sout}"])
1537 AS_IF([test "${enable_vlm}" != "no"], [
1538   AS_IF([test "${enable_sout}" = "no"], [
1539     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1540   ])
1541   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1542 ])
1543 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1544
1545
1546 dnl
1547 dnl  Input plugins
1548 dnl
1549
1550 EXTEND_HELP_STRING([Input plugins:])
1551
1552 dnl
1553 dnl libproxy support
1554 dnl
1555 AC_ARG_ENABLE(libproxy,
1556   [AS_HELP_STRING([--enable-libproxy],[support libproxy (default auto)])])
1557 AS_IF([test "${enable_libproxy}" != "no"], [
1558   PKG_CHECK_MODULES(LIBPROXY, libproxy-1.0, [
1559     AC_DEFINE(HAVE_LIBPROXY, 1, [Define if libproxy is available])
1560     VLC_ADD_CFLAGS([access_http],[$LIBPROXY_CFLAGS])
1561     VLC_ADD_LIBS([access_http],[$LIBPROXY_LIBS])
1562   ], [
1563     AS_IF([test -n "${enable_libproxy}"], [
1564       AC_MSG_ERROR([${LIBPROXY_PKG_ERRORS}.])
1565     ])
1566   ])
1567 ])
1568
1569 dnl
1570 dnl  live555 input
1571 dnl
1572 AC_ARG_ENABLE(live555,
1573   [AS_HELP_STRING([--enable-live555],
1574     [enable RTSP input through live555 (default enabled)])])
1575
1576 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1577   AC_LANG_PUSH(C++)
1578   VLC_SAVE_FLAGS
1579
1580   dnl detect include paths
1581   AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1582     CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1583   ], [
1584     AS_IF([test ${SYS} != "os2"], [
1585       LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1586       CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1587     ], [
1588       LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1589       CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1590       LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1591     ])
1592   ])
1593
1594   dnl CPP Flags
1595   AS_IF([test "${SYS}" = "solaris"], [
1596     CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1597   ])
1598   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1599   LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1600
1601   dnl version check
1602   AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1603     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1604 [#include <liveMedia_version.hh>
1605 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1606 # error BOOM
1607 #endif]])
1608     ], [
1609       ac_cv_live555="yes"
1610     ], [
1611       ac_cv_live555="no"
1612     ])
1613   ])
1614
1615   AS_IF([test "$ac_cv_live555" = "no"], [
1616     AC_MSG_WARN([liveMedia is missing or its installed version is too old:
1617 Version 2011.12.23 or later is required to proceed.
1618 You can get an updated one from http://www.live555.com/liveMedia .])
1619     AS_IF([test -n "${enable_live555}"], [
1620       AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1621     ])
1622   ], [
1623     other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1624     other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1625     AS_IF([test "${SYS}" = "mingw32"], [
1626       # add ws2_32 for closesocket, select, recv
1627       other_libs="$other_libs -lws2_32"
1628     ])
1629
1630     dnl We need to check for pic because live555 don't provide shared libs
1631     dnl and we want to build a plugins so we need -fPIC on some arch.
1632     VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1633     VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1634     AC_CHECK_LIB(liveMedia_pic, main, [
1635       VLC_ADD_PLUGIN([live555])
1636       VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1637     ],[
1638       AC_CHECK_LIB(liveMedia, main, [
1639         VLC_ADD_PLUGIN([live555])
1640         VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1641       ],[],[${other_libs}])],[${other_libs_pic}])
1642   ])
1643   VLC_RESTORE_FLAGS
1644   AC_LANG_POP(C++)
1645 ])
1646
1647 dnl
1648 dnl IIDC and DV FireWire input modules
1649 dnl
1650 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1651 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1652
1653 dnl
1654 dnl - linsys modules: access module check for libzvbi
1655 dnl
1656 AC_ARG_ENABLE(linsys,
1657   [AS_HELP_STRING([--enable-linsys],
1658     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1659 if test "$SYS" = "linux" -a "${enable_linsys}" != "no"; then
1660   VLC_ADD_PLUGIN([linsys_hdsdi])
1661   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28],
1662     [ VLC_ADD_LIBS([linsys_sdi],[$LINSYS_SDI_LIBS])
1663       VLC_ADD_CFLAGS([linsys_sdi],[$LINSYS_SDI_CFLAGS])
1664       VLC_ADD_PLUGIN([linsys_sdi]) ],
1665     [AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])]
1666   )
1667 fi
1668
1669 dnl
1670 dnl dvdread module: check for libdvdread
1671 dnl
1672 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread], [dvdread input module], [auto])
1673
1674 dnl
1675 dnl libdvdnav plugin
1676 dnl
1677 AC_ARG_ENABLE(dvdnav,
1678   [AS_HELP_STRING([--disable-dvdnav],
1679     [disable DVD navigation with libdvdnav (default auto)])])
1680 if test "${enable_dvdnav}" != "no"
1681 then
1682   PKG_CHECK_MODULES(DVDNAV, dvdnav, [
1683     VLC_ADD_PLUGIN([dvdnav])
1684     VLC_ADD_CFLAGS([dvdnav],[${DVDNAV_CFLAGS}])
1685     VLC_ADD_LIBS([dvdnav],[${DVDNAV_LIBS}])
1686     AC_CHECK_LIB(dvdnav, dvdnav_get_video_resolution,
1687       AC_DEFINE(HAVE_DVDNAV_GET_VIDEO_RESOLUTION, 1, [Define if you have dvdnav_get_video_resolution.]),
1688         [], [${LIBS_dvdnav}])
1689     AC_CHECK_LIB(dvdnav, dvdnav_describe_title_chapters,
1690       AC_DEFINE(HAVE_DVDNAV_DESCRIBE_TITLE_CHAPTERS, 1, [Define if you have dvdnav_describe_title_chapters.]),
1691         [], [${LIBS_dvdnav}])],
1692       [AC_MSG_WARN([${DVDNAV_PKG_ERRORS}.])])
1693 fi
1694
1695 dnl
1696 dnl  Blu-ray Disc Support with libbluray
1697 dnl
1698 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.2.1], (libbluray for Blu-ray disc support ) )
1699
1700 dnl
1701 dnl  OpenCV wrapper and example filters
1702 dnl
1703 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1704
1705
1706 dnl
1707 dnl  libsmbclient plugin
1708 dnl
1709 AC_ARG_ENABLE(smb,
1710   [AS_HELP_STRING([--disable-smb], [disable SMB/CIFS support (default auto)])])
1711 if test "${enable_smb}" != "no"; then
1712   AC_CHECK_HEADERS(libsmbclient.h,
1713     [ VLC_ADD_PLUGIN([access_smb])
1714       VLC_ADD_LIBS([access_smb],[-lsmbclient]) ],
1715     [ if test -n "${enable_smb}"; then
1716         AC_MSG_ERROR([cannot find libsmbclient headers])
1717      fi ])
1718 fi
1719
1720
1721 dnl
1722 dnl sftp access support
1723 dnl
1724 PKG_ENABLE_MODULES_VLC([SFTP], [access_sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1725
1726 dnl
1727 dnl  Video4Linux 2
1728 dnl
1729 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1730   [disable Video4Linux version 2 (default auto)])])
1731 have_v4l2="no"
1732 AS_IF([test "$enable_v4l2" != "no"], [
1733   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1734     have_v4l2="yes"
1735   ])
1736 ])
1737 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1738
1739 dnl
1740 dnl special access module for Blackmagic SDI cards
1741 dnl
1742 AC_ARG_ENABLE(decklink,
1743   [AS_HELP_STRING([--disable-decklink],
1744     [disable Blackmagic DeckLink SDI input (default auto)])])
1745 AC_ARG_WITH(decklink_sdk,
1746   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1747     [                        location of Blackmagic DeckLink SDI SDK])])
1748 have_decklink=no
1749 if test "${enable_decklink}" != "no"
1750 then
1751   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1752   then
1753     VLC_ADD_CXXFLAGS([decklink],[-I${with_decklink_sdk}/include])
1754   fi
1755   VLC_SAVE_FLAGS
1756   CXXFLAGS="${CXXFLAGS} ${CXXFLAGS_decklink}"
1757   AC_LANG_PUSH(C++)
1758   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1759       have_decklink=yes
1760   ], [
1761       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1762   ])
1763   AC_LANG_POP(C++)
1764   VLC_RESTORE_FLAGS
1765 fi
1766 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1767
1768
1769 dnl
1770 dnl  gnomeVFS access module
1771 dnl
1772 PKG_ENABLE_MODULES_VLC([GNOMEVFS], [access_gnomevfs], [gnome-vfs-2.0], [GnomeVFS access module], [auto])
1773
1774 dnl
1775 dnl  VCDX modules
1776 dnl
1777 PKG_ENABLE_MODULES_VLC([VCDX], [vcdx], [libcdio >= 0.78.2 libiso9660 >= 0.72 libvcdinfo >= 0.7.22], [navigate VCD with libvcdinfo], [no])
1778
1779 dnl
1780 dnl  Built-in CD-DA and VCD module
1781 dnl
1782 AC_ARG_ENABLE(vcd,
1783   [AS_HELP_STRING([--disable-vcd],
1784     [disable built-in VCD and CD-DA support (default enabled)])])
1785
1786 AC_ARG_ENABLE(libcddb,
1787   [AS_HELP_STRING([--disable-libcddb],
1788     [disable CDDB for Audio CD (default enabled)])])
1789
1790 if test "${enable_vcd}" != "no"
1791 then
1792   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1793   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1794     AC_MSG_RESULT(yes)
1795     VLC_ADD_PLUGIN([vcd cdda])
1796   ],[
1797     AC_MSG_RESULT(no)
1798   ])
1799
1800   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1801   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1802     AC_MSG_RESULT(yes)
1803     VLC_ADD_PLUGIN([vcd cdda])
1804     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1805   ],[
1806     AC_MSG_RESULT(no)
1807   ])
1808
1809   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1810   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1811     AC_MSG_RESULT(yes)
1812     VLC_ADD_PLUGIN([vcd cdda])
1813     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1814   ],[
1815     AC_MSG_RESULT(no)
1816   ])
1817
1818   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2"
1819   then
1820     VLC_ADD_PLUGIN([vcd cdda])
1821   fi
1822
1823   if test "${SYS}" = "darwin"
1824   then
1825     VLC_ADD_PLUGIN([vcd cdda])
1826     VLC_ADD_LIBS([vcd vcdx cdda],[-Wl,-framework,IOKit,-framework,CoreFoundation])
1827     VLC_ADD_LIBS([vcdx cdda],[-liconv])
1828   fi
1829
1830   if test "$enable_libcddb" != "no"; then
1831     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1832       HAVE_LIBCDDB=yes
1833       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1834       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1835       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1836       ],:
1837       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1838       HAVE_LIBCDDB=no])
1839   fi
1840 fi
1841
1842 dnl
1843 dnl Linux DVB
1844 dnl
1845 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1846   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1847 [#include <linux/dvb/version.h>
1848 #if (DVB_API_VERSION < 5)
1849 # error Linux DVB API v3.2 and older are not supported.
1850 #endif
1851 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1852 # error Linux DVB API v5.0 is unsupported. Please update.
1853 #endif
1854 ]])], [
1855   ac_cv_linux_dvb_5_1=yes
1856 ], [
1857   ac_cv_linux_dvb_5_1=no
1858 ])])
1859 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1860
1861 dnl
1862 dnl  Screen capture module
1863 dnl
1864 AC_ARG_ENABLE(screen,
1865   [AS_HELP_STRING([--enable-screen],
1866     [disable screen capture (default enabled)])])
1867 if test "${enable_screen}" != "no"; then
1868   if test "${SYS}" = "darwin"; then
1869     AC_CHECK_HEADERS(OpenGL/gl.h, [
1870       AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1871         VLC_ADD_PLUGIN([screen])
1872       ])
1873     ])
1874   fi
1875 fi
1876
1877 dnl
1878 dnl  Real RTSP plugin
1879 dnl
1880 AC_ARG_ENABLE(realrtsp,
1881   [  --enable-realrtsp       Real RTSP module (default disabled)])
1882 if test "${enable_realrtsp}" = "yes"; then
1883   VLC_ADD_PLUGIN([realrtsp])
1884 fi
1885
1886 dnl
1887 dnl MacOS eyeTV
1888 AC_ARG_ENABLE(macosx-eyetv,
1889   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1890 if test "x${enable_macosx_eyetv}" != "xno" &&
1891   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1892 then
1893   VLC_ADD_LIBS([access_eyetv], [-Wl,-framework,Foundation])
1894   VLC_ADD_PLUGIN([access_eyetv])
1895 fi
1896
1897 dnl
1898 dnl QTKit
1899 AC_ARG_ENABLE(macosx-qtkit,
1900   [  --enable-macosx-qtkit Mac OS X qtcapture (video) and qtsound (audio) module (default enabled on Mac OS X)])
1901 if test "x${enable_macosx_qtkit}" != "xno" &&
1902   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1903 then
1904   VLC_ADD_PLUGIN([qtcapture])
1905   VLC_ADD_PLUGIN([qtsound])
1906 fi
1907 AM_CONDITIONAL(HAVE_QTKIT, [test "${SYS}" = "darwin" -a "x${enable_macosx_qtkit}" != "xno"])
1908
1909
1910 dnl
1911 dnl  Demux plugins
1912 dnl
1913
1914 EXTEND_HELP_STRING([Mux/Demux plugins:])
1915
1916 dnl
1917 dnl  libdvbpsi check for ts mux/demux
1918 dnl
1919 have_dvbpsi="no"
1920 PKG_WITH_MODULES([DVBPSI], [libdvbpsi], [have_dvbpsi="yes"])
1921 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
1922
1923
1924 dnl
1925 dnl  GME demux plugin
1926 dnl
1927 AC_ARG_ENABLE(gme,
1928   [AS_HELP_STRING([--enable-gme],
1929     [use Game Music Emu (default auto)])])
1930 AS_IF([test "${enable_gme}" != "no"], [
1931   AC_CHECK_HEADER([gme/gme.h], [
1932     VLC_ADD_LIBS([gme], [-lgme])
1933     VLC_ADD_PLUGIN([gme])
1934   ], [
1935     AS_IF([test "x${enable_gme}" != "x"], [
1936       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
1937     ])
1938   ])
1939 ])
1940
1941
1942 dnl
1943 dnl  SIDPlay plugin
1944 dnl
1945 AC_ARG_ENABLE(sid,
1946     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
1947 AS_IF([test "${enable_sid}" != "no"], [
1948     PKG_CHECK_MODULES(SID, [libsidplay2], [
1949         AC_LANG_PUSH(C++)
1950         oldCPPFLAGS="$CPPFLAGS"
1951         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
1952         AC_CHECK_HEADER([sidplay/builders/resid.h], [
1953             VLC_ADD_PLUGIN([sid])
1954             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
1955             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
1956         ], [
1957             AS_IF([test -n "${enable_sid}"],
1958                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
1959                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
1960                 )
1961         ])
1962         CPPFLAGS="$oldCPPFLAGS"
1963         AC_LANG_POP(C++)
1964     ], [
1965         AS_IF([test "x${enable_sid}" = "xyes"],
1966             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
1967             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
1968             )
1969     ])
1970 ])
1971
1972
1973 dnl
1974 dnl  ogg demux plugin
1975 dnl
1976 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto])
1977 if test "${enable_sout}" != "no"; then
1978     PKG_ENABLE_MODULES_VLC([MUX_OGG], [], [ogg >= 1.0], [Ogg mux support], [auto])
1979 dnl Check for libshout
1980     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
1981 fi
1982
1983 dnl
1984 dnl  matroska demux plugin
1985 dnl
1986 AC_ARG_ENABLE(mkv,
1987   [AS_HELP_STRING([--disable-mkv],
1988     [do not use libmatroska (default auto)])])
1989 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
1990   AC_LANG_PUSH(C++)
1991   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
1992     AC_MSG_CHECKING(for libebml version >= 1.0.0)
1993     AC_EGREP_CPP(yes,
1994       [#include <ebml/EbmlVersion.h>
1995        #ifdef LIBEBML_VERSION
1996        #if LIBEBML_VERSION >= 0x010000
1997        yes
1998        #endif
1999        #endif],
2000       [AC_MSG_RESULT([yes])
2001         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2002           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2003           AC_EGREP_CPP(yes,
2004             [#include <matroska/KaxVersion.h>
2005              #ifdef LIBMATROSKA_VERSION
2006              #if LIBMATROSKA_VERSION >= 0x010000
2007              yes
2008              #endif
2009              #endif],
2010             [AC_MSG_RESULT([yes])
2011               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2012               VLC_ADD_CXXFLAGS([mkv],[])
2013               AC_CHECK_LIB(ebml_pic, main, [
2014                 VLC_ADD_PLUGIN([mkv])
2015                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2016               ],[
2017                 AC_CHECK_LIB(ebml, main, [
2018                   VLC_ADD_PLUGIN([mkv])
2019                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2020                 ])
2021               ])
2022             ], [
2023               AC_MSG_RESULT([no])
2024               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2025           ])
2026         ])
2027       ],
2028       [AC_MSG_RESULT([no])
2029         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2030     ])
2031   ])
2032   AC_LANG_POP(C++)
2033 fi
2034
2035 dnl
2036 dnl  modplug demux plugin
2037 dnl
2038 AC_ARG_ENABLE(mod,
2039   [AS_HELP_STRING([--disable-mod],
2040     [do not use libmodplug (default auto)])])
2041 if test "${enable_mod}" != "no" ; then
2042     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2043           VLC_ADD_PLUGIN([mod])
2044           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2045           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2046     ],[
2047        AS_IF([test -n "${enable_mod}"],
2048          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2049          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2050     ])
2051 fi
2052
2053 dnl
2054 dnl  mpc demux plugin
2055 dnl
2056 AC_ARG_ENABLE(mpc,
2057   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2058 if test "${enable_mpc}" != "no"
2059 then
2060   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2061     VLC_ADD_PLUGIN([mpc])
2062     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2063     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2064     VLC_ADD_PLUGIN([mpc])
2065     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2066 fi
2067
2068 dnl
2069 dnl  Codec plugins
2070 dnl
2071
2072 EXTEND_HELP_STRING([Codec plugins:])
2073
2074 dnl
2075 dnl wmafixed plugin
2076 dnl
2077 AC_ARG_ENABLE(wma-fixed,
2078   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2079 if test "${enable_wma_fixed}" = "yes"
2080 then
2081   VLC_ADD_PLUGIN([wma_fixed])
2082 fi
2083
2084 dnl
2085 dnl shine fixed point mp3 encoder
2086 dnl
2087 AC_ARG_ENABLE(shine,
2088   [  --enable-shine          shine mp3 encoding module (default disabled)])
2089 if test "${enable_shine}" = "yes"
2090 then
2091   VLC_ADD_PLUGIN([shine])
2092 fi
2093
2094 dnl
2095 dnl openmax il codec plugin
2096 dnl
2097 AC_ARG_ENABLE(omxil,
2098   [  --enable-omxil          openmax il codec module (default disabled)])
2099 if test "${enable_omxil}" = "yes"
2100 then
2101   VLC_ADD_PLUGIN([omxil])
2102 fi
2103
2104 dnl
2105 dnl CrystalHD codec plugin
2106 dnl
2107 AC_ARG_ENABLE(crystalhd,
2108   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2109 if test "${enable_crystalhd}" != "no"; then
2110     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2111       VLC_ADD_PLUGIN([crystalhd])
2112       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2113     ],[
2114       if test "${SYS}" = "mingw32" ; then
2115         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2116           VLC_ADD_PLUGIN([crystalhd])
2117           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2118             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2119             ])
2120         ],[
2121           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2122                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2123                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2124         ],[#define __LINUX_USER__
2125                #include <libcrystalhd/bc_dts_types.h>
2126         ])
2127       fi
2128     ],[
2129        #include <libcrystalhd/bc_dts_types.h>
2130       ])
2131 fi
2132
2133 dnl
2134 dnl  mad plugin
2135 dnl
2136 AC_ARG_ENABLE(mad,
2137   [  --enable-mad            libmad module (default enabled)])
2138 if test "${enable_mad}" != "no"
2139 then
2140   AC_ARG_WITH(mad,
2141     [  --with-mad=PATH         path to libmad],[],[])
2142   if test "${with_mad}" != "no" -a -n "${with_mad}"
2143   then
2144     VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${with_mad}/include])
2145     VLC_ADD_LIBS([mpgatofixed32],[-L${with_mad}/lib])
2146   fi
2147
2148   AC_ARG_WITH(mad-tree,
2149     [  --with-mad-tree=PATH    mad tree for static linking],[],[])
2150   if test "${with_mad_tree}" != "no" -a -n "${with_mad_tree}"
2151   then
2152     real_mad_tree="`cd ${with_mad_tree} 2>/dev/null && pwd`"
2153     if test -z "${real_mad_tree}"
2154     then
2155       dnl  The given directory can't be found
2156       AC_MSG_RESULT(no)
2157       AC_MSG_ERROR([${with_mad_tree} directory does not exist])
2158     fi
2159     dnl  Use a custom libmad
2160     AC_MSG_CHECKING(for mad.h in ${real_mad_tree})
2161     if test -f ${real_mad_tree}/mad.h
2162     then
2163       AC_MSG_RESULT(yes)
2164       VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${real_mad_tree}])
2165       VLC_ADD_LIBS([mpgatofixed32],[-L${real_mad_tree}/.libs])
2166       VLC_SAVE_FLAGS
2167       LDFLAGS="${LDFLAGS} ${LIBS_mpgatofixed32}"
2168       AC_CHECK_LIB(mad, mad_bit_init, [
2169         VLC_ADD_PLUGIN([mpgatofixed32])
2170         VLC_ADD_LIBS([mpgatofixed32],[-lmad])
2171         ],[ AC_MSG_ERROR([the specified tree has not been compiled ])
2172       ],[])
2173       VLC_RESTORE_FLAGS
2174     else
2175       AC_MSG_RESULT(no)
2176       AC_MSG_ERROR([the specified tree does not have mad.h])
2177     fi
2178   else
2179     VLC_SAVE_FLAGS
2180     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_mpgatofixed32}"
2181     LDFLAGS="${LDFLAGS} ${LIBS_mpgatofixed32}"
2182     AC_CHECK_HEADERS(mad.h, ,
2183       [ AC_MSG_ERROR([Could not find libmad on your system: you may get it from http://www.underbit.com/products/mad/. Alternatively you can use --disable-mad to disable the mad plugin.]) ])
2184     AC_CHECK_LIB(mad, mad_bit_init, [
2185       VLC_ADD_PLUGIN([mpgatofixed32])
2186       VLC_ADD_LIBS([mpgatofixed32],[-lmad])],
2187       [ AC_MSG_ERROR([Cannot find libmad library...]) ])
2188     VLC_RESTORE_FLAGS
2189   fi
2190 fi
2191
2192
2193 AC_ARG_ENABLE(merge-ffmpeg,
2194 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2195   enable_merge_ffmpeg="no"
2196 ])
2197 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2198
2199 VLC_SAVE_FLAGS
2200 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
2201 AC_CACHE_CHECK([if linker supports -Bsymbolic],
2202   [ac_cv_ld_bsymbolic],
2203   [AC_TRY_LINK([],,ac_cv_ld_bsymbolic=yes,ac_cv_ld_bsymbolic=no)])
2204 VLC_RESTORE_FLAGS
2205
2206 dnl
2207 dnl  avcodec decoder/encoder plugin
2208 dnl
2209 AC_ARG_ENABLE(avcodec,
2210 [  --enable-avcodec        libavcodec codec (default enabled)])
2211 AS_IF([test "${enable_avcodec}" != "no"], [
2212   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 53.34.0 libavutil >= 51.22.0],
2213     [
2214       VLC_SAVE_FLAGS
2215       CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2216       CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2217       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2218       AC_CHECK_HEADERS(libavutil/avutil.h)
2219       VLC_ADD_PLUGIN([avcodec])
2220       VLC_ADD_LIBS([avcodec],[$AVCODEC_LIBS])
2221       AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2222         VLC_ADD_LIBS([avcodec],[-Wl,-Bsymbolic])
2223       ])
2224       VLC_ADD_CFLAGS([avcodec],[$AVCODEC_CFLAGS])
2225       VLC_RESTORE_FLAGS
2226       have_avcodec="yes"
2227     ],[
2228       AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2229   ])
2230 ], [
2231   have_avcodec="no"
2232 ])
2233
2234 dnl
2235 dnl libva needs avcodec
2236 dnl
2237 AC_ARG_ENABLE(libva,
2238   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2239
2240 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2241   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2242 ])
2243 have_avcodec_vaapi="no"
2244 AS_IF([test "${enable_libva}" != "no"], [
2245   PKG_CHECK_MODULES(LIBVA, [libva libva-x11], [
2246     VLC_SAVE_FLAGS
2247     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2248     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2249     AC_CHECK_HEADERS(libavcodec/vaapi.h, [
2250       AC_MSG_NOTICE([VAAPI acceleration activated])
2251       have_avcodec_vaapi="yes"
2252     ],[
2253       AS_IF([test -n "${enable_libva}"], [
2254         AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2255       ], [
2256         AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2257       ])
2258     ])
2259     VLC_RESTORE_FLAGS
2260   ],[
2261     AS_IF([test -n "${enable_libva}"], [
2262       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2263     ], [
2264       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2265     ])
2266   ])
2267 ])
2268 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2269
2270 dnl
2271 dnl dxva2 needs avcodec
2272 dnl
2273 AC_ARG_ENABLE(dxva2,
2274   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2275
2276 have_avcodec_dxva2="no"
2277 AS_IF([test "${enable_dxva2}" != "no"], [
2278   if test "${SYS}" = "mingw32"; then
2279   AS_IF([test "x${have_avcodec}" = "xyes"], [
2280     AC_CHECK_HEADERS(dxva2api.h,
2281       [
2282         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2283            AC_MSG_NOTICE([DxVA2 acceleration activated])
2284            have_avcodec_dxva2="yes"
2285         ],[
2286     AS_IF([test "${enable_dxva2}" = "yes"],
2287           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2288               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2289         ], [#undef _WIN32_WINNT
2290             /* DXVA2 is only available in Vista and above */
2291             #define _WIN32_WINNT 0x600])
2292       ],[
2293     AS_IF([test "${enable_dxva2}" = "yes"],
2294               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2295               [AC_MSG_WARN([dxva2api.h not found])])
2296       ])
2297   ],[
2298     AS_IF([test "x${enable_dxva2}" != "x"], [
2299       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2300     ])
2301   ])
2302   fi
2303 ])
2304 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2305
2306 dnl
2307 dnl vda needs avcodec
2308 dnl
2309 AC_ARG_ENABLE(vda,
2310   [  --enable-vda          VDA  support (default auto)])
2311
2312 have_avcodec_vda="no"
2313 AS_IF([test "${enable_vda}" != "no"], [
2314   if test "${SYS}" = "darwin"; then
2315   AS_IF([test "x${have_avcodec}" = "xyes"], [
2316     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2317       [
2318         AC_CHECK_HEADERS(libavcodec/vda.h, [
2319            have_avcodec_vda="yes"
2320         ],[
2321         AS_IF([test "${enable_vda}" = "yes"],
2322               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2323               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2324         ])
2325   ],[
2326         AS_IF([test "${enable_vda}" = "yes"],
2327               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2328               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2329       ])
2330   ],[
2331     AS_IF([test "x${enable_vda}" != "x"], [
2332       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2333     ])
2334  ])
2335   fi
2336 ])
2337 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2338
2339 dnl
2340 dnl stream_out switcher needs libavcodec
2341 dnl
2342 AC_ARG_ENABLE(switcher,
2343   [  --enable-switcher       Stream-out switcher plugin (default disabled)])
2344 AS_IF([test "${enable_switcher}" = "yes"], [
2345   AS_IF([test "x${have_avcodec}" = "xyes"], [
2346     VLC_ADD_PLUGIN([stream_out_switcher])
2347     VLC_ADD_LIBS([stream_out_switcher],[$AVCODEC_LIBS $AVUTIL_LIBS $LIBM])
2348     VLC_ADD_CFLAGS([stream_out_switcher],[$AVCODEC_CFLAGS $AVUTIL_CFLAGS])
2349   ],[AC_MSG_ERROR([Stream_out switcher depends on avcodec])
2350   ])
2351 ])
2352
2353
2354 dnl
2355 dnl  avformat demuxer/muxer plugin
2356 dnl
2357
2358 AC_ARG_ENABLE(avformat,
2359 [  --enable-avformat       libavformat containers (default enabled)],, [
2360   enable_avformat="${have_avcodec}"
2361 ])
2362 if test "${enable_avformat}" != "no"
2363 then
2364   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil],
2365     [
2366       VLC_SAVE_FLAGS
2367       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2368       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2369       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2370       AC_CHECK_HEADERS(libavutil/avutil.h)
2371       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2372         VLC_ADD_PLUGIN([avformat access_avio])
2373         VLC_ADD_LIBS([access_avio],[$AVFORMAT_LIBS $AVUTIL_LIBS])
2374         VLC_ADD_CFLAGS([access_avio],[$AVFORMAT_CFLAGS $AVUTIL_CFLAGS])
2375         AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2376           VLC_ADD_LDFLAGS([avformat access_avio],[-Wl,-Bsymbolic])
2377         ])
2378       ], [
2379         VLC_ADD_LIBS([avcodec],[$AVFORMAT_LIBS $AVUTIL_LIBS])
2380         VLC_ADD_CFLAGS([avcodec],[$AVFORMAT_CFLAGS $AVUTIL_CFLAGS])
2381       ])
2382       VLC_RESTORE_FLAGS
2383     ],[
2384       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2385   ])
2386 fi
2387
2388 dnl
2389 dnl  swscale image scaling and conversion plugin
2390 dnl
2391
2392 AC_ARG_ENABLE(swscale,
2393   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2394           (default enabled)]))
2395 if test "${enable_swscale}" != "no"
2396 then
2397   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2398     [
2399       VLC_SAVE_FLAGS
2400       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2401       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2402       AC_CHECK_HEADERS(libswscale/swscale.h)
2403       VLC_ADD_PLUGIN([swscale])
2404       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2405       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2406       AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2407         VLC_ADD_LIBS([swscale],[-Wl,-Bsymbolic])
2408       ])
2409       VLC_RESTORE_FLAGS
2410     ],[
2411       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2412   ])
2413 fi
2414
2415 dnl
2416 dnl  postproc plugin
2417 dnl
2418
2419 AC_ARG_ENABLE(postproc,
2420 [  --enable-postproc       libpostproc image post-processing (default auto)])
2421 if test "${enable_postproc}" != "no"
2422 then
2423   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2424     [
2425       VLC_SAVE_FLAGS
2426       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2427       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2428       AC_CHECK_HEADERS(postproc/postprocess.h)
2429       VLC_ADD_PLUGIN([postproc])
2430       VLC_ADD_LIBS([postproc],[$POSTPROC_LIBS $AVUTIL_LIBS])
2431       VLC_ADD_CFLAGS([postproc],[$POSTPROC_CFLAGS $AVUTIL_CFLAGS])
2432       VLC_RESTORE_FLAGS
2433     ],[
2434       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2435   ])
2436 fi
2437
2438 dnl
2439 dnl  faad decoder plugin
2440 dnl
2441 AC_ARG_ENABLE(faad,
2442 [  --enable-faad           faad codec (default auto)])
2443 if test "${enable_faad}" != "no"; then
2444   AC_ARG_WITH(faad-tree,  [  --with-faad-tree=PATH   faad tree for static linking])
2445   if test -n "${with_faad_tree}"; then
2446     AC_MSG_CHECKING(for libfaad.a in ${with_faad_tree})
2447     real_faad_tree="`cd ${with_faad_tree} 2>/dev/null && pwd`"
2448     if test -z "${real_faad_tree}"; then
2449       dnl  The given directory can't be found
2450       AC_MSG_RESULT(no)
2451       AC_MSG_ERROR([cannot cd to ${with_faad_tree}])
2452     fi
2453     if test -f "${real_faad_tree}/libfaad/.libs/libfaad.a"; then
2454       dnl  Use the custom faad
2455       AC_MSG_RESULT(${real_faad_tree}/libfaad/.libs/libfaad.a)
2456       VLC_ADD_PLUGIN([faad])
2457       VLC_ADD_LIBS([faad],[${real_faad_tree}/libfaad/.libs/libfaad.a])
2458       VLC_ADD_CPPFLAGS([faad],[-I${real_faad_tree}/include])
2459     else
2460       dnl  The given libfaad wasn't built
2461       AC_MSG_RESULT(no)
2462       AC_MSG_ERROR([cannot find ${real_faad_tree}/libfaad/.libs/libfaad.a, make sure you compiled libfaad in ${with_faad_tree}])
2463     fi
2464   else
2465     VLC_SAVE_FLAGS
2466     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_faad}"
2467     LDFLAGS="${LDFLAGS} ${LIBS_faad}"
2468     AC_CHECK_HEADERS(faad.h,
2469       [ AC_CHECK_LIB(faad, faacDecOpen, [
2470           VLC_ADD_PLUGIN([faad])
2471           VLC_ADD_LIBS([faad],[-lfaad]) ], [
2472             AC_CHECK_LIB(faad, NeAACDecOpen, [
2473               VLC_ADD_PLUGIN([faad])
2474               VLC_ADD_LIBS([faad],[-lfaad]) ], [
2475                 AS_IF([test "${enable_faad}" = "yes"],
2476                 [ AC_MSG_ERROR([Cannot find libfaad library...]) ],
2477                 [ AC_MSG_WARN([Cannot find libfaad library...]) ]) ]) ])
2478       ] , [ AS_IF([test "${enable_faad}" = "yes"],
2479         [ AC_MSG_ERROR([Cannot find development headers for libfaad...]) ],
2480         [ AC_MSG_WARN([Cannot find development headers for libfaad...]) ]) ])
2481     VLC_RESTORE_FLAGS
2482   fi
2483 fi
2484
2485 dnl
2486 dnl twolame encoder plugin
2487 dnl
2488 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2489
2490 dnl
2491 dnl fdk-aac encoder plugin
2492 dnl
2493 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2494
2495 dnl
2496 dnl  QuickTime plugin
2497 dnl
2498 AC_ARG_ENABLE(quicktime,
2499   [  --enable-quicktime      QuickTime module (deprecated)])
2500 if test "${enable_quicktime}" = "yes"; then
2501   if test "${SYS}" = "mingw32"; then
2502     VLC_ADD_PLUGIN([quicktime])
2503   else
2504   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2505     [ VLC_ADD_PLUGIN([quicktime])
2506       VLC_ADD_LIBS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2507     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2508   fi
2509 fi
2510
2511 dnl
2512 dnl A52/AC3 decoder plugin
2513 dnl
2514 AC_ARG_ENABLE(a52,
2515   [  --enable-a52            A/52 support with liba52 (default enabled)])
2516 if test "${enable_a52}" != "no"
2517 then
2518   AC_ARG_WITH(a52,
2519     [  --with-a52=PATH         a52 headers and libraries])
2520   AC_ARG_WITH(a52-tree,
2521     [  --with-a52-tree=PATH    a52dec tree for static linking ],[],[])
2522   if test "${with_a52_tree}" != "no" -a -n "${with_a52_tree}"
2523   then
2524     real_a52_tree="`cd ${with_a52_tree} 2>/dev/null && pwd`"
2525     if test -z "${real_a52_tree}"
2526     then
2527       dnl  The given directory can't be found
2528       AC_MSG_RESULT(no)
2529       AC_MSG_ERROR([${with_a52_tree} directory does not exist])
2530     fi
2531     dnl  Use a custom a52dec
2532     AC_MSG_CHECKING(for a52.h in ${real_a52_tree}/include)
2533     if test -f ${real_a52_tree}/include/a52.h
2534     then
2535       AC_MSG_RESULT(yes)
2536       VLC_ADD_CPPFLAGS([a52tofloat32],[-I${real_a52_tree}])
2537       VLC_ADD_LIBS([a52tofloat32],[-L${real_a52_tree}/liba52/.libs])
2538       VLC_SAVE_FLAGS
2539       LDFLAGS="${LDFLAGS} ${LIBS_a52tofloat32}"
2540       AC_CHECK_LIB(a52, a52_free, [
2541         VLC_ADD_PLUGIN([a52tofloat32])
2542         VLC_ADD_CPPFLAGS([a52tofloat32],[-DUSE_A52DEC_TREE])
2543         VLC_ADD_LIBS([a52tofloat32],[-la52])
2544         ],[
2545         if test -f ${real_a52_tree}/liba52/.libs/liba52.a
2546         then
2547           AC_MSG_ERROR([make sure you have at least a52dec-0.7.3 ($real_a52_tree)])
2548         else
2549           AC_MSG_ERROR([the specified tree has not been compiled])
2550         fi
2551       ])
2552     else
2553       AC_MSG_RESULT(no)
2554       AC_MSG_ERROR([the specified tree does not have a52.h])
2555     fi
2556   else
2557     if test -z "${with_a52}"
2558     then
2559       LDFLAGS_test=""
2560       CPPFLAGS_test=""
2561     else
2562       LDFLAGS_test="-L${with_a52}/lib"
2563       CPPFLAGS_test="-I${with_a52}/include"
2564     fi
2565     VLC_SAVE_FLAGS
2566     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2567     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2568     AC_CHECK_HEADERS(a52dec/a52.h, [
2569       AC_CHECK_LIB(a52, a52_free, [
2570         VLC_ADD_PLUGIN([a52tofloat32])
2571         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2572         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2573       ],[
2574         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2575         ], [$LIBM])
2576     ],[
2577       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2578     ])
2579     VLC_RESTORE_FLAGS
2580   fi
2581 fi
2582
2583 AC_ARG_WITH(a52-fixed,
2584       [  --with-a52-fixed        specify if liba52 has been compiled with fixed point support],
2585       [
2586         VLC_ADD_CPPFLAGS([a52tofloat32],[-DLIBA52_FIXED]) ])
2587
2588 dnl
2589 dnl DTS Coherent Acoustics decoder plugin
2590 dnl
2591 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2592
2593 dnl
2594 dnl  Flac plugin
2595 dnl
2596 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2597
2598 dnl
2599 dnl  Libmpeg2 plugin
2600 dnl
2601 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2602
2603 dnl
2604 dnl  Vorbis plugin
2605 dnl
2606 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2607
2608 dnl
2609 dnl  Tremor plugin
2610 dnl
2611 AC_ARG_ENABLE(tremor,
2612   [  --enable-tremor         Tremor decoder support (default disabled)])
2613 if test "${enable_tremor}" = "yes"
2614 then
2615   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2616     VLC_ADD_PLUGIN([tremor])
2617     VLC_ADD_LIBS([tremor],[-lvorbisidec -logg])
2618    ],[])
2619 fi
2620
2621 dnl
2622 dnl  Speex plugins
2623 dnl
2624 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2625 have_speexdsp="no"
2626 AS_IF([test "${enable_speex}" != "no"], [
2627   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2628     have_speexdsp="yes"
2629   ], [
2630     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2631   ])
2632 ])
2633 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2634
2635 dnl
2636 dnl  Opus plugin
2637 dnl
2638 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus], [Opus support], [auto])
2639
2640 dnl
2641 dnl  theora decoder plugin
2642 dnl
2643 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2644
2645 dnl
2646 dnl  dirac encoder plugin
2647 dnl
2648 PKG_ENABLE_MODULES_VLC([DIRAC], [], [dirac >= 0.10.0], [dirac encoder], [auto])
2649
2650 dnl
2651 dnl  schroedinger decoder plugin (for dirac format video)
2652 dnl
2653 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2654
2655 dnl
2656 dnl  PNG decoder module
2657 dnl
2658 AC_ARG_ENABLE(png,
2659   [  --enable-png            PNG support (default enabled)])
2660 AS_IF([test "${enable_png}" != "no"], [
2661 AC_CHECK_HEADERS(png.h, [
2662   VLC_SAVE_FLAGS
2663   LDFLAGS="${LDFLAGS} -lz $LIBM"
2664   AC_CHECK_LIB(png, png_set_rows, [
2665     VLC_ADD_LIBS([png],[-lpng -lz $LIBM])
2666     VLC_ADD_PLUGIN([png])
2667   ], [], [-lz $LIBM])
2668   VLC_RESTORE_FLAGS
2669   ])
2670 ])
2671
2672 dnl
2673 dnl H264 encoder plugin (10-bit lib264)
2674 dnl
2675 AC_ARG_ENABLE(x26410b,
2676   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2677 if test "${enable_x26410b}" != "no"; then
2678 AC_ARG_WITH(x26410b-tree,
2679   [ --with-x26410b-tree=PATH      H264 10-bit encoding module with libx264 (static linking)],[],[])
2680   if test "${with_x26410b_tree}" != "no" -a -n "${with_x26410b_tree}"
2681   then
2682     real_x26410b_tree="̧`cd ${with_x26410b_tree} 2>/dev/null && pwd`"
2683     if test -z "${real_x26410b_tree}"
2684     then
2685       AC_MSG_RESULT(no)
2686       AC_MSG_ERROR([${with_x26410b_tree} directory does not exist])
2687     fi
2688     AC_MSG_CHECKING(for x264.h in ${real_x26410b_tree})
2689     if test -f ${with_x26410b_tree}/x264_config.h
2690     then
2691       AC_MSG_RESULT(yes)
2692       AC_MSG_CHECKING(for 10-bit build of x264)
2693       if grep -q "BIT_DEPTH.*10"  ${with_x26410b_tree}/x264_config.h ;then
2694         AC_MSG_RESULT(yes)
2695         VLC_ADD_PLUGIN([x26410b])
2696         VLC_ADD_CFLAGS([x26410b],[-I${with_x26410b_tree}])
2697         VLC_ADD_LIBS([x26410b],[-L${with_x26410b_tree} -lm -lpthread -lx264])
2698       else
2699         AC_MSG_RESULT(no)
2700         AC_MSG_ERROR([${with_x26410b_tree} isnt build 10-bit])
2701       fi
2702     else
2703       AC_MSG_RESULT(no)
2704       AC_MSG_ERROR([${with_x26410b_tree} doesnt have x264_config.h])
2705     fi
2706   else
2707     PKG_CHECK_MODULES(X26410B, x26410b, [
2708         VLC_ADD_PLUGIN([x26410b])
2709         VLC_ADD_LDFLAGS([x26410b],[${X26410B_LIBS}])
2710         AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2711           VLC_ADD_LIBS([x26410b],[-Wl,-Bsymbolic])
2712         ])
2713         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2714         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2715           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2716         fi
2717     ], [
2718        if test "${enable_x26410b}" = "yes"; then
2719         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2720        fi
2721     ])
2722   fi
2723 fi
2724
2725
2726 dnl
2727 dnl H264 encoder plugin (using libx264)
2728 dnl
2729 AC_ARG_ENABLE(x264,
2730   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2731 if test "${enable_x264}" != "no"; then
2732   AC_ARG_WITH(x264-tree,
2733     [  --with-x264-tree=PATH   x264 tree for static linking ],[],[])
2734   if test "${with_x264_tree}" != "no" -a -n "${with_x264_tree}"
2735   then
2736     real_x264_tree="`cd ${with_x264_tree} 2>/dev/null && pwd`"
2737     if test -z "${real_x264_tree}"
2738     then
2739       dnl  The given directory can't be found
2740       AC_MSG_RESULT(no)
2741       AC_MSG_ERROR([${with_x264_tree} directory does not exist])
2742     fi
2743     dnl  Use a custom libx264
2744     AC_MSG_CHECKING(for x264.h in ${real_x264_tree})
2745     if test -f ${real_x264_tree}/x264.h
2746     then
2747       AC_MSG_RESULT(yes)
2748       VLC_ADD_CPPFLAGS([x264],[-I${real_x264_tree}])
2749       VLC_ADD_LIBS([x264],[-L${real_x264_tree}])
2750       PKG_CHECK_MODULES(X264,x264, [
2751         VLC_ADD_PLUGIN([x264])
2752         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2753         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2754         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2755           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2756         fi
2757       ],[
2758         AC_MSG_ERROR([the specified tree has not been compiled])
2759       ])
2760     else
2761       AC_MSG_RESULT(no)
2762       AC_MSG_ERROR([the specified tree does not have x264.h])
2763     fi
2764   else
2765       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2766         VLC_ADD_PLUGIN([x264])
2767         VLC_ADD_LDFLAGS([x264],[${X264_LIBS}])
2768
2769         AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2770           VLC_ADD_LIBS([x264],[-Wl,-Bsymbolic])
2771         ])
2772
2773         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2774         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2775           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2776         fi
2777       ],[
2778         if test "${enable_x264}" = "yes"; then
2779             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2780           fi
2781       ])
2782   fi
2783 fi
2784
2785 dnl
2786 dnl libfluidsynth (MIDI synthetizer) plugin
2787 dnl
2788 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2789
2790 dnl
2791 dnl Teletext Modules
2792 dnl vbi decoder plugin (using libzbvi)
2793 dnl telx module
2794 dnl uncompatible
2795 dnl
2796 AC_ARG_ENABLE(zvbi,
2797   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2798                   libzvbi (default enabled)]))
2799 AC_ARG_ENABLE(telx,
2800   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2801                   zvbi) (default enabled if zvbi is absent)]))
2802
2803 AS_IF( [test "${enable_zvbi}" != "no"],[
2804     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2805         [
2806           VLC_ADD_LIBS([zvbi],[$ZVBI_LIBS])
2807           if test "${SYS}" = "mingw32"; then
2808               VLC_ADD_LIBS([zvbi],[ -lpthreadGC2])
2809           fi
2810           VLC_ADD_CFLAGS([zvbi],[$ZVBI_CFLAGS])
2811           VLC_ADD_PLUGIN([zvbi])
2812           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2813           AS_IF( [test "${enable_telx}" = "yes"],[
2814                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2815                   ])
2816         ],[
2817           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2818         ])
2819     ])
2820 AS_IF( [test "${enable_telx}" != "no" ],[
2821   VLC_ADD_PLUGIN([telx])
2822   ])
2823
2824 dnl
2825 dnl libass subtitle rendering module
2826 dnl
2827 AC_ARG_ENABLE(libass,
2828   [  --enable-libass         Subtitle support using libass (default enabled)])
2829 AS_IF( [test "${enable_libass}" != "no"], [
2830   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2831       [
2832         VLC_ADD_LIBS([libass],[$LIBASS_LIBS])
2833         VLC_ADD_CFLAGS([libass],[$LIBASS_CFLAGS])
2834         VLC_ADD_PLUGIN([libass])
2835
2836         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2837           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2838            VLC_ADD_LIBS([libass],[-lfontconfig])
2839        ])
2840       ],[
2841         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2842       ])
2843   ])
2844
2845 dnl
2846 dnl  kate decoder plugin
2847 dnl
2848 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2849
2850 dnl
2851 dnl  tiger rendering for kate decoder plugin
2852 dnl
2853 AC_ARG_ENABLE(tiger,
2854 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2855 AS_IF([test "${enable_tiger}" != "no"], [
2856   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2857       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])
2858       VLC_ADD_CFLAGS([kate],[$TIGER_CFLAGS])
2859       VLC_ADD_LIBS([kate],[$TIGER_LIBS]) ],[
2860         AS_IF([test -n "${enable_tiger}"], [
2861           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2862         ])
2863   ])
2864 ])
2865
2866
2867 dnl
2868 dnl  Video plugins
2869 dnl
2870
2871 EXTEND_HELP_STRING([Video plugins:])
2872
2873 dnl
2874 dnl  OpenGL
2875 dnl
2876 PKG_CHECK_MODULES([GL], [gl], [
2877   have_gl="yes"
2878 ], [
2879   AC_CHECK_HEADER([GL/gl.h], [
2880     have_gl="yes"
2881     GL_CFLAGS=""
2882     GL_LIBS="-lGL"
2883   ], [
2884     have_gl="no"
2885   ])
2886 ])
2887
2888 dnl OpenGL ES 2: depends on EGL 1.1 and is currently unfinished
2889 dnl PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [auto])
2890 dnl OpenGL ES 1: depends on EGL 1.0 and is currently broken
2891 dnl PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [auto])
2892
2893 AC_ARG_ENABLE(egl,
2894   [  --enable-egl            OpenGL support through EGL (default disabled)],, [
2895   enable_egl="no"
2896 ])
2897 AS_IF([test "$enable_egl" != "no"], [
2898   PKG_CHECK_MODULES([EGL], [egl], [
2899     VLC_ADD_PLUGIN([gl])
2900     VLC_ADD_PLUGIN([egl])
2901   ])
2902 ])
2903
2904 dnl
2905 dnl  Xlib
2906 dnl
2907
2908 AC_PATH_XTRA()
2909 AC_CHECK_HEADERS(X11/Xlib.h)
2910
2911 dnl
2912 dnl  X C Bindings modules
2913 dnl
2914 AC_ARG_ENABLE(xcb,
2915   [  --enable-xcb            X11 support with XCB (default enabled)],, [
2916   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" -a "${SYS}" != "symbian"], [
2917     enable_xcb="yes"
2918   ], [
2919     enable_xcb="no"
2920   ])
2921 ])
2922 AC_ARG_ENABLE(xvideo,
2923   [  --enable-xvideo         XVideo support (default enabled)],, [
2924     enable_xvideo="$enable_xcb"
2925 ])
2926 AC_ARG_ENABLE(glx,
2927   [  --enable-glx            OpenGL support through GLX (default enabled)],, [
2928   enable_glx="$enable_xcb"
2929 ])
2930
2931 have_xcb="no"
2932 AS_IF([test "${enable_xcb}" != "no"], [
2933   dnl libxcb
2934   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
2935   have_xcb="yes"
2936   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
2937   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
2938
2939   AS_IF([test "${enable_xvideo}" != "no"], [
2940     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [
2941       VLC_ADD_PLUGIN([xcb_xv])
2942     ])
2943   ])
2944
2945   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [
2946     VLC_ADD_PLUGIN([panoramix])
2947     VLC_ADD_LIBS([panoramix],[${XCB_RANDR_LIBS} ${XCB_LIBS}])
2948     VLC_ADD_CFLAGS([panoramix],[${XCB_RANDR_CFLAGS} ${XCB_CFLAGS}])
2949   ], [
2950     AC_MSG_WARN([${XCB_RANDR_PKG_ERRORS}. Panoramix filter will not be supported.])
2951   ])
2952
2953   PKG_CHECK_MODULES(XPROTO, [xproto], [
2954     VLC_ADD_PLUGIN([xwd])
2955
2956     dnl xcb-utils
2957     PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [
2958       VLC_ADD_PLUGIN([globalhotkeys])
2959       VLC_ADD_CFLAGS([xcb_window], [-DHAVE_XCB_KEYSYMS])
2960     ], [
2961       AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
2962     ])
2963   ], [
2964     AC_MSG_WARN([${XPROTO_PKG_ERRORS}. Hotkeys and XWD will not work.])
2965   ])
2966
2967   AS_IF([test "${enable_glx}" != "no"], [
2968     AS_IF([test "${have_gl}" != "yes"], [
2969       AC_MSG_ERROR([${GL_PKG_ERRORS}. Pass --disable-glx if you do not need OpenGL X11 support.])
2970     ])
2971     VLC_ADD_PLUGIN([xcb_glx])
2972     VLC_ADD_PLUGIN([glx])
2973     VLC_ADD_PLUGIN([gl])
2974   ])
2975 ])
2976 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
2977
2978 dnl
2979 dnl  SDL module
2980 dnl
2981 AC_ARG_ENABLE(sdl,
2982   [  --enable-sdl            SDL support (default enabled)])
2983 AC_ARG_ENABLE(sdl-image,
2984   [  --enable-sdl-image      SDL image support (default enabled)])
2985 if test "${enable_sdl}" != "no"
2986 then
2987    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
2988       # SDL on Darwin is heavily patched and can only run SDL_image
2989       if test "${SYS}" != "darwin"; then
2990         VLC_ADD_PLUGIN([vout_sdl])
2991       fi
2992       if test "${SYS}" != "mingw32" -a "${SYS}" != "os2"; then
2993         VLC_ADD_LIBS([vout_sdl],[${X_LIBS} ${X_PRE_LIBS} -lX11])
2994       fi
2995       VLC_ADD_CFLAGS([vout_sdl],[${SDL_CFLAGS}])
2996       VLC_ADD_LIBS([vout_sdl],[${SDL_LIBS}])
2997
2998       # SDL_image
2999       AS_IF([ test "${enable_sdl_image}" != "no"],[
3000         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3001           VLC_ADD_PLUGIN([sdl_image])
3002           VLC_ADD_LIBS([sdl_image],[${SDL_IMAGE_LIBS}])
3003           VLC_ADD_CFLAGS([sdl_image], [${SDL_IMAGE_CFLAGS}])],
3004           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3005           ])
3006       ])
3007    ],[
3008      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3009    ])
3010 fi
3011
3012
3013 dnl
3014 dnl Mac Vout
3015 AC_ARG_ENABLE(macosx-vout,
3016   [  --enable-macosx-vout    Mac OS X video output module (default enabled on Mac OS X)])
3017 if test "x${enable_macosx_vout}" != "xno" &&
3018   (test "${SYS}" = "darwin" || test "${enable_macosx_vout}" = "yes")
3019 then
3020   VLC_ADD_LIBS([vout_macosx],[-Wl,-framework,Cocoa])
3021   VLC_ADD_LIBS([vout_macosx],[-Wl,-framework,OpenGL])
3022   VLC_ADD_PLUGIN([vout_macosx])
3023 fi
3024
3025
3026 dnl
3027 dnl  freetype module
3028 dnl
3029 AC_ARG_ENABLE(freetype,
3030   [  --enable-freetype       freetype support   (default auto)])
3031 AC_ARG_ENABLE(fribidi,
3032   [  --enable-fribidi        fribidi support    (default auto)])
3033 AC_ARG_ENABLE(fontconfig,
3034   [  --enable-fontconfig     fontconfig support (default auto)])
3035
3036 if test "${enable_freetype}" != "no"; then
3037    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3038       have_freetype=yes
3039       VLC_ADD_PLUGIN([freetype])
3040       VLC_ADD_CPPFLAGS([freetype skins2],[${FREETYPE_CFLAGS}])
3041       if test "${SYS}" = "mingw32"; then
3042         VLC_ADD_LIBS([freetype],[-liconv -lz])
3043       fi
3044       VLC_ADD_LIBS([freetype skins2],[${FREETYPE_LIBS}])
3045
3046       AC_CHECK_HEADERS(Carbon/Carbon.h,
3047                        [VLC_ADD_LIBS([freetype],[-Wl,-framework,Carbon])])
3048
3049       dnl fontconfig support
3050       if test "${SYS}" != "mingw32"; then
3051           if test "${enable_fontconfig}" != "no"; then
3052             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3053               VLC_ADD_CPPFLAGS([freetype],[-DHAVE_FONTCONFIG])
3054               VLC_ADD_LIBS([freetype],[-lfontconfig])
3055             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3056           fi
3057       else
3058           VLC_ADD_LIBS([freetype],[-lgdi32])
3059       fi
3060
3061       dnl fribidi support
3062       if test "${enable_fribidi}" != "no"; then
3063         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3064           VLC_ADD_CPPFLAGS([freetype skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3065           VLC_ADD_LIBS([freetype skins2], [${FRIBIDI_LIBS}])
3066         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional support will be disabled in FreeType.])])
3067       fi
3068
3069   ],[
3070   have_freetype=no
3071   AS_IF([test -n "${enable_freetype}"],[
3072     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3073     ])
3074   ])
3075 fi
3076
3077
3078 dnl
3079 dnl  QuartzText vout module (iOS/Mac OS)
3080 dnl
3081 AC_ARG_ENABLE(macosx-quartztext,
3082   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3083 if test "x${enable_macosx_quartztext}" != "xno" &&
3084   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3085 then
3086   VLC_ADD_PLUGIN([quartztext])
3087   VLC_ADD_LIBS([quartztext],[-Wl,-framework,ApplicationServices])
3088 fi
3089
3090 dnl
3091 dnl  SVG module
3092 dnl
3093 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3094
3095 dnl
3096 dnl  android surface module
3097 dnl
3098 AC_ARG_ENABLE(android-surface,
3099   [  --enable-android-surface   Android Surface video output module (default disabled)])
3100 if test "${enable_android_surface}" = "yes"; then
3101   if test "${HAVE_ANDROID}" = "1"; then
3102      VLC_ADD_PLUGIN([android_surface])
3103      VLC_ADD_LDFLAGS([android_surface], [-ldl])
3104   fi
3105 fi
3106
3107
3108 dnl
3109 dnl  iOS vout module
3110 dnl
3111 AC_ARG_ENABLE(ios-vout,
3112   [  --enable-ios-vout    iOS video output module (default disabled)])
3113 if test "${enable_ios_vout}" = "yes"
3114 then
3115   VLC_ADD_PLUGIN([vout_ios])
3116   VLC_ADD_CFLAGS([vout_ios], [-DUSE_OPENGL_ES=1])
3117   VLC_ADD_LIBS([vout_ios], [-Wl,-framework,OpenGLES,-framework,QuartzCore,-framework,UIKit,-framework,Foundation])
3118 fi
3119
3120 dnl
3121 dnl  Windows DirectX module
3122 dnl
3123
3124 if test "${SYS}" = "mingw32"
3125 then
3126   VLC_ADD_PLUGIN([panoramix])
3127 fi
3128
3129 AC_ARG_ENABLE(directx,
3130   [AS_HELP_STRING([--enable-directx],
3131     [Microsoft DirectX support (default enabled on Windows)])],, [
3132   AS_IF([test "${SYS}" = "mingw32"], [
3133     enable_directx="yes"
3134   ], [
3135     enable_directx="no"
3136   ])
3137 ])
3138 have_directx="no"
3139 AS_IF([test "${enable_directx}" != "no"], [
3140   dnl DirectDraw
3141   AC_CHECK_HEADERS(ddraw.h, [
3142     have_directx="yes"
3143   ], [
3144     AC_MSG_ERROR([Cannot find DirectX headers!])
3145   ])
3146
3147   dnl OpenGL
3148   AC_CHECK_HEADERS(GL/wglew.h, [
3149     VLC_ADD_PLUGIN([glwin32])
3150   ],, [
3151     #include <windows.h>
3152     #include <GL/gl.h>
3153   ])
3154
3155   dnl Direct3D
3156   AC_CHECK_HEADERS(d3d9.h, [
3157     VLC_ADD_PLUGIN([direct3d])
3158   ])
3159
3160   dnl Direct2D
3161   AC_CHECK_HEADERS(d2d1.h, [
3162     VLC_ADD_PLUGIN([direct2d])
3163   ])
3164 ])
3165 AM_CONDITIONAL([HAVE_DIRECTX], [test "$have_directx" = "yes"])
3166
3167 dnl
3168 dnl  Linux framebuffer module
3169 dnl
3170 AC_CHECK_HEADER([linux/fb.h], [
3171   VLC_ADD_PLUGIN([fb])
3172 ])
3173
3174
3175 dnl
3176 dnl  DirectFB module
3177 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3178 dnl  TODO: support for static linking
3179 dnl
3180 AC_ARG_ENABLE(directfb,
3181   [  --enable-directfb       DirectFB support (default disabled)])
3182 AC_ARG_WITH(directfb,
3183   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3184
3185 if test "${enable_directfb}" = "yes"; then
3186     have_directfb="false"
3187     CPPFLAGS_mydirectfb=
3188     LIBS_mydirectfb=
3189     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3190         dnl Trying the given location
3191         VLC_SAVE_FLAGS
3192
3193         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3194         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3195
3196         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3197         LIBS="${LIBS} ${LIBS_new}"
3198
3199         dnl FIXME: too obscure
3200         AC_CHECK_HEADER([directfb.h], [
3201             AC_CHECK_LIB([direct],[direct_initialize], [
3202                 AC_CHECK_LIB([fusion], [fusion_enter], [
3203                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3204                 ], have_directfb="false")
3205             ], have_directfb="false")
3206         ], have_directfb="false")
3207
3208         VLC_RESTORE_FLAGS
3209
3210         if test "${have_directfb}" = "true"; then
3211             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3212             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3213         fi
3214     else
3215         dnl Look for directfb-config
3216         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3217         if test "${DIRECTFB_CONFIG}" != "no"; then
3218             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3219             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3220             have_directfb="true"
3221         else
3222             dnl Trying with pkg-config
3223             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3224                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3225                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3226                 have_directfb="true"
3227                 ], [have_directfb="false"])
3228         fi
3229     fi
3230     if test "${have_directfb}" = "true"; then
3231         VLC_ADD_PLUGIN([directfb])
3232         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3233         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3234     else
3235         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3236     fi
3237 fi
3238
3239 dnl
3240 dnl  AA plugin
3241 dnl
3242 AC_ARG_ENABLE(aa,
3243   [  --enable-aa             aalib output (default disabled)])
3244 if test "${enable_aa}" = "yes"
3245 then
3246   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3247   if test "${have_aa}" = "true"
3248   then
3249     VLC_ADD_PLUGIN([aa])
3250     VLC_ADD_LIBS([aa],[-laa])
3251     if test "${SYS}" != "mingw32"; then
3252       VLC_ADD_LIBS([aa],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3253     fi
3254   fi
3255 fi
3256
3257 dnl
3258 dnl  libcaca plugin
3259 dnl
3260 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3261
3262 dnl
3263 dnl  OS/2 KVA plugin
3264 dnl
3265 AC_ARG_ENABLE(kva,
3266   [AS_HELP_STRING([--enable-kva],
3267     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3268   AS_IF([test "$SYS" = "os2"], [
3269     enable_kva="yes"
3270   ])
3271 ])
3272 have_kva="no"
3273 KVA_LIBS=""
3274 AS_IF([test "$enable_kva" != "no"], [
3275   AC_CHECK_HEADERS([kva.h], [
3276     have_kva="yes"
3277     AC_CHECK_LIB(kva, main, [
3278       KVA_LIBS="-lkva"
3279     ])
3280   ])
3281 ])
3282 AC_SUBST(KVA_LIBS)
3283 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3284
3285 dnl
3286 dnl  Audio plugins
3287 dnl
3288
3289 EXTEND_HELP_STRING([Audio plugins:])
3290
3291 dnl
3292 dnl  Pulseaudio module
3293 dnl
3294 AC_ARG_ENABLE(pulse,
3295   [AS_HELP_STRING([--enable-pulse],
3296     [use the PulseAudio client library (default auto)])])
3297 have_pulse="no"
3298 AS_IF([test "${enable_pulse}" != "no"], [
3299   PKG_CHECK_MODULES([PULSE], [libpulse >= 0.9.22], [
3300     have_pulse="yes"
3301   ], [
3302     PKG_CHECK_MODULES([PULSE], [libpulse >= 0.9.16], [
3303       AS_IF([test "${no_x}" != "yes"], [
3304         have_pulse="yes"
3305         PULSE_LIBS="$PULSE_LIBS ${X_LIBS} ${X_PRE_LIBS} -lX11"
3306       ], [
3307         AS_IF([test "${enable_pulse}" = "yes"], [
3308           AC_MSG_ERROR([Xlib is required with PulseAudio pre-0.9.22 versions
3309 (see http://www.pulseaudio.org/ticket/799 for further reference).])
3310         ])
3311       ])
3312     ], [
3313       AS_IF([test "x${enable_pulse}" != "x"], [
3314         AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 0.9.22 or later required.])
3315       ])
3316     ])
3317   ])
3318 ])
3319 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3320
3321 dnl
3322 dnl  ALSA module
3323 dnl
3324 AC_ARG_ENABLE(alsa,
3325   [AS_HELP_STRING([--enable-alsa],
3326     [support the Advanced Linux Sound Architecture (default auto)])],, [
3327   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3328     enable_alsa="yes"
3329   ])
3330 ])
3331 have_alsa="no"
3332 AS_IF([test "${enable_alsa}" != "no"], [
3333   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3334     have_alsa="yes"
3335   ], [
3336     AS_IF([test "x${enable_alsa}" != "x"], [
3337       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3338     ])
3339   ])
3340 ])
3341 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3342
3343 dnl
3344 dnl  Open Sound System module
3345 dnl
3346 AC_ARG_ENABLE(oss,
3347   [AS_HELP_STRING([--enable-oss],
3348     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3349   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3350     enable_oss="no"
3351   ])
3352 ])
3353 have_oss="no"
3354 OSS_LIBS=""
3355 AS_IF([test "$enable_oss" != "no"], [
3356   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3357     have_oss="yes"
3358     AC_CHECK_LIB(ossaudio, main, [
3359       OSS_LIBS="-lossaudio"
3360     ])
3361   ])
3362 ])
3363 AC_SUBST(OSS_LIBS)
3364 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3365
3366 dnl
3367 dnl  OpenBSD sndio module
3368 dnl
3369 AC_ARG_ENABLE([sndio],
3370   [AS_HELP_STRING([--disable-sndio],
3371     [support the OpenBSD sndio (default auto)])],, [
3372   AS_IF([test "$SYS" = "opensd"], [
3373     enable_sndio="yes"
3374   ])
3375 ])
3376 have_sndio="no"
3377 AS_IF([test "$enable_sndio" != "no"], [
3378   AC_CHECK_HEADER([sndio.h], [
3379     have_sndio="yes"
3380   ])
3381 ])
3382 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3383
3384 dnl
3385 dnl  Windows Audio Session plugin
3386 dnl
3387 AC_ARG_ENABLE([wasapi],
3388   [AS_HELP_STRING([--enable-wasapi],
3389     [use the Windows Audio Session API (default auto)])
3390 ])
3391 have_wasapi="no"
3392 AS_IF([test "$enable_wasapi" != "no"], [
3393   AC_CHECK_HEADER([audioclient.h], [
3394     have_wasapi="yes"
3395   ], [
3396     AS_IF([test "x${enable_wasapi}" != "x"], [
3397       AC_MSG_ERROR([Windows Audio Session API not found.])
3398     ])
3399   ])
3400 ])
3401 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3402
3403 dnl
3404 dnl  win32 waveOut plugin
3405 dnl
3406 AC_ARG_ENABLE(waveout,
3407   [  --enable-waveout        Win32 waveOut module (default enabled on Win32)])
3408 if test "${enable_waveout}" != "no"; then
3409   if test "${SYS}" = "mingw32"; then
3410     VLC_ADD_PLUGIN([waveout])
3411     VLC_ADD_LIBS([waveout],[-lwinmm])
3412   fi
3413 fi
3414
3415 dnl
3416 dnl  CoreAudio plugin
3417 dnl
3418 AC_ARG_ENABLE(macosx-audio,
3419   [  --enable-macosx-audio   Mac OS X audio module (default enabled on MacOS X)])
3420 if test "x${enable_macosx_audio}" != "xno" &&
3421   (test "${SYS}" = "darwin" || test "${enable_macosx_audio}" = "yes")
3422 then
3423   AC_CHECK_HEADERS(CoreAudio/CoreAudio.h,
3424     [ VLC_ADD_PLUGIN([auhal])
3425       VLC_ADD_LIBS([auhal],[-Wl,-framework,CoreAudio,-framework,AudioUnit,-framework,AudioToolbox,-framework,Carbon])
3426     ], [ AC_MSG_ERROR([cannot find CoreAudio headers]) ])
3427 fi
3428
3429 dnl
3430 dnl  AudioQueue plugin
3431 dnl
3432 AC_ARG_ENABLE(audioqueue,
3433   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3434 if test "${enable_audioqueue}" = "yes"
3435 then
3436   VLC_ADD_PLUGIN([audioqueue])
3437   VLC_ADD_LIBS([audioqueue], [-Wl,-framework,AudioToolbox,-framework,CoreFoundation])
3438 fi
3439
3440 dnl
3441 dnl  JACK modules
3442 dnl
3443 PKG_ENABLE_MODULES_VLC([JACK], [jack access_jack], [jack], [JACK audio I/O modules],[auto])
3444
3445 dnl
3446 dnl  OpenSLES Android
3447 dnl
3448 AC_ARG_ENABLE(opensles,
3449   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3450 if test "${HAVE_ANDROID}" = "1"; then
3451   if test "${enable_opensles}" = "yes"; then
3452       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3453         [ VLC_ADD_PLUGIN([opensles_android]) ],
3454         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3455   fi
3456 fi
3457
3458 dnl
3459 dnl libsamplerate plugin
3460 dnl
3461 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3462
3463 dnl
3464 dnl  OS/2 KAI plugin
3465 dnl
3466 AC_ARG_ENABLE(kai,
3467   [AS_HELP_STRING([--enable-kai],
3468     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3469   AS_IF([test "$SYS" = "os2"], [
3470     enable_kai="yes"
3471   ])
3472 ])
3473 have_kai="no"
3474 KAI_LIBS=""
3475 AS_IF([test "$enable_kai" != "no"], [
3476   AC_CHECK_HEADERS([kai.h], [
3477     have_kai="yes"
3478     AC_CHECK_LIB(kai, main, [
3479       KAI_LIBS="-lkai"
3480     ])
3481   ])
3482 ])
3483 AC_SUBST(KAI_LIBS)
3484 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3485
3486 dnl
3487 dnl  Interface plugins
3488 dnl
3489
3490 EXTEND_HELP_STRING([Interface plugins:])
3491
3492 dnl
3493 dnl QT
3494 dnl
3495 AC_ARG_ENABLE(qt, [
3496   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3497   AS_IF([test "${SYS}" = "darwin"], [
3498     enable_qt="no"
3499   ])
3500 ])
3501 AS_IF([test "${enable_qt}" != "no"], [
3502   PKG_CHECK_MODULES([QT], [QtCore >= 5 QtWidgets QtGui],, [
3503     PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.6.0],, [
3504       AS_IF([test -n "${enable_qt}"],[
3505         AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3506       ],[
3507         AC_MSG_WARN([${QT_PKG_ERRORS}.])
3508       ])
3509       enable_qt="no"
3510     ])
3511   ])
3512 ])
3513 AS_IF([test "${enable_qt}" != "no"], [
3514   VLC_ADD_PLUGIN([qt4])
3515   VLC_ADD_LIBS([qt4],[${QT_LIBS}])
3516   VLC_ADD_CXXFLAGS([qt4],[${QT_CFLAGS}])
3517   ALIASES="${ALIASES} qvlc"
3518
3519   AC_LANG_PUSH([C++])
3520   VLC_SAVE_FLAGS
3521
3522   AC_MSG_CHECKING([whether Qt uses Xlib])
3523   CPPFLAGS="${CPPFLAGS} ${QT_CFLAGS}"
3524   AC_PREPROC_IFELSE([AC_LANG_SOURCE([
3525 #include <QWidget>
3526 #if !defined (Q_WS_X11)
3527 # error Fail
3528 #endif
3529   ])], [
3530     AC_MSG_RESULT([yes])
3531     VLC_ADD_LIBS([qt4],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3532     VLC_ADD_CXXFLAGS([qt4],[${X_CFLAGS}])
3533   ], [
3534     AC_MSG_RESULT([no])
3535   ])
3536
3537   VLC_RESTORE_FLAGS
3538   AC_LANG_POP([C++])
3539
3540   AS_IF([test "${SYS}" = "mingw32"], [
3541       VLC_ADD_LIBS([qt4],[-lole32])
3542   ])
3543   AS_IF([test "${SYS}" = "darwin" ],[
3544        VLC_ADD_LIBS([qt4], [-Wl,-framework,Cocoa])
3545   ])
3546
3547   QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3548   AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3549   AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3550   AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3551 ])
3552 AM_CONDITIONAL(ENABLE_QT4, [test "$enable_qt" != "no"])
3553
3554 dnl
3555 dnl Simple test for skins2 dependency
3556 dnl
3557 AS_IF([test "$enable_qt" = "no"], [
3558   AS_IF([test "${enable_skins2}" = "yes"], [
3559     AC_MSG_ERROR([The skins2 module depends on the Qt4 interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt4 development package or alternatively you can also configure with: --disable-qt4 --disable-skins2.])
3560   ], [
3561     enable_skins2="no"
3562     AC_MSG_WARN([The skins2 module depends on the Qt4 interface, Qt4 is not built so skins2 is disabled.])
3563   ])
3564 ])
3565
3566 dnl
3567 dnl Skins2 module
3568 dnl
3569 AC_ARG_ENABLE(skins2,
3570   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3571 AS_IF([test "${enable_skins2}" != "no"], [
3572   have_skins_deps="yes"
3573
3574   dnl Win32
3575   AS_IF([test "${SYS}" = "mingw32"], [
3576     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3577     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3578   dnl MacOS
3579   ], [test "${SYS}" = "darwin"], [
3580     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3581     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3582   dnl Linux/Unix
3583   ], [
3584     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3585     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3586     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3587     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3588     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3589   ])
3590
3591   dnl for All OSes
3592   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3593
3594   dnl we need freetype
3595   AS_IF([test "${have_freetype}" != "yes"], [
3596     have_skins_deps="no"
3597   ])
3598
3599   AS_IF([test "${have_skins_deps}" = "no"], [
3600     AS_IF([test "x${enable_skins2}" = "x"], [
3601       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3602     ], [
3603       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3604     ])
3605     enable_skins2="no"
3606   ], [
3607     VLC_ADD_PLUGIN([skins2])
3608     ALIASES="${ALIASES} svlc"
3609     enable_skins2="yes"
3610   ])
3611 ])
3612 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3613
3614 AC_ARG_ENABLE(libtar,
3615   [  --enable-libtar         libtar support for skins2 (default auto)])
3616 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3617   AC_CHECK_HEADERS(libtar.h, [
3618     VLC_ADD_LIBS([skins2],[-ltar])
3619   ])
3620 ])
3621
3622 dnl
3623 dnl  MacOS X gui module
3624 dnl
3625 AC_ARG_ENABLE(macosx,
3626   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3627 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3628 then
3629   VLC_ADD_LIBS([macosx], [-Wl,-framework,Cocoa -Wl,-framework,OpenGL -Wl,-framework,Carbon -Wl,-framework,CoreServices -Wl,-framework,AGL])
3630   VLC_ADD_OBJCFLAGS([macosx], [-fobjc-exceptions] )
3631   VLC_ADD_PLUGIN([macosx])
3632
3633   VLC_ADD_LIBS([macosx], [-Wl,-framework,QTKit -Wl,-framework,IOKit -Wl,-framework,AddressBook -Wl,-framework,WebKit -Wl,-framework,CoreAudio -Wl,-framework,SystemConfiguration])
3634
3635   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3636   then
3637     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3638   fi
3639   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,Sparkle])
3640   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3641
3642   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3643   then
3644     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3645   fi
3646   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,BGHUDAppKit])
3647   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3648 fi
3649 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3650
3651 dnl
3652 dnl  Minimal Mac OS X module
3653 dnl
3654 AC_ARG_ENABLE(minimal-macosx,
3655   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3656 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3657 then
3658   VLC_ADD_LIBS([minimal_macosx], [-Wl,-framework,Cocoa])
3659   VLC_ADD_OBJCFLAGS([minimal_macosx], [-fobjc-exceptions] )
3660   VLC_ADD_PLUGIN([minimal_macosx])
3661 fi
3662 AM_CONDITIONAL(ENABLE_MINIMAL_MACOSX, [test "$enable_minimal_macosx" != "no"])
3663
3664 dnl
3665 dnl  MacOS X dialog provider
3666 dnl
3667 AC_ARG_ENABLE(macosx-dialog-provider,
3668   [  --enable-macosx-dialog-provider Mac OS X dialog module (default enabled on Mac OS X)])
3669 if test "x${enable_macosx_dialog_provider}" != "xno" &&
3670   (test "${SYS}" = "darwin" || test "${enable_macosx_dialog_provider}" = "yes")
3671 then
3672   VLC_ADD_LIBS([macosx_dialog_provider],[-Wl,-framework,Cocoa])
3673   VLC_ADD_PLUGIN([macosx_dialog_provider])
3674 fi
3675 AM_CONDITIONAL(ENABLE_MACOSX_DIALOG_PROVIDER, [test "$enable_macosx_dialog_provider" != "no"])
3676
3677 dnl
3678 dnl  ncurses module
3679 dnl
3680 AC_ARG_ENABLE(ncurses,
3681 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3682 AS_IF([test "${enable_ncurses}" != "no"] ,[
3683   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3684     VLC_ADD_PLUGIN([ncurses])
3685     VLC_ADD_CFLAGS([ncurses],[${NCURSES_CFLAGS}])
3686     VLC_ADD_LIBS([ncurses],[${NCURSES_LIBS}])
3687     ALIASES="${ALIASES} nvlc"
3688   ], [
3689     AS_IF([test -n "${enable_ncurses}"], [
3690       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3691     ])
3692   ])
3693 ])
3694
3695 dnl
3696 dnl  Lirc plugin
3697 dnl
3698 AC_ARG_ENABLE(lirc,
3699   [  --enable-lirc           lirc support (default disabled)])
3700 if test "${enable_lirc}" = "yes"
3701 then
3702   AC_CHECK_HEADER(lirc/lirc_client.h, AC_CHECK_LIB(lirc_client, lirc_init, have_lirc="true", have_lirc="false"),have_lirc="false")
3703   if test "${have_lirc}" = "true"
3704   then
3705     VLC_ADD_PLUGIN([lirc])
3706     VLC_ADD_LIBS([lirc],[-llirc_client])
3707   fi
3708 fi
3709
3710 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3711 dnl
3712 dnl  goom visualization plugin
3713 dnl
3714 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3715
3716 dnl
3717 dnl libprojectM visualization plugin
3718 dnl
3719 AC_ARG_ENABLE(projectm,
3720   [  --enable-projectm       projectM visualization plugin (default enabled)])
3721 AS_IF([test "${enable_projectm}" != "no"],
3722   [
3723     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3724     [
3725       VLC_ADD_PLUGIN([projectm])
3726       VLC_ADD_CXXFLAGS([projectm],[$PROJECTM_CFLAGS])
3727       VLC_ADD_LIBS([projectm],[$PROJECTM_LIBS])
3728       PKG_CHECK_MODULES(PROJECTM2, [libprojectM >= 2.0.0],
3729         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3730         [ AC_MSG_WARN( [Using libprojectM version 1] )
3731       ])
3732     ],[
3733       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3734     ])
3735   ])
3736
3737 dnl
3738 dnl Vovoid VSXu visualization plugin
3739 dnl
3740 AC_ARG_ENABLE(vsxu,
3741   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3742 AS_IF([test "${enable_vsxu}" != "no"],
3743   [
3744     PKG_CHECK_MODULES(VSXU, libvsxu,
3745     [
3746       VLC_ADD_PLUGIN([vsxu])
3747       VLC_ADD_CXXFLAGS([vsxu],[$VSXU_CFLAGS])
3748       VLC_ADD_LIBS([vsxu],[$VSXU_LIBS])
3749     ],[
3750       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3751     ])
3752   ])
3753
3754 dnl
3755 dnl  AtmoLight (homemade Philips Ambilight clone)
3756 dnl
3757 AC_ARG_ENABLE(atmo,
3758 AS_HELP_STRING([--disable-atmo],[AtmoLight (homemade Philips Ambilight clone)
3759                 (default enabled)]),, [enable_atmo="yes"])
3760 AS_IF([test "${enable_atmo}" != no], [
3761   AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "linux"], [
3762     AC_LANG_PUSH(C++)
3763     VLC_ADD_PLUGIN([atmo])
3764     AC_LANG_POP(C++)
3765   ])
3766 ])
3767
3768 AC_ARG_ENABLE(osdmenu,
3769   AS_HELP_STRING([--enable-osdmenu],[OSD menu (default disabled)]),, [
3770   enable_osdmenu="no"
3771 ])
3772 AM_CONDITIONAL(BUILD_OSDMENU, [test "${enable_osdmenu}" != "no"])
3773
3774
3775 EXTEND_HELP_STRING([Service Discovery plugins:])
3776 dnl
3777 dnl  Bonjour services discovery
3778 PKG_ENABLE_MODULES_VLC([BONJOUR], [], [avahi-client >= 0.6], [Bonjour services discovery], [auto])
3779
3780 dnl
3781 dnl  libudev services discovery
3782 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3783
3784 dnl
3785 dnl MTP devices services discovery
3786 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3787
3788 dnl
3789 dnl UPnP Plugin (Intel SDK)
3790 dnl
3791 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3792 VLC_ADD_CXXFLAGS([upnp],[${UPNP_CFLAGS}])
3793
3794 EXTEND_HELP_STRING([Misc options:])
3795
3796 dnl
3797 dnl  libxml2 module
3798 dnl
3799 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3800
3801
3802 dnl
3803 dnl libgcrypt
3804 dnl
3805 AC_ARG_ENABLE(libgcrypt,
3806   [  --disable-libgcrypt     gcrypt support (default enabled)])
3807 AS_IF([test "${enable_libgcrypt}" != "no"], [
3808   AC_CHECK_DECL([GCRYCTL_SET_THREAD_CBS], [
3809     libgcrypt-config --version >/dev/null || \
3810         AC_MSG_ERROR([gcrypt.h present but libgcrypt-config could not be found])
3811     AC_CHECK_LIB(gcrypt, gcry_control, [
3812       have_libgcrypt="yes"
3813       GCRYPT_CFLAGS="`libgcrypt-config --cflags`"
3814       GCRYPT_LIBS="`libgcrypt-config --libs`"
3815     ], [
3816       AC_MSG_ERROR([libgcrypt not found. Install libgcrypt or use --disable-libgcrypt. Have a nice day.])
3817     ], [`libgcrypt-config --libs`])
3818   ], [
3819     AC_MSG_ERROR([libgcrypt version 1.1.94 or higher not found. Install libgcrypt or use --disable-libgcrypt. Have a nice day.])
3820   ], [#include <gcrypt.h>]
3821   )
3822 ])
3823
3824 AC_SUBST(GCRYPT_CFLAGS)
3825 AC_SUBST(GCRYPT_LIBS)
3826 AM_CONDITIONAL([HAVE_GCRYPT], [test "${have_libgcrypt}" = "yes"])
3827
3828 dnl
3829 dnl TLS/SSL
3830 dnl
3831 AC_ARG_ENABLE(gnutls,
3832   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
3833 AS_IF([test "${enable_gnutls}" != "no"], [
3834   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 2.6.6], [
3835     VLC_ADD_PLUGIN([gnutls])
3836   ], [
3837     AS_IF([test -n "${enable_gnutls}"], [
3838       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
3839     ])
3840   ])
3841 ])
3842
3843
3844 dnl
3845 dnl Nokia MCE plugin (Maemo screen unblanking)
3846 dnl
3847 PKG_CHECK_MODULES([MCE], [dbus-1 mce], [VLC_ADD_PLUGIN([mce])], [true])
3848
3849
3850 AS_IF([test -f "/etc/maemo_version"], [
3851   AC_DEFINE([HAVE_MAEMO], 1, [Define to 1 if building for the Maemo platform.])
3852 ])
3853
3854
3855 dnl
3856 dnl Taglib plugin
3857 dnl
3858 AC_ARG_ENABLE(taglib,
3859   [AS_HELP_STRING([--disable-taglib],
3860     [do not use TagLib (default enabled)])])
3861 AS_IF([test "${enable_taglib}" != "no"], [
3862   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.6.1, [
3863     VLC_ADD_PLUGIN([taglib])
3864     VLC_ADD_LIBS([taglib],[$TAGLIB_LIBS -lz])
3865     VLC_ADD_CXXFLAGS([taglib],[$TAGLIB_CFLAGS])
3866   ], [
3867     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
3868 ])
3869
3870
3871 dnl
3872 dnl update checking system
3873 dnl
3874 AC_ARG_ENABLE(update-check,
3875   [  --enable-update-check   update checking system (default disabled)])
3876 if test "${enable_update_check}" = "yes"
3877 then
3878   if test "${have_libgcrypt}" != "yes"
3879   then
3880     AC_MSG_ERROR([libgcrypt is required for update checking system])
3881   fi
3882   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
3883   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
3884   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
3885 fi
3886
3887 dnl
3888 dnl Growl notification plugin
3889 dnl
3890 AC_ARG_ENABLE(growl,
3891   [  --enable-growl          growl notification plugin (default disabled)],,
3892   [enable_growl=no])
3893 AS_IF([test "${enable_growl}" != "no"], [
3894     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
3895       VLC_ADD_PLUGIN([growl])
3896       VLC_ADD_LIBS([growl], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
3897       VLC_ADD_OBJCFLAGS([growl], [-F${CONTRIB_DIR}])
3898       VLC_ADD_OBJCFLAGS([growl], [-fobjc-exceptions] )
3899     ])
3900   ]
3901 )
3902
3903 dnl
3904 dnl Libnotify notification plugin
3905 dnl
3906 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
3907
3908 dnl
3909 dnl media library
3910 dnl
3911 AC_ARG_ENABLE(media-library,
3912     [  --enable-media-library  media library (default disabled)])
3913 AS_IF([test "${enable_media_library}" = "yes"], [
3914   AC_DEFINE([MEDIA_LIBRARY], 1, [Define if you want to use the VLC media library])
3915   VLC_ADD_CPPFLAGS([qt4],"-DMEDIA_LIBRARY")
3916   VLC_ADD_PLUGIN([media_library])
3917
3918 dnl
3919 dnl SQLite
3920 dnl
3921   AS_IF([test "${SYS}" != "darwin"], [
3922     PKG_ENABLE_MODULES_VLC([SQLITE], [], [sqlite3 >= 3.6.0], [sqlite3], [auto])
3923   ], [
3924     AS_IF([test "${enable_sqlite}" != "no"], [
3925       AC_CHECK_HEADERS(sqlite3.h, [
3926         VLC_ADD_PLUGIN([sqlite])
3927         VLC_ADD_LIBS([sqlite], [-lsqlite3])
3928       ], [
3929         AC_MSG_ERROR([sqlite3 is required for the media library])
3930       ])
3931     ])
3932   ])
3933 ])
3934
3935
3936 dnl
3937 dnl  Endianness check
3938 dnl
3939 AC_C_BIGENDIAN
3940 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
3941   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
3942 ], [
3943   DEFS_BIGENDIAN=""
3944 ])
3945 AC_SUBST(DEFS_BIGENDIAN)
3946
3947 dnl
3948 dnl Where to install KDE solid .desktop
3949 dnl
3950 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3951 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3952   KDE4_CONFIG="kde4-config"
3953 ])
3954
3955 AC_ARG_WITH(kde-solid,
3956   AS_HELP_STRING([--with-kde-solid=PATH],
3957                  [KDE Solid actions directory (auto)]),, [
3958
3959 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
3960   with_kde_solid="yes"
3961 fi
3962 ])
3963 soliddatadir=""
3964 AS_IF([test "${with_kde_solid}" != "no"], [
3965   AS_IF([test "${with_kde_solid}" = "yes"], [
3966     kde4datadir="`${KDE4_CONFIG} --install data`"
3967     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
3968     soliddatadir="${kde4datadir}/solid/actions"
3969   ], [
3970     soliddatadir="${with_kde_solid}"
3971   ])
3972 ])
3973 AC_SUBST(soliddatadir)
3974 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
3975
3976 dnl
3977 dnl  DLL loader copied from MPlayer copied from somewhere else (WINE ?)
3978 dnl
3979 loader=false
3980 AC_ARG_ENABLE(loader,
3981   AS_HELP_STRING([--enable-loader],[build DLL loader for ELF i386 platforms
3982           (default disabled)]))
3983 AM_CONDITIONAL(LOADER, [test "${enable_loader}" = "yes"])
3984 AS_IF([test "${enable_loader}" = "yes"],
3985   [ VLC_ADD_PLUGIN([dmo])
3986     VLC_ADD_CPPFLAGS([dmo quicktime ],[-I\\\$(srcdir)/loader])
3987     VLC_ADD_LIBS([dmo quicktime ],[libloader.la])
3988     VLC_ADD_LIBS([dmo quicktime], [-lpthread])
3989   ])
3990
3991 AS_IF([test "${SYS}" = "mingw32"], [VLC_ADD_PLUGIN([dmo]) VLC_ADD_LIBS([dmo],[-lole32 -luuid]) ])
3992
3993 EXTEND_HELP_STRING([Components:])
3994
3995 dnl
3996 dnl  the VLC binary
3997 dnl
3998 AC_ARG_ENABLE(vlc,
3999   [  --enable-vlc            build the VLC media player (default enabled)])
4000 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4001
4002 AC_ARG_ENABLE(macosx-vlc-app,
4003   [  --enable-macosx-vlc-app build the VLC media player (default enabled on Mac OS X)])
4004 AM_CONDITIONAL(BUILD_MACOSX_VLC_APP, [test "${enable_macosx_vlc_app}" != "no" &&
4005     (test "${SYS}" = "darwin" || test "${enable_macosx_vlc_app}" = "yes") ])
4006
4007 dnl
4008 dnl  Stuff used by the program
4009 dnl
4010 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4011 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4012 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4013 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4014 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4015 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4016 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4017 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4018 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4019 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4020 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4021 AC_SUBST(COPYRIGHT_MESSAGE)
4022 AC_SUBST(VERSION_MESSAGE)
4023 AC_SUBST(VERSION_MAJOR)
4024 AC_SUBST(VERSION_MINOR)
4025 AC_SUBST(VERSION_REVISION)
4026 AC_SUBST(VERSION_EXTRA)
4027 AC_SUBST(COPYRIGHT_YEARS)
4028 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4029 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4030 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4031 dnl
4032 dnl  Handle substvars that use $(top_srcdir)
4033 dnl
4034 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4035
4036 dnl
4037 dnl  Configuration is finished
4038 dnl
4039 AC_SUBST(SYS)
4040 AC_SUBST(ARCH)
4041 AC_SUBST(ALIASES)
4042 AC_SUBST(ASM)
4043 AC_SUBST(MOC)
4044 AC_SUBST(RCC)
4045 AC_SUBST(UIC)
4046 AC_SUBST(WINDRES)
4047 AC_SUBST(WINE_SDK_PATH)
4048 AC_SUBST(LIBEXT)
4049 AC_SUBST(AM_CPPFLAGS)
4050 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4051 AC_SUBST(FILE_LIBVLCCORE_DLL)
4052 AC_SUBST(FILE_LIBVLC_DLL)
4053
4054 AC_CONFIG_FILES([
4055   Makefile
4056   doc/Makefile
4057   modules/Makefile
4058   m4/Makefile
4059   po/Makefile.in
4060   share/Makefile
4061   compat/Makefile
4062   src/Makefile
4063   lib/Makefile
4064   bin/Makefile
4065   test/Makefile
4066   modules/access/Makefile
4067   modules/access/rtp/Makefile
4068   modules/access_output/Makefile
4069   modules/audio_filter/Makefile
4070   modules/audio_mixer/Makefile
4071   modules/audio_output/Makefile
4072   modules/codec/Makefile
4073   modules/control/Makefile
4074   modules/demux/Makefile
4075   modules/gui/Makefile
4076   modules/gui/macosx/Makefile
4077   modules/gui/minimal_macosx/Makefile
4078   modules/gui/macosx_dialog_provider/Makefile
4079   modules/gui/qt4/Makefile
4080   modules/gui/skins2/Makefile
4081   modules/lua/Makefile
4082   modules/meta_engine/Makefile
4083   modules/misc/Makefile
4084   modules/media_library/Makefile
4085   modules/mux/Makefile
4086   modules/notify/Makefile
4087   modules/packetizer/Makefile
4088   modules/services_discovery/Makefile
4089   modules/stream_filter/Makefile
4090   modules/stream_out/Makefile
4091   modules/text_renderer/Makefile
4092   modules/video_chroma/Makefile
4093   modules/video_filter/Makefile
4094   modules/video_output/Makefile
4095   modules/visualization/Makefile
4096   modules/mmx/Makefile
4097   modules/sse2/Makefile
4098   modules/altivec/Makefile
4099   modules/arm_neon/Makefile
4100 ])
4101
4102 AM_COND_IF([HAVE_WIN32], [
4103   AC_CONFIG_FILES([
4104     extras/package/win32/NSIS/spad.nsi
4105     extras/package/win32/NSIS/vlc.win32.nsi
4106   ])
4107 ])
4108
4109 AM_COND_IF([HAVE_DARWIN], [
4110   AC_CONFIG_FILES([
4111     extras/package/macosx/Info.plist
4112     extras/package/macosx/Resources/English.lproj/InfoPlist.strings
4113   ])
4114 ])
4115
4116 dnl Generate makefiles
4117 AC_OUTPUT
4118
4119 dnl Do we have to use make or gmake ?
4120 if make --version 2>&1|grep -q GNU
4121 then
4122     # GNU make, all seems good
4123     MAKE=make
4124 else
4125     # Known GNU make alias (on BSD)
4126     MAKE=gmake
4127 fi
4128 dnl Shortcut to nice compile message
4129 if test -n $SHELL; then
4130   SHELL=${CONFIG_SHELL-/bin/sh}
4131 fi
4132 rm -f compile
4133 echo "#! $SHELL
4134 rm -f .error\$\$
4135 ERROR=0
4136 export PATH=\"$PATH\" LANG=C
4137 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| `sed -ne \"s/^top_srcdir *= *//p\" < Makefile`/extras/buildsystem/make.pl
4138 test -f .error\$\$ && ERROR=1
4139 rm -f .error\$\$
4140 exit \$ERROR" >compile
4141 chmod a+x compile
4142
4143 echo "
4144 libvlc configuration
4145 --------------------
4146 version               : ${VERSION}
4147 system                : ${SYS}
4148 architecture          : ${ARCH}
4149 optimizations         : ${enable_optimizations}"
4150 if test "${enable_vlc}" != "no"; then
4151 echo "vlc aliases           :${ALIASES}"
4152 else
4153 echo "build vlc executable  : no"
4154 fi
4155 echo "
4156 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."