configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2018 VLC authors and VideoLAN])
   4
   5 AC_INIT([vlc], [4.0.0-dev])
   6 VERSION_MAJOR=4
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=dev
  11
  12 PKGDIR="vlc"
  13 AC_SUBST([PKGDIR])
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Otto Chriek"
  17 COPYRIGHT_YEARS="1996-2018"
  18
  19 AC_CONFIG_SRCDIR([src/libvlc.c])
  20 AC_CONFIG_AUX_DIR([autotools])
  21 AC_CONFIG_MACRO_DIR([m4])
  22 AC_CONFIG_LIBOBJ_DIR([compat])
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE([tar-ustar color-tests foreign])
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Check for tools
  35 dnl
  36 AC_PROG_CC
  37 AC_USE_SYSTEM_EXTENSIONS
  38 VLC_PROG_CC_C11
  39 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  40 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  41 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  42 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  43
  44 AC_PROG_CXX
  45 AC_PROG_CPP
  46 AC_PROG_OBJC
  47 AC_PROG_EGREP
  48 AC_PROG_MAKE_SET
  49 AC_PROG_INSTALL
  50 AM_PROG_AS
  51 AC_PROG_LEX
  52 AC_PROG_YACC
  53
  54 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  55 AC_CHECK_PROGS([DESKTOP_FILE_VALIDATE], [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  56 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  57 AC_CHECK_PROGS([BUILDCC], [c11-gcc c11 c99-gcc c99], [false])
  58 AS_IF([test "$BUILDCC" = "false"], [
  59   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  60 ])
  61
  62 dnl Check for compiler properties
  63 AC_C_CONST
  64 AC_C_INLINE
  65 AC_C_RESTRICT
  66 AX_CXX_COMPILE_STDCXX_11([noext], [mandatory])
  67
  68 dnl Extend the --help string at the current spot.
  69 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  70
  71 dnl Allow binary package maintainer to pass a custom string to avoid
  72 dnl cache problem
  73 AC_ARG_WITH([binary-version],
  74     AS_HELP_STRING([--with-binary-version=STRING],
  75          [To avoid plugins cache problem between binary version]),[],[])
  76 AS_IF([test -n "${with_binary_version}"],[
  77     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  78          [Binary specific version])
  79 ])
  80
  81 dnl Prevent clang from accepting unknown flags with a mere warning
  82 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
  83 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
  84
  85 dnl
  86 dnl  Check the operating system
  87 dnl
  88 HAVE_WIN64="0"
  89 HAVE_IOS="0"
  90 HAVE_OSX="0"
  91 HAVE_TVOS="0"
  92
  93 case "${host_os}" in
  94   "")
  95     SYS=unknown
  96     ;;
  97   linux*)
  98     SYS=linux
  99     CFLAGS="${CFLAGS} -pthread"
 100     ;;
 101   bsdi*)
 102     SYS=bsdi
 103     CFLAGS="${CFLAGS} -pthread"
 104     ;;
 105   freebsd*)
 106     SYS=freebsd
 107     CFLAGS="${CFLAGS} -pthread"
 108     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 109     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 110     ac_cv_ld_z_defs=no
 111     ;;
 112   openbsd*)
 113     SYS=openbsd
 114     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 115     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 116     ;;
 117   netbsd*)
 118     SYS=netbsd
 119     ;;
 120   dragonfly*)
 121     SYS=dragonfly
 122     ;;
 123   darwin*)
 124
 125     dnl Force gcc "-arch" flag
 126     ARCH_flag=""
 127     case "${host_cpu}" in
 128       i?86)
 129         ARCH_flag="-arch i386"
 130       ;;
 131       ppc64*)
 132         ARCH_flag="-arch ppc64"
 133       ;;
 134       ppc*)
 135         ARCH_flag="-arch ppc"
 136       ;;
 137       x86_64)
 138         ARCH_flag="-arch x86_64"
 139       ;;
 140       arm*)
 141         ac_cv_c_bigendian="no"
 142         ac_cv_c_attribute_packed="no"
 143       ;;
 144     esac
 145
 146     SYS=darwin
 147     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 148     CXX="${CXX} -stdlib=libc++ -std=c++11"
 149     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 150     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 151     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
 152     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 153     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 154     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 155
 156     AC_EGREP_CPP(yes,
 157             [#import <TargetConditionals.h>
 158              #if TARGET_OS_IPHONE
 159              yes
 160              #endif],
 161              [HAVE_IOS="1"],
 162              [HAVE_OSX="1"])
 163
 164     AC_EGREP_CPP(yes,
 165             [#import <TargetConditionals.h>
 166              #if TARGET_OS_TV
 167              yes
 168              #endif],
 169              [HAVE_TVOS="1"
 170              HAVE_IOS="0"
 171              HAVE_OSX="0"
 172              ],)
 173
 174     dnl
 175     dnl  Handle Mac OS X SDK flags
 176     dnl
 177     AC_ARG_WITH(macosx-sdk,
 178       AS_HELP_STRING([--with-macosx-sdk=DIR],
 179         [compile using the SDK in DIR]))
 180     if test "${with_macosx_sdk}" != "" ; then
 181         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 182         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 183         CC="${CC} -isysroot ${with_macosx_sdk}"
 184         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 185         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 186         LD="${LD} -syslibroot ${with_macosx_sdk}"
 187     fi
 188     AC_ARG_WITH(macosx-version-min,
 189       AS_HELP_STRING([--with-macosx-version-min=VERSION],
 190         [compile for Mac OS X VERSION and above]))
 191     if test "${with_macosx_version_min}" != "" ; then
 192         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 193         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 194         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 195         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 196         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 197     fi
 198     ;;
 199   *mingw32* | *cygwin* | *wince* | *mingwce*)
 200     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 201     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 202     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 203     AC_CHECK_TOOL(WINDRES, windres, :)
 204     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 205     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 206       [[#ifdef _WIN32_WINNT
 207        # error _WIN32_WINNT already defined
 208        #endif
 209       ]],[[;]])
 210     ],[
 211       AC_DEFINE([_WIN32_WINNT], 0x0601, [Define to '0x0601' for Windows 7 APIs.])
 212     ])
 213     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 214     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 215     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 216     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 217     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 218     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 219     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 220     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 221     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 222     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 223     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 224
 225     case "${host_os}" in
 226       *mingw32*)
 227         SYS=mingw32
 228         ;;
 229       *cygwin*)
 230         dnl Check if we are using the mno-cygwin mode in which case we are
 231         dnl actually dealing with a mingw32 compiler.
 232         AC_EGREP_CPP(yes,
 233             [#ifdef _WIN32
 234              yes
 235              #endif],
 236             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 237         ;;
 238     esac
 239
 240     if test "${SYS}" = "mingw32"; then
 241         # DEP, ASLR, NO SEH
 242         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 243
 244         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 245         ac_default_prefix="`pwd`/_win32"
 246         DESTDIR="`pwd`/_win32/"
 247
 248         dnl
 249         dnl NSIS/MSI Installer prefix and WIN64
 250         dnl
 251         case "${host_cpu}" in
 252             amd64|x86_64)
 253                 HAVE_WIN64="1"
 254                 WINDOWS_ARCH="x64"
 255                 PROGRAMFILES="PROGRAMFILES64"
 256                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 257             ;;
 258             *)
 259                 WINDOWS_ARCH="x86"
 260                 PROGRAMFILES="PROGRAMFILES"
 261             ;;
 262         esac
 263         AC_SUBST([WINDOWS_ARCH])
 264         AC_SUBST([PROGRAMFILES])
 265
 266     fi
 267     ;;
 268   *nto*)
 269     SYS=nto
 270     ;;
 271   solaris*)
 272     SYS=solaris
 273     ;;
 274   hpux*)
 275     SYS=hpux
 276     ;;
 277   *os2*)
 278     SYS=os2
 279     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 280     AC_LIBOBJ([freeaddrinfo])
 281     AC_LIBOBJ([gai_strerror])
 282     AC_CHECK_FUNCS([if_nametoindex])
 283     ;;
 284   *nacl*)
 285     SYS=nacl
 286     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 287     AC_LIBOBJ([sigwait])
 288     AC_LIBOBJ([recvmsg])
 289     AC_LIBOBJ([sendmsg])
 290     ;;
 291   *)
 292     SYS="${host_os}"
 293     ;;
 294 esac
 295
 296 dnl WinRT
 297 AC_ARG_ENABLE([winstore_app],
 298      AS_HELP_STRING([--enable-winstore-app],
 299                     [Build targetted for Windows Store apps (default disabled)]))
 300
 301 vlc_winstore_app=0
 302 AS_IF([test "${SYS}" = "mingw32"],[
 303   LIBCOM="-lole32"
 304   AS_IF([test "${enable_winstore_app}" = "yes"], [
 305     vlc_winstore_app=1
 306     LIBCOM=""
 307      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 308      AC_LIBOBJ([gai_strerror])
 309     ],[])
 310   AC_SUBST([LIBCOM])
 311   ])
 312 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 313
 314 AM_CONDITIONAL([HAVE_LINUX],   [test "${SYS}" = "linux"])
 315 AM_CONDITIONAL([HAVE_OS2],     [test "${SYS}" = "os2"])
 316
 317 AM_CONDITIONAL([HAVE_DARWIN],  [test "${SYS}" = "darwin"])
 318 AM_CONDITIONAL([HAVE_IOS],     [test "${HAVE_IOS}" = "1"])
 319 AM_CONDITIONAL([HAVE_OSX],     [test "${HAVE_OSX}" = "1"])
 320 AM_CONDITIONAL([HAVE_TVOS],    [test "${HAVE_TVOS}" = "1"])
 321
 322 AM_CONDITIONAL([HAVE_NACL],    [test "${SYS}" = "nacl"])
 323 AM_CONDITIONAL([HAVE_LIBANL],  [test "${HAVE_LIBANL}" = "1"])
 324
 325 AM_CONDITIONAL([HAVE_WIN32],   [test "${SYS}" = "mingw32"])
 326 AM_CONDITIONAL([HAVE_WIN64],   [test "${HAVE_WIN64}" = "1"]) dnl Only used for the packaging
 327 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 328 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 329
 330 dnl
 331 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 332 dnl for program foo on win32
 333 case "${build_os}" in
 334     cygwin|msys|mingw32)
 335         ac_executable_extensions=".exe"
 336         BUILDEXEEXT=".exe"
 337     ;;
 338     os2*)
 339         BUILDEXEEXT=".exe"
 340     ;;
 341     *)
 342     ;;
 343 esac
 344 AC_SUBST([BUILDEXEEXT])
 345
 346 dnl Android is linux, but a bit different
 347 AS_IF([test "$SYS" = linux],[
 348     AC_MSG_CHECKING([for an Android system])
 349     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 350         [[#ifndef __ANDROID__
 351          # error Not Android
 352          #endif
 353         ]],[[;]])
 354     ],[
 355       HAVE_ANDROID="1"
 356       AC_MSG_RESULT([yes])
 357     ],[
 358       AC_MSG_RESULT([no])
 359     ])
 360 ])
 361 AM_CONDITIONAL([HAVE_ANDROID], [test "${HAVE_ANDROID}" = "1"])
 362
 363 dnl Tizen (minimum SDK version: 2.3)
 364 AS_IF([test "$SYS" = linux],[
 365     AC_MSG_CHECKING([for Tizen])
 366     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 367         [[#include <tizen.h>
 368         ]],[[;]])
 369     ],[
 370       HAVE_TIZEN="1"
 371       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 372       AC_MSG_RESULT([yes])
 373     ],[
 374       AC_MSG_RESULT([no])
 375     ])
 376 ])
 377 AM_CONDITIONAL([HAVE_TIZEN], [test "${HAVE_TIZEN}" = "1"])
 378
 379 dnl
 380 dnl  Check for the contrib directory
 381 dnl
 382 AC_ARG_WITH(contrib,
 383   AS_HELP_STRING([--with-contrib[=DIR]],
 384     [search for 3rd party libraries in DIR/include and DIR/lib])
 385 )
 386 AC_MSG_CHECKING([for 3rd party libraries path])
 387 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 388   CONTRIB_DIR="${srcdir}/contrib/${host}"
 389   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 390     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 391     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 392     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 393       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 394       CONTRIB_DIR=""
 395       AC_MSG_RESULT([not found])
 396     ])
 397   ])
 398 ], [
 399   AS_IF([test "${with_contrib}" != "no"], [
 400     CONTRIB_DIR="${with_contrib}"
 401   ], [
 402     CONTRIB_DIR=""
 403     AC_MSG_RESULT([disabled])
 404   ])
 405 ])
 406 AS_IF([test -n "${CONTRIB_DIR}"], [
 407   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 408     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 409   ], [
 410     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 411     CONTRIB_DIR=""
 412     AC_MSG_RESULT([not usable])
 413   ])
 414
 415 ])
 416 AS_IF([test -n "${CONTRIB_DIR}"], [
 417   AC_MSG_RESULT([${CONTRIB_DIR}])
 418   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 419   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 420   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 421   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
 422   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:${CONTRIB_DIR}/share/pkgconfig:$PKG_CONFIG_PATH"
 423   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 424
 425   AS_IF([test -z "$LUAC"], [
 426     dnl Old contribs mixed cross-tools and cross-compiled executables
 427     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
 428       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
 429     ])
 430
 431     dnl Newer contribs follow usual name space rules
 432     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
 433       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
 434     ])
 435   ])
 436
 437   AS_IF([test "${SYS}" = "darwin"], [
 438     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 439     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 440   ])
 441 ], [
 442   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 443     AC_MSG_ERROR([Third party libraries not found!])
 444   ])
 445 ])
 446 AC_SUBST([CONTRIB_DIR])
 447
 448 dnl Add extras/tools to the PATH
 449 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 450 AS_IF([test -d "${TOOLS_DIR}"], [
 451     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 452     export PATH="${TOOLS_DIR}":$PATH
 453 ])
 454
 455 dnl
 456 dnl  Libtool
 457 dnl  It's very bad, but our former custom system was worst
 458 dnl  -- Courmisch
 459 dnl
 460
 461 dnl override platform specific check for dependent libraries
 462 dnl otherwise libtool linking of shared libraries will
 463 dnl fail on anything other than pass_all.
 464 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 465     [lt_cv_deplibs_check_method=pass_all])
 466
 467 LT_INIT([dlopen win32-dll shared disable-static])
 468 LT_LANG([C++])
 469 LT_LANG([Windows Resource])
 470
 471 DOLT
 472
 473 lt_cv_deplibs_check_method=pass_all
 474
 475 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 476   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 477 ])
 478
 479 dnl
 480 dnl Gettext stuff
 481 dnl
 482 AM_GNU_GETTEXT_VERSION([0.19.8])
 483 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 484
 485 dnl
 486 dnl Iconv stuff
 487 dnl
 488 AM_ICONV
 489
 490 dnl
 491 dnl checks for mingw
 492 AS_IF([test "${SYS}" = "mingw32"], [
 493
 494 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 495 #if !defined(__MINGW32__)
 496 # error Not compiling with mingw
 497 #endif
 498     ])], [
 499
 500 dnl Check for broken versions of mingw-runtime compatability library
 501     AC_MSG_CHECKING(for broken mingw-runtime)
 502     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 503 #include <_mingw.h>
 504 #if defined(__MINGW64_VERSION_MAJOR)
 505 # if __MINGW64_VERSION_MAJOR < 5
 506 #  error Update your mingw-w64! This one is too old.
 507 # endif
 508 #else
 509 # error You cannot compile with Mingw. Use Mingw-w64!
 510 #endif
 511     ])], [
 512         AC_MSG_RESULT([ok])
 513     ], [
 514         AC_MSG_RESULT([present])
 515         AC_MSG_ERROR([LibVLC requires Mingw-w64 version 5.0 or higher!])
 516     ])
 517
 518     dnl force use of mingw provided c99 *printf over msvcrt
 519     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 520
 521     dnl Check for the need to include the mingwex lib for mingw32
 522     VLC_SAVE_FLAGS
 523     AC_CHECK_LIB([mingwex], [opendir],
 524         AC_CHECK_LIB([mingw32], [opendir],,
 525             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 526     )
 527     VLC_RESTORE_FLAGS
 528     ], [
 529         AC_MSG_RESULT([Not compiling with mingw])
 530     ])
 531
 532     dnl Check for fnative-struct or mms-bitfields support for mingw32
 533     AX_CHECK_COMPILE_FLAG([-mms-bitfields], [
 534         AX_APPEND_FLAG([-mms-bitfields], [CFLAGS])
 535         AX_APPEND_FLAG([-mms-bitfields], [CXXFLAGS])
 536         # Check for the warning flag without "-Wno-", GCC accepts
 537         # -Wno-<anything> for unsupported warnings, which can trigger
 538         # other warnings instead.
 539         AX_CHECK_COMPILE_FLAG([-Wincompatible-ms-struct], [
 540             AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CFLAGS])
 541             AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CXXFLAGS])
 542         ])
 543     ], [
 544         AX_CHECK_COMPILE_FLAG([-fnative-struct], [
 545             AX_APPEND_FLAG([-fnative-struct], [CFLAGS])
 546             AX_APPEND_FLAG([-fnative-struct], [CXXFLAGS])
 547         ])
 548     ])
 549 ])
 550
 551
 552 dnl
 553 dnl Buggy glibc prevention. Purposedly not cached.
 554 dnl See sourceware.org bugs 5058 and 5443.
 555 dnl Ubuntu alone has 20 bug numbers for this...
 556 dnl
 557 AC_MSG_CHECKING(for buggy GNU/libc versions)
 558 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 559 #include <limits.h>
 560 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 561   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 562 # error GNU/libc with dcgettext killer bug!
 563 #endif
 564 ])], [
 565   AC_MSG_RESULT([not present])
 566 ], [
 567   AC_MSG_RESULT([found])
 568   AS_IF([test "x${enable_nls}" != "xno"], [
 569     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 570 work-around for this. Check with your distribution vendor on how to update the
 571 glibc run-time. Alternatively, build with --disable-nls.])
 572   ])
 573 ])
 574
 575 dnl Plugin compilation stuff
 576
 577 VLC_LIBRARY_SUFFIX
 578
 579 dnl Check for system libs needed
 580 need_libc=false
 581
 582 dnl Check for usual libc functions
 583 AC_CHECK_FUNCS([accept4 daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty memalign mkostemp mmap open_memstream newlocale openat pipe2 pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime uselocale])
 584 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir flockfile fsync getdelim getpid lfind lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy tfind timegm timespec_get strverscmp pathconf])
 585 AC_REPLACE_FUNCS([gettimeofday])
 586 AC_CHECK_FUNC(fdatasync,,
 587   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 588 ])
 589
 590 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 591
 592 dnl mingw64 implements those as static inline, not functions with C linkage
 593 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 594 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 595 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 596 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 597
 598 dnl C11 static_assert()
 599 AC_MSG_CHECKING([for static_assert in assert.h])
 600 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 601 static_assert(1, "The impossible happened.");
 602 ])], [
 603   AC_MSG_RESULT([yes])
 604   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 605 ], [
 606   AC_MSG_RESULT([no])
 607 ])
 608
 609 # Windows CE does not have strcoll()
 610 AC_FUNC_STRCOLL
 611
 612 dnl Check for non-standard system calls
 613 case "$SYS" in
 614   "linux")
 615     AC_CHECK_FUNCS([eventfd vmsplice sched_getaffinity recvmmsg memfd_create])
 616     ;;
 617   "mingw32")
 618     AC_CHECK_FUNCS([_lock_file])
 619     ;;
 620 esac
 621
 622 AH_BOTTOM([#include <vlc_fixups.h>])
 623
 624 dnl Check for struct pollfd
 625 AC_CHECK_TYPES([struct pollfd],,,
 626 [#include <sys/types.h>
 627 #if HAVE_POLL
 628 # include <poll.h>
 629 #elif defined (_WIN32)
 630 # include <winsock2.h>
 631 #endif
 632 ])
 633
 634 dnl Check for struct timespec
 635 AC_CHECK_TYPES([struct timespec],,,
 636 [#include <time.h>])
 637
 638 dnl Check for max_align_t
 639 AC_CHECK_TYPES([max_align_t],,,
 640 [#include <stddef.h>])
 641
 642 dnl Checks for socket stuff
 643 VLC_SAVE_FLAGS
 644 SOCKET_LIBS=""
 645 AC_SEARCH_LIBS(connect, [socket], [
 646   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 647     SOCKET_LIBS="$ac_cv_search_connect"
 648   ])
 649 ], [
 650   AS_IF([test "${SYS}" = "mingw32"], [
 651     SOCKET_LIBS="-lws2_32 -liphlpapi"
 652   ])
 653 ])
 654
 655 AC_SEARCH_LIBS([inet_pton], [nsl], [
 656  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 657     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 658   ])
 659 ],, [${SOCKET_LIBS}])
 660
 661 LIBS="${LIBS} ${SOCKET_LIBS}"
 662 AC_LINK_IFELSE([
 663     AC_LANG_PROGRAM([#ifdef _WIN32
 664         #include <ws2tcpip.h>
 665         #include <windows.h>
 666         # if _WIN32_WINNT < 0x600
 667         #  error Needs vista+
 668         # endif
 669         #else
 670         #include <sys/socket.h>
 671         #include <arpa/inet.h>
 672         #endif], [
 673         char dst[[sizeof(struct in_addr)]];
 674         inet_pton(AF_INET, "127.0.0.1", dst);
 675     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 676 AC_CHECK_TYPES([struct if_nameindex],,,[#include <net/if.h>])
 677 AC_CHECK_FUNCS([if_nameindex])
 678 VLC_RESTORE_FLAGS
 679 AC_SUBST([SOCKET_LIBS])
 680
 681 dnl Check for socklen_t
 682 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 683 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 684 ac_cv_type_socklen_t,
 685 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 686 [#include <sys/types.h>
 687 #ifdef _WIN32
 688 # include <winsock2.h>
 689 # include <ws2tcpip.h>
 690 #else
 691 # include <sys/socket.h>
 692 #endif]], [[socklen_t len; len = 0;]])],
 693 ac_cv_type_socklen_t=yes,
 694 ac_cv_type_socklen_t=no)])
 695 AS_IF([test "$ac_cv_type_socklen_t" = no],
 696  [AC_DEFINE(socklen_t, int)])
 697
 698 dnl Check for struct sockaddr_storage
 699 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 700 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 701 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 702   [AC_TRY_COMPILE(
 703     [#include <sys/types.h>
 704      #if defined( _WIN32 )
 705      # include <winsock2.h>
 706      #else
 707      # include <sys/socket.h>
 708      #endif], [struct sockaddr_storage addr;],
 709      ac_cv_struct_sockaddr_storage=yes,
 710      ac_cv_struct_sockaddr_storage=no)])
 711 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 712   AC_DEFINE(sockaddr_storage, sockaddr)
 713   AC_DEFINE(ss_family, sa_family)
 714 ])
 715
 716 dnl FreeBSD has a gnugetopt library for this:
 717 GNUGETOPT_LIBS=""
 718 AC_CHECK_FUNC(getopt_long,, [
 719   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 720     GNUGETOPT_LIBS="-lgnugetopt"
 721   ])
 722 ])
 723 AC_SUBST([GNUGETOPT_LIBS])
 724
 725 AC_CHECK_LIB([m], [cos], [
 726   LIBM="-lm"
 727 ], [
 728   LIBM=""
 729 ])
 730 AC_SUBST([LIBM])
 731
 732 AC_CHECK_LIB([m], [lrintf], [
 733   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 734   VLC_ADD_LIBS([skins2],[-lm])
 735 ])
 736 AC_CHECK_LIB([m], [nanf],
 737   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 738 )
 739 AC_CHECK_LIB([m], [sincos], [
 740   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 741 ], [
 742   AC_LIBOBJ([sincos])
 743 ])
 744
 745 AC_MSG_CHECKING([_Thread_local support])
 746 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
 747                    int main() {}])], [
 748     AC_MSG_RESULT([ok])
 749     AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
 750 ],[ AC_MSG_RESULT([no])])
 751
 752 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
 753 dnl check for its availability explicitely
 754 AC_CHECK_HEADERS([threads.h])
 755
 756 AC_CHECK_LIB([anl],[getaddrinfo_a],[
 757   AC_DEFINE(HAVE_LIBANL, 1, [Define to 1 if you have the anl library])
 758 ])
 759
 760 dnl Check for dynamic plugins
 761 LIBDL=""
 762 have_dynamic_objects="no"
 763 VLC_SAVE_FLAGS
 764 AC_SEARCH_LIBS(dlsym, [dl svld], [
 765   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 766     LIBDL="$ac_cv_search_dlsym"
 767   ])
 768   have_dynamic_objects="yes"
 769 ])
 770 VLC_RESTORE_FLAGS
 771
 772 # Windows
 773 AS_IF([test "${SYS}" = "mingw32"], [
 774   LIBDL=""
 775   have_dynamic_objects="yes" #assume we can use shared objects
 776 ])
 777
 778 AC_ARG_WITH([libfuzzer],
 779     AS_HELP_STRING([--with-libfuzzer=DIR],
 780         [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)]),
 781      [],
 782      [with_libfuzzer=no])
 783 AS_VAR_IF(with_libfuzzer, no, [], [
 784     enable_shared=no
 785     enable_static=yes
 786     enable_vlc=no
 787 ])
 788 AM_CONDITIONAL([HAVE_LIBFUZZER], [test "${with_libfuzzer}" != "no"])
 789
 790 AS_IF([test "${enable_shared}" = "no"], [
 791   have_dynamic_objects=no
 792 ])
 793 AM_CONDITIONAL([HAVE_DYNAMIC_PLUGINS], [test "${have_dynamic_objects}" != "no"])
 794
 795 AC_SUBST([LIBDL])
 796
 797 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 798   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 799     LIBRT="$ac_cv_search_clock_nanosleep"
 800   ])
 801 ], [
 802   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 803     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 804       LIBRT="$ac_cv_search_nanosleep"
 805     ])
 806   ])
 807 ])
 808 AC_SUBST([LIBRT])
 809
 810 dnl
 811 dnl Check for headers
 812 dnl
 813
 814 dnl  POSIX
 815 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 816 AC_CHECK_HEADERS([net/if.h], [], [],
 817 [
 818 #include <sys/types.h>
 819 #include <sys/socket.h>
 820 ])
 821 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 822 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 823
 824 dnl  BSD
 825 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
 826
 827 dnl  GNU/Linux
 828 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 829
 830 dnl  MacOS
 831 AC_CHECK_HEADERS([xlocale.h])
 832
 833 dnl Check if C++ headers define locale_t
 834 AC_LANG_PUSH(C++)
 835 AC_CACHE_CHECK([if C++ headers define locale_t],
 836   [ac_cv_cxx_locale_t],
 837   [ac_cv_cxx_locale_t=no
 838    AC_TRY_COMPILE([#include <locale>], [locale_t loc;],
 839                     [ac_cv_cxx_locale_t=yes])])
 840 if test "${ac_cv_cxx_locale_t}" != "no"; then
 841   AC_DEFINE(HAVE_CXX_LOCALE_T, 1, Define to 1 if C++ headers define locale_t)
 842 fi
 843 AC_LANG_POP(C++)
 844
 845 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 846 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 847 AC_CHECK_TYPE(ssize_t,, [
 848   AC_DEFINE(ssize_t, int)
 849 ])
 850
 851 dnl It seems that autoconf detects pkg-config only during the first
 852 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 853 dnl it is nested within a conditional block, so it was not working right.
 854 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 855 AC_ARG_VAR(PKG_CONFIG_PATH,
 856        [Paths where to find .pc not at the default location])
 857 PKG_PROG_PKG_CONFIG()
 858
 859 dnl On some OS we need static linking
 860 AS_IF([test -n "${PKG_CONFIG}" ],[
 861     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 862         PKG_CONFIG="${PKG_CONFIG} --static"
 863     ])
 864 ])
 865
 866
 867 dnl
 868 dnl Check for zlib.h and -lz if available
 869 dnl
 870 AC_CHECK_HEADERS([zlib.h], [ have_zlib=yes ], [ have_zlib=no ])
 871 AM_CONDITIONAL([HAVE_ZLIB], [ test "${have_zlib}" = "yes" ])
 872 if test "${have_zlib}" = "yes"
 873 then
 874   VLC_ADD_LIBS([sap],[-lz])
 875 fi
 876
 877
 878 dnl
 879 dnl Domain name i18n support via GNU libidn
 880 dnl
 881 PKG_CHECK_MODULES([IDN], [libidn], [
 882   have_libidn="yes"
 883   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 884 ], [
 885   have_libidn="no"
 886 ])
 887
 888
 889 dnl Check for dbus
 890 AC_ARG_ENABLE([dbus],
 891   AS_HELP_STRING([--enable-dbus],
 892     [compile D-Bus message bus support (default enabled)]))
 893 have_dbus="no"
 894 AS_IF([test "${enable_dbus}" != "no"], [
 895   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 896     have_dbus="yes"
 897   ], [
 898     AS_IF([test -n "${enable_dbus}"], [
 899       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 900     ], [
 901       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 902     ])
 903   ])
 904 ])
 905 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 906
 907
 908 dnl Check for systemd
 909 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 910   have_systemd="yes"
 911 ], [
 912   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 913 ])
 914 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 915
 916
 917 EXTEND_HELP_STRING([Optimization options:])
 918 dnl
 919 dnl  Compiler warnings
 920 dnl
 921
 922 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security -Wduplicated-branches -Wduplicated-cond], [CFLAGS])
 923 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security -Wduplicated-branches -Wduplicated-cond], [CXXFLAGS])
 924
 925 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local -Wmultistatement-macros], [CFLAGS])
 926 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
 927
 928 dnl
 929 dnl  Debugging mode
 930 dnl
 931 AC_ARG_ENABLE([debug],
 932   AS_HELP_STRING([--enable-debug],
 933     [build with run-time assertions (default disabled)]),,
 934   [enable_debug="no"])
 935 AH_TEMPLATE(NDEBUG,
 936             [Define to 1 if debug code should NOT be compiled])
 937 AS_IF([test "${enable_debug}" != "no"], [
 938   AC_CHECK_HEADERS([valgrind/valgrind.h])
 939 ], [
 940   AC_DEFINE(NDEBUG)
 941 ])
 942
 943 dnl
 944 dnl  Profiling
 945 dnl
 946 AC_ARG_ENABLE([gprof],
 947   AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)]),,
 948   [enable_gprof="no"])
 949 AS_IF([test "${enable_gprof}" != "no"], [
 950   CFLAGS="${CFLAGS} -pg"
 951   CXXFLAGS="${CXXFLAGS} -pg"
 952   OBJCFLAGS="${OBJCFLAGS} -pg"
 953   LDFLAGS="${LDFLAGS} -pg"
 954 ])
 955
 956 AC_ARG_ENABLE([cprof],
 957   AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)]),,
 958   [enable_cprof="no"])
 959 AS_IF([test "${enable_gprof}" != "no"], [
 960   CFLAGS="${CFLAGS} -finstrument-functions"
 961   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 962   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 963   LDFLAGS="${LDFLAGS} -finstrument-functions"
 964 ])
 965
 966 dnl
 967 dnl  Test coverage
 968 dnl
 969 AC_ARG_ENABLE([coverage],
 970   AS_HELP_STRING([--enable-coverage],
 971     [build for test coverage (default disabled)]),,
 972   [enable_coverage="no"])
 973 AS_IF([test "${enable_coverage}" != "no"], [
 974   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 975   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 976   LDFLAGS="-lgcov ${LDFLAGS}"
 977 ])
 978
 979 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 980   VLC_SAVE_FLAGS
 981   CFLAGS="${CFLAGS} -fvisibility=hidden"
 982   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 983   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 984   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 985                  [ac_cv_c_visibility_hidden], [
 986     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 987       ac_cv_c_visibility_hidden=yes
 988     ], [
 989       ac_cv_c_visibility_hidden=no
 990     ])
 991   ])
 992   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
 993 ])
 994
 995 dnl
 996 dnl Sanitizer flags
 997 dnl
 998 AC_ARG_WITH([sanitizer],
 999     AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1000         [build with sanitizer flags (default disabled)]),
