| blob | a3758704ac87678a67c9b87f7d59613c60ba7ab0 |
1 dnl Autoconf settings for vlc
3 AC_COPYRIGHT([Copyright 1999-2018 VLC authors and VideoLAN])
5 AC_INIT(vlc, 4.0.0-dev)
6 VERSION_MAJOR=4
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=dev
12 PKGDIR="vlc"
13 AC_SUBST(PKGDIR)
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Otto Chriek"
17 COPYRIGHT_YEARS="1996-2018"
19 AC_CONFIG_SRCDIR(src/libvlc.c)
20 AC_CONFIG_AUX_DIR(autotools)
21 AC_CONFIG_MACRO_DIR(m4)
22 AC_CONFIG_LIBOBJ_DIR(compat)
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
28 AC_CONFIG_HEADERS([config.h])
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
33 dnl
34 dnl Check for tools
35 dnl
36 AC_PROG_CC
37 AC_USE_SYSTEM_EXTENSIONS
38 VLC_PROG_CC_C11
39 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
40 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
41 AH_TOP([
42 #ifndef _REENTRANT
43 # define _REENTRANT
44 #endif
45 ])
46 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
47 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
48 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
50 AC_PROG_CXX
51 AC_PROG_CPP
52 AC_PROG_OBJC
53 AC_PROG_EGREP
54 AC_PROG_MAKE_SET
55 AC_PROG_INSTALL
56 AM_PROG_AS
57 AC_PROG_LEX
58 AC_PROG_YACC
60 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
61 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
62 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
63 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
64 AS_IF([test "$BUILDCC" = "false"], [
65 AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
66 ])
68 dnl Check for compiler properties
69 AC_C_CONST
70 AC_C_INLINE
71 AC_C_RESTRICT
72 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
74 dnl Extend the --help string at the current spot.
75 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
77 dnl Allow binary package maintainer to pass a custom string to avoid
78 dnl cache problem
79 AC_ARG_WITH(binary-version,
80 AS_HELP_STRING([--with-binary-version=STRING],
81 [To avoid plugins cache problem between binary version]),[],[])
82 AS_IF([test -n "${with_binary_version}"],[
83 AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
84 [Binary specific version])
85 ])
87 dnl Prevent clang from accepting unknown flags with a mere warning
88 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
89 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
91 dnl
92 dnl Check the operating system
93 dnl
94 HAVE_WIN64="0"
95 HAVE_IOS="0"
96 HAVE_OSX="0"
97 HAVE_TVOS="0"
99 case "${host_os}" in
100 "")
101 SYS=unknown
102 ;;
103 linux*)
104 SYS=linux
105 ;;
106 bsdi*)
107 SYS=bsdi
108 CFLAGS="${CFLAGS} -pthread"
109 ;;
110 freebsd*)
111 SYS=freebsd
112 CFLAGS="${CFLAGS} -pthread"
113 CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
114 LDFLAGS="${LDFLAGS} -L/usr/local/lib"
115 ac_cv_ld_z_defs=no
116 ;;
117 openbsd*)
118 SYS=openbsd
119 CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
120 LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
121 ;;
122 netbsd*)
123 SYS=netbsd
124 ;;
125 dragonfly*)
126 SYS=dragonfly
127 ;;
128 darwin*)
130 dnl Force gcc "-arch" flag
131 ARCH_flag=""
132 case "${host}" in
133 i?86*)
134 ARCH_flag="-arch i386"
135 ;;
136 ppc64*)
137 ARCH_flag="-arch ppc64"
138 ;;
139 ppc*)
140 ARCH_flag="-arch ppc"
141 ;;
142 x86_64*)
143 ARCH_flag="-arch x86_64"
144 ;;
145 arm*)
146 ac_cv_c_bigendian="no"
147 ac_cv_c_attribute_packed="no"
148 ;;
149 esac
151 SYS=darwin
152 CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
153 CXX="${CXX} -stdlib=libc++ -std=c++11"
154 CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
155 CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
156 OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
157 LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
158 VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
159 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
161 AC_EGREP_CPP(yes,
162 [#import <TargetConditionals.h>
163 #if TARGET_OS_IPHONE
164 yes
165 #endif],
166 [HAVE_IOS="1"],
167 [HAVE_OSX="1"])
169 AC_EGREP_CPP(yes,
170 [#import <TargetConditionals.h>
171 #if TARGET_OS_TV
172 yes
173 #endif],
174 [HAVE_TVOS="1"
175 HAVE_IOS="0"
176 HAVE_OSX="0"
177 ],)
179 dnl
180 dnl Handle Mac OS X SDK flags
181 dnl
182 AC_ARG_WITH(macosx-sdk,
183 [AS_HELP_STRING([--with-macosx-sdk=DIR],
184 [compile using the SDK in DIR])])
185 if test "${with_macosx_sdk}" != "" ; then
186 test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
187 CPP="${CPP} -isysroot ${with_macosx_sdk}"
188 CC="${CC} -isysroot ${with_macosx_sdk}"
189 CXX="${CXX} -isysroot ${with_macosx_sdk}"
190 OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
191 LD="${LD} -syslibroot ${with_macosx_sdk}"
192 fi
193 AC_ARG_WITH(macosx-version-min,
194 [AS_HELP_STRING([--with-macosx-version-min=VERSION],
195 [compile for Mac OS X VERSION and above])])
196 if test "${with_macosx_version_min}" != "" ; then
197 CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
198 CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
199 CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
200 OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
201 LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
202 fi
203 ;;
204 *mingw32* | *cygwin* | *wince* | *mingwce*)
205 dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
206 dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
207 CXXFLAGS="${CXXFLAGS} -static-libgcc"
208 AC_CHECK_TOOL(WINDRES, windres, :)
209 AC_CHECK_TOOL(OBJCOPY, objcopy, :)
210 AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
211 AH_TOP([# define _WIN32_WINNT 0x0601 /* Windows 7 */])
212 AH_TOP([#endif])
213 AC_DEFINE([_WIN32_WINNT], 0x0601, [Define to '0x0601' for Windows 7 APIs.])
214 AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
215 AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
216 AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
217 AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
218 AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
219 AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
220 AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
221 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
222 AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
223 AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
224 AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
226 case "${host_os}" in
227 *mingw32*)
228 SYS=mingw32
229 ;;
230 *cygwin*)
231 dnl Check if we are using the mno-cygwin mode in which case we are
232 dnl actually dealing with a mingw32 compiler.
233 AC_EGREP_CPP(yes,
234 [#ifdef _WIN32
235 yes
236 #endif],
237 SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
238 ;;
239 esac
241 if test "${SYS}" = "mingw32"; then
242 # DEP, ASLR, NO SEH
243 LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
245 AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
246 ac_default_prefix="`pwd`/_win32"
247 DESTDIR="`pwd`/_win32/"
249 dnl
250 dnl NSIS/MSI Installer prefix and WIN64
251 dnl
252 case "${host}" in
253 amd64*|x86_64*)
254 HAVE_WIN64="1"
255 WINDOWS_ARCH="x64"
256 PROGRAMFILES="PROGRAMFILES64"
257 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
258 ;;
259 *)
260 WINDOWS_ARCH="x86"
261 PROGRAMFILES="PROGRAMFILES"
262 ;;
263 esac
264 AC_SUBST(WINDOWS_ARCH)
265 AC_SUBST(PROGRAMFILES)
267 fi
268 ;;
269 *nto*)
270 SYS=nto
271 ;;
272 solaris*)
273 SYS=solaris
274 ;;
275 hpux*)
276 SYS=hpux
277 ;;
278 *os2*)
279 SYS=os2
280 LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
281 AC_LIBOBJ([freeaddrinfo])
282 AC_LIBOBJ([gai_strerror])
283 AC_CHECK_FUNCS([if_nametoindex])
284 ;;
285 *nacl*)
286 SYS=nacl
287 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
288 AC_LIBOBJ([sigwait])
289 AC_LIBOBJ([recvmsg])
290 AC_LIBOBJ([sendmsg])
291 ;;
292 *)
293 SYS="${host_os}"
294 ;;
295 esac
297 dnl WinRT
298 AC_ARG_ENABLE(winstore_app,
299 AS_HELP_STRING([--enable-winstore-app],
300 [Build targetted for Windows Store apps (default disabled)]))
302 vlc_winstore_app=0
303 AS_IF([test "${SYS}" = "mingw32"],[
304 LIBCOM="-lole32"
305 AS_IF([test "${enable_winstore_app}" = "yes"], [
306 vlc_winstore_app=1
307 LIBCOM=""
308 VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
309 AC_LIBOBJ([gai_strerror])
310 ],[])
311 AC_SUBST(LIBCOM)
312 ])
313 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
315 AM_CONDITIONAL(HAVE_LINUX, test "${SYS}" = "linux")
316 AM_CONDITIONAL(HAVE_OS2, test "${SYS}" = "os2")
318 AM_CONDITIONAL(HAVE_DARWIN, test "${SYS}" = "darwin")
319 AM_CONDITIONAL(HAVE_IOS, test "${HAVE_IOS}" = "1")
320 AM_CONDITIONAL(HAVE_OSX, test "${HAVE_OSX}" = "1")
321 AM_CONDITIONAL(HAVE_TVOS, test "${HAVE_TVOS}" = "1")
323 AM_CONDITIONAL(HAVE_NACL, test "${SYS}" = "nacl")
324 AM_CONDITIONAL(HAVE_LIBANL, test "${HAVE_LIBANL}" = "1")
326 AM_CONDITIONAL(HAVE_WIN32, test "${SYS}" = "mingw32")
327 AM_CONDITIONAL(HAVE_WIN64, test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
328 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
329 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
331 dnl
332 dnl Sadly autoconf does not think about testing foo.exe when ask to test
333 dnl for program foo on win32
334 case "${build_os}" in
335 cygwin|msys|mingw32)
336 ac_executable_extensions=".exe"
337 BUILDEXEEXT=".exe"
338 ;;
339 os2*)
340 BUILDEXEEXT=".exe"
341 ;;
342 *)
343 ;;
344 esac
345 AC_SUBST(BUILDEXEEXT)
347 dnl Android is linux, but a bit different
348 AS_IF([test "$SYS" = linux],[
349 AC_MSG_CHECKING([for an Android system])
350 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
351 [[#ifndef __ANDROID__
352 # error Not Android
353 #endif
354 ]],[[;]])
355 ],[
356 HAVE_ANDROID="1"
357 AC_MSG_RESULT([yes])
358 ],[
359 AC_MSG_RESULT([no])
360 ])
361 ])
362 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
364 dnl Tizen (minimum SDK version: 2.3)
365 AS_IF([test "$SYS" = linux],[
366 AC_MSG_CHECKING([for Tizen])
367 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
368 [[#include <tizen.h>
369 ]],[[;]])
370 ],[
371 HAVE_TIZEN="1"
372 AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
373 AC_MSG_RESULT([yes])
374 ],[
375 AC_MSG_RESULT([no])
376 ])
377 ])
378 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
380 dnl
381 dnl Check for the contrib directory
382 dnl
383 AC_ARG_WITH(contrib,
384 [AS_HELP_STRING([--with-contrib[=DIR]],
385 [search for 3rd party libraries in DIR/include and DIR/lib])
386 ])
387 AC_MSG_CHECKING([for 3rd party libraries path])
388 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
389 CONTRIB_DIR="${srcdir}/contrib/${host}"
390 AS_IF([test ! -d "${CONTRIB_DIR}"], [
391 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
392 CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
393 AS_IF([test ! -d "${CONTRIB_DIR}"], [
394 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
395 CONTRIB_DIR=""
396 AC_MSG_RESULT([not found])
397 ])
398 ])
399 ], [
400 AS_IF([test "${with_contrib}" != "no"], [
401 CONTRIB_DIR="${with_contrib}"
402 ], [
403 CONTRIB_DIR=""
404 AC_MSG_RESULT([disabled])
405 ])
406 ])
407 AS_IF([test -n "${CONTRIB_DIR}"], [
408 AS_IF([test -d "${CONTRIB_DIR}/lib"],[
409 CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
410 ], [
411 echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
412 CONTRIB_DIR=""
413 AC_MSG_RESULT([not usable])
414 ])
416 ])
417 AS_IF([test -n "${CONTRIB_DIR}"], [
418 AC_MSG_RESULT([${CONTRIB_DIR}])
419 CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
420 CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
421 CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
422 OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
423 export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
424 LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
426 AS_IF([test -z "$LUAC"], [
427 dnl Old contribs mixed cross-tools and cross-compiled executables
428 AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
429 LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
430 ])
432 dnl Newer contribs follow usual name space rules
433 AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
434 LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
435 ])
436 ])
438 AS_IF([test "${SYS}" = "darwin"], [
439 export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
440 export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
441 ])
442 ], [
443 AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
444 AC_MSG_ERROR([Third party libraries not found!])
445 ])
446 ])
447 AC_SUBST(CONTRIB_DIR)
449 dnl Add extras/tools to the PATH
450 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
451 AS_IF([test -d "${TOOLS_DIR}"], [
452 TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
453 export PATH="${TOOLS_DIR}":$PATH
454 ])
456 dnl
457 dnl Libtool
458 dnl It's very bad, but our former custom system was worst
459 dnl -- Courmisch
460 dnl
462 dnl override platform specific check for dependent libraries
463 dnl otherwise libtool linking of shared libraries will
464 dnl fail on anything other than pass_all.
465 AC_CACHE_VAL(lt_cv_deplibs_check_method,
466 [lt_cv_deplibs_check_method=pass_all])
468 LT_INIT([dlopen win32-dll shared disable-static])
469 LT_LANG([C++])
470 LT_LANG([Windows Resource])
472 DOLT
474 lt_cv_deplibs_check_method=pass_all
476 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
477 AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
478 ])
480 dnl
481 dnl Gettext stuff
482 dnl
483 AM_GNU_GETTEXT_VERSION([0.19.8])
484 AM_GNU_GETTEXT([external], [need-formatstring-macros])
486 dnl
487 dnl Iconv stuff
488 dnl
489 AM_ICONV
491 dnl
492 dnl checks for mingw
493 AS_IF([test "${SYS}" = "mingw32"], [
495 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
496 #if !defined(__MINGW32__)
497 # error Not compiling with mingw
498 #endif
499 ])], [
501 dnl Check for broken versions of mingw-runtime compatability library
502 AC_MSG_CHECKING(for broken mingw-runtime)
503 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
504 #include <_mingw.h>
505 #if defined(__MINGW64_VERSION_MAJOR)
506 # if __MINGW64_VERSION_MAJOR < 5
507 # error Update your mingw-w64! This one is too old.
508 # endif
509 #else
510 # error You cannot compile with Mingw. Use Mingw-w64!
511 #endif
512 ])], [
513 AC_MSG_RESULT([ok])
514 ], [
515 AC_MSG_RESULT([present])
516 AC_MSG_ERROR([LibVLC requires Mingw-w64 version 5.0 or higher!])
517 ])
519 dnl force use of mingw provided c99 *printf over msvcrt
520 CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
522 dnl Check for the need to include the mingwex lib for mingw32
523 VLC_SAVE_FLAGS
524 AC_CHECK_LIB(mingwex,opendir,
525 AC_CHECK_LIB(mingw32,opendir,,
526 [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
527 )
528 VLC_RESTORE_FLAGS
529 ], [
530 AC_MSG_RESULT([Not compiling with mingw])
531 ])
533 dnl Check for fnative-struct or mms-bitfields support for mingw32
534 AX_CHECK_COMPILE_FLAG([-mms-bitfields], [
535 AX_APPEND_FLAG([-mms-bitfields], [CFLAGS])
536 AX_APPEND_FLAG([-mms-bitfields], [CXXFLAGS])
537 # Check for the warning flag without "-Wno-", GCC accepts
538 # -Wno-<anything> for unsupported warnings, which can trigger
539 # other warnings instead.
540 AX_CHECK_COMPILE_FLAG([-Wincompatible-ms-struct], [
541 AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CFLAGS])
542 AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CXXFLAGS])
543 ])
544 ], [
545 AX_CHECK_COMPILE_FLAG([-fnative-struct], [
546 AX_APPEND_FLAG([-fnative-struct], [CFLAGS])
547 AX_APPEND_FLAG([-fnative-struct], [CXXFLAGS])
548 ])
549 ])
550 ])
553 dnl
554 dnl Buggy glibc prevention. Purposedly not cached.
555 dnl See sourceware.org bugs 5058 and 5443.
556 dnl Ubuntu alone has 20 bug numbers for this...
557 dnl
558 AC_MSG_CHECKING(for buggy GNU/libc versions)
559 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
560 #include <limits.h>
561 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
562 && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
563 # error GNU/libc with dcgettext killer bug!
564 #endif
565 ])], [
566 AC_MSG_RESULT([not present])
567 ], [
568 AC_MSG_RESULT([found])
569 AS_IF([test "x${enable_nls}" != "xno"], [
570 AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
571 work-around for this. Check with your distribution vendor on how to update the
572 glibc run-time. Alternatively, build with --disable-nls.])
573 ])
574 ])
576 dnl Plugin compilation stuff
578 VLC_LIBRARY_SUFFIX
580 dnl Check for system libs needed
581 need_libc=false
583 dnl Check for usual libc functions
584 AC_CHECK_FUNCS([accept4 daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty memalign mkostemp mmap open_memstream newlocale openat pipe2 pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime uselocale])
585 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir flockfile fsync getdelim getpid lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy tfind timegm timespec_get strverscmp pathconf])
586 AC_REPLACE_FUNCS([gettimeofday])
587 AC_CHECK_FUNC(fdatasync,,
588 [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
589 ])
591 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
593 dnl mingw64 implements those as static inline, not functions with C linkage
594 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
595 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
596 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
597 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
599 dnl C11 static_assert()
600 AC_MSG_CHECKING([for static_assert in assert.h])
601 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
602 static_assert(1, "The impossible happened.");
603 ])], [
604 AC_MSG_RESULT([yes])
605 AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
606 ], [
607 AC_MSG_RESULT([no])
608 ])
610 # Windows CE does not have strcoll()
611 AC_FUNC_STRCOLL
613 dnl Check for non-standard system calls
614 case "$SYS" in
615 "linux")
616 AC_CHECK_FUNCS([eventfd vmsplice sched_getaffinity recvmmsg memfd_create])
617 ;;
618 "mingw32")
619 AC_CHECK_FUNCS([_lock_file])
620 ;;
621 esac
623 AH_BOTTOM([#include <vlc_fixups.h>])
625 dnl Check for struct pollfd
626 AC_CHECK_TYPES([struct pollfd],,,
627 [#include <sys/types.h>
628 #if HAVE_POLL
629 # include <poll.h>
630 #elif defined (_WIN32)
631 # include <winsock2.h>
632 #endif
633 ])
635 dnl Check for struct timespec
636 AC_CHECK_TYPES([struct timespec],,,
637 [#include <time.h>])
639 dnl Check for max_align_t
640 AC_CHECK_TYPES([max_align_t],,,
641 [#include <stddef.h>])
643 dnl Checks for socket stuff
644 VLC_SAVE_FLAGS
645 SOCKET_LIBS=""
646 AC_SEARCH_LIBS(connect, [socket], [
647 AS_IF([test "$ac_cv_search_connect" != "none required"], [
648 SOCKET_LIBS="$ac_cv_search_connect"
649 ])
650 ], [
651 AS_IF([test "${SYS}" = "mingw32"], [
652 SOCKET_LIBS="-lws2_32 -liphlpapi"
653 ])
654 ])
656 AC_SEARCH_LIBS([inet_pton], [nsl], [
657 AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
658 SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
659 ])
660 ],, [${SOCKET_LIBS}])
662 LIBS="${LIBS} ${SOCKET_LIBS}"
663 AC_LINK_IFELSE([
664 AC_LANG_PROGRAM([#ifdef _WIN32
665 #include <ws2tcpip.h>
666 #include <windows.h>
667 # if _WIN32_WINNT < 0x600
668 # error Needs vista+
669 # endif
670 #else
671 #include <sys/socket.h>
672 #include <arpa/inet.h>
673 #endif], [
674 char dst[[sizeof(struct in_addr)]];
675 inet_pton(AF_INET, "127.0.0.1", dst);
676 ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
677 AC_CHECK_FUNCS([if_nameindex])
678 VLC_RESTORE_FLAGS
679 AC_SUBST(SOCKET_LIBS)
681 dnl Check for socklen_t
682 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
683 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
684 ac_cv_type_socklen_t,
685 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
686 [#include <sys/types.h>
687 #ifdef _WIN32
688 # include <winsock2.h>
689 # include <ws2tcpip.h>
690 #else
691 # include <sys/socket.h>
692 #endif]], [[socklen_t len; len = 0;]])],
693 ac_cv_type_socklen_t=yes,
694 ac_cv_type_socklen_t=no)])
695 AS_IF([test "$ac_cv_type_socklen_t" = no],
696 [AC_DEFINE(socklen_t, int)])
698 dnl Check for struct sockaddr_storage
699 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
700 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
701 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
702 [AC_TRY_COMPILE(
703 [#include <sys/types.h>
704 #if defined( _WIN32 )
705 # include <winsock2.h>
706 #else
707 # include <sys/socket.h>
708 #endif], [struct sockaddr_storage addr;],
709 ac_cv_struct_sockaddr_storage=yes,
710 ac_cv_struct_sockaddr_storage=no)])
711 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
712 AC_DEFINE(sockaddr_storage, sockaddr)
713 AC_DEFINE(ss_family, sa_family)
714 ])
716 dnl FreeBSD has a gnugetopt library for this:
717 GNUGETOPT_LIBS=""
718 AC_CHECK_FUNC(getopt_long,, [
719 AC_CHECK_LIB([gnugetopt],[getopt_long], [
720 GNUGETOPT_LIBS="-lgnugetopt"
721 ])
722 ])
723 AC_SUBST(GNUGETOPT_LIBS)
725 AC_CHECK_LIB(m,cos,[
726 LIBM="-lm"
727 ], [
728 LIBM=""
729 ])
730 AC_SUBST(LIBM)
732 AC_CHECK_LIB(m,lrintf, [
733 AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
734 VLC_ADD_LIBS([skins2],[-lm])
735 ])
736 AC_CHECK_LIB(m,nanf,
737 AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
738 )
739 AC_CHECK_LIB(m,sincos, [
740 AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
741 ], [
742 AC_LIBOBJ([sincos])
743 ])
745 AC_MSG_CHECKING([_Thread_local support])
746 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
747 int main() {}])], [
748 AC_MSG_RESULT([ok])
749 AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
750 ],[ AC_MSG_RESULT([no])])
752 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
753 dnl check for its availability explicitely
754 AC_CHECK_HEADERS([threads.h])
756 AC_CHECK_LIB([anl],[getaddrinfo_a],[
757 AC_DEFINE(HAVE_LIBANL, 1, [Define to 1 if you have the anl library])
758 ])
760 dnl Check for dynamic plugins
761 LIBDL=""
762 have_dynamic_objects="no"
763 VLC_SAVE_FLAGS
764 AC_SEARCH_LIBS(dlsym, [dl svld], [
765 AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
766 LIBDL="$ac_cv_search_dlsym"
767 ])
768 have_dynamic_objects="yes"
769 ])
770 VLC_RESTORE_FLAGS
772 # Windows
773 AS_IF([test "${SYS}" = "mingw32"], [
774 LIBDL=""
775 have_dynamic_objects="yes" #assume we can use shared objects
776 ])
778 AC_ARG_WITH([libfuzzer],
779 [AS_HELP_STRING([--with-libfuzzer=DIR],
780 [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)])],
781 [],
782 [with_libfuzzer=no])
783 AS_VAR_IF(with_libfuzzer, no, [], [
784 enable_shared=no
785 enable_static=yes
786 enable_vlc=no
787 ])
788 AM_CONDITIONAL(HAVE_LIBFUZZER, [test "${with_libfuzzer}" != "no"])
790 AS_IF([test "${enable_shared}" = "no"], [
791 have_dynamic_objects=no
792 ])
793 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
795 AC_SUBST(LIBDL)
797 dnl Check for thread library
798 LIBPTHREAD=""
799 AS_IF([test "${SYS}" != "mingw32"], [
800 VLC_SAVE_FLAGS
801 LIBS=""
802 AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
803 AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
804 LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
805 ])
806 ])
807 VLC_RESTORE_FLAGS
808 ])
809 AC_SUBST(LIBPTHREAD)
811 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
812 AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
813 LIBRT="$ac_cv_search_clock_nanosleep"
814 ])
815 ], [
816 AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
817 AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
818 LIBRT="$ac_cv_search_nanosleep"
819 ])
820 ])
821 ])
822 AC_SUBST(LIBRT)
824 dnl
825 dnl Check for headers
826 dnl
828 dnl POSIX
829 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
830 AC_CHECK_HEADERS([net/if.h], [], [],
831 [
832 #include <sys/types.h>
833 #include <sys/socket.h>
834 ])
835 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
836 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
838 dnl BSD
839 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
841 dnl GNU/Linux
842 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
844 dnl MacOS
845 AC_CHECK_HEADERS([xlocale.h])
847 dnl Check if C++ headers define locale_t
848 AC_LANG_PUSH(C++)
849 AC_CACHE_CHECK([if C++ headers define locale_t],
850 [ac_cv_cxx_locale_t],
851 [ac_cv_cxx_locale_t=no
852 AC_TRY_COMPILE([#include <locale>], [locale_t loc;],
853 [ac_cv_cxx_locale_t=yes])])
854 if test "${ac_cv_cxx_locale_t}" != "no"; then
855 AC_DEFINE(HAVE_CXX_LOCALE_T, 1, Define to 1 if C++ headers define locale_t)
856 fi
857 AC_LANG_POP(C++)
859 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
860 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
861 AC_CHECK_TYPE(ssize_t,, [
862 AC_DEFINE(ssize_t, int)
863 ])
865 dnl It seems that autoconf detects pkg-config only during the first
866 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
867 dnl it is nested within a conditional block, so it was not working right.
868 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
869 AC_ARG_VAR(PKG_CONFIG_PATH,
870 [Paths where to find .pc not at the default location])
871 PKG_PROG_PKG_CONFIG()
873 dnl On some OS we need static linking
874 AS_IF([test -n "${PKG_CONFIG}" ],[
875 AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
876 PKG_CONFIG="${PKG_CONFIG} --static"
877 ])
878 ])
881 dnl
882 dnl Check for zlib.h and -lz if available
883 dnl
884 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
885 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
886 if test "${have_zlib}" = "yes"
887 then
888 VLC_ADD_LIBS([sap],[-lz])
889 fi
892 dnl
893 dnl Domain name i18n support via GNU libidn
894 dnl
895 PKG_CHECK_MODULES([IDN], [libidn], [
896 have_libidn="yes"
897 AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
898 ], [
899 have_libidn="no"
900 ])
903 dnl Check for dbus
904 AC_ARG_ENABLE(dbus,
905 [AS_HELP_STRING([--enable-dbus],
906 [compile D-Bus message bus support (default enabled)])])
907 have_dbus="no"
908 AS_IF([test "${enable_dbus}" != "no"], [
909 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
910 have_dbus="yes"
911 ], [
912 AS_IF([test -n "${enable_dbus}"], [
913 AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
914 ], [
915 AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
916 ])
917 ])
918 ])
919 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
922 dnl Check for systemd
923 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
924 have_systemd="yes"
925 ], [
926 AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
927 ])
928 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
931 EXTEND_HELP_STRING([Optimization options:])
932 dnl
933 dnl Compiler warnings
934 dnl
936 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CFLAGS])
937 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CXXFLAGS])
939 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local -Wmultistatement-macros], [CFLAGS])
940 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
942 dnl
943 dnl Debugging mode
944 dnl
945 AC_ARG_ENABLE(debug,
946 [AS_HELP_STRING([--enable-debug],
947 [build with run-time assertions (default disabled)])],,
948 [enable_debug="no"])
949 AH_TEMPLATE(NDEBUG,
950 [Define to 1 if debug code should NOT be compiled])
951 AS_IF([test "${enable_debug}" != "no"], [
952 AC_CHECK_HEADERS([valgrind/valgrind.h])
953 ], [
954 AC_DEFINE(NDEBUG)
955 ])
957 dnl
958 dnl Profiling
959 dnl
960 AC_ARG_ENABLE(gprof,
961 [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
962 [enable_gprof="no"])
963 AS_IF([test "${enable_gprof}" != "no"], [
964 CFLAGS="${CFLAGS} -pg"
965 CXXFLAGS="${CXXFLAGS} -pg"
966 OBJCFLAGS="${OBJCFLAGS} -pg"
967 LDFLAGS="${LDFLAGS} -pg"
968 ])
970 AC_ARG_ENABLE(cprof,
971 [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
972 [enable_cprof="no"])
973 AS_IF([test "${enable_gprof}" != "no"], [
974 CFLAGS="${CFLAGS} -finstrument-functions"
975 CXXFLAGS="${CXXFLAGS} -finstrument-functions"
976 OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
977 LDFLAGS="${LDFLAGS} -finstrument-functions"
978 ])
980 dnl
981 dnl Test coverage
982 dnl
983 AC_ARG_ENABLE(coverage,
984 [AS_HELP_STRING([--enable-coverage],
985 [build for test coverage (default disabled)])],,
986 [enable_coverage="no"])
987 AS_IF([test "${enable_coverage}" != "no"], [
988 CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
989 CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
990 LDFLAGS="-lgcov ${LDFLAGS}"
991 ])
993 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
994 VLC_SAVE_FLAGS
995 CFLAGS="${CFLAGS} -fvisibility=hidden"
996 CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
997 OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
998 AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
999 [ac_cv_c_visibility_hidden], [
1000 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1001 ac_cv_c_visibility_hidden=yes
1002 ], [
1003 ac_cv_c_visibility_hidden=no
1004 ])
1005 ])
1006 AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1007 ])
1009 dnl
1010 dnl Sanitizer flags
1011 dnl
1012 AC_ARG_WITH([sanitizer],
1013 [AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1014 [build with sanitizer flags (default disabled)])],
1015 [],
1016 [with_sanitizer=no])
1018 AS_VAR_IF(with_sanitizer, no, [], [
1019 AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1020 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1021 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1022 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1023 ], [
1024 AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1025 ])
1026 AX_APPEND_FLAG([-g])
1027 AX_APPEND_FLAG([-g], [CXXFLAGS])
1029 AS_IF([test -z "${with_sanitizer##*address*}" ], [
1030 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer])
1031 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer], [CXXFLAGS])
1032 ])
1033 AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1034 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1035 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1036 ])
1037 AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1038 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1039 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1040 ])
1041 ])
1043 dnl
1044 dnl Enable/disable optimizations
1045 dnl
1046 AC_ARG_ENABLE(optimizations,
1047 [AS_HELP_STRING([--disable-optimizations],
1048 [disable compiler optimizations (default enabled)])],,
1049 [enable_optimizations="yes"])
1051 dnl Check for various optimization flags
1052 AS_IF([test "${enable_optimizations}" != "no"], [
1054 dnl -O3 only in production builds
1055 AS_IF([test "${enable_debug}" = "no"], [
1056 VLC_SAVE_FLAGS
1057 CFLAGS="${CFLAGS} -O3"
1058 CXXFLAGS="${CXXFLAGS} -O3"
1059 OBJCFLAGS="${OBJCFLAGS} -O3"
1060 AC_CACHE_CHECK([if $CC accepts -O3], [ac_cv_c_o3], [
1061 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1062 ac_cv_c_o3=yes
1063 ], [
1064 ac_cv_c_o3=no
1065 ])
1066 ])
1067 AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1068 ])
1070 dnl Check for fast maths
1071 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1072 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1074 AH_BOTTOM([
1075 #if defined(_MSC_VER) && !defined(__clang__)
1076 # pragma fenv_access(off)
1077 # pragma fp_contract(on)
1078 #elif defined(__GNUC__)
1079 /* Not supported so far */
1080 #else
1081 # pragma STDC FENV_ACCESS OFF
1082 # pragma STDC FP_CONTRACT ON
1083 #endif
1084 ])
1086 dnl Check for -funroll-loops
1087 VLC_SAVE_FLAGS
1088 CFLAGS="${CFLAGS} -funroll-loops"
1089 CXXFLAGS="${CXXFLAGS} -funroll-loops"
1090 OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1091 AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1092 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1093 ac_cv_c_unroll_loops=yes
1094 ], [
1095 ac_cv_c_unroll_loops=no
1096 ])
1097 ])
1098 AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1100 AS_IF([test "$enable_debug" = "no"], [
1101 dnl Check for -fomit-frame-pointer
1102 VLC_SAVE_FLAGS
1103 CFLAGS="${CFLAGS} -fomit-frame-pointer"
1104 CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1105 OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1106 AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1107 [ac_cv_c_omit_frame_pointer], [
1108 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1109 ac_cv_c_omit_frame_pointer=yes
1110 ], [
1111 ac_cv_c_omit_frame_pointer=no
1112 ])
1113 ])
1114 AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1115 ])
1117 ])
1119 AC_ARG_ENABLE(ssp, [
1120 AS_HELP_STRING([--disable-ssp],
1121 [disable stack smashing protection (default enabled for optimized builds)])
1122 ],,[enable_ssp="yes"])
1124 AS_IF([test "${enable_ssp}" != "no" -a "${enable_optimizations}" != "no"], [
1125 VLC_SAVE_FLAGS
1126 AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1127 AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1128 dnl Win32 requires linking to ssp for stack-protection
1129 AS_IF([test "${SYS}" = "mingw32"], [
1130 LDFLAGS="${LDFLAGS} -lssp"
1131 dnl library for Crypt/BCrypt APIs
1132 AS_IF([test "${vlc_winstore_app}" != 1],
1133 [LDFLAGS="${LDFLAGS} -ladvapi32"],
1134 [LDFLAGS="${LDFLAGS} -lbcrypt"])
1135 AC_CACHE_CHECK([if linker supports stack protectors], [ac_cv_ld_ssp], [
1136 AC_TRY_LINK([#include <stdio.h>],[char buf[100]; fgets(buf, sizeof(buf), stdin);], [
1137 ac_cv_ld_ssp="yes"
1138 ], [
1139 ac_cv_ld_ssp="no"
1140 ])
1141 ])
1142 AS_IF([test "${ac_cv_ld_ssp}" = "no"], [VLC_RESTORE_FLAGS])
1143 ])
1144 ])
1146 VLC_SAVE_FLAGS
1147 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1148 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1149 AC_TRY_LINK([],, [
1150 ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1151 ], [
1152 ac_cv_ld_bsymbolic=""
1153 ])
1154 ])
1155 VLC_RESTORE_FLAGS
1156 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1157 AC_SUBST(SYMBOLIC_LDFLAGS)
1159 VLC_SAVE_FLAGS
1160 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1161 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1162 AC_TRY_LINK([],, [
1163 ac_cv_ld_z_defs="yes"
1164 ], [
1165 ac_cv_ld_z_defs="no"
1166 ])
1167 ])
1168 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1170 dnl Check for __attribute__((packed))
1171 AC_CACHE_CHECK([for __attribute__((packed))],
1172 [ac_cv_c_attribute_packed],
1173 [ac_cv_c_attribute_packed=no
1174 AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1175 [ac_cv_c_attribute_packed=yes])])
1176 if test "${ac_cv_c_attribute_packed}" != "no"; then
1177 AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1178 fi
1180 dnl
1181 dnl Check the CPU
1182 dnl
1183 case "${host_cpu}" in
1184 "")
1185 ARCH=unknown
1186 ;;
1187 armv*)
1188 ARCH="arm"
1189 host_cpu="arm"
1190 ;;
1191 *)
1192 ARCH="${host_cpu}"
1193 ;;
1194 esac
1196 dnl Check for backtrace() support
1197 AC_CHECK_HEADERS(execinfo.h)
1198 AC_CHECK_FUNCS(backtrace)
1200 dnl
1201 dnl default modules
1202 dnl
1203 ALIASES="${ALIASES} cvlc rvlc"
1205 dnl
1206 dnl Accelerated modules
1207 dnl
1209 dnl Check for fully working MMX intrinsics
1210 dnl We need support for -mmmx, we need <mmintrin.h>, and we also need a
1211 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1212 AC_ARG_ENABLE(mmx,
1213 [AS_HELP_STRING([--disable-mmx],
1214 [disable MMX optimizations (default auto)])],,[
1215 case "${host_cpu}" in
1216 i?86|x86_64)
1217 enable_mmx="yes"
1218 ;;
1219 *)
1220 enable_mmx="no"
1221 ;;
1222 esac
1223 ])
1224 have_mmx="no"
1225 have_mmxext="no"
1226 AS_IF([test "${enable_mmx}" != "no"], [
1227 ARCH="${ARCH} mmx"
1228 VLC_SAVE_FLAGS
1229 CFLAGS="${CFLAGS} -mmmx"
1230 AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1231 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1232 [#include <mmintrin.h>
1233 #include <stdint.h>
1234 uint64_t frobzor;]], [
1235 [__m64 a, b, c;
1236 a = b = c = (__m64)frobzor;
1237 a = _mm_slli_pi16(a, 3);
1238 a = _mm_adds_pi16(a, b);
1239 c = _mm_srli_pi16(c, 8);
1240 c = _mm_slli_pi16(c, 3);
1241 b = _mm_adds_pi16(b, c);
1242 a = _mm_unpacklo_pi8(a, b);
1243 frobzor = (uint64_t)a;]])], [
1244 ac_cv_c_mmx_intrinsics=yes
1245 ], [
1246 ac_cv_c_mmx_intrinsics=no
1247 ])
1248 ])
1249 VLC_RESTORE_FLAGS
1250 AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1251 AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1252 ])
1254 VLC_SAVE_FLAGS
1255 CFLAGS="${CFLAGS} -mmmx"
1256 AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1257 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1258 void *p;
1259 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1260 ]])
1261 ], [
1262 ac_cv_mmx_inline=yes
1263 ], [
1264 ac_cv_mmx_inline=no
1265 ])
1266 ])
1267 AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1268 AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1269 have_mmx="yes"
1270 ])
1272 AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1273 [ac_cv_mmxext_inline], [
1274 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1275 void *p;
1276 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1277 ]])
1278 ], [
1279 ac_cv_mmxext_inline=yes
1280 ], [
1281 ac_cv_mmxext_inline=no
1282 ])
1283 ])
1284 VLC_RESTORE_FLAGS
1285 AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1286 AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1287 have_mmxext="yes"
1288 ])
1289 ])
1290 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1291 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1293 dnl Check for fully workin SSE2 intrinsics
1294 dnl We need support for -mmmx, we need <emmintrin.h>, and we also need a
1295 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1296 AC_ARG_ENABLE(sse,
1297 [AS_HELP_STRING([--disable-sse],
1298 [disable SSE (1-4) optimizations (default auto)])],, [
1299 case "${host_cpu}" in
1300 i?86|x86_64)
1301 enable_sse=yes
1302 ;;
1303 *)
1304 enable_sse=no
1305 ;;
1306 esac
1307 ])
1308 have_sse2="no"
1309 AS_IF([test "${enable_sse}" != "no"], [
1310 ARCH="${ARCH} sse sse2"
1312 VLC_SAVE_FLAGS
1313 CFLAGS="${CFLAGS} -msse2"
1314 AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1315 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1316 [#include <emmintrin.h>
1317 #include <stdint.h>
1318 uint64_t frobzor;]], [
1319 [__m128i a, b, c;
1320 a = b = c = _mm_set1_epi64((__m64)frobzor);
1321 a = _mm_slli_epi16(a, 3);
1322 a = _mm_adds_epi16(a, b);
1323 c = _mm_srli_epi16(c, 8);
1324 c = _mm_slli_epi16(c, 3);
1325 b = _mm_adds_epi16(b, c);
1326 a = _mm_unpacklo_epi8(a, b);
1327 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1328 ac_cv_c_sse2_intrinsics=yes
1329 ], [
1330 ac_cv_c_sse2_intrinsics=no
1331 ])
1332 ])
1333 VLC_RESTORE_FLAGS
1334 AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1335 AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1336 ])
1338 VLC_SAVE_FLAGS
1339 CFLAGS="${CFLAGS} -msse"
1340 AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1341 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1342 void *p;
1343 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1344 ]])
1345 ], [
1346 ac_cv_sse_inline=yes
1347 ], [
1348 ac_cv_sse_inline=no
1349 ])
1350 ])
1352 AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1353 AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1354 ])
1356 AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1357 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1358 void *p;
1359 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1360 ]])
1361 ], [
1362 ac_cv_sse2_inline=yes
1363 ], [
1364 ac_cv_sse2_inline=no
1365 ])
1366 ])
1367 AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1368 AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1369 have_sse2="yes"
1370 ])
1372 # SSE3
1373 AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1374 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1375 void *p;
1376 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1377 ]])
1378 ], [
1379 ac_cv_sse3_inline=yes
1380 ], [
1381 ac_cv_sse3_inline=no
1382 ])
1383 ])
1385 AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1386 AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1387 # SSSE3
1388 AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1389 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1390 void *p;
1391 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1392 ]])
1393 ], [
1394 ac_cv_ssse3_inline=yes
1395 ], [
1396 ac_cv_ssse3_inline=no
1397 ])
1398 ])
1400 AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1401 AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1403 # SSE4.1
1404 AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1405 [ac_cv_sse4_1_inline], [
1406 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1407 void *p;
1408 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1409 ]])
1410 ], [
1411 ac_cv_sse4_1_inline=yes
1412 ], [
1413 ac_cv_sse4_1_inline=no
1414 ])
1415 ])
1417 AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1418 AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1420 # SSE4.2
1421 AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1422 [ac_cv_sse4_2_inline], [
1423 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1424 void *p;
1425 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1426 ]])
1427 ], [
1428 ac_cv_sse4_2_inline=yes
1429 ], [
1430 ac_cv_sse4_2_inline=no
1431 ])
1432 ])
1434 AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1435 AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1437 # SSE4A
1438 AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1439 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1440 void *p;
1441 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1442 ]])
1443 ], [
1444 ac_cv_sse4a_inline=yes
1445 ], [
1446 ac_cv_sse4a_inline=no
1447 ])
1448 ])
1449 VLC_RESTORE_FLAGS
1450 AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1451 AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1452 ])
1453 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1455 VLC_SAVE_FLAGS
1456 CFLAGS="${CFLAGS} -mmmx"
1457 have_3dnow="no"
1458 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1459 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1460 void *p;
1461 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1462 ]])
1463 ], [
1464 ac_cv_3dnow_inline=yes
1465 ], [
1466 ac_cv_3dnow_inline=no
1467 ])
1468 ])
1469 VLC_RESTORE_FLAGS
1470 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1471 AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1472 [Define to 1 if 3D Now! inline assembly is available.])
1473 have_3dnow="yes"
1474 ])
1475 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1478 AC_ARG_ENABLE(neon,
1479 [AS_HELP_STRING([--disable-neon],
1480 [disable NEON optimizations (default auto)])],, [
1481 AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1482 ])
1483 AS_IF([test "${enable_neon}" != "no"], [
1484 VLC_SAVE_FLAGS
1485 CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1486 AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1487 AC_COMPILE_IFELSE([
1488 AC_LANG_PROGRAM(,[[
1489 asm volatile("vqmovun.s64 d0, q1":::"d0");
1490 ]])
1491 ], [
1492 ac_cv_arm_neon="yes"
1493 ], [
1494 ac_cv_arm_neon="no"
1495 ])
1496 ])
1497 VLC_RESTORE_FLAGS
1498 ])
1499 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1501 AC_ARG_ENABLE(arm64,
1502 [AS_HELP_STRING([--disable-arm64],
1503 [disable arm 64-bit optimizations (default auto)])],, [
1504 AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1505 ])
1506 AS_IF([test "${enable_arm64}" != "no"], [
1507 AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1508 AC_COMPILE_IFELSE([
1509 AC_LANG_PROGRAM(,[[
1510 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1511 ]])
1512 ], [
1513 ac_cv_arm64="yes"
1514 ], [
1515 ac_cv_arm64="no"
1516 ])
1517 ])
1518 ])
1519 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1522 AC_ARG_ENABLE(altivec,
1523 [AS_HELP_STRING([--disable-altivec],
1524 [disable AltiVec optimizations (default auto)])],, [
1525 AS_CASE("${host_cpu}", [powerpc*],
1526 [enable_altivec=yes], [enable_altivec=no])
1527 ])
1528 have_altivec="no"
1529 ALTIVEC_CFLAGS=""
1530 AS_IF([test "${enable_altivec}" = "yes"], [
1531 ARCH="${ARCH} altivec";
1532 VLC_SAVE_FLAGS
1533 AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1534 [ac_cv_altivec_inline],
1535 [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1536 ac_cv_altivec_inline="yes",
1537 [CFLAGS="${CFLAGS} -Wa,-maltivec"
1538 AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1539 [ac_cv_altivec_inline="-Wa,-maltivec"],
1540 ac_cv_altivec_inline=no)
1541 ])])
1542 VLC_RESTORE_FLAGS
1543 AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1544 AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1545 [Define to 1 if AltiVec inline assembly is available.])
1546 AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1547 ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1548 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1549 ])
1550 have_altivec="yes"
1551 ])
1553 VLC_SAVE_FLAGS
1554 AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1555 [ac_cv_c_altivec], [
1556 CFLAGS="${CFLAGS} -maltivec"
1557 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1558 [#include <altivec.h>]], [
1559 [vec_ld(0, (unsigned char *)0);]])], [
1560 ac_cv_c_altivec="-maltivec"
1561 ], [
1562 ac_cv_c_altivec="no"
1563 ])
1564 ])
1565 VLC_RESTORE_FLAGS
1566 AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1567 CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1568 AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1569 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1570 ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1571 VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1572 have_altivec="yes"
1573 ])
1574 AC_CHECK_HEADERS(altivec.h)
1576 VLC_SAVE_FLAGS
1577 LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1578 AC_CACHE_CHECK([if linker needs -framework vecLib],
1579 [ac_cv_ld_altivec],
1580 [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1581 VLC_RESTORE_FLAGS
1582 AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1583 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1584 ])
1585 ])
1586 AC_SUBST(ALTIVEC_CFLAGS)
1587 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1589 dnl
1590 dnl Memory usage
1591 dnl
1592 AC_ARG_ENABLE(optimize-memory,
1593 [AS_HELP_STRING([--enable-optimize-memory],
1594 [optimize memory usage over performance])])
1595 if test "${enable_optimize_memory}" = "yes"; then
1596 AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1597 fi
1599 dnl
1600 dnl Allow running as root (useful for people running on embedded platforms)
1601 dnl
1602 AC_ARG_ENABLE(run-as-root,
1603 [AS_HELP_STRING([--enable-run-as-root],
1604 [allow running VLC as root (default disabled)])])
1605 AS_IF([test "${enable_run_as_root}" = "yes"],[
1606 AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1607 [Define to 1 to allow running VLC as root (uid 0).])
1608 ])
1610 dnl
1611 dnl Stream output
1612 dnl
1613 AC_ARG_ENABLE(sout,
1614 [AS_HELP_STRING([--disable-sout],
1615 [disable streaming output (default enabled)])])
1616 AS_IF([test "${enable_sout}" != "no"], [
1617 AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1618 ])
1619 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1621 dnl Lua modules
1622 AC_ARG_ENABLE(lua,
1623 [AS_HELP_STRING([--disable-lua],
1624 [disable LUA scripting support (default enabled)])])
1625 if test "${enable_lua}" != "no"
1626 then
1627 PKG_CHECK_MODULES(LUA, lua5.2,
1628 [ have_lua=yes ],
1629 [
1630 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1632 PKG_CHECK_MODULES(LUA, lua5.1,
1633 [ have_lua=yes ],
1634 [
1635 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1636 PKG_CHECK_MODULES(LUA, lua >= 5.1,
1637 [ have_lua=yes ],
1638 [
1639 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1640 have_lua=yes
1641 AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1642 [],
1643 [ have_lua=no ] )
1644 AC_CHECK_LIB( lua5.2 , luaL_newstate,
1645 [LUA_LIBS="-llua5.2"],
1646 AC_CHECK_LIB( lua5.1 , luaL_newstate,
1647 [LUA_LIBS="-llua5.1"],
1648 AC_CHECK_LIB( lua51 , luaL_newstate,
1649 [LUA_LIBS="-llua51"],
1650 AC_CHECK_LIB( lua , luaL_newstate,
1651 [LUA_LIBS="-llua"],
1652 [ have_lua=no
1653 ], [-lm])
1654 )))
1655 ])
1656 ])
1657 ])
1658 if test "x${have_lua}" != "xyes" ; then
1659 AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1660 fi
1661 AC_ARG_VAR([LUAC], [LUA byte compiler])
1662 AS_IF([test -z "$LUAC"], [
1663 AC_CHECK_TOOL(LUAC, [luac], [false])
1664 ])
1665 AS_IF([test "${LUAC}" = "false"], [
1666 AC_MSG_ERROR([Could not find the LUA byte compiler.])
1667 ])
1668 AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1669 AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1670 ])
1671 fi
1672 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1675 dnl
1676 dnl VideoLAN manager
1677 dnl
1678 AC_ARG_ENABLE(vlm,
1679 [AS_HELP_STRING([--disable-vlm],
1680 [disable the stream manager (default enabled)])],,
1681 [enable_vlm="${enable_sout}"])
1682 AS_IF([test "${enable_vlm}" != "no"], [
1683 AS_IF([test "${enable_sout}" = "no"], [
1684 AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1685 ])
1686 AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1687 ])
1688 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1691 dnl
1692 dnl Addons manager storage and repositories modules
1693 dnl
1694 AC_ARG_ENABLE(addonmanagermodules,
1695 [AS_HELP_STRING([--disable-addonmanagermodules],
1696 [disable the addons manager modules (default enabled)])])
1697 if test "${enable_addonmanagermodules}" != "no"
1698 then
1699 AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1700 fi
1701 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1704 dnl
1705 dnl Input plugins
1706 dnl
1708 EXTEND_HELP_STRING([Input plugins:])
1710 dnl
1711 dnl libarchive access module
1712 dnl
1713 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1715 dnl
1716 dnl live555 input
1717 dnl
1718 AC_ARG_ENABLE(live555,
1719 [AS_HELP_STRING([--enable-live555],
1720 [enable RTSP input through live555 (default enabled)])])
1722 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1723 PKG_CHECK_MODULES(LIVE555, live555, [
1724 VLC_ADD_PLUGIN([live555])
1725 VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1726 VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1727 ], [
1728 AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1730 AC_LANG_PUSH(C++)
1731 VLC_SAVE_FLAGS
1733 dnl detect include paths
1734 AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1735 CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1736 ], [
1737 AS_IF([test "${SYS}" != "os2"], [
1738 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1739 CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1740 ], [
1741 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1742 CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1743 LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1744 ])
1745 ])
1747 dnl CPP Flags
1748 AS_IF([test "${SYS}" = "solaris"], [
1749 CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1750 ])
1751 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1752 LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1754 dnl version check
1755 AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1756 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1757 [#include <liveMedia_version.hh>
1758 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1759 # error BOOM
1760 #endif]])
1761 ], [
1762 ac_cv_live555="yes"
1763 ], [
1764 ac_cv_live555="no"
1765 ])
1766 ])
1768 AS_IF([test "$ac_cv_live555" = "no"], [
1769 AC_MSG_WARN([live555 is missing or its installed version is too old:
1770 Version 2011.12.23 or later is required to proceed.
1771 You can get an updated one from http://www.live555.com/liveMedia .])
1772 AS_IF([test -n "${enable_live555}"], [
1773 AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1774 ])
1775 ], [
1776 other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1777 other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1778 AS_IF([test "${SYS}" = "mingw32"], [
1779 # add ws2_32 for closesocket, select, recv
1780 other_libs="$other_libs -lws2_32"
1781 ])
1783 dnl We need to check for pic because live555 don't provide shared libs
1784 dnl and we want to build a plugins so we need -fPIC on some arch.
1785 VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1786 VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1787 AC_CHECK_LIB(liveMedia_pic, main, [
1788 VLC_ADD_PLUGIN([live555])
1789 VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1790 ],[
1791 AC_CHECK_LIB(liveMedia, main, [
1792 VLC_ADD_PLUGIN([live555])
1793 VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1794 ],[],[${other_libs}])
1795 ],[${other_libs_pic}])
1796 ])
1797 VLC_RESTORE_FLAGS
1798 AC_LANG_POP(C++)
1799 ])
1800 ])
1802 dnl
1803 dnl IIDC and DV FireWire input modules
1804 dnl
1805 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1806 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1808 dnl
1809 dnl - linsys modules: access module check for libzvbi
1810 dnl
1811 AC_ARG_ENABLE(linsys,
1812 [AS_HELP_STRING([--enable-linsys],
1813 [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1814 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1815 VLC_ADD_PLUGIN([linsys_hdsdi])
1816 PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1817 VLC_ADD_PLUGIN([linsys_sdi])
1818 ], [
1819 AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1820 ])
1821 ])
1823 dnl
1824 dnl dvdread module: check for libdvdread
1825 dnl
1826 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1828 dnl
1829 dnl libdvdnav plugin
1830 dnl
1831 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1832 AS_IF([test "${enable_dvdnav}" != "no"], [
1833 AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1834 AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1835 AC_MSG_RESULT(yes)
1836 AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1837 ],[
1838 AC_MSG_RESULT(no)
1839 ])
1840 ])
1842 dnl
1843 dnl Blu-ray Disc Support with libbluray
1844 dnl
1845 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1847 dnl
1848 dnl OpenCV wrapper and example filters
1849 dnl
1850 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1853 dnl
1854 dnl libsmbclient plugin
1855 dnl
1856 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smbc], [smbclient], (SMB/CIFS support), [auto])
1858 dnl
1859 dnl liBDSM access module
1860 dnl
1861 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1863 dnl
1864 dnl sftp access support
1865 dnl
1866 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1868 dnl
1869 dnl nfs access support
1870 dnl
1871 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1873 dnl
1874 dnl Video4Linux 2
1875 dnl
1876 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1877 [disable Video4Linux version 2 (default auto)])])
1878 have_v4l2="no"
1879 AS_IF([test "$enable_v4l2" != "no"], [
1880 AC_CHECK_HEADERS([linux/videodev2.h], [
1881 have_v4l2="yes"
1882 ])
1883 ])
1884 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1886 dnl
1887 dnl special access module for Blackmagic SDI cards
1888 dnl
1889 AC_ARG_ENABLE(decklink,
1890 [AS_HELP_STRING([--disable-decklink],
1891 [disable Blackmagic DeckLink SDI input (default auto)])])
1892 AC_ARG_WITH(decklink_sdk,
1893 [AS_HELP_STRING[--with-decklink-sdk=DIR],
1894 [ location of Blackmagic DeckLink SDI SDK])])
1895 have_decklink=no
1896 if test "${enable_decklink}" != "no"
1897 then
1898 if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1899 then
1900 VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1901 fi
1902 VLC_SAVE_FLAGS
1903 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1904 AC_LANG_PUSH(C++)
1905 AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1906 have_decklink=yes
1907 ], [
1908 AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1909 ])
1910 AC_LANG_POP(C++)
1911 VLC_RESTORE_FLAGS
1912 fi
1913 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1916 dnl
1917 dnl Built-in CD-DA and VCD module
1918 dnl
1919 AC_ARG_ENABLE(vcd,
1920 [AS_HELP_STRING([--disable-vcd],
1921 [disable built-in VCD and CD-DA support (default enabled)])])
1923 AC_ARG_ENABLE(libcddb,
1924 [AS_HELP_STRING([--disable-libcddb],
1925 [disable CDDB for Audio CD (default enabled)])])
1927 if test "${enable_vcd}" != "no"
1928 then
1929 AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1930 AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1931 AC_MSG_RESULT(yes)
1932 VLC_ADD_PLUGIN([vcd cdda])
1933 ],[
1934 AC_MSG_RESULT(no)
1935 ])
1937 AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1938 AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1939 AC_MSG_RESULT(yes)
1940 VLC_ADD_PLUGIN([vcd cdda])
1941 AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1942 ],[
1943 AC_MSG_RESULT(no)
1944 ])
1946 AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1947 AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1948 AC_MSG_RESULT(yes)
1949 VLC_ADD_PLUGIN([vcd cdda])
1950 AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1951 ],[
1952 AC_MSG_RESULT(no)
1953 ])
1955 if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1956 then
1957 VLC_ADD_PLUGIN([vcd cdda])
1958 fi
1960 if test "$enable_libcddb" != "no"; then
1961 PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1962 HAVE_LIBCDDB=yes
1963 AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1964 VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1965 VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1966 ],:
1967 [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1968 HAVE_LIBCDDB=no])
1969 fi
1970 fi
1972 dnl
1973 dnl Linux DVB
1974 dnl
1975 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1976 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1977 [#include <linux/dvb/version.h>
1978 #if (DVB_API_VERSION < 5)
1979 # error Linux DVB API v3.2 and older are not supported.
1980 #endif
1981 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1982 # error Linux DVB API v5.0 is unsupported. Please update.
1983 #endif
1984 ]])], [
1985 ac_cv_linux_dvb_5_1=yes
1986 ], [
1987 ac_cv_linux_dvb_5_1=no
1988 ])])
1989 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1991 dnl
1992 dnl Screen capture module
1993 dnl
1994 AC_ARG_ENABLE(screen,
1995 [AS_HELP_STRING([--enable-screen],
1996 [disable screen capture (default enabled)])])
1997 if test "${enable_screen}" != "no"; then
1998 if test "${SYS}" = "darwin"; then
1999 AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
2000 VLC_ADD_PLUGIN([screen])
2001 ])
2002 fi
2003 fi
2004 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
2006 dnl
2007 dnl VNC/RFB access module
2008 dnl
2009 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
2011 dnl RDP/Remote Desktop access module
2012 dnl
2013 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
2015 dnl
2016 dnl Real RTSP plugin
2017 dnl
2018 AC_ARG_ENABLE(realrtsp,
2019 [ --enable-realrtsp Real RTSP module (default disabled)])
2020 if test "${enable_realrtsp}" = "yes"; then
2021 VLC_ADD_PLUGIN([access_realrtsp])
2022 fi
2024 dnl
2025 dnl QTKit
2026 AC_ARG_ENABLE(macosx-qtkit,
2027 [ --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
2028 if test "x${enable_macosx_qtkit}" != "xno" &&
2029 (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2030 then
2031 AC_CHECK_HEADERS(QTKit/QTKit.h, [
2032 VLC_ADD_PLUGIN([qtsound])
2033 ])
2034 fi
2036 dnl
2037 dnl AVFoundation
2038 AC_SUBST(have_avfoundation, ["no"])
2039 AC_ARG_ENABLE(macosx-avfoundation,
2040 [ --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2041 if test "x${enable_macosx_avfoundation}" != "xno" &&
2042 (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2043 then
2044 SAVED_LIBS="${LIBS}"
2045 LIBS="-framework AVFoundation"
2046 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2047 LIBS="${SAVED_LIBS}"
2048 if test "${have_avfoundation}" != "no"
2049 then
2050 VLC_ADD_PLUGIN([avcapture])
2051 fi
2052 fi
2053 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2055 dnl
2056 dnl DCP plugin (using asdcplib)
2057 dnl
2058 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2059 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2061 dnl
2062 dnl Demux plugins
2063 dnl
2065 EXTEND_HELP_STRING([Mux/Demux plugins:])
2067 dnl
2068 dnl libdvbpsi check for ts mux/demux
2069 dnl
2070 have_dvbpsi="no"
2071 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2072 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2075 dnl
2076 dnl GME demux plugin
2077 dnl
2078 AC_ARG_ENABLE(gme,
2079 [AS_HELP_STRING([--enable-gme],
2080 [use Game Music Emu (default auto)])])
2081 AS_IF([test "${enable_gme}" != "no"], [
2082 AC_CHECK_HEADER([gme/gme.h], [
2083 AC_CHECK_LIB([gme], [gme_identify_header], [
2084 VLC_ADD_PLUGIN([gme])
2085 ], [
2086 AC_CHECK_LIB([gme], [gme_identify_extension], [
2087 VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2088 VLC_ADD_PLUGIN([gme])
2089 ],, [-lstdc++ $LIBM])
2090 ])
2091 VLC_ADD_LIBS([gme], [-lgme])
2092 ], [
2093 AS_IF([test "x${enable_gme}" != "x"], [
2094 AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2095 ])
2096 ])
2097 ])
2100 dnl
2101 dnl SIDPlay plugin
2102 dnl
2103 AC_ARG_ENABLE(sid,
2104 [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2105 AS_IF([test "${enable_sid}" != "no"], [
2106 PKG_CHECK_MODULES(SID, [libsidplay2], [
2107 AC_LANG_PUSH(C++)
2108 oldCPPFLAGS="$CPPFLAGS"
2109 CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2110 AC_CHECK_HEADER([sidplay/builders/resid.h], [
2111 VLC_ADD_PLUGIN([sid])
2112 VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2113 VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2114 ], [
2115 AS_IF([test -n "${enable_sid}"],
2116 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2117 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2118 )
2119 ])
2120 CPPFLAGS="$oldCPPFLAGS"
2121 AC_LANG_POP(C++)
2122 ], [
2123 AS_IF([test "x${enable_sid}" = "xyes"],
2124 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2125 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2126 )
2127 ])
2128 ])
2131 dnl
2132 dnl ogg demux plugin
2133 dnl
2134 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2135 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2136 AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2137 ],[true])
2138 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2139 if test "${enable_sout}" != "no"; then
2140 dnl Check for libshout
2141 PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2142 fi
2144 dnl
2145 dnl matroska demux plugin
2146 dnl
2147 PKG_WITH_MODULES([MATROSKA], [libebml libmatroska], [
2148 VLC_ADD_PLUGIN([mkv])
2149 VLC_ADD_CFLAGS([mkv], [$MATROSKA_CFLAGS])
2150 VLC_ADD_LIBS([mkv], [$MATROSKA_LIBS])
2151 have_matroska="yes"
2152 ],,[MKV format support], [auto])
2153 AM_CONDITIONAL([HAVE_MATROSKA], [test "${have_matroska}" = "yes"])
2155 dnl
2156 dnl modplug demux plugin
2157 dnl
2158 AC_ARG_ENABLE(mod,
2159 [AS_HELP_STRING([--disable-mod],
2160 [do not use libmodplug (default auto)])])
2161 if test "${enable_mod}" != "no" ; then
2162 PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2163 VLC_ADD_PLUGIN([mod])
2164 VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2165 VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2166 VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2167 ],[
2168 AS_IF([test -n "${enable_mod}"],
2169 [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2170 [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2171 ])
2172 fi
2174 dnl
2175 dnl mpc demux plugin
2176 dnl
2177 AC_ARG_ENABLE(mpc,
2178 [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2179 if test "${enable_mpc}" != "no"
2180 then
2181 AC_CHECK_HEADERS([mpc/mpcdec.h], [
2182 VLC_ADD_PLUGIN([mpc])
2183 VLC_ADD_LIBS([mpc],[-lmpcdec])],
2184 [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2185 VLC_ADD_PLUGIN([mpc])
2186 VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2187 fi
2189 dnl
2190 dnl Codec plugins
2191 dnl
2193 EXTEND_HELP_STRING([Codec plugins:])
2195 dnl
2196 dnl wmafixed plugin
2197 dnl
2198 AC_ARG_ENABLE(wma-fixed,
2199 [ --enable-wma-fixed libwma-fixed module (default disabled)])
2200 if test "${enable_wma_fixed}" = "yes"
2201 then
2202 VLC_ADD_PLUGIN([wma_fixed])
2203 fi
2205 dnl
2206 dnl shine encoder plugin
2207 dnl
2208 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2211 dnl
2212 dnl openmax il codec plugin
2213 dnl
2214 AC_ARG_ENABLE(omxil,
2215 [ --enable-omxil openmax il codec module (default disabled)])
2216 if test "${enable_omxil}" = "yes"
2217 then
2218 VLC_ADD_PLUGIN([omxil])
2219 fi
2221 dnl
2222 dnl raspberry pi openmax il configuration
2223 dnl
2224 AC_ARG_ENABLE(rpi-omxil,
2225 [ --enable-rpi-omxil openmax il configured for raspberry pi (default disabled)])
2226 if test "${enable_rpi_omxil}" = "yes"
2227 then
2228 VLC_ADD_PLUGIN([omxil])
2229 VLC_ADD_CFLAGS([omxil],[-DRPI_OMX])
2230 fi
2232 dnl
2233 dnl CrystalHD codec plugin
2234 dnl
2235 AC_ARG_ENABLE(crystalhd,
2236 [ --enable-crystalhd crystalhd codec plugin (default auto)])
2237 if test "${enable_crystalhd}" != "no"; then
2238 AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2239 VLC_ADD_PLUGIN([crystalhd])
2240 VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2241 ],[
2242 if test "${SYS}" = "mingw32" ; then
2243 AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2244 VLC_ADD_PLUGIN([crystalhd])
2245 AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2246 VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2247 ])
2248 ],[
2249 AS_IF([test x"${enable_crystalhd}" = "xyes"],
2250 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2251 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2252 ],[#define __LINUX_USER__
2253 #include <libcrystalhd/bc_dts_types.h>
2254 ])
2255 fi
2256 ],[
2257 #include <libcrystalhd/bc_dts_types.h>
2258 ])
2259 fi
2261 dnl
2262 dnl mad plugin
2263 dnl
2264 have_mad="no"
2265 MAD_CFLAGS=""
2266 MAD_LIBS=""
2268 AC_ARG_WITH(mad, [ --with-mad=PATH path to libmad], [
2269 enable_mad="yes"
2270 ], [
2271 with_mad="no"
2272 ])
2273 AS_IF([test "${with_mad}" != "no"], [
2274 MAD_CFLAGS="-I${with_mad}/include"
2275 MAD_LIBS="-L${with_mad}/lib"
2276 ])
2278 AC_ARG_ENABLE(mad,
2279 [ --enable-mad libmad module (default enabled)])
2280 AS_IF([test "${enable_mad}" != "no"], [
2281 VLC_SAVE_FLAGS
2282 CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2283 LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2284 AC_CHECK_HEADERS(mad.h, [
2285 AC_CHECK_LIB(mad, mad_bit_init, [
2286 have_mad="yes"
2287 MAD_LIBS="${MAD_LIBS} -lmad"
2288 ])
2289 ])
2290 VLC_RESTORE_FLAGS
2291 AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2292 AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2293 ])
2294 ])
2295 AC_SUBST(MAD_CFLAGS)
2296 AC_SUBST(MAD_LIBS)
2297 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2299 dnl mpg123 plugin
2300 dnl
2301 dnl
2302 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2304 dnl
2305 dnl gstreamer stuff
2306 dnl
2307 AC_ARG_ENABLE(gst-decode,
2308 [ --enable-gst-decode GStreamer based decoding support (currently supports only video decoding) (default auto)])
2310 have_gst_decode="no"
2311 AS_IF([test "${enable_gst_decode}" != "no"], [
2312 PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2313 PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2314 have_gst_decode="yes"
2315 ], [
2316 AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2317 ])
2318 ], [
2319 AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2320 ])
2321 ])
2322 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2324 dnl
2325 dnl avcodec decoder/encoder plugin
2326 dnl
2327 AC_ARG_ENABLE(merge-ffmpeg,
2328 [ --enable-merge-ffmpeg merge FFmpeg-based plugins (default disabled)],, [
2329 enable_merge_ffmpeg="no"
2330 ])
2331 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2333 AC_MSG_CHECKING([for libavutil variant])
2334 PKG_CHECK_EXISTS([libavutil], [
2335 libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2336 libavutil_micro="${libavutil_version##*.}"
2337 AS_IF([test ${libavutil_micro} -le 99], [
2338 avfork="libav"
2339 ], [
2340 avfork="ffmpeg"
2341 ])
2342 ], [
2343 avfork="none"
2344 ])
2345 AC_MSG_RESULT([${avfork}])
2347 AC_ARG_ENABLE(avcodec,
2348 [ --enable-avcodec libavcodec codec (default enabled)])
2349 AS_IF([test "${enable_avcodec}" != "no"], [
2350 dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2351 case "${avfork}" in
2352 libav) av_codec_ver="57.16.0" ;;
2353 ffmpeg) av_codec_ver="57.37.100" ;;
2354 *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2355 esac
2356 PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2357 VLC_SAVE_FLAGS
2358 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2359 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2360 AC_CHECK_HEADERS(libavcodec/avcodec.h)
2361 AC_CHECK_HEADERS(libavutil/avutil.h)
2362 VLC_RESTORE_FLAGS
2363 have_avcodec="yes"
2364 ],[
2365 AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2366 ])
2367 ], [
2368 have_avcodec="no"
2369 ])
2370 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2372 dnl
2373 dnl libva needs avcodec
2374 dnl
2375 AC_ARG_ENABLE(libva,
2376 [ --enable-libva VAAPI GPU decoding support (libVA) (default auto)])
2378 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2379 AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2380 ])
2382 have_vaapi="no"
2383 have_vaapi_drm="no"
2384 have_vaapi_x11="no"
2385 have_vaapi_wl="no"
2386 AS_IF([test "${enable_libva}" != "no"], [
2387 PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2388 have_vaapi="yes"
2389 ], [
2390 AS_IF([test -n "${enable_libva}"], [
2391 AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2392 ], [
2393 AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2394 ])
2395 ])
2396 PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2397 have_vaapi_drm="yes"
2398 ], [
2399 AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2400 ])
2401 PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2402 have_vaapi_x11="yes"
2403 ], [
2404 AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2405 ])
2406 PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2407 have_vaapi_wl="yes"
2408 ], [
2409 AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2410 ])
2411 ])
2412 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2413 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2414 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2415 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2417 have_avcodec_vaapi="no"
2418 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2419 VLC_SAVE_FLAGS
2420 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2421 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2422 AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2423 AC_MSG_NOTICE([VA API acceleration activated])
2424 have_avcodec_vaapi="yes"
2425 ],[
2426 AS_IF([test -n "${enable_libva}"], [
2427 AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2428 ], [
2429 AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2430 ])
2431 ])
2432 VLC_RESTORE_FLAGS
2433 ])
2434 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2436 dnl
2437 dnl dxva2 needs avcodec
2438 dnl
2439 AC_ARG_ENABLE(dxva2,
2440 [ --enable-dxva2 DxVA2 GPU decoding support (default auto)])
2442 have_avcodec_dxva2="no"
2443 AS_IF([test "${enable_dxva2}" != "no"], [
2444 if test "${SYS}" = "mingw32"; then
2445 AS_IF([test "x${have_avcodec}" = "xyes"], [
2446 AC_CHECK_HEADERS(dxva2api.h,
2447 [
2448 AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2449 AC_MSG_NOTICE([DxVA2 acceleration activated])
2450 have_avcodec_dxva2="yes"
2451 ],[
2452 AS_IF([test "${enable_dxva2}" = "yes"],
2453 [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2454 [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2455 ], [#undef _WIN32_WINNT
2456 /* DXVA2 is only available in Vista and above */
2457 #define _WIN32_WINNT 0x600])
2458 ],[
2459 AS_IF([test "${enable_dxva2}" = "yes"],
2460 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2461 [AC_MSG_WARN([dxva2api.h not found])])
2462 ],[#include <d3d9.h>])
2463 ],[
2464 AS_IF([test "x${enable_dxva2}" != "x"], [
2465 AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2466 ])
2467 ])
2468 fi
2469 ])
2470 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2472 dnl
2473 dnl d3d11va needs avcodec
2474 dnl
2475 AC_ARG_ENABLE(d3d11va,
2476 [ --enable-d3d11va D3D11 GPU decoding support (default auto)])
2478 have_avcodec_d3d11va="no"
2479 AS_IF([test "${enable_d3d11va}" != "no"], [
2480 if test "${SYS}" = "mingw32"; then
2481 AS_IF([test "x${have_avcodec}" = "xyes"], [
2482 AC_CHECK_TYPES([ID3D11VideoDecoder],
2483 [
2484 AC_CHECK_HEADERS(dxva2api.h,
2485 [
2486 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2487 AC_MSG_NOTICE([D3D11 acceleration activated])
2488 AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2489 have_avcodec_d3d11va="yes"
2490 ],[
2491 AS_IF([test "${enable_d3d11va}" = "yes"],
2492 [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2493 [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2494 ], [#undef _WIN32_WINNT
2495 /* D3D11 is only available in Vista and above */
2496 #define _WIN32_WINNT 0x600])
2497 ],[
2498 AS_IF([test "${enable_d3d11va}" = "yes"],
2499 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2500 [AC_MSG_WARN([dxva2api.h not found])])
2501 ],[#include <d3d9.h>])
2502 ],[
2503 AS_IF([test "${enable_d3d11va}" = "yes"],
2504 [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2505 [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2506 ], [#include <d3d11.h>])
2507 ],[
2508 AS_IF([test "x${enable_d3d11va}" != "x"], [
2509 AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2510 ])
2511 ])
2512 fi
2513 ])
2514 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2516 dnl
2517 dnl DXGI debug
2518 dnl
2519 AC_CHECK_HEADERS(dxgidebug.h dxgi1_6.h)
2521 dnl
2522 dnl avformat demuxer/muxer plugin
2523 dnl
2525 AC_ARG_ENABLE(avformat,
2526 [ --enable-avformat libavformat containers (default enabled)],, [
2527 enable_avformat="${have_avcodec}"
2528 ])
2529 have_avformat="no"
2530 AS_IF([test "${enable_avformat}" != "no"], [
2531 PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2532 have_avformat="yes"
2533 VLC_SAVE_FLAGS
2534 CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2535 CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2536 AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2537 AC_CHECK_HEADERS(libavcodec/avcodec.h)
2538 AC_CHECK_HEADERS(libavutil/avutil.h)
2539 AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2540 have_avformat="no"
2541 ])
2542 VLC_RESTORE_FLAGS
2543 ],[
2544 AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2545 ])
2546 ])
2547 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2549 dnl
2550 dnl swscale image scaling and conversion plugin
2551 dnl
2553 AC_ARG_ENABLE(swscale,
2554 AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2555 (default enabled)]))
2556 if test "${enable_swscale}" != "no"
2557 then
2558 PKG_CHECK_MODULES(SWSCALE,[libswscale],
2559 [
2560 VLC_SAVE_FLAGS
2561 CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2562 CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2563 AC_CHECK_HEADERS(libswscale/swscale.h)
2564 AC_CHECK_HEADERS(libavutil/avutil.h)
2565 VLC_ADD_PLUGIN([swscale])
2566 VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2567 VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2568 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2569 VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2570 ])
2571 VLC_RESTORE_FLAGS
2572 ],[
2573 AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2574 ])
2575 fi
2577 dnl
2578 dnl postproc plugin
2579 dnl
2581 AC_ARG_ENABLE(postproc,
2582 [ --enable-postproc libpostproc image post-processing (default auto)])
2583 if test "${enable_postproc}" != "no"
2584 then
2585 PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2586 [
2587 VLC_SAVE_FLAGS
2588 CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2589 CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2590 AC_CHECK_HEADERS(postproc/postprocess.h)
2591 VLC_ADD_PLUGIN([postproc])
2592 VLC_RESTORE_FLAGS
2593 ],[
2594 AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2595 ])
2596 fi
2598 dnl
2599 dnl faad decoder plugin
2600 dnl
2601 AC_ARG_ENABLE(faad,
2602 [ --enable-faad faad codec (default auto)])
2603 have_faad="no"
2604 AS_IF([test "${enable_faad}" != "no"], [
2605 AC_CHECK_HEADERS([neaacdec.h], [
2606 AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2608 AS_IF([test "${have_faad}" = "yes"], [
2609 VLC_ADD_PLUGIN([faad])
2610 VLC_ADD_LIBS([faad],[-lfaad])
2611 ], [
2612 AS_IF([test "${enable_faad}" = "yes"], [
2613 AC_MSG_ERROR([cannot find FAAD library])
2614 ], [
2615 AC_MSG_WARN([cannot find FAAD library])
2616 ])
2617 ])
2618 ])
2619 ])
2621 dnl
2622 dnl AOM decoder plugin
2623 dnl
2624 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec (default auto)])
2626 dnl
2627 dnl libvpx decoder plugin
2628 dnl
2629 AC_ARG_ENABLE(vpx,
2630 AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2631 AS_IF([test "${enable_vpx}" != "no"],[
2632 PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2633 VLC_ADD_PLUGIN([vpx])
2634 VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2635 VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2636 AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2637 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2638 ], [], [${VPX_LIBS}])
2639 AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2640 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2641 ], [], [${VPX_LIBS}])
2642 AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2643 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2644 ], [], [${VPX_LIBS}])
2645 AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2646 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2647 ], [], [${VPX_LIBS}])
2648 ], [
2649 AS_IF([test "${enable_vpx}" = "yes"],[
2650 AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2651 ])])
2652 ])
2654 dnl
2655 dnl twolame encoder plugin
2656 dnl
2657 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2659 dnl
2660 dnl fdk-aac encoder plugin
2661 dnl
2662 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2665 dnl
2666 dnl A52/AC3 decoder plugin
2667 dnl
2668 AC_ARG_ENABLE(a52,
2669 [ --enable-a52 A/52 support with liba52 (default enabled)])
2670 if test "${enable_a52}" != "no"
2671 then
2672 AC_ARG_WITH(a52,
2673 [ --with-a52=PATH a52 headers and libraries])
2674 if test -z "${with_a52}"
2675 then
2676 LDFLAGS_test=""
2677 CPPFLAGS_test=""
2678 else
2679 LDFLAGS_test="-L${with_a52}/lib"
2680 CPPFLAGS_test="-I${with_a52}/include"
2681 fi
2682 VLC_SAVE_FLAGS
2683 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2684 LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2685 AC_CHECK_HEADERS(a52dec/a52.h, [
2686 AC_CHECK_LIB(a52, a52_free, [
2687 VLC_ADD_PLUGIN([a52])
2688 VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2689 VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2690 ],[
2691 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2692 ], [$LIBM])
2693 ],[
2694 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2695 ])
2696 VLC_RESTORE_FLAGS
2697 fi
2699 dnl
2700 dnl DTS Coherent Acoustics decoder plugin
2701 dnl
2702 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2704 dnl
2705 dnl Flac plugin
2706 dnl
2707 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2709 dnl
2710 dnl Libmpeg2 plugin
2711 dnl
2712 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2714 dnl
2715 dnl Vorbis plugin
2716 dnl
2717 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2719 dnl
2720 dnl Tremor plugin
2721 dnl
2722 AC_ARG_ENABLE(tremor,
2723 [ --enable-tremor Tremor decoder support (default disabled)])
2724 if test "${enable_tremor}" = "yes"
2725 then
2726 AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2727 VLC_ADD_PLUGIN([tremor])
2728 ],[])
2729 fi
2731 dnl
2732 dnl Speex plugins
2733 dnl
2734 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2735 have_speexdsp="no"
2736 AS_IF([test "${enable_speex}" != "no"], [
2737 PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2738 have_speexdsp="yes"
2739 ], [
2740 AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2741 ])
2742 ])
2743 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2745 dnl
2746 dnl Opus plugin
2747 dnl
2748 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2750 dnl
2751 dnl Ambisonic channel mixer and binauralizer plugin
2752 dnl
2753 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2755 dnl
2756 dnl theora decoder plugin
2757 dnl
2758 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2760 dnl
2761 dnl OggSpots decoder plugin
2762 dnl
2763 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2765 dnl
2766 dnl Daala decoder plugin
2767 dnl
2768 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2770 dnl
2771 dnl schroedinger decoder plugin (for dirac format video)
2772 dnl
2773 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2775 dnl
2776 dnl PNG decoder module
2777 dnl
2778 AC_ARG_ENABLE(png,
2779 [ --enable-png PNG support (default enabled)])
2780 AS_IF([test "${enable_png}" != "no"], [
2781 AC_CHECK_HEADERS(png.h, [
2782 VLC_SAVE_FLAGS
2783 LDFLAGS="${LDFLAGS} -lz $LIBM"
2784 AC_CHECK_LIB(png, png_set_alpha_mode, [
2785 VLC_ADD_PLUGIN([png])
2786 ], [], [-lz $LIBM])
2787 VLC_RESTORE_FLAGS
2788 ])
2789 ])
2791 dnl
2792 dnl JPEG decoder module
2793 dnl
2794 AC_ARG_ENABLE(jpeg,
2795 [ --enable-jpeg JPEG support (default enabled)])
2796 AS_IF([test "${enable_jpeg}" != "no"], [
2797 AC_CHECK_HEADERS(jpeglib.h, [
2798 VLC_ADD_PLUGIN([jpeg])
2799 ])
2800 ])
2802 dnl
2803 dnl BPG decoder module
2804 dnl
2805 AC_ARG_ENABLE(bpg,
2806 [ --enable-bpg BPG support (default disabled)])
2807 AS_IF([test "${enable_bpg}" != "no"], [
2808 AC_CHECK_HEADERS(libbpg.h, [
2809 VLC_ADD_PLUGIN([bpg])
2810 ])
2811 ])
2813 dnl
2814 dnl H262 encoder plugin (lib262)
2815 dnl
2816 AC_ARG_ENABLE(x262,
2817 [ --enable-x262 H262 encoding support with static libx262 (default disabled)])
2818 if test "${enable_x262}" != "no"; then
2819 PKG_CHECK_MODULES(X262, x262, [
2820 VLC_ADD_PLUGIN([x262])
2821 VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2822 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2823 VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2824 ])
2825 VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2826 if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2827 VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2828 fi
2829 ], [
2830 if test "${enable_x262}" = "yes"; then
2831 AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2832 fi
2833 ])
2834 fi
2836 dnl x265 encoder
2837 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2839 dnl
2840 dnl H264 encoder plugin (using libx264)
2841 dnl
2842 AC_ARG_ENABLE(x264,
2843 [ --enable-x264 H264 encoding support with libx264 (default enabled)])
2844 if test "${enable_x264}" != "no"; then
2845 PKG_CHECK_MODULES(X264,x264 >= 0.148, [
2846 VLC_ADD_PLUGIN([x264])
2847 VLC_ADD_LIBS([x264],[${X264_LIBS}])
2849 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2850 VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2851 ])
2853 VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2854 if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2855 VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2856 fi
2857 ],[
2858 if test "${enable_x264}" = "yes"; then
2859 AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2860 fi
2861 ])
2862 fi
2864 dnl
2865 dnl H264 encoder plugin (libx264 > 153)
2866 dnl
2867 AC_ARG_ENABLE(x26410b,
2868 [ --enable-x26410b H264 10-bit encoding support with libx264 (default enabled)])
2869 if test "${enable_x26410b}" != "no"; then
2870 PKG_CHECK_MODULES(X26410b,x264 >= 0.153, [
2871 VLC_ADD_PLUGIN([x26410b])
2872 VLC_ADD_LIBS([x26410b],[${X264_LIBS}])
2874 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2875 VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2876 ])
2878 VLC_ADD_CFLAGS([x26410b],[${X264_CFLAGS}])
2879 if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2880 VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2881 fi
2882 ],[
2883 if test "${enable_x26410b}" = "yes"; then
2884 AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2885 fi
2886 ])
2887 fi
2890 dnl
2891 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2892 dnl
2893 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2895 dnl
2896 dnl libfluidsynth (MIDI synthetizer) plugin
2897 dnl
2898 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2899 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2900 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2902 dnl
2903 dnl Teletext Modules
2904 dnl vbi decoder plugin (using libzbvi)
2905 dnl telx module
2906 dnl uncompatible
2907 dnl
2908 AC_ARG_ENABLE(zvbi,
2909 AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2910 libzvbi (default enabled)]))
2911 AC_ARG_ENABLE(telx,
2912 AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2913 zvbi) (default enabled if zvbi is absent)]))
2915 AS_IF( [test "${enable_zvbi}" != "no"],[
2916 PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2917 [
2918 VLC_ADD_PLUGIN([zvbi])
2919 AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2920 AS_IF( [test "${enable_telx}" = "yes"],[
2921 AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2922 ])
2923 ],[
2924 AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2925 ])
2926 ])
2927 AS_IF( [test "${enable_telx}" != "no" ],[
2928 VLC_ADD_PLUGIN([telx])
2929 ])
2931 dnl
2932 dnl libass subtitle rendering module
2933 dnl
2934 AC_ARG_ENABLE(libass,
2935 [ --enable-libass Subtitle support using libass (default enabled)])
2936 AS_IF( [test "${enable_libass}" != "no"], [
2937 PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2938 [
2939 VLC_ADD_PLUGIN([libass])
2941 AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2942 [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2943 VLC_ADD_LIBS([libass],[-lfontconfig])
2944 ])
2945 ],[
2946 AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2947 ])
2948 ])
2950 dnl
2951 dnl ARIB subtitles rendering module
2952 dnl
2953 AC_ARG_ENABLE(aribsub,
2954 [ --enable-aribsub ARIB Subtitles support (default enabled)])
2955 AS_IF( [test "${enable_aribsub}" != "no" ],[
2956 PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2957 have_aribb24="yes"
2958 VLC_ADD_PLUGIN([aribsub])
2959 VLC_ADD_LIBS([aribsub],[-laribb24])
2960 AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2961 ],[
2962 AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2963 have_aribb24="no"
2964 ])
2965 ])
2966 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2968 dnl
2969 dnl ARIB B25
2970 dnl
2971 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2973 dnl
2974 dnl kate decoder plugin
2975 dnl
2976 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2978 dnl
2979 dnl tiger rendering for kate decoder plugin
2980 dnl
2981 AC_ARG_ENABLE(tiger,
2982 [ --enable-tiger Tiger rendering library for Kate streams (default auto)])
2983 AS_IF([test "${enable_tiger}" != "no"], [
2984 PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2985 AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2986 AS_IF([test -n "${enable_tiger}"], [
2987 AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2988 ])
2989 ])
2990 ])
2992 dnl
2993 dnl check if we can build the css selector engine
2994 dnl
2995 AC_ARG_ENABLE(css,
2996 [ --enable-css CSS selector engine (default auto)])
2997 AS_IF([test "${enable_css}" != "no"], [
2998 with_css="yes"
2999 AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
3000 ])
3001 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
3004 dnl
3005 dnl Video plugins
3006 dnl
3008 EXTEND_HELP_STRING([Video plugins:])
3010 dnl
3011 dnl OpenGL
3012 dnl
3013 PKG_CHECK_MODULES([EGL], [egl], [
3014 have_egl="yes"
3015 ], [
3016 have_egl="no"
3017 ])
3018 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3020 have_gl="no"
3021 PKG_CHECK_MODULES([GL], [gl], [
3022 have_gl="yes"
3023 ], [
3024 AC_MSG_CHECKING([for OpenGL])
3025 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3026 #ifdef _WIN32
3027 # include <GL/glew.h>
3028 #endif
3029 #include <GL/gl.h>
3030 ]], [
3031 [int t0 = GL_TEXTURE0;]])
3032 ], [
3033 GL_CFLAGS=""
3034 have_gl="yes"
3035 AS_IF([test "${SYS}" != "mingw32"], [
3036 GL_LIBS="-lGL"
3037 ], [
3038 GL_LIBS="-lopengl32"
3039 ])
3040 ])
3041 AC_MSG_RESULT([${have_gl}])
3042 ])
3043 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3044 AS_IF([test "${have_gl}" = "yes"], [
3045 AC_DEFINE([HAVE_GL], 1, [Defined if having OpenGL])
3046 ])
3048 dnl OpenGL ES 2: depends on EGL 1.1
3049 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3051 dnl
3052 dnl Xlib
3053 dnl
3055 AC_PATH_XTRA()
3056 AC_CHECK_HEADERS(X11/Xlib.h)
3058 dnl
3059 dnl X C Bindings modules
3060 dnl
3061 AC_ARG_ENABLE(xcb,
3062 [ --enable-xcb X11 support with XCB (default enabled)],, [
3063 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3064 enable_xcb="yes"
3065 ], [
3066 enable_xcb="no"
3067 ])
3068 ])
3069 AC_ARG_ENABLE(xvideo,
3070 [ --enable-xvideo XVideo support (default enabled)],, [
3071 enable_xvideo="$enable_xcb"
3072 ])
3074 have_xcb="no"
3075 have_xcb_keysyms="no"
3076 have_xcb_randr="no"
3077 have_xcb_xvideo="no"
3078 AS_IF([test "${enable_xcb}" != "no"], [
3079 dnl libxcb
3080 PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3081 have_xcb="yes"
3082 PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3083 PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3084 PKG_CHECK_MODULES(XPROTO, [xproto])
3086 AS_IF([test "${enable_xvideo}" != "no"], [
3087 PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3088 ])
3090 PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3092 dnl xcb-utils
3093 PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3094 AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3095 ])
3096 ])
3097 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3098 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3099 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3100 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3103 dnl
3104 dnl VDPAU needs X11
3105 dnl
3106 AC_ARG_ENABLE(vdpau,
3107 [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3108 have_vdpau="no"
3109 AS_IF([test "${enable_vdpau}" != "no"], [
3110 PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3111 have_vdpau="yes"
3112 AS_IF([test "${no_x}" = "yes"], [
3113 AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3114 ])
3115 ], [
3116 AS_IF([test -n "${enable_vdpau}"], [
3117 AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3118 ])
3119 ])
3120 ])
3121 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3123 have_avcodec_vdpau="no"
3124 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3125 case "${avfork}" in
3126 libav) av_vdpau_ver="56.10.0" ;;
3127 ffmpeg) av_vdpau_ver="56.19.100" ;;
3128 esac
3129 PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3130 have_avcodec_vdpau="yes"
3131 AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3132 ], [
3133 AS_IF([test -n "${enable_vdpau}"], [
3134 AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3135 ], [
3136 AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3137 ])
3138 ])
3139 ])
3140 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3143 dnl
3144 dnl Wayland
3145 dnl
3146 AC_ARG_ENABLE(wayland,
3147 [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3148 have_wayland="no"
3149 have_wayland_egl="no"
3151 AS_IF([test "${enable_wayland}" != "no"], [
3152 PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3153 AC_MSG_CHECKING([for the Wayland protocols])
3154 PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3155 WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3156 AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3157 ], [
3158 AC_MSG_RESULT([not found])
3159 AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3160 ])
3162 AC_MSG_CHECKING([for the Wayland scanner])
3163 PKG_CHECK_EXISTS([wayland-scanner], [
3164 WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3165 AC_MSG_RESULT([${WAYLAND_SCANNER}])
3166 ], [
3167 AC_MSG_RESULT([not found])
3168 AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3169 ])
3171 have_wayland="yes"
3173 AS_IF([test "${have_egl}" = "yes"], [
3174 PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3175 have_wayland_egl="yes"
3176 ], [
3177 AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3178 ])
3179 ])
3180 ], [
3181 AS_IF([test -n "${enable_wayland}"], [
3182 AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3183 ])
3184 ])
3185 ])
3186 AC_SUBST([WAYLAND_PROTOCOLS])
3187 AC_SUBST([WAYLAND_SCANNER])
3188 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3189 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3192 dnl
3193 dnl SDL image decoder module
3194 dnl
3195 AC_ARG_ENABLE(sdl-image,
3196 [ --enable-sdl-image SDL image support (default enabled)])
3197 AS_IF([test "${enable_sdl_image}" != "no"],[
3198 PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3199 VLC_ADD_PLUGIN([sdl_image])
3200 ], [
3201 AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3202 ])
3203 ])
3205 dnl
3206 dnl freetype module
3207 dnl
3208 AC_ARG_ENABLE(freetype,
3209 [ --enable-freetype freetype support (default auto)])
3210 AC_ARG_ENABLE(fribidi,
3211 [ --enable-fribidi fribidi support (default auto)])
3212 AC_ARG_ENABLE(harfbuzz,
3213 [ --enable-harfbuzz harfbuzz support (default auto)])
3214 AC_ARG_ENABLE(fontconfig,
3215 [ --enable-fontconfig fontconfig support (default auto)])
3217 AC_ARG_WITH([default-font],
3218 AS_HELP_STRING([--with-default-font=PATH],
3219 [Path to the default font]),
3220 [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3221 "$withval", [Default font])])
3222 AC_ARG_WITH([default-monospace-font],
3223 AS_HELP_STRING([--with-default-monospace-font=PATH],
3224 [Path to the default font]),
3225 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3226 "$withval", [Default monospace font])])
3228 AC_ARG_WITH([default-font-family],
3229 AS_HELP_STRING([--with-default-font-family=NAME],
3230 [Path to the default font family]),
3231 [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3232 "$withval", [Default font family])])
3233 AC_ARG_WITH([default-monospace-font-family],
3234 AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3235 [Path to the default font family]),
3236 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3237 "$withval", [Default monospace font family])])
3239 have_freetype="no"
3240 have_fontconfig="no"
3241 have_fribidi="no"
3242 have_harfbuzz="no"
3244 if test "${enable_freetype}" != "no"; then
3245 PKG_CHECK_MODULES(FREETYPE, freetype2, [
3246 have_freetype="yes"
3247 VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3248 VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3250 dnl fontconfig support
3251 AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3252 PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3253 have_fontconfig="yes"
3254 ], [
3255 AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3256 ])
3257 ])
3259 dnl fribidi support
3260 if test "${enable_fribidi}" != "no"; then
3261 PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3262 have_fribidi="yes"
3263 VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3264 VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3265 ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3266 fi
3268 dnl harfbuzz support
3269 if test "${have_fribidi}" != "no"; then
3270 if test "${enable_harfbuzz}" != "no"; then
3271 PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3272 have_harfbuzz="yes"
3273 VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3274 VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3275 ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3276 fi
3277 fi
3278 ],[
3279 AS_IF([test -n "${enable_freetype}"],[
3280 AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3281 ])
3282 ])
3283 fi
3285 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3286 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3287 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3288 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3290 dnl
3291 dnl SAPI (text to Speech renderer for Windows)
3292 dnl
3293 AC_LANG_PUSH([C++])
3294 AC_CHECK_TYPES([ISpObjectToken],[
3295 have_sapi="yes"
3296 ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3297 [#include <windows.h>
3298 #include <sapi.h>
3299 #include <sphelper.h>])
3300 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3301 AC_LANG_POP([C++])
3303 dnl
3304 dnl SVG module (text rendering and image decoding)
3305 dnl
3306 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3307 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3309 dnl
3310 dnl Windows DirectX module
3311 dnl
3313 AC_ARG_ENABLE(directx,
3314 [AS_HELP_STRING([--enable-directx],
3315 [Microsoft DirectX support (default enabled on Windows)])],, [
3316 AS_IF([test "${SYS}" = "mingw32"], [
3317 enable_directx="yes"
3318 ], [
3319 enable_directx="no"
3320 ])
3321 ])
3322 AS_IF([test "${enable_directx}" != "no"], [
3323 dnl DirectDraw
3324 AC_CHECK_HEADERS(ddraw.h, [
3325 VLC_ADD_PLUGIN([directdraw])
3326 ])
3328 dnl OpenGL
3329 AC_CHECK_HEADERS(GL/wglew.h, [
3330 VLC_ADD_PLUGIN([glwin32 wgl])
3331 ],, [
3332 #include <windows.h>
3333 #include <GL/gl.h>
3334 ])
3336 dnl Direct3D11
3337 AC_CHECK_HEADERS(d3d11.h, [
3338 VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3339 ])
3341 dnl Direct3D9
3342 AC_CHECK_HEADERS(d3d9.h, [
3343 VLC_ADD_PLUGIN([direct3d9])
3344 AC_CHECK_HEADERS(d3dx9effect.h)
3346 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3347 [[#define COBJMACROS
3348 #include <d3d9.h>
3349 #include <dxva2api.h>
3350 #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3351 # error dxva2 too old
3352 #endif
3353 ]],[[;]])
3354 ],[
3355 VLC_ADD_PLUGIN([direct3d9_filters])
3356 ],
3357 [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3359 ])
3360 ])
3362 dnl
3363 dnl Linux framebuffer module
3364 dnl
3365 AC_CHECK_HEADER([linux/fb.h], [
3366 VLC_ADD_PLUGIN([fb])
3367 ])
3369 dnl
3370 dnl libcaca plugin
3371 dnl
3372 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3374 dnl
3375 dnl OS/2 KVA plugin
3376 dnl
3377 AC_ARG_ENABLE(kva,
3378 [AS_HELP_STRING([--enable-kva],
3379 [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3380 AS_IF([test "$SYS" = "os2"], [
3381 enable_kva="yes"
3382 ])
3383 ])
3384 have_kva="no"
3385 KVA_LIBS=""
3386 AS_IF([test "$enable_kva" != "no"], [
3387 AC_CHECK_HEADERS([kva.h], [
3388 have_kva="yes"
3389 AC_CHECK_LIB(kva, main, [
3390 KVA_LIBS="-lkva"
3391 ])
3392 ])
3393 ])
3394 AC_SUBST(KVA_LIBS)
3395 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3397 dnl
3398 dnl MMAL plugin
3399 dnl
3400 AC_ARG_ENABLE(mmal,
3401 AS_HELP_STRING([--enable-mmal],
3402 [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3403 if test "${enable_mmal}" != "no"; then
3404 VLC_SAVE_FLAGS
3405 LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3406 CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3407 AC_CHECK_HEADERS(interface/mmal/mmal.h,
3408 [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3409 have_mmal="yes"
3410 VLC_ADD_PLUGIN([mmal])
3411 VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3412 VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3413 VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif ]) ], [
3414 AS_IF([test "${enable_mmal}" = "yes"],
3415 [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3416 [ AC_MSG_WARN([Cannot find bcm library...]) ])
3417 ],
3418 [])
3419 ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3420 [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3421 [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3422 VLC_RESTORE_FLAGS
3423 fi
3424 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3426 dnl
3427 dnl Audio plugins
3428 dnl
3430 EXTEND_HELP_STRING([Audio plugins:])
3432 dnl
3433 dnl Pulseaudio module
3434 dnl
3435 AC_ARG_ENABLE(pulse,
3436 [AS_HELP_STRING([--enable-pulse],
3437 [use the PulseAudio client library (default auto)])])
3438 have_pulse="no"
3439 AS_IF([test "${enable_pulse}" != "no"], [
3440 PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3441 have_pulse="yes"
3442 ], [
3443 AS_IF([test "x${enable_pulse}" != "x"], [
3444 AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3445 ])
3446 ])
3447 ])
3448 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3450 dnl
3451 dnl ALSA module
3452 dnl
3453 AC_ARG_ENABLE(alsa,
3454 [AS_HELP_STRING([--enable-alsa],
3455 [support the Advanced Linux Sound Architecture (default auto)])],, [
3456 AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3457 enable_alsa="yes"
3458 ])
3459 ])
3460 have_alsa="no"
3461 AS_IF([test "${enable_alsa}" != "no"], [
3462 PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3463 have_alsa="yes"
3464 ], [
3465 AS_IF([test "x${enable_alsa}" != "x"], [
3466 AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3467 ])
3468 ])
3469 ])
3470 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3472 dnl
3473 dnl Open Sound System module
3474 dnl
3475 AC_ARG_ENABLE(oss,
3476 [AS_HELP_STRING([--enable-oss],
3477 [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3478 AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3479 enable_oss="no"
3480 ])
3481 ])
3482 have_oss="no"
3483 OSS_LIBS=""
3484 AS_IF([test "$enable_oss" != "no"], [
3485 AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3486 have_oss="yes"
3487 AC_CHECK_LIB(ossaudio, main, [
3488 OSS_LIBS="-lossaudio"
3489 ])
3490 ])
3491 ])
3492 AC_SUBST(OSS_LIBS)
3493 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3495 dnl
3496 dnl OpenBSD sndio module
3497 dnl
3498 AC_ARG_ENABLE([sndio],
3499 [AS_HELP_STRING([--disable-sndio],
3500 [support the OpenBSD sndio (default auto)])],, [
3501 AS_IF([test "$SYS" = "openbsd"], [
3502 enable_sndio="yes"
3503 ])
3504 ])
3505 have_sndio="no"
3506 AS_IF([test "$enable_sndio" != "no"], [
3507 AC_CHECK_HEADER([sndio.h], [
3508 have_sndio="yes"
3509 ])
3510 ])
3511 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3513 dnl
3514 dnl Windows Audio Session plugin
3515 dnl
3516 AC_ARG_ENABLE([wasapi],
3517 [AS_HELP_STRING([--enable-wasapi],
3518 [use the Windows Audio Session API (default auto)])
3519 ])
3520 have_wasapi="no"
3521 AS_IF([test "$enable_wasapi" != "no"], [
3522 AC_CHECK_HEADER([audioclient.h], [
3523 have_wasapi="yes"
3524 ], [
3525 AS_IF([test "x${enable_wasapi}" != "x"], [
3526 AC_MSG_ERROR([Windows Audio Session API not found.])
3527 ])
3528 ])
3529 ])
3530 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3532 dnl
3533 dnl JACK modules
3534 dnl
3535 AC_ARG_ENABLE(jack,
3536 [AS_HELP_STRING([--disable-jack],
3537 [do not use jack (default auto)])])
3538 have_jack="no"
3539 AS_IF([test "${enable_jack}" != "no"], [
3540 PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3541 [ have_jack=yes ],
3542 [
3543 AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3545 PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3546 [ have_jack=yes ],
3547 [
3548 AS_IF([test -n "${enable_jack}"],
3549 [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3550 [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3551 ])
3552 ])
3553 ])
3554 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3556 dnl
3557 dnl OpenSLES Android
3558 dnl
3559 AC_ARG_ENABLE(opensles,
3560 [ --enable-opensles Android OpenSL ES audio module (default disabled)])
3561 if test "${HAVE_ANDROID}" = "1"; then
3562 if test "${enable_opensles}" = "yes"; then
3563 AC_CHECK_HEADERS(SLES/OpenSLES.h,
3564 [ VLC_ADD_PLUGIN([opensles_android]) ],
3565 [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3566 fi
3567 fi
3569 dnl
3570 dnl Tizen audio
3571 dnl
3572 AC_ARG_ENABLE(tizen_audio,
3573 [AS_HELP_STRING([--enable-tizen-audio],
3574 [Tizen audio module (default enabled on Tizen)])],, [
3575 AS_IF([test "$HAVE_TIZEN" = "1"], [
3576 enable_tizen_audio="yes"
3577 ])
3578 ])
3579 if test "${enable_tizen_audio}" = "yes"; then
3580 AC_CHECK_HEADERS(audio_io.h,
3581 [ VLC_ADD_PLUGIN([tizen_audio]) ],
3582 [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3583 fi
3585 dnl
3586 dnl libsamplerate plugin
3587 dnl
3588 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3590 dnl
3591 dnl soxr module
3592 dnl
3593 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3595 dnl
3596 dnl OS/2 KAI plugin
3597 dnl
3598 AC_ARG_ENABLE(kai,
3599 [AS_HELP_STRING([--enable-kai],
3600 [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3601 AS_IF([test "$SYS" = "os2"], [
3602 enable_kai="yes"
3603 ])
3604 ])
3605 have_kai="no"
3606 KAI_LIBS=""
3607 AS_IF([test "$enable_kai" != "no"], [
3608 AC_CHECK_HEADERS([kai.h], [
3609 have_kai="yes"
3610 AC_CHECK_LIB(kai, main, [
3611 KAI_LIBS="-lkai"
3612 ])
3613 ])
3614 ])
3615 AC_SUBST(KAI_LIBS)
3616 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3618 dnl
3619 dnl chromaprint audio track fingerprinter
3620 dnl
3621 m4_pushdef([libchromaprint_version], 0.6.0)
3622 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3623 VLC_ADD_PLUGIN([stream_out_chromaprint]),
3624 AS_IF([test "${enable_chromaprint}" = "yes"],
3625 [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3626 [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3627 ),
3628 [(Chromaprint based audio fingerprinter)],[auto])
3629 m4_popdef([libchromaprint_version])
3631 dnl
3632 dnl Chromecast streaming support
3633 dnl
3634 m4_pushdef([protobuf_lite_version], 2.5.0)
3635 AC_ARG_VAR(PROTOC, [protobuf compiler])
3636 AC_CHECK_PROGS(PROTOC, protoc, no)
3637 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3638 AS_IF([test "x${PROTOC}" != "xno"], [
3639 build_chromecast="yes"
3640 ], [
3641 AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3642 ])
3643 ], [
3644 AS_IF([test "${enable_chromecast}" = "yes"],
3645 AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3646 AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3647 )
3648 enable_chromecast="no"
3649 ], [(Chromecast streaming support)], [auto])
3650 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3651 m4_popdef([protobuf_lite_version])
3653 dnl
3654 dnl Interface plugins
3655 dnl
3657 EXTEND_HELP_STRING([Interface plugins:])
3659 dnl
3660 dnl QT
3661 dnl
3662 AC_ARG_ENABLE(qt, [
3663 AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3664 AS_IF([test "${SYS}" = "darwin"], [
3665 enable_qt="no"
3666 ])
3667 ])
3668 have_qt5_x11="no"
3669 AS_IF([test "${enable_qt}" != "no"], [
3670 PKG_CHECK_MODULES([QT], [Qt5Core >= 5.5.0 Qt5Widgets Qt5Gui Qt5Svg], [
3671 PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3672 have_qt5_x11="yes"
3673 ],[
3674 AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3675 ])
3676 QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3677 QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3678 QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3679 AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3680 AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3681 AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3682 ], [
3683 AS_IF([test -n "${enable_qt}"],[
3684 AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3685 ],[
3686 AC_MSG_WARN([${QT_PKG_ERRORS}.])
3687 ])
3688 enable_qt="no"
3689 ])
3690 ])
3692 AS_IF([test "${enable_qt}" != "no"], [
3693 ALIASES="${ALIASES} qvlc"
3694 ])
3695 AC_SUBST(QT_VERSION)
3696 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3697 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3699 dnl
3700 dnl detect kde4-config patch (used for kde solids).
3701 dnl
3702 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3703 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3704 KDE4_CONFIG="kde4-config"
3705 ])
3707 dnl
3708 dnl Simple test for skins2 dependency
3709 dnl
3710 AS_IF([test "$enable_qt" = "no"], [
3711 AS_IF([test "${enable_skins2}" = "yes"], [
3712 AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3713 ], [
3714 enable_skins2="no"
3715 AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3716 ])
3717 ])
3719 dnl
3720 dnl Skins2 module
3721 dnl
3722 AC_ARG_ENABLE(skins2,
3723 [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3724 AS_IF([test "${enable_skins2}" != "no"], [
3725 have_skins_deps="yes"
3727 dnl Win32
3728 AS_IF([test "${SYS}" = "mingw32"], [
3729 VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3730 VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3731 dnl OS/2
3732 ], [test "${SYS}" = "os2"], [
3733 VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3734 dnl Linux/Unix
3735 ], [
3736 PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3737 PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3738 PKG_CHECK_MODULES([XCURSOR], [xcursor],, [have_skins_deps="no"])
3739 PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3740 VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3741 VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} ${XCURSOR_LIBS} -lX11])
3742 ])
3744 dnl we need freetype
3745 AS_IF([test "${have_freetype}" != "yes"], [
3746 have_skins_deps="no"
3747 ])
3749 AS_IF([test "${have_skins_deps}" = "no"], [
3750 AS_IF([test "x${enable_skins2}" = "x"], [
3751 AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3752 ], [
3753 AC_MSG_ERROR([Skins2 interface requires FreeType, libxcursor, libxpm, libxext and libxinerama])
3754 ])
3755 enable_skins2="no"
3756 ], [
3757 ALIASES="${ALIASES} svlc"
3758 enable_skins2="yes"
3759 ])
3760 ])
3761 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3763 AC_ARG_ENABLE(libtar,
3764 [ --enable-libtar libtar support for skins2 (default auto)])
3765 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3766 AC_CHECK_HEADERS(libtar.h, [
3767 VLC_ADD_LIBS([skins2],[-ltar])
3768 ])
3769 ])
3771 dnl
3772 dnl MacOS X gui module
3773 dnl
3774 AC_ARG_ENABLE(macosx,
3775 [ --enable-macosx Mac OS X gui support (default enabled on Mac OS X)])
3776 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3777 then
3779 dnl
3780 dnl If possible, use xcrun to find the right ibtool
3781 dnl
3783 AC_PATH_PROG([XCRUN], [xcrun], [no])
3784 AS_IF([test ! "x${XCRUN}" = "xno"], [
3785 AC_MSG_CHECKING([for ibtool (using xcrun)])
3786 XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3787 AC_MSG_RESULT([${XIB}])
3788 ], [
3789 AC_MSG_WARN([Looking for tools without using xcrun])
3790 ])
3792 AS_IF([test "x${XIB}" = "xno"], [
3793 AC_PATH_PROG(XIB, [ibtool], [no])
3794 AS_IF([test "x${XIB}" = "xno"], [
3795 AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3796 ])
3797 ])
3798 fi
3799 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3801 dnl
3802 dnl MacOS X sparkle update support
3803 dnl
3804 AC_ARG_ENABLE(sparkle,
3805 [ --enable-sparkle Sparkle update support for OS X (default enabled on Mac OS X)])
3806 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3807 then
3808 if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3809 then
3810 AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3811 fi
3813 AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3814 fi
3815 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3817 dnl
3818 dnl MacOS X breakpad creash reporter support
3819 dnl
3820 AC_ARG_WITH([breakpad],
3821 AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
3823 AS_IF([test "$with_breakpad" != "no"], [
3825 AS_IF([test "$with_breakpad" = "yes"], [
3826 AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
3827 ])
3829 AS_IF([test "$HAVE_OSX" = "1"], [
3830 AC_MSG_CHECKING([for Breakpad framework])
3831 AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
3832 ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
3833 AC_MSG_RESULT([no])
3834 with_breakpad="no"
3835 AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3836 ], [
3837 AC_MSG_RESULT([yes])
3838 ])
3839 ],[
3840 PKG_CHECK_MODULES([BREAKPAD], [breakpad-client], [
3841 LDFLAGS="${LDFLAGS} -Wl,--build-id"
3842 ], [
3843 AC_MSG_ERROR(["breakpad not found"])
3844 ])
3845 ])
3846 ])
3848 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$with_breakpad" != "no"])
3849 AS_IF([test "$with_breakpad" != "no"], [
3850 AC_SUBST(BREAKPAD_URL, ["${with_breakpad}"])
3851 ])
3853 dnl
3854 dnl Minimal Mac OS X module
3855 dnl
3856 AC_ARG_ENABLE(minimal-macosx,
3857 [ --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3858 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3859 then
3860 VLC_ADD_PLUGIN([minimal_macosx])
3861 fi
3863 dnl
3864 dnl Mac OS X fancy dmg build tool
3865 dnl
3866 if test "${HAVE_OSX}" = "1"
3867 then
3868 AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3869 AS_IF([test "x${DMGBUILD}" = "xno"], [
3870 AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3871 ])
3872 fi
3873 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3875 dnl
3876 dnl VideoToolbox plugins
3877 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3878 VLC_ADD_PLUGIN([videotoolbox])
3879 VLC_ADD_PLUGIN([cvpx])
3880 ])
3882 dnl
3883 dnl AudioToolbox MIDI plugin
3884 AC_CHECK_HEADERS([AudioToolbox/AudioToolbox.h], [
3885 VLC_ADD_PLUGIN([audiotoolboxmidi])
3886 ])
3888 dnl
3889 dnl ncurses module
3890 dnl
3891 AC_ARG_ENABLE(ncurses,
3892 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3893 have_ncurses="no"
3894 AS_IF([test "${enable_ncurses}" != "no"] ,[
3895 PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3896 have_ncurses="yes"
3897 ALIASES="${ALIASES} nvlc"
3898 ], [
3899 AS_IF([test -n "${enable_ncurses}"], [
3900 AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3901 ])
3902 ])
3903 ])
3904 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3906 dnl
3907 dnl Lirc plugin
3908 dnl
3909 AC_ARG_ENABLE(lirc,
3910 [ --enable-lirc lirc support (default disabled)])
3911 have_lirc="no"
3912 AS_IF([test "${enable_lirc}" = "yes"], [
3913 AC_CHECK_HEADER(lirc/lirc_client.h, [
3914 AC_CHECK_LIB(lirc_client, lirc_init, [
3915 have_lirc="yes"
3916 ])
3917 ])
3918 ])
3919 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3921 dnl
3922 dnl SRT plugin
3923 dnl
3924 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.2], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
3926 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3927 dnl
3928 dnl goom visualization plugin
3929 dnl
3930 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3932 dnl
3933 dnl libprojectM visualization plugin
3934 dnl
3935 AC_ARG_ENABLE(projectm,
3936 [ --enable-projectm projectM visualization plugin (default enabled)])
3937 AS_IF([test "${enable_projectm}" != "no"],
3938 [
3939 PKG_CHECK_MODULES(PROJECTM, libprojectM,
3940 [
3941 VLC_ADD_PLUGIN([projectm])
3942 PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3943 [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3944 [ AC_MSG_WARN( [Using libprojectM version 1] )
3945 ])
3946 ],[
3947 AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3948 ])
3949 ])
3951 dnl
3952 dnl Vovoid VSXu visualization plugin
3953 dnl
3954 AC_ARG_ENABLE(vsxu,
3955 [ --enable-vsxu Vovoid VSXu visualization plugin (default auto)])
3956 AS_IF([test "${enable_vsxu}" != "no"],
3957 [
3958 PKG_CHECK_MODULES(VSXU, libvsxu,
3959 [
3960 VLC_ADD_PLUGIN([vsxu])
3961 ],[
3962 AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3963 ])
3964 ])
3966 EXTEND_HELP_STRING([Service Discovery plugins:])
3967 dnl
3968 dnl Avahi-Zeroconf services discovery
3969 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3971 dnl
3972 dnl libudev services discovery
3973 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3975 dnl
3976 dnl MTP devices services discovery
3977 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3979 dnl
3980 dnl UPnP Plugin (Intel SDK)
3981 dnl
3982 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3984 dnl
3985 dnl mDNS using libmicrodns
3986 dnl
3987 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
3990 EXTEND_HELP_STRING([Misc options:])
3992 dnl
3993 dnl libxml2 module
3994 dnl
3995 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3998 dnl
3999 dnl libgcrypt
4000 dnl
4001 AC_ARG_ENABLE(libgcrypt,
4002 [ --disable-libgcrypt gcrypt support (default enabled)])
4003 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4004 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4006 # require libgcrypt >= 1.6.0
4007 AS_IF([test "${enable_libgcrypt}" != "no"], [
4008 AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4009 VLC_SAVE_FLAGS
4010 CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4011 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4012 [#include <gcrypt.h>
4013 #if GCRYPT_VERSION_NUMBER < 0x010600
4014 #error
4015 #endif]])], [
4016 ac_cv_lib_gcrypt=yes
4017 ], [
4018 ac_cv_lib_gcrypt=no
4019 ])
4020 VLC_RESTORE_FLAGS
4021 ])
4023 AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4024 AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4025 ], [
4026 AS_IF([test "${enable_libgcrypt}" = "yes"], [
4027 AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4028 ])
4029 ])
4030 ])
4032 AS_IF([test -z "$GCRYPT_LIBS"], [
4033 GCRYPT_LIBS="-lgcrypt -lgpg-error"
4034 ])
4036 AC_SUBST(GCRYPT_CFLAGS)
4037 AC_SUBST(GCRYPT_LIBS)
4038 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4040 dnl
4041 dnl TLS/SSL
4042 dnl
4043 AC_ARG_ENABLE(gnutls,
4044 [ --enable-gnutls GNU TLS TLS/SSL support (default enabled)])
4045 AS_IF([test "${enable_gnutls}" != "no"], [
4046 PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4047 VLC_ADD_PLUGIN([gnutls])
4048 ], [
4049 AS_IF([test -n "${enable_gnutls}"], [
4050 AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4051 ])
4052 ])
4053 ])
4056 dnl
4057 dnl Taglib plugin
4058 dnl
4059 AC_ARG_ENABLE(taglib,
4060 [AS_HELP_STRING([--disable-taglib],
4061 [do not use TagLib (default enabled)])])
4062 AS_IF([test "${enable_taglib}" != "no"], [
4063 PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4064 VLC_ADD_PLUGIN([taglib])
4065 ], [
4066 AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4067 ])
4069 dnl
4070 dnl libsecret
4071 dnl
4072 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4074 dnl
4075 dnl kwallet
4076 dnl
4077 AC_ARG_ENABLE(kwallet,
4078 [AS_HELP_STRING([--enable-kwallet],
4079 [use kwallet (via D-Bus) for keystore (default enabled)])])
4080 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4081 VLC_ADD_PLUGIN([kwallet])
4082 ])
4084 dnl
4085 dnl update checking system
4086 dnl
4087 AC_ARG_ENABLE(update-check,
4088 [ --enable-update-check update checking system (default disabled)])
4089 if test "${enable_update_check}" = "yes"
4090 then
4091 AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4092 AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4093 fi
4094 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4096 dnl
4097 dnl OS X notification plugin
4098 dnl
4099 AC_ARG_ENABLE(osx_notifications,
4100 [AS_HELP_STRING([--enable-osx-notifications],
4101 [macOS notification plugin (default disabled)])],,
4102 [enable_osx_notifications=no])
4103 AS_IF([test "${enable_osx_notifications}" != "no"], [
4104 VLC_ADD_PLUGIN([osx_notifications])
4105 ])
4107 dnl
4108 dnl Libnotify notification plugin
4109 dnl
4110 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-3.0], [libnotify notification], [auto])
4112 dnl
4113 dnl libplacebo support
4114 dnl
4115 AC_ARG_ENABLE(libplacebo,
4116 [AS_HELP_STRING([--disable-libplacebo],
4117 [disable libplacebo support (default auto)])])
4119 AS_IF([test "$enable_libplacebo" != "no"], [
4120 PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.2.1], [
4121 AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
4122 ], [
4123 AS_IF([test -n "${enable_libplacebo}"], [
4124 AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
4125 ])
4126 enable_libplacebo="no"
4127 ])
4128 ])
4129 AM_CONDITIONAL(HAVE_LIBPLACEBO, [test "$enable_libplacebo" != "no"])
4132 dnl
4133 dnl Endianness check
4134 dnl
4135 AC_C_BIGENDIAN
4136 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4137 DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4138 ], [
4139 DEFS_BIGENDIAN=""
4140 ])
4141 AC_SUBST(DEFS_BIGENDIAN)
4143 dnl
4144 dnl Where to install KDE solid .desktop
4145 dnl
4146 AC_ARG_WITH(kde-solid,
4147 AS_HELP_STRING([--with-kde-solid=PATH],
4148 [KDE Solid actions directory (auto)]),, [
4150 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4151 with_kde_solid="yes"
4152 fi
4153 ])
4154 soliddatadir=""
4155 AS_IF([test "${with_kde_solid}" != "no"], [
4156 AS_IF([test "${with_kde_solid}" = "yes"], [
4157 kde4datadir="`${KDE4_CONFIG} --install data`"
4158 AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4159 soliddatadir="${kde4datadir}/solid/actions"
4160 ], [
4161 soliddatadir="${with_kde_solid}"
4162 ])
4163 ])
4164 AC_SUBST(soliddatadir)
4165 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4167 dnl
4168 dnl Find tools for win32 packaging
4169 dnl
4170 AS_IF([test "${SYS}" = "mingw32"], [
4171 dnl
4172 dnl Find makensis required to build the NSIS installer
4173 dnl
4174 nsis_major_required="3"
4175 nsis_version_ok="no"
4176 AC_PATH_PROG([MAKENSIS], [makensis], [no])
4177 AS_IF([test "$MAKENSIS" != "no"], [
4178 # Check version
4179 AC_MSG_CHECKING([makensis version])
4180 nsis_version=$($MAKENSIS -VERSION)
4181 AC_MSG_RESULT([$nsis_version])
4182 nsis_version_major=$(echo "$nsis_version" | awk -F \. '{print $1}' | sed 's/v//')
4183 # Check if major version is a valid number
4184 AS_IF([test -n "$nsis_version_major" && \
4185 test "$nsis_version_major" -eq "$nsis_version_major" 2> /dev/null], [
4186 # Do the version check using major version
4187 AS_IF([test "$nsis_version_major" -lt "$nsis_major_required"], [
4188 AC_MSG_WARN([makensis too old, (needs ${nsis_major_required}.x, have ${nsis_version_major}.x)])
4189 ], [
4190 nsis_version_ok="yes"
4191 ])
4192 ], [
4193 AC_MSG_WARN([failed to check the makensis version])
4194 ])
4195 ])
4196 dnl
4197 dnl Find 7zip
4198 dnl
4199 AC_PATH_PROG([SEVENZIP], [7z], [7z])
4200 ])
4201 AM_CONDITIONAL(HAVE_MAKENSIS, [test "x$MAKENSIS" != "xno" && test "$nsis_version_ok" = "yes"])
4203 dnl
4204 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4205 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4206 dnl
4207 if test "${SYS}" = "mingw32"; then
4208 AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4209 fi
4211 EXTEND_HELP_STRING([Components:])
4213 dnl
4214 dnl the VLC binary
4215 dnl
4216 AC_ARG_ENABLE(vlc,
4217 [ --enable-vlc build the VLC media player (default enabled)])
4218 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4220 dnl
4221 dnl Fuzzer (at the end in order to don't mess dependencies FLAGS)
4222 dnl
4223 AS_VAR_IF(with_libfuzzer, no, [], [
4224 LIBS="-lstdc++ ${LIBM} ${LIBPTHREAD} -L${with_libfuzzer} -lFuzzer"
4225 AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc-guard, [
4226 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard])
4227 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard], [CXXFLAGS])
4228 AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp])
4229 AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp], [CXXFLAGS])
4230 ], [
4231 AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc, [
4232 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc])
4233 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc], [CXXFLAGS])
4234 ], [
4235 AC_MSG_ERROR([Sanitizer coverage not supported by your compiler])
4236 ])
4237 ])
4238 ])
4240 dnl
4241 dnl Stuff used by the program
4242 dnl
4243 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4244 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4245 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4246 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4247 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4248 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4249 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4250 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4251 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4252 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4253 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4254 AC_SUBST(COPYRIGHT_MESSAGE)
4255 AC_SUBST(VERSION_MESSAGE)
4256 AC_SUBST(VERSION_MAJOR)
4257 AC_SUBST(VERSION_MINOR)
4258 AC_SUBST(VERSION_REVISION)
4259 AC_SUBST(VERSION_EXTRA)
4260 AC_SUBST(COPYRIGHT_YEARS)
4261 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4262 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4263 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4264 dnl
4265 dnl Handle substvars that use $(top_srcdir)
4266 dnl
4267 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4269 dnl
4270 dnl Configuration is finished
4271 dnl
4272 AC_SUBST(SYS)
4273 AC_SUBST(ARCH)
4274 AC_SUBST(ALIASES)
4275 AC_SUBST(ASM)
4276 AC_SUBST(MOC)
4277 AC_SUBST(RCC)
4278 AC_SUBST(UIC)
4279 AC_SUBST(WINDRES)
4280 AC_SUBST(WINE_SDK_PATH)
4281 AC_SUBST(LIBEXT)
4282 AC_SUBST(AM_CPPFLAGS)
4283 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4284 AC_SUBST(FILE_LIBVLCCORE_DLL)
4285 AC_SUBST(FILE_LIBVLC_DLL)
4287 AC_CONFIG_FILES([
4288 Makefile
4289 doc/Makefile
4290 modules/Makefile
4291 m4/Makefile
4292 po/Makefile.in
4293 share/Makefile
4294 compat/Makefile
4295 src/Makefile
4296 lib/Makefile
4297 bin/Makefile
4298 test/Makefile
4299 modules/hw/mmal/Makefile
4300 share/vlc.appdata.xml.in
4301 ])
4303 AM_COND_IF([HAVE_WIN32], [
4304 AC_CONFIG_FILES([
4305 extras/package/win32/NSIS/spad.nsi
4306 extras/package/win32/NSIS/vlc.win32.nsi
4307 extras/package/win32/msi/config.wxi
4308 ])
4309 ])
4311 AM_COND_IF([HAVE_DARWIN], [
4312 AC_CONFIG_FILES([
4313 modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4314 share/macosx/Info.plist:share/Info.plist.in
4315 ])
4316 ])
4318 dnl Generate makefiles
4319 AC_OUTPUT
4321 dnl Do we have to use make or gmake ?
4322 if make --version 2>&1|grep -q GNU
4323 then
4324 # GNU make, all seems good
4325 MAKE=make
4326 else
4327 # Known GNU make alias (on BSD)
4328 MAKE=gmake
4329 fi
4330 dnl Shortcut to nice compile message
4331 if test -n $SHELL; then
4332 SHELL=${CONFIG_SHELL-/bin/sh}
4333 fi
4334 rm -f compile
4335 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4336 echo "#! $SHELL
4337 rm -f .error\$\$
4338 ERROR=0
4339 export PATH=\"$PATH\" LANG=C
4340 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4341 test -f .error\$\$ && ERROR=1
4342 rm -f .error\$\$
4343 exit \$ERROR" >compile
4344 chmod a+x compile
4346 echo "
4347 libvlc configuration
4348 --------------------
4349 version : ${VERSION}
4350 system : ${SYS}
4351 architecture : ${ARCH}
4352 optimizations : ${enable_optimizations}"
4353 if test "${enable_vlc}" != "no"; then
4354 echo "vlc aliases :${ALIASES}"
4355 else
4356 echo "build vlc executable : no"
4357 fi
4358 echo "
4359 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."