configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2015 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 3.0.0-git)
   6 VERSION_MAJOR=3
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Vetinari"
  17 COPYRIGHT_YEARS="1996-2015"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Directories
  35 dnl
  36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  37 dnl AC_SUBST(vlcincludedir)
  38 vlcdatadir="\${datadir}/\${PKGDIR}"
  39 AC_SUBST(vlcdatadir)
  40 vlclibdir="\${libdir}/\${PKGDIR}"
  41 AC_SUBST(vlclibdir)
  42
  43 dnl
  44 dnl Check for tools
  45 dnl
  46 AC_PROG_CC_C99
  47 AC_USE_SYSTEM_EXTENSIONS
  48 VLC_PROG_CC_C11
  49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  51 AH_TOP([
  52 #ifndef _REENTRANT
  53 # define _REENTRANT
  54 #endif
  55 ])
  56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  59
  60 AM_PROG_CC_C_O
  61 AC_PROG_CXX
  62 AC_PROG_CPP
  63 AC_PROG_OBJC
  64 _AM_DEPENDENCIES([OBJC])
  65 AC_PROG_EGREP
  66 AC_PROG_MAKE_SET
  67 AC_PROG_INSTALL
  68 AM_PROG_AS
  69
  70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  74 AS_IF([test "$BUILDCC" = "false"], [
  75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  76 ])
  77
  78 dnl Check for compiler properties
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AC_C_RESTRICT
  82 AX_CXX_COMPILE_STDCXX_11(noext, optional)
  83
  84 dnl Extend the --help string at the current spot.
  85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  86
  87 dnl Allow binary package maintainer to pass a custom string to avoid
  88 dnl cache problem
  89 AC_ARG_WITH(binary-version,
  90     AS_HELP_STRING([--with-binary-version=STRING],
  91          [To avoid plugins cache problem between binary version]),[],[])
  92 AS_IF([test -n "${with_binary_version}"],[
  93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  94          [Binary specific version])
  95 ])
  96
  97 dnl
  98 dnl  Check the operating system
  99 dnl
 100 HAVE_WIN64="0"
 101 HAVE_IOS="0"
 102 HAVE_OSX="0"
 103
 104 case "${host_os}" in
 105   "")
 106     SYS=unknown
 107     ;;
 108   linux*)
 109     SYS=linux
 110     ;;
 111   bsdi*)
 112     SYS=bsdi
 113     CFLAGS="${CFLAGS} -pthread"
 114     ;;
 115   freebsd*)
 116     SYS=freebsd
 117     CFLAGS="${CFLAGS} -pthread"
 118     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 119     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 120     ;;
 121   openbsd*)
 122     SYS=openbsd
 123     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 124     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 125     ;;
 126   netbsd*)
 127     SYS=netbsd
 128     ;;
 129   dragonfly*)
 130     SYS=dragonfly
 131     ;;
 132   darwin*)
 133
 134     dnl Force gcc "-arch" flag
 135     ARCH_flag=""
 136     case "${host}" in
 137       i?86*)
 138         ARCH_flag="-arch i386"
 139       ;;
 140       ppc64*)
 141         ARCH_flag="-arch ppc64"
 142       ;;
 143       ppc*)
 144         ARCH_flag="-arch ppc"
 145       ;;
 146       x86_64*)
 147         ARCH_flag="-arch x86_64"
 148       ;;
 149       arm*)
 150         ac_cv_c_bigendian="no"
 151         ac_cv_c_attribute_packed="no"
 152       ;;
 153     esac
 154
 155     SYS=darwin
 156     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 157     CXX="${CXX} -stdlib=libc++ -std=c++11"
 158     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 159     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 160     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 161     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 162     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 163     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 164
 165     AC_EGREP_CPP(yes,
 166             [#import <TargetConditionals.h>
 167              #if TARGET_OS_IPHONE
 168              yes
 169              #endif],
 170              [HAVE_IOS="1"],
 171              [HAVE_OSX="1"])
 172
 173     dnl Allow binaries created on Lion to run on earlier releases
 174     AC_EGREP_CPP(yes,
 175            [#import <Cocoa/Cocoa.h>
 176             #ifdef MAC_OS_X_VERSION_10_7
 177             yes
 178             #endif],
 179             [AC_MSG_RESULT([yes])
 180             AC_LIBOBJ([getdelim])
 181             AC_LIBOBJ([strndup])
 182             AC_LIBOBJ([strnlen])],)
 183
 184     dnl
 185     dnl  Handle Mac OS X SDK flags
 186     dnl
 187     AC_ARG_WITH(macosx-sdk,
 188       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 189         [compile using the SDK in DIR])])
 190     if test "${with_macosx_sdk}" != "" ; then
 191         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 192         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 193         CC="${CC} -isysroot ${with_macosx_sdk}"
 194         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 195         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 196         LD="${LD} -syslibroot ${with_macosx_sdk}"
 197     fi
 198     AC_ARG_WITH(macosx-version-min,
 199       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 200         [compile for Mac OS X VERSION and above])])
 201     if test "${with_macosx_version_min}" != "" ; then
 202         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 203         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 204         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 205         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 206         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 207     fi
 208     ;;
 209   *mingw32* | *cygwin* | *wince* | *mingwce*)
 210     AC_CHECK_TOOL(WINDRES, windres, :)
 211     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 212     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 213     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
 214     AH_TOP([#endif])
 215     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 216     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 217     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 218     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 219     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 220     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 221     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 222     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 223     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 224     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 225     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 226
 227     case "${host_os}" in
 228       *mingw32*)
 229         SYS=mingw32
 230         ;;
 231       *cygwin*)
 232         dnl Check if we are using the mno-cygwin mode in which case we are
 233         dnl actually dealing with a mingw32 compiler.
 234         AC_EGREP_CPP(yes,
 235             [#ifdef _WIN32
 236              yes
 237              #endif],
 238             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 239         ;;
 240     esac
 241
 242     if test "${SYS}" = "mingw32"; then
 243         # DEP, ASLR, NO SEH
 244         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 245
 246         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 247         ac_default_prefix="`pwd`/_win32"
 248         DESTDIR="`pwd`/_win32/"
 249
 250         dnl
 251         dnl NSIS/MSI Installer prefix and WIN64
 252         dnl
 253         case "${host}" in
 254             amd64*|x86_64*)
 255                 HAVE_WIN64="1"
 256                 WINDOWS_ARCH="x64"
 257                 PROGRAMFILES="PROGRAMFILES64"
 258             ;;
 259             *)
 260                 WINDOWS_ARCH="x86"
 261                 PROGRAMFILES="PROGRAMFILES"
 262             ;;
 263         esac
 264         AC_SUBST(WINDOWS_ARCH)
 265         AC_SUBST(PROGRAMFILES)
 266
 267     fi
 268     ;;
 269   *nto*)
 270     SYS=nto
 271     ;;
 272   solaris*)
 273     SYS=solaris
 274     ;;
 275   hpux*)
 276     SYS=hpux
 277     ;;
 278   *os2*)
 279     SYS=os2
 280     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 281     AC_LIBOBJ([freeaddrinfo])
 282     ;;
 283   *)
 284     SYS="${host_os}"
 285     ;;
 286 esac
 287 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 288 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 289 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 290 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 291 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
 292 AM_CONDITIONAL(HAVE_IOS,   test "${HAVE_IOS}" = "1")
 293 AM_CONDITIONAL(HAVE_OSX,   test "${HAVE_OSX}" = "1")
 294
 295 dnl
 296 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 297 dnl for program foo on win32
 298 case "${build_os}" in
 299     cygwin|msys)
 300         ac_executable_extensions=".exe"
 301     ;;
 302     os2*)
 303         BUILDEXEEXT=".exe"
 304     ;;
 305     *)
 306     ;;
 307 esac
 308 AC_SUBST(BUILDEXEEXT)
 309
 310 dnl Android is linux, but a bit different
 311 AS_IF([test "$SYS" = linux],[
 312     AC_MSG_CHECKING([for an Android system])
 313     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 314         [[#ifndef __ANDROID__
 315          # error Not Android
 316          #endif
 317         ]],[[;]])
 318     ],[
 319       HAVE_ANDROID="1"
 320       AC_MSG_RESULT([yes])
 321     ],[
 322       AC_MSG_RESULT([no])
 323     ])
 324 ])
 325 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 326
 327
 328 dnl
 329 dnl  Check for the contrib directory
 330 dnl
 331 AC_ARG_WITH(contrib,
 332   [AS_HELP_STRING([--with-contrib[=DIR]],
 333     [search for 3rd party libraries in DIR/include and DIR/lib])
 334 ])
 335 AC_MSG_CHECKING([for 3rd party libraries path])
 336 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 337   CONTRIB_DIR="${srcdir}/contrib/${host}"
 338   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 339     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 340     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 341     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 342       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 343       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
 344       AS_IF([test ! -d "${CONTRIB_DIR}"], [
 345         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 346         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
 347         AS_IF([test ! -d "${CONTRIB_DIR}"], [
 348           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 349           CONTRIB_DIR=""
 350           AC_MSG_RESULT([not found])
 351         ])
 352       ])
 353     ])
 354   ])
 355 ], [
 356   AS_IF([test "${with_contrib}" != "no"], [
 357     CONTRIB_DIR="${with_contrib}"
 358   ], [
 359     CONTRIB_DIR=""
 360     AC_MSG_RESULT([disabled])
 361   ])
 362 ])
 363 AS_IF([test -n "${CONTRIB_DIR}"], [
 364   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 365     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 366   ], [
 367     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 368     CONTRIB_DIR=""
 369     AC_MSG_RESULT([not usable])
 370   ])
 371
 372 ])
 373 AS_IF([test -n "${CONTRIB_DIR}"], [
 374   AC_MSG_RESULT([${CONTRIB_DIR}])
 375   export PATH=${CONTRIB_DIR}/bin:$PATH
 376   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 377   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 378   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 379   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
 380   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 381   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 382
 383   AS_IF([test "${SYS}" = "darwin"], [
 384     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 385     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 386   ])
 387 ], [
 388   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 389     AC_MSG_ERROR([Third party libraries not found!])
 390   ])
 391 ])
 392 AC_SUBST(CONTRIB_DIR)
 393
 394 dnl Add extras/tools to the PATH
 395 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 396 AS_IF([test -d "${TOOLS_DIR}"], [
 397     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 398     export PATH="${TOOLS_DIR}":$PATH
 399 ])
 400
 401 dnl
 402 dnl  Libtool
 403 dnl  It's very bad, but our former custom system was worst
 404 dnl  -- Courmisch
 405 dnl
 406
 407 dnl override platform specific check for dependent libraries
 408 dnl otherwise libtool linking of shared libraries will
 409 dnl fail on anything other than pass_all.
 410 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 411     [lt_cv_deplibs_check_method=pass_all])
 412
 413 LT_INIT([dlopen win32-dll shared disable-static])
 414 LT_LANG([C++])
 415 LT_LANG([Windows Resource])
 416
 417 DOLT
 418
 419 lt_cv_deplibs_check_method=pass_all
 420
 421 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 422   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 423 ])
 424
 425 dnl
 426 dnl Gettext stuff
 427 dnl
 428 AM_GNU_GETTEXT_VERSION([0.19.4])
 429 AM_GNU_GETTEXT([external], [need-ngettext])
 430
 431 dnl
 432 dnl Iconv stuff
 433 dnl
 434 AM_ICONV
 435
 436 dnl
 437 dnl checks for mingw
 438 AS_IF([test "${SYS}" = "mingw32"], [
 439
 440 dnl Check for broken versions of mingw-runtime compatability library
 441     AC_MSG_CHECKING(for broken mingw-runtime)
 442     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 443 #include <_mingw.h>
 444 #if defined(__MINGW64_VERSION_MAJOR)
 445 # if __MINGW64_VERSION_MAJOR < 3
 446 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
 447 # endif
 448 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 449 # error Attempting to use mingw-runtime with broken vsnprintf support
 450 #endif
 451     ])], [
 452         AC_MSG_RESULT([ok])
 453     ], [
 454         AC_MSG_RESULT([present])
 455         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 456     ])
 457
 458     dnl force use of mingw provided c99 *printf over msvcrt
 459     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 460
 461     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
 462     VLC_ADD_LDFLAGS([vlc],[-mwindows])
 463
 464     dnl Check for the need to include the mingwex lib for mingw32
 465     VLC_SAVE_FLAGS
 466     AC_CHECK_LIB(mingwex,opendir,
 467         AC_CHECK_LIB(mingw32,opendir,,
 468             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 469     )
 470     VLC_RESTORE_FLAGS
 471
 472     dnl Check for fnative-struct or mms-bitfields support for mingw32
 473     VLC_SAVE_FLAGS
 474     CFLAGS="${CFLAGS} -mms-bitfields"
 475     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 476     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 477         [ac_cv_c_mms_bitfields],
 478         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 479     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 480         VLC_RESTORE_FLAGS
 481         CFLAGS="${CFLAGS} -fnative-struct"
 482         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 483         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 484             [ac_cv_c_fnative_struct],
 485             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 486         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 487     fi
 488 ])
 489
 490 AC_ARG_ENABLE(winstore_app,
 491      AS_HELP_STRING([--enable-winstore-app],
 492                     [Build targetted for Windows Store apps (default disabled)]))
 493
 494 vlc_winstore_app=0
 495 AS_IF([test "${SYS}" = "mingw32"],[
 496   AS_IF([test "${enable_winstore_app}" = "yes"], [
 497     vlc_winstore_app=1
 498      VLC_ADD_LIBS([libvlccore], [-lole32 -lruntimeobject])
 499     ],[
 500      VLC_ADD_LIBS([libvlccore],[-lwinmm])
 501     ])
 502   ])
 503 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 504 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 505
 506
 507 dnl
 508 dnl Buggy glibc prevention. Purposedly not cached.
 509 dnl See sourceware.org bugs 5058 and 5443.
 510 dnl Ubuntu alone has 20 bug numbers for this...
 511 dnl
 512 AC_MSG_CHECKING(for buggy GNU/libc versions)
 513 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 514 #include <limits.h>
 515 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 516   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 517 # error GNU/libc with dcgettext killer bug!
 518 #endif
 519 ])], [
 520   AC_MSG_RESULT([not present])
 521 ], [
 522   AC_MSG_RESULT([found])
 523   AS_IF([test "x${enable_nls}" != "xno"], [
 524     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 525 work-around for this. Check with your distribution vendor on how to update the
 526 glibc run-time. Alternatively, build with --disable-nls.])
 527   ])
 528 ])
 529
 530 dnl Plugin compilation stuff
 531
 532 VLC_LIBRARY_SUFFIX
 533
 534 dnl Check for system libs needed
 535 need_libc=false
 536
 537 dnl Check for usual libc functions
 538 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
 539 AC_CHECK_FUNCS([daemon fcntl fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale pthread_cond_timedwait_monotonic_np pthread_condattr_setclock])
 540 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv nrand48 poll posix_memalign rewind setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strsep strtof strtok_r strtoll swab tdestroy strverscmp])
 541 AC_CHECK_FUNCS(fdatasync,,
 542   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 543 ])
 544
 545 dnl mingw64 implements those as static inline, not functions with C linkage
 546 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 547 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 548 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 549 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 550
 551 dnl C11 static_assert()
 552 AC_MSG_CHECKING([for static_assert in assert.h])
 553 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 554 static_assert(1, "The impossible happened.");
 555 ])], [
 556   AC_MSG_RESULT([yes])
 557   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 558 ], [
 559   AC_MSG_RESULT([no])
 560 ])
 561
 562 # Windows CE does not have strcoll()
 563 AC_FUNC_STRCOLL
 564
 565 dnl Check for non-standard system calls
 566 case "$SYS" in
 567   "linux")
 568     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
 569     ;;
 570   "mingw32")
 571     AC_CHECK_FUNCS([_lock_file])
 572     ;;
 573 esac
 574
 575 AH_BOTTOM([#include <vlc_fixups.h>])
 576
 577 dnl Check for struct pollfd
 578 AC_CHECK_TYPES([struct pollfd],,,
 579 [#include <sys/types.h>
 580 #if HAVE_POLL
 581 # include <poll.h>
 582 #elif defined (_WIN32)
 583 # include <winsock2.h>
 584 #endif
 585 ])
 586
 587 dnl Checks for socket stuff
 588 VLC_SAVE_FLAGS
 589 SOCKET_LIBS=""
 590 AC_SEARCH_LIBS(connect, [socket], [
 591   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 592     SOCKET_LIBS="$ac_cv_search_connect"
 593   ])
 594 ], [
 595   AS_IF([test "${SYS}" = "mingw32"], [
 596     SOCKET_LIBS="-lws2_32"
 597   ])
 598 ])
 599
 600 AC_SEARCH_LIBS([inet_pton], [nsl], [
 601  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 602     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 603   ])
 604 ],, [${SOCKET_LIBS}])
 605
 606 LIBS="${LIBS} ${SOCKET_LIBS}"
 607 AC_LINK_IFELSE([
 608     AC_LANG_PROGRAM([#ifdef _WIN32
 609         # if _WIN32_WINNT < 0x600
 610         #  error Needs vista+
 611         # endif
 612         #include <ws2tcpip.h>
 613         #else
 614         #include <sys/socket.h>
 615         #include <arpa/inet.h>
 616         #endif], [
 617         char dst[[sizeof(struct in_addr)]];
 618         inet_pton(AF_INET, "127.0.0.1", dst);
 619     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 620 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 621 VLC_RESTORE_FLAGS
 622 AC_SUBST(SOCKET_LIBS)
 623
 624 dnl Check for socklen_t
 625 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 626 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 627 ac_cv_type_socklen_t,
 628 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 629 [#include <sys/types.h>
 630 #ifdef _WIN32
 631 # include <winsock2.h>
 632 # include <ws2tcpip.h>
 633 #else
 634 # include <sys/socket.h>
 635 #endif]], [[socklen_t len; len = 0;]])],
 636 ac_cv_type_socklen_t=yes,
 637 ac_cv_type_socklen_t=no)])
 638 AS_IF([test "$ac_cv_type_socklen_t" = no],
 639  [AC_DEFINE(socklen_t, int)])
 640
 641 dnl Check for struct sockaddr_storage
 642 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 643 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 644 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 645   [AC_TRY_COMPILE(
 646     [#include <sys/types.h>
 647      #if defined( _WIN32 )
 648      # include <winsock2.h>
 649      #else
 650      # include <sys/socket.h>
 651      #endif], [struct sockaddr_storage addr;],
 652      ac_cv_struct_sockaddr_storage=yes,
 653      ac_cv_struct_sockaddr_storage=no)])
 654 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 655   AC_DEFINE(sockaddr_storage, sockaddr)
 656   AC_DEFINE(ss_family, sa_family)
 657 ])
 658
 659 dnl FreeBSD has a gnugetopt library for this:
 660 GNUGETOPT_LIBS=""
 661 AC_CHECK_FUNC(getopt_long,, [
 662   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 663     GNUGETOPT_LIBS="-lgnugetopt"
 664   ])
 665 ])
 666 AC_SUBST(GNUGETOPT_LIBS)
 667
 668 AC_CHECK_LIB(m,cos,[
 669   LIBM="-lm"
 670 ], [
 671   LIBM=""
 672 ])
 673 AC_SUBST(LIBM)
 674
 675 AC_CHECK_LIB(m,lrintf, [
 676   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 677   VLC_ADD_LIBS([skins2],[-lm])
 678 ])
 679 AC_CHECK_LIB(m,nanf,
 680   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 681 )
 682
 683 dnl Check for dynamic plugins
 684 LIBDL=""
 685 have_dynamic_objects="no"
 686 VLC_SAVE_FLAGS
 687 AC_SEARCH_LIBS(dlsym, [dl svld], [
 688   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 689     LIBDL="$ac_cv_search_dlsym"
 690   ])
 691   have_dynamic_objects="yes"
 692 ])
 693 VLC_RESTORE_FLAGS
 694
 695 # Windows
 696 AS_IF([test "${SYS}" = "mingw32"], [
 697   LIBDL=""
 698   have_dynamic_objects="yes" #assume we can use shared objects
 699 ])
 700
 701 AS_IF([test "${enable_shared}" = "no"], [
 702   have_dynamic_objects=no
 703 ])
 704 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 705
 706 AC_SUBST(LIBDL)
 707
 708 dnl Check for thread library
 709 LIBPTHREAD=""
 710 AS_IF([test "${SYS}" != "mingw32"], [
 711   VLC_SAVE_FLAGS
 712   LIBS=""
 713   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 714     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 715       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 716     ])
 717   ])
 718   VLC_RESTORE_FLAGS
 719
 720   AC_CHECK_LIB(rt, clock_nanosleep, [
 721     VLC_ADD_LIBS([libvlccore],[-lrt])
 722   ], [
 723     AC_CHECK_FUNC(nanosleep,,[
 724       AC_CHECK_LIB(rt,nanosleep, [
 725         VLC_ADD_LIBS([libvlccore],[-lrt])
 726       ], [
 727         AC_CHECK_LIB(posix4,nanosleep, [
 728           VLC_ADD_LIBS([libvlccore],[-lposix4])
 729         ])
 730       ])
 731     ])
 732     dnl HP/UX port
 733     AC_CHECK_LIB(rt,sem_init, [VLC_ADD_LIBS([libvlccore],[-lrt])])
 734   ])
 735 ])
 736 AC_SUBST(LIBPTHREAD)
 737
 738 dnl
 739 dnl Check for headers
 740 dnl
 741
 742 dnl  POSIX
 743 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h])
 744 AC_CHECK_HEADERS([net/if.h], [], [],
 745 [
 746 #include <sys/types.h>
 747 #include <sys/socket.h>
 748 ])
 749 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 750 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 751
 752 dnl  BSD
 753 AC_CHECK_HEADERS([netinet/udplite.h sys/param.h sys/mount.h])
 754
 755 dnl  GNU/Linux
 756 AC_CHECK_HEADERS([getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 757
 758 dnl  MacOS
 759 AC_CHECK_HEADERS([xlocale.h])
 760
 761 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 762 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 763 AC_CHECK_TYPE(ssize_t,, [
 764   AC_DEFINE(ssize_t, int)
 765 ])
 766
 767 dnl It seems that autoconf detects pkg-config only during the first
 768 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 769 dnl it is nested within a conditional block, so it was not working right.
 770 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 771 AC_ARG_VAR(PKG_CONFIG_PATH,
 772        [Paths where to find .pc not at the default location])
 773 PKG_PROG_PKG_CONFIG()
 774
 775 dnl On some OS we need static linking
 776 AS_IF([test -n "${PKG_CONFIG}" ],[
 777     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 778         PKG_CONFIG="${PKG_CONFIG} --static"
 779     ])
 780 ])
 781
 782
 783 dnl
 784 dnl Check for zlib.h and -lz along with system -lminizip if available
 785 dnl
 786 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 787 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 788 if test "${have_zlib}" = "yes"
 789 then
 790   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
 791   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 792     AC_CHECK_HEADERS([unzip.h], [
 793       have_minizip=yes
 794       MINIZIP_LIBS="-lminizip -lz"
 795     ], [
 796       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
 797       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
 798       have_minizip=no
 799     ])
 800   ])
 801   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
 802   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
 803 fi
 804 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 805
 806
 807 dnl
 808 dnl Domain name i18n support via GNU libidn
 809 dnl
 810 PKG_CHECK_MODULES([IDN], [libidn], [
 811   have_libidn="yes"
 812   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 813 ], [
 814   have_libidn="no"
 815 ])
 816
 817
 818 dnl Check for dbus
 819 AC_ARG_ENABLE(dbus,
 820   [AS_HELP_STRING([--enable-dbus],
 821     [compile D-Bus message bus support (default enabled)])])
 822 have_dbus="no"
 823 AS_IF([test "${enable_dbus}" != "no"], [
 824   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 825     have_dbus="yes"
 826   ], [
 827     AS_IF([test -n "${enable_dbus}"], [
 828       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 829     ], [
 830       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 831     ])
 832   ])
 833 ])
 834 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 835
 836
 837 dnl Check for systemd
 838 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 839   have_systemd="yes"
 840 ], [
 841   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 842 ])
 843 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 844
 845
 846 dnl Check for ntohl, etc.
 847 VLC_SAVE_FLAGS
 848 CFLAGS="${CFLAGS} -Wall -Werror"
 849 AC_CACHE_CHECK([for ntohl in sys/param.h],
 850     [ac_cv_c_ntohl_sys_param_h],
 851     [     AC_TRY_COMPILE([#include <sys/param.h>],
 852         [int meuh; ntohl(meuh);],
 853         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 854 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 855     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 856 fi
 857 VLC_RESTORE_FLAGS
 858
 859 EXTEND_HELP_STRING([Optimization options:])
 860 dnl
 861 dnl  Compiler warnings
 862 dnl
 863
 864 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op])
 865 RDC_PROG_CC_FLAGS([-pipe])
 866 AC_LANG_PUSH([C++])
 867 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var])
 868 AC_LANG_POP([C++])
 869
 870 dnl
 871 dnl  Debugging mode
 872 dnl
 873 AC_ARG_ENABLE(debug,
 874   [AS_HELP_STRING([--enable-debug],
 875     [build with run-time assertions (default disabled)])],,
 876   [enable_debug="no"])
 877 AH_TEMPLATE(NDEBUG,
 878             [Define to 1 if debug code should NOT be compiled])
 879 AS_IF([test "${enable_debug}" != "no"], [
 880   AC_CHECK_HEADERS([valgrind/valgrind.h])
 881 ], [
 882   AC_DEFINE(NDEBUG)
 883 ])
 884
 885 dnl
 886 dnl  Profiling
 887 dnl
 888 AC_ARG_ENABLE(gprof,
 889   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 890   [enable_gprof="no"])
 891 AS_IF([test "${enable_gprof}" != "no"], [
 892   CFLAGS="${CFLAGS} -pg"
 893   CXXFLAGS="${CXXFLAGS} -pg"
 894   OBJCFLAGS="${OBJCFLAGS} -pg"
 895   LDFLAGS="${LDFLAGS} -pg"
 896 ])
 897
 898 AC_ARG_ENABLE(cprof,
 899   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 900   [enable_cprof="no"])
 901 AS_IF([test "${enable_gprof}" != "no"], [
 902   CFLAGS="${CFLAGS} -finstrument-functions"
 903   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 904   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 905   LDFLAGS="${LDFLAGS} -finstrument-functions"
 906 ])
 907
 908 dnl
 909 dnl  Test coverage
 910 dnl
 911 AC_ARG_ENABLE(coverage,
 912   [AS_HELP_STRING([--enable-coverage],
 913     [build for test coverage (default disabled)])],,
 914   [enable_coverage="no"])
 915 AS_IF([test "${enable_coverage}" != "no"], [
 916   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 917   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 918   LDFLAGS="-lgcov ${LDFLAGS}"
 919 ])
 920
 921 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 922   VLC_SAVE_FLAGS
 923   CFLAGS="${CFLAGS} -fvisibility=hidden"
 924   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 925   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 926   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 927                  [ac_cv_c_visibility_hidden], [
 928     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 929       ac_cv_c_visibility_hidden=yes
 930     ], [
 931       ac_cv_c_visibility_hidden=no
 932     ])
 933   ])
 934   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
 935 ])
 936
 937
 938 dnl
 939 dnl  Enable/disable optimizations
 940 dnl
 941 AC_ARG_ENABLE(optimizations,
 942   [AS_HELP_STRING([--disable-optimizations],
 943     [disable compiler optimizations (default enabled)])],,
 944   [enable_optimizations="yes"])
 945
 946 dnl Check for various optimization flags
 947 AS_IF([test "${enable_optimizations}" != "no"], [
 948
 949   dnl -O3 only in production builds
 950   AS_IF([test "${enable_debug}" = "no"], [
 951     VLC_SAVE_FLAGS
 952     CFLAGS="${CFLAGS} -O3"
 953     CXXFLAGS="${CXXFLAGS} -O3"
 954     OBJCFLAGS="${OBJCFLAGS} -O3"
 955     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
 956       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 957         ac_cv_c_o3=yes
 958       ], [
 959         ac_cv_c_o3=no
 960       ])
 961     ])
 962     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
 963   ])
 964
 965   dnl Check for -ffast-math
 966   VLC_SAVE_FLAGS
 967   CFLAGS="${CFLAGS} -ffast-math"
 968   CXXFLAGS="${CXXFLAGS} -ffast-math"
 969   OBJCFLAGS="${OBJCFLAGS} -ffast-math"
 970   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
 971     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 972       ac_cv_c_fast_math=yes
 973     ], [
 974       ac_cv_c_fast_math=no
 975     ])
 976   ])
 977   AS_IF([test "${ac_cv_c_fast_math}" = "no"], [VLC_RESTORE_FLAGS])
 978   AH_BOTTOM([
 979 #ifndef __FAST_MATH__
 980 # ifndef _MSC_VER
 981 #  pragma STDC FENV_ACCESS OFF
 982 #  pragma STDC FP_CONTRACT ON
 983 # else
 984 #  pragma fenv_access(off)
 985 #  pragma fp_contract(on)
 986 # endif
 987 #endif
 988 ])
 989
 990   dnl Check for -funroll-loops
 991   VLC_SAVE_FLAGS
 992   CFLAGS="${CFLAGS} -funroll-loops"
 993   CXXFLAGS="${CXXFLAGS} -funroll-loops"
 994   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
 995   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
 996     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 997       ac_cv_c_unroll_loops=yes
 998     ], [
 999       ac_cv_c_unroll_loops=no
1000     ])
1001   ])
1002   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1003
1004   AS_IF([test "$enable_debug" = "no"], [
1005     dnl Check for -fomit-frame-pointer
1006     VLC_SAVE_FLAGS
1007     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1008     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1009     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1010     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1011       [ac_cv_c_omit_frame_pointer], [
1012       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1013         ac_cv_c_omit_frame_pointer=yes
1014       ], [
1015         ac_cv_c_omit_frame_pointer=no
1016       ])
1017     ])
1018     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1019   ])
1020 ])
1021
1022 VLC_SAVE_FLAGS
1023 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1024 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1025   AC_TRY_LINK([],, [
1026     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1027   ], [
1028     ac_cv_ld_bsymbolic=""
1029   ])
1030 ])
1031 VLC_RESTORE_FLAGS
1032 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1033 AC_SUBST(SYMBOLIC_LDFLAGS)
1034
1035 dnl Checks for __attribute__(aligned()) directive
1036 VLC_SAVE_FLAGS
1037 CFLAGS="${CFLAGS} -Werror"
1038 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1039     [ac_cv_c_attribute_aligned],
1040     [ac_cv_c_attribute_aligned=0
1041     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1042         AC_TRY_COMPILE([],
1043         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1044         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1045     done])
1046 VLC_RESTORE_FLAGS
1047 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1048     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1049         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1050 fi
1051
1052 dnl Check for __attribute__((packed))
1053 AC_CACHE_CHECK([for __attribute__((packed))],
1054   [ac_cv_c_attribute_packed],
1055   [ac_cv_c_attribute_packed=no
1056    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1057                     [ac_cv_c_attribute_packed=yes])])
1058 if test "${ac_cv_c_attribute_packed}" != "no"; then
1059   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1060 fi
1061
1062 dnl
1063 dnl  Check the CPU
1064 dnl
1065 case "${host_cpu}" in
1066   "")
1067     ARCH=unknown
1068     ;;
1069   *)
1070     ARCH="${host_cpu}"
1071     ;;
1072 esac
1073
1074 dnl Check for backtrace() support
1075 AC_CHECK_HEADERS(execinfo.h)
1076 AC_CHECK_FUNCS(backtrace)
1077
1078 dnl
1079 dnl  default modules
1080 dnl
1081 ALIASES="${ALIASES} cvlc rvlc"
1082
1083 dnl
1084 dnl  Accelerated modules
1085 dnl
1086
1087 dnl  Check for fully working MMX intrinsics
1088 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1089 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1090 AC_ARG_ENABLE(mmx,
1091   [AS_HELP_STRING([--disable-mmx],
1092     [disable MMX optimizations (default auto)])],,[
1093   case "${host_cpu}" in
1094     i?86|x86_64)
1095       enable_mmx="yes"
1096       ;;
1097     *)
1098       enable_mmx="no"
1099       ;;
1100   esac
1101 ])
1102 have_mmx="no"
1103 have_mmxext="no"
1104 AS_IF([test "${enable_mmx}" != "no"], [
1105   ARCH="${ARCH} mmx"
1106   VLC_SAVE_FLAGS
1107   CFLAGS="${CFLAGS} -mmmx"
1108   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1109     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1110 [#include <mmintrin.h>
1111 #include <stdint.h>
1112 uint64_t frobzor;]], [
1113 [__m64 a, b, c;
1114 a = b = c = (__m64)frobzor;
1115 a = _mm_slli_pi16(a, 3);
1116 a = _mm_adds_pi16(a, b);
1117 c = _mm_srli_pi16(c, 8);
1118 c = _mm_slli_pi16(c, 3);
1119 b = _mm_adds_pi16(b, c);
1120 a = _mm_unpacklo_pi8(a, b);
1121 frobzor = (uint64_t)a;]])], [
1122       ac_cv_c_mmx_intrinsics=yes
1123     ], [
1124       ac_cv_c_mmx_intrinsics=no
1125     ])
1126   ])
1127   VLC_RESTORE_FLAGS
1128   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1129     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1130   ])
1131
1132   VLC_SAVE_FLAGS
1133   CFLAGS="${CFLAGS} -mmmx"
1134   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1135     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1136 void *p;
1137 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1138 ]])
1139     ], [
1140       ac_cv_mmx_inline=yes
1141     ], [
1142       ac_cv_mmx_inline=no
1143     ])
1144   ])
1145   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1146     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1147     have_mmx="yes"
1148   ])
1149
1150   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1151                  [ac_cv_mmxext_inline], [
1152     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1153 void *p;
1154 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1155 ]])
1156     ], [
1157       ac_cv_mmxext_inline=yes
1158     ], [
1159       ac_cv_mmxext_inline=no
1160     ])
1161   ])
1162   VLC_RESTORE_FLAGS
1163   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1164     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1165     have_mmxext="yes"
1166   ])
1167 ])
1168 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1169 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1170
1171 dnl  Check for fully workin SSE2 intrinsics
1172 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1173 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1174 AC_ARG_ENABLE(sse,
1175   [AS_HELP_STRING([--disable-sse],
1176     [disable SSE (1-4) optimizations (default auto)])],, [
1177   case "${host_cpu}" in
1178     i?86|x86_64)
1179       enable_sse=yes
1180       ;;
1181     *)
1182       enable_sse=no
1183       ;;
1184   esac
1185 ])
1186 have_sse2="no"
1187 AS_IF([test "${enable_sse}" != "no"], [
1188   ARCH="${ARCH} sse sse2"
1189
1190   VLC_SAVE_FLAGS
1191   CFLAGS="${CFLAGS} -msse2"
1192   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1193     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1194 [#include <emmintrin.h>
1195 #include <stdint.h>
1196 uint64_t frobzor;]], [
1197 [__m128i a, b, c;
1198 a = b = c = _mm_set1_epi64((__m64)frobzor);
1199 a = _mm_slli_epi16(a, 3);
1200 a = _mm_adds_epi16(a, b);
1201 c = _mm_srli_epi16(c, 8);
1202 c = _mm_slli_epi16(c, 3);
1203 b = _mm_adds_epi16(b, c);
1204 a = _mm_unpacklo_epi8(a, b);
1205 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1206       ac_cv_c_sse2_intrinsics=yes
1207     ], [
1208       ac_cv_c_sse2_intrinsics=no
1209     ])
1210   ])
1211   VLC_RESTORE_FLAGS
1212   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1213     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1214   ])
1215
1216   VLC_SAVE_FLAGS
1217   CFLAGS="${CFLAGS} -msse"
1218   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1219     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1220 void *p;
1221 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1222 ]])
1223     ], [
1224       ac_cv_sse_inline=yes
1225     ], [
1226       ac_cv_sse_inline=no
1227     ])
1228   ])
1229
1230   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1231     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1232   ])
1233
1234   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1235     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1236 void *p;
1237 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1238 ]])
1239     ], [
1240       ac_cv_sse2_inline=yes
1241     ], [
1242       ac_cv_sse2_inline=no
1243     ])
1244   ])
1245   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1246     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1247     have_sse2="yes"
1248   ])
1249
1250   # SSE3
1251   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1252     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1253 void *p;
1254 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1255 ]])
1256     ], [
1257       ac_cv_sse3_inline=yes
1258     ], [
1259       ac_cv_sse3_inline=no
1260     ])
1261   ])
1262
1263   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1264     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1265   # SSSE3
1266   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1267     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1268 void *p;
1269 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1270 ]])
1271     ], [
1272       ac_cv_ssse3_inline=yes
1273     ], [
1274       ac_cv_ssse3_inline=no
1275     ])
1276   ])
1277
1278   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1279     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1280
1281   # SSE4.1
1282   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1283                  [ac_cv_sse4_1_inline], [
1284     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1285 void *p;
1286 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1287 ]])
1288     ], [
1289       ac_cv_sse4_1_inline=yes
1290     ], [
1291       ac_cv_sse4_1_inline=no
1292     ])
1293   ])
1294
1295   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1296     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1297
1298   # SSE4.2
1299   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1300                  [ac_cv_sse4_2_inline], [
1301     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1302 void *p;
1303 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1304 ]])
1305     ], [
1306       ac_cv_sse4_2_inline=yes
1307     ], [
1308       ac_cv_sse4_2_inline=no
1309     ])
1310   ])
1311
1312   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1313     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1314
1315   # SSE4A
1316   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1317     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1318 void *p;
1319 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1320 ]])
1321     ], [
1322       ac_cv_sse4a_inline=yes
1323     ], [
1324       ac_cv_sse4a_inline=no
1325     ])
1326   ])
1327   VLC_RESTORE_FLAGS
1328   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1329     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1330 ])
1331 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1332
1333 VLC_SAVE_FLAGS
1334 CFLAGS="${CFLAGS} -mmmx"
1335 have_3dnow="no"
1336 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1337   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1338 void *p;
1339 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1340 ]])
1341   ], [
1342     ac_cv_3dnow_inline=yes
1343   ], [
1344     ac_cv_3dnow_inline=no
1345   ])
1346 ])
1347 VLC_RESTORE_FLAGS
1348 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1349   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1350             [Define to 1 if 3D Now! inline assembly is available.])
1351   have_3dnow="yes"
1352 ])
1353 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1354
1355
1356 AC_ARG_ENABLE(neon,
1357   [AS_HELP_STRING([--disable-neon],
1358     [disable NEON optimizations (default auto)])],, [
1359   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1360 ])
1361 AS_IF([test "${enable_neon}" != "no"], [
1362   VLC_SAVE_FLAGS
1363   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1364   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1365     AC_COMPILE_IFELSE([
1366       AC_LANG_PROGRAM(,[[
1367 asm volatile("vqmovun.s64 d0, q1":::"d0");
1368 ]])
1369     ], [
1370       ac_cv_arm_neon="yes"
1371     ], [
1372       ac_cv_arm_neon="no"
1373     ])
1374   ])
1375   VLC_RESTORE_FLAGS
1376 ])
1377 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1378
1379
1380 AC_ARG_ENABLE(altivec,
1381   [AS_HELP_STRING([--disable-altivec],
1382     [disable AltiVec optimizations (default auto)])],, [
1383   AS_CASE("${host_cpu}", [powerpc*],
1384         [enable_altivec=yes], [enable_altivec=no])
1385 ])
1386 have_altivec="no"
1387 ALTIVEC_CFLAGS=""
1388 AS_IF([test "${enable_altivec}" = "yes"], [
1389   ARCH="${ARCH} altivec";
1390   VLC_SAVE_FLAGS
1391   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1392     [ac_cv_altivec_inline],
1393     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1394          ac_cv_altivec_inline="yes",
1395          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1396           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1397             [ac_cv_altivec_inline="-Wa,-maltivec"],
1398             ac_cv_altivec_inline=no)
1399          ])])
1400   VLC_RESTORE_FLAGS
1401   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1402     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1403               [Define to 1 if AltiVec inline assembly is available.])
1404     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1405       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1406       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1407     ])
1408     have_altivec="yes"
1409   ])
1410
1411   VLC_SAVE_FLAGS
1412   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1413   [ac_cv_c_altivec], [
1414     CFLAGS="${CFLAGS} -maltivec"
1415     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1416 [#include <altivec.h>]], [
1417 [vec_ld(0, (unsigned char *)0);]])], [
1418       ac_cv_c_altivec="-maltivec"
1419     ], [
1420       ac_cv_c_altivec="no"
1421     ])
1422   ])
1423   VLC_RESTORE_FLAGS
1424   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1425     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1426     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1427     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1428     ALTIVEC_CFLAGS="$ALTIVEC_FLAGS ${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}"
1429     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1430     have_altivec="yes"
1431   ])
1432   AC_CHECK_HEADERS(altivec.h)
1433
1434   VLC_SAVE_FLAGS
1435   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1436   AC_CACHE_CHECK([if linker needs -framework vecLib],
1437     [ac_cv_ld_altivec],
1438     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1439   VLC_RESTORE_FLAGS
1440   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1441     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1442   ])
1443 ])
1444 AC_SUBST(ALTIVEC_CFLAGS)
1445 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1446
1447 dnl
1448 dnl  Memory usage
1449 dnl
1450 AC_ARG_ENABLE(optimize-memory,
1451   [AS_HELP_STRING([--enable-optimize-memory],
1452     [optimize memory usage over performance])])
1453 if test "${enable_optimize_memory}" = "yes"; then
1454   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1455 fi
1456
1457 dnl
1458 dnl Allow running as root (useful for people running on embedded platforms)
1459 dnl
1460 AC_ARG_ENABLE(run-as-root,
1461   [AS_HELP_STRING([--enable-run-as-root],
1462     [allow running VLC as root (default disabled)])])
1463 AS_IF([test "${enable_run_as_root}" = "yes"],[
1464     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1465               [Define to 1 to allow running VLC as root (uid 0).])
1466 ])
1467
1468 dnl
1469 dnl Stream output
1470 dnl
1471 AC_ARG_ENABLE(sout,
1472   [AS_HELP_STRING([--disable-sout],
1473     [disable streaming output (default enabled)])])
1474 AS_IF([test "${enable_sout}" != "no"], [
1475   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1476 ])
1477 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1478
1479 dnl Lua modules
1480 AC_ARG_ENABLE(lua,
1481   [AS_HELP_STRING([--disable-lua],
1482     [disable LUA scripting support (default enabled)])])
1483 if test "${enable_lua}" != "no"
1484 then
1485   PKG_CHECK_MODULES(LUA, lua5.2,
1486     [ have_lua=yes ],
1487     [
1488     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1489
1490     PKG_CHECK_MODULES(LUA, lua5.1,
1491       [ have_lua=yes ],
1492       [
1493       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1494       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1495         [ have_lua=yes ],
1496         [
1497           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1498           have_lua=yes
1499           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1500             [],
1501             [ have_lua=no ] )
1502           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1503             [LUA_LIBS="-llua5.2"],
1504           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1505             [LUA_LIBS="-llua5.1"],
1506             AC_CHECK_LIB( lua51 , luaL_newstate,
1507               [LUA_LIBS="-llua51"],
1508               AC_CHECK_LIB( lua , luaL_newstate,
1509                 [LUA_LIBS="-llua"],
1510                 [ have_lua=no
1511                 ], [-lm])
1512             )))
1513         ])
1514       ])
1515     ])
1516   if test "x${have_lua}" != "xyes" ;  then
1517       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1518   fi
1519   AC_ARG_VAR([LUAC], [LUA byte compiler])
1520   AC_CHECK_PROGS(LUAC, [${LUAC} luac], [false])
1521   AS_IF([test "${LUAC}" = "false"], [
1522     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1523   ])
1524   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1525     AC_MSG_ERROR([You need 32-bits luac when using using lua from contrib.])
1526   ])
1527 fi
1528 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1529
1530
1531 dnl
1532 dnl HTTP daemon
1533 dnl
1534 AC_ARG_ENABLE(httpd,
1535   [AS_HELP_STRING([--disable-httpd],
1536     [disable the built-in HTTP server (default enabled)])])
1537 if test "${enable_httpd}" != "no"
1538 then
1539   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1540 fi
1541 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1542
1543
1544 dnl
1545 dnl VideoLAN manager
1546 dnl
1547 AC_ARG_ENABLE(vlm,
1548   [AS_HELP_STRING([--disable-vlm],
1549     [disable the stream manager (default enabled)])],,
1550   [enable_vlm="${enable_sout}"])
1551 AS_IF([test "${enable_vlm}" != "no"], [
1552   AS_IF([test "${enable_sout}" = "no"], [
1553     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1554   ])
1555   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1556 ])
1557 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1558
1559
1560 dnl
1561 dnl Addons manager storage and repositories modules
1562 dnl
1563 AC_ARG_ENABLE(addonmanagermodules,
1564   [AS_HELP_STRING([--disable-addonmanagermodules],
1565     [disable the addons manager modules (default enabled)])])
1566 if test "${enable_addonmanagermodules}" != "no"
1567 then
1568   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1569 fi
1570 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1571
1572
1573 dnl
1574 dnl  Input plugins
1575 dnl
1576
1577 EXTEND_HELP_STRING([Input plugins:])
1578
1579 dnl
1580 dnl  libarchive access module
1581 dnl
1582 PKG_ENABLE_MODULES_VLC([ARCHIVE], [access_archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1583
1584 dnl
1585 dnl  live555 input
1586 dnl
1587 AC_ARG_ENABLE(live555,
1588   [AS_HELP_STRING([--enable-live555],
1589     [enable RTSP input through live555 (default enabled)])])
1590
1591 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1592   PKG_CHECK_MODULES(LIVE555, live555, [
1593     VLC_ADD_PLUGIN([live555])
1594     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1595     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1596   ], [
1597     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1598
1599     AC_LANG_PUSH(C++)
1600     VLC_SAVE_FLAGS
1601
1602     dnl detect include paths
1603     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1604       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1605     ], [
1606       AS_IF([test "${SYS}" != "os2"], [
1607         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1608         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1609       ], [
1610         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1611         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1612         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1613       ])
1614     ])
1615
1616     dnl CPP Flags
1617     AS_IF([test "${SYS}" = "solaris"], [
1618       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1619     ])
1620     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1621     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1622
1623     dnl version check
1624     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1625       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1626 [#include <liveMedia_version.hh>
1627 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1628 # error BOOM
1629 #endif]])
1630       ], [
1631         ac_cv_live555="yes"
1632       ], [
1633         ac_cv_live555="no"
1634       ])
1635     ])
1636
1637     AS_IF([test "$ac_cv_live555" = "no"], [
1638       AC_MSG_WARN([live555 is missing or its installed version is too old:
1639 Version 2011.12.23 or later is required to proceed.
1640 You can get an updated one from http://www.live555.com/liveMedia .])
1641       AS_IF([test -n "${enable_live555}"], [
1642         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1643       ])
1644     ], [
1645       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1646       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1647       AS_IF([test "${SYS}" = "mingw32"], [
1648         # add ws2_32 for closesocket, select, recv
1649         other_libs="$other_libs -lws2_32"
1650       ])
1651
1652       dnl We need to check for pic because live555 don't provide shared libs
1653       dnl and we want to build a plugins so we need -fPIC on some arch.
1654       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1655       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1656       AC_CHECK_LIB(liveMedia_pic, main, [
1657         VLC_ADD_PLUGIN([live555])
1658         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1659       ],[
1660         AC_CHECK_LIB(liveMedia, main, [
1661           VLC_ADD_PLUGIN([live555])
1662           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1663         ],[],[${other_libs}])
1664       ],[${other_libs_pic}])
1665     ])
1666     VLC_RESTORE_FLAGS
1667     AC_LANG_POP(C++)
1668   ])
1669 ])
1670
1671 dnl
1672 dnl IIDC and DV FireWire input modules
1673 dnl
1674 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1675 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1676
1677 dnl
1678 dnl - linsys modules: access module check for libzvbi
1679 dnl
1680 AC_ARG_ENABLE(linsys,
1681   [AS_HELP_STRING([--enable-linsys],
1682     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1683 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1684   VLC_ADD_PLUGIN([linsys_hdsdi])
1685   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1686     VLC_ADD_PLUGIN([linsys_sdi])
1687   ], [
1688     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1689   ])
1690 ])
1691
1692 dnl
1693 dnl dvdread module: check for libdvdread
1694 dnl
1695 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1696
1697 dnl
1698 dnl libdvdnav plugin
1699 dnl
1700 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1701
1702 dnl
1703 dnl  Blu-ray Disc Support with libbluray
1704 dnl
1705 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.5.0], (libbluray for Blu-ray disc support ) )
1706
1707 dnl
1708 dnl  OpenCV wrapper and example filters
1709 dnl
1710 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1711
1712
1713 dnl
1714 dnl  libsmbclient plugin
1715 dnl
1716 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1717 AS_IF([test "${SYS}" = "mingw32"], [ VLC_ADD_PLUGIN([smb]) ])
1718
1719 dnl
1720 dnl  liBDSM access module
1721 dnl
1722 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.0.4], [libdsm SMB/CIFS access/sd module], [auto])
1723
1724 dnl
1725 dnl sftp access support
1726 dnl
1727 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1728
1729 dnl
1730 dnl  Video4Linux 2
1731 dnl
1732 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1733   [disable Video4Linux version 2 (default auto)])])
1734 have_v4l2="no"
1735 AS_IF([test "$enable_v4l2" != "no"], [
1736   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1737     have_v4l2="yes"
1738   ])
1739 ])
1740 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1741
1742 dnl
1743 dnl special access module for Blackmagic SDI cards
1744 dnl
1745 AC_ARG_ENABLE(decklink,
1746   [AS_HELP_STRING([--disable-decklink],
1747     [disable Blackmagic DeckLink SDI input (default auto)])])
1748 AC_ARG_WITH(decklink_sdk,
1749   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1750     [                        location of Blackmagic DeckLink SDI SDK])])
1751 have_decklink=no
1752 if test "${enable_decklink}" != "no"
1753 then
1754   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1755   then
1756     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1757   fi
1758   VLC_SAVE_FLAGS
1759   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1760   AC_LANG_PUSH(C++)
1761   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1762       have_decklink=yes
1763   ], [
1764       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1765   ])
1766   AC_LANG_POP(C++)
1767   VLC_RESTORE_FLAGS
1768 fi
1769 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1770
1771
1772 dnl
1773 dnl  gnomeVFS access module
1774 dnl
1775 PKG_ENABLE_MODULES_VLC([GNOMEVFS], [gnomevfs], [gnome-vfs-2.0], [GnomeVFS access module], [auto])
1776
1777 dnl
1778 dnl  VCDX modules
1779 dnl
1780 PKG_ENABLE_MODULES_VLC([VCDX], [vcdx], [libcdio >= 0.78.2 libiso9660 >= 0.72 libvcdinfo >= 0.7.22], [navigate VCD with libvcdinfo], [no])
1781
1782 dnl
1783 dnl  Built-in CD-DA and VCD module
1784 dnl
1785 AC_ARG_ENABLE(vcd,
1786   [AS_HELP_STRING([--disable-vcd],
1787     [disable built-in VCD and CD-DA support (default enabled)])])
1788
1789 AC_ARG_ENABLE(libcddb,
1790   [AS_HELP_STRING([--disable-libcddb],
1791     [disable CDDB for Audio CD (default enabled)])])
1792
1793 if test "${enable_vcd}" != "no"
1794 then
1795   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1796   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1797     AC_MSG_RESULT(yes)
1798     VLC_ADD_PLUGIN([vcd cdda])
1799   ],[
1800     AC_MSG_RESULT(no)
1801   ])
1802
1803   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1804   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1805     AC_MSG_RESULT(yes)
1806     VLC_ADD_PLUGIN([vcd cdda])
1807     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1808   ],[
1809     AC_MSG_RESULT(no)
1810   ])
1811
1812   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1813   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1814     AC_MSG_RESULT(yes)
1815     VLC_ADD_PLUGIN([vcd cdda])
1816     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1817   ],[
1818     AC_MSG_RESULT(no)
1819   ])
1820
1821   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1822   then
1823     VLC_ADD_PLUGIN([vcd cdda])
1824   fi
1825
1826   if test "$enable_libcddb" != "no"; then
1827     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1828       HAVE_LIBCDDB=yes
1829       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1830       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1831       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1832       ],:
1833       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1834       HAVE_LIBCDDB=no])
1835   fi
1836 fi
1837
1838 dnl
1839 dnl Linux DVB
1840 dnl
1841 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1842   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1843 [#include <linux/dvb/version.h>
1844 #if (DVB_API_VERSION < 5)
1845 # error Linux DVB API v3.2 and older are not supported.
1846 #endif
1847 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1848 # error Linux DVB API v5.0 is unsupported. Please update.
1849 #endif
1850 ]])], [
1851   ac_cv_linux_dvb_5_1=yes
1852 ], [
1853   ac_cv_linux_dvb_5_1=no
1854 ])])
1855 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1856
1857 dnl
1858 dnl  Screen capture module
1859 dnl
1860 AC_ARG_ENABLE(screen,
1861   [AS_HELP_STRING([--enable-screen],
1862     [disable screen capture (default enabled)])])
1863 if test "${enable_screen}" != "no"; then
1864   if test "${SYS}" = "darwin"; then
1865     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1866       VLC_ADD_PLUGIN([screen])
1867     ])
1868   fi
1869 fi
1870 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1871
1872 dnl
1873 dnl  VNC/RFB access module
1874 dnl
1875 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1876
1877 dnl  RDP/Remote Desktop access module
1878 dnl
1879 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1880
1881 dnl
1882 dnl  Real RTSP plugin
1883 dnl
1884 AC_ARG_ENABLE(realrtsp,
1885   [  --enable-realrtsp       Real RTSP module (default disabled)])
1886 if test "${enable_realrtsp}" = "yes"; then
1887   VLC_ADD_PLUGIN([access_realrtsp])
1888 fi
1889
1890 dnl
1891 dnl MacOS eyeTV
1892 AC_ARG_ENABLE(macosx-eyetv,
1893   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1894 if test "x${enable_macosx_eyetv}" != "xno" &&
1895   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1896 then
1897   VLC_ADD_PLUGIN([access_eyetv])
1898 fi
1899
1900 dnl
1901 dnl QTKit
1902 AC_ARG_ENABLE(macosx-qtkit,
1903   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X)])
1904 if test "x${enable_macosx_qtkit}" != "xno" &&
1905   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1906 then
1907   VLC_ADD_PLUGIN([qtsound])
1908 fi
1909 AM_CONDITIONAL(HAVE_QTKIT, [test "${SYS}" = "darwin" -a "x${enable_macosx_qtkit}" != "xno"])
1910
1911 dnl
1912 dnl AVFoundation
1913 AC_SUBST(have_avfoundation, ["no"])
1914 AC_ARG_ENABLE(macosx-avfoundation,
1915   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1916 if test "x${enable_macosx_avfoundation}" != "xno" &&
1917   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1918 then
1919   SAVED_LIBS="${LIBS}"
1920   LIBS="-framework AVFoundation"
1921   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1922   LIBS="${SAVED_LIBS}"
1923   if test "${have_avfoundation}" != "no"
1924   then
1925     VLC_ADD_PLUGIN([avcapture])
1926   fi
1927 fi
1928 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
1929
1930 dnl
1931 dnl  DCP plugin (using asdcplib)
1932 dnl
1933 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
1934 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
1935
1936 dnl
1937 dnl  Demux plugins
1938 dnl
1939
1940 EXTEND_HELP_STRING([Mux/Demux plugins:])
1941
1942 dnl
1943 dnl  libdvbpsi check for ts mux/demux
1944 dnl
1945 have_dvbpsi="no"
1946 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.0.0], [have_dvbpsi="yes"])
1947 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
1948
1949
1950 dnl
1951 dnl  GME demux plugin
1952 dnl
1953 AC_ARG_ENABLE(gme,
1954   [AS_HELP_STRING([--enable-gme],
1955     [use Game Music Emu (default auto)])])
1956 AS_IF([test "${enable_gme}" != "no"], [
1957   AC_CHECK_HEADER([gme/gme.h], [
1958     VLC_ADD_LIBS([gme], [-lgme])
1959     VLC_ADD_PLUGIN([gme])
1960   ], [
1961     AS_IF([test "x${enable_gme}" != "x"], [
1962       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
1963     ])
1964   ])
1965 ])
1966
1967
1968 dnl
1969 dnl  SIDPlay plugin
1970 dnl
1971 AC_ARG_ENABLE(sid,
1972     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
1973 AS_IF([test "${enable_sid}" != "no"], [
1974     PKG_CHECK_MODULES(SID, [libsidplay2], [
1975         AC_LANG_PUSH(C++)
1976         oldCPPFLAGS="$CPPFLAGS"
1977         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
1978         AC_CHECK_HEADER([sidplay/builders/resid.h], [
1979             VLC_ADD_PLUGIN([sid])
1980             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
1981             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
1982         ], [
1983             AS_IF([test -n "${enable_sid}"],
1984                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
1985                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
1986                 )
1987         ])
1988         CPPFLAGS="$oldCPPFLAGS"
1989         AC_LANG_POP(C++)
1990     ], [
1991         AS_IF([test "x${enable_sid}" = "xyes"],
1992             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
1993             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
1994             )
1995     ])
1996 ])
1997
1998
1999 dnl
2000 dnl  ogg demux plugin
2001 dnl
2002 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2003 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2004     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2005 ],[true])
2006 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2007 if test "${enable_sout}" != "no"; then
2008 dnl Check for libshout
2009     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2010 fi
2011
2012 dnl
2013 dnl  matroska demux plugin
2014 dnl
2015 AC_ARG_ENABLE(mkv,
2016   [AS_HELP_STRING([--disable-mkv],
2017     [do not use libmatroska (default auto)])])
2018 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2019   AC_LANG_PUSH(C++)
2020   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2021     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2022     AC_EGREP_CPP(yes,
2023       [#include <ebml/EbmlVersion.h>
2024        #ifdef LIBEBML_VERSION
2025        #if LIBEBML_VERSION >= 0x010000
2026        yes
2027        #endif
2028        #endif],
2029       [AC_MSG_RESULT([yes])
2030         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2031           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2032           AC_EGREP_CPP(yes,
2033             [#include <matroska/KaxVersion.h>
2034              #ifdef LIBMATROSKA_VERSION
2035              #if LIBMATROSKA_VERSION >= 0x010000
2036              yes
2037              #endif
2038              #endif],
2039             [AC_MSG_RESULT([yes])
2040               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2041               AC_CHECK_LIB(ebml_pic, main, [
2042                 VLC_ADD_PLUGIN([mkv])
2043                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2044               ],[
2045                 AC_CHECK_LIB(ebml, main, [
2046                   VLC_ADD_PLUGIN([mkv])
2047                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2048                 ])
2049               ])
2050             ], [
2051               AC_MSG_RESULT([no])
2052               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2053           ])
2054         ])
2055       ],
2056       [AC_MSG_RESULT([no])
2057         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2058     ])
2059   ])
2060   AC_LANG_POP(C++)
2061 fi
2062
2063 dnl
2064 dnl  modplug demux plugin
2065 dnl
2066 AC_ARG_ENABLE(mod,
2067   [AS_HELP_STRING([--disable-mod],
2068     [do not use libmodplug (default auto)])])
2069 if test "${enable_mod}" != "no" ; then
2070     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2071           VLC_ADD_PLUGIN([mod])
2072           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2073           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2074           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2075     ],[
2076        AS_IF([test -n "${enable_mod}"],
2077          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2078          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2079     ])
2080 fi
2081
2082 dnl
2083 dnl  mpc demux plugin
2084 dnl
2085 AC_ARG_ENABLE(mpc,
2086   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2087 if test "${enable_mpc}" != "no"
2088 then
2089   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2090     VLC_ADD_PLUGIN([mpc])
2091     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2092     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2093     VLC_ADD_PLUGIN([mpc])
2094     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2095 fi
2096
2097 dnl
2098 dnl  Codec plugins
2099 dnl
2100
2101 EXTEND_HELP_STRING([Codec plugins:])
2102
2103 dnl
2104 dnl wmafixed plugin
2105 dnl
2106 AC_ARG_ENABLE(wma-fixed,
2107   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2108 if test "${enable_wma_fixed}" = "yes"
2109 then
2110   VLC_ADD_PLUGIN([wma_fixed])
2111 fi
2112
2113 dnl
2114 dnl shine encoder plugin
2115 dnl
2116 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2117
2118
2119 dnl
2120 dnl openmax il codec plugin
2121 dnl
2122 AC_ARG_ENABLE(omxil,
2123   [  --enable-omxil          openmax il codec module (default disabled)])
2124 if test "${enable_omxil}" = "yes"
2125 then
2126   VLC_ADD_PLUGIN([omxil])
2127 fi
2128
2129 dnl
2130 dnl openmax il vout plugin
2131 dnl
2132 AC_ARG_ENABLE(omxil-vout,
2133   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2134 if test "${enable_omxil_vout}" = "yes"
2135 then
2136   VLC_ADD_PLUGIN([omxil_vout])
2137 fi
2138
2139 dnl
2140 dnl raspberry pi openmax il configuration
2141 dnl
2142 AC_ARG_ENABLE(rpi-omxil,
2143   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2144 if test "${enable_rpi_omxil}" = "yes"
2145 then
2146   VLC_ADD_PLUGIN([omxil omxil_vout])
2147   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2148 fi
2149
2150 dnl
2151 dnl CrystalHD codec plugin
2152 dnl
2153 AC_ARG_ENABLE(crystalhd,
2154   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2155 if test "${enable_crystalhd}" != "no"; then
2156     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2157       VLC_ADD_PLUGIN([crystalhd])
2158       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2159     ],[
2160       if test "${SYS}" = "mingw32" ; then
2161         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2162           VLC_ADD_PLUGIN([crystalhd])
2163           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2164             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2165             ])
2166         ],[
2167           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2168                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2169                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2170         ],[#define __LINUX_USER__
2171                #include <libcrystalhd/bc_dts_types.h>
2172         ])
2173       fi
2174     ],[
2175        #include <libcrystalhd/bc_dts_types.h>
2176       ])
2177 fi
2178
2179 dnl
2180 dnl  mad plugin
2181 dnl
2182 have_mad="no"
2183 MAD_CFLAGS=""
2184 MAD_LIBS=""
2185
2186 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2187   enable_mad="yes"
2188 ], [
2189   with_mad="no"
2190 ])
2191 AS_IF([test "${with_mad}" != "no"], [
2192   MAD_CFLAGS="-I${with_mad}/include"
2193   MAD_LIBS="-L${with_mad}/lib"
2194 ])
2195
2196 AC_ARG_ENABLE(mad,
2197   [  --enable-mad            libmad module (default enabled)])
2198 AS_IF([test "${enable_mad}" != "no"], [
2199   VLC_SAVE_FLAGS
2200   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2201   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2202   AC_CHECK_HEADERS(mad.h, [
2203     AC_CHECK_LIB(mad, mad_bit_init, [
2204       have_mad="yes"
2205       MAD_LIBS="${MAD_LIBS} -lmad"
2206     ])
2207   ])
2208   VLC_RESTORE_FLAGS
2209   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2210     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2211   ])
2212 ])
2213 AC_SUBST(MAD_CFLAGS)
2214 AC_SUBST(MAD_LIBS)
2215 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2216
2217 dnl  mpg123 plugin
2218 dnl
2219 dnl
2220 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2221
2222
2223 AC_ARG_ENABLE(merge-ffmpeg,
2224 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2225   enable_merge_ffmpeg="no"
2226 ])
2227 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2228
2229 AC_MSG_CHECKING([for libavutil variant])
2230 PKG_CHECK_EXISTS([libavutil], [
2231   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2232   libavutil_micro="${libavutil_version##*.}"
2233   AS_IF([test ${libavutil_micro} -le 99], [
2234     avfork="libav"
2235   ], [
2236     avfork="ffmpeg"
2237   ])
2238 ], [
2239   avfork="none"
2240 ])
2241 AC_MSG_RESULT([${avfork}])
2242
2243 dnl
2244 dnl gstreamer stuff
2245 dnl
2246 AC_ARG_ENABLE(gst-decode,
2247   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2248
2249 have_gst_decode="no"
2250 AS_IF([test "${enable_gst_decode}" != "no"], [
2251   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2252     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2253       have_gst_decode="yes"
2254     ], [
2255       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2256     ])
2257   ], [
2258     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2259   ])
2260 ])
2261 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2262
2263 dnl
2264 dnl  avcodec decoder/encoder plugin
2265 dnl
2266 AC_ARG_ENABLE(avcodec,
2267 [  --enable-avcodec        libavcodec codec (default enabled)])
2268 AS_IF([test "${enable_avcodec}" != "no"], [
2269   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 55.0.0 libavutil >= 52.0.0], [
2270     dnl PKG_CHECK_EXISTS([libavcodec < 56],, [
2271     dnl   AC_MSG_ERROR([libavcodec versions 56 and later are not supported yet.])
2272     dnl ])
2273     VLC_SAVE_FLAGS
2274     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2275     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2276     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2277     AC_CHECK_HEADERS(libavutil/avutil.h)
2278     VLC_RESTORE_FLAGS
2279     have_avcodec="yes"
2280   ],[
2281     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2282   ])
2283 ], [
2284   have_avcodec="no"
2285 ])
2286 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2287
2288 dnl
2289 dnl libva needs avcodec
2290 dnl
2291 AC_ARG_ENABLE(libva,
2292   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2293
2294 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2295   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2296 ])
2297
2298 have_vaapi="no"
2299 have_vaapi_drm="no"
2300 have_vaapi_x11="no"
2301 AS_IF([test "${enable_libva}" != "no"], [
2302   PKG_CHECK_EXISTS([libva], [
2303     have_vaapi="yes"
2304   ], [
2305     AS_IF([test -n "${enable_libva}"], [
2306       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2307     ], [
2308       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2309     ])
2310   ])
2311   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2312     have_vaapi_drm="yes"
2313   ], [
2314     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2315   ])
2316   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2317     have_vaapi_x11="yes"
2318   ], [
2319     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2320   ])
2321 ])
2322 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2323 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2324
2325 have_avcodec_vaapi="no"
2326 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2327   VLC_SAVE_FLAGS
2328   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2329   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2330   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2331     AC_MSG_NOTICE([VAAPI acceleration activated])
2332     have_avcodec_vaapi="yes"
2333   ],[
2334     AS_IF([test -n "${enable_libva}"], [
2335       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2336     ], [
2337       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2338     ])
2339   ])
2340   VLC_RESTORE_FLAGS
2341 ])
2342 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2343
2344 dnl
2345 dnl dxva2 needs avcodec
2346 dnl
2347 AC_ARG_ENABLE(dxva2,
2348   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2349
2350 have_avcodec_dxva2="no"
2351 AS_IF([test "${enable_dxva2}" != "no"], [
2352   if test "${SYS}" = "mingw32"; then
2353   AS_IF([test "x${have_avcodec}" = "xyes"], [
2354     AC_CHECK_HEADERS(dxva2api.h,
2355       [
2356         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2357            AC_MSG_NOTICE([DxVA2 acceleration activated])
2358            have_avcodec_dxva2="yes"
2359         ],[
2360     AS_IF([test "${enable_dxva2}" = "yes"],
2361           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2362               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2363         ], [#undef _WIN32_WINNT
2364             /* DXVA2 is only available in Vista and above */
2365             #define _WIN32_WINNT 0x600])
2366       ],[
2367     AS_IF([test "${enable_dxva2}" = "yes"],
2368               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2369               [AC_MSG_WARN([dxva2api.h not found])])
2370       ])
2371   ],[
2372     AS_IF([test "x${enable_dxva2}" != "x"], [
2373       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2374     ])
2375   ])
2376   fi
2377 ])
2378 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2379
2380 dnl
2381 dnl d3d11va needs avcodec
2382 dnl
2383 AC_ARG_ENABLE(d3d11va,
2384   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2385
2386 have_avcodec_d3d11va="no"
2387 AS_IF([test "${enable_d3d11va}" != "no"], [
2388   if test "${SYS}" = "mingw32"; then
2389   AS_IF([test "x${have_avcodec}" = "xyes"], [
2390         AC_CHECK_TYPES([ID3D11VideoDecoder],
2391           [
2392             AC_CHECK_HEADERS(dxva2api.h,
2393               [
2394                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2395                    AC_MSG_NOTICE([D3D11 acceleration activated])
2396                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2397                    have_avcodec_d3d11va="yes"
2398                 ],[
2399                   AS_IF([test "${enable_d3d11va}" = "yes"],
2400                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2401                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2402                   ], [#undef _WIN32_WINNT
2403                       /* D3D11 is only available in Vista and above */
2404                       #define _WIN32_WINNT 0x600])
2405                   ],[
2406                     AS_IF([test "${enable_d3d11va}" = "yes"],
2407                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2408                           [AC_MSG_WARN([dxva2api.h not found])])
2409                   ])
2410           ],[
2411             AS_IF([test "${enable_d3d11va}" = "yes"],
2412                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2413                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2414           ], [#include <d3d11.h>])
2415   ],[
2416     AS_IF([test "x${enable_d3d11va}" != "x"], [
2417       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2418     ])
2419   ])
2420   fi
2421 ])
2422 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2423
2424 dnl
2425 dnl DXGI debug
2426 dnl
2427 AC_CHECK_HEADERS(dxgidebug.h)
2428
2429 dnl
2430 dnl vda needs avcodec
2431 dnl
2432 AC_ARG_ENABLE(vda,
2433   [  --enable-vda          VDA  support (default auto)])
2434
2435 have_avcodec_vda="no"
2436 AS_IF([test "${enable_vda}" != "no"], [
2437   if test "${SYS}" = "darwin"; then
2438   AS_IF([test "x${have_avcodec}" = "xyes"], [
2439     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2440       [
2441         AC_CHECK_HEADERS(libavcodec/vda.h, [
2442            have_avcodec_vda="yes"
2443         ],[
2444         AS_IF([test "${enable_vda}" = "yes"],
2445               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2446               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2447         ])
2448   ],[
2449         AS_IF([test "${enable_vda}" = "yes"],
2450               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2451               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2452       ])
2453   ],[
2454     AS_IF([test "x${enable_vda}" != "x"], [
2455       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2456     ])
2457  ])
2458  AS_IF([test "${have_avcodec_vda}" = "yes"], [
2459      SAVE_LIBS=$LIBS
2460      LIBS="$LIBS $AVCODEC_LIBS"
2461      AC_CHECK_FUNCS([av_vda_alloc_context])
2462      LIBS=$SAVE_LIBS
2463  ])
2464  fi
2465 ])
2466 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2467
2468 dnl
2469 dnl  avformat demuxer/muxer plugin
2470 dnl
2471
2472 AC_ARG_ENABLE(avformat,
2473 [  --enable-avformat       libavformat containers (default enabled)],, [
2474   enable_avformat="${have_avcodec}"
2475 ])
2476 have_avformat="no"
2477 AS_IF([test "${enable_avformat}" != "no"], [
2478   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2479       have_avformat="yes"
2480       VLC_SAVE_FLAGS
2481       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2482       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2483       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2484       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2485       AC_CHECK_HEADERS(libavutil/avutil.h)
2486       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2487         have_avformat="no"
2488       ])
2489       VLC_RESTORE_FLAGS
2490     ],[
2491       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2492   ])
2493 ])
2494 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2495
2496 dnl
2497 dnl  swscale image scaling and conversion plugin
2498 dnl
2499
2500 AC_ARG_ENABLE(swscale,
2501   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2502           (default enabled)]))
2503 if test "${enable_swscale}" != "no"
2504 then
2505   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2506     [
2507       VLC_SAVE_FLAGS
2508       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2509       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2510       AC_CHECK_HEADERS(libswscale/swscale.h)
2511       AC_CHECK_HEADERS(libavutil/avutil.h)
2512       VLC_ADD_PLUGIN([swscale])
2513       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2514       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2515       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2516         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2517       ])
2518       VLC_RESTORE_FLAGS
2519     ],[
2520       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2521   ])
2522 fi
2523
2524 dnl
2525 dnl  postproc plugin
2526 dnl
2527
2528 AC_ARG_ENABLE(postproc,
2529 [  --enable-postproc       libpostproc image post-processing (default auto)])
2530 if test "${enable_postproc}" != "no"
2531 then
2532   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2533     [
2534       VLC_SAVE_FLAGS
2535       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2536       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2537       AC_CHECK_HEADERS(postproc/postprocess.h)
2538       VLC_ADD_PLUGIN([postproc])
2539       VLC_RESTORE_FLAGS
2540     ],[
2541       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2542   ])
2543 fi
2544
2545 dnl
2546 dnl  faad decoder plugin
2547 dnl
2548 AC_ARG_ENABLE(faad,
2549 [  --enable-faad           faad codec (default auto)])
2550 have_faad="no"
2551 AS_IF([test "${enable_faad}" != "no"], [
2552   AC_CHECK_HEADERS([neaacdec.h], [
2553     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2554
2555     AS_IF([test "${have_faad}" = "yes"], [
2556       VLC_ADD_PLUGIN([faad])
2557       VLC_ADD_LIBS([faad],[-lfaad])
2558     ], [
2559       AS_IF([test "${enable_faad}" = "yes"], [
2560         AC_MSG_ERROR([cannot find FAAD library])
2561       ], [
2562         AC_MSG_WARN([cannot find FAAD library])
2563       ])
2564     ])
2565   ])
2566 ])
2567
2568 dnl
2569 dnl libvpx decoder plugin
2570 dnl
2571 AC_ARG_ENABLE(vpx,
2572     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 decoder (default auto)]))
2573 AS_IF([test "${enable_vpx}" != "no"],[
2574     PKG_CHECK_MODULES([VPX], [vpx] , [
2575         VLC_ADD_PLUGIN([vpx])
2576         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2577         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2578         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2579             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2580         ], [], [${VPX_LIBS}])
2581         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2582             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2583         ], [], [${VPX_LIBS}])
2584     ], [
2585     AS_IF([test "${enable_vpx}" = "yes"],[
2586         AC_MSG_ERROR([libvpx was not found])
2587     ])])
2588 ])
2589
2590 dnl
2591 dnl twolame encoder plugin
2592 dnl
2593 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2594
2595 dnl
2596 dnl fdk-aac encoder plugin
2597 dnl
2598 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2599
2600 dnl
2601 dnl  QuickTime plugin
2602 dnl
2603 AC_ARG_ENABLE(quicktime,
2604   [  --enable-quicktime      QuickTime module (deprecated)])
2605 if test "${enable_quicktime}" = "yes"; then
2606   if test "${SYS}" = "mingw32"; then
2607     VLC_ADD_PLUGIN([quicktime])
2608   else
2609   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2610     [ VLC_ADD_PLUGIN([quicktime])
2611       VLC_ADD_LIBS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2612     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2613   fi
2614 fi
2615
2616 dnl
2617 dnl A52/AC3 decoder plugin
2618 dnl
2619 AC_ARG_ENABLE(a52,
2620   [  --enable-a52            A/52 support with liba52 (default enabled)])
2621 if test "${enable_a52}" != "no"
2622 then
2623   AC_ARG_WITH(a52,
2624     [  --with-a52=PATH         a52 headers and libraries])
2625     if test -z "${with_a52}"
2626     then
2627       LDFLAGS_test=""
2628       CPPFLAGS_test=""
2629     else
2630       LDFLAGS_test="-L${with_a52}/lib"
2631       CPPFLAGS_test="-I${with_a52}/include"
2632     fi
2633     VLC_SAVE_FLAGS
2634     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2635     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2636     AC_CHECK_HEADERS(a52dec/a52.h, [
2637       AC_CHECK_LIB(a52, a52_free, [
2638         VLC_ADD_PLUGIN([a52tofloat32])
2639         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2640         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2641       ],[
2642         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2643         ], [$LIBM])
2644     ],[
2645       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2646     ])
2647     VLC_RESTORE_FLAGS
2648 fi
2649
2650 dnl
2651 dnl DTS Coherent Acoustics decoder plugin
2652 dnl
2653 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2654
2655 dnl
2656 dnl  Flac plugin
2657 dnl
2658 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2659
2660 dnl
2661 dnl  Libmpeg2 plugin
2662 dnl
2663 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2664
2665 dnl
2666 dnl  Vorbis plugin
2667 dnl
2668 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2669
2670 dnl
2671 dnl  Tremor plugin
2672 dnl
2673 AC_ARG_ENABLE(tremor,
2674   [  --enable-tremor         Tremor decoder support (default disabled)])
2675 if test "${enable_tremor}" = "yes"
2676 then
2677   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2678     VLC_ADD_PLUGIN([tremor])
2679    ],[])
2680 fi
2681
2682 dnl
2683 dnl  Speex plugins
2684 dnl
2685 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2686 have_speexdsp="no"
2687 AS_IF([test "${enable_speex}" != "no"], [
2688   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2689     have_speexdsp="yes"
2690   ], [
2691     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2692   ])
2693 ])
2694 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2695
2696 dnl
2697 dnl  Opus plugin
2698 dnl
2699 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2700
2701 dnl
2702 dnl  theora decoder plugin
2703 dnl
2704 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2705
2706 dnl
2707 dnl  Daala decoder plugin
2708 dnl
2709 PKG_ENABLE_MODULES_VLC([DAALA], [], [ogg daaladec daalaenc], [experimental daala codec], [disabled])
2710
2711 dnl
2712 dnl  schroedinger decoder plugin (for dirac format video)
2713 dnl
2714 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2715
2716 dnl
2717 dnl  PNG decoder module
2718 dnl
2719 AC_ARG_ENABLE(png,
2720   [  --enable-png            PNG support (default enabled)])
2721 AS_IF([test "${enable_png}" != "no"], [
2722 AC_CHECK_HEADERS(png.h, [
2723   VLC_SAVE_FLAGS
2724   LDFLAGS="${LDFLAGS} -lz $LIBM"
2725   AC_CHECK_LIB(png, png_set_rows, [
2726     VLC_ADD_PLUGIN([png])
2727   ], [], [-lz $LIBM])
2728   VLC_RESTORE_FLAGS
2729   ])
2730 ])
2731
2732 dnl
2733 dnl  JPEG decoder module
2734 dnl
2735 AC_ARG_ENABLE(jpeg,
2736   [  --enable-jpeg           JPEG support (default enabled)])
2737 AS_IF([test "${enable_jpeg}" != "no"], [
2738 AC_CHECK_HEADERS(jpeglib.h, [
2739   VLC_ADD_PLUGIN([jpeg])
2740   ])
2741 ])
2742
2743 dnl
2744 dnl  BPG decoder module
2745 dnl
2746 AC_ARG_ENABLE(bpg,
2747   [  --enable-bpg           BPG support (default disabled)])
2748 AS_IF([test "${enable_bpg}" != "no"], [
2749 AC_CHECK_HEADERS(libbpg.h, [
2750   VLC_ADD_PLUGIN([bpg])
2751   ])
2752 ])
2753
2754 dnl
2755 dnl H262 encoder plugin (lib262)
2756 dnl
2757 AC_ARG_ENABLE(x262,
2758   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2759 if test "${enable_x262}" != "no"; then
2760     PKG_CHECK_MODULES(X262, x262, [
2761         VLC_ADD_PLUGIN([x262])
2762         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2763         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2764           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2765         ])
2766         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2767         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2768           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2769         fi
2770     ], [
2771        if test "${enable_x262}" = "yes"; then
2772         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2773        fi
2774     ])
2775 fi
2776
2777 dnl x265 encoder
2778 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2779
2780 dnl
2781 dnl H264 encoder plugin (10-bit lib264)
2782 dnl
2783 AC_ARG_ENABLE(x26410b,
2784   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2785 if test "${enable_x26410b}" != "no"; then
2786     PKG_CHECK_MODULES(X26410B, x26410b, [
2787         VLC_ADD_PLUGIN([x26410b])
2788         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2789         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2790           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2791         ])
2792         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2793         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2794           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2795         fi
2796     ], [
2797        if test "${enable_x26410b}" = "yes"; then
2798         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2799        fi
2800     ])
2801 fi
2802
2803
2804 dnl
2805 dnl H264 encoder plugin (using libx264)
2806 dnl
2807 AC_ARG_ENABLE(x264,
2808   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2809 if test "${enable_x264}" != "no"; then
2810       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2811         VLC_ADD_PLUGIN([x264])
2812         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2813
2814         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2815           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2816         ])
2817
2818         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2819         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2820           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2821         fi
2822       ],[
2823         if test "${enable_x264}" = "yes"; then
2824             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2825           fi
2826       ])
2827 fi
2828
2829 dnl
2830 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2831 dnl
2832 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2833
2834 dnl
2835 dnl libfluidsynth (MIDI synthetizer) plugin
2836 dnl
2837 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2838
2839 dnl
2840 dnl Teletext Modules
2841 dnl vbi decoder plugin (using libzbvi)
2842 dnl telx module
2843 dnl uncompatible
2844 dnl
2845 AC_ARG_ENABLE(zvbi,
2846   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2847                   libzvbi (default enabled)]))
2848 AC_ARG_ENABLE(telx,
2849   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2850                   zvbi) (default enabled if zvbi is absent)]))
2851
2852 AS_IF( [test "${enable_zvbi}" != "no"],[
2853     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2854         [
2855           VLC_ADD_PLUGIN([zvbi])
2856           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2857           AS_IF( [test "${enable_telx}" = "yes"],[
2858                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2859                   ])
2860         ],[
2861           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2862         ])
2863     ])
2864 AS_IF( [test "${enable_telx}" != "no" ],[
2865   VLC_ADD_PLUGIN([telx])
2866   ])
2867
2868 dnl
2869 dnl libass subtitle rendering module
2870 dnl
2871 AC_ARG_ENABLE(libass,
2872   [  --enable-libass         Subtitle support using libass (default enabled)])
2873 AS_IF( [test "${enable_libass}" != "no"], [
2874   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2875       [
2876         VLC_ADD_PLUGIN([libass])
2877
2878         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2879           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2880            VLC_ADD_LIBS([libass],[-lfontconfig])
2881        ])
2882       ],[
2883         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2884       ])
2885   ])
2886
2887 dnl
2888 dnl ARIB subtitles rendering module
2889 dnl
2890 AC_ARG_ENABLE(aribsub,
2891   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2892 AS_IF( [test "${enable_aribsub}" != "no" ],[
2893   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2894       have_aribb24="yes"
2895       VLC_ADD_PLUGIN([aribsub])
2896       VLC_ADD_LIBS([aribsub],[-laribb24])
2897       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2898     ],[
2899       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2900       have_aribb24="no"
2901   ])
2902 ])
2903 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2904
2905 dnl
2906 dnl ARIB B25
2907 dnl
2908 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2909
2910 dnl
2911 dnl  kate decoder plugin
2912 dnl
2913 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2914
2915 dnl
2916 dnl  tiger rendering for kate decoder plugin
2917 dnl
2918 AC_ARG_ENABLE(tiger,
2919 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2920 AS_IF([test "${enable_tiger}" != "no"], [
2921   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2922       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2923         AS_IF([test -n "${enable_tiger}"], [
2924           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2925         ])
2926   ])
2927 ])
2928
2929
2930 dnl
2931 dnl  Video plugins
2932 dnl
2933
2934 EXTEND_HELP_STRING([Video plugins:])
2935
2936 dnl
2937 dnl  OpenGL
2938 dnl
2939 PKG_CHECK_MODULES([EGL], [egl], [
2940   have_egl="yes"
2941 ], [
2942   have_egl="no"
2943 ])
2944 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2945
2946 have_gl="no"
2947 PKG_CHECK_MODULES([GL], [gl], [
2948   have_gl="yes"
2949 ], [
2950   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2951 #ifdef _WIN32
2952 # include <GL/glew.h>
2953 #endif
2954 #include <GL/gl.h>
2955 ]], [
2956     [int t0 = GL_TEXTURE0;]])
2957   ], [
2958     GL_CFLAGS=""
2959     have_gl="yes"
2960     AS_IF([test "${SYS}" != "mingw32"], [
2961       GL_LIBS="-lGL"
2962     ], [
2963       GL_LIBS="-lopengl32"
2964     ])
2965   ])
2966 ])
2967 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
2968
2969 dnl OpenGL ES 2: depends on EGL 1.1
2970 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
2971 dnl OpenGL ES 1: depends on EGL 1.0
2972 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
2973
2974 dnl
2975 dnl  Xlib
2976 dnl
2977
2978 AC_PATH_XTRA()
2979 AC_CHECK_HEADERS(X11/Xlib.h)
2980
2981 dnl
2982 dnl  X C Bindings modules
2983 dnl
2984 AC_ARG_ENABLE(xcb,
2985   [  --enable-xcb            X11 support with XCB (default enabled)],, [
2986   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
2987     enable_xcb="yes"
2988   ], [
2989     enable_xcb="no"
2990   ])
2991 ])
2992 AC_ARG_ENABLE(xvideo,
2993   [  --enable-xvideo         XVideo support (default enabled)],, [
2994     enable_xvideo="$enable_xcb"
2995 ])
2996
2997 have_xcb="no"
2998 have_xcb_keysyms="no"
2999 have_xcb_randr="no"
3000 have_xcb_xvideo="no"
3001 AS_IF([test "${enable_xcb}" != "no"], [
3002   dnl libxcb
3003   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3004   have_xcb="yes"
3005   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3006   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3007   PKG_CHECK_MODULES(XPROTO, [xproto])
3008
3009   AS_IF([test "${enable_xvideo}" != "no"], [
3010     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3011   ])
3012
3013   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3014
3015   dnl xcb-utils
3016   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3017     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3018   ])
3019 ])
3020 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3021 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3022 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3023 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3024
3025
3026 dnl
3027 dnl VDPAU needs X11
3028 dnl
3029 AC_ARG_ENABLE(vdpau,
3030   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3031 have_vdpau="no"
3032 AS_IF([test "${enable_vdpau}" != "no"], [
3033   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3034     have_vdpau="yes"
3035     AS_IF([test "${no_x}" = "yes"], [
3036       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3037     ])
3038   ], [
3039     AS_IF([test -n "${enable_vdpau}"], [
3040       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3041     ])
3042   ])
3043 ])
3044 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3045
3046 have_avcodec_vdpau="no"
3047 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3048   case "${avfork}" in
3049     libav) av_vdpau_ver="55.26.0" ;;
3050     ffmpeg) av_vdpau_ver="55.42.100" ;;
3051   esac
3052   PKG_CHECK_EXISTS([libavutil >= 52.4.0 libavcodec >= ${av_vdpau_ver}], [
3053     have_avcodec_vdpau="yes"
3054     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3055   ], [
3056     AS_IF([test -n "${enable_vdpau}"], [
3057       AC_MSG_ERROR([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3058     ], [
3059       AC_MSG_WARN([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3060     ])
3061   ])
3062 ])
3063 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3064
3065
3066 dnl
3067 dnl  Wayland
3068 dnl
3069 AC_ARG_ENABLE(wayland,
3070   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3071 have_wayland="no"
3072 AC_ARG_VAR([WAYLAND_SCANNER], [Wayland scanner utility])
3073
3074 AS_IF([test "${enable_wayland}" != "no"], [
3075   AC_MSG_CHECKING([for the Wayland scanner])
3076   AS_IF([test -z "$WAYLAND_SCANNER"], [
3077     PKG_CHECK_EXISTS([wayland-scanner], [
3078       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3079     ], [
3080       WAYLAND_SCANNER="wayland-scanner"
3081     ])
3082   ])
3083   AC_MSG_RESULT([$WAYLAND_SCANNER])
3084
3085   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3086     have_wayland="yes"
3087   ], [
3088     AS_IF([test -n "${enable_wayland}"], [
3089       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3090     ])
3091   ])
3092
3093   AS_IF([test "${have_egl}" = "yes"], [
3094     PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3095       have_wayland_egl="yes"
3096     ], [
3097       AS_IF([test -n "${enable_wayland}"], [
3098         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3099       ])
3100     ])
3101   ])
3102 ])
3103 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3104 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3105
3106
3107 dnl
3108 dnl  SDL module
3109 dnl
3110 AC_ARG_ENABLE(sdl,
3111   [  --enable-sdl            SDL support (default enabled)])
3112 AC_ARG_ENABLE(sdl-image,
3113   [  --enable-sdl-image      SDL image support (default enabled)])
3114 if test "${enable_sdl}" != "no"
3115 then
3116    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3117       # SDL on Darwin is heavily patched and can only run SDL_image
3118       if test "${SYS}" != "darwin"; then
3119         VLC_ADD_PLUGIN([vout_sdl])
3120       fi
3121
3122       # SDL_image
3123       AS_IF([ test "${enable_sdl_image}" != "no"],[
3124         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3125           VLC_ADD_PLUGIN([sdl_image])],
3126           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3127           ])
3128       ])
3129    ],[
3130      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3131    ])
3132 fi
3133
3134 dnl
3135 dnl  freetype module
3136 dnl
3137 AC_ARG_ENABLE(freetype,
3138   [  --enable-freetype       freetype support   (default auto)])
3139 AC_ARG_ENABLE(fribidi,
3140   [  --enable-fribidi        fribidi support    (default auto)])
3141 AC_ARG_ENABLE(harfbuzz,
3142   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3143 AC_ARG_ENABLE(fontconfig,
3144   [  --enable-fontconfig     fontconfig support (default auto)])
3145
3146 AC_ARG_WITH([default-font],
3147     AS_HELP_STRING([--with-default-font=PATH],
3148         [Path to the default font]),
3149         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3150             "$withval", [Default font])])
3151 AC_ARG_WITH([default-monospace-font],
3152     AS_HELP_STRING([--with-default-monospace-font=PATH],
3153         [Path to the default font]),
3154         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3155             "$withval", [Default monospace font])])
3156
3157 AC_ARG_WITH([default-font-family],
3158     AS_HELP_STRING([--with-default-font-family=NAME],
3159         [Path to the default font family]),
3160         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3161             "$withval", [Default font family])])
3162 AC_ARG_WITH([default-monospace-font-family],
3163     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3164         [Path to the default font family]),
3165         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3166             "$withval", [Default monospace font family])])
3167
3168 have_freetype="no"
3169 have_fontconfig="no"
3170 have_fribidi="no"
3171 have_harfbuzz="no"
3172
3173 if test "${enable_freetype}" != "no"; then
3174    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3175       have_freetype="yes"
3176       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3177       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3178
3179       dnl fontconfig support
3180       if test "${SYS}" != "mingw32"; then
3181           if test "${enable_fontconfig}" != "no"; then
3182             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3183               have_fontconfig="yes"
3184             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3185           fi
3186       fi
3187
3188       dnl fribidi support
3189       if test "${enable_fribidi}" != "no"; then
3190         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3191           have_fribidi="yes"
3192           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3193           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3194         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3195       fi
3196
3197       dnl harfbuzz support
3198       if test "${have_fribidi}" != "no"; then
3199         if test "${enable_harfbuzz}" != "no"; then
3200           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3201             have_harfbuzz="yes"
3202             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3203             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3204           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3205         fi
3206       fi
3207   ],[
3208   AS_IF([test -n "${enable_freetype}"],[
3209     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3210     ])
3211   ])
3212 fi
3213
3214 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3215 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3216 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3217 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3218
3219
3220 dnl
3221 dnl  QuartzText vout module (iOS/Mac OS)
3222 dnl
3223 AC_ARG_ENABLE(macosx-quartztext,
3224   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3225 if test "x${enable_macosx_quartztext}" != "xno" &&
3226   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3227 then
3228   VLC_ADD_PLUGIN([quartztext])
3229 fi
3230
3231 dnl
3232 dnl  SVG module (text rendering and image decoding)
3233 dnl
3234 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3235 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3236
3237 dnl
3238 dnl  Windows DirectX module
3239 dnl
3240
3241 AC_ARG_ENABLE(directx,
3242   [AS_HELP_STRING([--enable-directx],
3243     [Microsoft DirectX support (default enabled on Windows)])],, [
3244   AS_IF([test "${SYS}" = "mingw32"], [
3245     enable_directx="yes"
3246   ], [
3247     enable_directx="no"
3248   ])
3249 ])
3250 have_directx="no"
3251 AS_IF([test "${enable_directx}" != "no"], [
3252   dnl DirectDraw
3253   AC_CHECK_HEADERS(ddraw.h, [
3254     have_directx="yes"
3255   ], [
3256     AC_MSG_ERROR([Cannot find DirectX headers!])
3257   ])
3258
3259   dnl OpenGL
3260   AC_CHECK_HEADERS(GL/wglew.h, [
3261     VLC_ADD_PLUGIN([glwin32])
3262   ],, [
3263     #include <windows.h>
3264     #include <GL/gl.h>
3265   ])
3266
3267   dnl Direct3D11
3268   AC_CHECK_HEADERS(d3d11.h, [
3269     VLC_ADD_PLUGIN([direct3d11])
3270   ])
3271
3272   dnl Direct3D9
3273   AC_CHECK_HEADERS(d3d9.h, [
3274     VLC_ADD_PLUGIN([direct3d9])
3275   ])
3276
3277   dnl Direct2D
3278   AC_CHECK_HEADERS(d2d1.h, [
3279     VLC_ADD_PLUGIN([direct2d])
3280   ])
3281 ])
3282 AM_CONDITIONAL([HAVE_DIRECTX], [test "$have_directx" = "yes"])
3283
3284 dnl
3285 dnl  Linux framebuffer module
3286 dnl
3287 AC_CHECK_HEADER([linux/fb.h], [
3288   VLC_ADD_PLUGIN([fb])
3289 ])
3290
3291
3292 dnl
3293 dnl  DirectFB module
3294 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3295 dnl  TODO: support for static linking
3296 dnl
3297 AC_ARG_ENABLE(directfb,
3298   [  --enable-directfb       DirectFB support (default disabled)])
3299 AC_ARG_WITH(directfb,
3300   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3301
3302 if test "${enable_directfb}" = "yes"; then
3303     have_directfb="false"
3304     CPPFLAGS_mydirectfb=
3305     LIBS_mydirectfb=
3306     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3307         dnl Trying the given location
3308         VLC_SAVE_FLAGS
3309
3310         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3311         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3312
3313         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3314         LIBS="${LIBS} ${LIBS_new}"
3315
3316         dnl FIXME: too obscure
3317         AC_CHECK_HEADER([directfb.h], [
3318             AC_CHECK_LIB([direct],[direct_initialize], [
3319                 AC_CHECK_LIB([fusion], [fusion_enter], [
3320                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3321                 ], have_directfb="false")
3322             ], have_directfb="false")
3323         ], have_directfb="false")
3324
3325         VLC_RESTORE_FLAGS
3326
3327         if test "${have_directfb}" = "true"; then
3328             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3329             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3330         fi
3331     else
3332         dnl Look for directfb-config
3333         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3334         if test "${DIRECTFB_CONFIG}" != "no"; then
3335             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3336             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3337             have_directfb="true"
3338         else
3339             dnl Trying with pkg-config
3340             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3341                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3342                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3343                 have_directfb="true"
3344                 ], [have_directfb="false"])
3345         fi
3346     fi
3347     if test "${have_directfb}" = "true"; then
3348         VLC_ADD_PLUGIN([directfb])
3349         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3350         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3351     else
3352         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3353     fi
3354 fi
3355
3356 dnl
3357 dnl  AA plugin
3358 dnl
3359 AC_ARG_ENABLE(aa,
3360   [  --enable-aa             aalib output (default disabled)])
3361 if test "${enable_aa}" = "yes"
3362 then
3363   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3364   if test "${have_aa}" = "true"
3365   then
3366     VLC_ADD_PLUGIN([aa])
3367   fi
3368 fi
3369
3370 dnl
3371 dnl  libcaca plugin
3372 dnl
3373 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3374
3375 dnl
3376 dnl  OS/2 KVA plugin
3377 dnl
3378 AC_ARG_ENABLE(kva,
3379   [AS_HELP_STRING([--enable-kva],
3380     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3381   AS_IF([test "$SYS" = "os2"], [
3382     enable_kva="yes"
3383   ])
3384 ])
3385 have_kva="no"
3386 KVA_LIBS=""
3387 AS_IF([test "$enable_kva" != "no"], [
3388   AC_CHECK_HEADERS([kva.h], [
3389     have_kva="yes"
3390     AC_CHECK_LIB(kva, main, [
3391       KVA_LIBS="-lkva"
3392     ])
3393   ])
3394 ])
3395 AC_SUBST(KVA_LIBS)
3396 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3397
3398 dnl
3399 dnl MMAL plugin
3400 dnl
3401 AC_ARG_ENABLE(mmal,
3402   AS_HELP_STRING([--enable-mmal],
3403     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3404 if test "${enable_mmal}" != "no"; then
3405   VLC_SAVE_FLAGS
3406   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3407   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3408   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3409     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3410         have_mmal="yes"
3411         VLC_ADD_PLUGIN([mmal])
3412         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3413         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3414         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3415           AS_IF([test "${enable_mmal}" = "yes"],
3416             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3417             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3418           ],
3419         [])
3420     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3421       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3422       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3423   VLC_RESTORE_FLAGS
3424 fi
3425 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3426
3427 dnl
3428 dnl  Audio plugins
3429 dnl
3430
3431 EXTEND_HELP_STRING([Audio plugins:])
3432
3433 dnl
3434 dnl  Pulseaudio module
3435 dnl
3436 AC_ARG_ENABLE(pulse,
3437   [AS_HELP_STRING([--enable-pulse],
3438     [use the PulseAudio client library (default auto)])])
3439 have_pulse="no"
3440 AS_IF([test "${enable_pulse}" != "no"], [
3441   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3442     have_pulse="yes"
3443   ], [
3444     AS_IF([test "x${enable_pulse}" != "x"], [
3445       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3446     ])
3447   ])
3448 ])
3449 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3450
3451 dnl
3452 dnl  ALSA module
3453 dnl
3454 AC_ARG_ENABLE(alsa,
3455   [AS_HELP_STRING([--enable-alsa],
3456     [support the Advanced Linux Sound Architecture (default auto)])],, [
3457   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3458     enable_alsa="yes"
3459   ])
3460 ])
3461 have_alsa="no"
3462 AS_IF([test "${enable_alsa}" != "no"], [
3463   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3464     have_alsa="yes"
3465   ], [
3466     AS_IF([test "x${enable_alsa}" != "x"], [
3467       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3468     ])
3469   ])
3470 ])
3471 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3472
3473 dnl
3474 dnl  Open Sound System module
3475 dnl
3476 AC_ARG_ENABLE(oss,
3477   [AS_HELP_STRING([--enable-oss],
3478     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3479   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3480     enable_oss="no"
3481   ])
3482 ])
3483 have_oss="no"
3484 OSS_LIBS=""
3485 AS_IF([test "$enable_oss" != "no"], [
3486   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3487     have_oss="yes"
3488     AC_CHECK_LIB(ossaudio, main, [
3489       OSS_LIBS="-lossaudio"
3490     ])
3491   ])
3492 ])
3493 AC_SUBST(OSS_LIBS)
3494 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3495
3496 dnl
3497 dnl  OpenBSD sndio module
3498 dnl
3499 AC_ARG_ENABLE([sndio],
3500   [AS_HELP_STRING([--disable-sndio],
3501     [support the OpenBSD sndio (default auto)])],, [
3502   AS_IF([test "$SYS" = "openbsd"], [
3503     enable_sndio="yes"
3504   ])
3505 ])
3506 have_sndio="no"
3507 AS_IF([test "$enable_sndio" != "no"], [
3508   AC_CHECK_HEADER([sndio.h], [
3509     have_sndio="yes"
3510   ])
3511 ])
3512 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3513
3514 dnl
3515 dnl  Windows Audio Session plugin
3516 dnl
3517 AC_ARG_ENABLE([wasapi],
3518   [AS_HELP_STRING([--enable-wasapi],
3519     [use the Windows Audio Session API (default auto)])
3520 ])
3521 have_wasapi="no"
3522 AS_IF([test "$enable_wasapi" != "no"], [
3523   AC_CHECK_HEADER([audioclient.h], [
3524     have_wasapi="yes"
3525   ], [
3526     AS_IF([test "x${enable_wasapi}" != "x"], [
3527       AC_MSG_ERROR([Windows Audio Session API not found.])
3528     ])
3529   ])
3530 ])
3531 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3532
3533 dnl
3534 dnl  AudioQueue plugin
3535 dnl
3536 AC_ARG_ENABLE(audioqueue,
3537   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3538 if test "${enable_audioqueue}" = "yes"
3539 then
3540   VLC_ADD_PLUGIN([audioqueue])
3541 fi
3542
3543 dnl
3544 dnl  JACK modules
3545 dnl
3546 AC_ARG_ENABLE(jack,
3547   [AS_HELP_STRING([--disable-jack],
3548     [do not use jack (default auto)])])
3549 have_jack="no"
3550 AS_IF([test "${enable_jack}" != "no"], [
3551     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3552       [ have_jack=yes ],
3553       [
3554       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3555
3556       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3557       [ have_jack=yes ],
3558       [
3559       AS_IF([test -n "${enable_jack}"],
3560          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3561          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3562       ])
3563     ])
3564 ])
3565 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3566
3567 dnl
3568 dnl  OpenSLES Android
3569 dnl
3570 AC_ARG_ENABLE(opensles,
3571   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3572 if test "${HAVE_ANDROID}" = "1"; then
3573   if test "${enable_opensles}" = "yes"; then
3574       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3575         [ VLC_ADD_PLUGIN([opensles_android]) ],
3576         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3577   fi
3578 fi
3579
3580 dnl
3581 dnl libsamplerate plugin
3582 dnl
3583 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3584
3585 dnl
3586 dnl  OS/2 KAI plugin
3587 dnl
3588 AC_ARG_ENABLE(kai,
3589   [AS_HELP_STRING([--enable-kai],
3590     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3591   AS_IF([test "$SYS" = "os2"], [
3592     enable_kai="yes"
3593   ])
3594 ])
3595 have_kai="no"
3596 KAI_LIBS=""
3597 AS_IF([test "$enable_kai" != "no"], [
3598   AC_CHECK_HEADERS([kai.h], [
3599     have_kai="yes"
3600     AC_CHECK_LIB(kai, main, [
3601       KAI_LIBS="-lkai"
3602     ])
3603   ])
3604 ])
3605 AC_SUBST(KAI_LIBS)
3606 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3607
3608 dnl
3609 dnl  chromaprint audio track fingerprinter
3610 dnl
3611 m4_pushdef([libchromaprint_version], 0.6.0)
3612 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3613     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3614     AS_IF([test "${enable_chromaprint}" = "yes"],
3615         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3616         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3617          ),
3618     [(Chromaprint based audio fingerprinter)],[auto])
3619 m4_popdef([libchromaprint_version])
3620
3621 dnl
3622 dnl  Chromecast streaming support
3623 dnl
3624 m4_pushdef([protobuf_lite_version], 2.5.0)
3625 AC_ARG_VAR(PROTOC, [protobuf compiler])
3626 AC_CHECK_PROGS(PROTOC, protoc, no)
3627 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3628     AS_IF([test "x${PROTOC}" != "xno"], [
3629         build_chromecast="yes"
3630     ], [
3631     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3632     ])
3633 ], [
3634     AS_IF([test "${enable_chromecast}" = "yes"],
3635         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3636         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3637     )
3638     enable_chromecast="no"
3639 ], [(Chromecast streaming support)], [auto])
3640 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3641 m4_popdef([protobuf_lite_version])
3642
3643 dnl
3644 dnl  Interface plugins
3645 dnl
3646
3647 EXTEND_HELP_STRING([Interface plugins:])
3648
3649 dnl
3650 dnl QT
3651 dnl
3652 AC_ARG_ENABLE(qt, [
3653   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3654   AS_IF([test "${SYS}" = "darwin"], [
3655     enable_qt="no"
3656   ])
3657 ])
3658 AS_IF([test "${enable_qt}" != "no"], [
3659   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.1.0 Qt5Widgets Qt5Gui], [
3660       PKG_CHECK_MODULES([QTX11], [Qt5X11Extras], [
3661           VLC_ADD_LIBS([qt4],[${QTX11_LIBS}])
3662           VLC_ADD_CXXFLAGS([qt4],[${QTX11_CFLAGS} -DQT5_HAS_X11])
3663       ],[
3664           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3665       ])
3666       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3667       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3668       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3669       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3670       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3671     ], [
3672       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.6.0],, [
3673         AS_IF([test -n "${enable_qt}"],[
3674           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3675         ],[
3676           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3677         ])
3678         enable_qt="no"
3679       ])
3680       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3681       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3682       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3683       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3684     ])
3685 ])
3686 AS_IF([test "${enable_qt}" != "no"], [
3687   VLC_ADD_PLUGIN([qt4])
3688   ALIASES="${ALIASES} qvlc"
3689 ])
3690 AM_CONDITIONAL(ENABLE_QT4, [test "$enable_qt" != "no"])
3691
3692 dnl
3693 dnl Simple test for skins2 dependency
3694 dnl
3695 AS_IF([test "$enable_qt" = "no"], [
3696   AS_IF([test "${enable_skins2}" = "yes"], [
3697     AC_MSG_ERROR([The skins2 module depends on the Qt4 interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt4 development package or alternatively you can also configure with: --disable-qt4 --disable-skins2.])
3698   ], [
3699     enable_skins2="no"
3700     AC_MSG_WARN([The skins2 module depends on the Qt4 interface, Qt4 is not built so skins2 is disabled.])
3701   ])
3702 ])
3703
3704 dnl
3705 dnl Skins2 module
3706 dnl
3707 AC_ARG_ENABLE(skins2,
3708   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3709 AS_IF([test "${enable_skins2}" != "no"], [
3710   have_skins_deps="yes"
3711
3712   dnl Win32
3713   AS_IF([test "${SYS}" = "mingw32"], [
3714     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3715     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3716   dnl MacOS
3717   ], [test "${SYS}" = "darwin"], [
3718     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3719     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3720   dnl OS/2
3721   ], [test "${SYS}" = "os2"], [
3722     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3723   dnl Linux/Unix
3724   ], [
3725     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3726     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3727     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3728     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3729     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3730   ])
3731
3732   dnl for All OSes
3733   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3734
3735   dnl we need freetype
3736   AS_IF([test "${have_freetype}" != "yes"], [
3737     have_skins_deps="no"
3738   ])
3739
3740   AS_IF([test "${have_skins_deps}" = "no"], [
3741     AS_IF([test "x${enable_skins2}" = "x"], [
3742       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3743     ], [
3744       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3745     ])
3746     enable_skins2="no"
3747   ], [
3748     VLC_ADD_PLUGIN([skins2])
3749     ALIASES="${ALIASES} svlc"
3750     enable_skins2="yes"
3751   ])
3752 ])
3753 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3754
3755 AC_ARG_ENABLE(libtar,
3756   [  --enable-libtar         libtar support for skins2 (default auto)])
3757 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3758   AC_CHECK_HEADERS(libtar.h, [
3759     VLC_ADD_LIBS([skins2],[-ltar])
3760   ])
3761 ])
3762
3763 dnl
3764 dnl  MacOS X gui module
3765 dnl
3766 AC_ARG_ENABLE(macosx,
3767   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3768 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3769 then
3770   VLC_ADD_PLUGIN([macosx])
3771
3772   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3773   then
3774     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3775   fi
3776 fi
3777 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3778
3779 dnl
3780 dnl  MacOS X sparkle update support
3781 dnl
3782 AC_ARG_ENABLE(sparkle,
3783   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3784 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3785 then
3786   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3787   then
3788     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3789   fi
3790
3791   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3792 fi
3793 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3794
3795
3796 dnl
3797 dnl  Minimal Mac OS X module
3798 dnl
3799 AC_ARG_ENABLE(minimal-macosx,
3800   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3801 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3802 then
3803   VLC_ADD_PLUGIN([minimal_macosx])
3804 fi
3805
3806 dnl
3807 dnl  MacOS X dialog provider
3808 dnl
3809 AC_ARG_ENABLE(macosx-dialog-provider,
3810   [  --enable-macosx-dialog-provider Mac OS X dialog module (default enabled on Mac OS X)])
3811 if test "x${enable_macosx_dialog_provider}" != "xno" &&
3812   (test "${SYS}" = "darwin" || test "${enable_macosx_dialog_provider}" = "yes")
3813 then
3814   VLC_ADD_PLUGIN([macosx_dialog_provider])
3815 fi
3816
3817 dnl
3818 dnl  ncurses module
3819 dnl
3820 AC_ARG_ENABLE(ncurses,
3821 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3822 have_ncurses="no"
3823 AS_IF([test "${enable_ncurses}" != "no"] ,[
3824   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3825     have_ncurses="yes"
3826     ALIASES="${ALIASES} nvlc"
3827   ], [
3828     AS_IF([test -n "${enable_ncurses}"], [
3829       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3830     ])
3831   ])
3832 ])
3833 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3834
3835 dnl
3836 dnl  Lirc plugin
3837 dnl
3838 AC_ARG_ENABLE(lirc,
3839   [  --enable-lirc           lirc support (default disabled)])
3840 have_lirc="no"
3841 AS_IF([test "${enable_lirc}" = "yes"], [
3842   AC_CHECK_HEADER(lirc/lirc_client.h, [
3843     AC_CHECK_LIB(lirc_client, lirc_init, [
3844       have_lirc="true"
3845     ])
3846   ])
3847 ])
3848 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3849
3850 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3851 dnl
3852 dnl  goom visualization plugin
3853 dnl
3854 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3855
3856 dnl
3857 dnl libprojectM visualization plugin
3858 dnl
3859 AC_ARG_ENABLE(projectm,
3860   [  --enable-projectm       projectM visualization plugin (default enabled)])
3861 AS_IF([test "${enable_projectm}" != "no"],
3862   [
3863     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3864     [
3865       VLC_ADD_PLUGIN([projectm])
3866       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3867         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3868         [ AC_MSG_WARN( [Using libprojectM version 1] )
3869       ])
3870     ],[
3871       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3872     ])
3873   ])
3874
3875 dnl
3876 dnl Vovoid VSXu visualization plugin
3877 dnl
3878 AC_ARG_ENABLE(vsxu,
3879   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3880 AS_IF([test "${enable_vsxu}" != "no"],
3881   [
3882     PKG_CHECK_MODULES(VSXU, libvsxu,
3883     [
3884       VLC_ADD_PLUGIN([vsxu])
3885     ],[
3886       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3887     ])
3888   ])
3889
3890 EXTEND_HELP_STRING([Service Discovery plugins:])
3891 dnl
3892 dnl  Bonjour services discovery
3893 PKG_ENABLE_MODULES_VLC([BONJOUR], [], [avahi-client >= 0.6], [Bonjour services discovery], [auto])
3894
3895 dnl
3896 dnl  libudev services discovery
3897 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3898
3899 dnl
3900 dnl MTP devices services discovery
3901 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3902
3903 dnl
3904 dnl UPnP Plugin (Intel SDK)
3905 dnl
3906 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3907
3908 EXTEND_HELP_STRING([Misc options:])
3909
3910 dnl
3911 dnl  libxml2 module
3912 dnl
3913 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3914
3915
3916 dnl
3917 dnl libgcrypt
3918 dnl
3919 AC_ARG_ENABLE(libgcrypt,
3920   [  --disable-libgcrypt     gcrypt support (default enabled)])
3921 # require libgcrypt >= 1.6.0
3922 AS_IF([test "${enable_libgcrypt}" != "no"], [
3923   AC_TRY_COMPILE([
3924 #include <gcrypt.h>
3925 #if GCRYPT_VERSION_NUMBER < 0x010600
3926 #error
3927 #endif],
3928   [], [
3929     have_libgcrypt="yes"
3930     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
3931     GCRYPT_CFLAGS="`libgcrypt-config --cflags`"
3932     GCRYPT_LIBS="`libgcrypt-config --libs`"
3933   ], [
3934     AS_IF([test "${enable_libgcrypt}" == "yes"], [
3935       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
3936     ])
3937   ])
3938 ])
3939
3940 AC_SUBST(GCRYPT_CFLAGS)
3941 AC_SUBST(GCRYPT_LIBS)
3942 AM_CONDITIONAL([HAVE_GCRYPT], [test "${have_libgcrypt}" = "yes"])
3943
3944 dnl
3945 dnl TLS/SSL
3946 dnl
3947 AC_ARG_ENABLE(gnutls,
3948   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
3949 AS_IF([test "${enable_gnutls}" != "no"], [
3950   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.2.0], [
3951     VLC_ADD_PLUGIN([gnutls])
3952   ], [
3953     AS_IF([test -n "${enable_gnutls}"], [
3954       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
3955     ])
3956   ])
3957 ])
3958
3959
3960 dnl
3961 dnl Taglib plugin
3962 dnl
3963 AC_ARG_ENABLE(taglib,
3964   [AS_HELP_STRING([--disable-taglib],
3965     [do not use TagLib (default enabled)])])
3966 AS_IF([test "${enable_taglib}" != "no"], [
3967   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
3968     VLC_ADD_PLUGIN([taglib])
3969   ], [
3970     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
3971 ])
3972
3973 dnl
3974 dnl  Developers helper modules (should be hidden from configure help)
3975 dnl
3976 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
3977 AS_IF([test "${enable_devtools}" != "no"], [
3978   VLC_ADD_PLUGIN([accesstweaks])
3979 ])
3980
3981 dnl
3982 dnl update checking system
3983 dnl
3984 AC_ARG_ENABLE(update-check,
3985   [  --enable-update-check   update checking system (default disabled)])
3986 if test "${enable_update_check}" = "yes"
3987 then
3988   if test "${have_libgcrypt}" != "yes"
3989   then
3990     AC_MSG_ERROR([libgcrypt is required for update checking system])
3991   fi
3992   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
3993   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
3994   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
3995 fi
3996
3997 dnl
3998 dnl Growl notification plugin
3999 dnl
4000 AC_ARG_ENABLE(growl,
4001   [  --enable-growl          growl notification plugin (default disabled)],,
4002   [enable_growl=no])
4003 AS_IF([test "${enable_growl}" != "no"], [
4004     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4005       VLC_ADD_PLUGIN([growl])
4006       VLC_ADD_LIBS([growl], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
4007       VLC_ADD_OBJCFLAGS([growl], [-F${CONTRIB_DIR}])
4008       VLC_ADD_OBJCFLAGS([growl], [-fobjc-exceptions] )
4009     ])
4010   ]
4011 )
4012
4013 dnl
4014 dnl Libnotify notification plugin
4015 dnl
4016 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4017
4018 dnl
4019 dnl  Endianness check
4020 dnl
4021 AC_C_BIGENDIAN
4022 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4023   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4024 ], [
4025   DEFS_BIGENDIAN=""
4026 ])
4027 AC_SUBST(DEFS_BIGENDIAN)
4028
4029 dnl
4030 dnl Where to install KDE solid .desktop
4031 dnl
4032 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
4033 AS_IF([test "x$KDE4_CONFIG" = "x"], [
4034   KDE4_CONFIG="kde4-config"
4035 ])
4036
4037 AC_ARG_WITH(kde-solid,
4038   AS_HELP_STRING([--with-kde-solid=PATH],
4039                  [KDE Solid actions directory (auto)]),, [
4040
4041 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4042   with_kde_solid="yes"
4043 fi
4044 ])
4045 soliddatadir=""
4046 AS_IF([test "${with_kde_solid}" != "no"], [
4047   AS_IF([test "${with_kde_solid}" = "yes"], [
4048     kde4datadir="`${KDE4_CONFIG} --install data`"
4049     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4050     soliddatadir="${kde4datadir}/solid/actions"
4051   ], [
4052     soliddatadir="${with_kde_solid}"
4053   ])
4054 ])
4055 AC_SUBST(soliddatadir)
4056 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4057
4058 EXTEND_HELP_STRING([Components:])
4059
4060 dnl
4061 dnl  the VLC binary
4062 dnl
4063 AC_ARG_ENABLE(vlc,
4064   [  --enable-vlc            build the VLC media player (default enabled)])
4065 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4066
4067 AC_ARG_ENABLE(macosx-vlc-app,
4068   [  --enable-macosx-vlc-app build the VLC media player (default enabled on Mac OS X)])
4069 AM_CONDITIONAL(BUILD_MACOSX_VLC_APP, [test "${enable_macosx_vlc_app}" != "no" &&
4070     (test "${SYS}" = "darwin" || test "${enable_macosx_vlc_app}" = "yes") ])
4071
4072 dnl
4073 dnl  Stuff used by the program
4074 dnl
4075 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4076 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4077 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4078 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4079 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4080 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4081 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4082 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4083 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4084 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4085 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4086 AC_SUBST(COPYRIGHT_MESSAGE)
4087 AC_SUBST(VERSION_MESSAGE)
4088 AC_SUBST(VERSION_MAJOR)
4089 AC_SUBST(VERSION_MINOR)
4090 AC_SUBST(VERSION_REVISION)
4091 AC_SUBST(VERSION_EXTRA)
4092 AC_SUBST(COPYRIGHT_YEARS)
4093 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4094 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4095 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4096 dnl
4097 dnl  Handle substvars that use $(top_srcdir)
4098 dnl
4099 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4100
4101 dnl
4102 dnl  Configuration is finished
4103 dnl
4104 AC_SUBST(SYS)
4105 AC_SUBST(ARCH)
4106 AC_SUBST(ALIASES)
4107 AC_SUBST(ASM)
4108 AC_SUBST(MOC)
4109 AC_SUBST(RCC)
4110 AC_SUBST(UIC)
4111 AC_SUBST(WINDRES)
4112 AC_SUBST(WINE_SDK_PATH)
4113 AC_SUBST(LIBEXT)
4114 AC_SUBST(AM_CPPFLAGS)
4115 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4116 AC_SUBST(FILE_LIBVLCCORE_DLL)
4117 AC_SUBST(FILE_LIBVLC_DLL)
4118
4119 AC_CONFIG_FILES([
4120   Makefile
4121   doc/Makefile
4122   modules/Makefile
4123   m4/Makefile
4124   po/Makefile.in
4125   share/Makefile
4126   compat/Makefile
4127   src/Makefile
4128   lib/Makefile
4129   bin/Makefile
4130   test/Makefile
4131   modules/gui/macosx/Makefile
4132   modules/gui/qt4/Makefile
4133   modules/gui/skins2/Makefile
4134   modules/hw/mmal/Makefile
4135 ])
4136
4137 AM_COND_IF([HAVE_WIN32], [
4138   AC_CONFIG_FILES([
4139     extras/package/win32/NSIS/spad.nsi
4140     extras/package/win32/NSIS/vlc.win32.nsi
4141     extras/package/win32/msi/config.wxi
4142   ])
4143 ])
4144
4145 AM_COND_IF([HAVE_DARWIN], [
4146   AC_CONFIG_FILES([
4147     extras/package/macosx/Info.plist
4148     extras/package/macosx/Resources/English.lproj/InfoPlist.strings
4149   ])
4150 ])
4151
4152 dnl Generate makefiles
4153 AC_OUTPUT
4154
4155 dnl Do we have to use make or gmake ?
4156 if make --version 2>&1|grep -q GNU
4157 then
4158     # GNU make, all seems good
4159     MAKE=make
4160 else
4161     # Known GNU make alias (on BSD)
4162     MAKE=gmake
4163 fi
4164 dnl Shortcut to nice compile message
4165 if test -n $SHELL; then
4166   SHELL=${CONFIG_SHELL-/bin/sh}
4167 fi
4168 rm -f compile
4169 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4170 echo "#! $SHELL
4171 rm -f .error\$\$
4172 ERROR=0
4173 export PATH=\"$PATH\" LANG=C
4174 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4175 test -f .error\$\$ && ERROR=1
4176 rm -f .error\$\$
4177 exit \$ERROR" >compile
4178 chmod a+x compile
4179
4180 echo "
4181 libvlc configuration
4182 --------------------
4183 version               : ${VERSION}
4184 system                : ${SYS}
4185 architecture          : ${ARCH}
4186 optimizations         : ${enable_optimizations}"
4187 if test "${enable_vlc}" != "no"; then
4188 echo "vlc aliases           :${ALIASES}"
4189 else
4190 echo "build vlc executable  : no"
4191 fi
4192 echo "
4193 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."