1001      [],
1002      [with_sanitizer=no])
1003
1004 AS_VAR_IF(with_sanitizer, no, [], [
1005     AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1006         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1007         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1008         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1009     ], [
1010         AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1011     ])
1012     AX_APPEND_FLAG([-g])
1013     AX_APPEND_FLAG([-g], [CXXFLAGS])
1014
1015     AS_IF([test -z "${with_sanitizer##*address*}" ], [
1016        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer -fsanitize=pointer-compare -fsanitize=pointer-subtract])
1017        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer -fsanitize=pointer-compare -fsanitize=pointer-subtract], [CXXFLAGS])
1018     ])
1019     AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1020         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1021         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1022     ])
1023     AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1024         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1025         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1026     ])
1027 ])
1028
1029 dnl
1030 dnl  Enable/disable optimizations
1031 dnl
1032 AC_ARG_ENABLE([optimizations],
1033   AS_HELP_STRING([--disable-optimizations],
1034     [disable compiler optimizations (default enabled)]),,
1035   [enable_optimizations="yes"])
1036
1037 dnl Check for various optimization flags
1038 AS_IF([test "${enable_optimizations}" != "no"], [
1039
1040   dnl -O3 only in production builds
1041   AS_IF([test "${enable_debug}" = "no"], [
1042     VLC_SAVE_FLAGS
1043     CFLAGS="${CFLAGS} -O3"
1044     CXXFLAGS="${CXXFLAGS} -O3"
1045     OBJCFLAGS="${OBJCFLAGS} -O3"
1046     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1047       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1048         ac_cv_c_o3=yes
1049       ], [
1050         ac_cv_c_o3=no
1051       ])
1052     ])
1053     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1054   ])
1055
1056   dnl Check for fast maths
1057   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1058   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1059
1060 AH_BOTTOM([
1061 #if defined(_MSC_VER) && !defined(__clang__)
1062 # pragma fenv_access(off)
1063 # pragma fp_contract(on)
1064 #elif defined(__GNUC__)
1065 /* Not supported so far */
1066 #else
1067 # pragma STDC FENV_ACCESS OFF
1068 # pragma STDC FP_CONTRACT ON
1069 #endif
1070 ])
1071
1072   dnl Check for -funroll-loops
1073   VLC_SAVE_FLAGS
1074   CFLAGS="${CFLAGS} -funroll-loops"
1075   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1076   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1077   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1078     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1079       ac_cv_c_unroll_loops=yes
1080     ], [
1081       ac_cv_c_unroll_loops=no
1082     ])
1083   ])
1084   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1085
1086   AS_IF([test "$enable_debug" = "no"], [
1087     dnl Check for -fomit-frame-pointer
1088     VLC_SAVE_FLAGS
1089     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1090     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1091     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1092     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1093       [ac_cv_c_omit_frame_pointer], [
1094       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1095         ac_cv_c_omit_frame_pointer=yes
1096       ], [
1097         ac_cv_c_omit_frame_pointer=no
1098       ])
1099     ])
1100     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1101   ])
1102
1103 ])
1104
1105 AC_ARG_ENABLE([ssp],
1106   AS_HELP_STRING([--disable-ssp],
1107   [disable stack smashing protection (default enabled for optimized builds)]), [],
1108   [enable_ssp="yes"])
1109
1110 AS_IF([test "${enable_ssp}" != "no" -a "${enable_optimizations}" != "no"], [
1111   VLC_SAVE_FLAGS
1112   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1113   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1114   dnl Win32 requires linking to ssp for stack-protection
1115   AS_IF([test "${SYS}" = "mingw32"], [
1116       LDFLAGS="${LDFLAGS} -lssp"
1117       AC_CACHE_CHECK([if linker supports stack protectors], [ac_cv_ld_ssp], [
1118         AC_TRY_LINK([#include <stdio.h>],[char buf[100]; fgets(buf, sizeof(buf), stdin);], [
1119           ac_cv_ld_ssp="yes"
1120         ], [
1121           ac_cv_ld_ssp="no"
1122         ])
1123       ])
1124       AS_IF([test "${ac_cv_ld_ssp}" = "no"], [VLC_RESTORE_FLAGS])
1125   ])
1126 ])
1127
1128 AS_IF([test "${SYS}" = "mingw32"], [
1129     dnl library for BCrypt APIs
1130     AS_IF([test "${vlc_winstore_app}" = 1],
1131           [LDFLAGS="${LDFLAGS} -lbcrypt"])
1132 ])
1133
1134 VLC_SAVE_FLAGS
1135 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1136 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1137   AC_TRY_LINK([],, [
1138     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1139   ], [
1140     ac_cv_ld_bsymbolic=""
1141   ])
1142 ])
1143 VLC_RESTORE_FLAGS
1144 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1145 AC_SUBST([SYMBOLIC_LDFLAGS])
1146
1147 VLC_SAVE_FLAGS
1148 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1149 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1150   AC_TRY_LINK([],, [
1151     ac_cv_ld_z_defs="yes"
1152   ], [
1153     ac_cv_ld_z_defs="no"
1154   ])
1155 ])
1156 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1157
1158 dnl Check for __attribute__((packed))
1159 AC_CACHE_CHECK([for __attribute__((packed))],
1160   [ac_cv_c_attribute_packed],
1161   [ac_cv_c_attribute_packed=no
1162    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1163                     [ac_cv_c_attribute_packed=yes])])
1164 if test "${ac_cv_c_attribute_packed}" != "no"; then
1165   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1166 fi
1167
1168 dnl
1169 dnl  Check the CPU
1170 dnl
1171 case "${host_cpu}" in
1172   "")
1173     ARCH=unknown
1174     ;;
1175   armv*)
1176     ARCH="arm"
1177     host_cpu="arm"
1178     ;;
1179   *)
1180     ARCH="${host_cpu}"
1181     ;;
1182 esac
1183
1184 dnl Check for backtrace() support
1185 AC_CHECK_HEADERS([execinfo.h])
1186 AC_CHECK_FUNCS([backtrace])
1187
1188 dnl
1189 dnl  default modules
1190 dnl
1191 ALIASES="${ALIASES} cvlc rvlc"
1192
1193 dnl
1194 dnl  Accelerated modules
1195 dnl
1196
1197 dnl  Check for fully working MMX intrinsics
1198 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1199 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1200 AC_ARG_ENABLE([mmx],
1201   AS_HELP_STRING([--disable-mmx],
1202     [disable MMX optimizations (default auto)]),,[
1203   case "${host_cpu}" in
1204     i?86|x86_64)
1205       enable_mmx="yes"
1206       ;;
1207     *)
1208       enable_mmx="no"
1209       ;;
1210   esac
1211 ])
1212 have_mmx="no"
1213 have_mmxext="no"
1214 AS_IF([test "${enable_mmx}" != "no"], [
1215   ARCH="${ARCH} mmx"
1216   VLC_SAVE_FLAGS
1217   CFLAGS="${CFLAGS} -mmmx"
1218   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1219     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1220 [#include <mmintrin.h>
1221 #include <stdint.h>
1222 uint64_t frobzor;]], [
1223 [__m64 a, b, c;
1224 a = b = c = (__m64)frobzor;
1225 a = _mm_slli_pi16(a, 3);
1226 a = _mm_adds_pi16(a, b);
1227 c = _mm_srli_pi16(c, 8);
1228 c = _mm_slli_pi16(c, 3);
1229 b = _mm_adds_pi16(b, c);
1230 a = _mm_unpacklo_pi8(a, b);
1231 frobzor = (uint64_t)a;]])], [
1232       ac_cv_c_mmx_intrinsics=yes
1233     ], [
1234       ac_cv_c_mmx_intrinsics=no
1235     ])
1236   ])
1237   VLC_RESTORE_FLAGS
1238   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1239     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1240   ])
1241
1242   VLC_SAVE_FLAGS
1243   CFLAGS="${CFLAGS} -mmmx"
1244   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1245     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1246 void *p;
1247 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1248 ]])
1249     ], [
1250       ac_cv_mmx_inline=yes
1251     ], [
1252       ac_cv_mmx_inline=no
1253     ])
1254   ])
1255   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1256     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1257     have_mmx="yes"
1258   ])
1259
1260   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1261                  [ac_cv_mmxext_inline], [
1262     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1263 void *p;
1264 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1265 ]])
1266     ], [
1267       ac_cv_mmxext_inline=yes
1268     ], [
1269       ac_cv_mmxext_inline=no
1270     ])
1271   ])
1272   VLC_RESTORE_FLAGS
1273   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1274     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1275     have_mmxext="yes"
1276   ])
1277 ])
1278 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1279 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1280
1281 dnl  Check for fully workin SSE2 intrinsics
1282 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1283 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1284 AC_ARG_ENABLE([sse],
1285   AS_HELP_STRING([--disable-sse],
1286     [disable SSE (1-4) optimizations (default auto)]),, [
1287   case "${host_cpu}" in
1288     i?86|x86_64)
1289       enable_sse=yes
1290       ;;
1291     *)
1292       enable_sse=no
1293       ;;
1294   esac
1295 ])
1296 have_sse2="no"
1297 AS_IF([test "${enable_sse}" != "no"], [
1298   ARCH="${ARCH} sse sse2"
1299
1300   VLC_SAVE_FLAGS
1301   CFLAGS="${CFLAGS} -msse2"
1302   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1303     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1304 [#include <emmintrin.h>
1305 #include <stdint.h>
1306 uint64_t frobzor;]], [
1307 [__m128i a, b, c;
1308 a = b = c = _mm_set1_epi64((__m64)frobzor);
1309 a = _mm_slli_epi16(a, 3);
1310 a = _mm_adds_epi16(a, b);
1311 c = _mm_srli_epi16(c, 8);
1312 c = _mm_slli_epi16(c, 3);
1313 b = _mm_adds_epi16(b, c);
1314 a = _mm_unpacklo_epi8(a, b);
1315 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1316       ac_cv_c_sse2_intrinsics=yes
1317     ], [
1318       ac_cv_c_sse2_intrinsics=no
1319     ])
1320   ])
1321   VLC_RESTORE_FLAGS
1322   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1323     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1324   ])
1325
1326   VLC_SAVE_FLAGS
1327   CFLAGS="${CFLAGS} -msse"
1328   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1329     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1330 void *p;
1331 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1332 ]])
1333     ], [
1334       ac_cv_sse_inline=yes
1335     ], [
1336       ac_cv_sse_inline=no
1337     ])
1338   ])
1339
1340   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1341     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1342   ])
1343
1344   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1345     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1346 void *p;
1347 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1348 ]])
1349     ], [
1350       ac_cv_sse2_inline=yes
1351     ], [
1352       ac_cv_sse2_inline=no
1353     ])
1354   ])
1355   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1356     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1357     have_sse2="yes"
1358   ])
1359
1360   # SSE3
1361   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1362     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1363 void *p;
1364 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1365 ]])
1366     ], [
1367       ac_cv_sse3_inline=yes
1368     ], [
1369       ac_cv_sse3_inline=no
1370     ])
1371   ])
1372
1373   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1374     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1375   # SSSE3
1376   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1377     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1378 void *p;
1379 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1380 ]])
1381     ], [
1382       ac_cv_ssse3_inline=yes
1383     ], [
1384       ac_cv_ssse3_inline=no
1385     ])
1386   ])
1387
1388   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1389     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1390
1391   # SSE4.1
1392   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1393                  [ac_cv_sse4_1_inline], [
1394     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1395 void *p;
1396 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1397 ]])
1398     ], [
1399       ac_cv_sse4_1_inline=yes
1400     ], [
1401       ac_cv_sse4_1_inline=no
1402     ])
1403   ])
1404
1405   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1406     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1407
1408   # SSE4.2
1409   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1410                  [ac_cv_sse4_2_inline], [
1411     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1412 void *p;
1413 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1414 ]])
1415     ], [
1416       ac_cv_sse4_2_inline=yes
1417     ], [
1418       ac_cv_sse4_2_inline=no
1419     ])
1420   ])
1421
1422   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1423     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1424
1425   # SSE4A
1426   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1427     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1428 void *p;
1429 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1430 ]])
1431     ], [
1432       ac_cv_sse4a_inline=yes
1433     ], [
1434       ac_cv_sse4a_inline=no
1435     ])
1436   ])
1437   VLC_RESTORE_FLAGS
1438   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1439     AC_DEFINE([CAN_COMPILE_SSE4A], [1], [Define to 1 if SSE4A inline assembly is available.]) ])
1440 ])
1441 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1442
1443 VLC_SAVE_FLAGS
1444 CFLAGS="${CFLAGS} -mmmx"
1445 have_3dnow="no"
1446 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1447   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1448 void *p;
1449 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1450 ]])
1451   ], [
1452     ac_cv_3dnow_inline=yes
1453   ], [
1454     ac_cv_3dnow_inline=no
1455   ])
1456 ])
1457 VLC_RESTORE_FLAGS
1458 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1459   AC_DEFINE([CAN_COMPILE_3DNOW], 1,
1460             [Define to 1 if 3D Now! inline assembly is available.])
1461   have_3dnow="yes"
1462 ])
1463 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1464
1465
1466 AC_ARG_ENABLE([neon],
1467   AS_HELP_STRING([--disable-neon],
1468     [disable NEON optimizations (default auto)]),, [
1469   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1470 ])
1471 AS_IF([test "${enable_neon}" != "no"], [
1472   VLC_SAVE_FLAGS
1473   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1474   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1475     AC_COMPILE_IFELSE([
1476       AC_LANG_PROGRAM(,[[
1477 asm volatile("vqmovun.s64 d0, q1":::"d0");
1478 ]])
1479     ], [
1480       ac_cv_arm_neon="yes"
1481     ], [
1482       ac_cv_arm_neon="no"
1483     ])
1484   ])
1485   VLC_RESTORE_FLAGS
1486 ])
1487 AM_CONDITIONAL([HAVE_NEON], [test "${ac_cv_arm_neon}" = "yes"])
1488
1489 AC_ARG_ENABLE([arm64],
1490   AS_HELP_STRING([--disable-arm64],
1491     [disable arm 64-bit optimizations (default auto)]),, [
1492   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1493 ])
1494 AS_IF([test "${enable_arm64}" != "no"], [
1495   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1496     AC_COMPILE_IFELSE([
1497       AC_LANG_PROGRAM(,[[
1498 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1499 ]])
1500     ], [
1501       ac_cv_arm64="yes"
1502     ], [
1503       ac_cv_arm64="no"
1504     ])
1505   ])
1506 ])
1507 AM_CONDITIONAL([HAVE_ARM64], [test "${ac_cv_arm64}" = "yes"])
1508
1509
1510 AC_ARG_ENABLE([altivec],
1511   AS_HELP_STRING([--disable-altivec],
1512     [disable AltiVec optimizations (default auto)]),, [
1513   AS_CASE("${host_cpu}", [powerpc*],
1514         [enable_altivec=yes], [enable_altivec=no])
1515 ])
1516 have_altivec="no"
1517 ALTIVEC_CFLAGS=""
1518 AS_IF([test "${enable_altivec}" = "yes"], [
1519   ARCH="${ARCH} altivec";
1520   VLC_SAVE_FLAGS
1521   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1522     [ac_cv_altivec_inline],
1523     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1524          ac_cv_altivec_inline="yes",
1525          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1526           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1527             [ac_cv_altivec_inline="-Wa,-maltivec"],
1528             ac_cv_altivec_inline=no)
1529          ])])
1530   VLC_RESTORE_FLAGS
1531   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1532     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1533               [Define to 1 if AltiVec inline assembly is available.])
1534     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1535       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1536       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1537     ])
1538     have_altivec="yes"
1539   ])
1540
1541   VLC_SAVE_FLAGS
1542   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1543   [ac_cv_c_altivec], [
1544     CFLAGS="${CFLAGS} -maltivec"
1545     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1546 [#include <altivec.h>]], [
1547 [vec_ld(0, (unsigned char *)0);]])], [
1548       ac_cv_c_altivec="-maltivec"
1549     ], [
1550       ac_cv_c_altivec="no"
1551     ])
1552   ])
1553   VLC_RESTORE_FLAGS
1554   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1555     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1556     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1557     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1558     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1559     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1560     have_altivec="yes"
1561   ])
1562   AC_CHECK_HEADERS([altivec.h])
1563
1564   VLC_SAVE_FLAGS
1565   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1566   AC_CACHE_CHECK([if linker needs -framework vecLib],
1567     [ac_cv_ld_altivec],
1568     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1569   VLC_RESTORE_FLAGS
1570   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1571     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1572   ])
1573 ])
1574 AC_SUBST([ALTIVEC_CFLAGS])
1575 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1576
1577 dnl
1578 dnl  Memory usage
1579 dnl
1580 AC_ARG_ENABLE([optimize-memory],
1581   AS_HELP_STRING([--enable-optimize-memory],
1582     [optimize memory usage over performance]))
1583 if test "${enable_optimize_memory}" = "yes"; then
1584   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1585 fi
1586
1587 dnl
1588 dnl Allow running as root (useful for people running on embedded platforms)
1589 dnl
1590 AC_ARG_ENABLE([run-as-root],
1591   AS_HELP_STRING([--enable-run-as-root],
1592     [allow running VLC as root (default disabled)]))
1593 AS_IF([test "${enable_run_as_root}" = "yes"],[
1594     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1595               [Define to 1 to allow running VLC as root (uid 0).])
1596 ])
1597
1598 dnl
1599 dnl Stream output
1600 dnl
1601 AC_ARG_ENABLE([sout],
1602   AS_HELP_STRING([--disable-sout],
1603     [disable streaming output (default enabled)]))
1604 AS_IF([test "${enable_sout}" != "no"], [
1605   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1606 ])
1607 AM_CONDITIONAL([ENABLE_SOUT], [test "${enable_sout}" != "no"])
1608
1609 dnl Lua modules
1610 AC_ARG_ENABLE([lua],
1611   AS_HELP_STRING([--disable-lua],
1612     [disable LUA scripting support (default enabled)]))
1613 if test "${enable_lua}" != "no"
1614 then
1615   PKG_CHECK_MODULES(LUA, lua5.2,
1616     [ have_lua=yes ],
1617     [
1618     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1619
1620     PKG_CHECK_MODULES(LUA, lua5.1,
1621       [ have_lua=yes ],
1622       [
1623       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1624       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1625         [ have_lua=yes ],
1626         [
1627           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1628           have_lua=yes
1629           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1630             [],
1631             [ have_lua=no ] )
1632           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1633             [LUA_LIBS="-llua5.2"],
1634           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1635             [LUA_LIBS="-llua5.1"],
1636             AC_CHECK_LIB( lua51 , luaL_newstate,
1637               [LUA_LIBS="-llua51"],
1638               AC_CHECK_LIB( lua , luaL_newstate,
1639                 [LUA_LIBS="-llua"],
1640                 [ have_lua=no
1641                 ], [-lm])
1642             )))
1643         ])
1644       ])
1645     ])
1646   if test "x${have_lua}" != "xyes" ;  then
1647       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1648   fi
1649   AC_ARG_VAR([LUAC], [LUA byte compiler])
1650   AS_IF([test -z "$LUAC"], [
1651      AC_CHECK_TOOL(LUAC, [luac], [false])
1652   ])
1653   AS_IF([test "${LUAC}" = "false"], [
1654     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1655   ])
1656   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1657     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1658   ])
1659 fi
1660 AM_CONDITIONAL([BUILD_LUA], [test "${have_lua}" = "yes"])
1661
1662
1663 dnl
1664 dnl VideoLAN manager
1665 dnl
1666 AC_ARG_ENABLE([vlm],
1667   AS_HELP_STRING([--disable-vlm],
1668     [disable the stream manager (default enabled)]),,
1669   [enable_vlm="${enable_sout}"])
1670 AS_IF([test "${enable_vlm}" != "no"], [
1671   AS_IF([test "${enable_sout}" = "no"], [
1672     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1673   ])
1674   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1675 ])
1676 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1677
1678
1679 dnl
1680 dnl Addons manager storage and repositories modules
1681 dnl
1682 AC_ARG_ENABLE([addonmanagermodules],
1683   AS_HELP_STRING([--disable-addonmanagermodules],
1684     [disable the addons manager modules (default enabled)]))
1685 if test "${enable_addonmanagermodules}" != "no"
1686 then
1687   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1688 fi
1689 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1690
1691
1692 dnl
1693 dnl  Input plugins
1694 dnl
1695
1696 EXTEND_HELP_STRING([Input plugins:])
1697
1698 dnl
1699 dnl  libarchive access module
1700 dnl
1701 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1702
1703 dnl
1704 dnl  live555 input
1705 dnl
1706 AC_ARG_ENABLE([live555],
1707   AS_HELP_STRING([--enable-live555],
1708     [enable RTSP input through live555 (default enabled)]))
1709
1710 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1711   PKG_CHECK_MODULES(LIVE555, live555, [
1712     VLC_ADD_PLUGIN([live555])
1713     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1714     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1715   ], [
1716     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1717
1718     AC_LANG_PUSH(C++)
1719     VLC_SAVE_FLAGS
1720
1721     dnl detect include paths
1722     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1723       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1724     ], [
1725       AS_IF([test "${SYS}" != "os2"], [
1726         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1727         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1728       ], [
1729         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1730         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1731         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1732       ])
1733     ])
1734
1735     dnl CPP Flags
1736     AS_IF([test "${SYS}" = "solaris"], [
1737       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1738     ])
1739     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1740     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1741
1742     dnl version check
1743     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1744       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1745 [#include <liveMedia_version.hh>
1746 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1747 # error BOOM
1748 #endif]])
1749       ], [
1750         ac_cv_live555="yes"
1751       ], [
1752         ac_cv_live555="no"
1753       ])
1754     ])
1755
1756     AS_IF([test "$ac_cv_live555" = "no"], [
1757       AC_MSG_WARN([live555 is missing or its installed version is too old:
1758 Version 2011.12.23 or later is required to proceed.
1759 You can get an updated one from http://www.live555.com/liveMedia .])
1760       AS_IF([test -n "${enable_live555}"], [
1761         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1762       ])
1763     ], [
1764       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1765       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1766       AS_IF([test "${SYS}" = "mingw32"], [
1767         # add ws2_32 for closesocket, select, recv
1768         other_libs="$other_libs -lws2_32"
1769       ])
1770
1771       dnl We need to check for pic because live555 don't provide shared libs
1772       dnl and we want to build a plugins so we need -fPIC on some arch.
1773       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1774       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1775       AC_CHECK_LIB([liveMedia_pic], [main], [
1776         VLC_ADD_PLUGIN([live555])
1777         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1778       ],[
1779         AC_CHECK_LIB([liveMedia], [main], [
1780           VLC_ADD_PLUGIN([live555])
1781           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1782         ],[],[${other_libs}])
1783       ],[${other_libs_pic}])
1784     ])
1785     VLC_RESTORE_FLAGS
1786     AC_LANG_POP(C++)
1787   ])
1788 ])
1789
1790 dnl
1791 dnl IIDC and DV FireWire input modules
1792 dnl
1793 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1794 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1795
1796 dnl
1797 dnl - linsys modules: access module check for libzvbi
1798 dnl
1799 AC_ARG_ENABLE([linsys],
1800   AS_HELP_STRING([--enable-linsys],
1801     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)]))
1802 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1803   VLC_ADD_PLUGIN([linsys_hdsdi])
1804   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1805     VLC_ADD_PLUGIN([linsys_sdi])
1806   ], [
1807     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1808   ])
1809 ])
1810
1811 dnl
1812 dnl dvdread module: check for libdvdread
1813 dnl
1814 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1815
1816 dnl
1817 dnl libdvdnav plugin
1818 dnl
1819 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1820 AS_IF([test "${enable_dvdnav}" != "no"], [
1821   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1822     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1823       AC_MSG_RESULT(yes)
1824       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1825       ],[
1826       AC_MSG_RESULT(no)
1827     ])
1828 ])
1829
1830 dnl
1831 dnl  Blu-ray Disc Support with libbluray
1832 dnl
1833 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1834
1835 dnl
1836 dnl  OpenCV wrapper and example filters
1837 dnl
1838 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1839
1840
1841 dnl
1842 dnl  libsmbclient plugin
1843 dnl
1844 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smbc], [smbclient], (SMB/CIFS support), [auto])
1845
1846 dnl
1847 dnl  liBDSM access module
1848 dnl
1849 AM_CONDITIONAL([HAVE_DSM], [test "$AS_TR_SH(with_dsm)" = "yes"])
1850 PKG_WITH_MODULES([DSM], [libdsm >= 0.2.0], [
1851        VLC_ADD_PLUGIN([dsm])
1852        VLC_ADD_CFLAGS([dsm], [$DSM_CFLAGS])
1853        VLC_ADD_LIBS([dsm], [$DSM_LIBS])
1854        have_dsm="yes"
1855    ],,[libdsm SMB/CIFS access/sd module], [auto])
1856 AM_CONDITIONAL([HAVE_DSM], [test "${have_dsm}" = "yes"])
1857
1858 dnl
1859 dnl sftp access support
1860 dnl
1861 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1862
1863 dnl
1864 dnl nfs access support
1865 dnl
1866 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1867
1868 dnl
1869 dnl smb2 access support
1870 dnl
1871 PKG_ENABLE_MODULES_VLC([SMB2], [smb2], [libsmb2 >= 2.0.0], (support smb2 protocol via libsmb2), [auto])
1872
1873 dnl
1874 dnl  Video4Linux 2
1875 dnl
1876 AC_ARG_ENABLE([v4l2], AS_HELP_STRING([--disable-v4l2],
1877   [disable Video4Linux version 2 (default auto)]))
1878 have_v4l2="no"
1879 AS_IF([test "$enable_v4l2" != "no"], [
1880   AC_CHECK_HEADERS([linux/videodev2.h], [
1881     have_v4l2="yes"
1882   ])
1883 ])
1884 AM_CONDITIONAL([HAVE_V4L2], [test "${have_v4l2}" != "no"])
1885
1886 dnl
1887 dnl special access module for Blackmagic SDI cards
1888 dnl
1889 AC_ARG_ENABLE([decklink],
1890   AS_HELP_STRING([--disable-decklink],
1891     [disable Blackmagic DeckLink SDI input (default auto)]))
1892 AC_ARG_WITH([decklink_sdk],
1893   AS_HELP_STRING([--with-decklink-sdk=DIR],
1894     [location of Blackmagic DeckLink SDI SDK]))
1895 have_decklink=no
1896 if test "${enable_decklink}" != "no"
1897 then
1898   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1899   then
1900     VLC_ADD_CPPFLAGS([decklink decklinkoutput stream_out_sdi],[-I${with_decklink_sdk}/include])
1901   fi
1902   VLC_SAVE_FLAGS
1903   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1904   AC_LANG_PUSH([C++])
1905   AC_CHECK_HEADERS([DeckLinkAPIDispatch.cpp], [
1906       have_decklink=yes
1907       AS_IF([test "${SYS}" = "darwin"], [
1908         VLC_ADD_LIBS([decklink decklinkoutput],[-Wl,-framework,CoreFoundation])
1909       ])
1910   ], [
1911       AS_IF([test "${enable_decklink}" = "yes"], [
1912         AC_MSG_ERROR([Blackmagic DeckLink SDI include files not found!])
1913       ], [
1914         AC_MSG_WARN([Blackmagic DeckLink SDI include files not found, decklink disabled])
1915       ])
1916   ])
1917   AC_LANG_POP([C++])
1918   VLC_RESTORE_FLAGS
1919 fi
1920 AM_CONDITIONAL([HAVE_DECKLINK], [ test "${have_decklink}" != "no" ])
1921
1922
1923 dnl
1924 dnl  Built-in CD-DA and VCD module
1925 dnl
1926 AC_ARG_ENABLE([vcd],
1927   AS_HELP_STRING([--disable-vcd],
1928     [disable built-in VCD and CD-DA support (default enabled)]))
1929
1930 AC_ARG_ENABLE([libcddb],
1931   AS_HELP_STRING([--disable-libcddb],
1932     [disable CDDB for Audio CD (default enabled)]))
1933
1934 if test "${enable_vcd}" != "no"
1935 then
1936   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1937   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1938     AC_MSG_RESULT(yes)
1939     VLC_ADD_PLUGIN([vcd cdda])
1940   ],[
1941     AC_MSG_RESULT(no)
1942   ])
1943
1944   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1945   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1946     AC_MSG_RESULT(yes)
1947     VLC_ADD_PLUGIN([vcd cdda])
1948     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1949   ],[
1950     AC_MSG_RESULT(no)
1951   ])
1952
1953   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1954   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1955     AC_MSG_RESULT(yes)
1956     VLC_ADD_PLUGIN([vcd cdda])
1957     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1958   ],[
1959     AC_MSG_RESULT(no)
1960   ])
1961
1962   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1963   then
1964     VLC_ADD_PLUGIN([vcd cdda])
1965   fi
1966
1967   if test "$enable_libcddb" != "no"; then
1968     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1969       HAVE_LIBCDDB=yes
1970       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1971       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1972       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1973       ],:
1974       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1975       HAVE_LIBCDDB=no])
1976   fi
1977 fi
1978
1979 dnl
1980 dnl Linux DVB
1981 dnl
1982 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1983   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1984 [#include <linux/dvb/version.h>
1985 #if (DVB_API_VERSION < 5)
1986 # error Linux DVB API v3.2 and older are not supported.
1987 #endif
1988 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1989 # error Linux DVB API v5.0 is unsupported. Please update.
1990 #endif
1991 ]])], [
1992   ac_cv_linux_dvb_5_1=yes
1993 ], [
1994   ac_cv_linux_dvb_5_1=no
1995 ])])
1996 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1997
1998 dnl
1999 dnl  Screen capture module
2000 dnl
2001 AC_ARG_ENABLE([screen],
2002   AS_HELP_STRING([--enable-screen],
2003     [disable screen capture (default enabled)]))
2004 if test "${enable_screen}" != "no"; then
2005   if test "${SYS}" = "darwin"; then
2006     AC_CHECK_HEADERS([ApplicationServices/ApplicationServices.h], [
2007       VLC_ADD_PLUGIN([screen])
2008     ])
2009   fi
2010 fi
2011 AM_CONDITIONAL([HAVE_MAC_SCREEN], [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
2012
2013 dnl
2014 dnl  VNC/RFB access module
2015 dnl
2016 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
2017
2018 dnl  RDP/Remote Desktop access module
2019 dnl
2020 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
2021
2022 dnl
2023 dnl QTKit
2024 AC_ARG_ENABLE([macosx-qtkit],
2025   AS_HELP_STRING([--enable-macosx-qtkit], [Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)]))
2026 if test "x${enable_macosx_qtkit}" != "xno" &&
2027   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2028 then
2029   AC_LANG_PUSH([Objective C])
2030   AC_CHECK_HEADERS([QTKit/QTKit.h], [
2031       VLC_ADD_PLUGIN([access_qtsound])
2032     ])
2033   AC_LANG_POP([Objective C])
2034 fi
2035
2036 dnl
2037 dnl AVFoundation
2038 AC_SUBST([have_avfoundation], ["no"])
2039 AC_ARG_ENABLE([macosx-avfoundation],
2040   AS_HELP_STRING([--enable-macosx-avfoundation], [Mac OS X avcapture (video) module (default enabled on Mac OS X)]))
2041 if test "x${enable_macosx_avfoundation}" != "xno" &&
2042   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2043 then
2044   SAVED_LIBS="${LIBS}"
2045   LIBS="-framework AVFoundation"
2046   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2047   LIBS="${SAVED_LIBS}"
2048   if test "${have_avfoundation}" != "no"
2049   then
2050     VLC_ADD_PLUGIN([avcapture])
2051   fi
2052 fi
2053 AM_CONDITIONAL([HAVE_AVFOUNDATION], [test "${have_avfoundation}" != "no"])
2054
2055 dnl
2056 dnl  DCP plugin (using asdcplib)
2057 dnl
2058 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2059 AM_CONDITIONAL([HAVE_ASDCP], [test "${have_asdcp}" = "yes"])
2060
2061 dnl
2062 dnl  Demux plugins
2063 dnl
2064
2065 EXTEND_HELP_STRING([Mux/Demux plugins:])
2066
2067 dnl
2068 dnl  libdvbpsi check for ts mux/demux
2069 dnl
2070 have_dvbpsi="no"
2071 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2072 AM_CONDITIONAL([HAVE_DVBPSI], [test "${have_dvbpsi}" = "yes"])
2073
2074
2075 dnl
2076 dnl  GME demux plugin
2077 dnl
2078 AC_ARG_ENABLE([gme],
2079   AS_HELP_STRING([--enable-gme],
2080     [use Game Music Emu (default auto)]))
2081 AS_IF([test "${enable_gme}" != "no"], [
2082   AC_CHECK_HEADER([gme/gme.h], [
2083     AC_CHECK_LIB([gme], [gme_identify_header], [
2084       VLC_ADD_PLUGIN([gme])
2085     ], [
2086       AC_CHECK_LIB([gme], [gme_identify_extension], [
2087          VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2088          VLC_ADD_PLUGIN([gme])
2089       ],, [-lstdc++ $LIBM])
2090     ])
2091     VLC_ADD_LIBS([gme], [-lgme])
2092   ], [
2093     AS_IF([test "x${enable_gme}" != "x"], [
2094       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2095     ])
2096   ])
2097 ])
2098
2099
2100 dnl
2101 dnl  SIDPlay plugin
2102 dnl
2103 AC_ARG_ENABLE([sid],
2104     AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)]))
2105 AS_IF([test "${enable_sid}" != "no"], [
2106     PKG_CHECK_MODULES(SID, [libsidplay2], [
2107         AC_LANG_PUSH(C++)
2108         oldCPPFLAGS="$CPPFLAGS"
2109         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2110         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2111             VLC_ADD_PLUGIN([sid])
2112             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2113             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2114         ], [
2115             AS_IF([test -n "${enable_sid}"],
2116                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2117                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2118                 )
2119         ])
2120         CPPFLAGS="$oldCPPFLAGS"
2121         AC_LANG_POP(C++)
2122     ], [
2123         AS_IF([test "x${enable_sid}" = "xyes"],
2124             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2125             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2126             )
2127     ])
2128 ])
2129
2130
2131 dnl
2132 dnl  ogg demux plugin
2133 dnl
2134 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2135 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2136     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2137 ],[true])
2138 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2139 if test "${enable_sout}" != "no"; then
2140 dnl Check for libshout
2141     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2142 fi
2143
2144 dnl
2145 dnl  matroska demux plugin
2146 dnl
2147 PKG_WITH_MODULES([MATROSKA], [libebml libmatroska], [
2148        VLC_ADD_PLUGIN([mkv])
2149        VLC_ADD_CFLAGS([mkv], [$MATROSKA_CFLAGS])
2150        VLC_ADD_LIBS([mkv], [$MATROSKA_LIBS])
2151        have_matroska="yes"
2152    ],,[MKV format support], [auto])
2153 AM_CONDITIONAL([HAVE_MATROSKA], [test "${have_matroska}" = "yes"])
2154
2155 dnl
2156 dnl  modplug demux plugin
2157 dnl
2158 AC_ARG_ENABLE([mod],
2159   AS_HELP_STRING([--disable-mod],
2160     [do not use libmodplug (default auto)]))
2161 if test "${enable_mod}" != "no" ; then
2162     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2163           VLC_ADD_PLUGIN([mod])
2164           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2165           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2166           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2167     ],[
2168        AS_IF([test -n "${enable_mod}"],
2169          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2170          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2171     ])
2172 fi
2173
2174 dnl
2175 dnl  mpc demux plugin
2176 dnl
2177 AC_ARG_ENABLE([mpc],
2178   AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)]))
2179 if test "${enable_mpc}" != "no"
2180 then
2181     AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2182     VLC_ADD_PLUGIN([mpc])
2183     VLC_ADD_LIBS([mpc],[-lmpcdec])])
2184 fi
2185
2186 dnl
2187 dnl  Codec plugins
2188 dnl
2189
2190 EXTEND_HELP_STRING([Codec plugins:])
2191
2192 dnl
2193 dnl wmafixed plugin
2194 dnl
2195 AC_ARG_ENABLE([wma-fixed],
2196   AS_HELP_STRING([--enable-wma-fixed], [libwma-fixed module (default disabled)]))
2197 if test "${enable_wma_fixed}" = "yes"
2198 then
2199   VLC_ADD_PLUGIN([wma_fixed])
2200 fi
2201
2202 dnl
2203 dnl shine encoder plugin
2204 dnl
2205 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2206
2207
2208 dnl
2209 dnl openmax il codec plugin
2210 dnl
2211 AC_ARG_ENABLE([omxil],
2212   AS_HELP_STRING([--enable-omxil], [openmax il codec module (default disabled)]))
2213 if test "${enable_omxil}" = "yes"
2214 then
2215   VLC_ADD_PLUGIN([omxil])
2216 fi
2217
2218 dnl
2219 dnl raspberry pi openmax il configuration
2220 dnl
2221 AC_ARG_ENABLE([rpi-omxil],
2222   AS_HELP_STRING([--enable-rpi-omxil], [openmax il configured for raspberry pi (default disabled)]))
2223 if test "${enable_rpi_omxil}" = "yes"
2224 then
2225   VLC_ADD_PLUGIN([omxil])
2226   VLC_ADD_CFLAGS([omxil],[-DRPI_OMX])
2227 fi
2228
2229 dnl
2230 dnl CrystalHD codec plugin
2231 dnl
2232 AC_ARG_ENABLE([crystalhd],
2233   AS_HELP_STRING([--enable-crystalhd], [crystalhd codec plugin (default auto)]))
2234 if test "${enable_crystalhd}" != "no"; then
2235     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2236       VLC_ADD_PLUGIN([crystalhd])
2237       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2238     ],[
2239       if test "${SYS}" = "mingw32" ; then
2240         AC_CHECK_HEADERS([libcrystalhd/bc_dts_defs.h], [
2241           VLC_ADD_PLUGIN([crystalhd])
2242           AC_CHECK_HEADERS([libcrystalhd/bc_drv_if.h], [
2243             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2244             ])
2245         ],[
2246           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2247                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2248                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2249         ],[#define __LINUX_USER__
2250                #include <libcrystalhd/bc_dts_types.h>
2251         ])
2252       fi
2253     ],[
2254        #include <libcrystalhd/bc_dts_types.h>
2255       ])
2256 fi
2257
2258 dnl
2259 dnl  mad plugin
2260 dnl
2261 have_mad="no"
2262 MAD_CFLAGS=""
2263 MAD_LIBS=""
2264
2265 AC_ARG_WITH(mad, AS_HELP_STRING([--with-mad=PATH], [path to libmad]), [
2266   enable_mad="yes"
2267 ], [
2268   with_mad="no"
2269 ])
2270 AS_IF([test "${with_mad}" != "no"], [
2271   MAD_CFLAGS="-I${with_mad}/include"
2272   MAD_LIBS="-L${with_mad}/lib"
2273 ])
2274
2275 AC_ARG_ENABLE([mad],
2276   AS_HELP_STRING([--enable-mad], [libmad module (default enabled)]))
2277 AS_IF([test "${enable_mad}" != "no"], [
2278   VLC_SAVE_FLAGS
2279   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2280   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2281   AC_CHECK_HEADERS([mad.h], [
2282     AC_CHECK_LIB([mad], [mad_bit_init], [
2283       have_mad="yes"
2284       MAD_LIBS="${MAD_LIBS} -lmad"
2285     ])
2286   ])
2287   VLC_RESTORE_FLAGS
2288   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2289     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2290   ])
2291 ])
2292 AC_SUBST([MAD_CFLAGS])
2293 AC_SUBST([MAD_LIBS])
2294 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2295
2296 dnl  mpg123 plugin
2297 dnl
2298 dnl
2299 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2300
2301 dnl
2302 dnl gstreamer stuff
2303 dnl
2304 AC_ARG_ENABLE([gst-decode],
2305   AS_HELP_STRING([--enable-gst-decode], [GStreamer based decoding support (currently supports only video decoding) (default auto)]))
2306
2307 have_gst_decode="no"
2308 AS_IF([test "${enable_gst_decode}" != "no"], [
2309   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2310     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2311       have_gst_decode="yes"
2312     ], [
2313       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2314     ])
2315   ], [
2316     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2317   ])
2318 ])
2319 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2320
2321 dnl
2322 dnl  avcodec decoder/encoder plugin
2323 dnl
2324 AC_ARG_ENABLE([merge-ffmpeg],
2325 AS_HELP_STRING([--enable-merge-ffmpeg], [merge FFmpeg-based plugins (default disabled)]),, [
2326   enable_merge_ffmpeg="no"
2327 ])
2328 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2329
2330 AC_MSG_CHECKING([for libavutil variant])
2331 PKG_CHECK_EXISTS([libavutil], [
2332   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2333   libavutil_micro="${libavutil_version##*.}"
2334   AS_IF([test ${libavutil_micro} -le 99], [
2335     avfork="libav"
2336   ], [
2337     avfork="ffmpeg"
2338   ])
2339 ], [
2340   avfork="none"
2341 ])
2342 AC_MSG_RESULT([${avfork}])
2343
2344 AC_ARG_ENABLE([avcodec],
2345 AS_HELP_STRING([--enable-avcodec], [libavcodec codec (default enabled)]))
2346 AS_IF([test "${enable_avcodec}" != "no"], [
2347   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2348   case "${avfork}" in
2349     libav) av_codec_ver="57.16.0" ;;
2350     dnl 05f66706d182eb0c36af54d72614bf4c33e957a9  includes libavutil 55.9.0
2351     ffmpeg) av_codec_ver="57.37.100" ;;
2352     dnl 7fc329e2dd6226dfecaa4a1d7adf353bf2773726  include libavutil 55.22.101
2353     *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2354   esac
2355   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 55.9.0], [
2356     VLC_SAVE_FLAGS
2357     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2358     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2359     AC_CHECK_HEADERS([libavcodec/avcodec.h])
2360     AC_CHECK_HEADERS([libavutil/avutil.h])
2361     VLC_RESTORE_FLAGS
2362     have_avcodec="yes"
2363   ],[
2364     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2365   ])
2366 ], [
2367   have_avcodec="no"
2368 ])
2369 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2370
2371 dnl
2372 dnl libva needs avcodec
2373 dnl
2374 AC_ARG_ENABLE([libva],
2375   AS_HELP_STRING([--enable-libva], [VAAPI GPU decoding support (libVA) (default auto)]))
2376
2377 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2378   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2379 ])
2380
2381 have_vaapi="no"
2382 have_vaapi_drm="no"
2383 have_vaapi_x11="no"
2384 have_vaapi_wl="no"
2385 AS_IF([test "${enable_libva}" != "no"], [
2386   PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2387     have_vaapi="yes"
2388   ], [
2389     AS_IF([test -n "${enable_libva}"], [
2390       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2391     ], [
2392       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2393     ])
2394   ])
2395   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2396     have_vaapi_drm="yes"
2397   ], [
2398     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2399   ])
2400   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2401     have_vaapi_x11="yes"
2402   ], [
2403     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2404   ])
2405   PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2406     have_vaapi_wl="yes"
2407   ], [
2408     AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2409   ])
2410 ])
2411 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2412 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2413 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2414 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2415
2416 have_avcodec_vaapi="no"
2417 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2418   VLC_SAVE_FLAGS
2419   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2420   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2421   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2422     AC_MSG_NOTICE([VA API acceleration activated])
2423     have_avcodec_vaapi="yes"
2424   ],[
2425     AS_IF([test -n "${enable_libva}"], [
2426       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2427     ], [
2428       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2429     ])
2430   ])
2431   VLC_RESTORE_FLAGS
2432 ])
2433 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2434
2435 dnl
2436 dnl dxva2 needs avcodec
2437 dnl
2438 AC_ARG_ENABLE([dxva2],
2439   AS_HELP_STRING([--enable-dxva2], [DxVA2 GPU decoding support (default auto)]))
2440
2441 have_avcodec_dxva2="no"
2442 AS_IF([test "${enable_dxva2}" != "no"], [
2443   if test "${SYS}" = "mingw32"; then
2444   AS_IF([test "x${have_avcodec}" = "xyes"], [
2445     AC_CHECK_HEADERS([dxva2api.h],
2446       [
2447         AC_CHECK_HEADERS([libavcodec/dxva2.h], [
2448            AC_MSG_NOTICE([DxVA2 acceleration activated])
2449            have_avcodec_dxva2="yes"
2450         ],[
2451     AS_IF([test "${enable_dxva2}" = "yes"],
2452           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2453               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2454         ], [#undef _WIN32_WINNT
2455             /* DXVA2 is only available in Vista and above */
2456             #define _WIN32_WINNT 0x600])
2457       ],[
2458     AS_IF([test "${enable_dxva2}" = "yes"],
2459               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2460               [AC_MSG_WARN([dxva2api.h not found])])
2461       ],[#include <d3d9.h>])
2462   ],[
2463     AS_IF([test "x${enable_dxva2}" != "x"], [
2464       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2465     ])
2466   ])
2467   fi
2468 ])
2469 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2470
2471 dnl
2472 dnl d3d11va needs avcodec
2473 dnl
2474 AC_ARG_ENABLE([d3d11va],
2475   AS_HELP_STRING([--enable-d3d11va], [D3D11 GPU decoding support (default auto)]))
2476
2477 have_avcodec_d3d11va="no"
2478 AS_IF([test "${enable_d3d11va}" != "no"], [
2479   if test "${SYS}" = "mingw32"; then
2480   AS_IF([test "x${have_avcodec}" = "xyes"], [
2481         AC_CHECK_TYPES([ID3D11VideoDecoder],
2482           [
2483             AC_CHECK_HEADERS([dxva2api.h],
2484               [
2485                 AC_CHECK_HEADERS([libavcodec/d3d11va.h], [
2486                    AC_MSG_NOTICE([D3D11 acceleration activated])
2487                    AC_DEFINE([HAVE_AVCODEC_D3D11VA], [1], [Define if the d3d11va module is built])
2488                    have_avcodec_d3d11va="yes"
2489                 ],[
2490                   AS_IF([test "${enable_d3d11va}" = "yes"],
2491                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2492                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2493                   ], [#undef _WIN32_WINNT
2494                       /* D3D11 is only available in Vista and above */
2495                       #define _WIN32_WINNT 0x600])
2496                   ],[
2497                     AS_IF([test "${enable_d3d11va}" = "yes"],
2498                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2499                           [AC_MSG_WARN([dxva2api.h not found])])
2500                   ],[#include <d3d9.h>])
2501           ],[
2502             AS_IF([test "${enable_d3d11va}" = "yes"],
2503                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2504                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2505           ], [#include <d3d11.h>])
2506   ],[
2507     AS_IF([test "x${enable_d3d11va}" != "x"], [
2508       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2509     ])
2510   ])
2511   fi
2512 ])
2513 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2514
2515 dnl
2516 dnl DXGI debug
2517 dnl
2518 AC_CHECK_HEADERS([dxgidebug.h dxgi1_6.h])
2519
2520 dnl
2521 dnl  avformat demuxer/muxer plugin
2522 dnl
2523
2524 AC_ARG_ENABLE([avformat],
2525 AS_HELP_STRING([--enable-avformat], [libavformat containers (default enabled)]),, [
2526   enable_avformat="${have_avcodec}"
2527 ])
2528 have_avformat="no"
2529 AS_IF([test "${enable_avformat}" != "no"], [
2530   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2531       have_avformat="yes"
2532       VLC_SAVE_FLAGS
2533       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2534       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2535       AC_CHECK_HEADERS([libavformat/avformat.h libavformat/avio.h])
2536       AC_CHECK_HEADERS([libavcodec/avcodec.h])
2537       AC_CHECK_HEADERS([libavutil/avutil.h])
2538       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2539         have_avformat="no"
2540       ])
2541       VLC_RESTORE_FLAGS
2542     ],[
2543       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2544   ])
2545 ])
2546 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2547
2548 dnl
2549 dnl  swscale image scaling and conversion plugin
2550 dnl
2551
2552 AC_ARG_ENABLE([swscale],
2553   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2554           (default enabled)]))
2555 if test "${enable_swscale}" != "no"
2556 then
2557   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2558     [
2559       VLC_SAVE_FLAGS
2560       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2561       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2562       AC_CHECK_HEADERS([libswscale/swscale.h])
2563       AC_CHECK_HEADERS([libavutil/avutil.h])
2564       VLC_ADD_PLUGIN([swscale])
2565       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2566       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2567       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2568         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2569       ])
2570       VLC_RESTORE_FLAGS
2571     ],[
2572       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2573   ])
2574 fi
2575
2576 dnl
2577 dnl  postproc plugin
2578 dnl
2579
2580 AC_ARG_ENABLE([postproc],
2581 AS_HELP_STRING([--enable-postproc], [libpostproc image post-processing (default auto)]))
2582 if test "${enable_postproc}" != "no"
2583 then
2584   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2585     [
2586       VLC_SAVE_FLAGS
2587       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2588       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2589       AC_CHECK_HEADERS([postproc/postprocess.h])
2590       VLC_ADD_PLUGIN([postproc])
2591       VLC_RESTORE_FLAGS
2592     ],[
2593       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2594   ])
2595 fi
2596
2597 dnl
2598 dnl  faad decoder plugin
2599 dnl
2600 AC_ARG_ENABLE([faad],
2601 AS_HELP_STRING([--enable-faad], [faad codec (default auto)]))
2602 have_faad="no"
2603 AS_IF([test "${enable_faad}" != "no"], [
2604   AC_CHECK_HEADERS([neaacdec.h], [
2605     AC_CHECK_LIB([faad], [NeAACDecOpen], [have_faad="yes"],, [$LIBM])
2606
2607     AS_IF([test "${have_faad}" = "yes"], [
2608       VLC_ADD_PLUGIN([faad])
2609       VLC_ADD_LIBS([faad],[-lfaad])
2610     ], [
2611       AS_IF([test "${enable_faad}" = "yes"], [
2612         AC_MSG_ERROR([cannot find FAAD library])
2613       ], [
2614         AC_MSG_WARN([cannot find FAAD library])
2615       ])
2616     ])
2617   ])
2618 ])
2619
2620 dnl
2621 dnl  AOM decoder plugin
2622 dnl
2623 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec (default auto)])
2624
2625 dnl
2626 dnl libvpx decoder plugin
2627 dnl
2628 AC_ARG_ENABLE([vpx],
2629     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2630 AS_IF([test "${enable_vpx}" != "no"],[
2631     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2632         VLC_ADD_PLUGIN([vpx])
2633         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2634         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2635         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2636             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2637         ], [], [${VPX_LIBS}])
2638         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2639             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2640         ], [], [${VPX_LIBS}])
2641         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2642             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2643         ], [], [${VPX_LIBS}])
2644         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2645             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2646         ], [], [${VPX_LIBS}])
2647     ], [
2648     AS_IF([test "${enable_vpx}" = "yes"],[
2649         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2650     ])])
2651 ])
2652
2653 dnl
2654 dnl twolame encoder plugin
2655 dnl
2656 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2657
2658 dnl
2659 dnl fdk-aac encoder plugin
2660 dnl
2661 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2662
2663
2664 dnl
2665 dnl A52/AC3 decoder plugin
2666 dnl
2667 AC_ARG_ENABLE([a52],
2668   AS_HELP_STRING([--enable-a52], [A/52 support with liba52 (default enabled)]))
2669 if test "${enable_a52}" != "no"
2670 then
2671   AC_ARG_WITH([a52],
2672     AS_HELP_STRING([--with-a52=PATH], [a52 headers and libraries]))
2673     if test -z "${with_a52}"
2674     then
2675       LDFLAGS_test=""
2676       CPPFLAGS_test=""
2677     else
2678       LDFLAGS_test="-L${with_a52}/lib"
2679       CPPFLAGS_test="-I${with_a52}/include"
2680     fi
2681     VLC_SAVE_FLAGS
2682     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2683     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2684     AC_CHECK_HEADERS([a52dec/a52.h], [
2685       AC_CHECK_LIB([a52], [a52_free], [
2686         VLC_ADD_PLUGIN([a52])
2687         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2688         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2689       ],[
2690         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2691         ], [$LIBM])
2692     ],[
2693       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2694     ])
2695     VLC_RESTORE_FLAGS
2696 fi
2697
2698 dnl
2699 dnl DTS Coherent Acoustics decoder plugin
2700 dnl
2701 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2702
2703 dnl
2704 dnl  Flac plugin
2705 dnl
2706 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2707
2708 dnl
2709 dnl  Libmpeg2 plugin
2710 dnl
2711 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2712
2713 dnl
2714 dnl  Vorbis plugin
2715 dnl
2716 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2717
2718 dnl
2719 dnl  Tremor plugin
2720 dnl
2721 AC_ARG_ENABLE([tremor],
2722   AS_HELP_STRING([--enable-tremor], [Tremor decoder support (default disabled)]))
2723 if test "${enable_tremor}" = "yes"
2724 then
2725   AC_CHECK_HEADERS([tremor/ivorbiscodec.h], [
2726     VLC_ADD_PLUGIN([tremor])
2727    ],[])
2728 fi
2729
2730 dnl
2731 dnl  Speex plugins
2732 dnl
2733 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2734 have_speexdsp="no"
2735 AS_IF([test "${enable_speex}" != "no"], [
2736   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2737     have_speexdsp="yes"
2738   ], [
2739     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2740   ])
2741 ])
2742 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2743
2744 dnl
2745 dnl  Opus plugin
2746 dnl
2747 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2748
2749 dnl
2750 dnl  Ambisonic channel mixer and binauralizer plugin
2751 dnl
2752 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2753
2754 dnl
2755 dnl  theora decoder plugin
2756 dnl
2757 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2758
2759 dnl
2760 dnl  OggSpots decoder plugin
2761 dnl
2762 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2763
2764 dnl
2765 dnl  Daala decoder plugin
2766 dnl
2767 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2768
2769 dnl
2770 dnl  schroedinger decoder plugin (for dirac format video)
2771 dnl
2772 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2773
2774 dnl
2775 dnl  PNG decoder module
2776 dnl
2777 AC_ARG_ENABLE([png],
2778   AS_HELP_STRING([--enable-png], [PNG support (default enabled)]))
2779 AS_IF([test "${enable_png}" != "no"], [
2780 AC_CHECK_HEADERS([png.h], [
2781   VLC_SAVE_FLAGS
2782   LDFLAGS="${LDFLAGS} -lz $LIBM"
2783   AC_CHECK_LIB([png], [png_set_alpha_mode], [
2784     VLC_ADD_PLUGIN([png])
2785   ], [], [-lz $LIBM])
2786   VLC_RESTORE_FLAGS
2787   ])
2788 ])
2789
2790 dnl
2791 dnl  JPEG decoder module
2792 dnl
2793 AC_ARG_ENABLE([jpeg],
2794   AS_HELP_STRING([--enable-jpeg], [JPEG support (default enabled)]))
2795 AS_IF([test "${enable_jpeg}" != "no"], [
2796 AC_CHECK_HEADERS([jpeglib.h], [
2797   VLC_ADD_PLUGIN([jpeg])
2798   ])
2799 ])
2800
2801 dnl
2802 dnl  BPG decoder module
2803 dnl
2804 AC_ARG_ENABLE([bpg],
2805   AS_HELP_STRING([--enable-bpg], [BPG support (default disabled)]))
2806 AS_IF([test "${enable_bpg}" != "no"], [
2807 AC_CHECK_HEADERS([libbpg.h], [
2808   VLC_ADD_PLUGIN([bpg])
2809   ])
2810 ])
2811
2812 dnl
2813 dnl H262 encoder plugin (lib262)
2814 dnl
2815 AC_ARG_ENABLE([x262],
2816   AS_HELP_STRING([--enable-x262], [H262 encoding support with static libx262 (default disabled)]))
2817 if test "${enable_x262}" != "no"; then
2818     PKG_CHECK_MODULES(X262, x262, [
2819         VLC_ADD_PLUGIN([x262])
2820         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2821         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2822           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2823         ])
2824         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2825         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2826           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2827         fi
2828     ], [
2829        if test "${enable_x262}" = "yes"; then
2830         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2831        fi
2832     ])
2833 fi
2834
2835 dnl x265 encoder
2836 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2837
2838 dnl
2839 dnl H264 encoder plugin (using libx264)
2840 dnl
2841 AC_ARG_ENABLE([x264],
2842   AS_HELP_STRING([--enable-x264], [H264 encoding support with libx264 (default enabled)]))
2843 if test "${enable_x264}" != "no"; then
2844       PKG_CHECK_MODULES(X264,x264 >= 0.148, [
2845         VLC_ADD_PLUGIN([x264])
2846         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2847
2848         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2849           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2850         ])
2851
2852         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2853         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2854           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2855         fi
2856       ],[
2857         if test "${enable_x264}" = "yes"; then
2858             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2859           fi
2860       ])
2861 fi
2862
2863 dnl
2864 dnl H264 encoder plugin (libx264 > 153)
2865 dnl
2866 AC_ARG_ENABLE([x26410b],
2867   AS_HELP_STRING([--enable-x26410b], [H264 10-bit encoding support with libx264 (default enabled)]))
2868 if test "${enable_x26410b}" != "no"; then
2869       PKG_CHECK_MODULES(X26410b,x264 >= 0.153, [
2870         VLC_ADD_PLUGIN([x26410b])
2871         VLC_ADD_LIBS([x26410b],[${X264_LIBS}])
2872
2873         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2874           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2875         ])
2876
2877         VLC_ADD_CFLAGS([x26410b],[${X264_CFLAGS}])
2878         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2879           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2880         fi
2881       ],[
2882         if test "${enable_x26410b}" = "yes"; then
2883             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2884           fi
2885       ])
2886 fi
2887
2888
2889 dnl
2890 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2891 dnl
2892 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2893
2894 dnl
2895 dnl libfluidsynth (MIDI synthetizer) plugin
2896 dnl
2897 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2898 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2899 AC_CHECK_HEADERS([fluidlite.h], [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2900
2901 dnl
2902 dnl Teletext Modules
2903 dnl vbi decoder plugin (using libzbvi)
2904 dnl telx module
2905 dnl uncompatible
2906 dnl
2907 AC_ARG_ENABLE([zvbi],
2908   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2909                   libzvbi (default enabled)]))
2910 AC_ARG_ENABLE([telx],
2911   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2912                   zvbi) (default enabled if zvbi is absent)]))
2913
2914 AS_IF( [test "${enable_zvbi}" != "no"],[
2915     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2916         [
2917           VLC_ADD_PLUGIN([zvbi])
2918           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2919           AS_IF( [test "${enable_telx}" = "yes"],[
2920                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2921                   ])
2922         ],[
2923           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2924         ])
2925     ])
2926 AS_IF( [test "${enable_telx}" != "no" ],[
2927   VLC_ADD_PLUGIN([telx])
2928   ])
2929
2930 dnl
2931 dnl ARIB subtitles rendering module
2932 dnl
2933 AC_ARG_ENABLE([aribsub],
2934   AS_HELP_STRING([--enable-aribsub],[ARIB Subtitles support (default enabled)]))
2935 AS_IF( [test "${enable_aribsub}" != "no" ],[
2936   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2937       have_aribb24="yes"
2938       VLC_ADD_PLUGIN([aribsub])
2939       VLC_ADD_LIBS([aribsub],[-laribb24])
2940       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2941     ],[
2942       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2943       have_aribb24="no"
2944   ])
2945 ])
2946 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2947
2948 dnl
2949 dnl ARIB B25
2950 dnl
2951 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2952
2953 dnl
2954 dnl  kate decoder plugin
2955 dnl
2956 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2957
2958 dnl
2959 dnl  tiger rendering for kate decoder plugin
2960 dnl
2961 AC_ARG_ENABLE([tiger],
2962 AS_HELP_STRING([--enable-tiger], [Tiger rendering library for Kate streams (default auto)]))
2963 AS_IF([test "${enable_tiger}" != "no"], [
2964   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2965       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2966         AS_IF([test -n "${enable_tiger}"], [
2967           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2968         ])
2969   ])
2970 ])
2971
2972 dnl
2973 dnl  check if we can build the css selector engine
2974 dnl
2975 AC_ARG_ENABLE([css],
2976 AS_HELP_STRING([--enable-css], [CSS selector engine (default auto)]))
2977 AS_IF([test "${enable_css}" != "no"], [
2978   with_css="yes"
2979   AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
2980 ])
2981 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
2982
2983
2984 dnl
2985 dnl  Video plugins
2986 dnl
2987
2988 EXTEND_HELP_STRING([Video plugins:])
2989
2990 dnl
2991 dnl  OpenGL
2992 dnl
2993 PKG_CHECK_MODULES([EGL], [egl], [
2994   have_egl="yes"
2995 ], [
2996   have_egl="no"
2997 ])
2998 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2999
3000 have_gl="no"
3001 PKG_CHECK_MODULES([GL], [gl], [
3002   have_gl="yes"
3003 ], [
3004   AC_MSG_CHECKING([for OpenGL])
3005   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3006 #ifdef _WIN32
3007 # include <GL/glew.h>
3008 #endif
3009 #include <GL/gl.h>
3010 ]], [
3011     [int t0 = GL_TEXTURE0;]])
3012   ], [
3013     GL_CFLAGS=""
3014     have_gl="yes"
3015     AS_IF([test "${SYS}" != "mingw32"], [
3016       GL_LIBS="-lGL"
3017     ], [
3018       GL_LIBS="-lopengl32"
3019     ])
3020   ])
3021   AC_MSG_RESULT([${have_gl}])
3022 ])
3023 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3024 AS_IF([test "${have_gl}" = "yes"], [
3025   AC_DEFINE([HAVE_GL], 1, [Defined if having OpenGL])
3026 ])
3027
3028 dnl OpenGL ES 2: depends on EGL 1.1
3029 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3030
3031 dnl
3032 dnl  Xlib
3033 dnl
3034
3035 AC_PATH_XTRA()
3036 AC_CHECK_HEADERS([X11/Xlib.h])
3037
3038 dnl
3039 dnl  X C Bindings modules
3040 dnl
3041 AC_ARG_ENABLE([xcb],
3042   AS_HELP_STRING([--enable-xcb], [X11 support with XCB (default enabled)]),, [
3043   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3044     enable_xcb="yes"
3045   ], [
3046     enable_xcb="no"
3047   ])
3048 ])
3049
3050 have_xcb="no"
3051 have_xkbcommon_x11="no"
3052 have_xcb_keysyms="no"
3053 AS_IF([test "${enable_xcb}" != "no"], [
3054   xcb_err=""
3055
3056   dnl libxcb
3057   PKG_CHECK_MODULES([XCB], [xcb >= 1.6],, [
3058     xcb_err="$xcb_err ${XCB_PKG_ERRORS}."])
3059   PKG_CHECK_MODULES([XCB_COMPOSITE], [xcb-composite],, [
3060     xcb_err="$xcb_err ${XCB_COMPOSITE_PKG_ERRORS}."])
3061   PKG_CHECK_MODULES([XCB_RANDR], [xcb-randr >= 1.3],, [
3062     xcb_err="$xcb_err ${XCB_RANDR_PKG_ERRORS}."])
3063   PKG_CHECK_MODULES([XCB_SHM], [xcb-shm],, [
3064     xcb_err="$xcb_err ${XCB_SHM_PKG_ERRORS}."])
3065   PKG_CHECK_MODULES([XCB_XKB], [xcb-xkb],, [
3066     xcb_err="$xcb_err ${XCB_XKB_PKG_ERRORS}."])
3067   PKG_CHECK_MODULES([XCB_XV], [xcb-xv >= 1.1.90.1],, [
3068     xcb_err="$xcb_err ${XCB_XV_PKG_ERRORS}."])
3069
3070   dnl xproto
3071   PKG_CHECK_MODULES(XPROTO, [xproto],, [
3072     xcb_err="$xcb_err ${XPROTO_PKG_ERRORS}."])
3073
3074   AS_IF([test -n "$xcb_err"], [
3075     AC_MSG_ERROR([$xcb_err Pass --disable-xcb to skip X11 support.])
3076   ])
3077
3078   dnl xkbcommon
3079   PKG_CHECK_MODULES([XKBCOMMON_X11], [xkbcommon-x11], [
3080     have_xkbcommon_x11="yes"
3081   ], [
3082     AC_MSG_WARN([${XKBCOMMON_X11_PKG_ERRORS}. Hotkeys are disabled.])
3083   ])
3084
3085   dnl xcb-utils
3086   PKG_CHECK_MODULES([XCB_KEYSYMS], [xcb-keysyms >= 0.3.4], [
3087     have_xcb_keysyms="yes"
3088   ], [
3089     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Global hotkeys are disabled.])
3090   ])
3091
3092   have_xcb="yes"
3093 ])
3094 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3095 AM_CONDITIONAL([HAVE_XKBCOMMON_X11], [test "${have_xkbcommon_x11}" = "yes"])
3096 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3097
3098
3099 dnl
3100 dnl VDPAU needs X11
3101 dnl
3102 AC_ARG_ENABLE([vdpau],
3103   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3104 have_vdpau="no"
3105 AS_IF([test "${enable_vdpau}" != "no"], [
3106   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3107     have_vdpau="yes"
3108     AS_IF([test "${no_x}" = "yes"], [
3109       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3110     ])
3111   ], [
3112     AS_IF([test -n "${enable_vdpau}"], [
3113       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3114     ])
3115   ])
3116 ])
3117 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3118
3119 have_avcodec_vdpau="no"
3120 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3121   case "${avfork}" in
3122     libav) av_vdpau_ver="56.10.0" ;;
3123     ffmpeg) av_vdpau_ver="56.19.100" ;;
3124   esac
3125   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3126     have_avcodec_vdpau="yes"
3127     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3128   ], [
3129     AS_IF([test -n "${enable_vdpau}"], [
3130       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3131     ], [
3132       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3133     ])
3134   ])
3135 ])
3136 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3137
3138
3139 dnl
3140 dnl  Wayland
3141 dnl
3142 AC_ARG_ENABLE([wayland],
3143   AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)]))
3144
3145 have_wayland="no"
3146 AS_IF([test "${enable_wayland}" != "no"], [
3147   wl_err=""
3148
3149   dnl wayland
3150   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91],, [
3151     wl_err="$wl_err ${WAYLAND_CLIENT_PKG_ERRORS}."
3152   ])
3153   PKG_CHECK_MODULES([WAYLAND_CURSOR], [wayland-cursor],, [
3154     wl_err="$wl_err ${WAYLAND_CURSOR_PKG_ERRORS}."
3155   ])
3156   PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl],, [
3157     wl_err="$wl_err ${WAYLAND_EGL_PKG_ERRORS}."
3158   ])
3159   PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner >= 1.15], [
3160     WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3161   ], [
3162     wl_err="$wl_err ${WAYLAND_SCANNER_PKG_ERRORS}."
3163   ])
3164
3165   dnl wayland-protocols
3166   PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= 1.12], [
3167     WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3168   ], [
3169     wl_err="$wl_err ${WAYLAND_PROTOCOLS_PKG_ERRORS}."
3170   ])
3171
3172   AS_IF([test -n "$wl_err"], [
3173     AS_IF([test -n "$enable_wayland"], [
3174       AC_MSG_ERROR([$wl_err])
3175     ], [
3176       AC_MSG_WARN([$wl_err])
3177     ])
3178   ], [
3179     have_wayland="yes"
3180   ])
3181
3182   dnl xkbcommon
3183   PKG_CHECK_MODULES([XKBCOMMON], [xkbcommon], [
3184     have_xkbcommon="yes"
3185   ], [
3186     AC_MSG_WARN([${XKBCOMMON_PKG_ERRORS}. Hotkeys are disabled.])
3187   ])
3188 ])
3189 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3190 AC_SUBST([WAYLAND_PROTOCOLS])
3191 AC_SUBST([WAYLAND_SCANNER])
3192 AM_CONDITIONAL([HAVE_XKBCOMMON], [test "${have_xkbcommon}" = "yes"])
3193
3194
3195 dnl
3196 dnl  SDL image decoder module
3197 dnl
3198 AC_ARG_ENABLE([sdl-image],
3199   AS_HELP_STRING([--enable-sdl-image], [SDL image support (default enabled)]))
3200 AS_IF([test "${enable_sdl_image}" != "no"],[
3201   PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3202     VLC_ADD_PLUGIN([sdl_image])
3203   ], [
3204     AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3205   ])
3206 ])
3207
3208 dnl
3209 dnl  freetype module
3210 dnl
3211 AC_ARG_ENABLE([freetype],
3212   AS_HELP_STRING([--enable-freetype],   [freetype support   (default auto)]))
3213 AC_ARG_ENABLE([fribidi],
3214   AS_HELP_STRING([--enable-fribidi],    [fribidi support    (default auto)]))
3215 AC_ARG_ENABLE([harfbuzz],
3216   AS_HELP_STRING([--enable-harfbuzz],   [harfbuzz support   (default auto)]))
3217 AC_ARG_ENABLE([fontconfig],
3218   AS_HELP_STRING([--enable-fontconfig], [fontconfig support (default auto)]))
3219
3220 AC_ARG_WITH([default-font],
3221     AS_HELP_STRING([--with-default-font=PATH],
3222         [Path to the default font]),
3223         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3224             "$withval", [Default font])])
3225 AC_ARG_WITH([default-monospace-font],
3226     AS_HELP_STRING([--with-default-monospace-font=PATH],
3227         [Path to the default font]),
3228         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3229             "$withval", [Default monospace font])])
3230
3231 AC_ARG_WITH([default-font-family],
3232     AS_HELP_STRING([--with-default-font-family=NAME],
3233         [Name of the default font family]),
3234         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3235             "$withval", [Default font family])])
3236 AC_ARG_WITH([default-monospace-font-family],
3237     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3238         [Name of the default font family]),
3239         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3240             "$withval", [Default monospace font family])])
3241
3242 have_freetype="no"
3243 have_fontconfig="no"
3244 have_fribidi="no"
3245 have_harfbuzz="no"
3246
3247 if test "${enable_freetype}" != "no"; then
3248    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3249       have_freetype="yes"
3250       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3251       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3252
3253     dnl fontconfig support
3254     AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3255       PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3256         have_fontconfig="yes"
3257       ], [
3258         AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3259       ])
3260     ])
3261
3262       dnl fribidi support
3263       if test "${enable_fribidi}" != "no"; then
3264         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3265           have_fribidi="yes"
3266           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3267           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3268         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3269       fi
3270
3271       dnl harfbuzz support
3272       if test "${have_fribidi}" != "no"; then
3273         if test "${enable_harfbuzz}" != "no"; then
3274           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3275             have_harfbuzz="yes"
3276             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3277             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3278           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3279         fi
3280       fi
3281   ],[
3282   AS_IF([test -n "${enable_freetype}"],[
3283     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3284     ])
3285   ])
3286 fi
3287
3288 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3289 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3290 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3291 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3292
3293 dnl
3294 dnl libass subtitle rendering module
3295 dnl
3296 AC_ARG_ENABLE([libass],
3297   AS_HELP_STRING([--enable-libass], [Subtitle support using libass (default enabled)]))
3298 AS_IF( [test "${enable_libass}" != "no"], [
3299   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
3300       [
3301         VLC_ADD_PLUGIN([libass])
3302
3303         if test "${have_fontconfig}" != "no"; then
3304             VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
3305             VLC_ADD_LIBS([libass],[${FONTCONFIG_LIBS}])
3306         fi
3307       ],[
3308         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
3309       ])
3310   ])
3311
3312 dnl
3313 dnl SAPI (text to Speech renderer for Windows)
3314 dnl
3315 AC_LANG_PUSH([C++])
3316 AC_CHECK_TYPES([ISpObjectToken],[
3317               have_sapi="yes"
3318             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3319               [#include <windows.h>
3320                #include <sapi.h>
3321                #include <sphelper.h>])
3322 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3323 AC_LANG_POP([C++])
3324
3325 dnl
3326 dnl  SVG module (text rendering and image decoding)
3327 dnl
3328 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3329 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3330
3331 dnl
3332 dnl  Windows DirectX module
3333 dnl
3334
3335 AC_ARG_ENABLE([directx],
3336   AS_HELP_STRING([--enable-directx],
3337     [Microsoft DirectX support (default enabled on Windows)]),, [
3338   AS_IF([test "${SYS}" = "mingw32"], [
3339     enable_directx="yes"
3340   ], [
3341     enable_directx="no"
3342   ])
3343 ])
3344 AS_IF([test "${enable_directx}" != "no"], [
3345   dnl DirectDraw
3346   AC_CHECK_HEADERS([ddraw.h], [
3347     VLC_ADD_PLUGIN([directdraw])
3348   ])
3349
3350   dnl OpenGL
3351   AC_CHECK_HEADERS([GL/wglew.h], [
3352     VLC_ADD_PLUGIN([glwin32 wgl])
3353   ],, [
3354     #include <windows.h>
3355     #include <GL/gl.h>
3356   ])
3357
3358   dnl Direct3D11
3359   AC_CHECK_HEADERS([d3d11.h], [
3360     VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3361   ])
3362
3363   dnl Direct3D9
3364   AC_CHECK_HEADERS([d3d9.h], [
3365     VLC_ADD_PLUGIN([direct3d9])
3366     AC_CHECK_HEADERS([d3dx9effect.h])
3367
3368     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3369         [[#define COBJMACROS
3370           #include <d3d9.h>
3371           #include <dxva2api.h>
3372           #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3373           # error dxva2 too old
3374           #endif
3375         ]],[[;]])
3376       ],[
3377         VLC_ADD_PLUGIN([direct3d9_filters])
3378       ],
3379       [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3380
3381   ])
3382 ])
3383
3384 dnl
3385 dnl  Linux framebuffer module
3386 dnl
3387 AC_CHECK_HEADER([linux/fb.h], [
3388   VLC_ADD_PLUGIN([fb])
3389 ])
3390
3391 dnl
3392 dnl  Linux kernel mode setting module
3393 dnl
3394 PKG_ENABLE_MODULES_VLC([KMS], [], [libdrm >= 2.4.83], [Linux kernel mode setting output], [auto])
3395
3396 dnl
3397 dnl  libcaca plugin
3398 dnl
3399 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3400
3401 dnl
3402 dnl  OS/2 KVA plugin
3403 dnl
3404 AC_ARG_ENABLE([kva],
3405   AS_HELP_STRING([--enable-kva],
3406     [support the K Video Accelerator KVA (default enabled on OS/2)]),, [
3407   AS_IF([test "$SYS" = "os2"], [
3408     enable_kva="yes"
3409   ])
3410 ])
3411 have_kva="no"
3412 KVA_LIBS=""
3413 AS_IF([test "$enable_kva" != "no"], [
3414   AC_CHECK_HEADERS([kva.h], [
3415     have_kva="yes"
3416     AC_CHECK_LIB([kva], [main], [
3417       KVA_LIBS="-lkva"
3418     ])
3419   ])
3420 ])
3421 AC_SUBST([KVA_LIBS])
3422 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3423
3424 dnl
3425 dnl MMAL plugin
3426 dnl
3427 AC_ARG_ENABLE([mmal],
3428   AS_HELP_STRING([--enable-mmal],
3429     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3430 if test "${enable_mmal}" != "no"; then
3431   VLC_SAVE_FLAGS
3432   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3433   CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3434   AC_CHECK_HEADERS([interface/mmal/mmal.h],
3435     [ AC_CHECK_LIB([bcm_host], [vc_tv_unregister_callback_full], [
3436         have_mmal="yes"
3437         VLC_ADD_PLUGIN([mmal])
3438         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3439         VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3440         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif ]) ], [
3441           AS_IF([test "${enable_mmal}" = "yes"],
3442             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3443             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3444           ],
3445         [])
3446     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3447       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3448       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3449   VLC_RESTORE_FLAGS
3450 fi
3451 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3452
3453 dnl
3454 dnl  Audio plugins
3455 dnl
3456
3457 EXTEND_HELP_STRING([Audio plugins:])
3458
3459 dnl
3460 dnl  Pulseaudio module
3461 dnl
3462 AC_ARG_ENABLE([pulse],
3463   AS_HELP_STRING([--enable-pulse],
3464     [use the PulseAudio client library (default auto)]))
3465 have_pulse="no"
3466 AS_IF([test "${enable_pulse}" != "no"], [
3467   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3468     have_pulse="yes"
3469   ], [
3470     AS_IF([test "x${enable_pulse}" != "x"], [
3471       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3472     ])
3473   ])
3474 ])
3475 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3476
3477 dnl
3478 dnl  ALSA module
3479 dnl
3480 AC_ARG_ENABLE([alsa],
3481   AS_HELP_STRING([--enable-alsa],
3482     [support the Advanced Linux Sound Architecture (default auto)]),, [
3483   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3484     enable_alsa="yes"
3485   ])
3486 ])
3487 have_alsa="no"
3488 AS_IF([test "${enable_alsa}" != "no"], [
3489   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3490     have_alsa="yes"
3491   ], [
3492     AS_IF([test "x${enable_alsa}" != "x"], [
3493       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3494     ])
3495   ])
3496 ])
3497 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3498
3499 dnl
3500 dnl  Open Sound System module
3501 dnl
3502 AC_ARG_ENABLE([oss],
3503   AS_HELP_STRING([--enable-oss],
3504     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)]),, [
3505   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3506     enable_oss="no"
3507   ])
3508 ])
3509 have_oss="no"
3510 OSS_LIBS=""
3511 AS_IF([test "$enable_oss" != "no"], [
3512   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3513     have_oss="yes"
3514     AC_CHECK_LIB([ossaudio], [main], [
3515       OSS_LIBS="-lossaudio"
3516     ])
3517   ])
3518 ])
3519 AC_SUBST([OSS_LIBS])
3520 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3521
3522 dnl
3523 dnl  OpenBSD sndio module
3524 dnl
3525 AC_ARG_ENABLE([sndio],
3526   AS_HELP_STRING([--disable-sndio],
3527     [support the OpenBSD sndio (default auto)]),, [
3528   AS_IF([test "$SYS" = "openbsd"], [
3529     enable_sndio="yes"
3530   ])
3531 ])
3532 have_sndio="no"
3533 AS_IF([test "$enable_sndio" != "no"], [
3534   AC_CHECK_HEADER([sndio.h], [
3535     have_sndio="yes"
3536   ])
3537 ])
3538 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3539
3540 dnl
3541 dnl  Windows Audio Session plugin
3542 dnl
3543 AC_ARG_ENABLE([wasapi],
3544   AS_HELP_STRING([--enable-wasapi],
3545     [use the Windows Audio Session API (default auto)])
3546 )
3547 have_wasapi="no"
3548 AS_IF([test "$enable_wasapi" != "no"], [
3549   AC_CHECK_HEADER([audioclient.h], [
3550     have_wasapi="yes"
3551   ], [
3552     AS_IF([test "x${enable_wasapi}" != "x"], [
3553       AC_MSG_ERROR([Windows Audio Session API not found.])
3554     ])
3555   ])
3556 ])
3557 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3558
3559 dnl
3560 dnl  JACK modules
3561 dnl
3562 AC_ARG_ENABLE([jack],
3563   AS_HELP_STRING([--disable-jack],
3564     [do not use jack (default auto)]))
3565 have_jack="no"
3566 AS_IF([test "${enable_jack}" != "no"], [
3567     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3568       [ have_jack=yes ],
3569       [
3570       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3571
3572       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3573       [ have_jack=yes ],
3574       [
3575       AS_IF([test -n "${enable_jack}"],
3576          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3577          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3578       ])
3579     ])
3580 ])
3581 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3582
3583 dnl
3584 dnl  OpenSLES Android
3585 dnl
3586 AC_ARG_ENABLE([opensles],
3587   AS_HELP_STRING([--enable-opensles], [Android OpenSL ES audio module (default disabled)]))
3588 if test "${HAVE_ANDROID}" = "1"; then
3589   if test "${enable_opensles}" = "yes"; then
3590       AC_CHECK_HEADERS([SLES/OpenSLES.h],
3591         [ VLC_ADD_PLUGIN([opensles_android]) ],
3592         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3593   fi
3594 fi
3595
3596 dnl
3597 dnl  Tizen audio
3598 dnl
3599 AC_ARG_ENABLE([tizen_audio],
3600   AS_HELP_STRING([--enable-tizen-audio],
3601     [Tizen audio module (default enabled on Tizen)]),, [
3602   AS_IF([test "$HAVE_TIZEN" = "1"], [
3603     enable_tizen_audio="yes"
3604   ])
3605 ])
3606 if test "${enable_tizen_audio}" = "yes"; then
3607   AC_CHECK_HEADERS([audio_io.h],
3608     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3609     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3610 fi
3611
3612 dnl
3613 dnl libsamplerate plugin
3614 dnl
3615 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3616
3617 dnl
3618 dnl  soxr module
3619 dnl
3620 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3621
3622 dnl
3623 dnl  OS/2 KAI plugin
3624 dnl
3625 AC_ARG_ENABLE([kai],
3626   AS_HELP_STRING([--enable-kai],
3627     [support the K Audio Interface KAI (default enabled on OS/2)]),, [
3628   AS_IF([test "$SYS" = "os2"], [
3629     enable_kai="yes"
3630   ])
3631 ])
3632 have_kai="no"
3633 KAI_LIBS=""
3634 AS_IF([test "$enable_kai" != "no"], [
3635   AC_CHECK_HEADERS([kai.h], [
3636     have_kai="yes"
3637     AC_CHECK_LIB([kai], [main], [
3638       KAI_LIBS="-lkai"
3639     ])
3640   ])
3641 ])
3642 AC_SUBST([KAI_LIBS])
3643 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3644
3645 dnl
3646 dnl  chromaprint audio track fingerprinter
3647 dnl
3648 m4_pushdef([libchromaprint_version], 0.6.0)
3649 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3650     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3651     AS_IF([test "${enable_chromaprint}" = "yes"],
3652         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3653         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3654          ),
3655     [(Chromaprint based audio fingerprinter)],[auto])
3656 m4_popdef([libchromaprint_version])
3657
3658 dnl
3659 dnl  Chromecast streaming support
3660 dnl
3661 m4_pushdef([protobuf_lite_version], 2.5.0)
3662 AC_ARG_VAR(PROTOC, [protobuf compiler])
3663 AC_CHECK_PROGS(PROTOC, protoc, no)
3664 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3665     AS_IF([test "x${PROTOC}" != "xno"], [
3666         build_chromecast="yes"
3667     ], [
3668     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3669     ])
3670 ], [
3671     AS_IF([test "${enable_chromecast}" = "yes"],
3672         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3673         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3674     )
3675     enable_chromecast="no"
3676 ], [(Chromecast streaming support)], [auto])
3677 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3678 m4_popdef([protobuf_lite_version])
3679
3680 dnl
3681 dnl  Interface plugins
3682 dnl
3683
3684 EXTEND_HELP_STRING([Interface plugins:])
3685
3686 dnl
3687 dnl QT
3688 dnl
3689 AC_ARG_ENABLE([qt],
3690   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)]),, [
3691   AS_IF([test "${SYS}" = "darwin"], [
3692     enable_qt="no"
3693   ])
3694 ])
3695 have_qt5_x11="no"
3696 AS_IF([test "${enable_qt}" != "no"], [
3697   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.9.0 Qt5Widgets Qt5Gui Qt5Svg], [
3698       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3699           have_qt5_x11="yes"
3700       ],[
3701           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3702       ])
3703       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3704       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3705       QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3706       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3707       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3708       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3709     ], [
3710       AS_IF([test -n "${enable_qt}"],[
3711         AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3712       ],[
3713         AC_MSG_WARN([${QT_PKG_ERRORS}.])
3714       ])
3715       enable_qt="no"
3716     ])
3717 ])
3718
3719 AS_IF([test "${enable_qt}" != "no"], [
3720   ALIASES="${ALIASES} qvlc"
3721 ])
3722 AC_SUBST([QT_VERSION])
3723 AM_CONDITIONAL([ENABLE_QT], [test "$enable_qt" != "no"])
3724 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3725
3726 dnl
3727 dnl detect kde4-config patch (used for kde solids).
3728 dnl
3729 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3730 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3731   KDE4_CONFIG="kde4-config"
3732 ])
3733
3734 dnl
3735 dnl Simple test for skins2 dependency
3736 dnl
3737 AS_IF([test "$enable_qt" = "no"], [
3738   AS_IF([test "${enable_skins2}" = "yes"], [
3739     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3740   ], [
3741     enable_skins2="no"
3742     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3743   ])
3744 ])
3745
3746 dnl
3747 dnl Skins2 module
3748 dnl
3749 AC_ARG_ENABLE([skins2],
3750   AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)]))
3751 AS_IF([test "${enable_skins2}" != "no"], [
3752   have_skins_deps="yes"
3753
3754   dnl Win32
3755   AS_IF([test "${SYS}" = "mingw32"], [
3756     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3757     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3758   dnl OS/2
3759   ], [test "${SYS}" = "os2"], [
3760     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3761   dnl Linux/Unix
3762   ], [
3763     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3764     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3765     PKG_CHECK_MODULES([XCURSOR], [xcursor],, [have_skins_deps="no"])
3766     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3767     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3768     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} ${XCURSOR_LIBS} -lX11])
3769   ])
3770
3771   dnl we need freetype
3772   AS_IF([test "${have_freetype}" != "yes"], [
3773     have_skins_deps="no"
3774   ])
3775
3776   AS_IF([test "${have_skins_deps}" = "no"], [
3777     AS_IF([test "x${enable_skins2}" = "x"], [
3778       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3779     ], [
3780       AC_MSG_ERROR([Skins2 interface requires FreeType, libxcursor, libxpm, libxext and libxinerama])
3781     ])
3782     enable_skins2="no"
3783   ], [
3784     ALIASES="${ALIASES} svlc"
3785     enable_skins2="yes"
3786   ])
3787 ])
3788 AM_CONDITIONAL([BUILD_SKINS], [test "${enable_skins2}" = "yes"])
3789
3790 AC_ARG_ENABLE([libtar],
3791   AS_HELP_STRING([--enable-libtar], [libtar support for skins2 (default auto)]))
3792 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3793   AC_CHECK_HEADERS([libtar.h], [
3794     VLC_ADD_LIBS([skins2],[-ltar])
3795   ])
3796 ])
3797
3798 dnl
3799 dnl  MacOS X gui module
3800 dnl
3801 AC_ARG_ENABLE([macosx],
3802   AS_HELP_STRING([--enable-macosx], [Mac OS X gui support (default enabled on Mac OS X)]))
3803 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3804 then
3805
3806   dnl
3807   dnl If possible, use xcrun to find the right ibtool
3808   dnl
3809
3810   AC_PATH_PROG([XCRUN], [xcrun], [no])
3811   AS_IF([test ! "x${XCRUN}" = "xno"], [
3812     AC_MSG_CHECKING([for ibtool (using xcrun)])
3813     XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3814     AC_MSG_RESULT([${XIB}])
3815   ], [
3816     AC_MSG_WARN([Looking for tools without using xcrun])
3817   ])
3818
3819   AS_IF([test "x${XIB}" = "xno"], [
3820     AC_PATH_PROG(XIB, [ibtool], [no])
3821     AS_IF([test "x${XIB}" = "xno"], [
3822       AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3823     ])
3824   ])
3825 fi
3826 AM_CONDITIONAL([ENABLE_MACOSX_UI], [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3827
3828 dnl
3829 dnl  MacOS X sparkle update support
3830 dnl
3831 AC_ARG_ENABLE([sparkle],
3832   AS_HELP_STRING([--enable-sparkle], [Sparkle update support for OS X (default enabled on Mac OS X)]))
3833 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3834 then
3835   if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3836   then
3837     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3838   fi
3839
3840   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3841 fi
3842 AM_CONDITIONAL([HAVE_SPARKLE], [test "$enable_sparkle" != "no"])
3843
3844 dnl
3845 dnl  MacOS X breakpad creash reporter support
3846 dnl
3847 AC_ARG_WITH([breakpad],
3848   AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
3849
3850 AS_IF([test "$with_breakpad" != "no"], [
3851
3852   AS_IF([test "$with_breakpad" = "yes"], [
3853     AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
3854   ])
3855
3856   AS_IF([test "$HAVE_OSX" = "1"], [
3857     AC_MSG_CHECKING([for Breakpad framework])
3858     AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
3859                 ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
3860       AC_MSG_RESULT([no])
3861       with_breakpad="no"
3862       AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3863     ], [
3864       AC_MSG_RESULT([yes])
3865     ])
3866   ],[
3867     PKG_CHECK_MODULES([BREAKPAD], [breakpad-client], [
3868       LDFLAGS="${LDFLAGS} -Wl,--build-id"
3869     ], [
3870       AC_MSG_ERROR(["breakpad not found"])
3871     ])
3872   ])
3873 ])
3874
3875 AM_CONDITIONAL([HAVE_BREAKPAD], [test "$with_breakpad" != "no"])
3876 AS_IF([test "$with_breakpad" != "no"], [
3877   AC_SUBST([BREAKPAD_URL], ["${with_breakpad}"])
3878 ])
3879
3880 dnl
3881 dnl  Minimal Mac OS X module
3882 dnl
3883 AC_ARG_ENABLE([minimal-macosx],
3884   AS_HELP_STRING([--enable-minimal-macosx], [Minimal Mac OS X support (default disabled)]))
3885 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3886 then
3887   VLC_ADD_PLUGIN([minimal_macosx])
3888 fi
3889
3890 dnl
3891 dnl Mac OS X fancy dmg build tool
3892 dnl
3893 if test "${HAVE_OSX}" = "1"
3894 then
3895   AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3896   AS_IF([test "x${DMGBUILD}" = "xno"], [
3897     AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3898   ])
3899 fi
3900 AM_CONDITIONAL([HAVE_DMGBUILD], [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3901
3902 dnl
3903 dnl  VideoToolbox plugins
3904 AC_CHECK_HEADERS([VideoToolbox/VideoToolbox.h], [
3905     VLC_ADD_PLUGIN([videotoolbox])
3906     VLC_ADD_PLUGIN([cvpx])
3907   ])
3908
3909 dnl
3910 dnl  AudioToolbox MIDI plugin
3911 AC_CHECK_HEADERS([AudioToolbox/AudioToolbox.h], [
3912   VLC_ADD_PLUGIN([audiotoolboxmidi])
3913 ])
3914
3915 dnl
3916 dnl  ncurses module
3917 dnl
3918 AC_ARG_ENABLE([ncurses],
3919 AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)]))
3920 have_ncurses="no"
3921 AS_IF([test "${enable_ncurses}" != "no"] ,[
3922   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3923     have_ncurses="yes"
3924     ALIASES="${ALIASES} nvlc"
3925   ], [
3926     AS_IF([test -n "${enable_ncurses}"], [
3927       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3928     ])
3929   ])
3930 ])
3931 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3932
3933 dnl
3934 dnl  Lirc plugin
3935 dnl
3936 AC_ARG_ENABLE([lirc],
3937   AS_HELP_STRING([--enable-lirc], [lirc support (default disabled)]))
3938 have_lirc="no"
3939 AS_IF([test "${enable_lirc}" = "yes"], [
3940   AC_CHECK_HEADER(lirc/lirc_client.h, [
3941     AC_CHECK_LIB([lirc_client], [lirc_init], [
3942       have_lirc="yes"
3943     ])
3944   ])
3945 ])
3946 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3947
3948 dnl
3949 dnl  Bitstream
3950 dnl
3951 PKG_CHECK_MODULES([BITSTREAM], [bitstream > 1.4],[have_bitstream="yes"], [have_bitstream="no"])
3952 AM_CONDITIONAL([HAVE_BITSTREAM], [test "${have_bitstream}" = "yes"])
3953
3954 dnl
3955 dnl  SRT plugin
3956 dnl
3957 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.2], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
3958
3959 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3960 dnl
3961 dnl  goom visualization plugin
3962 dnl
3963 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3964
3965 dnl
3966 dnl libprojectM visualization plugin
3967 dnl
3968 AC_ARG_ENABLE([projectm],
3969   AS_HELP_STRING([--enable-projectm], [projectM visualization plugin (default enabled)]))
3970 AS_IF([test "${enable_projectm}" != "no"],
3971   [
3972     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3973     [
3974       VLC_ADD_PLUGIN([projectm])
3975       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3976         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3977         [ AC_MSG_WARN( [Using libprojectM version 1] )
3978       ])
3979     ],[
3980       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3981     ])
3982   ])
3983
3984 dnl
3985 dnl Vovoid VSXu visualization plugin
3986 dnl
3987 AC_ARG_ENABLE([vsxu],
3988   AS_HELP_STRING([--enable-vsxu], [Vovoid VSXu visualization plugin (default auto)]))
3989 AS_IF([test "${enable_vsxu}" != "no"],
3990   [
3991     PKG_CHECK_MODULES(VSXU, libvsxu,
3992     [
3993       VLC_ADD_PLUGIN([vsxu])
3994     ],[
3995       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3996     ])
3997   ])
3998
3999 EXTEND_HELP_STRING([Service Discovery plugins:])
4000 dnl
4001 dnl  Avahi-Zeroconf services discovery
4002 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
4003
4004 dnl
4005 dnl  libudev services discovery
4006 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4007
4008 dnl
4009 dnl MTP devices services discovery
4010 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4011
4012 dnl
4013 dnl UPnP Plugin (Intel SDK)
4014 dnl
4015 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4016
4017 dnl
4018 dnl mDNS using libmicrodns
4019 dnl
4020 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4021
4022
4023 EXTEND_HELP_STRING([Misc options:])
4024
4025 dnl
4026 dnl  libxml2 module
4027 dnl
4028 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4029
4030
4031 dnl
4032 dnl libgcrypt
4033 dnl
4034 AC_ARG_ENABLE([libgcrypt],
4035   AS_HELP_STRING([--disable-libgcrypt], [gcrypt support (default enabled)]))
4036 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4037 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4038
4039 # require libgcrypt >= 1.6.0
4040 AS_IF([test "${enable_libgcrypt}" != "no"], [
4041   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4042     VLC_SAVE_FLAGS
4043     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4044     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4045 [#include <gcrypt.h>
4046 #if GCRYPT_VERSION_NUMBER < 0x010600
4047 #error
4048 #endif]])], [
4049       ac_cv_lib_gcrypt=yes
4050     ], [
4051       ac_cv_lib_gcrypt=no
4052     ])
4053     VLC_RESTORE_FLAGS
4054   ])
4055
4056   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4057     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4058   ], [
4059     AS_IF([test "${enable_libgcrypt}" = "yes"], [
4060       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4061     ])
4062   ])
4063 ])
4064
4065 AS_IF([test -z "$GCRYPT_LIBS"], [
4066   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4067 ])
4068
4069 AC_SUBST([GCRYPT_CFLAGS])
4070 AC_SUBST([GCRYPT_LIBS])
4071 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4072
4073 dnl
4074 dnl TLS/SSL
4075 dnl
4076 AC_ARG_ENABLE([gnutls],
4077   AS_HELP_STRING([--enable-gnutls], [GNU TLS TLS/SSL support (default enabled)]))
4078 AS_IF([test "${enable_gnutls}" != "no"], [
4079   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4080     VLC_ADD_PLUGIN([gnutls])
4081   ], [
4082     AS_IF([test -n "${enable_gnutls}"], [
4083       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4084     ])
4085   ])
4086 ])
4087
4088
4089 dnl
4090 dnl Taglib plugin
4091 dnl
4092 AC_ARG_ENABLE([taglib],
4093   AS_HELP_STRING([--disable-taglib],
4094     [do not use TagLib (default enabled)]))
4095 AS_IF([test "${enable_taglib}" != "no"], [
4096   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4097     VLC_ADD_PLUGIN([taglib])
4098   ], [
4099     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4100 ])
4101
4102 dnl
4103 dnl  libsecret
4104 dnl
4105 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4106
4107 dnl
4108 dnl  kwallet
4109 dnl
4110 AC_ARG_ENABLE([kwallet],
4111   AS_HELP_STRING([--enable-kwallet],
4112     [use kwallet (via D-Bus) for keystore (default enabled)]))
4113 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4114   VLC_ADD_PLUGIN([kwallet])
4115 ])
4116
4117 dnl
4118 dnl update checking system
4119 dnl
4120 AC_ARG_ENABLE([update-check],
4121   AS_HELP_STRING([--enable-update-check], [update checking system (default disabled)]))
4122 if test "${enable_update_check}" = "yes"
4123 then
4124  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4125     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4126 fi
4127 AM_CONDITIONAL([UPDATE_CHECK], [test "${enable_update_check}" = "yes"])
4128
4129 dnl
4130 dnl OS X notification plugin
4131 dnl
4132 AC_ARG_ENABLE([osx_notifications],
4133   AS_HELP_STRING([--enable-osx-notifications],
4134     [macOS notification plugin (default disabled)]),,
4135   [enable_osx_notifications=no])
4136 AS_IF([test "${enable_osx_notifications}" != "no"], [
4137   VLC_ADD_PLUGIN([osx_notifications])
4138 ])
4139
4140 dnl
4141 dnl Libnotify notification plugin
4142 dnl
4143 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-3.0], [libnotify notification], [auto])
4144
4145 dnl
4146 dnl  libplacebo support
4147 dnl
4148 AC_ARG_ENABLE([libplacebo],
4149   AS_HELP_STRING([--disable-libplacebo],
4150       [disable libplacebo support (default auto)]))
4151
4152 AS_IF([test "$enable_libplacebo" != "no"], [
4153   PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.2.1], [
4154     AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
4155   ], [
4156     AS_IF([test -n "${enable_libplacebo}"], [
4157       AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
4158     ])
4159     enable_libplacebo="no"
4160   ])
4161 ])
4162 AM_CONDITIONAL([HAVE_LIBPLACEBO], [test "$enable_libplacebo" != "no"])
4163
4164 PKG_ENABLE_MODULES_VLC([MEDIALIBRARY], [medialibrary], [medialibrary], (medialibrary support), [auto])
4165
4166 dnl
4167 dnl  Endianness check
4168 dnl
4169 AC_C_BIGENDIAN
4170 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4171   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4172 ], [
4173   DEFS_BIGENDIAN=""
4174 ])
4175 AC_SUBST([DEFS_BIGENDIAN])
4176
4177 dnl
4178 dnl Where to install KDE solid .desktop
4179 dnl
4180 AC_ARG_WITH(kde-solid,
4181   AS_HELP_STRING([--with-kde-solid=PATH],
4182                  [KDE Solid actions directory (auto)]),, [
4183
4184 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4185   with_kde_solid="yes"
4186 fi
4187 ])
4188 soliddatadir=""
4189 AS_IF([test "${with_kde_solid}" != "no"], [
4190   AS_IF([test "${with_kde_solid}" = "yes"], [
4191     kde4datadir="`${KDE4_CONFIG} --install data`"
4192     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4193     soliddatadir="${kde4datadir}/solid/actions"
4194   ], [
4195     soliddatadir="${with_kde_solid}"
4196   ])
4197 ])
4198 AC_SUBST([soliddatadir])
4199 AM_CONDITIONAL([KDE_SOLID], [test "x${soliddatadir}" != "x"])
4200
4201 dnl
4202 dnl  Find tools for win32 packaging
4203 dnl
4204 AS_IF([test "${SYS}" = "mingw32"], [
4205     dnl
4206     dnl Find makensis required to build the NSIS installer
4207     dnl
4208     nsis_major_required="3"
4209     nsis_version_ok="no"
4210     AC_PATH_PROG([MAKENSIS], [makensis], [no])
4211     AS_IF([test "$MAKENSIS" != "no"], [
4212         # Check version
4213         AC_MSG_CHECKING([makensis version])
4214         nsis_version=$($MAKENSIS -VERSION)
4215         AC_MSG_RESULT([$nsis_version])
4216         nsis_version_major=$(echo "$nsis_version" | awk -F \. '{print $1}' | sed 's/v//')
4217         # Check if major version is a valid number
4218         AS_IF([test -n "$nsis_version_major" && \
4219                test "$nsis_version_major" -eq "$nsis_version_major" 2> /dev/null], [
4220             # Do the version check using major version
4221             AS_IF([test "$nsis_version_major" -lt "$nsis_major_required"], [
4222                 AC_MSG_WARN([makensis too old, (needs ${nsis_major_required}.x, have ${nsis_version_major}.x)])
4223             ], [
4224                 nsis_version_ok="yes"
4225             ])
4226         ], [
4227             AC_MSG_WARN([failed to check the makensis version])
4228         ])
4229     ])
4230     dnl
4231     dnl Find 7zip
4232     dnl
4233     AC_PATH_PROG([SEVENZIP], [7z], [7z])
4234 ])
4235 AM_CONDITIONAL([HAVE_MAKENSIS], [test "x$MAKENSIS" != "xno" && test "$nsis_version_ok" = "yes"])
4236
4237 dnl
4238 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4239 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4240 dnl
4241 if test "${SYS}" = "mingw32"; then
4242     AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4243 fi
4244
4245 EXTEND_HELP_STRING([Components:])
4246
4247 dnl
4248 dnl  the VLC binary
4249 dnl
4250 AC_ARG_ENABLE([vlc],
4251   AS_HELP_STRING([--enable-vlc], [build the VLC media player (default enabled)]))
4252 AM_CONDITIONAL([BUILD_VLC], [test "${enable_vlc}" != "no"])
4253
4254 dnl
4255 dnl Fuzzer (at the end in order to don't mess dependencies FLAGS)
4256 dnl
4257 AS_VAR_IF(with_libfuzzer, no, [], [
4258     LIBS="-lstdc++ ${LIBM} -L${with_libfuzzer} -lFuzzer"
4259     AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc-guard, [
4260         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard])
4261         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard], [CXXFLAGS])
4262         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp])
4263         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp], [CXXFLAGS])
4264     ], [
4265         AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc, [
4266             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc])
4267             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc], [CXXFLAGS])
4268         ], [
4269             AC_MSG_ERROR([Sanitizer coverage not supported by your compiler])
4270         ])
4271     ])
4272 ])
4273
4274 dnl
4275 dnl  Stuff used by the program
4276 dnl
4277 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4278 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4279 AC_DEFINE_UNQUOTED([VERSION_MESSAGE], "${VERSION_MESSAGE}", [Simple version string])
4280 AC_DEFINE_UNQUOTED([COPYRIGHT_MESSAGE], "${COPYRIGHT_MESSAGE}", [Copyright string])
4281 AC_DEFINE_UNQUOTED([COPYRIGHT_YEARS], "${COPYRIGHT_YEARS}", [The copyright years])
4282 AC_DEFINE_UNQUOTED([CONFIGURE_LINE], "${CONFIGURE_LINE}", [The ./configure command line])
4283 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_MAJOR],${VERSION_MAJOR}, [version major number])
4284 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_MINOR],${VERSION_MINOR}, [version minor number])
4285 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_REVISION],${VERSION_REVISION}, [version revision number])
4286 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_EXTRA],${VERSION_EXTRA}, [version extra number])
4287 AC_DEFINE_UNQUOTED([PACKAGE_VERSION_DEV],"${VERSION_DEV}", [version development string])
4288 AC_SUBST([COPYRIGHT_MESSAGE])
4289 AC_SUBST([VERSION_MESSAGE])
4290 AC_SUBST([VERSION_MAJOR])
4291 AC_SUBST([VERSION_MINOR])
4292 AC_SUBST([VERSION_REVISION])
4293 AC_SUBST([VERSION_EXTRA])
4294 AC_SUBST([COPYRIGHT_YEARS])
4295 AC_DEFINE_UNQUOTED([VLC_COMPILE_BY], "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4296 AC_DEFINE_UNQUOTED([VLC_COMPILE_HOST], "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4297 AC_DEFINE_UNQUOTED([VLC_COMPILER], "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4298 dnl
4299 dnl  Handle substvars that use $(top_srcdir)
4300 dnl
4301 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4302
4303 dnl
4304 dnl  Configuration is finished
4305 dnl
4306 AC_SUBST([SYS])
4307 AC_SUBST([ARCH])
4308 AC_SUBST([ALIASES])
4309 AC_SUBST([ASM])
4310 AC_SUBST([MOC])
4311 AC_SUBST([RCC])
4312 AC_SUBST([UIC])
4313 AC_SUBST([WINDRES])
4314 AC_SUBST([WINE_SDK_PATH])
4315 AC_SUBST([LIBEXT])
4316 AC_SUBST([AM_CPPFLAGS])
4317 AC_SUBST([MACOSX_DEPLOYMENT_TARGET])
4318 AC_SUBST([FILE_LIBVLCCORE_DLL])
4319 AC_SUBST([FILE_LIBVLC_DLL])
4320
4321 AC_CONFIG_FILES([
4322   Makefile
4323   doc/Makefile
4324   modules/Makefile
4325   m4/Makefile
4326   po/Makefile.in
4327   share/Makefile
4328   compat/Makefile
4329   src/Makefile
4330   lib/Makefile
4331   bin/Makefile
4332   test/Makefile
4333   modules/hw/mmal/Makefile
4334   share/vlc.appdata.xml.in
4335 ])
4336
4337 AM_COND_IF([HAVE_WIN32], [
4338   AC_CONFIG_FILES([
4339     extras/package/win32/NSIS/spad.nsi
4340     extras/package/win32/NSIS/vlc.win32.nsi
4341     extras/package/win32/msi/config.wxi
4342   ])
4343 ])
4344
4345 AM_COND_IF([HAVE_DARWIN], [
4346   AC_CONFIG_FILES([
4347     modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4348     share/macosx/Info.plist:share/Info.plist.in
4349   ])
4350 ])
4351
4352 dnl Generate makefiles
4353 AC_OUTPUT
4354
4355 dnl Do we have to use make or gmake ?
4356 if make --version 2>&1|grep -q GNU
4357 then
4358     # GNU make, all seems good
4359     MAKE=make
4360 else
4361     # Known GNU make alias (on BSD)
4362     MAKE=gmake
4363 fi
4364 dnl Shortcut to nice compile message
4365 if test -n $SHELL; then
4366   SHELL=${CONFIG_SHELL-/bin/sh}
4367 fi
4368 rm -f compile
4369 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4370 echo "#! $SHELL
4371 rm -f .error\$\$
4372 ERROR=0
4373 export PATH=\"$PATH\" LANG=C
4374 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4375 test -f .error\$\$ && ERROR=1
4376 rm -f .error\$\$
4377 exit \$ERROR" >compile
4378 chmod a+x compile
4379
4380 echo "
4381 libvlc configuration
4382 --------------------
4383 version               : ${VERSION}
4384 system                : ${SYS}
4385 architecture          : ${ARCH}
4386 optimizations         : ${enable_optimizations}"
4387 if test "${enable_vlc}" != "no"; then
4388 echo "vlc aliases           :${ALIASES}"
4389 else
4390 echo "build vlc executable  : no"
4391 fi
4392 echo "
4393 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."