configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2018 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 4.0.0-dev)
   6 VERSION_MAJOR=4
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=dev
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Otto Chriek"
  17 COPYRIGHT_YEARS="1996-2018"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Directories
  35 dnl
  36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  37 dnl AC_SUBST(vlcincludedir)
  38 vlcdatadir="\${datadir}/\${PKGDIR}"
  39 AC_SUBST(vlcdatadir)
  40 vlclibdir="\${libdir}/\${PKGDIR}"
  41 AC_SUBST(vlclibdir)
  42
  43 dnl
  44 dnl Check for tools
  45 dnl
  46 AC_PROG_CC
  47 AC_USE_SYSTEM_EXTENSIONS
  48 VLC_PROG_CC_C11
  49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  51 AH_TOP([
  52 #ifndef _REENTRANT
  53 # define _REENTRANT
  54 #endif
  55 ])
  56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  59
  60 AC_PROG_CXX
  61 AC_PROG_CPP
  62 AC_PROG_OBJC
  63 AC_PROG_EGREP
  64 AC_PROG_MAKE_SET
  65 AC_PROG_INSTALL
  66 AM_PROG_AS
  67 AC_PROG_LEX
  68 AC_PROG_YACC
  69
  70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  74 AS_IF([test "$BUILDCC" = "false"], [
  75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  76 ])
  77
  78 dnl Check for compiler properties
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AC_C_RESTRICT
  82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
  83
  84 dnl Extend the --help string at the current spot.
  85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  86
  87 dnl Allow binary package maintainer to pass a custom string to avoid
  88 dnl cache problem
  89 AC_ARG_WITH(binary-version,
  90     AS_HELP_STRING([--with-binary-version=STRING],
  91          [To avoid plugins cache problem between binary version]),[],[])
  92 AS_IF([test -n "${with_binary_version}"],[
  93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  94          [Binary specific version])
  95 ])
  96
  97 dnl Prevent clang from accepting unknown flags with a mere warning
  98 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
  99 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
 100
 101 dnl
 102 dnl  Check the operating system
 103 dnl
 104 HAVE_WIN64="0"
 105 HAVE_IOS="0"
 106 HAVE_OSX="0"
 107 HAVE_TVOS="0"
 108
 109 case "${host_os}" in
 110   "")
 111     SYS=unknown
 112     ;;
 113   linux*)
 114     SYS=linux
 115     ;;
 116   bsdi*)
 117     SYS=bsdi
 118     CFLAGS="${CFLAGS} -pthread"
 119     ;;
 120   freebsd*)
 121     SYS=freebsd
 122     CFLAGS="${CFLAGS} -pthread"
 123     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 124     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 125     ac_cv_ld_z_defs=no
 126     ;;
 127   openbsd*)
 128     SYS=openbsd
 129     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 130     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 131     ;;
 132   netbsd*)
 133     SYS=netbsd
 134     ;;
 135   dragonfly*)
 136     SYS=dragonfly
 137     ;;
 138   darwin*)
 139
 140     dnl Force gcc "-arch" flag
 141     ARCH_flag=""
 142     case "${host}" in
 143       i?86*)
 144         ARCH_flag="-arch i386"
 145       ;;
 146       ppc64*)
 147         ARCH_flag="-arch ppc64"
 148       ;;
 149       ppc*)
 150         ARCH_flag="-arch ppc"
 151       ;;
 152       x86_64*)
 153         ARCH_flag="-arch x86_64"
 154       ;;
 155       arm*)
 156         ac_cv_c_bigendian="no"
 157         ac_cv_c_attribute_packed="no"
 158       ;;
 159     esac
 160
 161     SYS=darwin
 162     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 163     CXX="${CXX} -stdlib=libc++ -std=c++11"
 164     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 165     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 166     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
 167     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 168     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 169     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 170
 171     AC_EGREP_CPP(yes,
 172             [#import <TargetConditionals.h>
 173              #if TARGET_OS_IPHONE
 174              yes
 175              #endif],
 176              [HAVE_IOS="1"],
 177              [HAVE_OSX="1"])
 178
 179     AC_EGREP_CPP(yes,
 180             [#import <TargetConditionals.h>
 181              #if TARGET_OS_TV
 182              yes
 183              #endif],
 184              [HAVE_TVOS="1"
 185              HAVE_IOS="0"
 186              HAVE_OSX="0"
 187              ],)
 188
 189     dnl
 190     dnl  Handle Mac OS X SDK flags
 191     dnl
 192     AC_ARG_WITH(macosx-sdk,
 193       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 194         [compile using the SDK in DIR])])
 195     if test "${with_macosx_sdk}" != "" ; then
 196         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 197         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 198         CC="${CC} -isysroot ${with_macosx_sdk}"
 199         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 200         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 201         LD="${LD} -syslibroot ${with_macosx_sdk}"
 202     fi
 203     AC_ARG_WITH(macosx-version-min,
 204       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 205         [compile for Mac OS X VERSION and above])])
 206     if test "${with_macosx_version_min}" != "" ; then
 207         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 208         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 209         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 210         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 211         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 212     fi
 213     ;;
 214   *mingw32* | *cygwin* | *wince* | *mingwce*)
 215     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 216     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 217     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 218     AC_CHECK_TOOL(WINDRES, windres, :)
 219     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 220     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 221     AH_TOP([# define _WIN32_WINNT 0x0601 /* Windows 7 */])
 222     AH_TOP([#endif])
 223     AC_DEFINE([_WIN32_WINNT], 0x0601, [Define to '0x0601' for Windows 7 APIs.])
 224     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 225     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 226     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 227     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 228     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 229     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 230     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 231     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 232     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 233     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 234     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 235
 236     case "${host_os}" in
 237       *mingw32*)
 238         SYS=mingw32
 239         ;;
 240       *cygwin*)
 241         dnl Check if we are using the mno-cygwin mode in which case we are
 242         dnl actually dealing with a mingw32 compiler.
 243         AC_EGREP_CPP(yes,
 244             [#ifdef _WIN32
 245              yes
 246              #endif],
 247             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 248         ;;
 249     esac
 250
 251     if test "${SYS}" = "mingw32"; then
 252         # DEP, ASLR, NO SEH
 253         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 254
 255         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 256         ac_default_prefix="`pwd`/_win32"
 257         DESTDIR="`pwd`/_win32/"
 258
 259         dnl
 260         dnl NSIS/MSI Installer prefix and WIN64
 261         dnl
 262         case "${host}" in
 263             amd64*|x86_64*)
 264                 HAVE_WIN64="1"
 265                 WINDOWS_ARCH="x64"
 266                 PROGRAMFILES="PROGRAMFILES64"
 267                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 268             ;;
 269             *)
 270                 WINDOWS_ARCH="x86"
 271                 PROGRAMFILES="PROGRAMFILES"
 272             ;;
 273         esac
 274         AC_SUBST(WINDOWS_ARCH)
 275         AC_SUBST(PROGRAMFILES)
 276
 277     fi
 278     ;;
 279   *nto*)
 280     SYS=nto
 281     ;;
 282   solaris*)
 283     SYS=solaris
 284     ;;
 285   hpux*)
 286     SYS=hpux
 287     ;;
 288   *os2*)
 289     SYS=os2
 290     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 291     AC_LIBOBJ([freeaddrinfo])
 292     AC_LIBOBJ([gai_strerror])
 293     AC_CHECK_FUNCS([if_nametoindex])
 294     ;;
 295   *nacl*)
 296     SYS=nacl
 297     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 298     AC_LIBOBJ([sigwait])
 299     AC_LIBOBJ([recvmsg])
 300     AC_LIBOBJ([sendmsg])
 301     ;;
 302   *)
 303     SYS="${host_os}"
 304     ;;
 305 esac
 306
 307 dnl WinRT
 308 AC_ARG_ENABLE(winstore_app,
 309      AS_HELP_STRING([--enable-winstore-app],
 310                     [Build targetted for Windows Store apps (default disabled)]))
 311
 312 vlc_winstore_app=0
 313 AS_IF([test "${SYS}" = "mingw32"],[
 314   LIBCOM="-lole32"
 315   AS_IF([test "${enable_winstore_app}" = "yes"], [
 316     vlc_winstore_app=1
 317     LIBCOM=""
 318      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 319      AC_LIBOBJ([gai_strerror])
 320     ],[])
 321   AC_SUBST(LIBCOM)
 322   ])
 323 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 324
 325 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 326 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 327
 328 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 329 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
 330 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
 331 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
 332
 333 AM_CONDITIONAL(HAVE_NACL,    test "${SYS}" = "nacl")
 334 AM_CONDITIONAL(HAVE_LIBANL,  test "${HAVE_LIBANL}" = "1")
 335
 336 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 337 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
 338 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 339 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 340
 341 dnl
 342 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 343 dnl for program foo on win32
 344 case "${build_os}" in
 345     cygwin|msys|mingw32)
 346         ac_executable_extensions=".exe"
 347         BUILDEXEEXT=".exe"
 348     ;;
 349     os2*)
 350         BUILDEXEEXT=".exe"
 351     ;;
 352     *)
 353     ;;
 354 esac
 355 AC_SUBST(BUILDEXEEXT)
 356
 357 dnl Android is linux, but a bit different
 358 AS_IF([test "$SYS" = linux],[
 359     AC_MSG_CHECKING([for an Android system])
 360     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 361         [[#ifndef __ANDROID__
 362          # error Not Android
 363          #endif
 364         ]],[[;]])
 365     ],[
 366       HAVE_ANDROID="1"
 367       AC_MSG_RESULT([yes])
 368     ],[
 369       AC_MSG_RESULT([no])
 370     ])
 371 ])
 372 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 373
 374 dnl Tizen (minimum SDK version: 2.3)
 375 AS_IF([test "$SYS" = linux],[
 376     AC_MSG_CHECKING([for Tizen])
 377     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 378         [[#include <tizen.h>
 379         ]],[[;]])
 380     ],[
 381       HAVE_TIZEN="1"
 382       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 383       AC_MSG_RESULT([yes])
 384     ],[
 385       AC_MSG_RESULT([no])
 386     ])
 387 ])
 388 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
 389
 390 dnl
 391 dnl  Check for the contrib directory
 392 dnl
 393 AC_ARG_WITH(contrib,
 394   [AS_HELP_STRING([--with-contrib[=DIR]],
 395     [search for 3rd party libraries in DIR/include and DIR/lib])
 396 ])
 397 AC_MSG_CHECKING([for 3rd party libraries path])
 398 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 399   CONTRIB_DIR="${srcdir}/contrib/${host}"
 400   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 401     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 402     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 403     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 404       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 405       CONTRIB_DIR=""
 406       AC_MSG_RESULT([not found])
 407     ])
 408   ])
 409 ], [
 410   AS_IF([test "${with_contrib}" != "no"], [
 411     CONTRIB_DIR="${with_contrib}"
 412   ], [
 413     CONTRIB_DIR=""
 414     AC_MSG_RESULT([disabled])
 415   ])
 416 ])
 417 AS_IF([test -n "${CONTRIB_DIR}"], [
 418   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 419     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 420   ], [
 421     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 422     CONTRIB_DIR=""
 423     AC_MSG_RESULT([not usable])
 424   ])
 425
 426 ])
 427 AS_IF([test -n "${CONTRIB_DIR}"], [
 428   AC_MSG_RESULT([${CONTRIB_DIR}])
 429   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 430   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 431   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 432   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
 433   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 434   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 435
 436   AS_IF([test -z "$LUAC"], [
 437     dnl Old contribs mixed cross-tools and cross-compiled executables
 438     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
 439       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
 440     ])
 441
 442     dnl Newer contribs follow usual name space rules
 443     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
 444       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
 445     ])
 446   ])
 447
 448   AS_IF([test "${SYS}" = "darwin"], [
 449     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 450     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 451   ])
 452 ], [
 453   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 454     AC_MSG_ERROR([Third party libraries not found!])
 455   ])
 456 ])
 457 AC_SUBST(CONTRIB_DIR)
 458
 459 dnl Add extras/tools to the PATH
 460 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 461 AS_IF([test -d "${TOOLS_DIR}"], [
 462     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 463     export PATH="${TOOLS_DIR}":$PATH
 464 ])
 465
 466 dnl
 467 dnl  Libtool
 468 dnl  It's very bad, but our former custom system was worst
 469 dnl  -- Courmisch
 470 dnl
 471
 472 dnl override platform specific check for dependent libraries
 473 dnl otherwise libtool linking of shared libraries will
 474 dnl fail on anything other than pass_all.
 475 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 476     [lt_cv_deplibs_check_method=pass_all])
 477
 478 LT_INIT([dlopen win32-dll shared disable-static])
 479 LT_LANG([C++])
 480 LT_LANG([Windows Resource])
 481
 482 DOLT
 483
 484 lt_cv_deplibs_check_method=pass_all
 485
 486 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 487   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 488 ])
 489
 490 dnl
 491 dnl Gettext stuff
 492 dnl
 493 AM_GNU_GETTEXT_VERSION([0.19.8])
 494 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 495
 496 dnl
 497 dnl Iconv stuff
 498 dnl
 499 AM_ICONV
 500
 501 dnl
 502 dnl checks for mingw
 503 AS_IF([test "${SYS}" = "mingw32"], [
 504
 505 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 506 #if !defined(__MINGW32__)
 507 # error Not compiling with mingw
 508 #endif
 509     ])], [
 510
 511 dnl Check for broken versions of mingw-runtime compatability library
 512     AC_MSG_CHECKING(for broken mingw-runtime)
 513     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 514 #include <_mingw.h>
 515 #if defined(__MINGW64_VERSION_MAJOR)
 516 # if __MINGW64_VERSION_MAJOR < 5
 517 #  error Update your mingw-w64! This one is too old.
 518 # endif
 519 #else
 520 # error You cannot compile with Mingw. Use Mingw-w64!
 521 #endif
 522     ])], [
 523         AC_MSG_RESULT([ok])
 524     ], [
 525         AC_MSG_RESULT([present])
 526         AC_MSG_ERROR([LibVLC requires Mingw-w64 version 5.0 or higher!])
 527     ])
 528
 529     dnl force use of mingw provided c99 *printf over msvcrt
 530     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 531
 532     dnl Check for the need to include the mingwex lib for mingw32
 533     VLC_SAVE_FLAGS
 534     AC_CHECK_LIB(mingwex,opendir,
 535         AC_CHECK_LIB(mingw32,opendir,,
 536             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 537     )
 538     VLC_RESTORE_FLAGS
 539     ], [
 540         AC_MSG_RESULT([Not compiling with mingw])
 541     ])
 542
 543     dnl Check for fnative-struct or mms-bitfields support for mingw32
 544     VLC_SAVE_FLAGS
 545     CFLAGS="${CFLAGS} -mms-bitfields"
 546     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 547     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 548         [ac_cv_c_mms_bitfields],
 549         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 550     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 551         VLC_RESTORE_FLAGS
 552         CFLAGS="${CFLAGS} -fnative-struct"
 553         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 554         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 555             [ac_cv_c_fnative_struct],
 556             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 557         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 558     fi
 559 ])
 560
 561
 562 dnl
 563 dnl Buggy glibc prevention. Purposedly not cached.
 564 dnl See sourceware.org bugs 5058 and 5443.
 565 dnl Ubuntu alone has 20 bug numbers for this...
 566 dnl
 567 AC_MSG_CHECKING(for buggy GNU/libc versions)
 568 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 569 #include <limits.h>
 570 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 571   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 572 # error GNU/libc with dcgettext killer bug!
 573 #endif
 574 ])], [
 575   AC_MSG_RESULT([not present])
 576 ], [
 577   AC_MSG_RESULT([found])
 578   AS_IF([test "x${enable_nls}" != "xno"], [
 579     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 580 work-around for this. Check with your distribution vendor on how to update the
 581 glibc run-time. Alternatively, build with --disable-nls.])
 582   ])
 583 ])
 584
 585 dnl Plugin compilation stuff
 586
 587 VLC_LIBRARY_SUFFIX
 588
 589 dnl Check for system libs needed
 590 need_libc=false
 591
 592 dnl Check for usual libc functions
 593 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime tdestroy uselocale])
 594 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tfind timegm timespec_get strverscmp pathconf])
 595 AC_REPLACE_FUNCS([gettimeofday])
 596 AC_CHECK_FUNC(fdatasync,,
 597   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 598 ])
 599
 600 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 601
 602 dnl mingw64 implements those as static inline, not functions with C linkage
 603 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 604 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 605 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 606 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 607
 608 dnl C11 static_assert()
 609 AC_MSG_CHECKING([for static_assert in assert.h])
 610 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 611 static_assert(1, "The impossible happened.");
 612 ])], [
 613   AC_MSG_RESULT([yes])
 614   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 615 ], [
 616   AC_MSG_RESULT([no])
 617 ])
 618
 619 # Windows CE does not have strcoll()
 620 AC_FUNC_STRCOLL
 621
 622 dnl Check for non-standard system calls
 623 case "$SYS" in
 624   "linux")
 625     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity recvmmsg memfd_create])
 626     ;;
 627   "mingw32")
 628     AC_CHECK_FUNCS([_lock_file])
 629     ;;
 630 esac
 631
 632 AH_BOTTOM([#include <vlc_fixups.h>])
 633
 634 dnl Check for struct pollfd
 635 AC_CHECK_TYPES([struct pollfd],,,
 636 [#include <sys/types.h>
 637 #if HAVE_POLL
 638 # include <poll.h>
 639 #elif defined (_WIN32)
 640 # include <winsock2.h>
 641 #endif
 642 ])
 643
 644 dnl Check for struct timespec
 645 AC_CHECK_TYPES([struct timespec],,,
 646 [#include <time.h>])
 647
 648 dnl Check for max_align_t
 649 AC_CHECK_TYPES([max_align_t],,,
 650 [#include <stddef.h>])
 651
 652 dnl Checks for socket stuff
 653 VLC_SAVE_FLAGS
 654 SOCKET_LIBS=""
 655 AC_SEARCH_LIBS(connect, [socket], [
 656   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 657     SOCKET_LIBS="$ac_cv_search_connect"
 658   ])
 659 ], [
 660   AS_IF([test "${SYS}" = "mingw32"], [
 661     SOCKET_LIBS="-lws2_32 -liphlpapi"
 662   ])
 663 ])
 664
 665 AC_SEARCH_LIBS([inet_pton], [nsl], [
 666  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 667     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 668   ])
 669 ],, [${SOCKET_LIBS}])
 670
 671 LIBS="${LIBS} ${SOCKET_LIBS}"
 672 AC_LINK_IFELSE([
 673     AC_LANG_PROGRAM([#ifdef _WIN32
 674         # if _WIN32_WINNT < 0x600
 675         #  error Needs vista+
 676         # endif
 677         #include <ws2tcpip.h>
 678         #else
 679         #include <sys/socket.h>
 680         #include <arpa/inet.h>
 681         #endif], [
 682         char dst[[sizeof(struct in_addr)]];
 683         inet_pton(AF_INET, "127.0.0.1", dst);
 684     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 685 AC_CHECK_FUNCS([if_nameindex])
 686 VLC_RESTORE_FLAGS
 687 AC_SUBST(SOCKET_LIBS)
 688
 689 dnl Check for socklen_t
 690 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 691 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 692 ac_cv_type_socklen_t,
 693 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 694 [#include <sys/types.h>
 695 #ifdef _WIN32
 696 # include <winsock2.h>
 697 # include <ws2tcpip.h>
 698 #else
 699 # include <sys/socket.h>
 700 #endif]], [[socklen_t len; len = 0;]])],
 701 ac_cv_type_socklen_t=yes,
 702 ac_cv_type_socklen_t=no)])
 703 AS_IF([test "$ac_cv_type_socklen_t" = no],
 704  [AC_DEFINE(socklen_t, int)])
 705
 706 dnl Check for struct sockaddr_storage
 707 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 708 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 709 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 710   [AC_TRY_COMPILE(
 711     [#include <sys/types.h>
 712      #if defined( _WIN32 )
 713      # include <winsock2.h>
 714      #else
 715      # include <sys/socket.h>
 716      #endif], [struct sockaddr_storage addr;],
 717      ac_cv_struct_sockaddr_storage=yes,
 718      ac_cv_struct_sockaddr_storage=no)])
 719 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 720   AC_DEFINE(sockaddr_storage, sockaddr)
 721   AC_DEFINE(ss_family, sa_family)
 722 ])
 723
 724 dnl FreeBSD has a gnugetopt library for this:
 725 GNUGETOPT_LIBS=""
 726 AC_CHECK_FUNC(getopt_long,, [
 727   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 728     GNUGETOPT_LIBS="-lgnugetopt"
 729   ])
 730 ])
 731 AC_SUBST(GNUGETOPT_LIBS)
 732
 733 AC_CHECK_LIB(m,cos,[
 734   LIBM="-lm"
 735 ], [
 736   LIBM=""
 737 ])
 738 AC_SUBST(LIBM)
 739
 740 AC_CHECK_LIB(m,lrintf, [
 741   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 742   VLC_ADD_LIBS([skins2],[-lm])
 743 ])
 744 AC_CHECK_LIB(m,nanf,
 745   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 746 )
 747 AC_CHECK_LIB(m,sincos, [
 748   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 749 ], [
 750   AC_LIBOBJ([sincos])
 751 ])
 752
 753 AC_MSG_CHECKING([_Thread_local support])
 754 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
 755                    int main() {}])], [
 756     AC_MSG_RESULT([ok])
 757     AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
 758 ],[ AC_MSG_RESULT([no])])
 759
 760 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
 761 dnl check for its availability explicitely
 762 AC_CHECK_HEADERS([threads.h])
 763
 764 AC_CHECK_LIB([anl],[getaddrinfo_a],[
 765   AC_DEFINE(HAVE_LIBANL, 1, [Define to 1 if you have the anl library])
 766 ])
 767
 768 dnl Check for dynamic plugins
 769 LIBDL=""
 770 have_dynamic_objects="no"
 771 VLC_SAVE_FLAGS
 772 AC_SEARCH_LIBS(dlsym, [dl svld], [
 773   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 774     LIBDL="$ac_cv_search_dlsym"
 775   ])
 776   have_dynamic_objects="yes"
 777 ])
 778 VLC_RESTORE_FLAGS
 779
 780 # Windows
 781 AS_IF([test "${SYS}" = "mingw32"], [
 782   LIBDL=""
 783   have_dynamic_objects="yes" #assume we can use shared objects
 784 ])
 785
 786 AC_ARG_WITH([libfuzzer],
 787     [AS_HELP_STRING([--with-libfuzzer=DIR],
 788         [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)])],
 789      [],
 790      [with_libfuzzer=no])
 791 AS_VAR_IF(with_libfuzzer, no, [], [
 792     enable_shared=no
 793     enable_static=yes
 794     enable_vlc=no
 795 ])
 796 AM_CONDITIONAL(HAVE_LIBFUZZER, [test "${with_libfuzzer}" != "no"])
 797
 798 AS_IF([test "${enable_shared}" = "no"], [
 799   have_dynamic_objects=no
 800 ])
 801 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 802
 803 AC_SUBST(LIBDL)
 804
 805 dnl Check for thread library
 806 LIBPTHREAD=""
 807 AS_IF([test "${SYS}" != "mingw32"], [
 808   VLC_SAVE_FLAGS
 809   LIBS=""
 810   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 811     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 812       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 813     ])
 814   ])
 815   VLC_RESTORE_FLAGS
 816 ])
 817 AC_SUBST(LIBPTHREAD)
 818
 819 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 820   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 821     LIBRT="$ac_cv_search_clock_nanosleep"
 822   ])
 823 ], [
 824   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 825     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 826       LIBRT="$ac_cv_search_nanosleep"
 827     ])
 828   ])
 829 ])
 830 AC_SUBST(LIBRT)
 831
 832 dnl
 833 dnl Check for headers
 834 dnl
 835
 836 dnl  POSIX
 837 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 838 AC_CHECK_HEADERS([net/if.h], [], [],
 839 [
 840 #include <sys/types.h>
 841 #include <sys/socket.h>
 842 ])
 843 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 844 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 845
 846 dnl  BSD
 847 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
 848
 849 dnl  GNU/Linux
 850 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 851
 852 dnl  MacOS
 853 AC_CHECK_HEADERS([xlocale.h])
 854
 855 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 856 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 857 AC_CHECK_TYPE(ssize_t,, [
 858   AC_DEFINE(ssize_t, int)
 859 ])
 860
 861 dnl It seems that autoconf detects pkg-config only during the first
 862 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 863 dnl it is nested within a conditional block, so it was not working right.
 864 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 865 AC_ARG_VAR(PKG_CONFIG_PATH,
 866        [Paths where to find .pc not at the default location])
 867 PKG_PROG_PKG_CONFIG()
 868
 869 dnl On some OS we need static linking
 870 AS_IF([test -n "${PKG_CONFIG}" ],[
 871     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 872         PKG_CONFIG="${PKG_CONFIG} --static"
 873     ])
 874 ])
 875
 876
 877 dnl
 878 dnl Check for zlib.h and -lz along with system -lminizip if available
 879 dnl
 880 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 881 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 882 if test "${have_zlib}" = "yes"
 883 then
 884   VLC_ADD_LIBS([sap],[-lz])
 885   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 886     AC_CHECK_HEADERS([unzip.h], [
 887       have_minizip=yes
 888       MINIZIP_LIBS="-lminizip -lz"
 889     ], [
 890       have_minizip=no
 891     ])
 892   ])
 893 fi
 894 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 895
 896
 897 dnl
 898 dnl Domain name i18n support via GNU libidn
 899 dnl
 900 PKG_CHECK_MODULES([IDN], [libidn], [
 901   have_libidn="yes"
 902   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 903 ], [
 904   have_libidn="no"
 905 ])
 906
 907
 908 dnl Check for dbus
 909 AC_ARG_ENABLE(dbus,
 910   [AS_HELP_STRING([--enable-dbus],
 911     [compile D-Bus message bus support (default enabled)])])
 912 have_dbus="no"
 913 AS_IF([test "${enable_dbus}" != "no"], [
 914   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 915     have_dbus="yes"
 916   ], [
 917     AS_IF([test -n "${enable_dbus}"], [
 918       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 919     ], [
 920       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 921     ])
 922   ])
 923 ])
 924 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 925
 926
 927 dnl Check for systemd
 928 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 929   have_systemd="yes"
 930 ], [
 931   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 932 ])
 933 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 934
 935
 936 EXTEND_HELP_STRING([Optimization options:])
 937 dnl
 938 dnl  Compiler warnings
 939 dnl
 940
 941 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CFLAGS])
 942 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CXXFLAGS])
 943
 944 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local], [CFLAGS])
 945 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
 946
 947 dnl
 948 dnl  Debugging mode
 949 dnl
 950 AC_ARG_ENABLE(debug,
 951   [AS_HELP_STRING([--enable-debug],
 952     [build with run-time assertions (default disabled)])],,
 953   [enable_debug="no"])
 954 AH_TEMPLATE(NDEBUG,
 955             [Define to 1 if debug code should NOT be compiled])
 956 AS_IF([test "${enable_debug}" != "no"], [
 957   AC_CHECK_HEADERS([valgrind/valgrind.h])
 958 ], [
 959   AC_DEFINE(NDEBUG)
 960 ])
 961
 962 dnl
 963 dnl  Profiling
 964 dnl
 965 AC_ARG_ENABLE(gprof,
 966   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 967   [enable_gprof="no"])
 968 AS_IF([test "${enable_gprof}" != "no"], [
 969   CFLAGS="${CFLAGS} -pg"
 970   CXXFLAGS="${CXXFLAGS} -pg"
 971   OBJCFLAGS="${OBJCFLAGS} -pg"
 972   LDFLAGS="${LDFLAGS} -pg"
 973 ])
 974
 975 AC_ARG_ENABLE(cprof,
 976   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 977   [enable_cprof="no"])
 978 AS_IF([test "${enable_gprof}" != "no"], [
 979   CFLAGS="${CFLAGS} -finstrument-functions"
 980   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 981   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 982   LDFLAGS="${LDFLAGS} -finstrument-functions"
 983 ])
 984
 985 dnl
 986 dnl  Test coverage
 987 dnl
 988 AC_ARG_ENABLE(coverage,
 989   [AS_HELP_STRING([--enable-coverage],
 990     [build for test coverage (default disabled)])],,
 991   [enable_coverage="no"])
 992 AS_IF([test "${enable_coverage}" != "no"], [
 993   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 994   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 995   LDFLAGS="-lgcov ${LDFLAGS}"
 996 ])
 997
 998 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 999   VLC_SAVE_FLAGS
