| blob | 4be9420a149af53f81370c73c478f989a7f541ab |
1 dnl Autoconf settings for vlc
3 AC_COPYRIGHT([Copyright 1999-2019 VLC authors and VideoLAN])
5 AC_INIT([vlc], [4.0.0-dev])
6 VERSION_MAJOR=4
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=dev
12 PKGDIR="vlc"
13 AC_SUBST([PKGDIR])
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Otto Chriek"
17 COPYRIGHT_YEARS="1996-2019"
19 AC_CONFIG_SRCDIR([src/libvlc.c])
20 AC_CONFIG_AUX_DIR([autotools])
21 AC_CONFIG_MACRO_DIR([m4])
22 AC_CONFIG_LIBOBJ_DIR([compat])
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
27 AM_INIT_AUTOMAKE([tar-ustar color-tests foreign])
28 AC_CONFIG_HEADERS([config.h])
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
33 dnl
34 dnl Check for tools
35 dnl
36 AC_PROG_CC
37 AC_USE_SYSTEM_EXTENSIONS
38 VLC_PROG_CC_C11
39 AH_VERBATIM([FORTIFY_SOURCE],
40 [/* Enable compile-time and run-time bounds-checking, and some warnings,
41 without upsetting glibc 2.15+ or toolchains predefining _FORTIFY_SOURCE */
42 #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
43 # define _FORTIFY_SOURCE 2
44 #endif])
45 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
46 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
47 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
49 AC_PROG_CXX
50 AC_PROG_CPP
51 AC_PROG_OBJC
52 AC_PROG_EGREP
53 AC_PROG_MAKE_SET
54 AC_PROG_INSTALL
55 AM_PROG_AS
56 AC_PROG_LEX
57 AC_PROG_YACC
59 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
60 AC_CHECK_PROGS([DESKTOP_FILE_VALIDATE], [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
61 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
62 AC_CHECK_PROGS([BUILDCC], [c11-gcc c11 c99-gcc c99], [false])
63 AS_IF([test "$BUILDCC" = "false"], [
64 AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
65 ])
67 dnl Check for compiler properties
68 AC_C_CONST
69 AC_C_INLINE
70 AC_C_RESTRICT
71 AX_CXX_COMPILE_STDCXX_11([noext], [mandatory])
73 dnl Extend the --help string at the current spot.
74 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
76 dnl Allow binary package maintainer to pass a custom string to avoid
77 dnl cache problem
78 AC_ARG_WITH([binary-version],
79 AS_HELP_STRING([--with-binary-version=STRING],
80 [To avoid plugins cache problem between binary version]),[],[])
81 AS_IF([test -n "${with_binary_version}"],[
82 AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
83 [Binary specific version])
84 ])
86 dnl Prevent clang from accepting unknown flags with a mere warning
87 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
88 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
90 dnl
91 dnl Check the operating system
92 dnl
93 HAVE_WIN64="0"
94 HAVE_IOS="0"
95 HAVE_OSX="0"
96 HAVE_TVOS="0"
98 dnl Set x86 asm flags and defines
99 X86ASMFLAGS=""
100 case "${host_cpu}" in
101 i?86)
102 X86ASMFLAGS="-f elf32"
103 X86ASMDEFS="-DARCH_X86_32=1 -DARCH_X86_64=0"
104 ;;
105 x86_64)
106 X86ASMFLAGS="-f elf64"
107 X86ASMDEFS="-DARCH_X86_32=0 -DARCH_X86_64=1"
108 ;;
109 esac
111 case "${host_os}" in
112 "")
113 SYS=unknown
114 ;;
115 linux*)
116 SYS=linux
117 CFLAGS="${CFLAGS} -pthread"
118 ;;
119 bsdi*)
120 SYS=bsdi
121 CFLAGS="${CFLAGS} -pthread"
122 ;;
123 freebsd*)
124 SYS=freebsd
125 CFLAGS="${CFLAGS} -pthread"
126 CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
127 LDFLAGS="${LDFLAGS} -L/usr/local/lib"
128 ac_cv_ld_z_defs=no
129 ;;
130 openbsd*)
131 SYS=openbsd
132 CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
133 LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
134 ;;
135 netbsd*)
136 SYS=netbsd
137 ;;
138 dragonfly*)
139 SYS=dragonfly
140 ;;
141 darwin*)
143 dnl Force gcc "-arch" flag
144 ARCH_flag=""
145 case "${host_cpu}" in
146 i?86)
147 ARCH_flag="-arch i386"
148 X86ASMFLAGS="-f macho32"
149 X86ASMDEFS="${X86ASMDEFS} -DPREFIX"
150 ;;
151 ppc64*)
152 ARCH_flag="-arch ppc64"
153 ;;
154 ppc*)
155 ARCH_flag="-arch ppc"
156 ;;
157 x86_64)
158 ARCH_flag="-arch x86_64"
159 X86ASMFLAGS="-f macho64"
160 X86ASMDEFS="${X86ASMDEFS} -DPREFIX"
161 ;;
162 arm*)
163 ac_cv_c_bigendian="no"
164 ac_cv_c_attribute_packed="no"
165 ;;
166 esac
168 SYS=darwin
169 CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
170 CXX="${CXX} -stdlib=libc++ -std=c++11"
171 CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
172 CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
173 OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
174 LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
175 VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
176 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
178 AC_EGREP_CPP(yes,
179 [#import <TargetConditionals.h>
180 #if TARGET_OS_IPHONE
181 yes
182 #endif],
183 [HAVE_IOS="1"],
184 [HAVE_OSX="1"])
186 AC_EGREP_CPP(yes,
187 [#import <TargetConditionals.h>
188 #if TARGET_OS_TV
189 yes
190 #endif],
191 [HAVE_TVOS="1"
192 HAVE_IOS="0"
193 HAVE_OSX="0"
194 ],)
196 dnl
197 dnl Handle Mac OS X SDK flags
198 dnl
199 AC_ARG_WITH(macosx-sdk,
200 AS_HELP_STRING([--with-macosx-sdk=DIR],
201 [compile using the SDK in DIR]))
202 if test "${with_macosx_sdk}" != "" ; then
203 test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
204 CPP="${CPP} -isysroot ${with_macosx_sdk}"
205 CC="${CC} -isysroot ${with_macosx_sdk}"
206 CXX="${CXX} -isysroot ${with_macosx_sdk}"
207 OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
208 LD="${LD} -syslibroot ${with_macosx_sdk}"
209 fi
210 AC_ARG_WITH(macosx-version-min,
211 AS_HELP_STRING([--with-macosx-version-min=VERSION],
212 [compile for Mac OS X VERSION and above]))
213 if test "${with_macosx_version_min}" != "" ; then
214 CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
215 CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
216 CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
217 OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
218 LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
219 fi
220 ;;
221 *mingw32* | *cygwin* | *wince* | *mingwce*)
222 dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
223 dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
224 CXXFLAGS="${CXXFLAGS} -static-libgcc"
225 AC_CHECK_TOOL(WINDRES, windres, :)
226 AC_CHECK_TOOL(OBJCOPY, objcopy, :)
227 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
228 [[#ifdef _WIN32_WINNT
229 # error _WIN32_WINNT already defined
230 #endif
231 ]],[[;]])
232 ],[
233 AC_DEFINE([_WIN32_WINNT], 0x0601, [Define to '0x0601' for Windows 7 APIs.])
234 ])
235 AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
236 AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
237 AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
238 AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
239 AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
240 AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
241 AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
242 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
243 AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
244 AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
245 AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
247 case "${host_os}" in
248 *mingw32*)
249 SYS=mingw32
250 ;;
251 *cygwin*)
252 dnl Check if we are using the mno-cygwin mode in which case we are
253 dnl actually dealing with a mingw32 compiler.
254 AC_EGREP_CPP(yes,
255 [#ifdef _WIN32
256 yes
257 #endif],
258 SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
259 ;;
260 esac
262 if test "${SYS}" = "mingw32"; then
263 # DEP, ASLR, NO SEH
264 LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
266 AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
267 ac_default_prefix="`pwd`/_win32"
268 DESTDIR="`pwd`/_win32/"
270 dnl
271 dnl NSIS/MSI Installer prefix and WIN64
272 dnl
273 case "${host_cpu}" in
274 aarch64)
275 HAVE_WIN64="1"
276 WINDOWS_ARCH="arm64"
277 PROGRAMFILES="PROGRAMFILES64"
278 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
279 ;;
280 amd64|x86_64)
281 HAVE_WIN64="1"
282 WINDOWS_ARCH="x64"
283 PROGRAMFILES="PROGRAMFILES64"
284 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
285 X86ASMFLAGS="-f win64"
286 ;;
287 armv7)
288 WINDOWS_ARCH="arm"
289 PROGRAMFILES="PROGRAMFILES"
290 ;;
291 *)
292 WINDOWS_ARCH="x86"
293 PROGRAMFILES="PROGRAMFILES"
294 X86ASMFLAGS="-f win32"
295 X86ASMDEFS="${X86ASMDEFS} -DPREFIX"
296 ;;
297 esac
298 AC_SUBST([WINDOWS_ARCH])
299 AC_SUBST([PROGRAMFILES])
301 fi
302 ;;
303 *nto*)
304 SYS=nto
305 ;;
306 solaris*)
307 SYS=solaris
308 ;;
309 hpux*)
310 SYS=hpux
311 ;;
312 *os2*)
313 SYS=os2
314 LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
315 AC_LIBOBJ([freeaddrinfo])
316 AC_LIBOBJ([gai_strerror])
317 AC_CHECK_FUNCS([if_nametoindex])
318 ;;
319 *nacl*)
320 SYS=nacl
321 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
322 AC_LIBOBJ([sigwait])
323 AC_LIBOBJ([recvmsg])
324 AC_LIBOBJ([sendmsg])
325 ;;
326 *)
327 SYS="${host_os}"
328 ;;
329 esac
331 dnl WinRT
332 AC_ARG_ENABLE([winstore_app],
333 AS_HELP_STRING([--enable-winstore-app],
334 [Build targetted for Windows Store apps (default disabled)]))
336 vlc_winstore_app=0
337 AS_IF([test "${SYS}" = "mingw32"],[
338 LIBCOM="-lole32"
339 AS_IF([test "${enable_winstore_app}" = "yes"], [
340 vlc_winstore_app=1
341 LIBCOM=""
342 VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
343 AC_LIBOBJ([gai_strerror])
344 ],[])
345 AC_SUBST([LIBCOM])
346 ])
347 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
349 AM_CONDITIONAL([HAVE_LINUX], [test "${SYS}" = "linux"])
350 AM_CONDITIONAL([HAVE_OS2], [test "${SYS}" = "os2"])
352 AM_CONDITIONAL([HAVE_DARWIN], [test "${SYS}" = "darwin"])
353 AM_CONDITIONAL([HAVE_IOS], [test "${HAVE_IOS}" = "1"])
354 AM_CONDITIONAL([HAVE_OSX], [test "${HAVE_OSX}" = "1"])
355 AM_CONDITIONAL([HAVE_TVOS], [test "${HAVE_TVOS}" = "1"])
357 AM_CONDITIONAL([HAVE_NACL], [test "${SYS}" = "nacl"])
358 AM_CONDITIONAL([HAVE_LIBANL], [test "${HAVE_LIBANL}" = "1"])
360 AM_CONDITIONAL([HAVE_WIN32], [test "${SYS}" = "mingw32"])
361 AM_CONDITIONAL([HAVE_WIN64], [test "${HAVE_WIN64}" = "1"]) dnl Only used for the packaging
362 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
363 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
365 dnl Use nasm/yasm only on x86
366 AC_CHECK_PROGS(X86ASM, [nasm yasm])
367 AM_CONDITIONAL([HAVE_X86ASM], [test -n "${X86ASM}" && test -n "${X86ASMFLAGS}"])
368 AM_COND_IF([HAVE_X86ASM], [
369 AC_DEFINE([HAVE_X86ASM], [1], [Use external asm on x86.])
370 ])
371 AC_SUBST([X86ASMFLAGS])
372 AC_SUBST([X86ASMDEFS])
374 dnl
375 dnl Sadly autoconf does not think about testing foo.exe when ask to test
376 dnl for program foo on win32
377 case "${build_os}" in
378 cygwin|msys|mingw32)
379 ac_executable_extensions=".exe"
380 BUILDEXEEXT=".exe"
381 ;;
382 os2*)
383 BUILDEXEEXT=".exe"
384 ;;
385 *)
386 ;;
387 esac
388 AC_SUBST([BUILDEXEEXT])
390 dnl Android is linux, but a bit different
391 AS_IF([test "$SYS" = linux],[
392 AC_MSG_CHECKING([for an Android system])
393 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
394 [[#ifndef __ANDROID__
395 # error Not Android
396 #endif
397 ]],[[;]])
398 ],[
399 HAVE_ANDROID="1"
400 AC_MSG_RESULT([yes])
401 ],[
402 AC_MSG_RESULT([no])
403 ])
404 ])
405 AM_CONDITIONAL([HAVE_ANDROID], [test "${HAVE_ANDROID}" = "1"])
407 dnl Tizen (minimum SDK version: 2.3)
408 AS_IF([test "$SYS" = linux],[
409 AC_MSG_CHECKING([for Tizen])
410 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
411 [[#include <tizen.h>
412 ]],[[;]])
413 ],[
414 HAVE_TIZEN="1"
415 AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
416 AC_MSG_RESULT([yes])
417 ],[
418 AC_MSG_RESULT([no])
419 ])
420 ])
421 AM_CONDITIONAL([HAVE_TIZEN], [test "${HAVE_TIZEN}" = "1"])
423 dnl
424 dnl Check for the contrib directory
425 dnl
426 AC_ARG_WITH(contrib,
427 AS_HELP_STRING([--with-contrib[=DIR]],
428 [search for 3rd party libraries in DIR/include and DIR/lib])
429 )
430 AC_MSG_CHECKING([for 3rd party libraries path])
431 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
432 CONTRIB_DIR="${srcdir}/contrib/${host}"
433 AS_IF([test ! -d "${CONTRIB_DIR}"], [
434 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
435 CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
436 AS_IF([test ! -d "${CONTRIB_DIR}"], [
437 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
438 CONTRIB_DIR=""
439 AC_MSG_RESULT([not found])
440 ])
441 ])
442 ], [
443 AS_IF([test "${with_contrib}" != "no"], [
444 CONTRIB_DIR="${with_contrib}"
445 ], [
446 CONTRIB_DIR=""
447 AC_MSG_RESULT([disabled])
448 ])
449 ])
450 AS_IF([test -n "${CONTRIB_DIR}"], [
451 AS_IF([test -d "${CONTRIB_DIR}/lib"],[
452 CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
453 ], [
454 echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
455 CONTRIB_DIR=""
456 AC_MSG_RESULT([not usable])
457 ])
459 ])
460 AS_IF([test -n "${CONTRIB_DIR}"], [
461 AC_MSG_RESULT([${CONTRIB_DIR}])
462 CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
463 CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
464 CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
465 OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
466 export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:${CONTRIB_DIR}/share/pkgconfig:$PKG_CONFIG_PATH"
467 LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
469 AS_IF([test -z "$LUAC"], [
470 dnl Old contribs mixed cross-tools and cross-compiled executables
471 AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
472 LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
473 ])
475 dnl Newer contribs follow usual name space rules
476 AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
477 LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
478 ])
479 ])
481 AS_IF([test "${SYS}" = "darwin"], [
482 export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
483 export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
484 ])
485 ], [
486 AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
487 AC_MSG_ERROR([Third party libraries not found!])
488 ])
489 ])
490 AC_SUBST([CONTRIB_DIR])
492 dnl Add extras/tools to the PATH
493 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
494 AS_IF([test -d "${TOOLS_DIR}"], [
495 TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
496 export PATH="${TOOLS_DIR}":$PATH
497 ])
499 dnl
500 dnl Libtool
501 dnl It's very bad, but our former custom system was worst
502 dnl -- Courmisch
503 dnl
505 dnl override platform specific check for dependent libraries
506 dnl otherwise libtool linking of shared libraries will
507 dnl fail on anything other than pass_all.
508 AC_CACHE_VAL(lt_cv_deplibs_check_method,
509 [lt_cv_deplibs_check_method=pass_all])
511 LT_INIT([dlopen win32-dll shared disable-static])
512 LT_LANG([C++])
513 LT_LANG([Windows Resource])
515 DOLT
517 lt_cv_deplibs_check_method=pass_all
519 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
520 AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
521 ])
523 dnl
524 dnl Gettext stuff
525 dnl
526 AM_GNU_GETTEXT_VERSION([0.19.8])
527 AM_GNU_GETTEXT([external], [need-formatstring-macros])
529 dnl
530 dnl Iconv stuff
531 dnl
532 AM_ICONV
534 dnl
535 dnl checks for mingw
536 AS_IF([test "${SYS}" = "mingw32"], [
538 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
539 #if !defined(__MINGW32__)
540 # error Not compiling with mingw
541 #endif
542 ])], [
544 dnl Check for broken versions of mingw-runtime compatability library
545 AC_MSG_CHECKING(for broken mingw-runtime)
546 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
547 #include <_mingw.h>
548 #if defined(__MINGW64_VERSION_MAJOR)
549 # if __MINGW64_VERSION_MAJOR < 5
550 # error Update your mingw-w64! This one is too old.
551 # endif
552 #else
553 # error You cannot compile with Mingw. Use Mingw-w64!
554 #endif
555 ])], [
556 AC_MSG_RESULT([ok])
557 ], [
558 AC_MSG_RESULT([present])
559 AC_MSG_ERROR([LibVLC requires Mingw-w64 version 5.0 or higher!])
560 ])
562 dnl force use of mingw provided c99 *printf over msvcrt
563 CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
565 dnl Check for the need to include the mingwex lib for mingw32
566 VLC_SAVE_FLAGS
567 AC_CHECK_LIB([mingwex], [opendir],
568 AC_CHECK_LIB([mingw32], [opendir],,
569 [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
570 )
571 VLC_RESTORE_FLAGS
572 ], [
573 AC_MSG_RESULT([Not compiling with mingw])
574 ])
576 dnl Check for fnative-struct or mms-bitfields support for mingw32
577 AX_CHECK_COMPILE_FLAG([-mms-bitfields], [
578 AX_APPEND_FLAG([-mms-bitfields], [CFLAGS])
579 AX_APPEND_FLAG([-mms-bitfields], [CXXFLAGS])
580 # Check for the warning flag without "-Wno-", GCC accepts
581 # -Wno-<anything> for unsupported warnings, which can trigger
582 # other warnings instead.
583 AX_CHECK_COMPILE_FLAG([-Wincompatible-ms-struct], [
584 AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CFLAGS])
585 AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CXXFLAGS])
586 ])
587 ], [
588 AX_CHECK_COMPILE_FLAG([-fnative-struct], [
589 AX_APPEND_FLAG([-fnative-struct], [CFLAGS])
590 AX_APPEND_FLAG([-fnative-struct], [CXXFLAGS])
591 ])
592 ])
593 ])
596 dnl
597 dnl Buggy glibc prevention. Purposedly not cached.
598 dnl See sourceware.org bugs 5058 and 5443.
599 dnl Ubuntu alone has 20 bug numbers for this...
600 dnl
601 AC_MSG_CHECKING(for buggy GNU/libc versions)
602 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
603 #include <limits.h>
604 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
605 && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
606 # error GNU/libc with dcgettext killer bug!
607 #endif
608 ])], [
609 AC_MSG_RESULT([not present])
610 ], [
611 AC_MSG_RESULT([found])
612 AS_IF([test "x${enable_nls}" != "xno"], [
613 AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
614 work-around for this. Check with your distribution vendor on how to update the
615 glibc run-time. Alternatively, build with --disable-nls.])
616 ])
617 ])
619 dnl Plugin compilation stuff
621 VLC_LIBRARY_SUFFIX
623 dnl Check for system libs needed
624 need_libc=false
626 dnl Check for usual libc functions
627 AC_CHECK_FUNCS([accept4 daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty memalign mkostemp mmap open_memstream newlocale openat pipe2 pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime uselocale])
628 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir flockfile fsync getdelim getpid lfind lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy tfind timegm timespec_get strverscmp pathconf])
629 AC_REPLACE_FUNCS([gettimeofday])
630 AC_CHECK_FUNC(fdatasync,,
631 [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
632 ])
634 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
636 dnl mingw64 implements those as static inline, not functions with C linkage
637 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
638 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
639 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
640 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
642 dnl C11 static_assert()
643 AC_MSG_CHECKING([for static_assert in assert.h])
644 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
645 static_assert(1, "The impossible happened.");
646 ])], [
647 AC_MSG_RESULT([yes])
648 AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
649 ], [
650 AC_MSG_RESULT([no])
651 ])
653 # Windows CE does not have strcoll()
654 AC_FUNC_STRCOLL
656 dnl Check for non-standard system calls
657 case "$SYS" in
658 "linux")
659 AC_CHECK_FUNCS([eventfd vmsplice sched_getaffinity recvmmsg memfd_create])
660 ;;
661 "mingw32")
662 AC_CHECK_FUNCS([_lock_file])
663 ;;
664 esac
666 AH_BOTTOM([#include <vlc_fixups.h>])
668 dnl Check for struct pollfd
669 AC_CHECK_TYPES([struct pollfd],,,
670 [#include <sys/types.h>
671 #if HAVE_POLL
672 # include <poll.h>
673 #elif defined (_WIN32)
674 # include <winsock2.h>
675 #endif
676 ])
678 dnl Check for struct timespec
679 AC_CHECK_TYPES([struct timespec],,,
680 [#include <time.h>])
682 dnl Check for max_align_t
683 AC_CHECK_TYPES([max_align_t],,,
684 [#include <stddef.h>])
686 dnl Checks for socket stuff
687 VLC_SAVE_FLAGS
688 SOCKET_LIBS=""
689 AC_SEARCH_LIBS(connect, [socket], [
690 AS_IF([test "$ac_cv_search_connect" != "none required"], [
691 SOCKET_LIBS="$ac_cv_search_connect"
692 ])
693 ], [
694 AS_IF([test "${SYS}" = "mingw32"], [
695 SOCKET_LIBS="-lws2_32 -liphlpapi"
696 ])
697 ])
699 AC_SEARCH_LIBS([inet_pton], [nsl], [
700 AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
701 SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
702 ])
703 ],, [${SOCKET_LIBS}])
705 LIBS="${LIBS} ${SOCKET_LIBS}"
706 AC_LINK_IFELSE([
707 AC_LANG_PROGRAM([#ifdef _WIN32
708 #include <ws2tcpip.h>
709 #include <windows.h>
710 # if _WIN32_WINNT < 0x600
711 # error Needs vista+
712 # endif
713 #else
714 #include <sys/socket.h>
715 #include <arpa/inet.h>
716 #endif], [
717 char dst[[sizeof(struct in_addr)]];
718 inet_pton(AF_INET, "127.0.0.1", dst);
719 ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
720 AC_CHECK_TYPES([struct if_nameindex],,,[#include <net/if.h>])
721 AC_CHECK_FUNCS([if_nameindex])
722 VLC_RESTORE_FLAGS
723 AC_SUBST([SOCKET_LIBS])
725 dnl Check for socklen_t
726 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
727 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
728 ac_cv_type_socklen_t,
729 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
730 [#include <sys/types.h>
731 #ifdef _WIN32
732 # include <winsock2.h>
733 # include <ws2tcpip.h>
734 #else
735 # include <sys/socket.h>
736 #endif]], [[socklen_t len; len = 0;]])],
737 ac_cv_type_socklen_t=yes,
738 ac_cv_type_socklen_t=no)])
739 AS_IF([test "$ac_cv_type_socklen_t" = no],
740 [AC_DEFINE(socklen_t, int)])
742 dnl Check for struct sockaddr_storage
743 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
744 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
745 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
746 [AC_TRY_COMPILE(
747 [#include <sys/types.h>
748 #if defined( _WIN32 )
749 # include <winsock2.h>
750 #else
751 # include <sys/socket.h>
752 #endif], [struct sockaddr_storage addr;],
753 ac_cv_struct_sockaddr_storage=yes,
754 ac_cv_struct_sockaddr_storage=no)])
755 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
756 AC_DEFINE(sockaddr_storage, sockaddr)
757 AC_DEFINE(ss_family, sa_family)
758 ])
760 dnl FreeBSD has a gnugetopt library for this:
761 GNUGETOPT_LIBS=""
762 AC_CHECK_FUNC(getopt_long,, [
763 AC_CHECK_LIB([gnugetopt],[getopt_long], [
764 GNUGETOPT_LIBS="-lgnugetopt"
765 ])
766 ])
767 AC_SUBST([GNUGETOPT_LIBS])
769 AC_CHECK_LIB([m], [cos], [
770 LIBM="-lm"
771 ], [
772 LIBM=""
773 ])
774 AC_SUBST([LIBM])
776 AC_CHECK_LIB([m], [lrintf], [
777 AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
778 VLC_ADD_LIBS([skins2],[-lm])
779 ])
780 AC_CHECK_LIB([m], [nanf],
781 AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
782 )
783 AC_CHECK_LIB([m], [sincos], [
784 AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
785 ], [
786 AC_LIBOBJ([sincos])
787 ])
789 AC_MSG_CHECKING([broken qsort_r prototype])
790 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <stdlib.h>
792 _Static_assert(_Generic((qsort_r),
793 void (*)(void *, size_t, size_t, void *,
794 int (*)(void *, const void *, const void *)) : 1, default: 0),
795 "Bad prototype not matched");
796 ])], [
797 AC_MSG_RESULT([broken])
798 AC_DEFINE([HAVE_BROKEN_QSORT_R], 1, [Defined to 1 if the qsort_r() prototype contradicts the upcoming POSIX standard.])
799 ], [
800 AC_MSG_RESULT([no])
801 ])
803 AC_MSG_CHECKING([_Thread_local support])
804 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
805 int main() {}])], [
806 AC_MSG_RESULT([ok])
807 AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
808 ],[ AC_MSG_RESULT([no])])
810 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
811 dnl check for its availability explicitely
812 AC_CHECK_HEADERS([threads.h])
814 AC_CHECK_LIB([anl],[getaddrinfo_a],[
815 AC_DEFINE(HAVE_LIBANL, 1, [Define to 1 if you have the anl library])
816 ])
818 dnl Check for dynamic plugins
819 LIBDL=""
820 have_dynamic_objects="no"
821 VLC_SAVE_FLAGS
822 AC_SEARCH_LIBS(dlsym, [dl svld], [
823 AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
824 LIBDL="$ac_cv_search_dlsym"
825 ])
826 have_dynamic_objects="yes"
827 ])
828 VLC_RESTORE_FLAGS
830 # Windows
831 AS_IF([test "${SYS}" = "mingw32"], [
832 LIBDL=""
833 have_dynamic_objects="yes" #assume we can use shared objects
834 ])
836 AC_ARG_WITH([libfuzzer],
837 AS_HELP_STRING([--with-libfuzzer=DIR],
838 [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)]),
839 [],
840 [with_libfuzzer=no])
841 AS_VAR_IF(with_libfuzzer, no, [], [
842 enable_shared=no
843 enable_static=yes
844 enable_vlc=no
845 ])
846 AM_CONDITIONAL([HAVE_LIBFUZZER], [test "${with_libfuzzer}" != "no"])
848 AS_IF([test "${enable_shared}" = "no"], [
849 have_dynamic_objects=no
850 ])
851 AM_CONDITIONAL([HAVE_DYNAMIC_PLUGINS], [test "${have_dynamic_objects}" != "no"])
853 AC_SUBST([LIBDL])
855 AS_IF([test "${SYS}" != "mingw32"], [
856 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
857 AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
858 LIBRT="$ac_cv_search_clock_nanosleep"
859 ])
860 ], [
861 AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
862 AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
863 LIBRT="$ac_cv_search_nanosleep"
864 ])
865 ])
866 ])
867 ])
868 AC_SUBST([LIBRT])
870 dnl
871 dnl Check for headers
872 dnl
874 dnl POSIX
875 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
876 AC_CHECK_HEADERS([net/if.h], [], [],
877 [
878 #include <sys/types.h>
879 #include <sys/socket.h>
880 ])
881 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
882 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
884 dnl BSD
885 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
887 dnl GNU/Linux
888 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
890 dnl MacOS
891 AC_CHECK_HEADERS([xlocale.h])
893 dnl Check if C++ headers define locale_t
894 AC_LANG_PUSH(C++)
895 AC_CACHE_CHECK([if C++ headers define locale_t],
896 [ac_cv_cxx_locale_t],
897 [ac_cv_cxx_locale_t=no
898 AC_TRY_COMPILE([#include <locale>], [locale_t loc;],
899 [ac_cv_cxx_locale_t=yes])])
900 if test "${ac_cv_cxx_locale_t}" != "no"; then
901 AC_DEFINE(HAVE_CXX_LOCALE_T, 1, Define to 1 if C++ headers define locale_t)
902 fi
903 AC_LANG_POP(C++)
905 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
906 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
907 AC_CHECK_TYPE(ssize_t,, [
908 AC_DEFINE(ssize_t, int)
909 ])
911 dnl It seems that autoconf detects pkg-config only during the first
912 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
913 dnl it is nested within a conditional block, so it was not working right.
914 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
915 AC_ARG_VAR(PKG_CONFIG_PATH,
916 [Paths where to find .pc not at the default location])
917 PKG_PROG_PKG_CONFIG()
919 dnl On some OS we need static linking
920 AS_IF([test -n "${PKG_CONFIG}" ],[
921 AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
922 PKG_CONFIG="${PKG_CONFIG} --static"
923 ])
924 ])
927 dnl
928 dnl Check for zlib.h and -lz if available
929 dnl
930 AC_CHECK_HEADERS([zlib.h], [ have_zlib=yes ], [ have_zlib=no ])
931 AM_CONDITIONAL([HAVE_ZLIB], [ test "${have_zlib}" = "yes" ])
932 if test "${have_zlib}" = "yes"
933 then
934 VLC_ADD_LIBS([sap],[-lz])
935 fi
938 dnl
939 dnl Domain name i18n support via GNU libidn
940 dnl
941 PKG_CHECK_MODULES([IDN], [libidn], [
942 have_libidn="yes"
943 AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
944 ], [
945 have_libidn="no"
946 ])
949 dnl Check for dbus
950 AC_ARG_ENABLE([dbus],
951 AS_HELP_STRING([--enable-dbus],
952 [compile D-Bus message bus support (default enabled)]))
953 have_dbus="no"
954 AS_IF([test "${enable_dbus}" != "no"], [
955 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
956 have_dbus="yes"
957 ], [
958 AS_IF([test -n "${enable_dbus}"], [
959 AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
960 ], [
961 AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
962 ])
963 ])
964 ])
965 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
968 dnl Check for systemd
969 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
970 have_systemd="yes"
971 ], [
972 AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
973 ])
974 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
977 EXTEND_HELP_STRING([Optimization options:])
978 dnl
979 dnl Compiler warnings
980 dnl
982 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security -Wduplicated-branches -Wduplicated-cond], [CFLAGS])
983 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security -Wduplicated-branches -Wduplicated-cond], [CXXFLAGS])
985 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local -Wmultistatement-macros], [CFLAGS])
986 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
988 dnl
989 dnl Debugging mode
990 dnl
991 AC_ARG_ENABLE([debug],
992 AS_HELP_STRING([--disable-debug],
993 [disable run-time assertions (default enabled)]),,
994 [enable_debug="yes"])
995 AH_TEMPLATE(NDEBUG,
996 [Define to 1 if debug code should NOT be compiled])
997 AS_IF([test "${enable_debug}" != "no"], [
998 AC_CHECK_HEADERS([valgrind/valgrind.h])
999 ], [
1000 AC_DEFINE(NDEBUG)
1001 ])
1003 dnl
1004 dnl Profiling
1005 dnl
1006 AC_ARG_ENABLE([gprof],
1007 AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)]),,
1008 [enable_gprof="no"])
1009 AS_IF([test "${enable_gprof}" != "no"], [
1010 CFLAGS="${CFLAGS} -pg"
1011 CXXFLAGS="${CXXFLAGS} -pg"
1012 OBJCFLAGS="${OBJCFLAGS} -pg"
1013 LDFLAGS="${LDFLAGS} -pg"
1014 ])
1016 AC_ARG_ENABLE([cprof],
1017 AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)]),,
1018 [enable_cprof="no"])
1019 AS_IF([test "${enable_gprof}" != "no"], [
1020 CFLAGS="${CFLAGS} -finstrument-functions"
1021 CXXFLAGS="${CXXFLAGS} -finstrument-functions"
1022 OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
1023 LDFLAGS="${LDFLAGS} -finstrument-functions"
1024 ])
1026 dnl
1027 dnl Test coverage
1028 dnl
1029 AC_ARG_ENABLE([coverage],
1030 AS_HELP_STRING([--enable-coverage],
1031 [build for test coverage (default disabled)]),,
1032 [enable_coverage="no"])
1033 AS_IF([test "${enable_coverage}" != "no"], [
1034 CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
1035 CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
1036 LDFLAGS="-lgcov ${LDFLAGS}"
1037 ])
1039 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
1040 VLC_SAVE_FLAGS
1041 CFLAGS="${CFLAGS} -fvisibility=hidden"
1042 CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
1043 OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1044 AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1045 [ac_cv_c_visibility_hidden], [
1046 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1047 ac_cv_c_visibility_hidden=yes
1048 ], [
1049 ac_cv_c_visibility_hidden=no
1050 ])
1051 ])
1052 AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1053 ])
1055 dnl
1056 dnl Sanitizer flags
1057 dnl
1058 AC_ARG_WITH([sanitizer],
1059 AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1060 [build with sanitizer flags (default disabled)]),
1061 [],
1062 [with_sanitizer=no])
1064 AS_VAR_IF(with_sanitizer, no, [], [
1065 AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1066 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1067 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1068 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1069 ], [
1070 AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1071 ])
1072 AX_APPEND_FLAG([-g])
1073 AX_APPEND_FLAG([-g], [CXXFLAGS])
1075 AS_IF([test -z "${with_sanitizer##*address*}" ], [
1076 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer -fsanitize=pointer-compare -fsanitize=pointer-subtract])
1077 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer -fsanitize=pointer-compare -fsanitize=pointer-subtract], [CXXFLAGS])
1078 ])
1079 AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1080 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1081 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1082 ])
1083 AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1084 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1085 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1086 ])
1087 ])
1089 dnl
1090 dnl Enable/disable optimizations
1091 dnl
1092 AC_ARG_ENABLE([optimizations],
1093 AS_HELP_STRING([--disable-optimizations],
1094 [disable compiler optimizations (default enabled)]),,
1095 [enable_optimizations="yes"])
1097 dnl Check for various optimization flags
1098 AS_IF([test "${enable_optimizations}" != "no"], [
1100 dnl -O3 only in production builds
1101 AS_IF([test "${enable_debug}" = "no"], [
1102 VLC_SAVE_FLAGS
1103 CFLAGS="${CFLAGS} -O3"
1104 CXXFLAGS="${CXXFLAGS} -O3"
1105 OBJCFLAGS="${OBJCFLAGS} -O3"
1106 AC_CACHE_CHECK([if $CC accepts -O3], [ac_cv_c_o3], [
1107 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1108 ac_cv_c_o3=yes
1109 ], [
1110 ac_cv_c_o3=no
1111 ])
1112 ])
1113 AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1114 ])
1116 dnl Check for fast maths
1117 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1118 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1120 AH_BOTTOM([
1121 #if defined(_MSC_VER) && !defined(__clang__)
1122 # pragma fenv_access(off)
1123 # pragma fp_contract(on)
1124 #elif defined(__GNUC__)
1125 /* Not supported so far */
1126 #else
1127 # pragma STDC FENV_ACCESS OFF
1128 # pragma STDC FP_CONTRACT ON
1129 #endif
1130 ])
1132 dnl Check for -funroll-loops
1133 VLC_SAVE_FLAGS
1134 CFLAGS="${CFLAGS} -funroll-loops"
1135 CXXFLAGS="${CXXFLAGS} -funroll-loops"
1136 OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1137 AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1138 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1139 ac_cv_c_unroll_loops=yes
1140 ], [
1141 ac_cv_c_unroll_loops=no
1142 ])
1143 ])
1144 AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1146 AS_IF([test "$enable_debug" = "no"], [
1147 dnl Check for -fomit-frame-pointer
1148 VLC_SAVE_FLAGS
1149 CFLAGS="${CFLAGS} -fomit-frame-pointer"
1150 CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1151 OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1152 AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1153 [ac_cv_c_omit_frame_pointer], [
1154 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1155 ac_cv_c_omit_frame_pointer=yes
1156 ], [
1157 ac_cv_c_omit_frame_pointer=no
1158 ])
1159 ])
1160 AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1161 ])
1163 ])
1165 AC_ARG_ENABLE([ssp],
1166 AS_HELP_STRING([--disable-ssp],
1167 [disable stack smashing protection (default enabled for optimized builds)]), [],
1168 [enable_ssp="yes"])
1170 AS_IF([test "${enable_ssp}" != "no" -a "${enable_optimizations}" != "no"], [
1171 VLC_SAVE_FLAGS
1172 AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1173 AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1174 dnl Win32 requires linking to ssp for stack-protection
1175 AS_IF([test "${SYS}" = "mingw32"], [
1176 LDFLAGS="${LDFLAGS} -lssp"
1177 AC_CACHE_CHECK([if linker supports stack protectors], [ac_cv_ld_ssp], [
1178 AC_TRY_LINK([#include <stdio.h>],[char buf[100]; fgets(buf, sizeof(buf), stdin);], [
1179 ac_cv_ld_ssp="yes"
1180 ], [
1181 ac_cv_ld_ssp="no"
1182 ])
1183 ])
1184 AS_IF([test "${ac_cv_ld_ssp}" = "no"], [VLC_RESTORE_FLAGS])
1185 ])
1186 ])
1188 AS_IF([test "${SYS}" = "mingw32"], [
1189 dnl library for BCrypt APIs
1190 AS_IF([test "${vlc_winstore_app}" = 1],
1191 [LDFLAGS="${LDFLAGS} -lbcrypt"])
1192 ])
1194 VLC_SAVE_FLAGS
1195 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1196 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1197 AC_TRY_LINK([],, [
1198 ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1199 ], [
1200 ac_cv_ld_bsymbolic=""
1201 ])
1202 ])
1203 VLC_RESTORE_FLAGS
1204 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1205 AC_SUBST([SYMBOLIC_LDFLAGS])
1207 VLC_SAVE_FLAGS
1208 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1209 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1210 AC_TRY_LINK([],, [
1211 ac_cv_ld_z_defs="yes"
1212 ], [
1213 ac_cv_ld_z_defs="no"
1214 ])
1215 ])
1216 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1218 dnl Check for __attribute__((packed))
1219 AC_CACHE_CHECK([for __attribute__((packed))],
1220 [ac_cv_c_attribute_packed],
1221 [ac_cv_c_attribute_packed=no
1222 AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1223 [ac_cv_c_attribute_packed=yes])])
1224 if test "${ac_cv_c_attribute_packed}" != "no"; then
1225 AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1226 fi
1228 dnl
1229 dnl Check the CPU
1230 dnl
1231 case "${host_cpu}" in
1232 "")
1233 ARCH=unknown
1234 ;;
1235 armv*)
1236 ARCH="arm"
1237 host_cpu="arm"
1238 ;;
1239 *)
1240 ARCH="${host_cpu}"
1241 ;;
1242 esac
1244 dnl Check for backtrace() support
1245 AC_CHECK_HEADERS([execinfo.h])
1246 AC_CHECK_FUNCS([backtrace])
1248 dnl
1249 dnl default modules
1250 dnl
1251 ALIASES="${ALIASES} cvlc rvlc"
1253 dnl
1254 dnl Accelerated modules
1255 dnl
1257 dnl Check for fully working MMX intrinsics
1258 dnl We need support for -mmmx, we need <mmintrin.h>, and we also need a
1259 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1260 AC_ARG_ENABLE([mmx],
1261 AS_HELP_STRING([--disable-mmx],
1262 [disable MMX optimizations (default auto)]),,[
1263 case "${host_cpu}" in
1264 i?86|x86_64)
1265 enable_mmx="yes"
1266 ;;
1267 *)
1268 enable_mmx="no"
1269 ;;
1270 esac
1271 ])
1272 have_mmx="no"
1273 have_mmxext="no"
1274 AS_IF([test "${enable_mmx}" != "no"], [
1275 ARCH="${ARCH} mmx"
1276 VLC_SAVE_FLAGS
1277 CFLAGS="${CFLAGS} -mmmx"
1278 AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1279 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1280 [#include <mmintrin.h>
1281 #include <stdint.h>
1282 uint64_t frobzor;]], [
1283 [__m64 a, b, c;
1284 a = b = c = (__m64)frobzor;
1285 a = _mm_slli_pi16(a, 3);
1286 a = _mm_adds_pi16(a, b);
1287 c = _mm_srli_pi16(c, 8);
1288 c = _mm_slli_pi16(c, 3);
1289 b = _mm_adds_pi16(b, c);
1290 a = _mm_unpacklo_pi8(a, b);
1291 frobzor = (uint64_t)a;]])], [
1292 ac_cv_c_mmx_intrinsics=yes
1293 ], [
1294 ac_cv_c_mmx_intrinsics=no
1295 ])
1296 ])
1297 VLC_RESTORE_FLAGS
1298 AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1299 AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1300 ])
1302 VLC_SAVE_FLAGS
1303 CFLAGS="${CFLAGS} -mmmx"
1304 AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1305 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1306 void *p;
1307 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1308 ]])
1309 ], [
1310 ac_cv_mmx_inline=yes
1311 ], [
1312 ac_cv_mmx_inline=no
1313 ])
1314 ])
1315 AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1316 AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1317 have_mmx="yes"
1318 ])
1320 AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1321 [ac_cv_mmxext_inline], [
1322 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1323 void *p;
1324 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1325 ]])
1326 ], [
1327 ac_cv_mmxext_inline=yes
1328 ], [
1329 ac_cv_mmxext_inline=no
1330 ])
1331 ])
1332 VLC_RESTORE_FLAGS
1333 AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1334 AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1335 have_mmxext="yes"
1336 ])
1337 ])
1338 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1339 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1341 dnl Check for fully workin SSE2 intrinsics
1342 dnl We need support for -mmmx, we need <emmintrin.h>, and we also need a
1343 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1344 AC_ARG_ENABLE([sse],
1345 AS_HELP_STRING([--disable-sse],
1346 [disable SSE (1-4) optimizations (default auto)]),, [
1347 case "${host_cpu}" in
1348 i?86|x86_64)
1349 enable_sse=yes
1350 ;;
1351 *)
1352 enable_sse=no
1353 ;;
1354 esac
1355 ])
1356 have_sse2="no"
1357 AS_IF([test "${enable_sse}" != "no"], [
1358 ARCH="${ARCH} sse sse2"
1360 VLC_SAVE_FLAGS
1361 CFLAGS="${CFLAGS} -msse2"
1362 AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1363 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1364 [#include <emmintrin.h>
1365 #include <stdint.h>
1366 uint64_t frobzor;]], [
1367 [__m128i a, b, c;
1368 a = b = c = _mm_set1_epi64((__m64)frobzor);
1369 a = _mm_slli_epi16(a, 3);
1370 a = _mm_adds_epi16(a, b);
1371 c = _mm_srli_epi16(c, 8);
1372 c = _mm_slli_epi16(c, 3);
1373 b = _mm_adds_epi16(b, c);
1374 a = _mm_unpacklo_epi8(a, b);
1375 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1376 ac_cv_c_sse2_intrinsics=yes
1377 ], [
1378 ac_cv_c_sse2_intrinsics=no
1379 ])
1380 ])
1381 VLC_RESTORE_FLAGS
1382 AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1383 AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1384 ])
1386 VLC_SAVE_FLAGS
1387 CFLAGS="${CFLAGS} -msse"
1388 AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1389 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1390 void *p;
1391 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1392 ]])
1393 ], [
1394 ac_cv_sse_inline=yes
1395 ], [
1396 ac_cv_sse_inline=no
1397 ])
1398 ])
1400 AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1401 AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1402 ])
1404 AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1405 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1406 void *p;
1407 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1408 ]])
1409 ], [
1410 ac_cv_sse2_inline=yes
1411 ], [
1412 ac_cv_sse2_inline=no
1413 ])
1414 ])
1415 AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1416 AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1417 have_sse2="yes"
1418 ])
1420 # SSE3
1421 AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1422 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1423 void *p;
1424 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1425 ]])
1426 ], [
1427 ac_cv_sse3_inline=yes
1428 ], [
1429 ac_cv_sse3_inline=no
1430 ])
1431 ])
1433 AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1434 AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1435 # SSSE3
1436 AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1437 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1438 void *p;
1439 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1440 ]])
1441 ], [
1442 ac_cv_ssse3_inline=yes
1443 ], [
1444 ac_cv_ssse3_inline=no
1445 ])
1446 ])
1448 AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1449 AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1451 # SSE4.1
1452 AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1453 [ac_cv_sse4_1_inline], [
1454 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1455 void *p;
1456 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1457 ]])
1458 ], [
1459 ac_cv_sse4_1_inline=yes
1460 ], [
1461 ac_cv_sse4_1_inline=no
1462 ])
1463 ])
1465 AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1466 AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1468 # SSE4.2
1469 AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1470 [ac_cv_sse4_2_inline], [
1471 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1472 void *p;
1473 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1474 ]])
1475 ], [
1476 ac_cv_sse4_2_inline=yes
1477 ], [
1478 ac_cv_sse4_2_inline=no
1479 ])
1480 ])
1482 AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1483 AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1485 # SSE4A
1486 AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1487 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1488 void *p;
1489 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1490 ]])
1491 ], [
1492 ac_cv_sse4a_inline=yes
1493 ], [
1494 ac_cv_sse4a_inline=no
1495 ])
1496 ])
1497 VLC_RESTORE_FLAGS
1498 AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1499 AC_DEFINE([CAN_COMPILE_SSE4A], [1], [Define to 1 if SSE4A inline assembly is available.]) ])
1500 ])
1501 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1503 VLC_SAVE_FLAGS
1504 CFLAGS="${CFLAGS} -mmmx"
1505 have_3dnow="no"
1506 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1507 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1508 void *p;
1509 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1510 ]])
1511 ], [
1512 ac_cv_3dnow_inline=yes
1513 ], [
1514 ac_cv_3dnow_inline=no
1515 ])
1516 ])
1517 VLC_RESTORE_FLAGS
1518 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1519 AC_DEFINE([CAN_COMPILE_3DNOW], 1,
1520 [Define to 1 if 3D Now! inline assembly is available.])
1521 have_3dnow="yes"
1522 ])
1523 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1526 AC_ARG_ENABLE([neon],
1527 AS_HELP_STRING([--disable-neon],
1528 [disable ARM NEON optimizations (default auto)]),, [
1529 case "${host_cpu}" in
1530 "arm")
1531 enable_neon="32"
1532 ;;
1533 "aarch64")
1534 enable_neon="64"
1535 ;;
1536 *)
1537 enable_neon="no"
1538 ;;
1539 esac
1540 ])
1541 AS_IF([test "${enable_neon}" != "no"], [
1542 VLC_SAVE_FLAGS
1543 AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1544 AS_IF([test "${enable_neon}" != "64"], [
1545 CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1546 AC_COMPILE_IFELSE([
1547 AC_LANG_PROGRAM(,[[
1548 asm volatile("vqmovun.s64 d0, q1":::"d0");
1549 ]])
1550 ], [
1551 ac_cv_arm_neon="32"
1552 ], [
1553 ac_cv_arm_neon="no"
1554 ])
1555 ], [
1556 CFLAGS="${CFLAGS} -march=armv8-a+simd"
1557 AC_COMPILE_IFELSE([
1558 AC_LANG_PROGRAM(,[[
1559 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1560 ]])
1561 ], [
1562 ac_cv_arm_neon="64"
1563 ], [
1564 ac_cv_arm_neon="no"
1565 ])
1566 ])
1567 ])
1568 VLC_RESTORE_FLAGS
1569 ])
1570 AM_CONDITIONAL([HAVE_NEON], [test "${ac_cv_arm_neon}" = "32"])
1571 AM_CONDITIONAL([HAVE_ARM64], [test "${ac_cv_arm_neon}" = "64"])
1573 AC_ARG_ENABLE([sve],
1574 AS_HELP_STRING([--disable-sve],
1575 [disable ARM SVE optimizations (default auto)]),, [
1576 AS_IF([test "${host_cpu}" = "aarch64"], [enable_sve="yes"] ,[enable_sve="no"])
1577 ])
1578 AS_IF([test "${enable_sve}" != "no"], [
1579 VLC_SAVE_FLAGS
1580 CFLAGS="${CFLAGS} -march=armv8-a+sve"
1581 AC_CACHE_CHECK([if $CCAS groks ARM SVE assembly], [ac_cv_arm_sve], [
1582 AC_COMPILE_IFELSE([
1583 AC_LANG_PROGRAM(,[[
1584 asm volatile("ptrue p0.s" ::: "p0");
1585 ]])
1586 ], [
1587 ac_cv_arm_sve="yes"
1588 ], [
1589 ac_cv_arm_sve="no"
1590 ])
1591 ])
1592 VLC_RESTORE_FLAGS
1593 ])
1594 AM_CONDITIONAL([HAVE_SVE], [test "${ac_cv_arm_sve}" = "yes"])
1597 AC_ARG_ENABLE([altivec],
1598 AS_HELP_STRING([--disable-altivec],
1599 [disable AltiVec optimizations (default auto)]),, [
1600 AS_CASE("${host_cpu}", [powerpc*],
1601 [enable_altivec=yes], [enable_altivec=no])
1602 ])
1603 have_altivec="no"
1604 ALTIVEC_CFLAGS=""
1605 AS_IF([test "${enable_altivec}" = "yes"], [
1606 ARCH="${ARCH} altivec";
1607 VLC_SAVE_FLAGS
1608 AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1609 [ac_cv_altivec_inline],
1610 [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1611 ac_cv_altivec_inline="yes",
1612 [CFLAGS="${CFLAGS} -Wa,-maltivec"
1613 AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1614 [ac_cv_altivec_inline="-Wa,-maltivec"],
1615 ac_cv_altivec_inline=no)
1616 ])])
1617 VLC_RESTORE_FLAGS
1618 AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1619 AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1620 [Define to 1 if AltiVec inline assembly is available.])
1621 AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1622 ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1623 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1624 ])
1625 have_altivec="yes"
1626 ])
1628 VLC_SAVE_FLAGS
1629 AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1630 [ac_cv_c_altivec], [
1631 CFLAGS="${CFLAGS} -maltivec"
1632 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1633 [#include <altivec.h>]], [
1634 [vec_ld(0, (unsigned char *)0);]])], [
1635 ac_cv_c_altivec="-maltivec"
1636 ], [
1637 ac_cv_c_altivec="no"
1638 ])
1639 ])
1640 VLC_RESTORE_FLAGS
1641 AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1642 CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1643 AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1644 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1645 ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1646 VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1647 have_altivec="yes"
1648 ])
1649 AC_CHECK_HEADERS([altivec.h])
1651 VLC_SAVE_FLAGS
1652 LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1653 AC_CACHE_CHECK([if linker needs -framework vecLib],
1654 [ac_cv_ld_altivec],
1655 [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1656 VLC_RESTORE_FLAGS
1657 AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1658 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1659 ])
1660 ])
1661 AC_SUBST([ALTIVEC_CFLAGS])
1662 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1664 dnl
1665 dnl Memory usage
1666 dnl
1667 AC_ARG_ENABLE([optimize-memory],
1668 AS_HELP_STRING([--enable-optimize-memory],
1669 [optimize memory usage over performance]))
1670 if test "${enable_optimize_memory}" = "yes"; then
1671 AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1672 fi
1674 dnl
1675 dnl Allow running as root (useful for people running on embedded platforms)
1676 dnl
1677 AC_ARG_ENABLE([run-as-root],
1678 AS_HELP_STRING([--enable-run-as-root],
1679 [allow running VLC as root (default disabled)]))
1680 AS_IF([test "${enable_run_as_root}" = "yes"],[
1681 AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1682 [Define to 1 to allow running VLC as root (uid 0).])
1683 ])
1685 dnl
1686 dnl Stream output
1687 dnl
1688 AC_ARG_ENABLE([sout],
1689 AS_HELP_STRING([--disable-sout],
1690 [disable streaming output (default enabled)]))
1691 AS_IF([test "${enable_sout}" != "no"], [
1692 AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1693 ])
1694 AM_CONDITIONAL([ENABLE_SOUT], [test "${enable_sout}" != "no"])
1696 dnl Lua modules
1697 AC_ARG_ENABLE([lua],
1698 AS_HELP_STRING([--disable-lua],
1699 [disable LUA scripting support (default enabled)]))
1700 if test "${enable_lua}" != "no"
1701 then
1702 PKG_CHECK_MODULES(LUA, lua5.2,
1703 [ have_lua=yes ],
1704 [
1705 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1707 PKG_CHECK_MODULES(LUA, lua5.1,
1708 [ have_lua=yes ],
1709 [
1710 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1711 PKG_CHECK_MODULES(LUA, lua >= 5.1,
1712 [ have_lua=yes ],
1713 [
1714 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1715 have_lua=yes
1716 AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1717 [],
1718 [ have_lua=no ] )
1719 AC_CHECK_LIB( lua5.2 , luaL_newstate,
1720 [LUA_LIBS="-llua5.2"],
1721 AC_CHECK_LIB( lua5.1 , luaL_newstate,
1722 [LUA_LIBS="-llua5.1"],
1723 AC_CHECK_LIB( lua51 , luaL_newstate,
1724 [LUA_LIBS="-llua51"],
1725 AC_CHECK_LIB( lua , luaL_newstate,
1726 [LUA_LIBS="-llua"],
1727 [ have_lua=no
1728 ], [-lm])
1729 )))
1730 ])
1731 ])
1732 ])
1733 if test "x${have_lua}" != "xyes" ; then
1734 AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1735 fi
1736 AC_ARG_VAR([LUAC], [LUA byte compiler])
1737 AS_IF([test -z "$LUAC"], [
1738 AC_CHECK_TOOL(LUAC, [luac], [false])
1739 ])
1740 AS_IF([test "${LUAC}" = "false"], [
1741 AC_MSG_ERROR([Could not find the LUA byte compiler.])
1742 ])
1743 AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1744 AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1745 ])
1746 fi
1747 AM_CONDITIONAL([BUILD_LUA], [test "${have_lua}" = "yes"])
1750 dnl
1751 dnl VideoLAN manager
1752 dnl
1753 AC_ARG_ENABLE([vlm],
1754 AS_HELP_STRING([--disable-vlm],
1755 [disable the stream manager (default enabled)]),,
1756 [enable_vlm="${enable_sout}"])
1757 AS_IF([test "${enable_vlm}" != "no"], [
1758 AS_IF([test "${enable_sout}" = "no"], [
1759 AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1760 ])
1761 AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1762 ])
1763 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1766 dnl
1767 dnl Addons manager storage and repositories modules
1768 dnl
1769 AC_ARG_ENABLE([addonmanagermodules],
1770 AS_HELP_STRING([--disable-addonmanagermodules],
1771 [disable the addons manager modules (default enabled)]))
1772 if test "${enable_addonmanagermodules}" != "no"
1773 then
1774 AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1775 fi
1776 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1779 dnl
1780 dnl Input plugins
1781 dnl
1783 EXTEND_HELP_STRING([Input plugins:])
1785 dnl
1786 dnl libarchive access module
1787 dnl
1788 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1790 dnl
1791 dnl live555 input
1792 dnl
1793 AC_ARG_ENABLE([live555],
1794 AS_HELP_STRING([--enable-live555],
1795 [enable RTSP input through live555 (default enabled)]))
1797 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1798 PKG_CHECK_MODULES(LIVE555, live555, [
1799 VLC_ADD_PLUGIN([live555])
1800 VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1801 VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1802 ], [
1803 AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1805 AC_LANG_PUSH(C++)
1806 VLC_SAVE_FLAGS
1808 dnl detect include paths
1809 AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1810 CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1811 ], [
1812 AS_IF([test "${SYS}" != "os2"], [
1813 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1814 CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1815 ], [
1816 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1817 CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1818 LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1819 ])
1820 ])
1822 dnl CPP Flags
1823 AS_IF([test "${SYS}" = "solaris"], [
1824 CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1825 ])
1826 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1827 LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1829 dnl version check
1830 AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1831 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1832 [#include <liveMedia_version.hh>
1833 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1834 # error BOOM
1835 #endif]])
1836 ], [
1837 ac_cv_live555="yes"
1838 ], [
1839 ac_cv_live555="no"
1840 ])
1841 ])
1843 AS_IF([test "$ac_cv_live555" = "no"], [
1844 AC_MSG_WARN([live555 is missing or its installed version is too old:
1845 Version 2011.12.23 or later is required to proceed.
1846 You can get an updated one from http://www.live555.com/liveMedia .])
1847 AS_IF([test -n "${enable_live555}"], [
1848 AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1849 ])
1850 ], [
1851 other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1852 other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1853 AS_IF([test "${SYS}" = "mingw32"], [
1854 # add ws2_32 for closesocket, select, recv
1855 other_libs="$other_libs -lws2_32"
1856 ])
1858 dnl We need to check for pic because live555 don't provide shared libs
1859 dnl and we want to build a plugins so we need -fPIC on some arch.
1860 VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1861 VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1862 AC_CHECK_LIB([liveMedia_pic], [main], [
1863 VLC_ADD_PLUGIN([live555])
1864 VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1865 ],[
1866 AC_CHECK_LIB([liveMedia], [main], [
1867 VLC_ADD_PLUGIN([live555])
1868 VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1869 ],[],[${other_libs}])
1870 ],[${other_libs_pic}])
1871 ])
1872 VLC_RESTORE_FLAGS
1873 AC_LANG_POP(C++)
1874 ])
1875 ])
1877 dnl
1878 dnl IIDC and DV FireWire input modules
1879 dnl
1880 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1881 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1883 dnl
1884 dnl - linsys modules: access module check for libzvbi
1885 dnl
1886 AC_ARG_ENABLE([linsys],
1887 AS_HELP_STRING([--enable-linsys],
1888 [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)]))
1889 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1890 VLC_ADD_PLUGIN([linsys_hdsdi])
1891 PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1892 VLC_ADD_PLUGIN([linsys_sdi])
1893 ], [
1894 AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1895 ])
1896 ])
1898 dnl
1899 dnl dvdread module: check for libdvdread
1900 dnl
1901 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 6.0.0], [dvdread input module], [auto])
1903 dnl
1904 dnl libdvdnav plugin
1905 dnl
1906 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav >= 6.0.0], [DVD with navigation input module (dvdnav)], [auto])
1908 dnl
1909 dnl Blu-ray Disc Support with libbluray
1910 dnl
1911 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1913 dnl
1914 dnl OpenCV wrapper and example filters
1915 dnl
1916 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1919 dnl
1920 dnl libsmbclient plugin
1921 dnl
1922 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smbc], [smbclient], (SMB/CIFS support), [auto])
1924 dnl
1925 dnl liBDSM access module
1926 dnl
1927 AM_CONDITIONAL([HAVE_DSM], [test "$AS_TR_SH(with_dsm)" = "yes"])
1928 PKG_WITH_MODULES([DSM], [libdsm >= 0.2.0], [
1929 VLC_ADD_PLUGIN([dsm])
1930 VLC_ADD_CFLAGS([dsm], [$DSM_CFLAGS])
1931 VLC_ADD_LIBS([dsm], [$DSM_LIBS])
1932 have_dsm="yes"
1933 ],,[libdsm SMB/CIFS access/sd module], [auto])
1934 AM_CONDITIONAL([HAVE_DSM], [test "${have_dsm}" = "yes"])
1936 dnl
1937 dnl sftp access support
1938 dnl
1939 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1941 dnl
1942 dnl nfs access support
1943 dnl
1944 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1946 dnl
1947 dnl smb2 access support
1948 dnl
1949 PKG_ENABLE_MODULES_VLC([SMB2], [smb2], [libsmb2 >= 2.0.0], (support smb2 protocol via libsmb2), [auto])
1951 dnl
1952 dnl Video4Linux 2
1953 dnl
1954 AC_ARG_ENABLE([v4l2], AS_HELP_STRING([--disable-v4l2],
1955 [disable Video4Linux version 2 (default auto)]))
1956 have_v4l2="no"
1957 AS_IF([test "$enable_v4l2" != "no"], [
1958 AC_CHECK_HEADERS([linux/videodev2.h], [
1959 have_v4l2="yes"
1960 ])
1961 ])
1962 AM_CONDITIONAL([HAVE_V4L2], [test "${have_v4l2}" != "no"])
1964 dnl
1965 dnl special access module for Blackmagic SDI cards
1966 dnl
1967 AC_ARG_ENABLE([decklink],
1968 AS_HELP_STRING([--disable-decklink],
1969 [disable Blackmagic DeckLink SDI input (default auto)]))
1970 AC_ARG_WITH([decklink_sdk],
1971 AS_HELP_STRING([--with-decklink-sdk=DIR],
1972 [location of Blackmagic DeckLink SDI SDK]))
1973 have_decklink=no
1974 if test "${enable_decklink}" != "no"
1975 then
1976 if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1977 then
1978 VLC_ADD_CPPFLAGS([decklink decklinkoutput stream_out_sdi],[-I${with_decklink_sdk}/include])
1979 fi
1980 VLC_SAVE_FLAGS
1981 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1982 AC_LANG_PUSH([C++])
1983 AC_CHECK_HEADERS([DeckLinkAPIDispatch.cpp], [
1984 have_decklink=yes
1985 AS_IF([test "${SYS}" = "darwin"], [
1986 VLC_ADD_LIBS([decklink decklinkoutput],[-Wl,-framework,CoreFoundation])
1987 ])
1988 ], [
1989 AS_IF([test "${enable_decklink}" = "yes"], [
1990 AC_MSG_ERROR([Blackmagic DeckLink SDI include files not found!])
1991 ], [
1992 AC_MSG_WARN([Blackmagic DeckLink SDI include files not found, decklink disabled])
1993 ])
1994 ])
1995 AC_LANG_POP([C++])
1996 VLC_RESTORE_FLAGS
1997 fi
1998 AM_CONDITIONAL([HAVE_DECKLINK], [ test "${have_decklink}" != "no" ])
2001 dnl
2002 dnl Built-in CD-DA and VCD module
2003 dnl
2004 AC_ARG_ENABLE([vcd],
2005 AS_HELP_STRING([--disable-vcd],
2006 [disable built-in VCD and CD-DA support (default enabled)]))
2008 AC_ARG_ENABLE([libcddb],
2009 AS_HELP_STRING([--disable-libcddb],
2010 [disable CDDB for Audio CD (default enabled)]))
2012 if test "${enable_vcd}" != "no"
2013 then
2014 AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
2015 AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
2016 AC_MSG_RESULT(yes)
2017 VLC_ADD_PLUGIN([vcd cdda])
2018 ],[
2019 AC_MSG_RESULT(no)
2020 ])
2022 AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
2023 AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
2024 AC_MSG_RESULT(yes)
2025 VLC_ADD_PLUGIN([vcd cdda])
2026 AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
2027 ],[
2028 AC_MSG_RESULT(no)
2029 ])
2031 AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
2032 AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
2033 AC_MSG_RESULT(yes)
2034 VLC_ADD_PLUGIN([vcd cdda])
2035 AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
2036 ],[
2037 AC_MSG_RESULT(no)
2038 ])
2040 if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
2041 then
2042 VLC_ADD_PLUGIN([vcd cdda])
2043 fi
2045 if test "$enable_libcddb" != "no"; then
2046 PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
2047 HAVE_LIBCDDB=yes
2048 AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
2049 VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
2050 VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
2051 ],:
2052 [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
2053 HAVE_LIBCDDB=no])
2054 fi
2055 fi
2057 dnl
2058 dnl Linux DVB
2059 dnl
2060 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
2061 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
2062 [#include <linux/dvb/version.h>
2063 #if (DVB_API_VERSION < 5)
2064 # error Linux DVB API v3.2 and older are not supported.
2065 #endif
2066 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
2067 # error Linux DVB API v5.0 is unsupported. Please update.
2068 #endif
2069 ]])], [
2070 ac_cv_linux_dvb_5_1=yes
2071 ], [
2072 ac_cv_linux_dvb_5_1=no
2073 ])])
2074 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
2076 dnl
2077 dnl Screen capture module
2078 dnl
2079 AC_ARG_ENABLE([screen],
2080 AS_HELP_STRING([--enable-screen],
2081 [disable screen capture (default enabled)]))
2082 if test "${enable_screen}" != "no"; then
2083 if test "${SYS}" = "darwin"; then
2084 AC_CHECK_HEADERS([ApplicationServices/ApplicationServices.h], [
2085 VLC_ADD_PLUGIN([screen])
2086 ])
2087 fi
2088 fi
2089 AM_CONDITIONAL([HAVE_MAC_SCREEN], [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
2091 dnl
2092 dnl VNC/RFB access module
2093 dnl
2094 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
2096 dnl RDP/Remote Desktop access module
2097 dnl
2098 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
2100 dnl
2101 dnl AVFoundation
2102 AC_SUBST([have_avfoundation], ["no"])
2103 AC_ARG_ENABLE([macosx-avfoundation],
2104 AS_HELP_STRING([--enable-macosx-avfoundation], [Mac OS X avcapture (video) module (default enabled on Mac OS X)]))
2105 if test "x${enable_macosx_avfoundation}" != "xno" &&
2106 (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2107 then
2108 SAVED_LIBS="${LIBS}"
2109 LIBS="-framework AVFoundation"
2110 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2111 LIBS="${SAVED_LIBS}"
2112 if test "${have_avfoundation}" != "no"
2113 then
2114 VLC_ADD_PLUGIN([avcapture])
2115 fi
2116 fi
2117 AM_CONDITIONAL([HAVE_AVFOUNDATION], [test "${have_avfoundation}" != "no"])
2119 dnl
2120 dnl DCP plugin (using asdcplib)
2121 dnl
2122 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2123 AM_CONDITIONAL([HAVE_ASDCP], [test "${have_asdcp}" = "yes"])
2125 dnl
2126 dnl Demux plugins
2127 dnl
2129 EXTEND_HELP_STRING([Mux/Demux plugins:])
2131 dnl
2132 dnl libdvbpsi check for ts mux/demux
2133 dnl
2134 have_dvbpsi="no"
2135 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2136 AM_CONDITIONAL([HAVE_DVBPSI], [test "${have_dvbpsi}" = "yes"])
2139 dnl
2140 dnl GME demux plugin
2141 dnl
2142 AC_ARG_ENABLE([gme],
2143 AS_HELP_STRING([--enable-gme],
2144 [use Game Music Emu (default auto)]))
2145 AS_IF([test "${enable_gme}" != "no"], [
2146 AC_CHECK_HEADER([gme/gme.h], [
2147 AC_CHECK_LIB([gme], [gme_identify_header], [
2148 VLC_ADD_PLUGIN([gme])
2149 ], [
2150 AC_CHECK_LIB([gme], [gme_identify_extension], [
2151 VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2152 VLC_ADD_PLUGIN([gme])
2153 ],, [-lstdc++ $LIBM])
2154 ])
2155 VLC_ADD_LIBS([gme], [-lgme])
2156 ], [
2157 AS_IF([test "x${enable_gme}" != "x"], [
2158 AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2159 ])
2160 ])
2161 ])
2164 dnl
2165 dnl SIDPlay plugin
2166 dnl
2167 AC_ARG_ENABLE([sid],
2168 AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)]))
2169 AS_IF([test "${enable_sid}" != "no"], [
2170 PKG_CHECK_MODULES(SID, [libsidplay2], [
2171 AC_LANG_PUSH(C++)
2172 oldCPPFLAGS="$CPPFLAGS"
2173 CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2174 AC_CHECK_HEADER([sidplay/builders/resid.h], [
2175 VLC_ADD_PLUGIN([sid])
2176 VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2177 VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2178 ], [
2179 AS_IF([test -n "${enable_sid}"],
2180 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2181 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2182 )
2183 ])
2184 CPPFLAGS="$oldCPPFLAGS"
2185 AC_LANG_POP(C++)
2186 ], [
2187 AS_IF([test "x${enable_sid}" = "xyes"],
2188 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2189 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2190 )
2191 ])
2192 ])
2195 dnl
2196 dnl ogg demux plugin
2197 dnl
2198 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2199 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2200 AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2201 ],[true])
2202 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2203 if test "${enable_sout}" != "no"; then
2204 dnl Check for libshout
2205 PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2206 fi
2208 dnl
2209 dnl matroska demux plugin
2210 dnl
2211 PKG_WITH_MODULES([MATROSKA], [libebml libmatroska], [
2212 VLC_ADD_PLUGIN([mkv])
2213 VLC_ADD_CFLAGS([mkv], [$MATROSKA_CFLAGS])
2214 VLC_ADD_LIBS([mkv], [$MATROSKA_LIBS])
2215 have_matroska="yes"
2216 ],,[MKV format support], [auto])
2217 AM_CONDITIONAL([HAVE_MATROSKA], [test "${have_matroska}" = "yes"])
2219 dnl
2220 dnl modplug demux plugin
2221 dnl
2222 AC_ARG_ENABLE([mod],
2223 AS_HELP_STRING([--disable-mod],
2224 [do not use libmodplug (default auto)]))
2225 if test "${enable_mod}" != "no" ; then
2226 PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2227 VLC_ADD_PLUGIN([mod])
2228 VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2229 VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2230 VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2231 ],[
2232 AS_IF([test -n "${enable_mod}"],
2233 [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2234 [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2235 ])
2236 fi
2238 dnl
2239 dnl mpc demux plugin
2240 dnl
2241 AC_ARG_ENABLE([mpc],
2242 AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)]))
2243 if test "${enable_mpc}" != "no"
2244 then
2245 AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2246 VLC_ADD_PLUGIN([mpc])
2247 VLC_ADD_LIBS([mpc],[-lmpcdec])])
2248 fi
2250 dnl
2251 dnl Codec plugins
2252 dnl
2254 EXTEND_HELP_STRING([Codec plugins:])
2256 dnl
2257 dnl wmafixed plugin
2258 dnl
2259 AC_ARG_ENABLE([wma-fixed],
2260 AS_HELP_STRING([--enable-wma-fixed], [libwma-fixed module (default disabled)]))
2261 if test "${enable_wma_fixed}" = "yes"
2262 then
2263 VLC_ADD_PLUGIN([wma_fixed])
2264 fi
2266 dnl
2267 dnl shine encoder plugin
2268 dnl
2269 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2272 dnl
2273 dnl openmax il codec plugin
2274 dnl
2275 AC_ARG_ENABLE([omxil],
2276 AS_HELP_STRING([--enable-omxil], [openmax il codec module (default disabled)]))
2277 if test "${enable_omxil}" = "yes"
2278 then
2279 VLC_ADD_PLUGIN([omxil])
2280 fi
2282 dnl
2283 dnl raspberry pi openmax il configuration
2284 dnl
2285 AC_ARG_ENABLE([rpi-omxil],
2286 AS_HELP_STRING([--enable-rpi-omxil], [openmax il configured for raspberry pi (default disabled)]))
2287 if test "${enable_rpi_omxil}" = "yes"
2288 then
2289 VLC_ADD_PLUGIN([omxil])
2290 VLC_ADD_CFLAGS([omxil],[-DRPI_OMX])
2291 fi
2293 dnl
2294 dnl CrystalHD codec plugin
2295 dnl
2296 AC_ARG_ENABLE([crystalhd],
2297 AS_HELP_STRING([--enable-crystalhd], [crystalhd codec plugin (default auto)]))
2298 if test "${enable_crystalhd}" != "no"; then
2299 AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2300 VLC_ADD_PLUGIN([crystalhd])
2301 VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2302 ],[
2303 if test "${SYS}" = "mingw32" ; then
2304 AC_CHECK_HEADERS([libcrystalhd/bc_dts_defs.h], [
2305 VLC_ADD_PLUGIN([crystalhd])
2306 AC_CHECK_HEADERS([libcrystalhd/bc_drv_if.h], [
2307 VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2308 ])
2309 ],[
2310 AS_IF([test x"${enable_crystalhd}" = "xyes"],
2311 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2312 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2313 ],[#define __LINUX_USER__
2314 #include <libcrystalhd/bc_dts_types.h>
2315 ])
2316 fi
2317 ],[
2318 #include <libcrystalhd/bc_dts_types.h>
2319 ])
2320 fi
2322 dnl
2323 dnl mad plugin
2324 dnl
2325 have_mad="no"
2326 MAD_CFLAGS=""
2327 MAD_LIBS=""
2329 AC_ARG_WITH(mad, AS_HELP_STRING([--with-mad=PATH], [path to libmad]), [
2330 enable_mad="yes"
2331 ], [
2332 with_mad="no"
2333 ])
2334 AS_IF([test "${with_mad}" != "no"], [
2335 MAD_CFLAGS="-I${with_mad}/include"
2336 MAD_LIBS="-L${with_mad}/lib"
2337 ])
2339 AC_ARG_ENABLE([mad],
2340 AS_HELP_STRING([--enable-mad], [libmad module (default enabled)]))
2341 AS_IF([test "${enable_mad}" != "no"], [
2342 VLC_SAVE_FLAGS
2343 CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2344 LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2345 AC_CHECK_HEADERS([mad.h], [
2346 AC_CHECK_LIB([mad], [mad_bit_init], [
2347 have_mad="yes"
2348 MAD_LIBS="${MAD_LIBS} -lmad"
2349 ])
2350 ])
2351 VLC_RESTORE_FLAGS
2352 AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2353 AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2354 ])
2355 ])
2356 AC_SUBST([MAD_CFLAGS])
2357 AC_SUBST([MAD_LIBS])
2358 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2360 dnl mpg123 plugin
2361 dnl
2362 dnl
2363 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2365 dnl
2366 dnl gstreamer stuff
2367 dnl
2368 AC_ARG_ENABLE([gst-decode],
2369 AS_HELP_STRING([--enable-gst-decode], [GStreamer based decoding support (currently supports only video decoding) (default auto)]))
2371 have_gst_decode="no"
2372 AS_IF([test "${enable_gst_decode}" != "no"], [
2373 PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2374 PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2375 have_gst_decode="yes"
2376 ], [
2377 AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2378 ])
2379 ], [
2380 AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2381 ])
2382 ])
2383 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2385 dnl
2386 dnl avcodec decoder/encoder plugin
2387 dnl
2388 AC_ARG_ENABLE([merge-ffmpeg],
2389 AS_HELP_STRING([--enable-merge-ffmpeg], [merge FFmpeg-based plugins (default disabled)]),, [
2390 enable_merge_ffmpeg="no"
2391 ])
2392 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2394 AC_MSG_CHECKING([for libavutil variant])
2395 PKG_CHECK_EXISTS([libavutil], [
2396 libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2397 libavutil_micro="${libavutil_version##*.}"
2398 AS_IF([test ${libavutil_micro} -le 99], [
2399 avfork="libav"
2400 ], [
2401 avfork="ffmpeg"
2402 ])
2403 ], [
2404 avfork="none"
2405 ])
2406 AC_MSG_RESULT([${avfork}])
2408 AC_ARG_ENABLE([avcodec],
2409 AS_HELP_STRING([--enable-avcodec], [libavcodec codec (default enabled)]))
2410 AS_IF([test "${enable_avcodec}" != "no"], [
2411 dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2412 case "${avfork}" in
2413 libav) av_codec_ver="57.16.0" ;;
2414 dnl 05f66706d182eb0c36af54d72614bf4c33e957a9 includes libavutil 55.9.0
2415 ffmpeg) av_codec_ver="57.37.100" ;;
2416 dnl 7fc329e2dd6226dfecaa4a1d7adf353bf2773726 include libavutil 55.22.101
2417 *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2418 esac
2419 PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 55.9.0], [
2420 VLC_SAVE_FLAGS
2421 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2422 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2423 AC_CHECK_HEADERS([libavcodec/avcodec.h])
2424 AC_CHECK_HEADERS([libavutil/avutil.h])
2425 VLC_RESTORE_FLAGS
2426 have_avcodec="yes"
2427 ],[
2428 AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2429 ])
2430 ], [
2431 have_avcodec="no"
2432 ])
2433 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2435 dnl
2436 dnl libva needs avcodec
2437 dnl
2438 AC_ARG_ENABLE([libva],
2439 AS_HELP_STRING([--enable-libva], [VAAPI GPU decoding support (libVA) (default auto)]))
2441 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2442 AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2443 ])
2445 have_vaapi="no"
2446 have_vaapi_drm="no"
2447 have_vaapi_x11="no"
2448 have_vaapi_wl="no"
2449 AS_IF([test "${enable_libva}" != "no"], [
2450 PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2451 have_vaapi="yes"
2452 ], [
2453 AS_IF([test -n "${enable_libva}"], [
2454 AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2455 ], [
2456 AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2457 ])
2458 ])
2459 PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2460 have_vaapi_drm="yes"
2461 ], [
2462 AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2463 ])
2464 PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2465 have_vaapi_x11="yes"
2466 ], [
2467 AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2468 ])
2469 PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2470 have_vaapi_wl="yes"
2471 ], [
2472 AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2473 ])
2474 ])
2475 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2476 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2477 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2478 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2480 have_avcodec_vaapi="no"
2481 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2482 VLC_SAVE_FLAGS
2483 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2484 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2485 AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2486 AC_MSG_NOTICE([VA API acceleration activated])
2487 have_avcodec_vaapi="yes"
2488 ],[
2489 AS_IF([test -n "${enable_libva}"], [
2490 AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2491 ], [
2492 AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2493 ])
2494 ])
2495 VLC_RESTORE_FLAGS
2496 ])
2497 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2499 dnl
2500 dnl dxva2 needs avcodec
2501 dnl
2502 AC_ARG_ENABLE([dxva2],
2503 AS_HELP_STRING([--enable-dxva2], [DxVA2 GPU decoding support (default auto)]))
2505 have_avcodec_dxva2="no"
2506 AS_IF([test "${enable_dxva2}" != "no"], [
2507 if test "${SYS}" = "mingw32"; then
2508 AS_IF([test "x${have_avcodec}" = "xyes"], [
2509 AC_CHECK_HEADERS([dxva2api.h],
2510 [
2511 AC_CHECK_HEADERS([libavcodec/dxva2.h], [
2512 AC_MSG_NOTICE([DxVA2 acceleration activated])
2513 have_avcodec_dxva2="yes"
2514 ],[
2515 AS_IF([test "${enable_dxva2}" = "yes"],
2516 [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2517 [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2518 ], [#undef _WIN32_WINNT
2519 /* DXVA2 is only available in Vista and above */
2520 #define _WIN32_WINNT 0x600])
2521 ],[
2522 AS_IF([test "${enable_dxva2}" = "yes"],
2523 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2524 [AC_MSG_WARN([dxva2api.h not found])])
2525 ],[#include <d3d9.h>])
2526 ],[
2527 AS_IF([test "x${enable_dxva2}" != "x"], [
2528 AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2529 ])
2530 ])
2531 fi
2532 ])
2533 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2535 dnl
2536 dnl d3d11va needs avcodec
2537 dnl
2538 AC_ARG_ENABLE([d3d11va],
2539 AS_HELP_STRING([--enable-d3d11va], [D3D11 GPU decoding support (default auto)]))
2541 have_avcodec_d3d11va="no"
2542 AS_IF([test "${enable_d3d11va}" != "no"], [
2543 if test "${SYS}" = "mingw32"; then
2544 AS_IF([test "x${have_avcodec}" = "xyes"], [
2545 AC_CHECK_TYPES([ID3D11VideoDecoder],
2546 [
2547 AC_CHECK_HEADERS([dxva2api.h],
2548 [
2549 AC_CHECK_HEADERS([libavcodec/d3d11va.h], [
2550 AC_MSG_NOTICE([D3D11 acceleration activated])
2551 AC_DEFINE([HAVE_AVCODEC_D3D11VA], [1], [Define if the d3d11va module is built])
2552 have_avcodec_d3d11va="yes"
2553 ],[
2554 AS_IF([test "${enable_d3d11va}" = "yes"],
2555 [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2556 [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2557 ], [#undef _WIN32_WINNT
2558 /* D3D11 is only available in Vista and above */
2559 #define _WIN32_WINNT 0x600])
2560 ],[
2561 AS_IF([test "${enable_d3d11va}" = "yes"],
2562 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2563 [AC_MSG_WARN([dxva2api.h not found])])
2564 ],[#include <d3d9.h>])
2565 ],[
2566 AS_IF([test "${enable_d3d11va}" = "yes"],
2567 [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2568 [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2569 ], [#include <d3d11.h>])
2570 ],[
2571 AS_IF([test "x${enable_d3d11va}" != "x"], [
2572 AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2573 ])
2574 ])
2575 fi
2576 ])
2577 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2579 dnl
2580 dnl DXGI debug
2581 dnl
2582 AC_CHECK_HEADERS([dxgidebug.h dxgi1_6.h])
2584 dnl
2585 dnl avformat demuxer/muxer plugin
2586 dnl
2588 AC_ARG_ENABLE([avformat],
2589 AS_HELP_STRING([--enable-avformat], [libavformat containers (default enabled)]),, [
2590 enable_avformat="${have_avcodec}"
2591 ])
2592 have_avformat="no"
2593 AS_IF([test "${enable_avformat}" != "no"], [
2594 PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2595 have_avformat="yes"
2596 VLC_SAVE_FLAGS
2597 CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2598 CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2599 AC_CHECK_HEADERS([libavformat/avformat.h libavformat/avio.h])
2600 AC_CHECK_HEADERS([libavcodec/avcodec.h])
2601 AC_CHECK_HEADERS([libavutil/avutil.h])
2602 AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2603 have_avformat="no"
2604 ])
2605 VLC_RESTORE_FLAGS
2606 ],[
2607 AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2608 ])
2609 ])
2610 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2612 dnl
2613 dnl swscale image scaling and conversion plugin
2614 dnl
2616 AC_ARG_ENABLE([swscale],
2617 AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2618 (default enabled)]))
2619 if test "${enable_swscale}" != "no"
2620 then
2621 PKG_CHECK_MODULES(SWSCALE,[libswscale],
2622 [
2623 VLC_SAVE_FLAGS
2624 CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2625 CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2626 AC_CHECK_HEADERS([libswscale/swscale.h])
2627 AC_CHECK_HEADERS([libavutil/avutil.h])
2628 VLC_ADD_PLUGIN([swscale])
2629 VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2630 VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2631 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2632 VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2633 ])
2634 VLC_RESTORE_FLAGS
2635 ],[
2636 AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2637 ])
2638 fi
2640 dnl
2641 dnl postproc plugin
2642 dnl
2644 AC_ARG_ENABLE([postproc],
2645 AS_HELP_STRING([--enable-postproc], [libpostproc image post-processing (default auto)]))
2646 if test "${enable_postproc}" != "no"
2647 then
2648 PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2649 [
2650 VLC_SAVE_FLAGS
2651 CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2652 CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2653 AC_CHECK_HEADERS([postproc/postprocess.h])
2654 VLC_ADD_PLUGIN([postproc])
2655 VLC_RESTORE_FLAGS
2656 ],[
2657 AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2658 ])
2659 fi
2661 dnl
2662 dnl faad decoder plugin
2663 dnl
2664 AC_ARG_ENABLE([faad],
2665 AS_HELP_STRING([--enable-faad], [faad codec (default auto)]))
2666 have_faad="no"
2667 AS_IF([test "${enable_faad}" != "no"], [
2668 AC_CHECK_HEADERS([neaacdec.h], [
2669 AC_CHECK_LIB([faad], [NeAACDecOpen], [have_faad="yes"],, [$LIBM])
2671 AS_IF([test "${have_faad}" = "yes"], [
2672 VLC_ADD_PLUGIN([faad])
2673 VLC_ADD_LIBS([faad],[-lfaad])
2674 ], [
2675 AS_IF([test "${enable_faad}" = "yes"], [
2676 AC_MSG_ERROR([cannot find FAAD library])
2677 ], [
2678 AC_MSG_WARN([cannot find FAAD library])
2679 ])
2680 ])
2681 ])
2682 ])
2684 dnl
2685 dnl AOM decoder plugin
2686 dnl
2687 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec (default auto)])
2689 dnl
2690 dnl Dav1d decoder plugin
2691 dnl
2692 PKG_ENABLE_MODULES_VLC([DAV1D], [], [dav1d], [AV1 decoder (default auto)])
2694 dnl
2695 dnl libvpx decoder plugin
2696 dnl
2697 AC_ARG_ENABLE([vpx],
2698 AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2699 AS_IF([test "${enable_vpx}" != "no"],[
2700 PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2701 VLC_ADD_PLUGIN([vpx])
2702 VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2703 VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2704 AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2705 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2706 ], [], [${VPX_LIBS}])
2707 AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2708 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2709 ], [], [${VPX_LIBS}])
2710 AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2711 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2712 ], [], [${VPX_LIBS}])
2713 AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2714 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2715 ], [], [${VPX_LIBS}])
2716 ], [
2717 AS_IF([test "${enable_vpx}" = "yes"],[
2718 AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2719 ])])
2720 ])
2722 dnl
2723 dnl twolame encoder plugin
2724 dnl
2725 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2727 dnl
2728 dnl fdk-aac encoder plugin
2729 dnl
2730 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2733 dnl
2734 dnl A52/AC3 decoder plugin
2735 dnl
2736 AC_ARG_ENABLE([a52],
2737 AS_HELP_STRING([--enable-a52], [A/52 support with liba52 (default enabled)]))
2738 if test "${enable_a52}" != "no"
2739 then
2740 AC_ARG_WITH([a52],
2741 AS_HELP_STRING([--with-a52=PATH], [a52 headers and libraries]))
2742 if test -z "${with_a52}"
2743 then
2744 LDFLAGS_test=""
2745 CPPFLAGS_test=""
2746 else
2747 LDFLAGS_test="-L${with_a52}/lib"
2748 CPPFLAGS_test="-I${with_a52}/include"
2749 fi
2750 VLC_SAVE_FLAGS
2751 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2752 LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2753 AC_CHECK_HEADERS([a52dec/a52.h], [
2754 AC_CHECK_LIB([a52], [a52_free], [
2755 VLC_ADD_PLUGIN([a52])
2756 VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2757 VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2758 ],[
2759 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2760 ], [$LIBM])
2761 ],[
2762 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2763 ])
2764 VLC_RESTORE_FLAGS
2765 fi
2767 dnl
2768 dnl DTS Coherent Acoustics decoder plugin
2769 dnl
2770 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2772 dnl
2773 dnl Flac plugin
2774 dnl
2775 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2777 dnl
2778 dnl Libmpeg2 plugin
2779 dnl
2780 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2782 dnl
2783 dnl Vorbis plugin
2784 dnl
2785 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2787 dnl
2788 dnl Tremor plugin
2789 dnl
2790 AC_ARG_ENABLE([tremor],
2791 AS_HELP_STRING([--enable-tremor], [Tremor decoder support (default disabled)]))
2792 if test "${enable_tremor}" = "yes"
2793 then
2794 AC_CHECK_HEADERS([tremor/ivorbiscodec.h], [
2795 VLC_ADD_PLUGIN([tremor])
2796 ],[])
2797 fi
2799 dnl
2800 dnl Speex plugins
2801 dnl
2802 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2803 have_speexdsp="no"
2804 AS_IF([test "${enable_speex}" != "no"], [
2805 PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2806 have_speexdsp="yes"
2807 ], [
2808 AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2809 ])
2810 ])
2811 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2813 dnl
2814 dnl Opus plugin
2815 dnl
2816 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2818 dnl
2819 dnl Ambisonic channel mixer and binauralizer plugin
2820 dnl
2821 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2823 dnl
2824 dnl theora decoder plugin
2825 dnl
2826 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2828 dnl
2829 dnl OggSpots decoder plugin
2830 dnl
2831 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2833 dnl
2834 dnl Daala decoder plugin
2835 dnl
2836 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2838 dnl
2839 dnl schroedinger decoder plugin (for dirac format video)
2840 dnl
2841 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2843 dnl
2844 dnl PNG decoder module
2845 dnl
2846 AC_ARG_ENABLE([png],
2847 AS_HELP_STRING([--enable-png], [PNG support (default enabled)]))
2848 AS_IF([test "${enable_png}" != "no"], [
2849 AC_CHECK_HEADERS([png.h], [
2850 VLC_SAVE_FLAGS
2851 LDFLAGS="${LDFLAGS} -lz $LIBM"
2852 AC_CHECK_LIB([png], [png_set_alpha_mode], [
2853 VLC_ADD_PLUGIN([png])
2854 ], [], [-lz $LIBM])
2855 VLC_RESTORE_FLAGS
2856 ])
2857 ])
2859 dnl
2860 dnl JPEG decoder module
2861 dnl
2862 AC_ARG_ENABLE([jpeg],
2863 AS_HELP_STRING([--enable-jpeg], [JPEG support (default enabled)]))
2864 AS_IF([test "${enable_jpeg}" != "no"], [
2865 AC_CHECK_HEADERS([jpeglib.h], [
2866 VLC_ADD_PLUGIN([jpeg])
2867 ])
2868 ])
2870 dnl
2871 dnl BPG decoder module
2872 dnl
2873 AC_ARG_ENABLE([bpg],
2874 AS_HELP_STRING([--enable-bpg], [BPG support (default disabled)]))
2875 AS_IF([test "${enable_bpg}" != "no"], [
2876 AC_CHECK_HEADERS([libbpg.h], [
2877 VLC_ADD_PLUGIN([bpg])
2878 ])
2879 ])
2881 dnl
2882 dnl H262 encoder plugin (lib262)
2883 dnl
2884 AC_ARG_ENABLE([x262],
2885 AS_HELP_STRING([--enable-x262], [H262 encoding support with static libx262 (default disabled)]))
2886 if test "${enable_x262}" != "no"; then
2887 PKG_CHECK_MODULES(X262, x262, [
2888 VLC_ADD_PLUGIN([x262])
2889 VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2890 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2891 VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2892 ])
2893 VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2894 if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2895 VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2896 fi
2897 ], [
2898 if test "${enable_x262}" = "yes"; then
2899 AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2900 fi
2901 ])
2902 fi
2904 dnl x265 encoder
2905 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2907 dnl
2908 dnl H264 encoder plugin (using libx264)
2909 dnl
2910 AC_ARG_ENABLE([x264],
2911 AS_HELP_STRING([--enable-x264], [H264 encoding support with libx264 (default enabled)]))
2912 if test "${enable_x264}" != "no"; then
2913 PKG_CHECK_MODULES(X264,x264 >= 0.148, [
2914 VLC_ADD_PLUGIN([x264])
2915 VLC_ADD_LIBS([x264],[${X264_LIBS}])
2917 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2918 VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2919 ])
2921 VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2922 if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2923 VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2924 fi
2925 ],[
2926 if test "${enable_x264}" = "yes"; then
2927 AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2928 fi
2929 ])
2930 fi
2932 dnl
2933 dnl H264 encoder plugin (libx264 > 153)
2934 dnl
2935 AC_ARG_ENABLE([x26410b],
2936 AS_HELP_STRING([--enable-x26410b], [H264 10-bit encoding support with libx264 (default enabled)]))
2937 if test "${enable_x26410b}" != "no"; then
2938 PKG_CHECK_MODULES(X26410b,x264 >= 0.153, [
2939 VLC_ADD_PLUGIN([x26410b])
2940 VLC_ADD_LIBS([x26410b],[${X264_LIBS}])
2942 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2943 VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2944 ])
2946 VLC_ADD_CFLAGS([x26410b],[${X264_CFLAGS}])
2947 if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2948 VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2949 fi
2950 ],[
2951 if test "${enable_x26410b}" = "yes"; then
2952 AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2953 fi
2954 ])
2955 fi
2958 dnl
2959 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2960 dnl
2961 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2963 dnl
2964 dnl libfluidsynth (MIDI synthetizer) plugin
2965 dnl
2966 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2967 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2968 AC_CHECK_HEADERS([fluidlite.h], [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2970 dnl
2971 dnl Teletext Modules
2972 dnl vbi decoder plugin (using libzbvi)
2973 dnl telx module
2974 dnl uncompatible
2975 dnl
2976 AC_ARG_ENABLE([zvbi],
2977 AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2978 libzvbi (default enabled)]))
2979 AC_ARG_ENABLE([telx],
2980 AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2981 zvbi) (default enabled if zvbi is absent)]))
2983 AS_IF( [test "${enable_zvbi}" != "no"],[
2984 PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2985 [
2986 VLC_ADD_PLUGIN([zvbi])
2987 AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2988 AS_IF( [test "${enable_telx}" = "yes"],[
2989 AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2990 ])
2991 ],[
2992 AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2993 ])
2994 ])
2995 AS_IF( [test "${enable_telx}" != "no" ],[
2996 VLC_ADD_PLUGIN([telx])
2997 ])
2999 dnl
3000 dnl ARIB subtitles rendering module
3001 dnl
3002 AC_ARG_ENABLE([aribsub],
3003 AS_HELP_STRING([--enable-aribsub],[ARIB Subtitles support (default enabled)]))
3004 AS_IF( [test "${enable_aribsub}" != "no" ],[
3005 PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
3006 have_aribb24="yes"
3007 VLC_ADD_PLUGIN([aribsub])
3008 VLC_ADD_LIBS([aribsub],[-laribb24])
3009 AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
3010 ],[
3011 AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
3012 have_aribb24="no"
3013 ])
3014 ])
3015 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
3017 dnl
3018 dnl ARIB B25
3019 dnl
3020 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
3022 dnl
3023 dnl kate decoder plugin
3024 dnl
3025 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
3027 dnl
3028 dnl tiger rendering for kate decoder plugin
3029 dnl
3030 AC_ARG_ENABLE([tiger],
3031 AS_HELP_STRING([--enable-tiger], [Tiger rendering library for Kate streams (default auto)]))
3032 AS_IF([test "${enable_tiger}" != "no"], [
3033 PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
3034 AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
3035 AS_IF([test -n "${enable_tiger}"], [
3036 AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
3037 ])
3038 ])
3039 ])
3041 dnl
3042 dnl check if we can build the css selector engine
3043 dnl
3044 AC_ARG_ENABLE([css],
3045 AS_HELP_STRING([--enable-css], [CSS selector engine (default auto)]))
3046 AS_IF([test "${enable_css}" != "no"], [
3047 with_css="yes"
3048 AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
3049 ])
3050 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
3053 dnl
3054 dnl Video plugins
3055 dnl
3057 EXTEND_HELP_STRING([Video plugins:])
3059 dnl
3060 dnl libplacebo support
3061 dnl
3062 AC_ARG_ENABLE([libplacebo],
3063 AS_HELP_STRING([--disable-libplacebo],
3064 [disable libplacebo support (default auto)]))
3066 AS_IF([test "$enable_libplacebo" != "no"], [
3067 PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.5], [
3068 AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
3069 PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 1.7],
3070 [have_libplacebo_vk="yes"], [have_libplacebo_vk="no"])
3071 ], [
3072 AS_IF([test -n "${enable_libplacebo}"], [
3073 AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
3074 ])
3075 enable_libplacebo="no"
3076 ])
3077 ])
3078 AM_CONDITIONAL([HAVE_LIBPLACEBO], [test "$enable_libplacebo" != "no"])
3080 dnl
3081 dnl OpenGL
3082 dnl
3083 PKG_CHECK_MODULES([EGL], [egl], [
3084 have_egl="yes"
3085 ], [
3086 have_egl="no"
3087 ])
3088 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3090 have_gl="no"
3091 PKG_CHECK_MODULES([GL], [gl], [
3092 have_gl="yes"
3093 ], [
3094 AC_MSG_CHECKING([for OpenGL])
3095 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3096 #ifdef _WIN32
3097 # include <GL/glew.h>
3098 #endif
3099 #include <GL/gl.h>
3100 ]], [
3101 [int t0 = GL_TEXTURE0;]])
3102 ], [
3103 GL_CFLAGS=""
3104 have_gl="yes"
3105 AS_IF([test "${SYS}" != "mingw32"], [
3106 GL_LIBS="-lGL"
3107 ], [
3108 GL_LIBS="-lopengl32"
3109 ])
3110 ])
3111 AC_MSG_RESULT([${have_gl}])
3112 ])
3113 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3114 AS_IF([test "${have_gl}" = "yes"], [
3115 AC_DEFINE([HAVE_GL], 1, [Defined if having OpenGL])
3116 ])
3118 dnl OpenGL ES 2: depends on EGL 1.1
3119 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3121 dnl
3122 dnl Vulkan
3123 dnl
3124 AC_ARG_ENABLE(vulkan,
3125 [AS_HELP_STRING([--disable-vulkan],
3126 [disable Vulkan support (default auto)])])
3128 AS_IF([test "$enable_vulkan" != "no"], [
3129 AS_IF([test "$have_libplacebo_vk" = "yes"], [
3130 PKG_CHECK_MODULES([VULKAN], [vulkan >= 1.0.26], [
3131 AC_DEFINE([HAVE_VULKAN], [1], [Define to 1 if vulkan is enabled.])
3132 ], [
3133 AS_IF([test -n "${enable_vulkan}"], [
3134 AC_MSG_ERROR([${VULKAN_PKG_ERRORS}.])
3135 ])
3136 enable_vulkan="no"
3137 ])
3138 ], [
3139 AS_IF([test -n "${enable_vulkan}"], [
3140 AC_MSG_ERROR([Vulkan support requires libplacebo 1.7 as well. Do not use --disable-libplacebo.])
3141 ])
3142 enable_vulkan="no"
3143 ])
3144 ])
3145 AM_CONDITIONAL(HAVE_VULKAN, [test "$enable_vulkan" != "no"])
3147 dnl
3148 dnl Xlib
3149 dnl
3151 AC_PATH_XTRA()
3152 AC_CHECK_HEADERS([X11/Xlib.h])
3154 dnl
3155 dnl X C Bindings modules
3156 dnl
3157 AC_ARG_ENABLE([xcb],
3158 AS_HELP_STRING([--enable-xcb], [X11 support with XCB (default enabled)]),, [
3159 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3160 enable_xcb="yes"
3161 ], [
3162 enable_xcb="no"
3163 ])
3164 ])
3166 have_xcb="no"
3167 have_xkbcommon_x11="no"
3168 have_xcb_keysyms="no"
3169 AS_IF([test "${enable_xcb}" != "no"], [
3170 xcb_err=""
3172 dnl libxcb
3173 PKG_CHECK_MODULES([XCB], [xcb >= 1.6],, [
3174 xcb_err="$xcb_err ${XCB_PKG_ERRORS}."])
3175 PKG_CHECK_MODULES([XCB_COMPOSITE], [xcb-composite],, [
3176 xcb_err="$xcb_err ${XCB_COMPOSITE_PKG_ERRORS}."])
3177 PKG_CHECK_MODULES([XCB_RANDR], [xcb-randr >= 1.3],, [
3178 xcb_err="$xcb_err ${XCB_RANDR_PKG_ERRORS}."])
3179 PKG_CHECK_MODULES([XCB_RENDER], [xcb-render],, [
3180 xcb_err="$xcb_err ${XCB_RENDER_PKG_ERRORS}."])
3181 PKG_CHECK_MODULES([XCB_SHM], [xcb-shm >= 1.9.2],, [
3182 xcb_err="$xcb_err ${XCB_SHM_PKG_ERRORS}."])
3183 PKG_CHECK_MODULES([XCB_XKB], [xcb-xkb],, [
3184 xcb_err="$xcb_err ${XCB_XKB_PKG_ERRORS}."])
3186 dnl xproto
3187 PKG_CHECK_MODULES(XPROTO, [xproto],, [
3188 xcb_err="$xcb_err ${XPROTO_PKG_ERRORS}."])
3190 AS_IF([test -n "$xcb_err"], [
3191 AC_MSG_ERROR([$xcb_err Pass --disable-xcb to skip X11 support.])
3192 ])
3194 dnl xkbcommon
3195 PKG_CHECK_MODULES([XKBCOMMON_X11], [xkbcommon-x11], [
3196 have_xkbcommon_x11="yes"
3197 ], [
3198 AC_MSG_WARN([${XKBCOMMON_X11_PKG_ERRORS}. Hotkeys are disabled.])
3199 ])
3201 dnl xcb-utils
3202 PKG_CHECK_MODULES([XCB_KEYSYMS], [xcb-keysyms >= 0.3.4], [
3203 have_xcb_keysyms="yes"
3204 ], [
3205 AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Global hotkeys are disabled.])
3206 ])
3208 have_xcb="yes"
3209 ])
3210 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3211 AM_CONDITIONAL([HAVE_XKBCOMMON_X11], [test "${have_xkbcommon_x11}" = "yes"])
3212 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3215 dnl
3216 dnl VDPAU needs X11
3217 dnl
3218 AC_ARG_ENABLE([vdpau],
3219 [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3220 have_vdpau="no"
3221 AS_IF([test "${enable_vdpau}" != "no"], [
3222 PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3223 have_vdpau="yes"
3224 AS_IF([test "${no_x}" = "yes"], [
3225 AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3226 ])
3227 ], [
3228 AS_IF([test -n "${enable_vdpau}"], [
3229 AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3230 ])
3231 ])
3232 ])
3233 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3235 have_avcodec_vdpau="no"
3236 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3237 case "${avfork}" in
3238 libav) av_vdpau_ver="56.10.0" ;;
3239 ffmpeg) av_vdpau_ver="56.19.100" ;;
3240 esac
3241 PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3242 have_avcodec_vdpau="yes"
3243 AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3244 ], [
3245 AS_IF([test -n "${enable_vdpau}"], [
3246 AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3247 ], [
3248 AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3249 ])
3250 ])
3251 ])
3252 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3255 dnl
3256 dnl Wayland
3257 dnl
3258 AC_ARG_ENABLE([wayland],
3259 AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)]))
3261 have_wayland="no"
3262 AS_IF([test "${enable_wayland}" != "no"], [
3263 wl_err=""
3265 dnl wayland
3266 PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91],, [
3267 wl_err="$wl_err ${WAYLAND_CLIENT_PKG_ERRORS}."
3268 ])
3269 PKG_CHECK_MODULES([WAYLAND_CURSOR], [wayland-cursor],, [
3270 wl_err="$wl_err ${WAYLAND_CURSOR_PKG_ERRORS}."
3271 ])
3272 PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl],, [
3273 wl_err="$wl_err ${WAYLAND_EGL_PKG_ERRORS}."
3274 ])
3275 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner >= 1.15], [
3276 WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3277 ], [
3278 wl_err="$wl_err ${WAYLAND_SCANNER_PKG_ERRORS}."
3279 ])
3281 dnl wayland-protocols
3282 PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= 1.15], [
3283 WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3284 ], [
3285 wl_err="$wl_err ${WAYLAND_PROTOCOLS_PKG_ERRORS}."
3286 ])
3288 AS_IF([test -n "$wl_err"], [
3289 AS_IF([test -n "$enable_wayland"], [
3290 AC_MSG_ERROR([$wl_err])
3291 ], [
3292 AC_MSG_WARN([$wl_err])
3293 ])
3294 ], [
3295 have_wayland="yes"
3296 ])
3298 dnl xkbcommon
3299 PKG_CHECK_MODULES([XKBCOMMON], [xkbcommon], [
3300 have_xkbcommon="yes"
3301 ], [
3302 AC_MSG_WARN([${XKBCOMMON_PKG_ERRORS}. Hotkeys are disabled.])
3303 ])
3304 ])
3305 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3306 AC_SUBST([WAYLAND_PROTOCOLS])
3307 AC_SUBST([WAYLAND_SCANNER])
3308 AM_CONDITIONAL([HAVE_XKBCOMMON], [test "${have_xkbcommon}" = "yes"])
3311 dnl
3312 dnl SDL image decoder module
3313 dnl
3314 AC_ARG_ENABLE([sdl-image],
3315 AS_HELP_STRING([--enable-sdl-image], [SDL image support (default enabled)]))
3316 AS_IF([test "${enable_sdl_image}" != "no"],[
3317 PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3318 VLC_ADD_PLUGIN([sdl_image])
3319 ], [
3320 AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3321 ])
3322 ])
3324 dnl
3325 dnl freetype module
3326 dnl
3327 AC_ARG_ENABLE([freetype],
3328 AS_HELP_STRING([--enable-freetype], [freetype support (default auto)]))
3329 AC_ARG_ENABLE([fribidi],
3330 AS_HELP_STRING([--enable-fribidi], [fribidi support (default auto)]))
3331 AC_ARG_ENABLE([harfbuzz],
3332 AS_HELP_STRING([--enable-harfbuzz], [harfbuzz support (default auto)]))
3333 AC_ARG_ENABLE([fontconfig],
3334 AS_HELP_STRING([--enable-fontconfig], [fontconfig support (default auto)]))
3336 AC_ARG_WITH([default-font],
3337 AS_HELP_STRING([--with-default-font=PATH],
3338 [Path to the default font]),
3339 [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3340 "$withval", [Default font])])
3341 AC_ARG_WITH([default-monospace-font],
3342 AS_HELP_STRING([--with-default-monospace-font=PATH],
3343 [Path to the default font]),
3344 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3345 "$withval", [Default monospace font])])
3347 AC_ARG_WITH([default-font-family],
3348 AS_HELP_STRING([--with-default-font-family=NAME],
3349 [Name of the default font family]),
3350 [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3351 "$withval", [Default font family])])
3352 AC_ARG_WITH([default-monospace-font-family],
3353 AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3354 [Name of the default font family]),
3355 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3356 "$withval", [Default monospace font family])])
3358 have_freetype="no"
3359 have_fontconfig="no"
3360 have_fribidi="no"
3361 have_harfbuzz="no"
3363 if test "${enable_freetype}" != "no"; then
3364 PKG_CHECK_MODULES(FREETYPE, freetype2, [
3365 have_freetype="yes"
3366 VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3367 VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3369 dnl fontconfig support
3370 AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3371 PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3372 have_fontconfig="yes"
3373 ], [
3374 AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3375 ])
3376 ])
3378 dnl fribidi support
3379 if test "${enable_fribidi}" != "no"; then
3380 PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3381 have_fribidi="yes"
3382 VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3383 VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3384 ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3385 fi
3387 dnl harfbuzz support
3388 if test "${have_fribidi}" != "no"; then
3389 if test "${enable_harfbuzz}" != "no"; then
3390 PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3391 have_harfbuzz="yes"
3392 VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3393 VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3394 ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3395 fi
3396 fi
3397 ],[
3398 AS_IF([test -n "${enable_freetype}"],[
3399 AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3400 ])
3401 ])
3402 fi
3404 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3405 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3406 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3407 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3409 dnl
3410 dnl libass subtitle rendering module
3411 dnl
3412 AC_ARG_ENABLE([libass],
3413 AS_HELP_STRING([--enable-libass], [Subtitle support using libass (default enabled)]))
3414 AS_IF( [test "${enable_libass}" != "no"], [
3415 PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
3416 [
3417 VLC_ADD_PLUGIN([libass])
3419 if test "${have_fontconfig}" != "no"; then
3420 VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
3421 VLC_ADD_LIBS([libass],[${FONTCONFIG_LIBS}])
3422 fi
3423 ],[
3424 AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
3425 ])
3426 ])
3428 dnl
3429 dnl SAPI (text to Speech renderer for Windows)
3430 dnl
3431 AC_LANG_PUSH([C++])
3432 AC_CHECK_TYPES([ISpObjectToken],[
3433 have_sapi="yes"
3434 ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3435 [#include <windows.h>
3436 #include <sapi.h>
3437 #include <sphelper.h>])
3438 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3439 AC_LANG_POP([C++])
3441 dnl
3442 dnl SVG module (text rendering and image decoding)
3443 dnl
3444 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3445 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3447 dnl
3448 dnl Windows DirectX module
3449 dnl
3451 AC_ARG_ENABLE([directx],
3452 AS_HELP_STRING([--enable-directx],
3453 [Microsoft DirectX support (default enabled on Windows)]),, [
3454 AS_IF([test "${SYS}" = "mingw32"], [
3455 enable_directx="yes"
3456 ], [
3457 enable_directx="no"
3458 ])
3459 ])
3460 AS_IF([test "${enable_directx}" != "no"], [
3461 dnl DirectDraw
3462 AC_CHECK_HEADERS([ddraw.h], [
3463 VLC_ADD_PLUGIN([directdraw])
3464 ])
3466 dnl OpenGL
3467 AC_CHECK_HEADERS([GL/glew.h], [
3468 AC_CHECK_HEADERS([GL/wglew.h], [
3469 VLC_ADD_PLUGIN([glwin32 wgl])
3470 ],, [
3471 #include <windows.h>
3472 #include <GL/glew.h>
3473 ])],, [
3474 #include <windows.h>
3475 ])
3477 dnl Direct3D11
3478 AC_CHECK_HEADERS([d3d11.h], [
3479 VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3480 ])
3482 dnl Direct3D9
3483 AC_CHECK_HEADERS([d3d9.h], [
3484 VLC_ADD_PLUGIN([direct3d9])
3485 AC_CHECK_HEADERS([d3dx9effect.h])
3487 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3488 [[#define COBJMACROS
3489 #include <d3d9.h>
3490 #include <dxva2api.h>
3491 #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3492 # error dxva2 too old
3493 #endif
3494 ]],[[;]])
3495 ],[
3496 VLC_ADD_PLUGIN([direct3d9_filters])
3497 ],
3498 [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3500 ])
3501 ])
3503 dnl
3504 dnl Linux framebuffer module
3505 dnl
3506 AC_CHECK_HEADER([linux/fb.h], [
3507 VLC_ADD_PLUGIN([fb])
3508 ])
3510 dnl
3511 dnl Linux kernel mode setting module
3512 dnl
3513 PKG_ENABLE_MODULES_VLC([KMS], [], [libdrm >= 2.4.83], [Linux kernel mode setting output], [auto])
3515 dnl
3516 dnl libcaca plugin
3517 dnl
3518 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3520 dnl
3521 dnl OS/2 KVA plugin
3522 dnl
3523 AC_ARG_ENABLE([kva],
3524 AS_HELP_STRING([--enable-kva],
3525 [support the K Video Accelerator KVA (default enabled on OS/2)]),, [
3526 AS_IF([test "$SYS" = "os2"], [
3527 enable_kva="yes"
3528 ])
3529 ])
3530 have_kva="no"
3531 KVA_LIBS=""
3532 AS_IF([test "$enable_kva" != "no"], [
3533 AC_CHECK_HEADERS([kva.h], [
3534 have_kva="yes"
3535 AC_CHECK_LIB([kva], [main], [
3536 KVA_LIBS="-lkva"
3537 ])
3538 ])
3539 ])
3540 AC_SUBST([KVA_LIBS])
3541 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3543 dnl
3544 dnl MMAL plugin
3545 dnl
3546 AC_ARG_ENABLE([mmal],
3547 AS_HELP_STRING([--enable-mmal],
3548 [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3549 if test "${enable_mmal}" != "no"; then
3550 VLC_SAVE_FLAGS
3551 LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3552 CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3553 AC_CHECK_HEADERS([interface/mmal/mmal.h],
3554 [ AC_CHECK_LIB([bcm_host], [vc_tv_unregister_callback_full], [
3555 have_mmal="yes"
3556 VLC_ADD_PLUGIN([mmal])
3557 VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3558 VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3559 VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif ]) ], [
3560 AS_IF([test "${enable_mmal}" = "yes"],
3561 [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3562 [ AC_MSG_WARN([Cannot find bcm library...]) ])
3563 ],
3564 [])
3565 ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3566 [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3567 [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3568 VLC_RESTORE_FLAGS
3569 fi
3570 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3572 dnl
3573 dnl Audio plugins
3574 dnl
3576 EXTEND_HELP_STRING([Audio plugins:])
3578 dnl
3579 dnl Pulseaudio module
3580 dnl
3581 AC_ARG_ENABLE([pulse],
3582 AS_HELP_STRING([--enable-pulse],
3583 [use the PulseAudio client library (default auto)]))
3584 have_pulse="no"
3585 AS_IF([test "${enable_pulse}" != "no"], [
3586 PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3587 have_pulse="yes"
3588 ], [
3589 AS_IF([test "x${enable_pulse}" != "x"], [
3590 AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3591 ])
3592 ])
3593 ])
3594 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3596 dnl
3597 dnl ALSA module
3598 dnl
3599 AC_ARG_ENABLE([alsa],
3600 AS_HELP_STRING([--enable-alsa],
3601 [support the Advanced Linux Sound Architecture (default auto)]),, [
3602 AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3603 enable_alsa="yes"
3604 ])
3605 ])
3606 have_alsa="no"
3607 AS_IF([test "${enable_alsa}" != "no"], [
3608 PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3609 have_alsa="yes"
3610 ], [
3611 AS_IF([test "x${enable_alsa}" != "x"], [
3612 AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3613 ])
3614 ])
3615 ])
3616 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3618 dnl
3619 dnl Open Sound System module
3620 dnl
3621 AC_ARG_ENABLE([oss],
3622 AS_HELP_STRING([--enable-oss],
3623 [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)]),, [
3624 AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3625 enable_oss="no"
3626 ])
3627 ])
3628 have_oss="no"
3629 OSS_LIBS=""
3630 AS_IF([test "$enable_oss" != "no"], [
3631 AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3632 have_oss="yes"
3633 AC_CHECK_LIB([ossaudio], [main], [
3634 OSS_LIBS="-lossaudio"
3635 ])
3636 ])
3637 ])
3638 AC_SUBST([OSS_LIBS])
3639 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3641 dnl
3642 dnl OpenBSD sndio module
3643 dnl
3644 AC_ARG_ENABLE([sndio],
3645 AS_HELP_STRING([--disable-sndio],
3646 [support the OpenBSD sndio (default auto)]),, [
3647 AS_IF([test "$SYS" = "openbsd"], [
3648 enable_sndio="yes"
3649 ])
3650 ])
3651 have_sndio="no"
3652 AS_IF([test "$enable_sndio" != "no"], [
3653 AC_CHECK_HEADER([sndio.h], [
3654 have_sndio="yes"
3655 ])
3656 ])
3657 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3659 dnl
3660 dnl Windows Audio Session plugin
3661 dnl
3662 AC_ARG_ENABLE([wasapi],
3663 AS_HELP_STRING([--enable-wasapi],
3664 [use the Windows Audio Session API (default auto)])
3665 )
3666 have_wasapi="no"
3667 AS_IF([test "$enable_wasapi" != "no"], [
3668 AC_CHECK_HEADER([audioclient.h], [
3669 have_wasapi="yes"
3670 ], [
3671 AS_IF([test "x${enable_wasapi}" != "x"], [
3672 AC_MSG_ERROR([Windows Audio Session API not found.])
3673 ])
3674 ])
3675 ])
3676 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3678 dnl
3679 dnl JACK modules
3680 dnl
3681 AC_ARG_ENABLE([jack],
3682 AS_HELP_STRING([--disable-jack],
3683 [do not use jack (default auto)]))
3684 have_jack="no"
3685 AS_IF([test "${enable_jack}" != "no"], [
3686 PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3687 [ have_jack=yes ],
3688 [
3689 AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3691 PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3692 [ have_jack=yes ],
3693 [
3694 AS_IF([test -n "${enable_jack}"],
3695 [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3696 [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3697 ])
3698 ])
3699 ])
3700 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3702 dnl
3703 dnl OpenSLES Android
3704 dnl
3705 AC_ARG_ENABLE([opensles],
3706 AS_HELP_STRING([--enable-opensles], [Android OpenSL ES audio module (default disabled)]))
3707 if test "${HAVE_ANDROID}" = "1"; then
3708 if test "${enable_opensles}" = "yes"; then
3709 AC_CHECK_HEADERS([SLES/OpenSLES.h],
3710 [ VLC_ADD_PLUGIN([opensles_android]) ],
3711 [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3712 fi
3713 fi
3715 dnl
3716 dnl Tizen audio
3717 dnl
3718 AC_ARG_ENABLE([tizen_audio],
3719 AS_HELP_STRING([--enable-tizen-audio],
3720 [Tizen audio module (default enabled on Tizen)]),, [
3721 AS_IF([test "$HAVE_TIZEN" = "1"], [
3722 enable_tizen_audio="yes"
3723 ])
3724 ])
3725 if test "${enable_tizen_audio}" = "yes"; then
3726 AC_CHECK_HEADERS([audio_io.h],
3727 [ VLC_ADD_PLUGIN([tizen_audio]) ],
3728 [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3729 fi
3731 dnl
3732 dnl libsamplerate plugin
3733 dnl
3734 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3736 dnl
3737 dnl soxr module
3738 dnl
3739 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3741 dnl
3742 dnl OS/2 KAI plugin
3743 dnl
3744 AC_ARG_ENABLE([kai],
3745 AS_HELP_STRING([--enable-kai],
3746 [support the K Audio Interface KAI (default enabled on OS/2)]),, [
3747 AS_IF([test "$SYS" = "os2"], [
3748 enable_kai="yes"
3749 ])
3750 ])
3751 have_kai="no"
3752 KAI_LIBS=""
3753 AS_IF([test "$enable_kai" != "no"], [
3754 AC_CHECK_HEADERS([kai.h], [
3755 have_kai="yes"
3756 AC_CHECK_LIB([kai], [main], [
3757 KAI_LIBS="-lkai"
3758 ])
3759 ])
3760 ])
3761 AC_SUBST([KAI_LIBS])
3762 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3764 dnl
3765 dnl chromaprint audio track fingerprinter
3766 dnl
3767 m4_pushdef([libchromaprint_version], 0.6.0)
3768 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3769 VLC_ADD_PLUGIN([stream_out_chromaprint]),
3770 AS_IF([test "${enable_chromaprint}" = "yes"],
3771 [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3772 [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3773 ),
3774 [(Chromaprint based audio fingerprinter)],[auto])
3775 m4_popdef([libchromaprint_version])
3777 dnl
3778 dnl Chromecast streaming support
3779 dnl
3780 m4_pushdef([protobuf_lite_version], 2.5.0)
3781 AC_ARG_VAR(PROTOC, [protobuf compiler])
3782 AC_CHECK_PROGS(PROTOC, protoc, no)
3783 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3784 AS_IF([test "x${PROTOC}" != "xno"], [
3785 build_chromecast="yes"
3786 ], [
3787 AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3788 ])
3789 ], [
3790 AS_IF([test "${enable_chromecast}" = "yes"],
3791 AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3792 AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3793 )
3794 enable_chromecast="no"
3795 ], [(Chromecast streaming support)], [auto])
3796 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3797 m4_popdef([protobuf_lite_version])
3799 dnl
3800 dnl Interface plugins
3801 dnl
3803 EXTEND_HELP_STRING([Interface plugins:])
3805 dnl
3806 dnl QT
3807 dnl
3808 AC_ARG_ENABLE([qt],
3809 AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)]),, [
3810 AS_IF([test "${enable_vlc}" != "no"], [enable_qt="yes"])
3811 AS_IF([test "${SYS}" = "darwin"], [
3812 enable_qt="no"
3813 ])
3814 ])
3815 have_qt5_x11="no"
3816 AS_IF([test "${enable_qt}" != "no"], [
3817 PKG_CHECK_MODULES([QT], [Qt5Core >= 5.9.0 Qt5Widgets Qt5Gui Qt5Svg], [
3818 PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3819 have_qt5_x11="yes"
3820 ],[
3821 AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3822 ])
3823 QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3824 QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3825 QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3826 AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3827 AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3828 AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3829 ], [
3830 AS_IF([test -n "${enable_qt}"],[
3831 AC_MSG_ERROR([${QT_PKG_ERRORS}. If you want to build VLC without GUI, pass --disable-qt.])
3832 ],[
3833 AC_MSG_WARN([${QT_PKG_ERRORS}.])
3834 ])
3835 enable_qt="no"
3836 ])
3837 ])
3839 AS_IF([test "${enable_qt}" != "no"], [
3840 ALIASES="${ALIASES} qvlc"
3841 ])
3842 AC_SUBST([QT_VERSION])
3843 AM_CONDITIONAL([ENABLE_QT], [test "$enable_qt" != "no"])
3844 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3846 dnl
3847 dnl detect kde4-config patch (used for kde solids).
3848 dnl
3849 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3850 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3851 KDE4_CONFIG="kde4-config"
3852 ])
3854 dnl
3855 dnl Simple test for skins2 dependency
3856 dnl
3857 AS_IF([test "$enable_qt" = "no"], [
3858 AS_IF([test "${enable_skins2}" = "yes"], [
3859 AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3860 ], [
3861 enable_skins2="no"
3862 AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3863 ])
3864 ])
3866 dnl
3867 dnl Skins2 module
3868 dnl
3869 AC_ARG_ENABLE([skins2],
3870 AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)]))
3871 AS_IF([test "${enable_skins2}" != "no"], [
3872 have_skins_deps="yes"
3874 dnl Win32
3875 AS_IF([test "${SYS}" = "mingw32"], [
3876 VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3877 VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3878 dnl OS/2
3879 ], [test "${SYS}" = "os2"], [
3880 VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3881 dnl Linux/Unix
3882 ], [
3883 PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3884 PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3885 PKG_CHECK_MODULES([XCURSOR], [xcursor],, [have_skins_deps="no"])
3886 PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3887 VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3888 VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} ${XCURSOR_LIBS} -lX11])
3889 ])
3891 dnl we need freetype
3892 AS_IF([test "${have_freetype}" != "yes"], [
3893 have_skins_deps="no"
3894 ])
3896 AS_IF([test "${have_skins_deps}" = "no"], [
3897 AS_IF([test "x${enable_skins2}" = "x"], [
3898 AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3899 ], [
3900 AC_MSG_ERROR([Skins2 interface requires FreeType, libxcursor, libxpm, libxext and libxinerama])
3901 ])
3902 enable_skins2="no"
3903 ], [
3904 ALIASES="${ALIASES} svlc"
3905 enable_skins2="yes"
3906 ])
3907 ])
3908 AM_CONDITIONAL([BUILD_SKINS], [test "${enable_skins2}" = "yes"])
3910 AC_ARG_ENABLE([libtar],
3911 AS_HELP_STRING([--enable-libtar], [libtar support for skins2 (default auto)]))
3912 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3913 AC_CHECK_HEADERS([libtar.h], [
3914 VLC_ADD_LIBS([skins2],[-ltar])
3915 ])
3916 ])
3918 dnl
3919 dnl MacOS X gui module
3920 dnl
3921 AC_ARG_ENABLE([macosx],
3922 AS_HELP_STRING([--enable-macosx], [Mac OS X gui support (default enabled on Mac OS X)]))
3923 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3924 then
3926 dnl
3927 dnl If possible, use xcrun to find the right ibtool
3928 dnl
3930 AC_PATH_PROG([XCRUN], [xcrun], [no])
3931 AS_IF([test ! "x${XCRUN}" = "xno"], [
3932 AC_MSG_CHECKING([for ibtool (using xcrun)])
3933 XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3934 AC_MSG_RESULT([${XIB}])
3935 ], [
3936 AC_MSG_WARN([Looking for tools without using xcrun])
3937 ])
3939 AS_IF([test "x${XIB}" = "xno"], [
3940 AC_PATH_PROG(XIB, [ibtool], [no])
3941 AS_IF([test "x${XIB}" = "xno"], [
3942 AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3943 ])
3944 ])
3945 fi
3946 AM_CONDITIONAL([ENABLE_MACOSX_UI], [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3948 dnl
3949 dnl MacOS X sparkle update support
3950 dnl
3951 AC_ARG_ENABLE([sparkle],
3952 AS_HELP_STRING([--enable-sparkle], [Sparkle update support for OS X (default enabled on Mac OS X)]))
3953 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3954 then
3955 if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3956 then
3957 AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3958 fi
3960 AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3961 fi
3962 AM_CONDITIONAL([HAVE_SPARKLE], [test "$enable_sparkle" != "no"])
3964 dnl
3965 dnl MacOS X breakpad creash reporter support
3966 dnl
3967 AC_ARG_WITH([breakpad],
3968 AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
3970 AS_IF([test "$with_breakpad" != "no"], [
3972 AS_IF([test "$with_breakpad" = "yes"], [
3973 AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
3974 ])
3976 AS_IF([test "$HAVE_OSX" = "1"], [
3977 AC_MSG_CHECKING([for Breakpad framework])
3978 AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
3979 ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
3980 AC_MSG_RESULT([no])
3981 with_breakpad="no"
3982 AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3983 ], [
3984 AC_MSG_RESULT([yes])
3985 ])
3986 ],[
3987 PKG_CHECK_MODULES([BREAKPAD], [breakpad-client], [
3988 LDFLAGS="${LDFLAGS} -Wl,--build-id"
3989 ], [
3990 AC_MSG_ERROR(["breakpad not found"])
3991 ])
3992 ])
3993 ])
3995 AM_CONDITIONAL([HAVE_BREAKPAD], [test "$with_breakpad" != "no"])
3996 AS_IF([test "$with_breakpad" != "no"], [
3997 AC_SUBST([BREAKPAD_URL], ["${with_breakpad}"])
3998 ])
4000 dnl
4001 dnl Minimal Mac OS X module
4002 dnl
4003 AC_ARG_ENABLE([minimal-macosx],
4004 AS_HELP_STRING([--enable-minimal-macosx], [Minimal Mac OS X support (default disabled)]))
4005 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
4006 then
4007 VLC_ADD_PLUGIN([minimal_macosx])
4008 fi
4010 dnl
4011 dnl Mac OS X fancy dmg build tool
4012 dnl
4013 if test "${HAVE_OSX}" = "1"
4014 then
4015 AC_PATH_PROG(DMGBUILD, dmgbuild, no)
4016 AS_IF([test "x${DMGBUILD}" = "xno"], [
4017 AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
4018 ])
4019 fi
4020 AM_CONDITIONAL([HAVE_DMGBUILD], [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
4022 dnl
4023 dnl VideoToolbox plugins
4024 AC_CHECK_HEADERS([VideoToolbox/VideoToolbox.h], [
4025 VLC_ADD_PLUGIN([videotoolbox])
4026 VLC_ADD_PLUGIN([cvpx])
4027 ])
4029 dnl
4030 dnl AudioToolbox MIDI plugin
4031 AC_CHECK_HEADERS([AudioToolbox/AudioToolbox.h], [
4032 VLC_ADD_PLUGIN([audiotoolboxmidi])
4033 ])
4035 dnl
4036 dnl ncurses module
4037 dnl
4038 AC_ARG_ENABLE([ncurses],
4039 AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)]))
4040 have_ncurses="no"
4041 AS_IF([test "${enable_ncurses}" != "no"] ,[
4042 PKG_CHECK_MODULES([NCURSES], [ncursesw], [
4043 have_ncurses="yes"
4044 ALIASES="${ALIASES} nvlc"
4045 ], [
4046 AS_IF([test -n "${enable_ncurses}"], [
4047 AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
4048 ])
4049 ])
4050 ])
4051 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
4053 dnl
4054 dnl Lirc plugin
4055 dnl
4056 AC_ARG_ENABLE([lirc],
4057 AS_HELP_STRING([--enable-lirc], [lirc support (default disabled)]))
4058 have_lirc="no"
4059 AS_IF([test "${enable_lirc}" = "yes"], [
4060 AC_CHECK_HEADER(lirc/lirc_client.h, [
4061 AC_CHECK_LIB([lirc_client], [lirc_init], [
4062 have_lirc="yes"
4063 ])
4064 ])
4065 ])
4066 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
4068 dnl
4069 dnl Bitstream
4070 dnl
4071 PKG_CHECK_MODULES([BITSTREAM], [bitstream > 1.4],[have_bitstream="yes"], [have_bitstream="no"])
4072 AM_CONDITIONAL([HAVE_BITSTREAM], [test "${have_bitstream}" = "yes"])
4074 dnl
4075 dnl SRT plugin
4076 dnl
4077 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.2], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
4079 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
4080 dnl
4081 dnl goom visualization plugin
4082 dnl
4083 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
4085 dnl
4086 dnl libprojectM visualization plugin
4087 dnl
4088 AC_ARG_ENABLE([projectm],
4089 AS_HELP_STRING([--enable-projectm], [projectM visualization plugin (default enabled)]))
4090 AS_IF([test "${enable_projectm}" != "no"],
4091 [
4092 PKG_CHECK_MODULES(PROJECTM, libprojectM,
4093 [
4094 VLC_ADD_PLUGIN([projectm])
4095 PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
4096 [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
4097 [ AC_MSG_WARN( [Using libprojectM version 1] )
4098 ])
4099 ],[
4100 AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
4101 ])
4102 ])
4104 dnl
4105 dnl Vovoid VSXu visualization plugin
4106 dnl
4107 AC_ARG_ENABLE([vsxu],
4108 AS_HELP_STRING([--enable-vsxu], [Vovoid VSXu visualization plugin (default auto)]))
4109 AS_IF([test "${enable_vsxu}" != "no"],
4110 [
4111 PKG_CHECK_MODULES(VSXU, libvsxu,
4112 [
4113 VLC_ADD_PLUGIN([vsxu])
4114 ],[
4115 AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
4116 ])
4117 ])
4119 EXTEND_HELP_STRING([Service Discovery plugins:])
4120 dnl
4121 dnl Avahi-Zeroconf services discovery
4122 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
4124 dnl
4125 dnl libudev services discovery
4126 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4128 dnl
4129 dnl MTP devices services discovery
4130 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4132 dnl
4133 dnl UPnP Plugin (Intel SDK)
4134 dnl
4135 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4137 dnl
4138 dnl mDNS using libmicrodns
4139 dnl
4140 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4143 EXTEND_HELP_STRING([Misc options:])
4145 dnl
4146 dnl libxml2 module
4147 dnl
4148 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4151 dnl
4152 dnl libgcrypt
4153 dnl
4154 AC_ARG_ENABLE([libgcrypt],
4155 AS_HELP_STRING([--disable-libgcrypt], [gcrypt support (default enabled)]))
4156 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4157 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4159 # require libgcrypt >= 1.6.0
4160 AS_IF([test "${enable_libgcrypt}" != "no"], [
4161 AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4162 VLC_SAVE_FLAGS
4163 CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4164 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4165 [#include <gcrypt.h>
4166 #if GCRYPT_VERSION_NUMBER < 0x010600
4167 #error
4168 #endif]])], [
4169 ac_cv_lib_gcrypt=yes
4170 ], [
4171 ac_cv_lib_gcrypt=no
4172 ])
4173 VLC_RESTORE_FLAGS
4174 ])
4176 AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4177 AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4178 ], [
4179 AS_IF([test "${enable_libgcrypt}" = "yes"], [
4180 AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4181 ])
4182 ])
4183 ])
4185 AS_IF([test -z "$GCRYPT_LIBS"], [
4186 GCRYPT_LIBS="-lgcrypt -lgpg-error"
4187 ])
4189 AC_SUBST([GCRYPT_CFLAGS])
4190 AC_SUBST([GCRYPT_LIBS])
4191 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4193 dnl
4194 dnl TLS/SSL
4195 dnl
4196 AC_ARG_ENABLE([gnutls],
4197 AS_HELP_STRING([--enable-gnutls], [GNU TLS TLS/SSL support (default enabled)]))
4198 AS_IF([test "${enable_gnutls}" != "no"], [
4199 PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4200 VLC_ADD_PLUGIN([gnutls])
4201 ], [
4202 AS_IF([test -n "${enable_gnutls}"], [
4203 AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4204 ])
4205 ])
4206 ])
4209 dnl
4210 dnl Taglib plugin
4211 dnl
4212 AC_ARG_ENABLE([taglib],
4213 AS_HELP_STRING([--disable-taglib],
4214 [do not use TagLib (default enabled)]))
4215 AS_IF([test "${enable_taglib}" != "no"], [
4216 PKG_CHECK_MODULES(TAGLIB, taglib >= 1.11, [
4217 VLC_ADD_PLUGIN([taglib])
4218 ], [
4219 AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4220 ])
4222 dnl
4223 dnl libsecret
4224 dnl
4225 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4227 dnl
4228 dnl kwallet
4229 dnl
4230 AC_ARG_ENABLE([kwallet],
4231 AS_HELP_STRING([--enable-kwallet],
4232 [use kwallet (via D-Bus) for keystore (default enabled)]))
4233 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4234 VLC_ADD_PLUGIN([kwallet])
4235 ])
4237 dnl
4238 dnl update checking system
4239 dnl
4240 AC_ARG_ENABLE([update-check],
4241 AS_HELP_STRING([--enable-update-check], [update checking system (default disabled)]))
4242 if test "${enable_update_check}" = "yes"
4243 then
4244 AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4245 AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4246 fi
4247 AM_CONDITIONAL([UPDATE_CHECK], [test "${enable_update_check}" = "yes"])
4249 dnl
4250 dnl OS X notification plugin
4251 dnl
4252 AC_ARG_ENABLE([osx_notifications],
4253 AS_HELP_STRING([--enable-osx-notifications],
4254 [macOS notification plugin (default disabled)]),,
4255 [enable_osx_notifications=no])
4256 AS_IF([test "${enable_osx_notifications}" != "no"], [
4257 VLC_ADD_PLUGIN([osx_notifications])
4258 ])
4260 dnl
4261 dnl Libnotify notification plugin
4262 dnl
4263 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-3.0], [libnotify notification], [auto])
4265 PKG_ENABLE_MODULES_VLC([MEDIALIBRARY], [medialibrary], [medialibrary], (medialibrary support), [auto])
4267 dnl
4268 dnl Endianness check
4269 dnl
4270 AC_C_BIGENDIAN
4271 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4272 DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4273 ], [
4274 DEFS_BIGENDIAN=""
4275 ])
4276 AC_SUBST([DEFS_BIGENDIAN])
4278 dnl
4279 dnl Where to install KDE solid .desktop
4280 dnl
4281 AC_ARG_WITH(kde-solid,
4282 AS_HELP_STRING([--with-kde-solid=PATH],
4283 [KDE Solid actions directory (auto)]),, [
4285 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" -a "${HAVE_ANDROID}" != "1" ; then
4286 with_kde_solid="yes"
4287 fi
4288 ])
4289 soliddatadir=""
4290 AS_IF([test "${with_kde_solid}" != "no"], [
4291 AS_IF([test "${with_kde_solid}" = "yes"], [
4292 kde4datadir="`${KDE4_CONFIG} --install data`"
4293 AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4294 soliddatadir="${kde4datadir}/solid/actions"
4295 ], [
4296 soliddatadir="${with_kde_solid}"
4297 ])
4298 ])
4299 AC_SUBST([soliddatadir])
4300 AM_CONDITIONAL([KDE_SOLID], [test "x${soliddatadir}" != "x"])
4302 dnl
4303 dnl Find tools for win32 packaging
4304 dnl
4305 AS_IF([test "${SYS}" = "mingw32"], [
4306 dnl
4307 dnl Find makensis required to build the NSIS installer
4308 dnl
4309 nsis_major_required="3"
4310 nsis_version_ok="no"
4311 AC_PATH_PROG([MAKENSIS], [makensis], [no])
4312 AS_IF([test "$MAKENSIS" != "no"], [
4313 # Check version
4314 AC_MSG_CHECKING([makensis version])
4315 nsis_version=$($MAKENSIS -VERSION)
4316 AC_MSG_RESULT([$nsis_version])
4317 nsis_version_major=$(echo "$nsis_version" | awk -F \. '{print $1}' | sed 's/v//')
4318 # Check if major version is a valid number
4319 AS_IF([test -n "$nsis_version_major" && \
4320 test "$nsis_version_major" -eq "$nsis_version_major" 2> /dev/null], [
4321 # Do the version check using major version
4322 AS_IF([test "$nsis_version_major" -lt "$nsis_major_required"], [
4323 AC_MSG_WARN([makensis too old, (needs ${nsis_major_required}.x, have ${nsis_version_major}.x)])
4324 ], [
4325 nsis_version_ok="yes"
4326 ])
4327 ], [
4328 AC_MSG_WARN([failed to check the makensis version])
4329 ])
4330 ])
4331 dnl
4332 dnl Find 7zip
4333 dnl
4334 AC_PATH_PROG([SEVENZIP], [7z], [7z])
4335 ])
4336 AM_CONDITIONAL([HAVE_MAKENSIS], [test "x$MAKENSIS" != "xno" && test "$nsis_version_ok" = "yes"])
4338 dnl
4339 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4340 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4341 dnl
4342 if test "${SYS}" = "mingw32"; then
4343 AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4344 fi
4346 EXTEND_HELP_STRING([Components:])
4348 dnl
4349 dnl the VLC binary
4350 dnl
4351 AC_ARG_ENABLE([vlc],
4352 AS_HELP_STRING([--enable-vlc], [build the VLC media player (default enabled)]))
4353 AM_CONDITIONAL([BUILD_VLC], [test "${enable_vlc}" != "no"])
4355 dnl
4356 dnl Fuzzer (at the end in order to don't mess dependencies FLAGS)
4357 dnl
4358 AS_VAR_IF(with_libfuzzer, no, [], [
4359 LIBS="-lstdc++ ${LIBM} -L${with_libfuzzer} -lFuzzer"
4360 AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc-guard, [
4361 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard])
4362 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard], [CXXFLAGS])
4363 AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp])
4364 AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp], [CXXFLAGS])
4365 ], [
4366 AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc, [
4367 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc])
4368 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc], [CXXFLAGS])
4369 ], [
4370 AC_MSG_ERROR([Sanitizer coverage not supported by your compiler])
4371 ])
4372 ])
4373 ])
4375 dnl
4376 dnl Stuff used by the program
4377 dnl
4378 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4379 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4380 AC_DEFINE_UNQUOTED([VERSION_MESSAGE], "${VERSION_MESSAGE}", [Simple version string])
4381 AC_DEFINE_UNQUOTED([COPYRIGHT_MESSAGE], "${COPYRIGHT_MESSAGE}", [Copyright string])
4382 AC_DEFINE_UNQUOTED([COPYRIGHT_YEARS], "${COPYRIGHT_YEARS}", [The copyright years])
4383 AC_DEFINE_UNQUOTED([CONFIGURE_LINE], "${CONFIGURE_LINE}", [The ./configure command line])
4384 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_MAJOR],${VERSION_MAJOR}, [version major number])
4385 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_MINOR],${VERSION_MINOR}, [version minor number])
4386 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_REVISION],${VERSION_REVISION}, [version revision number])
4387 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_EXTRA],${VERSION_EXTRA}, [version extra number])
4388 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_DEV],"${VERSION_DEV}", [version development string])
4389 AC_SUBST([COPYRIGHT_MESSAGE])
4390 AC_SUBST([VERSION_MESSAGE])
4391 AC_SUBST([VERSION_MAJOR])
4392 AC_SUBST([VERSION_MINOR])
4393 AC_SUBST([VERSION_REVISION])
4394 AC_SUBST([VERSION_EXTRA])
4395 AC_SUBST([COPYRIGHT_YEARS])
4396 AC_DEFINE_UNQUOTED([VLC_COMPILE_BY], "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4397 AC_DEFINE_UNQUOTED([VLC_COMPILE_HOST], "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4398 AC_DEFINE_UNQUOTED([VLC_COMPILER], "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4399 dnl
4400 dnl Handle substvars that use $(top_srcdir)
4401 dnl
4402 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4404 dnl
4405 dnl Configuration is finished
4406 dnl
4407 AC_SUBST([SYS])
4408 AC_SUBST([ARCH])
4409 AC_SUBST([ALIASES])
4410 AC_SUBST([ASM])
4411 AC_SUBST([MOC])
4412 AC_SUBST([RCC])
4413 AC_SUBST([UIC])
4414 AC_SUBST([WINDRES])
4415 AC_SUBST([WINE_SDK_PATH])
4416 AC_SUBST([LIBEXT])
4417 AC_SUBST([AM_CPPFLAGS])
4418 AC_SUBST([MACOSX_DEPLOYMENT_TARGET])
4419 AC_SUBST([FILE_LIBVLCCORE_DLL])
4420 AC_SUBST([FILE_LIBVLC_DLL])
4422 AC_CONFIG_FILES([
4423 Makefile
4424 doc/Makefile
4425 modules/Makefile
4426 m4/Makefile
4427 po/Makefile.in
4428 share/Makefile
4429 compat/Makefile
4430 src/Makefile
4431 lib/Makefile
4432 bin/Makefile
4433 test/Makefile
4434 modules/hw/mmal/Makefile
4435 share/vlc.appdata.xml.in
4436 ])
4438 AM_COND_IF([HAVE_WIN32], [
4439 AC_CONFIG_FILES([
4440 extras/package/win32/NSIS/spad.nsi
4441 extras/package/win32/NSIS/vlc.win32.nsi
4442 extras/package/win32/msi/config.wxi
4443 ])
4444 ])
4446 AM_COND_IF([HAVE_DARWIN], [
4447 AC_CONFIG_FILES([
4448 modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4449 share/macosx/Info.plist:share/Info.plist.in
4450 ])
4451 ])
4453 dnl Generate makefiles
4454 AC_OUTPUT
4456 dnl Do we have to use make or gmake ?
4457 if make --version 2>&1|grep -q GNU
4458 then
4459 # GNU make, all seems good
4460 MAKE=make
4461 else
4462 # Known GNU make alias (on BSD)
4463 MAKE=gmake
4464 fi
4465 dnl Shortcut to nice compile message
4466 if test -n $SHELL; then
4467 SHELL=${CONFIG_SHELL-/bin/sh}
4468 fi
4469 rm -f compile
4470 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4471 echo "#! $SHELL
4472 rm -f .error\$\$
4473 ERROR=0
4474 export PATH=\"$PATH\" LANG=C
4475 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4476 test -f .error\$\$ && ERROR=1
4477 rm -f .error\$\$
4478 exit \$ERROR" >compile
4479 chmod a+x compile
4481 echo "
4482 libvlc configuration
4483 --------------------
4484 version : ${VERSION}
4485 system : ${SYS}
4486 architecture : ${ARCH}
4487 optimizations : ${enable_optimizations}"
4488 if test "${enable_vlc}" != "no"; then
4489 echo "vlc aliases :${ALIASES}"
4490 else
4491 echo "build vlc executable : no"
4492 fi
4493 echo "
4494 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."