1000   CFLAGS="${CFLAGS} -fvisibility=hidden"
1001   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
1002   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1003   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1004                  [ac_cv_c_visibility_hidden], [
1005     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1006       ac_cv_c_visibility_hidden=yes
1007     ], [
1008       ac_cv_c_visibility_hidden=no
1009     ])
1010   ])
1011   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1012 ])
1013
1014 dnl
1015 dnl Sanitizer flags
1016 dnl
1017 AC_ARG_WITH([sanitizer],
1018     [AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1019         [build with sanitizer flags (default disabled)])],
1020      [],
1021      [with_sanitizer=no])
1022
1023 AS_VAR_IF(with_sanitizer, no, [], [
1024     AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1025         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1026         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1027         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1028     ], [
1029         AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1030     ])
1031     AX_APPEND_FLAG([-g])
1032     AX_APPEND_FLAG([-g], [CXXFLAGS])
1033
1034     AS_IF([test -z "${with_sanitizer##*address*}" ], [
1035        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer])
1036        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer], [CXXFLAGS])
1037     ])
1038     AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1039         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1040         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1041     ])
1042     AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1043         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1044         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1045     ])
1046 ])
1047
1048 dnl
1049 dnl  Enable/disable optimizations
1050 dnl
1051 AC_ARG_ENABLE(optimizations,
1052   [AS_HELP_STRING([--disable-optimizations],
1053     [disable compiler optimizations (default enabled)])],,
1054   [enable_optimizations="yes"])
1055
1056 dnl Check for various optimization flags
1057 AS_IF([test "${enable_optimizations}" != "no"], [
1058
1059   dnl -O3 only in production builds
1060   AS_IF([test "${enable_debug}" = "no"], [
1061     VLC_SAVE_FLAGS
1062     CFLAGS="${CFLAGS} -O3"
1063     CXXFLAGS="${CXXFLAGS} -O3"
1064     OBJCFLAGS="${OBJCFLAGS} -O3"
1065     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1066       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1067         ac_cv_c_o3=yes
1068       ], [
1069         ac_cv_c_o3=no
1070       ])
1071     ])
1072     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1073   ])
1074
1075   dnl Check for fast maths
1076   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1077   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1078
1079 AH_BOTTOM([
1080 #if defined(_MSC_VER) && !defined(__clang__)
1081 # pragma fenv_access(off)
1082 # pragma fp_contract(on)
1083 #elif defined(__GNUC__)
1084 /* Not supported so far */
1085 #else
1086 # pragma STDC FENV_ACCESS OFF
1087 # pragma STDC FP_CONTRACT ON
1088 #endif
1089 ])
1090
1091   dnl Check for -funroll-loops
1092   VLC_SAVE_FLAGS
1093   CFLAGS="${CFLAGS} -funroll-loops"
1094   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1095   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1096   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1097     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1098       ac_cv_c_unroll_loops=yes
1099     ], [
1100       ac_cv_c_unroll_loops=no
1101     ])
1102   ])
1103   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1104
1105   AS_IF([test "$enable_debug" = "no"], [
1106     dnl Check for -fomit-frame-pointer
1107     VLC_SAVE_FLAGS
1108     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1109     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1110     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1111     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1112       [ac_cv_c_omit_frame_pointer], [
1113       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1114         ac_cv_c_omit_frame_pointer=yes
1115       ], [
1116         ac_cv_c_omit_frame_pointer=no
1117       ])
1118     ])
1119     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1120   ])
1121
1122   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1123   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1124   dnl Win32 requires linking to ssp for stack-protection
1125   AS_IF([test "${SYS}" = "mingw32"], [
1126       LDFLAGS="${LDFLAGS} -lssp"
1127       AS_IF([test "${vlc_winstore_app}" != 1], [LDFLAGS="${LDFLAGS} -ladvapi32"])
1128   ])
1129 ])
1130
1131 VLC_SAVE_FLAGS
1132 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1133 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1134   AC_TRY_LINK([],, [
1135     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1136   ], [
1137     ac_cv_ld_bsymbolic=""
1138   ])
1139 ])
1140 VLC_RESTORE_FLAGS
1141 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1142 AC_SUBST(SYMBOLIC_LDFLAGS)
1143
1144 VLC_SAVE_FLAGS
1145 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1146 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1147   AC_TRY_LINK([],, [
1148     ac_cv_ld_z_defs="yes"
1149   ], [
1150     ac_cv_ld_z_defs="no"
1151   ])
1152 ])
1153 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1154
1155 dnl Check for __attribute__((packed))
1156 AC_CACHE_CHECK([for __attribute__((packed))],
1157   [ac_cv_c_attribute_packed],
1158   [ac_cv_c_attribute_packed=no
1159    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1160                     [ac_cv_c_attribute_packed=yes])])
1161 if test "${ac_cv_c_attribute_packed}" != "no"; then
1162   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1163 fi
1164
1165 dnl
1166 dnl  Check the CPU
1167 dnl
1168 case "${host_cpu}" in
1169   "")
1170     ARCH=unknown
1171     ;;
1172   *)
1173     ARCH="${host_cpu}"
1174     ;;
1175 esac
1176
1177 dnl Check for backtrace() support
1178 AC_CHECK_HEADERS(execinfo.h)
1179 AC_CHECK_FUNCS(backtrace)
1180
1181 dnl
1182 dnl  default modules
1183 dnl
1184 ALIASES="${ALIASES} cvlc rvlc"
1185
1186 dnl
1187 dnl  Accelerated modules
1188 dnl
1189
1190 dnl  Check for fully working MMX intrinsics
1191 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1192 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1193 AC_ARG_ENABLE(mmx,
1194   [AS_HELP_STRING([--disable-mmx],
1195     [disable MMX optimizations (default auto)])],,[
1196   case "${host_cpu}" in
1197     i?86|x86_64)
1198       enable_mmx="yes"
1199       ;;
1200     *)
1201       enable_mmx="no"
1202       ;;
1203   esac
1204 ])
1205 have_mmx="no"
1206 have_mmxext="no"
1207 AS_IF([test "${enable_mmx}" != "no"], [
1208   ARCH="${ARCH} mmx"
1209   VLC_SAVE_FLAGS
1210   CFLAGS="${CFLAGS} -mmmx"
1211   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1212     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1213 [#include <mmintrin.h>
1214 #include <stdint.h>
1215 uint64_t frobzor;]], [
1216 [__m64 a, b, c;
1217 a = b = c = (__m64)frobzor;
1218 a = _mm_slli_pi16(a, 3);
1219 a = _mm_adds_pi16(a, b);
1220 c = _mm_srli_pi16(c, 8);
1221 c = _mm_slli_pi16(c, 3);
1222 b = _mm_adds_pi16(b, c);
1223 a = _mm_unpacklo_pi8(a, b);
1224 frobzor = (uint64_t)a;]])], [
1225       ac_cv_c_mmx_intrinsics=yes
1226     ], [
1227       ac_cv_c_mmx_intrinsics=no
1228     ])
1229   ])
1230   VLC_RESTORE_FLAGS
1231   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1232     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1233   ])
1234
1235   VLC_SAVE_FLAGS
1236   CFLAGS="${CFLAGS} -mmmx"
1237   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1238     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1239 void *p;
1240 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1241 ]])
1242     ], [
1243       ac_cv_mmx_inline=yes
1244     ], [
1245       ac_cv_mmx_inline=no
1246     ])
1247   ])
1248   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1249     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1250     have_mmx="yes"
1251   ])
1252
1253   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1254                  [ac_cv_mmxext_inline], [
1255     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1256 void *p;
1257 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1258 ]])
1259     ], [
1260       ac_cv_mmxext_inline=yes
1261     ], [
1262       ac_cv_mmxext_inline=no
1263     ])
1264   ])
1265   VLC_RESTORE_FLAGS
1266   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1267     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1268     have_mmxext="yes"
1269   ])
1270 ])
1271 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1272 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1273
1274 dnl  Check for fully workin SSE2 intrinsics
1275 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1276 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1277 AC_ARG_ENABLE(sse,
1278   [AS_HELP_STRING([--disable-sse],
1279     [disable SSE (1-4) optimizations (default auto)])],, [
1280   case "${host_cpu}" in
1281     i?86|x86_64)
1282       enable_sse=yes
1283       ;;
1284     *)
1285       enable_sse=no
1286       ;;
1287   esac
1288 ])
1289 have_sse2="no"
1290 AS_IF([test "${enable_sse}" != "no"], [
1291   ARCH="${ARCH} sse sse2"
1292
1293   VLC_SAVE_FLAGS
1294   CFLAGS="${CFLAGS} -msse2"
1295   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1296     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1297 [#include <emmintrin.h>
1298 #include <stdint.h>
1299 uint64_t frobzor;]], [
1300 [__m128i a, b, c;
1301 a = b = c = _mm_set1_epi64((__m64)frobzor);
1302 a = _mm_slli_epi16(a, 3);
1303 a = _mm_adds_epi16(a, b);
1304 c = _mm_srli_epi16(c, 8);
1305 c = _mm_slli_epi16(c, 3);
1306 b = _mm_adds_epi16(b, c);
1307 a = _mm_unpacklo_epi8(a, b);
1308 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1309       ac_cv_c_sse2_intrinsics=yes
1310     ], [
1311       ac_cv_c_sse2_intrinsics=no
1312     ])
1313   ])
1314   VLC_RESTORE_FLAGS
1315   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1316     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1317   ])
1318
1319   VLC_SAVE_FLAGS
1320   CFLAGS="${CFLAGS} -msse"
1321   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1322     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1323 void *p;
1324 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1325 ]])
1326     ], [
1327       ac_cv_sse_inline=yes
1328     ], [
1329       ac_cv_sse_inline=no
1330     ])
1331   ])
1332
1333   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1334     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1335   ])
1336
1337   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1338     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1339 void *p;
1340 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1341 ]])
1342     ], [
1343       ac_cv_sse2_inline=yes
1344     ], [
1345       ac_cv_sse2_inline=no
1346     ])
1347   ])
1348   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1349     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1350     have_sse2="yes"
1351   ])
1352
1353   # SSE3
1354   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1355     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1356 void *p;
1357 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1358 ]])
1359     ], [
1360       ac_cv_sse3_inline=yes
1361     ], [
1362       ac_cv_sse3_inline=no
1363     ])
1364   ])
1365
1366   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1367     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1368   # SSSE3
1369   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1370     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1371 void *p;
1372 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1373 ]])
1374     ], [
1375       ac_cv_ssse3_inline=yes
1376     ], [
1377       ac_cv_ssse3_inline=no
1378     ])
1379   ])
1380
1381   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1382     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1383
1384   # SSE4.1
1385   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1386                  [ac_cv_sse4_1_inline], [
1387     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1388 void *p;
1389 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1390 ]])
1391     ], [
1392       ac_cv_sse4_1_inline=yes
1393     ], [
1394       ac_cv_sse4_1_inline=no
1395     ])
1396   ])
1397
1398   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1399     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1400
1401   # SSE4.2
1402   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1403                  [ac_cv_sse4_2_inline], [
1404     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1405 void *p;
1406 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1407 ]])
1408     ], [
1409       ac_cv_sse4_2_inline=yes
1410     ], [
1411       ac_cv_sse4_2_inline=no
1412     ])
1413   ])
1414
1415   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1416     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1417
1418   # SSE4A
1419   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1420     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1421 void *p;
1422 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1423 ]])
1424     ], [
1425       ac_cv_sse4a_inline=yes
1426     ], [
1427       ac_cv_sse4a_inline=no
1428     ])
1429   ])
1430   VLC_RESTORE_FLAGS
1431   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1432     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1433 ])
1434 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1435
1436 VLC_SAVE_FLAGS
1437 CFLAGS="${CFLAGS} -mmmx"
1438 have_3dnow="no"
1439 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1440   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1441 void *p;
1442 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1443 ]])
1444   ], [
1445     ac_cv_3dnow_inline=yes
1446   ], [
1447     ac_cv_3dnow_inline=no
1448   ])
1449 ])
1450 VLC_RESTORE_FLAGS
1451 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1452   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1453             [Define to 1 if 3D Now! inline assembly is available.])
1454   have_3dnow="yes"
1455 ])
1456 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1457
1458
1459 AC_ARG_ENABLE(neon,
1460   [AS_HELP_STRING([--disable-neon],
1461     [disable NEON optimizations (default auto)])],, [
1462   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1463 ])
1464 AS_IF([test "${enable_neon}" != "no"], [
1465   VLC_SAVE_FLAGS
1466   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1467   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1468     AC_COMPILE_IFELSE([
1469       AC_LANG_PROGRAM(,[[
1470 asm volatile("vqmovun.s64 d0, q1":::"d0");
1471 ]])
1472     ], [
1473       ac_cv_arm_neon="yes"
1474     ], [
1475       ac_cv_arm_neon="no"
1476     ])
1477   ])
1478   VLC_RESTORE_FLAGS
1479 ])
1480 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1481
1482 AC_ARG_ENABLE(arm64,
1483   [AS_HELP_STRING([--disable-arm64],
1484     [disable arm 64-bit optimizations (default auto)])],, [
1485   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1486 ])
1487 AS_IF([test "${enable_arm64}" != "no"], [
1488   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1489     AC_COMPILE_IFELSE([
1490       AC_LANG_PROGRAM(,[[
1491 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1492 ]])
1493     ], [
1494       ac_cv_arm64="yes"
1495     ], [
1496       ac_cv_arm64="no"
1497     ])
1498   ])
1499 ])
1500 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1501
1502
1503 AC_ARG_ENABLE(altivec,
1504   [AS_HELP_STRING([--disable-altivec],
1505     [disable AltiVec optimizations (default auto)])],, [
1506   AS_CASE("${host_cpu}", [powerpc*],
1507         [enable_altivec=yes], [enable_altivec=no])
1508 ])
1509 have_altivec="no"
1510 ALTIVEC_CFLAGS=""
1511 AS_IF([test "${enable_altivec}" = "yes"], [
1512   ARCH="${ARCH} altivec";
1513   VLC_SAVE_FLAGS
1514   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1515     [ac_cv_altivec_inline],
1516     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1517          ac_cv_altivec_inline="yes",
1518          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1519           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1520             [ac_cv_altivec_inline="-Wa,-maltivec"],
1521             ac_cv_altivec_inline=no)
1522          ])])
1523   VLC_RESTORE_FLAGS
1524   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1525     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1526               [Define to 1 if AltiVec inline assembly is available.])
1527     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1528       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1529       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1530     ])
1531     have_altivec="yes"
1532   ])
1533
1534   VLC_SAVE_FLAGS
1535   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1536   [ac_cv_c_altivec], [
1537     CFLAGS="${CFLAGS} -maltivec"
1538     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1539 [#include <altivec.h>]], [
1540 [vec_ld(0, (unsigned char *)0);]])], [
1541       ac_cv_c_altivec="-maltivec"
1542     ], [
1543       ac_cv_c_altivec="no"
1544     ])
1545   ])
1546   VLC_RESTORE_FLAGS
1547   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1548     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1549     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1550     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1551     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1552     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1553     have_altivec="yes"
1554   ])
1555   AC_CHECK_HEADERS(altivec.h)
1556
1557   VLC_SAVE_FLAGS
1558   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1559   AC_CACHE_CHECK([if linker needs -framework vecLib],
1560     [ac_cv_ld_altivec],
1561     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1562   VLC_RESTORE_FLAGS
1563   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1564     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1565   ])
1566 ])
1567 AC_SUBST(ALTIVEC_CFLAGS)
1568 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1569
1570 dnl
1571 dnl  Memory usage
1572 dnl
1573 AC_ARG_ENABLE(optimize-memory,
1574   [AS_HELP_STRING([--enable-optimize-memory],
1575     [optimize memory usage over performance])])
1576 if test "${enable_optimize_memory}" = "yes"; then
1577   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1578 fi
1579
1580 dnl
1581 dnl Allow running as root (useful for people running on embedded platforms)
1582 dnl
1583 AC_ARG_ENABLE(run-as-root,
1584   [AS_HELP_STRING([--enable-run-as-root],
1585     [allow running VLC as root (default disabled)])])
1586 AS_IF([test "${enable_run_as_root}" = "yes"],[
1587     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1588               [Define to 1 to allow running VLC as root (uid 0).])
1589 ])
1590
1591 dnl
1592 dnl Stream output
1593 dnl
1594 AC_ARG_ENABLE(sout,
1595   [AS_HELP_STRING([--disable-sout],
1596     [disable streaming output (default enabled)])])
1597 AS_IF([test "${enable_sout}" != "no"], [
1598   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1599 ])
1600 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1601
1602 dnl Lua modules
1603 AC_ARG_ENABLE(lua,
1604   [AS_HELP_STRING([--disable-lua],
1605     [disable LUA scripting support (default enabled)])])
1606 if test "${enable_lua}" != "no"
1607 then
1608   PKG_CHECK_MODULES(LUA, lua5.2,
1609     [ have_lua=yes ],
1610     [
1611     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1612
1613     PKG_CHECK_MODULES(LUA, lua5.1,
1614       [ have_lua=yes ],
1615       [
1616       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1617       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1618         [ have_lua=yes ],
1619         [
1620           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1621           have_lua=yes
1622           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1623             [],
1624             [ have_lua=no ] )
1625           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1626             [LUA_LIBS="-llua5.2"],
1627           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1628             [LUA_LIBS="-llua5.1"],
1629             AC_CHECK_LIB( lua51 , luaL_newstate,
1630               [LUA_LIBS="-llua51"],
1631               AC_CHECK_LIB( lua , luaL_newstate,
1632                 [LUA_LIBS="-llua"],
1633                 [ have_lua=no
1634                 ], [-lm])
1635             )))
1636         ])
1637       ])
1638     ])
1639   if test "x${have_lua}" != "xyes" ;  then
1640       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1641   fi
1642   AC_ARG_VAR([LUAC], [LUA byte compiler])
1643   AS_IF([test -z "$LUAC"], [
1644      AC_CHECK_TOOL(LUAC, [luac], [false])
1645   ])
1646   AS_IF([test "${LUAC}" = "false"], [
1647     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1648   ])
1649   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1650     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1651   ])
1652 fi
1653 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1654
1655
1656 dnl
1657 dnl VideoLAN manager
1658 dnl
1659 AC_ARG_ENABLE(vlm,
1660   [AS_HELP_STRING([--disable-vlm],
1661     [disable the stream manager (default enabled)])],,
1662   [enable_vlm="${enable_sout}"])
1663 AS_IF([test "${enable_vlm}" != "no"], [
1664   AS_IF([test "${enable_sout}" = "no"], [
1665     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1666   ])
1667   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1668 ])
1669 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1670
1671
1672 dnl
1673 dnl Addons manager storage and repositories modules
1674 dnl
1675 AC_ARG_ENABLE(addonmanagermodules,
1676   [AS_HELP_STRING([--disable-addonmanagermodules],
1677     [disable the addons manager modules (default enabled)])])
1678 if test "${enable_addonmanagermodules}" != "no"
1679 then
1680   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1681 fi
1682 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1683
1684
1685 dnl
1686 dnl  Input plugins
1687 dnl
1688
1689 EXTEND_HELP_STRING([Input plugins:])
1690
1691 dnl
1692 dnl  libarchive access module
1693 dnl
1694 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1695
1696 dnl
1697 dnl  live555 input
1698 dnl
1699 AC_ARG_ENABLE(live555,
1700   [AS_HELP_STRING([--enable-live555],
1701     [enable RTSP input through live555 (default enabled)])])
1702
1703 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1704   PKG_CHECK_MODULES(LIVE555, live555, [
1705     VLC_ADD_PLUGIN([live555])
1706     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1707     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1708   ], [
1709     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1710
1711     AC_LANG_PUSH(C++)
1712     VLC_SAVE_FLAGS
1713
1714     dnl detect include paths
1715     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1716       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1717     ], [
1718       AS_IF([test "${SYS}" != "os2"], [
1719         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1720         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1721       ], [
1722         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1723         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1724         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1725       ])
1726     ])
1727
1728     dnl CPP Flags
1729     AS_IF([test "${SYS}" = "solaris"], [
1730       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1731     ])
1732     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1733     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1734
1735     dnl version check
1736     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1737       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1738 [#include <liveMedia_version.hh>
1739 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1740 # error BOOM
1741 #endif]])
1742       ], [
1743         ac_cv_live555="yes"
1744       ], [
1745         ac_cv_live555="no"
1746       ])
1747     ])
1748
1749     AS_IF([test "$ac_cv_live555" = "no"], [
1750       AC_MSG_WARN([live555 is missing or its installed version is too old:
1751 Version 2011.12.23 or later is required to proceed.
1752 You can get an updated one from http://www.live555.com/liveMedia .])
1753       AS_IF([test -n "${enable_live555}"], [
1754         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1755       ])
1756     ], [
1757       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1758       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1759       AS_IF([test "${SYS}" = "mingw32"], [
1760         # add ws2_32 for closesocket, select, recv
1761         other_libs="$other_libs -lws2_32"
1762       ])
1763
1764       dnl We need to check for pic because live555 don't provide shared libs
1765       dnl and we want to build a plugins so we need -fPIC on some arch.
1766       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1767       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1768       AC_CHECK_LIB(liveMedia_pic, main, [
1769         VLC_ADD_PLUGIN([live555])
1770         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1771       ],[
1772         AC_CHECK_LIB(liveMedia, main, [
1773           VLC_ADD_PLUGIN([live555])
1774           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1775         ],[],[${other_libs}])
1776       ],[${other_libs_pic}])
1777     ])
1778     VLC_RESTORE_FLAGS
1779     AC_LANG_POP(C++)
1780   ])
1781 ])
1782
1783 dnl
1784 dnl IIDC and DV FireWire input modules
1785 dnl
1786 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1787 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1788
1789 dnl
1790 dnl - linsys modules: access module check for libzvbi
1791 dnl
1792 AC_ARG_ENABLE(linsys,
1793   [AS_HELP_STRING([--enable-linsys],
1794     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1795 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1796   VLC_ADD_PLUGIN([linsys_hdsdi])
1797   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1798     VLC_ADD_PLUGIN([linsys_sdi])
1799   ], [
1800     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1801   ])
1802 ])
1803
1804 dnl
1805 dnl dvdread module: check for libdvdread
1806 dnl
1807 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1808
1809 dnl
1810 dnl libdvdnav plugin
1811 dnl
1812 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1813 AS_IF([test "${enable_dvdnav}" != "no"], [
1814   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1815     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1816       AC_MSG_RESULT(yes)
1817       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1818       ],[
1819       AC_MSG_RESULT(no)
1820     ])
1821 ])
1822
1823 dnl
1824 dnl  Blu-ray Disc Support with libbluray
1825 dnl
1826 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1827
1828 dnl
1829 dnl  OpenCV wrapper and example filters
1830 dnl
1831 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1832
1833
1834 dnl
1835 dnl  libsmbclient plugin
1836 dnl
1837 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1838 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" != "yes"], [ VLC_ADD_PLUGIN([smb]) ])
1839
1840 dnl
1841 dnl  liBDSM access module
1842 dnl
1843 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1844
1845 dnl
1846 dnl sftp access support
1847 dnl
1848 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1849
1850 dnl
1851 dnl nfs access support
1852 dnl
1853 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1854
1855 dnl
1856 dnl  Video4Linux 2
1857 dnl
1858 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1859   [disable Video4Linux version 2 (default auto)])])
1860 have_v4l2="no"
1861 AS_IF([test "$enable_v4l2" != "no"], [
1862   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1863     have_v4l2="yes"
1864   ])
1865 ])
1866 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1867
1868 dnl
1869 dnl special access module for Blackmagic SDI cards
1870 dnl
1871 AC_ARG_ENABLE(decklink,
1872   [AS_HELP_STRING([--disable-decklink],
1873     [disable Blackmagic DeckLink SDI input (default auto)])])
1874 AC_ARG_WITH(decklink_sdk,
1875   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1876     [                        location of Blackmagic DeckLink SDI SDK])])
1877 have_decklink=no
1878 if test "${enable_decklink}" != "no"
1879 then
1880   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1881   then
1882     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1883   fi
1884   VLC_SAVE_FLAGS
1885   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1886   AC_LANG_PUSH(C++)
1887   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1888       have_decklink=yes
1889   ], [
1890       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1891   ])
1892   AC_LANG_POP(C++)
1893   VLC_RESTORE_FLAGS
1894 fi
1895 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1896
1897
1898 dnl
1899 dnl  Built-in CD-DA and VCD module
1900 dnl
1901 AC_ARG_ENABLE(vcd,
1902   [AS_HELP_STRING([--disable-vcd],
1903     [disable built-in VCD and CD-DA support (default enabled)])])
1904
1905 AC_ARG_ENABLE(libcddb,
1906   [AS_HELP_STRING([--disable-libcddb],
1907     [disable CDDB for Audio CD (default enabled)])])
1908
1909 if test "${enable_vcd}" != "no"
1910 then
1911   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1912   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1913     AC_MSG_RESULT(yes)
1914     VLC_ADD_PLUGIN([vcd cdda])
1915   ],[
1916     AC_MSG_RESULT(no)
1917   ])
1918
1919   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1920   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1921     AC_MSG_RESULT(yes)
1922     VLC_ADD_PLUGIN([vcd cdda])
1923     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1924   ],[
1925     AC_MSG_RESULT(no)
1926   ])
1927
1928   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1929   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1930     AC_MSG_RESULT(yes)
1931     VLC_ADD_PLUGIN([vcd cdda])
1932     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1933   ],[
1934     AC_MSG_RESULT(no)
1935   ])
1936
1937   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1938   then
1939     VLC_ADD_PLUGIN([vcd cdda])
1940   fi
1941
1942   if test "$enable_libcddb" != "no"; then
1943     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1944       HAVE_LIBCDDB=yes
1945       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1946       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1947       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1948       ],:
1949       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1950       HAVE_LIBCDDB=no])
1951   fi
1952 fi
1953
1954 dnl
1955 dnl Linux DVB
1956 dnl
1957 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1958   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1959 [#include <linux/dvb/version.h>
1960 #if (DVB_API_VERSION < 5)
1961 # error Linux DVB API v3.2 and older are not supported.
1962 #endif
1963 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1964 # error Linux DVB API v5.0 is unsupported. Please update.
1965 #endif
1966 ]])], [
1967   ac_cv_linux_dvb_5_1=yes
1968 ], [
1969   ac_cv_linux_dvb_5_1=no
1970 ])])
1971 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1972
1973 dnl
1974 dnl  Screen capture module
1975 dnl
1976 AC_ARG_ENABLE(screen,
1977   [AS_HELP_STRING([--enable-screen],
1978     [disable screen capture (default enabled)])])
1979 if test "${enable_screen}" != "no"; then
1980   if test "${SYS}" = "darwin"; then
1981     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1982       VLC_ADD_PLUGIN([screen])
1983     ])
1984   fi
1985 fi
1986 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1987
1988 dnl
1989 dnl  VNC/RFB access module
1990 dnl
1991 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1992
1993 dnl  RDP/Remote Desktop access module
1994 dnl
1995 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1996
1997 dnl
1998 dnl  Real RTSP plugin
1999 dnl
2000 AC_ARG_ENABLE(realrtsp,
2001   [  --enable-realrtsp       Real RTSP module (default disabled)])
2002 if test "${enable_realrtsp}" = "yes"; then
2003   VLC_ADD_PLUGIN([access_realrtsp])
2004 fi
2005
2006 dnl
2007 dnl QTKit
2008 AC_ARG_ENABLE(macosx-qtkit,
2009   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
2010 if test "x${enable_macosx_qtkit}" != "xno" &&
2011   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2012 then
2013   AC_CHECK_HEADERS(QTKit/QTKit.h, [
2014       VLC_ADD_PLUGIN([qtsound])
2015     ])
2016 fi
2017
2018 dnl
2019 dnl AVFoundation
2020 AC_SUBST(have_avfoundation, ["no"])
2021 AC_ARG_ENABLE(macosx-avfoundation,
2022   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2023 if test "x${enable_macosx_avfoundation}" != "xno" &&
2024   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2025 then
2026   SAVED_LIBS="${LIBS}"
2027   LIBS="-framework AVFoundation"
2028   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2029   LIBS="${SAVED_LIBS}"
2030   if test "${have_avfoundation}" != "no"
2031   then
2032     VLC_ADD_PLUGIN([avcapture])
2033   fi
2034 fi
2035 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2036
2037 dnl
2038 dnl  DCP plugin (using asdcplib)
2039 dnl
2040 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2041 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2042
2043 dnl
2044 dnl  Demux plugins
2045 dnl
2046
2047 EXTEND_HELP_STRING([Mux/Demux plugins:])
2048
2049 dnl
2050 dnl  libdvbpsi check for ts mux/demux
2051 dnl
2052 have_dvbpsi="no"
2053 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2054 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2055
2056
2057 dnl
2058 dnl  GME demux plugin
2059 dnl
2060 AC_ARG_ENABLE(gme,
2061   [AS_HELP_STRING([--enable-gme],
2062     [use Game Music Emu (default auto)])])
2063 AS_IF([test "${enable_gme}" != "no"], [
2064   AC_CHECK_HEADER([gme/gme.h], [
2065     AC_CHECK_LIB([gme], [gme_identify_header], [
2066       VLC_ADD_PLUGIN([gme])
2067     ], [
2068       AC_CHECK_LIB([gme], [gme_identify_extension], [
2069          VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2070          VLC_ADD_PLUGIN([gme])
2071       ],, [-lstdc++ $LIBM])
2072     ])
2073     VLC_ADD_LIBS([gme], [-lgme])
2074   ], [
2075     AS_IF([test "x${enable_gme}" != "x"], [
2076       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2077     ])
2078   ])
2079 ])
2080
2081
2082 dnl
2083 dnl  SIDPlay plugin
2084 dnl
2085 AC_ARG_ENABLE(sid,
2086     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2087 AS_IF([test "${enable_sid}" != "no"], [
2088     PKG_CHECK_MODULES(SID, [libsidplay2], [
2089         AC_LANG_PUSH(C++)
2090         oldCPPFLAGS="$CPPFLAGS"
2091         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2092         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2093             VLC_ADD_PLUGIN([sid])
2094             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2095             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2096         ], [
2097             AS_IF([test -n "${enable_sid}"],
2098                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2099                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2100                 )
2101         ])
2102         CPPFLAGS="$oldCPPFLAGS"
2103         AC_LANG_POP(C++)
2104     ], [
2105         AS_IF([test "x${enable_sid}" = "xyes"],
2106             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2107             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2108             )
2109     ])
2110 ])
2111
2112
2113 dnl
2114 dnl  ogg demux plugin
2115 dnl
2116 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2117 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2118     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2119 ],[true])
2120 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2121 if test "${enable_sout}" != "no"; then
2122 dnl Check for libshout
2123     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2124 fi
2125
2126 dnl
2127 dnl  matroska demux plugin
2128 dnl
2129 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2130
2131 dnl
2132 dnl  modplug demux plugin
2133 dnl
2134 AC_ARG_ENABLE(mod,
2135   [AS_HELP_STRING([--disable-mod],
2136     [do not use libmodplug (default auto)])])
2137 if test "${enable_mod}" != "no" ; then
2138     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2139           VLC_ADD_PLUGIN([mod])
2140           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2141           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2142           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2143     ],[
2144        AS_IF([test -n "${enable_mod}"],
2145          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2146          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2147     ])
2148 fi
2149
2150 dnl
2151 dnl  mpc demux plugin
2152 dnl
2153 AC_ARG_ENABLE(mpc,
2154   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2155 if test "${enable_mpc}" != "no"
2156 then
2157   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2158     VLC_ADD_PLUGIN([mpc])
2159     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2160     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2161     VLC_ADD_PLUGIN([mpc])
2162     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2163 fi
2164
2165 dnl
2166 dnl  Codec plugins
2167 dnl
2168
2169 EXTEND_HELP_STRING([Codec plugins:])
2170
2171 dnl
2172 dnl wmafixed plugin
2173 dnl
2174 AC_ARG_ENABLE(wma-fixed,
2175   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2176 if test "${enable_wma_fixed}" = "yes"
2177 then
2178   VLC_ADD_PLUGIN([wma_fixed])
2179 fi
2180
2181 dnl
2182 dnl shine encoder plugin
2183 dnl
2184 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2185
2186
2187 dnl
2188 dnl openmax il codec plugin
2189 dnl
2190 AC_ARG_ENABLE(omxil,
2191   [  --enable-omxil          openmax il codec module (default disabled)])
2192 if test "${enable_omxil}" = "yes"
2193 then
2194   VLC_ADD_PLUGIN([omxil])
2195 fi
2196
2197 dnl
2198 dnl raspberry pi openmax il configuration
2199 dnl
2200 AC_ARG_ENABLE(rpi-omxil,
2201   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2202 if test "${enable_rpi_omxil}" = "yes"
2203 then
2204   VLC_ADD_PLUGIN([omxil])
2205   VLC_ADD_CFLAGS([omxil],[-DRPI_OMX])
2206 fi
2207
2208 dnl
2209 dnl CrystalHD codec plugin
2210 dnl
2211 AC_ARG_ENABLE(crystalhd,
2212   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2213 if test "${enable_crystalhd}" != "no"; then
2214     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2215       VLC_ADD_PLUGIN([crystalhd])
2216       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2217     ],[
2218       if test "${SYS}" = "mingw32" ; then
2219         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2220           VLC_ADD_PLUGIN([crystalhd])
2221           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2222             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2223             ])
2224         ],[
2225           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2226                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2227                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2228         ],[#define __LINUX_USER__
2229                #include <libcrystalhd/bc_dts_types.h>
2230         ])
2231       fi
2232     ],[
2233        #include <libcrystalhd/bc_dts_types.h>
2234       ])
2235 fi
2236
2237 dnl
2238 dnl  mad plugin
2239 dnl
2240 have_mad="no"
2241 MAD_CFLAGS=""
2242 MAD_LIBS=""
2243
2244 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2245   enable_mad="yes"
2246 ], [
2247   with_mad="no"
2248 ])
2249 AS_IF([test "${with_mad}" != "no"], [
2250   MAD_CFLAGS="-I${with_mad}/include"
2251   MAD_LIBS="-L${with_mad}/lib"
2252 ])
2253
2254 AC_ARG_ENABLE(mad,
2255   [  --enable-mad            libmad module (default enabled)])
2256 AS_IF([test "${enable_mad}" != "no"], [
2257   VLC_SAVE_FLAGS
2258   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2259   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2260   AC_CHECK_HEADERS(mad.h, [
2261     AC_CHECK_LIB(mad, mad_bit_init, [
2262       have_mad="yes"
2263       MAD_LIBS="${MAD_LIBS} -lmad"
2264     ])
2265   ])
2266   VLC_RESTORE_FLAGS
2267   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2268     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2269   ])
2270 ])
2271 AC_SUBST(MAD_CFLAGS)
2272 AC_SUBST(MAD_LIBS)
2273 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2274
2275 dnl  mpg123 plugin
2276 dnl
2277 dnl
2278 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2279
2280 dnl
2281 dnl gstreamer stuff
2282 dnl
2283 AC_ARG_ENABLE(gst-decode,
2284   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2285
2286 have_gst_decode="no"
2287 AS_IF([test "${enable_gst_decode}" != "no"], [
2288   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2289     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2290       have_gst_decode="yes"
2291     ], [
2292       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2293     ])
2294   ], [
2295     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2296   ])
2297 ])
2298 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2299
2300 dnl
2301 dnl  avcodec decoder/encoder plugin
2302 dnl
2303 AC_ARG_ENABLE(merge-ffmpeg,
2304 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2305   enable_merge_ffmpeg="no"
2306 ])
2307 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2308
2309 AC_MSG_CHECKING([for libavutil variant])
2310 PKG_CHECK_EXISTS([libavutil], [
2311   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2312   libavutil_micro="${libavutil_version##*.}"
2313   AS_IF([test ${libavutil_micro} -le 99], [
2314     avfork="libav"
2315   ], [
2316     avfork="ffmpeg"
2317   ])
2318 ], [
2319   avfork="none"
2320 ])
2321 AC_MSG_RESULT([${avfork}])
2322
2323 AC_ARG_ENABLE(avcodec,
2324 [  --enable-avcodec        libavcodec codec (default enabled)])
2325 AS_IF([test "${enable_avcodec}" != "no"], [
2326   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2327   case "${avfork}" in
2328     libav) av_codec_ver="57.16.0" ;;
2329     ffmpeg) av_codec_ver="57.37.100" ;;
2330     *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2331   esac
2332   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2333     VLC_SAVE_FLAGS
2334     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2335     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2336     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2337     AC_CHECK_HEADERS(libavutil/avutil.h)
2338     VLC_RESTORE_FLAGS
2339     have_avcodec="yes"
2340   ],[
2341     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2342   ])
2343 ], [
2344   have_avcodec="no"
2345 ])
2346 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2347
2348 dnl
2349 dnl libva needs avcodec
2350 dnl
2351 AC_ARG_ENABLE(libva,
2352   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2353
2354 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2355   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2356 ])
2357
2358 have_vaapi="no"
2359 have_vaapi_drm="no"
2360 have_vaapi_x11="no"
2361 have_vaapi_wl="no"
2362 AS_IF([test "${enable_libva}" != "no"], [
2363   PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2364     have_vaapi="yes"
2365   ], [
2366     AS_IF([test -n "${enable_libva}"], [
2367       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2368     ], [
2369       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2370     ])
2371   ])
2372   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2373     have_vaapi_drm="yes"
2374   ], [
2375     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2376   ])
2377   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2378     have_vaapi_x11="yes"
2379   ], [
2380     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2381   ])
2382   PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2383     have_vaapi_wl="yes"
2384   ], [
2385     AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2386   ])
2387 ])
2388 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2389 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2390 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2391 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2392
2393 have_avcodec_vaapi="no"
2394 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2395   VLC_SAVE_FLAGS
2396   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2397   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2398   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2399     AC_MSG_NOTICE([VA API acceleration activated])
2400     have_avcodec_vaapi="yes"
2401   ],[
2402     AS_IF([test -n "${enable_libva}"], [
2403       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2404     ], [
2405       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2406     ])
2407   ])
2408   VLC_RESTORE_FLAGS
2409 ])
2410 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2411
2412 dnl
2413 dnl dxva2 needs avcodec
2414 dnl
2415 AC_ARG_ENABLE(dxva2,
2416   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2417
2418 have_avcodec_dxva2="no"
2419 AS_IF([test "${enable_dxva2}" != "no"], [
2420   if test "${SYS}" = "mingw32"; then
2421   AS_IF([test "x${have_avcodec}" = "xyes"], [
2422     AC_CHECK_HEADERS(dxva2api.h,
2423       [
2424         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2425            AC_MSG_NOTICE([DxVA2 acceleration activated])
2426            have_avcodec_dxva2="yes"
2427         ],[
2428     AS_IF([test "${enable_dxva2}" = "yes"],
2429           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2430               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2431         ], [#undef _WIN32_WINNT
2432             /* DXVA2 is only available in Vista and above */
2433             #define _WIN32_WINNT 0x600])
2434       ],[
2435     AS_IF([test "${enable_dxva2}" = "yes"],
2436               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2437               [AC_MSG_WARN([dxva2api.h not found])])
2438       ],[#include <d3d9.h>])
2439   ],[
2440     AS_IF([test "x${enable_dxva2}" != "x"], [
2441       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2442     ])
2443   ])
2444   fi
2445 ])
2446 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2447
2448 dnl
2449 dnl d3d11va needs avcodec
2450 dnl
2451 AC_ARG_ENABLE(d3d11va,
2452   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2453
2454 have_avcodec_d3d11va="no"
2455 AS_IF([test "${enable_d3d11va}" != "no"], [
2456   if test "${SYS}" = "mingw32"; then
2457   AS_IF([test "x${have_avcodec}" = "xyes"], [
2458         AC_CHECK_TYPES([ID3D11VideoDecoder],
2459           [
2460             AC_CHECK_HEADERS(dxva2api.h,
2461               [
2462                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2463                    AC_MSG_NOTICE([D3D11 acceleration activated])
2464                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2465                    have_avcodec_d3d11va="yes"
2466                 ],[
2467                   AS_IF([test "${enable_d3d11va}" = "yes"],
2468                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2469                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2470                   ], [#undef _WIN32_WINNT
2471                       /* D3D11 is only available in Vista and above */
2472                       #define _WIN32_WINNT 0x600])
2473                   ],[
2474                     AS_IF([test "${enable_d3d11va}" = "yes"],
2475                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2476                           [AC_MSG_WARN([dxva2api.h not found])])
2477                   ],[#include <d3d9.h>])
2478           ],[
2479             AS_IF([test "${enable_d3d11va}" = "yes"],
2480                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2481                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2482           ], [#include <d3d11.h>])
2483   ],[
2484     AS_IF([test "x${enable_d3d11va}" != "x"], [
2485       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2486     ])
2487   ])
2488   fi
2489 ])
2490 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2491
2492 dnl
2493 dnl DXGI debug
2494 dnl
2495 AC_CHECK_HEADERS(dxgidebug.h dxgi1_6.h)
2496
2497 dnl
2498 dnl  avformat demuxer/muxer plugin
2499 dnl
2500
2501 AC_ARG_ENABLE(avformat,
2502 [  --enable-avformat       libavformat containers (default enabled)],, [
2503   enable_avformat="${have_avcodec}"
2504 ])
2505 have_avformat="no"
2506 AS_IF([test "${enable_avformat}" != "no"], [
2507   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2508       have_avformat="yes"
2509       VLC_SAVE_FLAGS
2510       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2511       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2512       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2513       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2514       AC_CHECK_HEADERS(libavutil/avutil.h)
2515       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2516         have_avformat="no"
2517       ])
2518       VLC_RESTORE_FLAGS
2519     ],[
2520       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2521   ])
2522 ])
2523 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2524
2525 dnl
2526 dnl  swscale image scaling and conversion plugin
2527 dnl
2528
2529 AC_ARG_ENABLE(swscale,
2530   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2531           (default enabled)]))
2532 if test "${enable_swscale}" != "no"
2533 then
2534   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2535     [
2536       VLC_SAVE_FLAGS
2537       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2538       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2539       AC_CHECK_HEADERS(libswscale/swscale.h)
2540       AC_CHECK_HEADERS(libavutil/avutil.h)
2541       VLC_ADD_PLUGIN([swscale])
2542       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2543       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2544       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2545         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2546       ])
2547       VLC_RESTORE_FLAGS
2548     ],[
2549       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2550   ])
2551 fi
2552
2553 dnl
2554 dnl  postproc plugin
2555 dnl
2556
2557 AC_ARG_ENABLE(postproc,
2558 [  --enable-postproc       libpostproc image post-processing (default auto)])
2559 if test "${enable_postproc}" != "no"
2560 then
2561   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2562     [
2563       VLC_SAVE_FLAGS
2564       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2565       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2566       AC_CHECK_HEADERS(postproc/postprocess.h)
2567       VLC_ADD_PLUGIN([postproc])
2568       VLC_RESTORE_FLAGS
2569     ],[
2570       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2571   ])
2572 fi
2573
2574 dnl
2575 dnl  faad decoder plugin
2576 dnl
2577 AC_ARG_ENABLE(faad,
2578 [  --enable-faad           faad codec (default auto)])
2579 have_faad="no"
2580 AS_IF([test "${enable_faad}" != "no"], [
2581   AC_CHECK_HEADERS([neaacdec.h], [
2582     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2583
2584     AS_IF([test "${have_faad}" = "yes"], [
2585       VLC_ADD_PLUGIN([faad])
2586       VLC_ADD_LIBS([faad],[-lfaad])
2587     ], [
2588       AS_IF([test "${enable_faad}" = "yes"], [
2589         AC_MSG_ERROR([cannot find FAAD library])
2590       ], [
2591         AC_MSG_WARN([cannot find FAAD library])
2592       ])
2593     ])
2594   ])
2595 ])
2596
2597 dnl
2598 dnl  AOM decoder plugin
2599 dnl
2600 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec (default auto)])
2601
2602 dnl
2603 dnl libvpx decoder plugin
2604 dnl
2605 AC_ARG_ENABLE(vpx,
2606     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2607 AS_IF([test "${enable_vpx}" != "no"],[
2608     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2609         VLC_ADD_PLUGIN([vpx])
2610         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2611         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2612         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2613             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2614         ], [], [${VPX_LIBS}])
2615         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2616             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2617         ], [], [${VPX_LIBS}])
2618         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2619             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2620         ], [], [${VPX_LIBS}])
2621         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2622             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2623         ], [], [${VPX_LIBS}])
2624     ], [
2625     AS_IF([test "${enable_vpx}" = "yes"],[
2626         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2627     ])])
2628 ])
2629
2630 dnl
2631 dnl twolame encoder plugin
2632 dnl
2633 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2634
2635 dnl
2636 dnl fdk-aac encoder plugin
2637 dnl
2638 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2639
2640
2641 dnl
2642 dnl A52/AC3 decoder plugin
2643 dnl
2644 AC_ARG_ENABLE(a52,
2645   [  --enable-a52            A/52 support with liba52 (default enabled)])
2646 if test "${enable_a52}" != "no"
2647 then
2648   AC_ARG_WITH(a52,
2649     [  --with-a52=PATH         a52 headers and libraries])
2650     if test -z "${with_a52}"
2651     then
2652       LDFLAGS_test=""
2653       CPPFLAGS_test=""
2654     else
2655       LDFLAGS_test="-L${with_a52}/lib"
2656       CPPFLAGS_test="-I${with_a52}/include"
2657     fi
2658     VLC_SAVE_FLAGS
2659     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2660     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2661     AC_CHECK_HEADERS(a52dec/a52.h, [
2662       AC_CHECK_LIB(a52, a52_free, [
2663         VLC_ADD_PLUGIN([a52])
2664         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2665         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2666       ],[
2667         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2668         ], [$LIBM])
2669     ],[
2670       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2671     ])
2672     VLC_RESTORE_FLAGS
2673 fi
2674
2675 dnl
2676 dnl DTS Coherent Acoustics decoder plugin
2677 dnl
2678 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2679
2680 dnl
2681 dnl  Flac plugin
2682 dnl
2683 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2684
2685 dnl
2686 dnl  Libmpeg2 plugin
2687 dnl
2688 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2689
2690 dnl
2691 dnl  Vorbis plugin
2692 dnl
2693 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2694
2695 dnl
2696 dnl  Tremor plugin
2697 dnl
2698 AC_ARG_ENABLE(tremor,
2699   [  --enable-tremor         Tremor decoder support (default disabled)])
2700 if test "${enable_tremor}" = "yes"
2701 then
2702   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2703     VLC_ADD_PLUGIN([tremor])
2704    ],[])
2705 fi
2706
2707 dnl
2708 dnl  Speex plugins
2709 dnl
2710 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2711 have_speexdsp="no"
2712 AS_IF([test "${enable_speex}" != "no"], [
2713   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2714     have_speexdsp="yes"
2715   ], [
2716     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2717   ])
2718 ])
2719 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2720
2721 dnl
2722 dnl  Opus plugin
2723 dnl
2724 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2725
2726 dnl
2727 dnl  Ambisonic channel mixer and binauralizer plugin
2728 dnl
2729 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2730
2731 dnl
2732 dnl  theora decoder plugin
2733 dnl
2734 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2735
2736 dnl
2737 dnl  OggSpots decoder plugin
2738 dnl
2739 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2740
2741 dnl
2742 dnl  Daala decoder plugin
2743 dnl
2744 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2745
2746 dnl
2747 dnl  schroedinger decoder plugin (for dirac format video)
2748 dnl
2749 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2750
2751 dnl
2752 dnl  PNG decoder module
2753 dnl
2754 AC_ARG_ENABLE(png,
2755   [  --enable-png            PNG support (default enabled)])
2756 AS_IF([test "${enable_png}" != "no"], [
2757 AC_CHECK_HEADERS(png.h, [
2758   VLC_SAVE_FLAGS
2759   LDFLAGS="${LDFLAGS} -lz $LIBM"
2760   AC_CHECK_LIB(png, png_set_alpha_mode, [
2761     VLC_ADD_PLUGIN([png])
2762   ], [], [-lz $LIBM])
2763   VLC_RESTORE_FLAGS
2764   ])
2765 ])
2766
2767 dnl
2768 dnl  JPEG decoder module
2769 dnl
2770 AC_ARG_ENABLE(jpeg,
2771   [  --enable-jpeg           JPEG support (default enabled)])
2772 AS_IF([test "${enable_jpeg}" != "no"], [
2773 AC_CHECK_HEADERS(jpeglib.h, [
2774   VLC_ADD_PLUGIN([jpeg])
2775   ])
2776 ])
2777
2778 dnl
2779 dnl  BPG decoder module
2780 dnl
2781 AC_ARG_ENABLE(bpg,
2782   [  --enable-bpg           BPG support (default disabled)])
2783 AS_IF([test "${enable_bpg}" != "no"], [
2784 AC_CHECK_HEADERS(libbpg.h, [
2785   VLC_ADD_PLUGIN([bpg])
2786   ])
2787 ])
2788
2789 dnl
2790 dnl H262 encoder plugin (lib262)
2791 dnl
2792 AC_ARG_ENABLE(x262,
2793   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2794 if test "${enable_x262}" != "no"; then
2795     PKG_CHECK_MODULES(X262, x262, [
2796         VLC_ADD_PLUGIN([x262])
2797         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2798         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2799           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2800         ])
2801         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2802         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2803           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2804         fi
2805     ], [
2806        if test "${enable_x262}" = "yes"; then
2807         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2808        fi
2809     ])
2810 fi
2811
2812 dnl x265 encoder
2813 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2814
2815 dnl
2816 dnl H264 encoder plugin (10-bit lib264)
2817 dnl
2818 AC_ARG_ENABLE(x26410b,
2819   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2820 if test "${enable_x26410b}" != "no"; then
2821     PKG_CHECK_MODULES(X26410B, x26410b, [
2822         VLC_ADD_PLUGIN([x26410b])
2823         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2824         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2825           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2826         ])
2827         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2828         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2829           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2830         fi
2831     ], [
2832        if test "${enable_x26410b}" = "yes"; then
2833         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2834        fi
2835     ])
2836 fi
2837
2838
2839 dnl
2840 dnl H264 encoder plugin (using libx264)
2841 dnl
2842 AC_ARG_ENABLE(x264,
2843   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2844 if test "${enable_x264}" != "no"; then
2845       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2846         VLC_ADD_PLUGIN([x264])
2847         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2848
2849         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2850           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2851         ])
2852
2853         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2854         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2855           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2856         fi
2857       ],[
2858         if test "${enable_x264}" = "yes"; then
2859             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2860           fi
2861       ])
2862 fi
2863
2864 dnl
2865 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2866 dnl
2867 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2868
2869 dnl
2870 dnl libfluidsynth (MIDI synthetizer) plugin
2871 dnl
2872 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2873 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2874 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2875
2876 dnl
2877 dnl Teletext Modules
2878 dnl vbi decoder plugin (using libzbvi)
2879 dnl telx module
2880 dnl uncompatible
2881 dnl
2882 AC_ARG_ENABLE(zvbi,
2883   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2884                   libzvbi (default enabled)]))
2885 AC_ARG_ENABLE(telx,
2886   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2887                   zvbi) (default enabled if zvbi is absent)]))
2888
2889 AS_IF( [test "${enable_zvbi}" != "no"],[
2890     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2891         [
2892           VLC_ADD_PLUGIN([zvbi])
2893           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2894           AS_IF( [test "${enable_telx}" = "yes"],[
2895                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2896                   ])
2897         ],[
2898           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2899         ])
2900     ])
2901 AS_IF( [test "${enable_telx}" != "no" ],[
2902   VLC_ADD_PLUGIN([telx])
2903   ])
2904
2905 dnl
2906 dnl libass subtitle rendering module
2907 dnl
2908 AC_ARG_ENABLE(libass,
2909   [  --enable-libass         Subtitle support using libass (default enabled)])
2910 AS_IF( [test "${enable_libass}" != "no"], [
2911   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2912       [
2913         VLC_ADD_PLUGIN([libass])
2914
2915         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2916           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2917            VLC_ADD_LIBS([libass],[-lfontconfig])
2918        ])
2919       ],[
2920         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2921       ])
2922   ])
2923
2924 dnl
2925 dnl ARIB subtitles rendering module
2926 dnl
2927 AC_ARG_ENABLE(aribsub,
2928   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2929 AS_IF( [test "${enable_aribsub}" != "no" ],[
2930   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2931       have_aribb24="yes"
2932       VLC_ADD_PLUGIN([aribsub])
2933       VLC_ADD_LIBS([aribsub],[-laribb24])
2934       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2935     ],[
2936       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2937       have_aribb24="no"
2938   ])
2939 ])
2940 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2941
2942 dnl
2943 dnl ARIB B25
2944 dnl
2945 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2946
2947 dnl
2948 dnl  kate decoder plugin
2949 dnl
2950 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2951
2952 dnl
2953 dnl  tiger rendering for kate decoder plugin
2954 dnl
2955 AC_ARG_ENABLE(tiger,
2956 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2957 AS_IF([test "${enable_tiger}" != "no"], [
2958   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2959       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2960         AS_IF([test -n "${enable_tiger}"], [
2961           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2962         ])
2963   ])
2964 ])
2965
2966 dnl
2967 dnl  check if we can build the css selector engine
2968 dnl
2969 AC_ARG_ENABLE(css,
2970 [  --enable-css            CSS selector engine (default auto)])
2971 AS_IF([test "${enable_css}" != "no"], [
2972   with_css="yes"
2973   AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
2974 ])
2975 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
2976
2977
2978 dnl
2979 dnl  Video plugins
2980 dnl
2981
2982 EXTEND_HELP_STRING([Video plugins:])
2983
2984 dnl
2985 dnl  OpenGL
2986 dnl
2987 PKG_CHECK_MODULES([EGL], [egl], [
2988   have_egl="yes"
2989 ], [
2990   have_egl="no"
2991 ])
2992 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2993
2994 have_gl="no"
2995 PKG_CHECK_MODULES([GL], [gl], [
2996   have_gl="yes"
2997 ], [
2998   AC_MSG_CHECKING([for OpenGL])
2999   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3000 #ifdef _WIN32
3001 # include <GL/glew.h>
3002 #endif
3003 #include <GL/gl.h>
3004 ]], [
3005     [int t0 = GL_TEXTURE0;]])
3006   ], [
3007     GL_CFLAGS=""
3008     have_gl="yes"
3009     AS_IF([test "${SYS}" != "mingw32"], [
3010       GL_LIBS="-lGL"
3011     ], [
3012       GL_LIBS="-lopengl32"
3013     ])
3014   ])
3015   AC_MSG_RESULT([${have_gl}])
3016 ])
3017 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3018
3019 dnl OpenGL ES 2: depends on EGL 1.1
3020 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3021
3022 dnl
3023 dnl  Xlib
3024 dnl
3025
3026 AC_PATH_XTRA()
3027 AC_CHECK_HEADERS(X11/Xlib.h)
3028
3029 dnl
3030 dnl  X C Bindings modules
3031 dnl
3032 AC_ARG_ENABLE(xcb,
3033   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3034   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3035     enable_xcb="yes"
3036   ], [
3037     enable_xcb="no"
3038   ])
3039 ])
3040 AC_ARG_ENABLE(xvideo,
3041   [  --enable-xvideo         XVideo support (default enabled)],, [
3042     enable_xvideo="$enable_xcb"
3043 ])
3044
3045 have_xcb="no"
3046 have_xcb_keysyms="no"
3047 have_xcb_randr="no"
3048 have_xcb_xvideo="no"
3049 AS_IF([test "${enable_xcb}" != "no"], [
3050   dnl libxcb
3051   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3052   have_xcb="yes"
3053   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3054   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3055   PKG_CHECK_MODULES(XPROTO, [xproto])
3056
3057   AS_IF([test "${enable_xvideo}" != "no"], [
3058     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3059   ])
3060
3061   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3062
3063   dnl xcb-utils
3064   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3065     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3066   ])
3067 ])
3068 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3069 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3070 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3071 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3072
3073
3074 dnl
3075 dnl VDPAU needs X11
3076 dnl
3077 AC_ARG_ENABLE(vdpau,
3078   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3079 have_vdpau="no"
3080 AS_IF([test "${enable_vdpau}" != "no"], [
3081   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3082     have_vdpau="yes"
3083     AS_IF([test "${no_x}" = "yes"], [
3084       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3085     ])
3086   ], [
3087     AS_IF([test -n "${enable_vdpau}"], [
3088       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3089     ])
3090   ])
3091 ])
3092 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3093
3094 have_avcodec_vdpau="no"
3095 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3096   case "${avfork}" in
3097     libav) av_vdpau_ver="56.10.0" ;;
3098     ffmpeg) av_vdpau_ver="56.19.100" ;;
3099   esac
3100   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3101     have_avcodec_vdpau="yes"
3102     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3103   ], [
3104     AS_IF([test -n "${enable_vdpau}"], [
3105       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3106     ], [
3107       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3108     ])
3109   ])
3110 ])
3111 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3112
3113
3114 dnl
3115 dnl  Wayland
3116 dnl
3117 AC_ARG_ENABLE(wayland,
3118   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3119 have_wayland="no"
3120 have_wayland_egl="no"
3121
3122 AS_IF([test "${enable_wayland}" != "no"], [
3123   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3124     AC_MSG_CHECKING([for the Wayland protocols])
3125     PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3126       WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3127       AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3128     ], [
3129       AC_MSG_RESULT([not found])
3130       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3131     ])
3132
3133     AC_MSG_CHECKING([for the Wayland scanner])
3134     PKG_CHECK_EXISTS([wayland-scanner], [
3135       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3136       AC_MSG_RESULT([${WAYLAND_SCANNER}])
3137     ], [
3138       AC_MSG_RESULT([not found])
3139       AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3140     ])
3141
3142     have_wayland="yes"
3143
3144     AS_IF([test "${have_egl}" = "yes"], [
3145       PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3146         have_wayland_egl="yes"
3147       ], [
3148         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3149       ])
3150     ])
3151   ], [
3152     AS_IF([test -n "${enable_wayland}"], [
3153       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3154     ])
3155   ])
3156 ])
3157 AC_SUBST([WAYLAND_PROTOCOLS])
3158 AC_SUBST([WAYLAND_SCANNER])
3159 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3160 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3161
3162
3163 dnl
3164 dnl  SDL image decoder module
3165 dnl
3166 AC_ARG_ENABLE(sdl-image,
3167   [  --enable-sdl-image      SDL image support (default enabled)])
3168 AS_IF([test "${enable_sdl_image}" != "no"],[
3169   PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3170     VLC_ADD_PLUGIN([sdl_image])
3171   ], [
3172     AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3173   ])
3174 ])
3175
3176 dnl
3177 dnl  freetype module
3178 dnl
3179 AC_ARG_ENABLE(freetype,
3180   [  --enable-freetype       freetype support   (default auto)])
3181 AC_ARG_ENABLE(fribidi,
3182   [  --enable-fribidi        fribidi support    (default auto)])
3183 AC_ARG_ENABLE(harfbuzz,
3184   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3185 AC_ARG_ENABLE(fontconfig,
3186   [  --enable-fontconfig     fontconfig support (default auto)])
3187
3188 AC_ARG_WITH([default-font],
3189     AS_HELP_STRING([--with-default-font=PATH],
3190         [Path to the default font]),
3191         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3192             "$withval", [Default font])])
3193 AC_ARG_WITH([default-monospace-font],
3194     AS_HELP_STRING([--with-default-monospace-font=PATH],
3195         [Path to the default font]),
3196         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3197             "$withval", [Default monospace font])])
3198
3199 AC_ARG_WITH([default-font-family],
3200     AS_HELP_STRING([--with-default-font-family=NAME],
3201         [Path to the default font family]),
3202         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3203             "$withval", [Default font family])])
3204 AC_ARG_WITH([default-monospace-font-family],
3205     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3206         [Path to the default font family]),
3207         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3208             "$withval", [Default monospace font family])])
3209
3210 have_freetype="no"
3211 have_fontconfig="no"
3212 have_fribidi="no"
3213 have_harfbuzz="no"
3214
3215 if test "${enable_freetype}" != "no"; then
3216    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3217       have_freetype="yes"
3218       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3219       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3220
3221     dnl fontconfig support
3222     AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3223       PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3224         have_fontconfig="yes"
3225       ], [
3226         AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3227       ])
3228     ])
3229
3230       dnl fribidi support
3231       if test "${enable_fribidi}" != "no"; then
3232         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3233           have_fribidi="yes"
3234           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3235           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3236         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3237       fi
3238
3239       dnl harfbuzz support
3240       if test "${have_fribidi}" != "no"; then
3241         if test "${enable_harfbuzz}" != "no"; then
3242           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3243             have_harfbuzz="yes"
3244             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3245             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3246           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3247         fi
3248       fi
3249   ],[
3250   AS_IF([test -n "${enable_freetype}"],[
3251     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3252     ])
3253   ])
3254 fi
3255
3256 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3257 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3258 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3259 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3260
3261 dnl
3262 dnl SAPI (text to Speech renderer for Windows)
3263 dnl
3264 AC_LANG_PUSH([C++])
3265 AC_CHECK_TYPES([ISpObjectToken],[
3266               have_sapi="yes"
3267             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3268               [#include <windows.h>
3269                #include <sapi.h>
3270                #include <sphelper.h>])
3271 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3272 AC_LANG_POP([C++])
3273
3274 dnl
3275 dnl  SVG module (text rendering and image decoding)
3276 dnl
3277 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3278 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3279
3280 dnl
3281 dnl  Windows DirectX module
3282 dnl
3283
3284 AC_ARG_ENABLE(directx,
3285   [AS_HELP_STRING([--enable-directx],
3286     [Microsoft DirectX support (default enabled on Windows)])],, [
3287   AS_IF([test "${SYS}" = "mingw32"], [
3288     enable_directx="yes"
3289   ], [
3290     enable_directx="no"
3291   ])
3292 ])
3293 AS_IF([test "${enable_directx}" != "no"], [
3294   dnl DirectDraw
3295   AC_CHECK_HEADERS(ddraw.h, [
3296     VLC_ADD_PLUGIN([directdraw])
3297   ])
3298
3299   dnl OpenGL
3300   AC_CHECK_HEADERS(GL/wglew.h, [
3301     VLC_ADD_PLUGIN([glwin32 wgl])
3302   ],, [
3303     #include <windows.h>
3304     #include <GL/gl.h>
3305   ])
3306
3307   dnl Direct3D11
3308   AC_CHECK_HEADERS(d3d11.h, [
3309     VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3310   ])
3311
3312   dnl Direct3D9
3313   AC_CHECK_HEADERS(d3d9.h, [
3314     VLC_ADD_PLUGIN([direct3d9])
3315     AC_CHECK_HEADERS(d3dx9effect.h)
3316
3317     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3318         [[#define COBJMACROS
3319           #include <d3d9.h>
3320           #include <dxva2api.h>
3321           #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3322           # error dxva2 too old
3323           #endif
3324         ]],[[;]])
3325       ],[
3326         VLC_ADD_PLUGIN([direct3d9_filters])
3327       ],
3328       [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3329
3330   ])
3331 ])
3332
3333 dnl
3334 dnl  Linux framebuffer module
3335 dnl
3336 AC_CHECK_HEADER([linux/fb.h], [
3337   VLC_ADD_PLUGIN([fb])
3338 ])
3339
3340 dnl
3341 dnl  libcaca plugin
3342 dnl
3343 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3344
3345 dnl
3346 dnl  OS/2 KVA plugin
3347 dnl
3348 AC_ARG_ENABLE(kva,
3349   [AS_HELP_STRING([--enable-kva],
3350     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3351   AS_IF([test "$SYS" = "os2"], [
3352     enable_kva="yes"
3353   ])
3354 ])
3355 have_kva="no"
3356 KVA_LIBS=""
3357 AS_IF([test "$enable_kva" != "no"], [
3358   AC_CHECK_HEADERS([kva.h], [
3359     have_kva="yes"
3360     AC_CHECK_LIB(kva, main, [
3361       KVA_LIBS="-lkva"
3362     ])
3363   ])
3364 ])
3365 AC_SUBST(KVA_LIBS)
3366 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3367
3368 dnl
3369 dnl MMAL plugin
3370 dnl
3371 AC_ARG_ENABLE(mmal,
3372   AS_HELP_STRING([--enable-mmal],
3373     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3374 if test "${enable_mmal}" != "no"; then
3375   VLC_SAVE_FLAGS
3376   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3377   CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3378   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3379     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3380         have_mmal="yes"
3381         VLC_ADD_PLUGIN([mmal])
3382         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3383         VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3384         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif ]) ], [
3385           AS_IF([test "${enable_mmal}" = "yes"],
3386             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3387             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3388           ],
3389         [])
3390     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3391       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3392       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3393   VLC_RESTORE_FLAGS
3394 fi
3395 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3396
3397 dnl
3398 dnl  Audio plugins
3399 dnl
3400
3401 EXTEND_HELP_STRING([Audio plugins:])
3402
3403 dnl
3404 dnl  Pulseaudio module
3405 dnl
3406 AC_ARG_ENABLE(pulse,
3407   [AS_HELP_STRING([--enable-pulse],
3408     [use the PulseAudio client library (default auto)])])
3409 have_pulse="no"
3410 AS_IF([test "${enable_pulse}" != "no"], [
3411   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3412     have_pulse="yes"
3413   ], [
3414     AS_IF([test "x${enable_pulse}" != "x"], [
3415       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3416     ])
3417   ])
3418 ])
3419 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3420
3421 dnl
3422 dnl  ALSA module
3423 dnl
3424 AC_ARG_ENABLE(alsa,
3425   [AS_HELP_STRING([--enable-alsa],
3426     [support the Advanced Linux Sound Architecture (default auto)])],, [
3427   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3428     enable_alsa="yes"
3429   ])
3430 ])
3431 have_alsa="no"
3432 AS_IF([test "${enable_alsa}" != "no"], [
3433   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3434     have_alsa="yes"
3435   ], [
3436     AS_IF([test "x${enable_alsa}" != "x"], [
3437       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3438     ])
3439   ])
3440 ])
3441 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3442
3443 dnl
3444 dnl  Open Sound System module
3445 dnl
3446 AC_ARG_ENABLE(oss,
3447   [AS_HELP_STRING([--enable-oss],
3448     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3449   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3450     enable_oss="no"
3451   ])
3452 ])
3453 have_oss="no"
3454 OSS_LIBS=""
3455 AS_IF([test "$enable_oss" != "no"], [
3456   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3457     have_oss="yes"
3458     AC_CHECK_LIB(ossaudio, main, [
3459       OSS_LIBS="-lossaudio"
3460     ])
3461   ])
3462 ])
3463 AC_SUBST(OSS_LIBS)
3464 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3465
3466 dnl
3467 dnl  OpenBSD sndio module
3468 dnl
3469 AC_ARG_ENABLE([sndio],
3470   [AS_HELP_STRING([--disable-sndio],
3471     [support the OpenBSD sndio (default auto)])],, [
3472   AS_IF([test "$SYS" = "openbsd"], [
3473     enable_sndio="yes"
3474   ])
3475 ])
3476 have_sndio="no"
3477 AS_IF([test "$enable_sndio" != "no"], [
3478   AC_CHECK_HEADER([sndio.h], [
3479     have_sndio="yes"
3480   ])
3481 ])
3482 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3483
3484 dnl
3485 dnl  Windows Audio Session plugin
3486 dnl
3487 AC_ARG_ENABLE([wasapi],
3488   [AS_HELP_STRING([--enable-wasapi],
3489     [use the Windows Audio Session API (default auto)])
3490 ])
3491 have_wasapi="no"
3492 AS_IF([test "$enable_wasapi" != "no"], [
3493   AC_CHECK_HEADER([audioclient.h], [
3494     have_wasapi="yes"
3495   ], [
3496     AS_IF([test "x${enable_wasapi}" != "x"], [
3497       AC_MSG_ERROR([Windows Audio Session API not found.])
3498     ])
3499   ])
3500 ])
3501 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3502
3503 dnl
3504 dnl  JACK modules
3505 dnl
3506 AC_ARG_ENABLE(jack,
3507   [AS_HELP_STRING([--disable-jack],
3508     [do not use jack (default auto)])])
3509 have_jack="no"
3510 AS_IF([test "${enable_jack}" != "no"], [
3511     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3512       [ have_jack=yes ],
3513       [
3514       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3515
3516       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3517       [ have_jack=yes ],
3518       [
3519       AS_IF([test -n "${enable_jack}"],
3520          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3521          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3522       ])
3523     ])
3524 ])
3525 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3526
3527 dnl
3528 dnl  OpenSLES Android
3529 dnl
3530 AC_ARG_ENABLE(opensles,
3531   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3532 if test "${HAVE_ANDROID}" = "1"; then
3533   if test "${enable_opensles}" = "yes"; then
3534       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3535         [ VLC_ADD_PLUGIN([opensles_android]) ],
3536         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3537   fi
3538 fi
3539
3540 dnl
3541 dnl  Tizen audio
3542 dnl
3543 AC_ARG_ENABLE(tizen_audio,
3544   [AS_HELP_STRING([--enable-tizen-audio],
3545     [Tizen audio module (default enabled on Tizen)])],, [
3546   AS_IF([test "$HAVE_TIZEN" = "1"], [
3547     enable_tizen_audio="yes"
3548   ])
3549 ])
3550 if test "${enable_tizen_audio}" = "yes"; then
3551   AC_CHECK_HEADERS(audio_io.h,
3552     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3553     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3554 fi
3555
3556 dnl
3557 dnl libsamplerate plugin
3558 dnl
3559 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3560
3561 dnl
3562 dnl  soxr module
3563 dnl
3564 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3565
3566 dnl
3567 dnl  OS/2 KAI plugin
3568 dnl
3569 AC_ARG_ENABLE(kai,
3570   [AS_HELP_STRING([--enable-kai],
3571     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3572   AS_IF([test "$SYS" = "os2"], [
3573     enable_kai="yes"
3574   ])
3575 ])
3576 have_kai="no"
3577 KAI_LIBS=""
3578 AS_IF([test "$enable_kai" != "no"], [
3579   AC_CHECK_HEADERS([kai.h], [
3580     have_kai="yes"
3581     AC_CHECK_LIB(kai, main, [
3582       KAI_LIBS="-lkai"
3583     ])
3584   ])
3585 ])
3586 AC_SUBST(KAI_LIBS)
3587 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3588
3589 dnl
3590 dnl  chromaprint audio track fingerprinter
3591 dnl
3592 m4_pushdef([libchromaprint_version], 0.6.0)
3593 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3594     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3595     AS_IF([test "${enable_chromaprint}" = "yes"],
3596         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3597         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3598          ),
3599     [(Chromaprint based audio fingerprinter)],[auto])
3600 m4_popdef([libchromaprint_version])
3601
3602 dnl
3603 dnl  Chromecast streaming support
3604 dnl
3605 m4_pushdef([protobuf_lite_version], 2.5.0)
3606 AC_ARG_VAR(PROTOC, [protobuf compiler])
3607 AC_CHECK_PROGS(PROTOC, protoc, no)
3608 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3609     AS_IF([test "x${PROTOC}" != "xno"], [
3610         build_chromecast="yes"
3611     ], [
3612     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3613     ])
3614 ], [
3615     AS_IF([test "${enable_chromecast}" = "yes"],
3616         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3617         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3618     )
3619     enable_chromecast="no"
3620 ], [(Chromecast streaming support)], [auto])
3621 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3622 m4_popdef([protobuf_lite_version])
3623
3624 dnl
3625 dnl  Interface plugins
3626 dnl
3627
3628 EXTEND_HELP_STRING([Interface plugins:])
3629
3630 dnl
3631 dnl QT
3632 dnl
3633 AC_ARG_ENABLE(qt, [
3634   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3635   AS_IF([test "${SYS}" = "darwin"], [
3636     enable_qt="no"
3637   ])
3638 ])
3639 have_qt5_x11="no"
3640 AS_IF([test "${enable_qt}" != "no"], [
3641   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.5.0 Qt5Widgets Qt5Gui Qt5Svg], [
3642       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3643           have_qt5_x11="yes"
3644       ],[
3645           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3646       ])
3647       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3648       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3649       QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3650       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3651       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3652       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3653     ], [
3654       AS_IF([test -n "${enable_qt}"],[
3655         AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3656       ],[
3657         AC_MSG_WARN([${QT_PKG_ERRORS}.])
3658       ])
3659       enable_qt="no"
3660     ])
3661 ])
3662
3663 AS_IF([test "${enable_qt}" != "no"], [
3664   ALIASES="${ALIASES} qvlc"
3665 ])
3666 AC_SUBST(QT_VERSION)
3667 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3668 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3669
3670 dnl
3671 dnl detect kde4-config patch (used for kde solids).
3672 dnl
3673 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3674 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3675   KDE4_CONFIG="kde4-config"
3676 ])
3677
3678 dnl
3679 dnl Simple test for skins2 dependency
3680 dnl
3681 AS_IF([test "$enable_qt" = "no"], [
3682   AS_IF([test "${enable_skins2}" = "yes"], [
3683     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3684   ], [
3685     enable_skins2="no"
3686     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3687   ])
3688 ])
3689
3690 dnl
3691 dnl Skins2 module
3692 dnl
3693 AC_ARG_ENABLE(skins2,
3694   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3695 AS_IF([test "${enable_skins2}" != "no"], [
3696   have_skins_deps="yes"
3697
3698   dnl Win32
3699   AS_IF([test "${SYS}" = "mingw32"], [
3700     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3701     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3702   dnl OS/2
3703   ], [test "${SYS}" = "os2"], [
3704     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3705   dnl Linux/Unix
3706   ], [
3707     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3708     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3709     PKG_CHECK_MODULES([XCURSOR], [xcursor],, [have_skins_deps="no"])
3710     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3711     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3712     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} ${XCURSOR_LIBS} -lX11])
3713   ])
3714
3715   dnl we need freetype
3716   AS_IF([test "${have_freetype}" != "yes"], [
3717     have_skins_deps="no"
3718   ])
3719
3720   AS_IF([test "${have_skins_deps}" = "no"], [
3721     AS_IF([test "x${enable_skins2}" = "x"], [
3722       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3723     ], [
3724       AC_MSG_ERROR([Skins2 interface requires FreeType, libxcursor, libxpm, libxext and libxinerama])
3725     ])
3726     enable_skins2="no"
3727   ], [
3728     ALIASES="${ALIASES} svlc"
3729     enable_skins2="yes"
3730   ])
3731 ])
3732 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3733
3734 AC_ARG_ENABLE(libtar,
3735   [  --enable-libtar         libtar support for skins2 (default auto)])
3736 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3737   AC_CHECK_HEADERS(libtar.h, [
3738     VLC_ADD_LIBS([skins2],[-ltar])
3739   ])
3740 ])
3741
3742 dnl
3743 dnl  MacOS X gui module
3744 dnl
3745 AC_ARG_ENABLE(macosx,
3746   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3747 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3748 then
3749
3750   dnl
3751   dnl If possible, use xcrun to find the right ibtool
3752   dnl
3753
3754   AC_PATH_PROG([XCRUN], [xcrun], [no])
3755   AS_IF([test ! "x${XCRUN}" = "xno"], [
3756     AC_MSG_CHECKING([for ibtool (using xcrun)])
3757     XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3758     AC_MSG_RESULT([${XIB}])
3759   ], [
3760     AC_MSG_WARN([Looking for tools without using xcrun])
3761   ])
3762
3763   AS_IF([test "x${XIB}" = "xno"], [
3764     AC_PATH_PROG(XIB, [ibtool], [no])
3765     AS_IF([test "x${XIB}" = "xno"], [
3766       AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3767     ])
3768   ])
3769 fi
3770 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3771
3772 dnl
3773 dnl  MacOS X sparkle update support
3774 dnl
3775 AC_ARG_ENABLE(sparkle,
3776   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3777 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3778 then
3779   if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3780   then
3781     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3782   fi
3783
3784   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3785 fi
3786 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3787
3788 dnl
3789 dnl  MacOS X breakpad creash reporter support
3790 dnl
3791 AC_ARG_WITH([breakpad],
3792   AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
3793
3794 AS_IF([test "$with_breakpad" != "no"], [
3795
3796   AS_IF([test "$with_breakpad" = "yes"], [
3797     AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
3798   ])
3799
3800   AS_IF([test "$HAVE_OSX" = "1"], [
3801     AC_MSG_CHECKING([for Breakpad framework])
3802     AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
3803                 ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
3804       AC_MSG_RESULT([no])
3805       with_breakpad="no"
3806       AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3807     ], [
3808       AC_MSG_RESULT([yes])
3809     ])
3810   ],[
3811     PKG_CHECK_MODULES([BREAKPAD], [breakpad-client], [
3812       LDFLAGS="${LDFLAGS} -Wl,--build-id"
3813     ], [
3814       AC_MSG_ERROR(["breakpad not found"])
3815     ])
3816   ])
3817 ])
3818
3819 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$with_breakpad" != "no"])
3820 AS_IF([test "$with_breakpad" != "no"], [
3821   AC_SUBST(BREAKPAD_URL, ["${with_breakpad}"])
3822 ])
3823
3824 dnl
3825 dnl  Minimal Mac OS X module
3826 dnl
3827 AC_ARG_ENABLE(minimal-macosx,
3828   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3829 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3830 then
3831   VLC_ADD_PLUGIN([minimal_macosx])
3832 fi
3833
3834 dnl
3835 dnl Mac OS X fancy dmg build tool
3836 dnl
3837 if test "${HAVE_OSX}" = "1"
3838 then
3839   AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3840   AS_IF([test "x${DMGBUILD}" = "xno"], [
3841     AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3842   ])
3843 fi
3844 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3845
3846 dnl
3847 dnl  VideoToolbox plugins
3848 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3849     VLC_ADD_PLUGIN([videotoolbox])
3850     VLC_ADD_PLUGIN([cvpx])
3851   ])
3852
3853 dnl
3854 dnl  AudioToolbox MIDI plugin
3855 AC_CHECK_HEADERS([AudioToolbox/AudioToolbox.h], [
3856   VLC_ADD_PLUGIN([audiotoolboxmidi])
3857 ])
3858
3859 dnl
3860 dnl  ncurses module
3861 dnl
3862 AC_ARG_ENABLE(ncurses,
3863 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3864 have_ncurses="no"
3865 AS_IF([test "${enable_ncurses}" != "no"] ,[
3866   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3867     have_ncurses="yes"
3868     ALIASES="${ALIASES} nvlc"
3869   ], [
3870     AS_IF([test -n "${enable_ncurses}"], [
3871       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3872     ])
3873   ])
3874 ])
3875 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3876
3877 dnl
3878 dnl  Lirc plugin
3879 dnl
3880 AC_ARG_ENABLE(lirc,
3881   [  --enable-lirc           lirc support (default disabled)])
3882 have_lirc="no"
3883 AS_IF([test "${enable_lirc}" = "yes"], [
3884   AC_CHECK_HEADER(lirc/lirc_client.h, [
3885     AC_CHECK_LIB(lirc_client, lirc_init, [
3886       have_lirc="yes"
3887     ])
3888   ])
3889 ])
3890 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3891
3892 dnl
3893 dnl  SRT plugin
3894 dnl
3895 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.2], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
3896
3897 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3898 dnl
3899 dnl  goom visualization plugin
3900 dnl
3901 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3902
3903 dnl
3904 dnl libprojectM visualization plugin
3905 dnl
3906 AC_ARG_ENABLE(projectm,
3907   [  --enable-projectm       projectM visualization plugin (default enabled)])
3908 AS_IF([test "${enable_projectm}" != "no"],
3909   [
3910     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3911     [
3912       VLC_ADD_PLUGIN([projectm])
3913       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3914         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3915         [ AC_MSG_WARN( [Using libprojectM version 1] )
3916       ])
3917     ],[
3918       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3919     ])
3920   ])
3921
3922 dnl
3923 dnl Vovoid VSXu visualization plugin
3924 dnl
3925 AC_ARG_ENABLE(vsxu,
3926   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3927 AS_IF([test "${enable_vsxu}" != "no"],
3928   [
3929     PKG_CHECK_MODULES(VSXU, libvsxu,
3930     [
3931       VLC_ADD_PLUGIN([vsxu])
3932     ],[
3933       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3934     ])
3935   ])
3936
3937 EXTEND_HELP_STRING([Service Discovery plugins:])
3938 dnl
3939 dnl  Avahi-Zeroconf services discovery
3940 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3941
3942 dnl
3943 dnl  libudev services discovery
3944 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3945
3946 dnl
3947 dnl MTP devices services discovery
3948 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3949
3950 dnl
3951 dnl UPnP Plugin (Intel SDK)
3952 dnl
3953 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3954
3955 dnl
3956 dnl mDNS using libmicrodns
3957 dnl
3958 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
3959
3960
3961 EXTEND_HELP_STRING([Misc options:])
3962
3963 dnl
3964 dnl  libxml2 module
3965 dnl
3966 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3967
3968
3969 dnl
3970 dnl libgcrypt
3971 dnl
3972 AC_ARG_ENABLE(libgcrypt,
3973   [  --disable-libgcrypt     gcrypt support (default enabled)])
3974 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
3975 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
3976
3977 # require libgcrypt >= 1.6.0
3978 AS_IF([test "${enable_libgcrypt}" != "no"], [
3979   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
3980     VLC_SAVE_FLAGS
3981     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
3982     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
3983 [#include <gcrypt.h>
3984 #if GCRYPT_VERSION_NUMBER < 0x010600
3985 #error
3986 #endif]])], [
3987       ac_cv_lib_gcrypt=yes
3988     ], [
3989       ac_cv_lib_gcrypt=no
3990     ])
3991     VLC_RESTORE_FLAGS
3992   ])
3993
3994   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
3995     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
3996   ], [
3997     AS_IF([test "${enable_libgcrypt}" = "yes"], [
3998       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
3999     ])
4000   ])
4001 ])
4002
4003 AS_IF([test -z "$GCRYPT_LIBS"], [
4004   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4005 ])
4006
4007 AC_SUBST(GCRYPT_CFLAGS)
4008 AC_SUBST(GCRYPT_LIBS)
4009 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4010
4011 dnl
4012 dnl TLS/SSL
4013 dnl
4014 AC_ARG_ENABLE(gnutls,
4015   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4016 AS_IF([test "${enable_gnutls}" != "no"], [
4017   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4018     VLC_ADD_PLUGIN([gnutls])
4019   ], [
4020     AS_IF([test -n "${enable_gnutls}"], [
4021       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4022     ])
4023   ])
4024 ])
4025
4026
4027 dnl
4028 dnl Taglib plugin
4029 dnl
4030 AC_ARG_ENABLE(taglib,
4031   [AS_HELP_STRING([--disable-taglib],
4032     [do not use TagLib (default enabled)])])
4033 AS_IF([test "${enable_taglib}" != "no"], [
4034   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4035     VLC_ADD_PLUGIN([taglib])
4036   ], [
4037     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4038 ])
4039
4040 dnl
4041 dnl  libsecret
4042 dnl
4043 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4044
4045 dnl
4046 dnl  kwallet
4047 dnl
4048 AC_ARG_ENABLE(kwallet,
4049   [AS_HELP_STRING([--enable-kwallet],
4050     [use kwallet (via D-Bus) for keystore (default enabled)])])
4051 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4052   VLC_ADD_PLUGIN([kwallet])
4053 ])
4054
4055 dnl
4056 dnl update checking system
4057 dnl
4058 AC_ARG_ENABLE(update-check,
4059   [  --enable-update-check   update checking system (default disabled)])
4060 if test "${enable_update_check}" = "yes"
4061 then
4062  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4063     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4064 fi
4065 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4066
4067 dnl
4068 dnl OS X notification plugin
4069 dnl
4070 AC_ARG_ENABLE(osx_notifications,
4071   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4072   [enable_osx_notifications=no])
4073 AS_IF([test "${enable_osx_notifications}" != "no"], [
4074   if test -d ${CONTRIB_DIR}/Growl.framework -o -d ${CONTRIB_DIR}/Frameworks/Growl.framework
4075   then
4076       VLC_ADD_PLUGIN([osx_notifications])
4077       VLC_ADD_LIBS([osx_notifications], [-Wl,-framework,Growl,-framework,Foundation])
4078       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4079   fi
4080 ])
4081
4082 dnl
4083 dnl Libnotify notification plugin
4084 dnl
4085 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-3.0], [libnotify notification], [auto])
4086
4087 dnl
4088 dnl  libplacebo support
4089 dnl
4090 AC_ARG_ENABLE(libplacebo,
4091   [AS_HELP_STRING([--disable-libplacebo],
4092       [disable libplacebo support (default auto)])])
4093
4094 AS_IF([test "$enable_libplacebo" != "no"], [
4095   PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.2], [
4096     AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
4097   ], [
4098     AS_IF([test -n "${enable_libplacebo}"], [
4099       AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
4100     ])
4101     enable_libplacebo="no"
4102   ])
4103 ])
4104 AM_CONDITIONAL(HAVE_LIBPLACEBO, [test "$enable_libplacebo" != "no"])
4105
4106
4107 dnl
4108 dnl  Endianness check
4109 dnl
4110 AC_C_BIGENDIAN
4111 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4112   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4113 ], [
4114   DEFS_BIGENDIAN=""
4115 ])
4116 AC_SUBST(DEFS_BIGENDIAN)
4117
4118 dnl
4119 dnl Where to install KDE solid .desktop
4120 dnl
4121 AC_ARG_WITH(kde-solid,
4122   AS_HELP_STRING([--with-kde-solid=PATH],
4123                  [KDE Solid actions directory (auto)]),, [
4124
4125 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4126   with_kde_solid="yes"
4127 fi
4128 ])
4129 soliddatadir=""
4130 AS_IF([test "${with_kde_solid}" != "no"], [
4131   AS_IF([test "${with_kde_solid}" = "yes"], [
4132     kde4datadir="`${KDE4_CONFIG} --install data`"
4133     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4134     soliddatadir="${kde4datadir}/solid/actions"
4135   ], [
4136     soliddatadir="${with_kde_solid}"
4137   ])
4138 ])
4139 AC_SUBST(soliddatadir)
4140 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4141
4142 dnl
4143 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4144 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4145 dnl
4146 if test "${SYS}" = "mingw32"; then
4147     AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4148 fi
4149
4150 EXTEND_HELP_STRING([Components:])
4151
4152 dnl
4153 dnl  the VLC binary
4154 dnl
4155 AC_ARG_ENABLE(vlc,
4156   [  --enable-vlc            build the VLC media player (default enabled)])
4157 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4158
4159 dnl
4160 dnl Fuzzer (at the end in order to don't mess dependencies FLAGS)
4161 dnl
4162 AS_VAR_IF(with_libfuzzer, no, [], [
4163     LIBS="-lstdc++ ${LIBM} ${LIBPTHREAD} -L${with_libfuzzer} -lFuzzer"
4164     AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc-guard, [
4165         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard])
4166         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard], [CXXFLAGS])
4167         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp])
4168         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp], [CXXFLAGS])
4169     ], [
4170         AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc, [
4171             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc])
4172             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc], [CXXFLAGS])
4173         ], [
4174             AC_MSG_ERROR([Sanitizer coverage not supported by your compiler])
4175         ])
4176     ])
4177 ])
4178
4179 dnl
4180 dnl  Stuff used by the program
4181 dnl
4182 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4183 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4184 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4185 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4186 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4187 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4188 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4189 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4190 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4191 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4192 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4193 AC_SUBST(COPYRIGHT_MESSAGE)
4194 AC_SUBST(VERSION_MESSAGE)
4195 AC_SUBST(VERSION_MAJOR)
4196 AC_SUBST(VERSION_MINOR)
4197 AC_SUBST(VERSION_REVISION)
4198 AC_SUBST(VERSION_EXTRA)
4199 AC_SUBST(COPYRIGHT_YEARS)
4200 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4201 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4202 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4203 dnl
4204 dnl  Handle substvars that use $(top_srcdir)
4205 dnl
4206 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4207
4208 dnl
4209 dnl  Configuration is finished
4210 dnl
4211 AC_SUBST(SYS)
4212 AC_SUBST(ARCH)
4213 AC_SUBST(ALIASES)
4214 AC_SUBST(ASM)
4215 AC_SUBST(MOC)
4216 AC_SUBST(RCC)
4217 AC_SUBST(UIC)
4218 AC_SUBST(WINDRES)
4219 AC_SUBST(WINE_SDK_PATH)
4220 AC_SUBST(LIBEXT)
4221 AC_SUBST(AM_CPPFLAGS)
4222 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4223 AC_SUBST(FILE_LIBVLCCORE_DLL)
4224 AC_SUBST(FILE_LIBVLC_DLL)
4225
4226 AC_CONFIG_FILES([
4227   Makefile
4228   doc/Makefile
4229   modules/Makefile
4230   m4/Makefile
4231   po/Makefile.in
4232   share/Makefile
4233   compat/Makefile
4234   src/Makefile
4235   lib/Makefile
4236   bin/Makefile
4237   test/Makefile
4238   modules/hw/mmal/Makefile
4239   share/vlc.appdata.xml.in
4240 ])
4241
4242 AM_COND_IF([HAVE_WIN32], [
4243   AC_CONFIG_FILES([
4244     extras/package/win32/NSIS/spad.nsi
4245     extras/package/win32/NSIS/vlc.win32.nsi
4246     extras/package/win32/msi/config.wxi
4247   ])
4248 ])
4249
4250 AM_COND_IF([HAVE_DARWIN], [
4251   AC_CONFIG_FILES([
4252     modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4253     share/macosx/Info.plist:share/Info.plist.in
4254   ])
4255 ])
4256
4257 dnl Generate makefiles
4258 AC_OUTPUT
4259
4260 dnl Do we have to use make or gmake ?
4261 if make --version 2>&1|grep -q GNU
4262 then
4263     # GNU make, all seems good
4264     MAKE=make
4265 else
4266     # Known GNU make alias (on BSD)
4267     MAKE=gmake
4268 fi
4269 dnl Shortcut to nice compile message
4270 if test -n $SHELL; then
4271   SHELL=${CONFIG_SHELL-/bin/sh}
4272 fi
4273 rm -f compile
4274 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4275 echo "#! $SHELL
4276 rm -f .error\$\$
4277 ERROR=0
4278 export PATH=\"$PATH\" LANG=C
4279 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4280 test -f .error\$\$ && ERROR=1
4281 rm -f .error\$\$
4282 exit \$ERROR" >compile
4283 chmod a+x compile
4284
4285 echo "
4286 libvlc configuration
4287 --------------------
4288 version               : ${VERSION}
4289 system                : ${SYS}
4290 architecture          : ${ARCH}
4291 optimizations         : ${enable_optimizations}"
4292 if test "${enable_vlc}" != "no"; then
4293 echo "vlc aliases           :${ALIASES}"
4294 else
4295 echo "build vlc executable  : no"
4296 fi
4297 echo "
4298 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."