| blob | 7af0979cfe1d6195f9d11620ba1372159072fda6 |
1 dnl Autoconf settings for vlc
3 AC_COPYRIGHT([Copyright 1999-2018 VLC authors and VideoLAN])
5 AC_INIT(vlc, 4.0.0-dev)
6 VERSION_MAJOR=4
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=dev
12 PKGDIR="vlc"
13 AC_SUBST(PKGDIR)
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Otto Chriek"
17 COPYRIGHT_YEARS="1996-2018"
19 AC_CONFIG_SRCDIR(src/libvlc.c)
20 AC_CONFIG_AUX_DIR(autotools)
21 AC_CONFIG_MACRO_DIR(m4)
22 AC_CONFIG_LIBOBJ_DIR(compat)
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
28 AC_CONFIG_HEADERS([config.h])
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
33 dnl
34 dnl Check for tools
35 dnl
36 AC_PROG_CC
37 AC_USE_SYSTEM_EXTENSIONS
38 VLC_PROG_CC_C11
39 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
40 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
41 AH_TOP([
42 #ifndef _REENTRANT
43 # define _REENTRANT
44 #endif
45 ])
46 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
47 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
48 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
50 AC_PROG_CXX
51 AC_PROG_CPP
52 AC_PROG_OBJC
53 AC_PROG_EGREP
54 AC_PROG_MAKE_SET
55 AC_PROG_INSTALL
56 AM_PROG_AS
57 AC_PROG_LEX
58 AC_PROG_YACC
60 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
61 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
62 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
63 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
64 AS_IF([test "$BUILDCC" = "false"], [
65 AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
66 ])
68 dnl Check for compiler properties
69 AC_C_CONST
70 AC_C_INLINE
71 AC_C_RESTRICT
72 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
74 dnl Extend the --help string at the current spot.
75 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
77 dnl Allow binary package maintainer to pass a custom string to avoid
78 dnl cache problem
79 AC_ARG_WITH(binary-version,
80 AS_HELP_STRING([--with-binary-version=STRING],
81 [To avoid plugins cache problem between binary version]),[],[])
82 AS_IF([test -n "${with_binary_version}"],[
83 AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
84 [Binary specific version])
85 ])
87 dnl Prevent clang from accepting unknown flags with a mere warning
88 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
89 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
91 dnl
92 dnl Check the operating system
93 dnl
94 HAVE_WIN64="0"
95 HAVE_IOS="0"
96 HAVE_OSX="0"
97 HAVE_TVOS="0"
99 case "${host_os}" in
100 "")
101 SYS=unknown
102 ;;
103 linux*)
104 SYS=linux
105 ;;
106 bsdi*)
107 SYS=bsdi
108 CFLAGS="${CFLAGS} -pthread"
109 ;;
110 freebsd*)
111 SYS=freebsd
112 CFLAGS="${CFLAGS} -pthread"
113 CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
114 LDFLAGS="${LDFLAGS} -L/usr/local/lib"
115 ac_cv_ld_z_defs=no
116 ;;
117 openbsd*)
118 SYS=openbsd
119 CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
120 LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
121 ;;
122 netbsd*)
123 SYS=netbsd
124 ;;
125 dragonfly*)
126 SYS=dragonfly
127 ;;
128 darwin*)
130 dnl Force gcc "-arch" flag
131 ARCH_flag=""
132 case "${host}" in
133 i?86*)
134 ARCH_flag="-arch i386"
135 ;;
136 ppc64*)
137 ARCH_flag="-arch ppc64"
138 ;;
139 ppc*)
140 ARCH_flag="-arch ppc"
141 ;;
142 x86_64*)
143 ARCH_flag="-arch x86_64"
144 ;;
145 arm*)
146 ac_cv_c_bigendian="no"
147 ac_cv_c_attribute_packed="no"
148 ;;
149 esac
151 SYS=darwin
152 CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
153 CXX="${CXX} -stdlib=libc++ -std=c++11"
154 CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
155 CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
156 OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
157 LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
158 VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
159 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
161 AC_EGREP_CPP(yes,
162 [#import <TargetConditionals.h>
163 #if TARGET_OS_IPHONE
164 yes
165 #endif],
166 [HAVE_IOS="1"],
167 [HAVE_OSX="1"])
169 AC_EGREP_CPP(yes,
170 [#import <TargetConditionals.h>
171 #if TARGET_OS_TV
172 yes
173 #endif],
174 [HAVE_TVOS="1"
175 HAVE_IOS="0"
176 HAVE_OSX="0"
177 ],)
179 dnl
180 dnl Handle Mac OS X SDK flags
181 dnl
182 AC_ARG_WITH(macosx-sdk,
183 [AS_HELP_STRING([--with-macosx-sdk=DIR],
184 [compile using the SDK in DIR])])
185 if test "${with_macosx_sdk}" != "" ; then
186 test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
187 CPP="${CPP} -isysroot ${with_macosx_sdk}"
188 CC="${CC} -isysroot ${with_macosx_sdk}"
189 CXX="${CXX} -isysroot ${with_macosx_sdk}"
190 OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
191 LD="${LD} -syslibroot ${with_macosx_sdk}"
192 fi
193 AC_ARG_WITH(macosx-version-min,
194 [AS_HELP_STRING([--with-macosx-version-min=VERSION],
195 [compile for Mac OS X VERSION and above])])
196 if test "${with_macosx_version_min}" != "" ; then
197 CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
198 CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
199 CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
200 OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
201 LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
202 fi
203 ;;
204 *mingw32* | *cygwin* | *wince* | *mingwce*)
205 dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
206 dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
207 CXXFLAGS="${CXXFLAGS} -static-libgcc"
208 AC_CHECK_TOOL(WINDRES, windres, :)
209 AC_CHECK_TOOL(OBJCOPY, objcopy, :)
210 AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
211 AH_TOP([# define _WIN32_WINNT 0x0601 /* Windows 7 */])
212 AH_TOP([#endif])
213 AC_DEFINE([_WIN32_WINNT], 0x0601, [Define to '0x0601' for Windows 7 APIs.])
214 AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
215 AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
216 AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
217 AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
218 AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
219 AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
220 AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
221 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
222 AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
223 AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
224 AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
226 case "${host_os}" in
227 *mingw32*)
228 SYS=mingw32
229 ;;
230 *cygwin*)
231 dnl Check if we are using the mno-cygwin mode in which case we are
232 dnl actually dealing with a mingw32 compiler.
233 AC_EGREP_CPP(yes,
234 [#ifdef _WIN32
235 yes
236 #endif],
237 SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
238 ;;
239 esac
241 if test "${SYS}" = "mingw32"; then
242 # DEP, ASLR, NO SEH
243 LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
245 AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
246 ac_default_prefix="`pwd`/_win32"
247 DESTDIR="`pwd`/_win32/"
249 dnl
250 dnl NSIS/MSI Installer prefix and WIN64
251 dnl
252 case "${host}" in
253 amd64*|x86_64*)
254 HAVE_WIN64="1"
255 WINDOWS_ARCH="x64"
256 PROGRAMFILES="PROGRAMFILES64"
257 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
258 ;;
259 *)
260 WINDOWS_ARCH="x86"
261 PROGRAMFILES="PROGRAMFILES"
262 ;;
263 esac
264 AC_SUBST(WINDOWS_ARCH)
265 AC_SUBST(PROGRAMFILES)
267 fi
268 ;;
269 *nto*)
270 SYS=nto
271 ;;
272 solaris*)
273 SYS=solaris
274 ;;
275 hpux*)
276 SYS=hpux
277 ;;
278 *os2*)
279 SYS=os2
280 LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
281 AC_LIBOBJ([freeaddrinfo])
282 AC_LIBOBJ([gai_strerror])
283 AC_CHECK_FUNCS([if_nametoindex])
284 ;;
285 *nacl*)
286 SYS=nacl
287 AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
288 AC_LIBOBJ([sigwait])
289 AC_LIBOBJ([recvmsg])
290 AC_LIBOBJ([sendmsg])
291 ;;
292 *)
293 SYS="${host_os}"
294 ;;
295 esac
297 dnl WinRT
298 AC_ARG_ENABLE(winstore_app,
299 AS_HELP_STRING([--enable-winstore-app],
300 [Build targetted for Windows Store apps (default disabled)]))
302 vlc_winstore_app=0
303 AS_IF([test "${SYS}" = "mingw32"],[
304 LIBCOM="-lole32"
305 AS_IF([test "${enable_winstore_app}" = "yes"], [
306 vlc_winstore_app=1
307 LIBCOM=""
308 VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
309 AC_LIBOBJ([gai_strerror])
310 ],[])
311 AC_SUBST(LIBCOM)
312 ])
313 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
315 AM_CONDITIONAL(HAVE_LINUX, test "${SYS}" = "linux")
316 AM_CONDITIONAL(HAVE_OS2, test "${SYS}" = "os2")
318 AM_CONDITIONAL(HAVE_DARWIN, test "${SYS}" = "darwin")
319 AM_CONDITIONAL(HAVE_IOS, test "${HAVE_IOS}" = "1")
320 AM_CONDITIONAL(HAVE_OSX, test "${HAVE_OSX}" = "1")
321 AM_CONDITIONAL(HAVE_TVOS, test "${HAVE_TVOS}" = "1")
323 AM_CONDITIONAL(HAVE_NACL, test "${SYS}" = "nacl")
324 AM_CONDITIONAL(HAVE_LIBANL, test "${HAVE_LIBANL}" = "1")
326 AM_CONDITIONAL(HAVE_WIN32, test "${SYS}" = "mingw32")
327 AM_CONDITIONAL(HAVE_WIN64, test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
328 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
329 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
331 dnl
332 dnl Sadly autoconf does not think about testing foo.exe when ask to test
333 dnl for program foo on win32
334 case "${build_os}" in
335 cygwin|msys|mingw32)
336 ac_executable_extensions=".exe"
337 BUILDEXEEXT=".exe"
338 ;;
339 os2*)
340 BUILDEXEEXT=".exe"
341 ;;
342 *)
343 ;;
344 esac
345 AC_SUBST(BUILDEXEEXT)
347 dnl Android is linux, but a bit different
348 AS_IF([test "$SYS" = linux],[
349 AC_MSG_CHECKING([for an Android system])
350 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
351 [[#ifndef __ANDROID__
352 # error Not Android
353 #endif
354 ]],[[;]])
355 ],[
356 HAVE_ANDROID="1"
357 AC_MSG_RESULT([yes])
358 ],[
359 AC_MSG_RESULT([no])
360 ])
361 ])
362 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
364 dnl Tizen (minimum SDK version: 2.3)
365 AS_IF([test "$SYS" = linux],[
366 AC_MSG_CHECKING([for Tizen])
367 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
368 [[#include <tizen.h>
369 ]],[[;]])
370 ],[
371 HAVE_TIZEN="1"
372 AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
373 AC_MSG_RESULT([yes])
374 ],[
375 AC_MSG_RESULT([no])
376 ])
377 ])
378 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
380 dnl
381 dnl Check for the contrib directory
382 dnl
383 AC_ARG_WITH(contrib,
384 [AS_HELP_STRING([--with-contrib[=DIR]],
385 [search for 3rd party libraries in DIR/include and DIR/lib])
386 ])
387 AC_MSG_CHECKING([for 3rd party libraries path])
388 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
389 CONTRIB_DIR="${srcdir}/contrib/${host}"
390 AS_IF([test ! -d "${CONTRIB_DIR}"], [
391 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
392 CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
393 AS_IF([test ! -d "${CONTRIB_DIR}"], [
394 echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
395 CONTRIB_DIR=""
396 AC_MSG_RESULT([not found])
397 ])
398 ])
399 ], [
400 AS_IF([test "${with_contrib}" != "no"], [
401 CONTRIB_DIR="${with_contrib}"
402 ], [
403 CONTRIB_DIR=""
404 AC_MSG_RESULT([disabled])
405 ])
406 ])
407 AS_IF([test -n "${CONTRIB_DIR}"], [
408 AS_IF([test -d "${CONTRIB_DIR}/lib"],[
409 CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
410 ], [
411 echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
412 CONTRIB_DIR=""
413 AC_MSG_RESULT([not usable])
414 ])
416 ])
417 AS_IF([test -n "${CONTRIB_DIR}"], [
418 AC_MSG_RESULT([${CONTRIB_DIR}])
419 CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
420 CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
421 CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
422 OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
423 export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
424 LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
426 AS_IF([test -z "$LUAC"], [
427 dnl Old contribs mixed cross-tools and cross-compiled executables
428 AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
429 LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
430 ])
432 dnl Newer contribs follow usual name space rules
433 AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
434 LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
435 ])
436 ])
438 AS_IF([test "${SYS}" = "darwin"], [
439 export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
440 export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
441 ])
442 ], [
443 AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
444 AC_MSG_ERROR([Third party libraries not found!])
445 ])
446 ])
447 AC_SUBST(CONTRIB_DIR)
449 dnl Add extras/tools to the PATH
450 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
451 AS_IF([test -d "${TOOLS_DIR}"], [
452 TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
453 export PATH="${TOOLS_DIR}":$PATH
454 ])
456 dnl
457 dnl Libtool
458 dnl It's very bad, but our former custom system was worst
459 dnl -- Courmisch
460 dnl
462 dnl override platform specific check for dependent libraries
463 dnl otherwise libtool linking of shared libraries will
464 dnl fail on anything other than pass_all.
465 AC_CACHE_VAL(lt_cv_deplibs_check_method,
466 [lt_cv_deplibs_check_method=pass_all])
468 LT_INIT([dlopen win32-dll shared disable-static])
469 LT_LANG([C++])
470 LT_LANG([Windows Resource])
472 DOLT
474 lt_cv_deplibs_check_method=pass_all
476 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
477 AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
478 ])
480 dnl
481 dnl Gettext stuff
482 dnl
483 AM_GNU_GETTEXT_VERSION([0.19.8])
484 AM_GNU_GETTEXT([external], [need-formatstring-macros])
486 dnl
487 dnl Iconv stuff
488 dnl
489 AM_ICONV
491 dnl
492 dnl checks for mingw
493 AS_IF([test "${SYS}" = "mingw32"], [
495 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
496 #if !defined(__MINGW32__)
497 # error Not compiling with mingw
498 #endif
499 ])], [
501 dnl Check for broken versions of mingw-runtime compatability library
502 AC_MSG_CHECKING(for broken mingw-runtime)
503 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
504 #include <_mingw.h>
505 #if defined(__MINGW64_VERSION_MAJOR)
506 # if __MINGW64_VERSION_MAJOR < 5
507 # error Update your mingw-w64! This one is too old.
508 # endif
509 #else
510 # error You cannot compile with Mingw. Use Mingw-w64!
511 #endif
512 ])], [
513 AC_MSG_RESULT([ok])
514 ], [
515 AC_MSG_RESULT([present])
516 AC_MSG_ERROR([LibVLC requires Mingw-w64 version 5.0 or higher!])
517 ])
519 dnl force use of mingw provided c99 *printf over msvcrt
520 CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
522 dnl Check for the need to include the mingwex lib for mingw32
523 VLC_SAVE_FLAGS
524 AC_CHECK_LIB(mingwex,opendir,
525 AC_CHECK_LIB(mingw32,opendir,,
526 [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
527 )
528 VLC_RESTORE_FLAGS
529 ], [
530 AC_MSG_RESULT([Not compiling with mingw])
531 ])
533 dnl Check for fnative-struct or mms-bitfields support for mingw32
534 AX_CHECK_COMPILE_FLAG([-mms-bitfields], [
535 AX_APPEND_FLAG([-mms-bitfields], [CFLAGS])
536 AX_APPEND_FLAG([-mms-bitfields], [CXXFLAGS])
537 # Check for the warning flag without "-Wno-", GCC accepts
538 # -Wno-<anything> for unsupported warnings, which can trigger
539 # other warnings instead.
540 AX_CHECK_COMPILE_FLAG([-Wincompatible-ms-struct], [
541 AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CFLAGS])
542 AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CXXFLAGS])
543 ])
544 ], [
545 AX_CHECK_COMPILE_FLAG([-fnative-struct], [
546 AX_APPEND_FLAG([-fnative-struct], [CFLAGS])
547 AX_APPEND_FLAG([-fnative-struct], [CXXFLAGS])
548 ])
549 ])
550 ])
553 dnl
554 dnl Buggy glibc prevention. Purposedly not cached.
555 dnl See sourceware.org bugs 5058 and 5443.
556 dnl Ubuntu alone has 20 bug numbers for this...
557 dnl
558 AC_MSG_CHECKING(for buggy GNU/libc versions)
559 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
560 #include <limits.h>
561 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
562 && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
563 # error GNU/libc with dcgettext killer bug!
564 #endif
565 ])], [
566 AC_MSG_RESULT([not present])
567 ], [
568 AC_MSG_RESULT([found])
569 AS_IF([test "x${enable_nls}" != "xno"], [
570 AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
571 work-around for this. Check with your distribution vendor on how to update the
572 glibc run-time. Alternatively, build with --disable-nls.])
573 ])
574 ])
576 dnl Plugin compilation stuff
578 VLC_LIBRARY_SUFFIX
580 dnl Check for system libs needed
581 need_libc=false
583 dnl Check for usual libc functions
584 AC_CHECK_FUNCS([accept4 daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty memalign mkostemp mmap open_memstream newlocale openat pipe2 pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime uselocale])
585 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir flockfile fsync getdelim getpid lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy tfind timegm timespec_get strverscmp pathconf])
586 AC_REPLACE_FUNCS([gettimeofday])
587 AC_CHECK_FUNC(fdatasync,,
588 [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
589 ])
591 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
593 dnl mingw64 implements those as static inline, not functions with C linkage
594 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
595 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
596 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
597 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
599 dnl C11 static_assert()
600 AC_MSG_CHECKING([for static_assert in assert.h])
601 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
602 static_assert(1, "The impossible happened.");
603 ])], [
604 AC_MSG_RESULT([yes])
605 AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
606 ], [
607 AC_MSG_RESULT([no])
608 ])
610 # Windows CE does not have strcoll()
611 AC_FUNC_STRCOLL
613 dnl Check for non-standard system calls
614 case "$SYS" in
615 "linux")
616 AC_CHECK_FUNCS([eventfd vmsplice sched_getaffinity recvmmsg memfd_create])
617 ;;
618 "mingw32")
619 AC_CHECK_FUNCS([_lock_file])
620 ;;
621 esac
623 AH_BOTTOM([#include <vlc_fixups.h>])
625 dnl Check for struct pollfd
626 AC_CHECK_TYPES([struct pollfd],,,
627 [#include <sys/types.h>
628 #if HAVE_POLL
629 # include <poll.h>
630 #elif defined (_WIN32)
631 # include <winsock2.h>
632 #endif
633 ])
635 dnl Check for struct timespec
636 AC_CHECK_TYPES([struct timespec],,,
637 [#include <time.h>])
639 dnl Check for max_align_t
640 AC_CHECK_TYPES([max_align_t],,,
641 [#include <stddef.h>])
643 dnl Checks for socket stuff
644 VLC_SAVE_FLAGS
645 SOCKET_LIBS=""
646 AC_SEARCH_LIBS(connect, [socket], [
647 AS_IF([test "$ac_cv_search_connect" != "none required"], [
648 SOCKET_LIBS="$ac_cv_search_connect"
649 ])
650 ], [
651 AS_IF([test "${SYS}" = "mingw32"], [
652 SOCKET_LIBS="-lws2_32 -liphlpapi"
653 ])
654 ])
656 AC_SEARCH_LIBS([inet_pton], [nsl], [
657 AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
658 SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
659 ])
660 ],, [${SOCKET_LIBS}])
662 LIBS="${LIBS} ${SOCKET_LIBS}"
663 AC_LINK_IFELSE([
664 AC_LANG_PROGRAM([#ifdef _WIN32
665 #include <ws2tcpip.h>
666 #include <windows.h>
667 # if _WIN32_WINNT < 0x600
668 # error Needs vista+
669 # endif
670 #else
671 #include <sys/socket.h>
672 #include <arpa/inet.h>
673 #endif], [
674 char dst[[sizeof(struct in_addr)]];
675 inet_pton(AF_INET, "127.0.0.1", dst);
676 ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
677 AC_CHECK_FUNCS([if_nameindex])
678 VLC_RESTORE_FLAGS
679 AC_SUBST(SOCKET_LIBS)
681 dnl Check for socklen_t
682 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
683 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
684 ac_cv_type_socklen_t,
685 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
686 [#include <sys/types.h>
687 #ifdef _WIN32
688 # include <winsock2.h>
689 # include <ws2tcpip.h>
690 #else
691 # include <sys/socket.h>
692 #endif]], [[socklen_t len; len = 0;]])],
693 ac_cv_type_socklen_t=yes,
694 ac_cv_type_socklen_t=no)])
695 AS_IF([test "$ac_cv_type_socklen_t" = no],
696 [AC_DEFINE(socklen_t, int)])
698 dnl Check for struct sockaddr_storage
699 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
700 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
701 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
702 [AC_TRY_COMPILE(
703 [#include <sys/types.h>
704 #if defined( _WIN32 )
705 # include <winsock2.h>
706 #else
707 # include <sys/socket.h>
708 #endif], [struct sockaddr_storage addr;],
709 ac_cv_struct_sockaddr_storage=yes,
710 ac_cv_struct_sockaddr_storage=no)])
711 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
712 AC_DEFINE(sockaddr_storage, sockaddr)
713 AC_DEFINE(ss_family, sa_family)
714 ])
716 dnl FreeBSD has a gnugetopt library for this:
717 GNUGETOPT_LIBS=""
718 AC_CHECK_FUNC(getopt_long,, [
719 AC_CHECK_LIB([gnugetopt],[getopt_long], [
720 GNUGETOPT_LIBS="-lgnugetopt"
721 ])
722 ])
723 AC_SUBST(GNUGETOPT_LIBS)
725 AC_CHECK_LIB(m,cos,[
726 LIBM="-lm"
727 ], [
728 LIBM=""
729 ])
730 AC_SUBST(LIBM)
732 AC_CHECK_LIB(m,lrintf, [
733 AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
734 VLC_ADD_LIBS([skins2],[-lm])
735 ])
736 AC_CHECK_LIB(m,nanf,
737 AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
738 )
739 AC_CHECK_LIB(m,sincos, [
740 AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
741 ], [
742 AC_LIBOBJ([sincos])
743 ])
745 AC_MSG_CHECKING([_Thread_local support])
746 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
747 int main() {}])], [
748 AC_MSG_RESULT([ok])
749 AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
750 ],[ AC_MSG_RESULT([no])])
752 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
753 dnl check for its availability explicitely
754 AC_CHECK_HEADERS([threads.h])
756 AC_CHECK_LIB([anl],[getaddrinfo_a],[
757 AC_DEFINE(HAVE_LIBANL, 1, [Define to 1 if you have the anl library])
758 ])
760 dnl Check for dynamic plugins
761 LIBDL=""
762 have_dynamic_objects="no"
763 VLC_SAVE_FLAGS
764 AC_SEARCH_LIBS(dlsym, [dl svld], [
765 AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
766 LIBDL="$ac_cv_search_dlsym"
767 ])
768 have_dynamic_objects="yes"
769 ])
770 VLC_RESTORE_FLAGS
772 # Windows
773 AS_IF([test "${SYS}" = "mingw32"], [
774 LIBDL=""
775 have_dynamic_objects="yes" #assume we can use shared objects
776 ])
778 AC_ARG_WITH([libfuzzer],
779 [AS_HELP_STRING([--with-libfuzzer=DIR],
780 [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)])],
781 [],
782 [with_libfuzzer=no])
783 AS_VAR_IF(with_libfuzzer, no, [], [
784 enable_shared=no
785 enable_static=yes
786 enable_vlc=no
787 ])
788 AM_CONDITIONAL(HAVE_LIBFUZZER, [test "${with_libfuzzer}" != "no"])
790 AS_IF([test "${enable_shared}" = "no"], [
791 have_dynamic_objects=no
792 ])
793 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
795 AC_SUBST(LIBDL)
797 dnl Check for thread library
798 LIBPTHREAD=""
799 AS_IF([test "${SYS}" != "mingw32"], [
800 VLC_SAVE_FLAGS
801 LIBS=""
802 AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
803 AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
804 LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
805 ])
806 ])
807 VLC_RESTORE_FLAGS
808 ])
809 AC_SUBST(LIBPTHREAD)
811 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
812 AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
813 LIBRT="$ac_cv_search_clock_nanosleep"
814 ])
815 ], [
816 AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
817 AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
818 LIBRT="$ac_cv_search_nanosleep"
819 ])
820 ])
821 ])
822 AC_SUBST(LIBRT)
824 dnl
825 dnl Check for headers
826 dnl
828 dnl POSIX
829 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
830 AC_CHECK_HEADERS([net/if.h], [], [],
831 [
832 #include <sys/types.h>
833 #include <sys/socket.h>
834 ])
835 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
836 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
838 dnl BSD
839 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
841 dnl GNU/Linux
842 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
844 dnl MacOS
845 AC_CHECK_HEADERS([xlocale.h])
847 dnl Check if C++ headers define locale_t
848 AC_LANG_PUSH(C++)
849 AC_CACHE_CHECK([if C++ headers define locale_t],
850 [ac_cv_cxx_locale_t],
851 [ac_cv_cxx_locale_t=no
852 AC_TRY_COMPILE([#include <locale>], [locale_t loc;],
853 [ac_cv_cxx_locale_t=yes])])
854 if test "${ac_cv_cxx_locale_t}" != "no"; then
855 AC_DEFINE(HAVE_CXX_LOCALE_T, 1, Define to 1 if C++ headers define locale_t)
856 fi
857 AC_LANG_POP(C++)
859 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
860 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
861 AC_CHECK_TYPE(ssize_t,, [
862 AC_DEFINE(ssize_t, int)
863 ])
865 dnl It seems that autoconf detects pkg-config only during the first
866 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
867 dnl it is nested within a conditional block, so it was not working right.
868 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
869 AC_ARG_VAR(PKG_CONFIG_PATH,
870 [Paths where to find .pc not at the default location])
871 PKG_PROG_PKG_CONFIG()
873 dnl On some OS we need static linking
874 AS_IF([test -n "${PKG_CONFIG}" ],[
875 AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
876 PKG_CONFIG="${PKG_CONFIG} --static"
877 ])
878 ])
881 dnl
882 dnl Check for zlib.h and -lz along with system -lminizip if available
883 dnl
884 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
885 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
886 if test "${have_zlib}" = "yes"
887 then
888 VLC_ADD_LIBS([sap],[-lz])
889 PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
890 AC_CHECK_HEADERS([unzip.h], [
891 have_minizip=yes
892 MINIZIP_LIBS="-lminizip -lz"
893 ], [
894 have_minizip=no
895 ])
896 ])
897 fi
898 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
901 dnl
902 dnl Domain name i18n support via GNU libidn
903 dnl
904 PKG_CHECK_MODULES([IDN], [libidn], [
905 have_libidn="yes"
906 AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
907 ], [
908 have_libidn="no"
909 ])
912 dnl Check for dbus
913 AC_ARG_ENABLE(dbus,
914 [AS_HELP_STRING([--enable-dbus],
915 [compile D-Bus message bus support (default enabled)])])
916 have_dbus="no"
917 AS_IF([test "${enable_dbus}" != "no"], [
918 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
919 have_dbus="yes"
920 ], [
921 AS_IF([test -n "${enable_dbus}"], [
922 AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
923 ], [
924 AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
925 ])
926 ])
927 ])
928 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
931 dnl Check for systemd
932 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
933 have_systemd="yes"
934 ], [
935 AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
936 ])
937 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
940 EXTEND_HELP_STRING([Optimization options:])
941 dnl
942 dnl Compiler warnings
943 dnl
945 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CFLAGS])
946 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security], [CXXFLAGS])
948 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local -Wmultistatement-macros], [CFLAGS])
949 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
951 dnl
952 dnl Debugging mode
953 dnl
954 AC_ARG_ENABLE(debug,
955 [AS_HELP_STRING([--enable-debug],
956 [build with run-time assertions (default disabled)])],,
957 [enable_debug="no"])
958 AH_TEMPLATE(NDEBUG,
959 [Define to 1 if debug code should NOT be compiled])
960 AS_IF([test "${enable_debug}" != "no"], [
961 AC_CHECK_HEADERS([valgrind/valgrind.h])
962 ], [
963 AC_DEFINE(NDEBUG)
964 ])
966 dnl
967 dnl Profiling
968 dnl
969 AC_ARG_ENABLE(gprof,
970 [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
971 [enable_gprof="no"])
972 AS_IF([test "${enable_gprof}" != "no"], [
973 CFLAGS="${CFLAGS} -pg"
974 CXXFLAGS="${CXXFLAGS} -pg"
975 OBJCFLAGS="${OBJCFLAGS} -pg"
976 LDFLAGS="${LDFLAGS} -pg"
977 ])
979 AC_ARG_ENABLE(cprof,
980 [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
981 [enable_cprof="no"])
982 AS_IF([test "${enable_gprof}" != "no"], [
983 CFLAGS="${CFLAGS} -finstrument-functions"
984 CXXFLAGS="${CXXFLAGS} -finstrument-functions"
985 OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
986 LDFLAGS="${LDFLAGS} -finstrument-functions"
987 ])
989 dnl
990 dnl Test coverage
991 dnl
992 AC_ARG_ENABLE(coverage,
993 [AS_HELP_STRING([--enable-coverage],
994 [build for test coverage (default disabled)])],,
995 [enable_coverage="no"])
996 AS_IF([test "${enable_coverage}" != "no"], [
997 CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
998 CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
999 LDFLAGS="-lgcov ${LDFLAGS}"
1000 ])
1002 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
1003 VLC_SAVE_FLAGS
1004 CFLAGS="${CFLAGS} -fvisibility=hidden"
1005 CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
1006 OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1007 AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1008 [ac_cv_c_visibility_hidden], [
1009 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1010 ac_cv_c_visibility_hidden=yes
1011 ], [
1012 ac_cv_c_visibility_hidden=no
1013 ])
1014 ])
1015 AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1016 ])
1018 dnl
1019 dnl Sanitizer flags
1020 dnl
1021 AC_ARG_WITH([sanitizer],
1022 [AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1023 [build with sanitizer flags (default disabled)])],
1024 [],
1025 [with_sanitizer=no])
1027 AS_VAR_IF(with_sanitizer, no, [], [
1028 AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1029 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1030 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1031 AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1032 ], [
1033 AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1034 ])
1035 AX_APPEND_FLAG([-g])
1036 AX_APPEND_FLAG([-g], [CXXFLAGS])
1038 AS_IF([test -z "${with_sanitizer##*address*}" ], [
1039 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer])
1040 AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer], [CXXFLAGS])
1041 ])
1042 AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1043 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1044 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1045 ])
1046 AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1047 AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1048 AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1049 ])
1050 ])
1052 dnl
1053 dnl Enable/disable optimizations
1054 dnl
1055 AC_ARG_ENABLE(optimizations,
1056 [AS_HELP_STRING([--disable-optimizations],
1057 [disable compiler optimizations (default enabled)])],,
1058 [enable_optimizations="yes"])
1060 dnl Check for various optimization flags
1061 AS_IF([test "${enable_optimizations}" != "no"], [
1063 dnl -O3 only in production builds
1064 AS_IF([test "${enable_debug}" = "no"], [
1065 VLC_SAVE_FLAGS
1066 CFLAGS="${CFLAGS} -O3"
1067 CXXFLAGS="${CXXFLAGS} -O3"
1068 OBJCFLAGS="${OBJCFLAGS} -O3"
1069 AC_CACHE_CHECK([if $CC accepts -O3], [ac_cv_c_o3], [
1070 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1071 ac_cv_c_o3=yes
1072 ], [
1073 ac_cv_c_o3=no
1074 ])
1075 ])
1076 AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1077 ])
1079 dnl Check for fast maths
1080 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1081 AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1083 AH_BOTTOM([
1084 #if defined(_MSC_VER) && !defined(__clang__)
1085 # pragma fenv_access(off)
1086 # pragma fp_contract(on)
1087 #elif defined(__GNUC__)
1088 /* Not supported so far */
1089 #else
1090 # pragma STDC FENV_ACCESS OFF
1091 # pragma STDC FP_CONTRACT ON
1092 #endif
1093 ])
1095 dnl Check for -funroll-loops
1096 VLC_SAVE_FLAGS
1097 CFLAGS="${CFLAGS} -funroll-loops"
1098 CXXFLAGS="${CXXFLAGS} -funroll-loops"
1099 OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1100 AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1101 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1102 ac_cv_c_unroll_loops=yes
1103 ], [
1104 ac_cv_c_unroll_loops=no
1105 ])
1106 ])
1107 AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1109 AS_IF([test "$enable_debug" = "no"], [
1110 dnl Check for -fomit-frame-pointer
1111 VLC_SAVE_FLAGS
1112 CFLAGS="${CFLAGS} -fomit-frame-pointer"
1113 CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1114 OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1115 AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1116 [ac_cv_c_omit_frame_pointer], [
1117 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1118 ac_cv_c_omit_frame_pointer=yes
1119 ], [
1120 ac_cv_c_omit_frame_pointer=no
1121 ])
1122 ])
1123 AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1124 ])
1126 VLC_SAVE_FLAGS
1127 AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1128 AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1129 dnl Win32 requires linking to ssp for stack-protection
1130 AS_IF([test "${SYS}" = "mingw32"], [
1131 LDFLAGS="${LDFLAGS} -lssp"
1132 AS_IF([test "${vlc_winstore_app}" != 1], [LDFLAGS="${LDFLAGS} -ladvapi32"])
1133 AC_CACHE_CHECK([if linker supports stack protectors], [ac_cv_ld_ssp], [
1134 AC_TRY_LINK([#include <stdio.h>],[char buf[100]; fgets(buf, sizeof(buf), stdin);], [
1135 ac_cv_ld_ssp="yes"
1136 ], [
1137 ac_cv_ld_ssp="no"
1138 ])
1139 ])
1140 AS_IF([test "${ac_cv_ld_ssp}" = "no"], [VLC_RESTORE_FLAGS])
1141 ])
1142 ])
1144 VLC_SAVE_FLAGS
1145 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1146 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1147 AC_TRY_LINK([],, [
1148 ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1149 ], [
1150 ac_cv_ld_bsymbolic=""
1151 ])
1152 ])
1153 VLC_RESTORE_FLAGS
1154 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1155 AC_SUBST(SYMBOLIC_LDFLAGS)
1157 VLC_SAVE_FLAGS
1158 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1159 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1160 AC_TRY_LINK([],, [
1161 ac_cv_ld_z_defs="yes"
1162 ], [
1163 ac_cv_ld_z_defs="no"
1164 ])
1165 ])
1166 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1168 dnl Check for __attribute__((packed))
1169 AC_CACHE_CHECK([for __attribute__((packed))],
1170 [ac_cv_c_attribute_packed],
1171 [ac_cv_c_attribute_packed=no
1172 AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1173 [ac_cv_c_attribute_packed=yes])])
1174 if test "${ac_cv_c_attribute_packed}" != "no"; then
1175 AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1176 fi
1178 dnl
1179 dnl Check the CPU
1180 dnl
1181 case "${host_cpu}" in
1182 "")
1183 ARCH=unknown
1184 ;;
1185 armv*)
1186 ARCH="arm"
1187 host_cpu="arm"
1188 ;;
1189 *)
1190 ARCH="${host_cpu}"
1191 ;;
1192 esac
1194 dnl Check for backtrace() support
1195 AC_CHECK_HEADERS(execinfo.h)
1196 AC_CHECK_FUNCS(backtrace)
1198 dnl
1199 dnl default modules
1200 dnl
1201 ALIASES="${ALIASES} cvlc rvlc"
1203 dnl
1204 dnl Accelerated modules
1205 dnl
1207 dnl Check for fully working MMX intrinsics
1208 dnl We need support for -mmmx, we need <mmintrin.h>, and we also need a
1209 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1210 AC_ARG_ENABLE(mmx,
1211 [AS_HELP_STRING([--disable-mmx],
1212 [disable MMX optimizations (default auto)])],,[
1213 case "${host_cpu}" in
1214 i?86|x86_64)
1215 enable_mmx="yes"
1216 ;;
1217 *)
1218 enable_mmx="no"
1219 ;;
1220 esac
1221 ])
1222 have_mmx="no"
1223 have_mmxext="no"
1224 AS_IF([test "${enable_mmx}" != "no"], [
1225 ARCH="${ARCH} mmx"
1226 VLC_SAVE_FLAGS
1227 CFLAGS="${CFLAGS} -mmmx"
1228 AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1229 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1230 [#include <mmintrin.h>
1231 #include <stdint.h>
1232 uint64_t frobzor;]], [
1233 [__m64 a, b, c;
1234 a = b = c = (__m64)frobzor;
1235 a = _mm_slli_pi16(a, 3);
1236 a = _mm_adds_pi16(a, b);
1237 c = _mm_srli_pi16(c, 8);
1238 c = _mm_slli_pi16(c, 3);
1239 b = _mm_adds_pi16(b, c);
1240 a = _mm_unpacklo_pi8(a, b);
1241 frobzor = (uint64_t)a;]])], [
1242 ac_cv_c_mmx_intrinsics=yes
1243 ], [
1244 ac_cv_c_mmx_intrinsics=no
1245 ])
1246 ])
1247 VLC_RESTORE_FLAGS
1248 AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1249 AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1250 ])
1252 VLC_SAVE_FLAGS
1253 CFLAGS="${CFLAGS} -mmmx"
1254 AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1255 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1256 void *p;
1257 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1258 ]])
1259 ], [
1260 ac_cv_mmx_inline=yes
1261 ], [
1262 ac_cv_mmx_inline=no
1263 ])
1264 ])
1265 AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1266 AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1267 have_mmx="yes"
1268 ])
1270 AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1271 [ac_cv_mmxext_inline], [
1272 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1273 void *p;
1274 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1275 ]])
1276 ], [
1277 ac_cv_mmxext_inline=yes
1278 ], [
1279 ac_cv_mmxext_inline=no
1280 ])
1281 ])
1282 VLC_RESTORE_FLAGS
1283 AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1284 AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1285 have_mmxext="yes"
1286 ])
1287 ])
1288 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1289 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1291 dnl Check for fully workin SSE2 intrinsics
1292 dnl We need support for -mmmx, we need <emmintrin.h>, and we also need a
1293 dnl working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1294 AC_ARG_ENABLE(sse,
1295 [AS_HELP_STRING([--disable-sse],
1296 [disable SSE (1-4) optimizations (default auto)])],, [
1297 case "${host_cpu}" in
1298 i?86|x86_64)
1299 enable_sse=yes
1300 ;;
1301 *)
1302 enable_sse=no
1303 ;;
1304 esac
1305 ])
1306 have_sse2="no"
1307 AS_IF([test "${enable_sse}" != "no"], [
1308 ARCH="${ARCH} sse sse2"
1310 VLC_SAVE_FLAGS
1311 CFLAGS="${CFLAGS} -msse2"
1312 AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1313 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1314 [#include <emmintrin.h>
1315 #include <stdint.h>
1316 uint64_t frobzor;]], [
1317 [__m128i a, b, c;
1318 a = b = c = _mm_set1_epi64((__m64)frobzor);
1319 a = _mm_slli_epi16(a, 3);
1320 a = _mm_adds_epi16(a, b);
1321 c = _mm_srli_epi16(c, 8);
1322 c = _mm_slli_epi16(c, 3);
1323 b = _mm_adds_epi16(b, c);
1324 a = _mm_unpacklo_epi8(a, b);
1325 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1326 ac_cv_c_sse2_intrinsics=yes
1327 ], [
1328 ac_cv_c_sse2_intrinsics=no
1329 ])
1330 ])
1331 VLC_RESTORE_FLAGS
1332 AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1333 AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1334 ])
1336 VLC_SAVE_FLAGS
1337 CFLAGS="${CFLAGS} -msse"
1338 AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1339 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1340 void *p;
1341 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1342 ]])
1343 ], [
1344 ac_cv_sse_inline=yes
1345 ], [
1346 ac_cv_sse_inline=no
1347 ])
1348 ])
1350 AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1351 AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1352 ])
1354 AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1355 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1356 void *p;
1357 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1358 ]])
1359 ], [
1360 ac_cv_sse2_inline=yes
1361 ], [
1362 ac_cv_sse2_inline=no
1363 ])
1364 ])
1365 AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1366 AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1367 have_sse2="yes"
1368 ])
1370 # SSE3
1371 AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1372 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1373 void *p;
1374 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1375 ]])
1376 ], [
1377 ac_cv_sse3_inline=yes
1378 ], [
1379 ac_cv_sse3_inline=no
1380 ])
1381 ])
1383 AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1384 AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1385 # SSSE3
1386 AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1387 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1388 void *p;
1389 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1390 ]])
1391 ], [
1392 ac_cv_ssse3_inline=yes
1393 ], [
1394 ac_cv_ssse3_inline=no
1395 ])
1396 ])
1398 AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1399 AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1401 # SSE4.1
1402 AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1403 [ac_cv_sse4_1_inline], [
1404 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1405 void *p;
1406 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1407 ]])
1408 ], [
1409 ac_cv_sse4_1_inline=yes
1410 ], [
1411 ac_cv_sse4_1_inline=no
1412 ])
1413 ])
1415 AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1416 AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1418 # SSE4.2
1419 AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1420 [ac_cv_sse4_2_inline], [
1421 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1422 void *p;
1423 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1424 ]])
1425 ], [
1426 ac_cv_sse4_2_inline=yes
1427 ], [
1428 ac_cv_sse4_2_inline=no
1429 ])
1430 ])
1432 AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1433 AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1435 # SSE4A
1436 AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1437 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1438 void *p;
1439 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1440 ]])
1441 ], [
1442 ac_cv_sse4a_inline=yes
1443 ], [
1444 ac_cv_sse4a_inline=no
1445 ])
1446 ])
1447 VLC_RESTORE_FLAGS
1448 AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1449 AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1450 ])
1451 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1453 VLC_SAVE_FLAGS
1454 CFLAGS="${CFLAGS} -mmmx"
1455 have_3dnow="no"
1456 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1457 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1458 void *p;
1459 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1460 ]])
1461 ], [
1462 ac_cv_3dnow_inline=yes
1463 ], [
1464 ac_cv_3dnow_inline=no
1465 ])
1466 ])
1467 VLC_RESTORE_FLAGS
1468 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1469 AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1470 [Define to 1 if 3D Now! inline assembly is available.])
1471 have_3dnow="yes"
1472 ])
1473 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1476 AC_ARG_ENABLE(neon,
1477 [AS_HELP_STRING([--disable-neon],
1478 [disable NEON optimizations (default auto)])],, [
1479 AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1480 ])
1481 AS_IF([test "${enable_neon}" != "no"], [
1482 VLC_SAVE_FLAGS
1483 CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1484 AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1485 AC_COMPILE_IFELSE([
1486 AC_LANG_PROGRAM(,[[
1487 asm volatile("vqmovun.s64 d0, q1":::"d0");
1488 ]])
1489 ], [
1490 ac_cv_arm_neon="yes"
1491 ], [
1492 ac_cv_arm_neon="no"
1493 ])
1494 ])
1495 VLC_RESTORE_FLAGS
1496 ])
1497 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1499 AC_ARG_ENABLE(arm64,
1500 [AS_HELP_STRING([--disable-arm64],
1501 [disable arm 64-bit optimizations (default auto)])],, [
1502 AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1503 ])
1504 AS_IF([test "${enable_arm64}" != "no"], [
1505 AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1506 AC_COMPILE_IFELSE([
1507 AC_LANG_PROGRAM(,[[
1508 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1509 ]])
1510 ], [
1511 ac_cv_arm64="yes"
1512 ], [
1513 ac_cv_arm64="no"
1514 ])
1515 ])
1516 ])
1517 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1520 AC_ARG_ENABLE(altivec,
1521 [AS_HELP_STRING([--disable-altivec],
1522 [disable AltiVec optimizations (default auto)])],, [
1523 AS_CASE("${host_cpu}", [powerpc*],
1524 [enable_altivec=yes], [enable_altivec=no])
1525 ])
1526 have_altivec="no"
1527 ALTIVEC_CFLAGS=""
1528 AS_IF([test "${enable_altivec}" = "yes"], [
1529 ARCH="${ARCH} altivec";
1530 VLC_SAVE_FLAGS
1531 AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1532 [ac_cv_altivec_inline],
1533 [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1534 ac_cv_altivec_inline="yes",
1535 [CFLAGS="${CFLAGS} -Wa,-maltivec"
1536 AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1537 [ac_cv_altivec_inline="-Wa,-maltivec"],
1538 ac_cv_altivec_inline=no)
1539 ])])
1540 VLC_RESTORE_FLAGS
1541 AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1542 AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1543 [Define to 1 if AltiVec inline assembly is available.])
1544 AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1545 ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1546 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1547 ])
1548 have_altivec="yes"
1549 ])
1551 VLC_SAVE_FLAGS
1552 AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1553 [ac_cv_c_altivec], [
1554 CFLAGS="${CFLAGS} -maltivec"
1555 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1556 [#include <altivec.h>]], [
1557 [vec_ld(0, (unsigned char *)0);]])], [
1558 ac_cv_c_altivec="-maltivec"
1559 ], [
1560 ac_cv_c_altivec="no"
1561 ])
1562 ])
1563 VLC_RESTORE_FLAGS
1564 AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1565 CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1566 AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1567 VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1568 ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1569 VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1570 have_altivec="yes"
1571 ])
1572 AC_CHECK_HEADERS(altivec.h)
1574 VLC_SAVE_FLAGS
1575 LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1576 AC_CACHE_CHECK([if linker needs -framework vecLib],
1577 [ac_cv_ld_altivec],
1578 [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1579 VLC_RESTORE_FLAGS
1580 AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1581 VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1582 ])
1583 ])
1584 AC_SUBST(ALTIVEC_CFLAGS)
1585 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1587 dnl
1588 dnl Memory usage
1589 dnl
1590 AC_ARG_ENABLE(optimize-memory,
1591 [AS_HELP_STRING([--enable-optimize-memory],
1592 [optimize memory usage over performance])])
1593 if test "${enable_optimize_memory}" = "yes"; then
1594 AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1595 fi
1597 dnl
1598 dnl Allow running as root (useful for people running on embedded platforms)
1599 dnl
1600 AC_ARG_ENABLE(run-as-root,
1601 [AS_HELP_STRING([--enable-run-as-root],
1602 [allow running VLC as root (default disabled)])])
1603 AS_IF([test "${enable_run_as_root}" = "yes"],[
1604 AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1605 [Define to 1 to allow running VLC as root (uid 0).])
1606 ])
1608 dnl
1609 dnl Stream output
1610 dnl
1611 AC_ARG_ENABLE(sout,
1612 [AS_HELP_STRING([--disable-sout],
1613 [disable streaming output (default enabled)])])
1614 AS_IF([test "${enable_sout}" != "no"], [
1615 AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1616 ])
1617 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1619 dnl Lua modules
1620 AC_ARG_ENABLE(lua,
1621 [AS_HELP_STRING([--disable-lua],
1622 [disable LUA scripting support (default enabled)])])
1623 if test "${enable_lua}" != "no"
1624 then
1625 PKG_CHECK_MODULES(LUA, lua5.2,
1626 [ have_lua=yes ],
1627 [
1628 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1630 PKG_CHECK_MODULES(LUA, lua5.1,
1631 [ have_lua=yes ],
1632 [
1633 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1634 PKG_CHECK_MODULES(LUA, lua >= 5.1,
1635 [ have_lua=yes ],
1636 [
1637 AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1638 have_lua=yes
1639 AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1640 [],
1641 [ have_lua=no ] )
1642 AC_CHECK_LIB( lua5.2 , luaL_newstate,
1643 [LUA_LIBS="-llua5.2"],
1644 AC_CHECK_LIB( lua5.1 , luaL_newstate,
1645 [LUA_LIBS="-llua5.1"],
1646 AC_CHECK_LIB( lua51 , luaL_newstate,
1647 [LUA_LIBS="-llua51"],
1648 AC_CHECK_LIB( lua , luaL_newstate,
1649 [LUA_LIBS="-llua"],
1650 [ have_lua=no
1651 ], [-lm])
1652 )))
1653 ])
1654 ])
1655 ])
1656 if test "x${have_lua}" != "xyes" ; then
1657 AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1658 fi
1659 AC_ARG_VAR([LUAC], [LUA byte compiler])
1660 AS_IF([test -z "$LUAC"], [
1661 AC_CHECK_TOOL(LUAC, [luac], [false])
1662 ])
1663 AS_IF([test "${LUAC}" = "false"], [
1664 AC_MSG_ERROR([Could not find the LUA byte compiler.])
1665 ])
1666 AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1667 AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1668 ])
1669 fi
1670 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1673 dnl
1674 dnl VideoLAN manager
1675 dnl
1676 AC_ARG_ENABLE(vlm,
1677 [AS_HELP_STRING([--disable-vlm],
1678 [disable the stream manager (default enabled)])],,
1679 [enable_vlm="${enable_sout}"])
1680 AS_IF([test "${enable_vlm}" != "no"], [
1681 AS_IF([test "${enable_sout}" = "no"], [
1682 AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1683 ])
1684 AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1685 ])
1686 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1689 dnl
1690 dnl Addons manager storage and repositories modules
1691 dnl
1692 AC_ARG_ENABLE(addonmanagermodules,
1693 [AS_HELP_STRING([--disable-addonmanagermodules],
1694 [disable the addons manager modules (default enabled)])])
1695 if test "${enable_addonmanagermodules}" != "no"
1696 then
1697 AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1698 fi
1699 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1702 dnl
1703 dnl Input plugins
1704 dnl
1706 EXTEND_HELP_STRING([Input plugins:])
1708 dnl
1709 dnl libarchive access module
1710 dnl
1711 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1713 dnl
1714 dnl live555 input
1715 dnl
1716 AC_ARG_ENABLE(live555,
1717 [AS_HELP_STRING([--enable-live555],
1718 [enable RTSP input through live555 (default enabled)])])
1720 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1721 PKG_CHECK_MODULES(LIVE555, live555, [
1722 VLC_ADD_PLUGIN([live555])
1723 VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1724 VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1725 ], [
1726 AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1728 AC_LANG_PUSH(C++)
1729 VLC_SAVE_FLAGS
1731 dnl detect include paths
1732 AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1733 CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1734 ], [
1735 AS_IF([test "${SYS}" != "os2"], [
1736 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1737 CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1738 ], [
1739 LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1740 CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1741 LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1742 ])
1743 ])
1745 dnl CPP Flags
1746 AS_IF([test "${SYS}" = "solaris"], [
1747 CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1748 ])
1749 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1750 LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1752 dnl version check
1753 AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1754 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1755 [#include <liveMedia_version.hh>
1756 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1757 # error BOOM
1758 #endif]])
1759 ], [
1760 ac_cv_live555="yes"
1761 ], [
1762 ac_cv_live555="no"
1763 ])
1764 ])
1766 AS_IF([test "$ac_cv_live555" = "no"], [
1767 AC_MSG_WARN([live555 is missing or its installed version is too old:
1768 Version 2011.12.23 or later is required to proceed.
1769 You can get an updated one from http://www.live555.com/liveMedia .])
1770 AS_IF([test -n "${enable_live555}"], [
1771 AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1772 ])
1773 ], [
1774 other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1775 other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1776 AS_IF([test "${SYS}" = "mingw32"], [
1777 # add ws2_32 for closesocket, select, recv
1778 other_libs="$other_libs -lws2_32"
1779 ])
1781 dnl We need to check for pic because live555 don't provide shared libs
1782 dnl and we want to build a plugins so we need -fPIC on some arch.
1783 VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1784 VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1785 AC_CHECK_LIB(liveMedia_pic, main, [
1786 VLC_ADD_PLUGIN([live555])
1787 VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1788 ],[
1789 AC_CHECK_LIB(liveMedia, main, [
1790 VLC_ADD_PLUGIN([live555])
1791 VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1792 ],[],[${other_libs}])
1793 ],[${other_libs_pic}])
1794 ])
1795 VLC_RESTORE_FLAGS
1796 AC_LANG_POP(C++)
1797 ])
1798 ])
1800 dnl
1801 dnl IIDC and DV FireWire input modules
1802 dnl
1803 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1804 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1806 dnl
1807 dnl - linsys modules: access module check for libzvbi
1808 dnl
1809 AC_ARG_ENABLE(linsys,
1810 [AS_HELP_STRING([--enable-linsys],
1811 [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1812 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1813 VLC_ADD_PLUGIN([linsys_hdsdi])
1814 PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1815 VLC_ADD_PLUGIN([linsys_sdi])
1816 ], [
1817 AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1818 ])
1819 ])
1821 dnl
1822 dnl dvdread module: check for libdvdread
1823 dnl
1824 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1826 dnl
1827 dnl libdvdnav plugin
1828 dnl
1829 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1830 AS_IF([test "${enable_dvdnav}" != "no"], [
1831 AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1832 AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1833 AC_MSG_RESULT(yes)
1834 AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1835 ],[
1836 AC_MSG_RESULT(no)
1837 ])
1838 ])
1840 dnl
1841 dnl Blu-ray Disc Support with libbluray
1842 dnl
1843 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1845 dnl
1846 dnl OpenCV wrapper and example filters
1847 dnl
1848 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1851 dnl
1852 dnl libsmbclient plugin
1853 dnl
1854 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1855 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" != "yes"], [ VLC_ADD_PLUGIN([smb]) ])
1857 dnl
1858 dnl liBDSM access module
1859 dnl
1860 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1862 dnl
1863 dnl sftp access support
1864 dnl
1865 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1867 dnl
1868 dnl nfs access support
1869 dnl
1870 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1872 dnl
1873 dnl Video4Linux 2
1874 dnl
1875 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1876 [disable Video4Linux version 2 (default auto)])])
1877 have_v4l2="no"
1878 AS_IF([test "$enable_v4l2" != "no"], [
1879 AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1880 have_v4l2="yes"
1881 ])
1882 ])
1883 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1885 dnl
1886 dnl special access module for Blackmagic SDI cards
1887 dnl
1888 AC_ARG_ENABLE(decklink,
1889 [AS_HELP_STRING([--disable-decklink],
1890 [disable Blackmagic DeckLink SDI input (default auto)])])
1891 AC_ARG_WITH(decklink_sdk,
1892 [AS_HELP_STRING[--with-decklink-sdk=DIR],
1893 [ location of Blackmagic DeckLink SDI SDK])])
1894 have_decklink=no
1895 if test "${enable_decklink}" != "no"
1896 then
1897 if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1898 then
1899 VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1900 fi
1901 VLC_SAVE_FLAGS
1902 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1903 AC_LANG_PUSH(C++)
1904 AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1905 have_decklink=yes
1906 ], [
1907 AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1908 ])
1909 AC_LANG_POP(C++)
1910 VLC_RESTORE_FLAGS
1911 fi
1912 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1915 dnl
1916 dnl Built-in CD-DA and VCD module
1917 dnl
1918 AC_ARG_ENABLE(vcd,
1919 [AS_HELP_STRING([--disable-vcd],
1920 [disable built-in VCD and CD-DA support (default enabled)])])
1922 AC_ARG_ENABLE(libcddb,
1923 [AS_HELP_STRING([--disable-libcddb],
1924 [disable CDDB for Audio CD (default enabled)])])
1926 if test "${enable_vcd}" != "no"
1927 then
1928 AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1929 AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1930 AC_MSG_RESULT(yes)
1931 VLC_ADD_PLUGIN([vcd cdda])
1932 ],[
1933 AC_MSG_RESULT(no)
1934 ])
1936 AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1937 AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1938 AC_MSG_RESULT(yes)
1939 VLC_ADD_PLUGIN([vcd cdda])
1940 AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1941 ],[
1942 AC_MSG_RESULT(no)
1943 ])
1945 AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1946 AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1947 AC_MSG_RESULT(yes)
1948 VLC_ADD_PLUGIN([vcd cdda])
1949 AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1950 ],[
1951 AC_MSG_RESULT(no)
1952 ])
1954 if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1955 then
1956 VLC_ADD_PLUGIN([vcd cdda])
1957 fi
1959 if test "$enable_libcddb" != "no"; then
1960 PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1961 HAVE_LIBCDDB=yes
1962 AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1963 VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1964 VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1965 ],:
1966 [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1967 HAVE_LIBCDDB=no])
1968 fi
1969 fi
1971 dnl
1972 dnl Linux DVB
1973 dnl
1974 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1975 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1976 [#include <linux/dvb/version.h>
1977 #if (DVB_API_VERSION < 5)
1978 # error Linux DVB API v3.2 and older are not supported.
1979 #endif
1980 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1981 # error Linux DVB API v5.0 is unsupported. Please update.
1982 #endif
1983 ]])], [
1984 ac_cv_linux_dvb_5_1=yes
1985 ], [
1986 ac_cv_linux_dvb_5_1=no
1987 ])])
1988 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1990 dnl
1991 dnl Screen capture module
1992 dnl
1993 AC_ARG_ENABLE(screen,
1994 [AS_HELP_STRING([--enable-screen],
1995 [disable screen capture (default enabled)])])
1996 if test "${enable_screen}" != "no"; then
1997 if test "${SYS}" = "darwin"; then
1998 AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1999 VLC_ADD_PLUGIN([screen])
2000 ])
2001 fi
2002 fi
2003 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
2005 dnl
2006 dnl VNC/RFB access module
2007 dnl
2008 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
2010 dnl RDP/Remote Desktop access module
2011 dnl
2012 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
2014 dnl
2015 dnl Real RTSP plugin
2016 dnl
2017 AC_ARG_ENABLE(realrtsp,
2018 [ --enable-realrtsp Real RTSP module (default disabled)])
2019 if test "${enable_realrtsp}" = "yes"; then
2020 VLC_ADD_PLUGIN([access_realrtsp])
2021 fi
2023 dnl
2024 dnl QTKit
2025 AC_ARG_ENABLE(macosx-qtkit,
2026 [ --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
2027 if test "x${enable_macosx_qtkit}" != "xno" &&
2028 (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2029 then
2030 AC_CHECK_HEADERS(QTKit/QTKit.h, [
2031 VLC_ADD_PLUGIN([qtsound])
2032 ])
2033 fi
2035 dnl
2036 dnl AVFoundation
2037 AC_SUBST(have_avfoundation, ["no"])
2038 AC_ARG_ENABLE(macosx-avfoundation,
2039 [ --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2040 if test "x${enable_macosx_avfoundation}" != "xno" &&
2041 (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2042 then
2043 SAVED_LIBS="${LIBS}"
2044 LIBS="-framework AVFoundation"
2045 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2046 LIBS="${SAVED_LIBS}"
2047 if test "${have_avfoundation}" != "no"
2048 then
2049 VLC_ADD_PLUGIN([avcapture])
2050 fi
2051 fi
2052 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2054 dnl
2055 dnl DCP plugin (using asdcplib)
2056 dnl
2057 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2058 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2060 dnl
2061 dnl Demux plugins
2062 dnl
2064 EXTEND_HELP_STRING([Mux/Demux plugins:])
2066 dnl
2067 dnl libdvbpsi check for ts mux/demux
2068 dnl
2069 have_dvbpsi="no"
2070 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2071 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2074 dnl
2075 dnl GME demux plugin
2076 dnl
2077 AC_ARG_ENABLE(gme,
2078 [AS_HELP_STRING([--enable-gme],
2079 [use Game Music Emu (default auto)])])
2080 AS_IF([test "${enable_gme}" != "no"], [
2081 AC_CHECK_HEADER([gme/gme.h], [
2082 AC_CHECK_LIB([gme], [gme_identify_header], [
2083 VLC_ADD_PLUGIN([gme])
2084 ], [
2085 AC_CHECK_LIB([gme], [gme_identify_extension], [
2086 VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2087 VLC_ADD_PLUGIN([gme])
2088 ],, [-lstdc++ $LIBM])
2089 ])
2090 VLC_ADD_LIBS([gme], [-lgme])
2091 ], [
2092 AS_IF([test "x${enable_gme}" != "x"], [
2093 AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2094 ])
2095 ])
2096 ])
2099 dnl
2100 dnl SIDPlay plugin
2101 dnl
2102 AC_ARG_ENABLE(sid,
2103 [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2104 AS_IF([test "${enable_sid}" != "no"], [
2105 PKG_CHECK_MODULES(SID, [libsidplay2], [
2106 AC_LANG_PUSH(C++)
2107 oldCPPFLAGS="$CPPFLAGS"
2108 CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2109 AC_CHECK_HEADER([sidplay/builders/resid.h], [
2110 VLC_ADD_PLUGIN([sid])
2111 VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2112 VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2113 ], [
2114 AS_IF([test -n "${enable_sid}"],
2115 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2116 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2117 )
2118 ])
2119 CPPFLAGS="$oldCPPFLAGS"
2120 AC_LANG_POP(C++)
2121 ], [
2122 AS_IF([test "x${enable_sid}" = "xyes"],
2123 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2124 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2125 )
2126 ])
2127 ])
2130 dnl
2131 dnl ogg demux plugin
2132 dnl
2133 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2134 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2135 AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2136 ],[true])
2137 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2138 if test "${enable_sout}" != "no"; then
2139 dnl Check for libshout
2140 PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2141 fi
2143 dnl
2144 dnl matroska demux plugin
2145 dnl
2146 PKG_WITH_MODULES([MATROSKA], [libebml libmatroska], [
2147 VLC_ADD_PLUGIN([mkv])
2148 VLC_ADD_CFLAGS([mkv], [$MATROSKA_CFLAGS])
2149 VLC_ADD_LIBS([mkv], [$MATROSKA_LIBS])
2150 have_matroska="yes"
2151 ],,[MKV format support], [auto])
2152 AM_CONDITIONAL([HAVE_MATROSKA], [test "${have_matroska}" = "yes"])
2154 dnl
2155 dnl modplug demux plugin
2156 dnl
2157 AC_ARG_ENABLE(mod,
2158 [AS_HELP_STRING([--disable-mod],
2159 [do not use libmodplug (default auto)])])
2160 if test "${enable_mod}" != "no" ; then
2161 PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2162 VLC_ADD_PLUGIN([mod])
2163 VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2164 VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2165 VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2166 ],[
2167 AS_IF([test -n "${enable_mod}"],
2168 [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2169 [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2170 ])
2171 fi
2173 dnl
2174 dnl mpc demux plugin
2175 dnl
2176 AC_ARG_ENABLE(mpc,
2177 [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2178 if test "${enable_mpc}" != "no"
2179 then
2180 AC_CHECK_HEADERS([mpc/mpcdec.h], [
2181 VLC_ADD_PLUGIN([mpc])
2182 VLC_ADD_LIBS([mpc],[-lmpcdec])],
2183 [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2184 VLC_ADD_PLUGIN([mpc])
2185 VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2186 fi
2188 dnl
2189 dnl Codec plugins
2190 dnl
2192 EXTEND_HELP_STRING([Codec plugins:])
2194 dnl
2195 dnl wmafixed plugin
2196 dnl
2197 AC_ARG_ENABLE(wma-fixed,
2198 [ --enable-wma-fixed libwma-fixed module (default disabled)])
2199 if test "${enable_wma_fixed}" = "yes"
2200 then
2201 VLC_ADD_PLUGIN([wma_fixed])
2202 fi
2204 dnl
2205 dnl shine encoder plugin
2206 dnl
2207 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2210 dnl
2211 dnl openmax il codec plugin
2212 dnl
2213 AC_ARG_ENABLE(omxil,
2214 [ --enable-omxil openmax il codec module (default disabled)])
2215 if test "${enable_omxil}" = "yes"
2216 then
2217 VLC_ADD_PLUGIN([omxil])
2218 fi
2220 dnl
2221 dnl raspberry pi openmax il configuration
2222 dnl
2223 AC_ARG_ENABLE(rpi-omxil,
2224 [ --enable-rpi-omxil openmax il configured for raspberry pi (default disabled)])
2225 if test "${enable_rpi_omxil}" = "yes"
2226 then
2227 VLC_ADD_PLUGIN([omxil])
2228 VLC_ADD_CFLAGS([omxil],[-DRPI_OMX])
2229 fi
2231 dnl
2232 dnl CrystalHD codec plugin
2233 dnl
2234 AC_ARG_ENABLE(crystalhd,
2235 [ --enable-crystalhd crystalhd codec plugin (default auto)])
2236 if test "${enable_crystalhd}" != "no"; then
2237 AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2238 VLC_ADD_PLUGIN([crystalhd])
2239 VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2240 ],[
2241 if test "${SYS}" = "mingw32" ; then
2242 AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2243 VLC_ADD_PLUGIN([crystalhd])
2244 AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2245 VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2246 ])
2247 ],[
2248 AS_IF([test x"${enable_crystalhd}" = "xyes"],
2249 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2250 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2251 ],[#define __LINUX_USER__
2252 #include <libcrystalhd/bc_dts_types.h>
2253 ])
2254 fi
2255 ],[
2256 #include <libcrystalhd/bc_dts_types.h>
2257 ])
2258 fi
2260 dnl
2261 dnl mad plugin
2262 dnl
2263 have_mad="no"
2264 MAD_CFLAGS=""
2265 MAD_LIBS=""
2267 AC_ARG_WITH(mad, [ --with-mad=PATH path to libmad], [
2268 enable_mad="yes"
2269 ], [
2270 with_mad="no"
2271 ])
2272 AS_IF([test "${with_mad}" != "no"], [
2273 MAD_CFLAGS="-I${with_mad}/include"
2274 MAD_LIBS="-L${with_mad}/lib"
2275 ])
2277 AC_ARG_ENABLE(mad,
2278 [ --enable-mad libmad module (default enabled)])
2279 AS_IF([test "${enable_mad}" != "no"], [
2280 VLC_SAVE_FLAGS
2281 CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2282 LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2283 AC_CHECK_HEADERS(mad.h, [
2284 AC_CHECK_LIB(mad, mad_bit_init, [
2285 have_mad="yes"
2286 MAD_LIBS="${MAD_LIBS} -lmad"
2287 ])
2288 ])
2289 VLC_RESTORE_FLAGS
2290 AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2291 AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2292 ])
2293 ])
2294 AC_SUBST(MAD_CFLAGS)
2295 AC_SUBST(MAD_LIBS)
2296 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2298 dnl mpg123 plugin
2299 dnl
2300 dnl
2301 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2303 dnl
2304 dnl gstreamer stuff
2305 dnl
2306 AC_ARG_ENABLE(gst-decode,
2307 [ --enable-gst-decode GStreamer based decoding support (currently supports only video decoding) (default auto)])
2309 have_gst_decode="no"
2310 AS_IF([test "${enable_gst_decode}" != "no"], [
2311 PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2312 PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2313 have_gst_decode="yes"
2314 ], [
2315 AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2316 ])
2317 ], [
2318 AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2319 ])
2320 ])
2321 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2323 dnl
2324 dnl avcodec decoder/encoder plugin
2325 dnl
2326 AC_ARG_ENABLE(merge-ffmpeg,
2327 [ --enable-merge-ffmpeg merge FFmpeg-based plugins (default disabled)],, [
2328 enable_merge_ffmpeg="no"
2329 ])
2330 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2332 AC_MSG_CHECKING([for libavutil variant])
2333 PKG_CHECK_EXISTS([libavutil], [
2334 libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2335 libavutil_micro="${libavutil_version##*.}"
2336 AS_IF([test ${libavutil_micro} -le 99], [
2337 avfork="libav"
2338 ], [
2339 avfork="ffmpeg"
2340 ])
2341 ], [
2342 avfork="none"
2343 ])
2344 AC_MSG_RESULT([${avfork}])
2346 AC_ARG_ENABLE(avcodec,
2347 [ --enable-avcodec libavcodec codec (default enabled)])
2348 AS_IF([test "${enable_avcodec}" != "no"], [
2349 dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2350 case "${avfork}" in
2351 libav) av_codec_ver="57.16.0" ;;
2352 ffmpeg) av_codec_ver="57.37.100" ;;
2353 *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2354 esac
2355 PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2356 VLC_SAVE_FLAGS
2357 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2358 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2359 AC_CHECK_HEADERS(libavcodec/avcodec.h)
2360 AC_CHECK_HEADERS(libavutil/avutil.h)
2361 VLC_RESTORE_FLAGS
2362 have_avcodec="yes"
2363 ],[
2364 AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2365 ])
2366 ], [
2367 have_avcodec="no"
2368 ])
2369 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2371 dnl
2372 dnl libva needs avcodec
2373 dnl
2374 AC_ARG_ENABLE(libva,
2375 [ --enable-libva VAAPI GPU decoding support (libVA) (default auto)])
2377 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2378 AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2379 ])
2381 have_vaapi="no"
2382 have_vaapi_drm="no"
2383 have_vaapi_x11="no"
2384 have_vaapi_wl="no"
2385 AS_IF([test "${enable_libva}" != "no"], [
2386 PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2387 have_vaapi="yes"
2388 ], [
2389 AS_IF([test -n "${enable_libva}"], [
2390 AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2391 ], [
2392 AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2393 ])
2394 ])
2395 PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2396 have_vaapi_drm="yes"
2397 ], [
2398 AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2399 ])
2400 PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2401 have_vaapi_x11="yes"
2402 ], [
2403 AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2404 ])
2405 PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2406 have_vaapi_wl="yes"
2407 ], [
2408 AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2409 ])
2410 ])
2411 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2412 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2413 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2414 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2416 have_avcodec_vaapi="no"
2417 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2418 VLC_SAVE_FLAGS
2419 CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2420 CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2421 AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2422 AC_MSG_NOTICE([VA API acceleration activated])
2423 have_avcodec_vaapi="yes"
2424 ],[
2425 AS_IF([test -n "${enable_libva}"], [
2426 AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2427 ], [
2428 AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2429 ])
2430 ])
2431 VLC_RESTORE_FLAGS
2432 ])
2433 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2435 dnl
2436 dnl dxva2 needs avcodec
2437 dnl
2438 AC_ARG_ENABLE(dxva2,
2439 [ --enable-dxva2 DxVA2 GPU decoding support (default auto)])
2441 have_avcodec_dxva2="no"
2442 AS_IF([test "${enable_dxva2}" != "no"], [
2443 if test "${SYS}" = "mingw32"; then
2444 AS_IF([test "x${have_avcodec}" = "xyes"], [
2445 AC_CHECK_HEADERS(dxva2api.h,
2446 [
2447 AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2448 AC_MSG_NOTICE([DxVA2 acceleration activated])
2449 have_avcodec_dxva2="yes"
2450 ],[
2451 AS_IF([test "${enable_dxva2}" = "yes"],
2452 [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2453 [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2454 ], [#undef _WIN32_WINNT
2455 /* DXVA2 is only available in Vista and above */
2456 #define _WIN32_WINNT 0x600])
2457 ],[
2458 AS_IF([test "${enable_dxva2}" = "yes"],
2459 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2460 [AC_MSG_WARN([dxva2api.h not found])])
2461 ],[#include <d3d9.h>])
2462 ],[
2463 AS_IF([test "x${enable_dxva2}" != "x"], [
2464 AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2465 ])
2466 ])
2467 fi
2468 ])
2469 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2471 dnl
2472 dnl d3d11va needs avcodec
2473 dnl
2474 AC_ARG_ENABLE(d3d11va,
2475 [ --enable-d3d11va D3D11 GPU decoding support (default auto)])
2477 have_avcodec_d3d11va="no"
2478 AS_IF([test "${enable_d3d11va}" != "no"], [
2479 if test "${SYS}" = "mingw32"; then
2480 AS_IF([test "x${have_avcodec}" = "xyes"], [
2481 AC_CHECK_TYPES([ID3D11VideoDecoder],
2482 [
2483 AC_CHECK_HEADERS(dxva2api.h,
2484 [
2485 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2486 AC_MSG_NOTICE([D3D11 acceleration activated])
2487 AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2488 have_avcodec_d3d11va="yes"
2489 ],[
2490 AS_IF([test "${enable_d3d11va}" = "yes"],
2491 [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2492 [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2493 ], [#undef _WIN32_WINNT
2494 /* D3D11 is only available in Vista and above */
2495 #define _WIN32_WINNT 0x600])
2496 ],[
2497 AS_IF([test "${enable_d3d11va}" = "yes"],
2498 [AC_MSG_ERROR([Could not find required dxva2api.h])],
2499 [AC_MSG_WARN([dxva2api.h not found])])
2500 ],[#include <d3d9.h>])
2501 ],[
2502 AS_IF([test "${enable_d3d11va}" = "yes"],
2503 [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2504 [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2505 ], [#include <d3d11.h>])
2506 ],[
2507 AS_IF([test "x${enable_d3d11va}" != "x"], [
2508 AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2509 ])
2510 ])
2511 fi
2512 ])
2513 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2515 dnl
2516 dnl DXGI debug
2517 dnl
2518 AC_CHECK_HEADERS(dxgidebug.h dxgi1_6.h)
2520 dnl
2521 dnl avformat demuxer/muxer plugin
2522 dnl
2524 AC_ARG_ENABLE(avformat,
2525 [ --enable-avformat libavformat containers (default enabled)],, [
2526 enable_avformat="${have_avcodec}"
2527 ])
2528 have_avformat="no"
2529 AS_IF([test "${enable_avformat}" != "no"], [
2530 PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2531 have_avformat="yes"
2532 VLC_SAVE_FLAGS
2533 CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2534 CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2535 AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2536 AC_CHECK_HEADERS(libavcodec/avcodec.h)
2537 AC_CHECK_HEADERS(libavutil/avutil.h)
2538 AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2539 have_avformat="no"
2540 ])
2541 VLC_RESTORE_FLAGS
2542 ],[
2543 AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2544 ])
2545 ])
2546 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2548 dnl
2549 dnl swscale image scaling and conversion plugin
2550 dnl
2552 AC_ARG_ENABLE(swscale,
2553 AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2554 (default enabled)]))
2555 if test "${enable_swscale}" != "no"
2556 then
2557 PKG_CHECK_MODULES(SWSCALE,[libswscale],
2558 [
2559 VLC_SAVE_FLAGS
2560 CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2561 CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2562 AC_CHECK_HEADERS(libswscale/swscale.h)
2563 AC_CHECK_HEADERS(libavutil/avutil.h)
2564 VLC_ADD_PLUGIN([swscale])
2565 VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2566 VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2567 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2568 VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2569 ])
2570 VLC_RESTORE_FLAGS
2571 ],[
2572 AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2573 ])
2574 fi
2576 dnl
2577 dnl postproc plugin
2578 dnl
2580 AC_ARG_ENABLE(postproc,
2581 [ --enable-postproc libpostproc image post-processing (default auto)])
2582 if test "${enable_postproc}" != "no"
2583 then
2584 PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2585 [
2586 VLC_SAVE_FLAGS
2587 CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2588 CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2589 AC_CHECK_HEADERS(postproc/postprocess.h)
2590 VLC_ADD_PLUGIN([postproc])
2591 VLC_RESTORE_FLAGS
2592 ],[
2593 AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2594 ])
2595 fi
2597 dnl
2598 dnl faad decoder plugin
2599 dnl
2600 AC_ARG_ENABLE(faad,
2601 [ --enable-faad faad codec (default auto)])
2602 have_faad="no"
2603 AS_IF([test "${enable_faad}" != "no"], [
2604 AC_CHECK_HEADERS([neaacdec.h], [
2605 AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2607 AS_IF([test "${have_faad}" = "yes"], [
2608 VLC_ADD_PLUGIN([faad])
2609 VLC_ADD_LIBS([faad],[-lfaad])
2610 ], [
2611 AS_IF([test "${enable_faad}" = "yes"], [
2612 AC_MSG_ERROR([cannot find FAAD library])
2613 ], [
2614 AC_MSG_WARN([cannot find FAAD library])
2615 ])
2616 ])
2617 ])
2618 ])
2620 dnl
2621 dnl AOM decoder plugin
2622 dnl
2623 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec (default auto)])
2625 dnl
2626 dnl libvpx decoder plugin
2627 dnl
2628 AC_ARG_ENABLE(vpx,
2629 AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2630 AS_IF([test "${enable_vpx}" != "no"],[
2631 PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2632 VLC_ADD_PLUGIN([vpx])
2633 VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2634 VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2635 AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2636 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2637 ], [], [${VPX_LIBS}])
2638 AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2639 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2640 ], [], [${VPX_LIBS}])
2641 AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2642 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2643 ], [], [${VPX_LIBS}])
2644 AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2645 VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2646 ], [], [${VPX_LIBS}])
2647 ], [
2648 AS_IF([test "${enable_vpx}" = "yes"],[
2649 AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2650 ])])
2651 ])
2653 dnl
2654 dnl twolame encoder plugin
2655 dnl
2656 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2658 dnl
2659 dnl fdk-aac encoder plugin
2660 dnl
2661 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2664 dnl
2665 dnl A52/AC3 decoder plugin
2666 dnl
2667 AC_ARG_ENABLE(a52,
2668 [ --enable-a52 A/52 support with liba52 (default enabled)])
2669 if test "${enable_a52}" != "no"
2670 then
2671 AC_ARG_WITH(a52,
2672 [ --with-a52=PATH a52 headers and libraries])
2673 if test -z "${with_a52}"
2674 then
2675 LDFLAGS_test=""
2676 CPPFLAGS_test=""
2677 else
2678 LDFLAGS_test="-L${with_a52}/lib"
2679 CPPFLAGS_test="-I${with_a52}/include"
2680 fi
2681 VLC_SAVE_FLAGS
2682 CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2683 LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2684 AC_CHECK_HEADERS(a52dec/a52.h, [
2685 AC_CHECK_LIB(a52, a52_free, [
2686 VLC_ADD_PLUGIN([a52])
2687 VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2688 VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2689 ],[
2690 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2691 ], [$LIBM])
2692 ],[
2693 AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2694 ])
2695 VLC_RESTORE_FLAGS
2696 fi
2698 dnl
2699 dnl DTS Coherent Acoustics decoder plugin
2700 dnl
2701 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2703 dnl
2704 dnl Flac plugin
2705 dnl
2706 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2708 dnl
2709 dnl Libmpeg2 plugin
2710 dnl
2711 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2713 dnl
2714 dnl Vorbis plugin
2715 dnl
2716 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2718 dnl
2719 dnl Tremor plugin
2720 dnl
2721 AC_ARG_ENABLE(tremor,
2722 [ --enable-tremor Tremor decoder support (default disabled)])
2723 if test "${enable_tremor}" = "yes"
2724 then
2725 AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2726 VLC_ADD_PLUGIN([tremor])
2727 ],[])
2728 fi
2730 dnl
2731 dnl Speex plugins
2732 dnl
2733 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2734 have_speexdsp="no"
2735 AS_IF([test "${enable_speex}" != "no"], [
2736 PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2737 have_speexdsp="yes"
2738 ], [
2739 AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2740 ])
2741 ])
2742 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2744 dnl
2745 dnl Opus plugin
2746 dnl
2747 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2749 dnl
2750 dnl Ambisonic channel mixer and binauralizer plugin
2751 dnl
2752 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2754 dnl
2755 dnl theora decoder plugin
2756 dnl
2757 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2759 dnl
2760 dnl OggSpots decoder plugin
2761 dnl
2762 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2764 dnl
2765 dnl Daala decoder plugin
2766 dnl
2767 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2769 dnl
2770 dnl schroedinger decoder plugin (for dirac format video)
2771 dnl
2772 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2774 dnl
2775 dnl PNG decoder module
2776 dnl
2777 AC_ARG_ENABLE(png,
2778 [ --enable-png PNG support (default enabled)])
2779 AS_IF([test "${enable_png}" != "no"], [
2780 AC_CHECK_HEADERS(png.h, [
2781 VLC_SAVE_FLAGS
2782 LDFLAGS="${LDFLAGS} -lz $LIBM"
2783 AC_CHECK_LIB(png, png_set_alpha_mode, [
2784 VLC_ADD_PLUGIN([png])
2785 ], [], [-lz $LIBM])
2786 VLC_RESTORE_FLAGS
2787 ])
2788 ])
2790 dnl
2791 dnl JPEG decoder module
2792 dnl
2793 AC_ARG_ENABLE(jpeg,
2794 [ --enable-jpeg JPEG support (default enabled)])
2795 AS_IF([test "${enable_jpeg}" != "no"], [
2796 AC_CHECK_HEADERS(jpeglib.h, [
2797 VLC_ADD_PLUGIN([jpeg])
2798 ])
2799 ])
2801 dnl
2802 dnl BPG decoder module
2803 dnl
2804 AC_ARG_ENABLE(bpg,
2805 [ --enable-bpg BPG support (default disabled)])
2806 AS_IF([test "${enable_bpg}" != "no"], [
2807 AC_CHECK_HEADERS(libbpg.h, [
2808 VLC_ADD_PLUGIN([bpg])
2809 ])
2810 ])
2812 dnl
2813 dnl H262 encoder plugin (lib262)
2814 dnl
2815 AC_ARG_ENABLE(x262,
2816 [ --enable-x262 H262 encoding support with static libx262 (default disabled)])
2817 if test "${enable_x262}" != "no"; then
2818 PKG_CHECK_MODULES(X262, x262, [
2819 VLC_ADD_PLUGIN([x262])
2820 VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2821 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2822 VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2823 ])
2824 VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2825 if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2826 VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2827 fi
2828 ], [
2829 if test "${enable_x262}" = "yes"; then
2830 AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2831 fi
2832 ])
2833 fi
2835 dnl x265 encoder
2836 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2838 dnl
2839 dnl H264 encoder plugin (10-bit lib264)
2840 dnl
2841 AC_ARG_ENABLE(x26410b,
2842 [ --enable-x26410b H264 10-bit encoding support with static libx264 (default disabled)])
2843 if test "${enable_x26410b}" != "no"; then
2844 PKG_CHECK_MODULES(X26410B, x26410b, [
2845 VLC_ADD_PLUGIN([x26410b])
2846 VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2847 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2848 VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2849 ])
2850 VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2851 if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2852 VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2853 fi
2854 ], [
2855 if test "${enable_x26410b}" = "yes"; then
2856 AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2857 fi
2858 ])
2859 fi
2862 dnl
2863 dnl H264 encoder plugin (using libx264)
2864 dnl
2865 AC_ARG_ENABLE(x264,
2866 [ --enable-x264 H264 encoding support with libx264 (default enabled)])
2867 if test "${enable_x264}" != "no"; then
2868 PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2869 VLC_ADD_PLUGIN([x264])
2870 VLC_ADD_LIBS([x264],[${X264_LIBS}])
2872 AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2873 VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2874 ])
2876 VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2877 if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2878 VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2879 fi
2880 ],[
2881 if test "${enable_x264}" = "yes"; then
2882 AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2883 fi
2884 ])
2885 fi
2887 dnl
2888 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2889 dnl
2890 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2892 dnl
2893 dnl libfluidsynth (MIDI synthetizer) plugin
2894 dnl
2895 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2896 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2897 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2899 dnl
2900 dnl Teletext Modules
2901 dnl vbi decoder plugin (using libzbvi)
2902 dnl telx module
2903 dnl uncompatible
2904 dnl
2905 AC_ARG_ENABLE(zvbi,
2906 AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2907 libzvbi (default enabled)]))
2908 AC_ARG_ENABLE(telx,
2909 AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2910 zvbi) (default enabled if zvbi is absent)]))
2912 AS_IF( [test "${enable_zvbi}" != "no"],[
2913 PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2914 [
2915 VLC_ADD_PLUGIN([zvbi])
2916 AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2917 AS_IF( [test "${enable_telx}" = "yes"],[
2918 AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2919 ])
2920 ],[
2921 AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2922 ])
2923 ])
2924 AS_IF( [test "${enable_telx}" != "no" ],[
2925 VLC_ADD_PLUGIN([telx])
2926 ])
2928 dnl
2929 dnl libass subtitle rendering module
2930 dnl
2931 AC_ARG_ENABLE(libass,
2932 [ --enable-libass Subtitle support using libass (default enabled)])
2933 AS_IF( [test "${enable_libass}" != "no"], [
2934 PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2935 [
2936 VLC_ADD_PLUGIN([libass])
2938 AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2939 [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2940 VLC_ADD_LIBS([libass],[-lfontconfig])
2941 ])
2942 ],[
2943 AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2944 ])
2945 ])
2947 dnl
2948 dnl ARIB subtitles rendering module
2949 dnl
2950 AC_ARG_ENABLE(aribsub,
2951 [ --enable-aribsub ARIB Subtitles support (default enabled)])
2952 AS_IF( [test "${enable_aribsub}" != "no" ],[
2953 PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2954 have_aribb24="yes"
2955 VLC_ADD_PLUGIN([aribsub])
2956 VLC_ADD_LIBS([aribsub],[-laribb24])
2957 AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2958 ],[
2959 AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2960 have_aribb24="no"
2961 ])
2962 ])
2963 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2965 dnl
2966 dnl ARIB B25
2967 dnl
2968 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2970 dnl
2971 dnl kate decoder plugin
2972 dnl
2973 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2975 dnl
2976 dnl tiger rendering for kate decoder plugin
2977 dnl
2978 AC_ARG_ENABLE(tiger,
2979 [ --enable-tiger Tiger rendering library for Kate streams (default auto)])
2980 AS_IF([test "${enable_tiger}" != "no"], [
2981 PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2982 AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2983 AS_IF([test -n "${enable_tiger}"], [
2984 AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2985 ])
2986 ])
2987 ])
2989 dnl
2990 dnl check if we can build the css selector engine
2991 dnl
2992 AC_ARG_ENABLE(css,
2993 [ --enable-css CSS selector engine (default auto)])
2994 AS_IF([test "${enable_css}" != "no"], [
2995 with_css="yes"
2996 AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
2997 ])
2998 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
3001 dnl
3002 dnl Video plugins
3003 dnl
3005 EXTEND_HELP_STRING([Video plugins:])
3007 dnl
3008 dnl OpenGL
3009 dnl
3010 PKG_CHECK_MODULES([EGL], [egl], [
3011 have_egl="yes"
3012 ], [
3013 have_egl="no"
3014 ])
3015 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3017 have_gl="no"
3018 PKG_CHECK_MODULES([GL], [gl], [
3019 have_gl="yes"
3020 ], [
3021 AC_MSG_CHECKING([for OpenGL])
3022 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3023 #ifdef _WIN32
3024 # include <GL/glew.h>
3025 #endif
3026 #include <GL/gl.h>
3027 ]], [
3028 [int t0 = GL_TEXTURE0;]])
3029 ], [
3030 GL_CFLAGS=""
3031 have_gl="yes"
3032 AS_IF([test "${SYS}" != "mingw32"], [
3033 GL_LIBS="-lGL"
3034 ], [
3035 GL_LIBS="-lopengl32"
3036 ])
3037 ])
3038 AC_MSG_RESULT([${have_gl}])
3039 ])
3040 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3042 dnl OpenGL ES 2: depends on EGL 1.1
3043 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3045 dnl
3046 dnl Xlib
3047 dnl
3049 AC_PATH_XTRA()
3050 AC_CHECK_HEADERS(X11/Xlib.h)
3052 dnl
3053 dnl X C Bindings modules
3054 dnl
3055 AC_ARG_ENABLE(xcb,
3056 [ --enable-xcb X11 support with XCB (default enabled)],, [
3057 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3058 enable_xcb="yes"
3059 ], [
3060 enable_xcb="no"
3061 ])
3062 ])
3063 AC_ARG_ENABLE(xvideo,
3064 [ --enable-xvideo XVideo support (default enabled)],, [
3065 enable_xvideo="$enable_xcb"
3066 ])
3068 have_xcb="no"
3069 have_xcb_keysyms="no"
3070 have_xcb_randr="no"
3071 have_xcb_xvideo="no"
3072 AS_IF([test "${enable_xcb}" != "no"], [
3073 dnl libxcb
3074 PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3075 have_xcb="yes"
3076 PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3077 PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3078 PKG_CHECK_MODULES(XPROTO, [xproto])
3080 AS_IF([test "${enable_xvideo}" != "no"], [
3081 PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3082 ])
3084 PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3086 dnl xcb-utils
3087 PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3088 AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3089 ])
3090 ])
3091 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3092 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3093 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3094 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3097 dnl
3098 dnl VDPAU needs X11
3099 dnl
3100 AC_ARG_ENABLE(vdpau,
3101 [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3102 have_vdpau="no"
3103 AS_IF([test "${enable_vdpau}" != "no"], [
3104 PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3105 have_vdpau="yes"
3106 AS_IF([test "${no_x}" = "yes"], [
3107 AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3108 ])
3109 ], [
3110 AS_IF([test -n "${enable_vdpau}"], [
3111 AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3112 ])
3113 ])
3114 ])
3115 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3117 have_avcodec_vdpau="no"
3118 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3119 case "${avfork}" in
3120 libav) av_vdpau_ver="56.10.0" ;;
3121 ffmpeg) av_vdpau_ver="56.19.100" ;;
3122 esac
3123 PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3124 have_avcodec_vdpau="yes"
3125 AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3126 ], [
3127 AS_IF([test -n "${enable_vdpau}"], [
3128 AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3129 ], [
3130 AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3131 ])
3132 ])
3133 ])
3134 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3137 dnl
3138 dnl Wayland
3139 dnl
3140 AC_ARG_ENABLE(wayland,
3141 [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3142 have_wayland="no"
3143 have_wayland_egl="no"
3145 AS_IF([test "${enable_wayland}" != "no"], [
3146 PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3147 AC_MSG_CHECKING([for the Wayland protocols])
3148 PKG_CHECK_EXISTS([wayland-protocols >= 1.4], [
3149 WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3150 AC_MSG_RESULT([${WAYLAND_PROTOCOLS}])
3151 ], [
3152 AC_MSG_RESULT([not found])
3153 AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors 'wayland-protocols >= 1.4')])
3154 ])
3156 AC_MSG_CHECKING([for the Wayland scanner])
3157 PKG_CHECK_EXISTS([wayland-scanner], [
3158 WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3159 AC_MSG_RESULT([${WAYLAND_SCANNER}])
3160 ], [
3161 AC_MSG_RESULT([not found])
3162 AC_MSG_ERROR([$(${PKG_CONFIG} --print-errors wayland-scanner)])
3163 ])
3165 have_wayland="yes"
3167 AS_IF([test "${have_egl}" = "yes"], [
3168 PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3169 have_wayland_egl="yes"
3170 ], [
3171 AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3172 ])
3173 ])
3174 ], [
3175 AS_IF([test -n "${enable_wayland}"], [
3176 AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3177 ])
3178 ])
3179 ])
3180 AC_SUBST([WAYLAND_PROTOCOLS])
3181 AC_SUBST([WAYLAND_SCANNER])
3182 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3183 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3186 dnl
3187 dnl SDL image decoder module
3188 dnl
3189 AC_ARG_ENABLE(sdl-image,
3190 [ --enable-sdl-image SDL image support (default enabled)])
3191 AS_IF([test "${enable_sdl_image}" != "no"],[
3192 PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3193 VLC_ADD_PLUGIN([sdl_image])
3194 ], [
3195 AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3196 ])
3197 ])
3199 dnl
3200 dnl freetype module
3201 dnl
3202 AC_ARG_ENABLE(freetype,
3203 [ --enable-freetype freetype support (default auto)])
3204 AC_ARG_ENABLE(fribidi,
3205 [ --enable-fribidi fribidi support (default auto)])
3206 AC_ARG_ENABLE(harfbuzz,
3207 [ --enable-harfbuzz harfbuzz support (default auto)])
3208 AC_ARG_ENABLE(fontconfig,
3209 [ --enable-fontconfig fontconfig support (default auto)])
3211 AC_ARG_WITH([default-font],
3212 AS_HELP_STRING([--with-default-font=PATH],
3213 [Path to the default font]),
3214 [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3215 "$withval", [Default font])])
3216 AC_ARG_WITH([default-monospace-font],
3217 AS_HELP_STRING([--with-default-monospace-font=PATH],
3218 [Path to the default font]),
3219 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3220 "$withval", [Default monospace font])])
3222 AC_ARG_WITH([default-font-family],
3223 AS_HELP_STRING([--with-default-font-family=NAME],
3224 [Path to the default font family]),
3225 [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3226 "$withval", [Default font family])])
3227 AC_ARG_WITH([default-monospace-font-family],
3228 AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3229 [Path to the default font family]),
3230 [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3231 "$withval", [Default monospace font family])])
3233 have_freetype="no"
3234 have_fontconfig="no"
3235 have_fribidi="no"
3236 have_harfbuzz="no"
3238 if test "${enable_freetype}" != "no"; then
3239 PKG_CHECK_MODULES(FREETYPE, freetype2, [
3240 have_freetype="yes"
3241 VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3242 VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3244 dnl fontconfig support
3245 AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3246 PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3247 have_fontconfig="yes"
3248 ], [
3249 AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3250 ])
3251 ])
3253 dnl fribidi support
3254 if test "${enable_fribidi}" != "no"; then
3255 PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3256 have_fribidi="yes"
3257 VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3258 VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3259 ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3260 fi
3262 dnl harfbuzz support
3263 if test "${have_fribidi}" != "no"; then
3264 if test "${enable_harfbuzz}" != "no"; then
3265 PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3266 have_harfbuzz="yes"
3267 VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3268 VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3269 ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3270 fi
3271 fi
3272 ],[
3273 AS_IF([test -n "${enable_freetype}"],[
3274 AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3275 ])
3276 ])
3277 fi
3279 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3280 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3281 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3282 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3284 dnl
3285 dnl SAPI (text to Speech renderer for Windows)
3286 dnl
3287 AC_LANG_PUSH([C++])
3288 AC_CHECK_TYPES([ISpObjectToken],[
3289 have_sapi="yes"
3290 ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3291 [#include <windows.h>
3292 #include <sapi.h>
3293 #include <sphelper.h>])
3294 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3295 AC_LANG_POP([C++])
3297 dnl
3298 dnl SVG module (text rendering and image decoding)
3299 dnl
3300 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3301 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3303 dnl
3304 dnl Windows DirectX module
3305 dnl
3307 AC_ARG_ENABLE(directx,
3308 [AS_HELP_STRING([--enable-directx],
3309 [Microsoft DirectX support (default enabled on Windows)])],, [
3310 AS_IF([test "${SYS}" = "mingw32"], [
3311 enable_directx="yes"
3312 ], [
3313 enable_directx="no"
3314 ])
3315 ])
3316 AS_IF([test "${enable_directx}" != "no"], [
3317 dnl DirectDraw
3318 AC_CHECK_HEADERS(ddraw.h, [
3319 VLC_ADD_PLUGIN([directdraw])
3320 ])
3322 dnl OpenGL
3323 AC_CHECK_HEADERS(GL/wglew.h, [
3324 VLC_ADD_PLUGIN([glwin32 wgl])
3325 ],, [
3326 #include <windows.h>
3327 #include <GL/gl.h>
3328 ])
3330 dnl Direct3D11
3331 AC_CHECK_HEADERS(d3d11.h, [
3332 VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3333 ])
3335 dnl Direct3D9
3336 AC_CHECK_HEADERS(d3d9.h, [
3337 VLC_ADD_PLUGIN([direct3d9])
3338 AC_CHECK_HEADERS(d3dx9effect.h)
3340 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3341 [[#define COBJMACROS
3342 #include <d3d9.h>
3343 #include <dxva2api.h>
3344 #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3345 # error dxva2 too old
3346 #endif
3347 ]],[[;]])
3348 ],[
3349 VLC_ADD_PLUGIN([direct3d9_filters])
3350 ],
3351 [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3353 ])
3354 ])
3356 dnl
3357 dnl Linux framebuffer module
3358 dnl
3359 AC_CHECK_HEADER([linux/fb.h], [
3360 VLC_ADD_PLUGIN([fb])
3361 ])
3363 dnl
3364 dnl libcaca plugin
3365 dnl
3366 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3368 dnl
3369 dnl OS/2 KVA plugin
3370 dnl
3371 AC_ARG_ENABLE(kva,
3372 [AS_HELP_STRING([--enable-kva],
3373 [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3374 AS_IF([test "$SYS" = "os2"], [
3375 enable_kva="yes"
3376 ])
3377 ])
3378 have_kva="no"
3379 KVA_LIBS=""
3380 AS_IF([test "$enable_kva" != "no"], [
3381 AC_CHECK_HEADERS([kva.h], [
3382 have_kva="yes"
3383 AC_CHECK_LIB(kva, main, [
3384 KVA_LIBS="-lkva"
3385 ])
3386 ])
3387 ])
3388 AC_SUBST(KVA_LIBS)
3389 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3391 dnl
3392 dnl MMAL plugin
3393 dnl
3394 AC_ARG_ENABLE(mmal,
3395 AS_HELP_STRING([--enable-mmal],
3396 [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3397 if test "${enable_mmal}" != "no"; then
3398 VLC_SAVE_FLAGS
3399 LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3400 CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3401 AC_CHECK_HEADERS(interface/mmal/mmal.h,
3402 [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3403 have_mmal="yes"
3404 VLC_ADD_PLUGIN([mmal])
3405 VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3406 VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3407 VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif ]) ], [
3408 AS_IF([test "${enable_mmal}" = "yes"],
3409 [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3410 [ AC_MSG_WARN([Cannot find bcm library...]) ])
3411 ],
3412 [])
3413 ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3414 [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3415 [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3416 VLC_RESTORE_FLAGS
3417 fi
3418 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3420 dnl
3421 dnl Audio plugins
3422 dnl
3424 EXTEND_HELP_STRING([Audio plugins:])
3426 dnl
3427 dnl Pulseaudio module
3428 dnl
3429 AC_ARG_ENABLE(pulse,
3430 [AS_HELP_STRING([--enable-pulse],
3431 [use the PulseAudio client library (default auto)])])
3432 have_pulse="no"
3433 AS_IF([test "${enable_pulse}" != "no"], [
3434 PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3435 have_pulse="yes"
3436 ], [
3437 AS_IF([test "x${enable_pulse}" != "x"], [
3438 AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3439 ])
3440 ])
3441 ])
3442 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3444 dnl
3445 dnl ALSA module
3446 dnl
3447 AC_ARG_ENABLE(alsa,
3448 [AS_HELP_STRING([--enable-alsa],
3449 [support the Advanced Linux Sound Architecture (default auto)])],, [
3450 AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3451 enable_alsa="yes"
3452 ])
3453 ])
3454 have_alsa="no"
3455 AS_IF([test "${enable_alsa}" != "no"], [
3456 PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3457 have_alsa="yes"
3458 ], [
3459 AS_IF([test "x${enable_alsa}" != "x"], [
3460 AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3461 ])
3462 ])
3463 ])
3464 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3466 dnl
3467 dnl Open Sound System module
3468 dnl
3469 AC_ARG_ENABLE(oss,
3470 [AS_HELP_STRING([--enable-oss],
3471 [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3472 AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3473 enable_oss="no"
3474 ])
3475 ])
3476 have_oss="no"
3477 OSS_LIBS=""
3478 AS_IF([test "$enable_oss" != "no"], [
3479 AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3480 have_oss="yes"
3481 AC_CHECK_LIB(ossaudio, main, [
3482 OSS_LIBS="-lossaudio"
3483 ])
3484 ])
3485 ])
3486 AC_SUBST(OSS_LIBS)
3487 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3489 dnl
3490 dnl OpenBSD sndio module
3491 dnl
3492 AC_ARG_ENABLE([sndio],
3493 [AS_HELP_STRING([--disable-sndio],
3494 [support the OpenBSD sndio (default auto)])],, [
3495 AS_IF([test "$SYS" = "openbsd"], [
3496 enable_sndio="yes"
3497 ])
3498 ])
3499 have_sndio="no"
3500 AS_IF([test "$enable_sndio" != "no"], [
3501 AC_CHECK_HEADER([sndio.h], [
3502 have_sndio="yes"
3503 ])
3504 ])
3505 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3507 dnl
3508 dnl Windows Audio Session plugin
3509 dnl
3510 AC_ARG_ENABLE([wasapi],
3511 [AS_HELP_STRING([--enable-wasapi],
3512 [use the Windows Audio Session API (default auto)])
3513 ])
3514 have_wasapi="no"
3515 AS_IF([test "$enable_wasapi" != "no"], [
3516 AC_CHECK_HEADER([audioclient.h], [
3517 have_wasapi="yes"
3518 ], [
3519 AS_IF([test "x${enable_wasapi}" != "x"], [
3520 AC_MSG_ERROR([Windows Audio Session API not found.])
3521 ])
3522 ])
3523 ])
3524 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3526 dnl
3527 dnl JACK modules
3528 dnl
3529 AC_ARG_ENABLE(jack,
3530 [AS_HELP_STRING([--disable-jack],
3531 [do not use jack (default auto)])])
3532 have_jack="no"
3533 AS_IF([test "${enable_jack}" != "no"], [
3534 PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3535 [ have_jack=yes ],
3536 [
3537 AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3539 PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3540 [ have_jack=yes ],
3541 [
3542 AS_IF([test -n "${enable_jack}"],
3543 [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3544 [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3545 ])
3546 ])
3547 ])
3548 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3550 dnl
3551 dnl OpenSLES Android
3552 dnl
3553 AC_ARG_ENABLE(opensles,
3554 [ --enable-opensles Android OpenSL ES audio module (default disabled)])
3555 if test "${HAVE_ANDROID}" = "1"; then
3556 if test "${enable_opensles}" = "yes"; then
3557 AC_CHECK_HEADERS(SLES/OpenSLES.h,
3558 [ VLC_ADD_PLUGIN([opensles_android]) ],
3559 [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3560 fi
3561 fi
3563 dnl
3564 dnl Tizen audio
3565 dnl
3566 AC_ARG_ENABLE(tizen_audio,
3567 [AS_HELP_STRING([--enable-tizen-audio],
3568 [Tizen audio module (default enabled on Tizen)])],, [
3569 AS_IF([test "$HAVE_TIZEN" = "1"], [
3570 enable_tizen_audio="yes"
3571 ])
3572 ])
3573 if test "${enable_tizen_audio}" = "yes"; then
3574 AC_CHECK_HEADERS(audio_io.h,
3575 [ VLC_ADD_PLUGIN([tizen_audio]) ],
3576 [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3577 fi
3579 dnl
3580 dnl libsamplerate plugin
3581 dnl
3582 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3584 dnl
3585 dnl soxr module
3586 dnl
3587 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3589 dnl
3590 dnl OS/2 KAI plugin
3591 dnl
3592 AC_ARG_ENABLE(kai,
3593 [AS_HELP_STRING([--enable-kai],
3594 [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3595 AS_IF([test "$SYS" = "os2"], [
3596 enable_kai="yes"
3597 ])
3598 ])
3599 have_kai="no"
3600 KAI_LIBS=""
3601 AS_IF([test "$enable_kai" != "no"], [
3602 AC_CHECK_HEADERS([kai.h], [
3603 have_kai="yes"
3604 AC_CHECK_LIB(kai, main, [
3605 KAI_LIBS="-lkai"
3606 ])
3607 ])
3608 ])
3609 AC_SUBST(KAI_LIBS)
3610 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3612 dnl
3613 dnl chromaprint audio track fingerprinter
3614 dnl
3615 m4_pushdef([libchromaprint_version], 0.6.0)
3616 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3617 VLC_ADD_PLUGIN([stream_out_chromaprint]),
3618 AS_IF([test "${enable_chromaprint}" = "yes"],
3619 [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3620 [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3621 ),
3622 [(Chromaprint based audio fingerprinter)],[auto])
3623 m4_popdef([libchromaprint_version])
3625 dnl
3626 dnl Chromecast streaming support
3627 dnl
3628 m4_pushdef([protobuf_lite_version], 2.5.0)
3629 AC_ARG_VAR(PROTOC, [protobuf compiler])
3630 AC_CHECK_PROGS(PROTOC, protoc, no)
3631 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3632 AS_IF([test "x${PROTOC}" != "xno"], [
3633 build_chromecast="yes"
3634 ], [
3635 AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3636 ])
3637 ], [
3638 AS_IF([test "${enable_chromecast}" = "yes"],
3639 AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3640 AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3641 )
3642 enable_chromecast="no"
3643 ], [(Chromecast streaming support)], [auto])
3644 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3645 m4_popdef([protobuf_lite_version])
3647 dnl
3648 dnl Interface plugins
3649 dnl
3651 EXTEND_HELP_STRING([Interface plugins:])
3653 dnl
3654 dnl QT
3655 dnl
3656 AC_ARG_ENABLE(qt, [
3657 AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3658 AS_IF([test "${SYS}" = "darwin"], [
3659 enable_qt="no"
3660 ])
3661 ])
3662 have_qt5_x11="no"
3663 AS_IF([test "${enable_qt}" != "no"], [
3664 PKG_CHECK_MODULES([QT], [Qt5Core >= 5.5.0 Qt5Widgets Qt5Gui Qt5Svg], [
3665 PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3666 have_qt5_x11="yes"
3667 ],[
3668 AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3669 ])
3670 QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3671 QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3672 QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3673 AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3674 AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3675 AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3676 ], [
3677 AS_IF([test -n "${enable_qt}"],[
3678 AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3679 ],[
3680 AC_MSG_WARN([${QT_PKG_ERRORS}.])
3681 ])
3682 enable_qt="no"
3683 ])
3684 ])
3686 AS_IF([test "${enable_qt}" != "no"], [
3687 ALIASES="${ALIASES} qvlc"
3688 ])
3689 AC_SUBST(QT_VERSION)
3690 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3691 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3693 dnl
3694 dnl detect kde4-config patch (used for kde solids).
3695 dnl
3696 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3697 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3698 KDE4_CONFIG="kde4-config"
3699 ])
3701 dnl
3702 dnl Simple test for skins2 dependency
3703 dnl
3704 AS_IF([test "$enable_qt" = "no"], [
3705 AS_IF([test "${enable_skins2}" = "yes"], [
3706 AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3707 ], [
3708 enable_skins2="no"
3709 AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3710 ])
3711 ])
3713 dnl
3714 dnl Skins2 module
3715 dnl
3716 AC_ARG_ENABLE(skins2,
3717 [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3718 AS_IF([test "${enable_skins2}" != "no"], [
3719 have_skins_deps="yes"
3721 dnl Win32
3722 AS_IF([test "${SYS}" = "mingw32"], [
3723 VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3724 VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3725 dnl OS/2
3726 ], [test "${SYS}" = "os2"], [
3727 VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3728 dnl Linux/Unix
3729 ], [
3730 PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3731 PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3732 PKG_CHECK_MODULES([XCURSOR], [xcursor],, [have_skins_deps="no"])
3733 PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3734 VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3735 VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} ${XCURSOR_LIBS} -lX11])
3736 ])
3738 dnl we need freetype
3739 AS_IF([test "${have_freetype}" != "yes"], [
3740 have_skins_deps="no"
3741 ])
3743 AS_IF([test "${have_skins_deps}" = "no"], [
3744 AS_IF([test "x${enable_skins2}" = "x"], [
3745 AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3746 ], [
3747 AC_MSG_ERROR([Skins2 interface requires FreeType, libxcursor, libxpm, libxext and libxinerama])
3748 ])
3749 enable_skins2="no"
3750 ], [
3751 ALIASES="${ALIASES} svlc"
3752 enable_skins2="yes"
3753 ])
3754 ])
3755 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3757 AC_ARG_ENABLE(libtar,
3758 [ --enable-libtar libtar support for skins2 (default auto)])
3759 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3760 AC_CHECK_HEADERS(libtar.h, [
3761 VLC_ADD_LIBS([skins2],[-ltar])
3762 ])
3763 ])
3765 dnl
3766 dnl MacOS X gui module
3767 dnl
3768 AC_ARG_ENABLE(macosx,
3769 [ --enable-macosx Mac OS X gui support (default enabled on Mac OS X)])
3770 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3771 then
3773 dnl
3774 dnl If possible, use xcrun to find the right ibtool
3775 dnl
3777 AC_PATH_PROG([XCRUN], [xcrun], [no])
3778 AS_IF([test ! "x${XCRUN}" = "xno"], [
3779 AC_MSG_CHECKING([for ibtool (using xcrun)])
3780 XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3781 AC_MSG_RESULT([${XIB}])
3782 ], [
3783 AC_MSG_WARN([Looking for tools without using xcrun])
3784 ])
3786 AS_IF([test "x${XIB}" = "xno"], [
3787 AC_PATH_PROG(XIB, [ibtool], [no])
3788 AS_IF([test "x${XIB}" = "xno"], [
3789 AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3790 ])
3791 ])
3792 fi
3793 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3795 dnl
3796 dnl MacOS X sparkle update support
3797 dnl
3798 AC_ARG_ENABLE(sparkle,
3799 [ --enable-sparkle Sparkle update support for OS X (default enabled on Mac OS X)])
3800 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3801 then
3802 if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3803 then
3804 AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3805 fi
3807 AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3808 fi
3809 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3811 dnl
3812 dnl MacOS X breakpad creash reporter support
3813 dnl
3814 AC_ARG_WITH([breakpad],
3815 AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
3817 AS_IF([test "$with_breakpad" != "no"], [
3819 AS_IF([test "$with_breakpad" = "yes"], [
3820 AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
3821 ])
3823 AS_IF([test "$HAVE_OSX" = "1"], [
3824 AC_MSG_CHECKING([for Breakpad framework])
3825 AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
3826 ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
3827 AC_MSG_RESULT([no])
3828 with_breakpad="no"
3829 AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3830 ], [
3831 AC_MSG_RESULT([yes])
3832 ])
3833 ],[
3834 PKG_CHECK_MODULES([BREAKPAD], [breakpad-client], [
3835 LDFLAGS="${LDFLAGS} -Wl,--build-id"
3836 ], [
3837 AC_MSG_ERROR(["breakpad not found"])
3838 ])
3839 ])
3840 ])
3842 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$with_breakpad" != "no"])
3843 AS_IF([test "$with_breakpad" != "no"], [
3844 AC_SUBST(BREAKPAD_URL, ["${with_breakpad}"])
3845 ])
3847 dnl
3848 dnl Minimal Mac OS X module
3849 dnl
3850 AC_ARG_ENABLE(minimal-macosx,
3851 [ --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3852 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3853 then
3854 VLC_ADD_PLUGIN([minimal_macosx])
3855 fi
3857 dnl
3858 dnl Mac OS X fancy dmg build tool
3859 dnl
3860 if test "${HAVE_OSX}" = "1"
3861 then
3862 AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3863 AS_IF([test "x${DMGBUILD}" = "xno"], [
3864 AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3865 ])
3866 fi
3867 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3869 dnl
3870 dnl VideoToolbox plugins
3871 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3872 VLC_ADD_PLUGIN([videotoolbox])
3873 VLC_ADD_PLUGIN([cvpx])
3874 ])
3876 dnl
3877 dnl AudioToolbox MIDI plugin
3878 AC_CHECK_HEADERS([AudioToolbox/AudioToolbox.h], [
3879 VLC_ADD_PLUGIN([audiotoolboxmidi])
3880 ])
3882 dnl
3883 dnl ncurses module
3884 dnl
3885 AC_ARG_ENABLE(ncurses,
3886 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3887 have_ncurses="no"
3888 AS_IF([test "${enable_ncurses}" != "no"] ,[
3889 PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3890 have_ncurses="yes"
3891 ALIASES="${ALIASES} nvlc"
3892 ], [
3893 AS_IF([test -n "${enable_ncurses}"], [
3894 AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3895 ])
3896 ])
3897 ])
3898 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3900 dnl
3901 dnl Lirc plugin
3902 dnl
3903 AC_ARG_ENABLE(lirc,
3904 [ --enable-lirc lirc support (default disabled)])
3905 have_lirc="no"
3906 AS_IF([test "${enable_lirc}" = "yes"], [
3907 AC_CHECK_HEADER(lirc/lirc_client.h, [
3908 AC_CHECK_LIB(lirc_client, lirc_init, [
3909 have_lirc="yes"
3910 ])
3911 ])
3912 ])
3913 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3915 dnl
3916 dnl SRT plugin
3917 dnl
3918 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.2], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
3920 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3921 dnl
3922 dnl goom visualization plugin
3923 dnl
3924 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3926 dnl
3927 dnl libprojectM visualization plugin
3928 dnl
3929 AC_ARG_ENABLE(projectm,
3930 [ --enable-projectm projectM visualization plugin (default enabled)])
3931 AS_IF([test "${enable_projectm}" != "no"],
3932 [
3933 PKG_CHECK_MODULES(PROJECTM, libprojectM,
3934 [
3935 VLC_ADD_PLUGIN([projectm])
3936 PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3937 [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3938 [ AC_MSG_WARN( [Using libprojectM version 1] )
3939 ])
3940 ],[
3941 AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3942 ])
3943 ])
3945 dnl
3946 dnl Vovoid VSXu visualization plugin
3947 dnl
3948 AC_ARG_ENABLE(vsxu,
3949 [ --enable-vsxu Vovoid VSXu visualization plugin (default auto)])
3950 AS_IF([test "${enable_vsxu}" != "no"],
3951 [
3952 PKG_CHECK_MODULES(VSXU, libvsxu,
3953 [
3954 VLC_ADD_PLUGIN([vsxu])
3955 ],[
3956 AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3957 ])
3958 ])
3960 EXTEND_HELP_STRING([Service Discovery plugins:])
3961 dnl
3962 dnl Avahi-Zeroconf services discovery
3963 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3965 dnl
3966 dnl libudev services discovery
3967 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3969 dnl
3970 dnl MTP devices services discovery
3971 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3973 dnl
3974 dnl UPnP Plugin (Intel SDK)
3975 dnl
3976 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3978 dnl
3979 dnl mDNS using libmicrodns
3980 dnl
3981 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
3984 EXTEND_HELP_STRING([Misc options:])
3986 dnl
3987 dnl libxml2 module
3988 dnl
3989 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3992 dnl
3993 dnl libgcrypt
3994 dnl
3995 AC_ARG_ENABLE(libgcrypt,
3996 [ --disable-libgcrypt gcrypt support (default enabled)])
3997 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
3998 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4000 # require libgcrypt >= 1.6.0
4001 AS_IF([test "${enable_libgcrypt}" != "no"], [
4002 AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4003 VLC_SAVE_FLAGS
4004 CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4005 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4006 [#include <gcrypt.h>
4007 #if GCRYPT_VERSION_NUMBER < 0x010600
4008 #error
4009 #endif]])], [
4010 ac_cv_lib_gcrypt=yes
4011 ], [
4012 ac_cv_lib_gcrypt=no
4013 ])
4014 VLC_RESTORE_FLAGS
4015 ])
4017 AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4018 AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4019 ], [
4020 AS_IF([test "${enable_libgcrypt}" = "yes"], [
4021 AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4022 ])
4023 ])
4024 ])
4026 AS_IF([test -z "$GCRYPT_LIBS"], [
4027 GCRYPT_LIBS="-lgcrypt -lgpg-error"
4028 ])
4030 AC_SUBST(GCRYPT_CFLAGS)
4031 AC_SUBST(GCRYPT_LIBS)
4032 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4034 dnl
4035 dnl TLS/SSL
4036 dnl
4037 AC_ARG_ENABLE(gnutls,
4038 [ --enable-gnutls GNU TLS TLS/SSL support (default enabled)])
4039 AS_IF([test "${enable_gnutls}" != "no"], [
4040 PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4041 VLC_ADD_PLUGIN([gnutls])
4042 ], [
4043 AS_IF([test -n "${enable_gnutls}"], [
4044 AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4045 ])
4046 ])
4047 ])
4050 dnl
4051 dnl Taglib plugin
4052 dnl
4053 AC_ARG_ENABLE(taglib,
4054 [AS_HELP_STRING([--disable-taglib],
4055 [do not use TagLib (default enabled)])])
4056 AS_IF([test "${enable_taglib}" != "no"], [
4057 PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4058 VLC_ADD_PLUGIN([taglib])
4059 ], [
4060 AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4061 ])
4063 dnl
4064 dnl libsecret
4065 dnl
4066 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4068 dnl
4069 dnl kwallet
4070 dnl
4071 AC_ARG_ENABLE(kwallet,
4072 [AS_HELP_STRING([--enable-kwallet],
4073 [use kwallet (via D-Bus) for keystore (default enabled)])])
4074 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4075 VLC_ADD_PLUGIN([kwallet])
4076 ])
4078 dnl
4079 dnl update checking system
4080 dnl
4081 AC_ARG_ENABLE(update-check,
4082 [ --enable-update-check update checking system (default disabled)])
4083 if test "${enable_update_check}" = "yes"
4084 then
4085 AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4086 AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4087 fi
4088 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4090 dnl
4091 dnl OS X notification plugin
4092 dnl
4093 AC_ARG_ENABLE(osx_notifications,
4094 [ --enable-osx-notifications osx notification plugin (default disabled)],,
4095 [enable_osx_notifications=no])
4096 AS_IF([test "${enable_osx_notifications}" != "no"], [
4097 if test -d ${CONTRIB_DIR}/Growl.framework -o -d ${CONTRIB_DIR}/Frameworks/Growl.framework
4098 then
4099 VLC_ADD_PLUGIN([osx_notifications])
4100 VLC_ADD_LIBS([osx_notifications], [-Wl,-framework,Growl,-framework,Foundation])
4101 VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4102 fi
4103 ])
4105 dnl
4106 dnl Libnotify notification plugin
4107 dnl
4108 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-3.0], [libnotify notification], [auto])
4110 dnl
4111 dnl libplacebo support
4112 dnl
4113 AC_ARG_ENABLE(libplacebo,
4114 [AS_HELP_STRING([--disable-libplacebo],
4115 [disable libplacebo support (default auto)])])
4117 AS_IF([test "$enable_libplacebo" != "no"], [
4118 PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.2.1], [
4119 AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
4120 ], [
4121 AS_IF([test -n "${enable_libplacebo}"], [
4122 AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
4123 ])
4124 enable_libplacebo="no"
4125 ])
4126 ])
4127 AM_CONDITIONAL(HAVE_LIBPLACEBO, [test "$enable_libplacebo" != "no"])
4130 dnl
4131 dnl Endianness check
4132 dnl
4133 AC_C_BIGENDIAN
4134 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4135 DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4136 ], [
4137 DEFS_BIGENDIAN=""
4138 ])
4139 AC_SUBST(DEFS_BIGENDIAN)
4141 dnl
4142 dnl Where to install KDE solid .desktop
4143 dnl
4144 AC_ARG_WITH(kde-solid,
4145 AS_HELP_STRING([--with-kde-solid=PATH],
4146 [KDE Solid actions directory (auto)]),, [
4148 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4149 with_kde_solid="yes"
4150 fi
4151 ])
4152 soliddatadir=""
4153 AS_IF([test "${with_kde_solid}" != "no"], [
4154 AS_IF([test "${with_kde_solid}" = "yes"], [
4155 kde4datadir="`${KDE4_CONFIG} --install data`"
4156 AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4157 soliddatadir="${kde4datadir}/solid/actions"
4158 ], [
4159 soliddatadir="${with_kde_solid}"
4160 ])
4161 ])
4162 AC_SUBST(soliddatadir)
4163 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4165 dnl
4166 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4167 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4168 dnl
4169 if test "${SYS}" = "mingw32"; then
4170 AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4171 fi
4173 EXTEND_HELP_STRING([Components:])
4175 dnl
4176 dnl the VLC binary
4177 dnl
4178 AC_ARG_ENABLE(vlc,
4179 [ --enable-vlc build the VLC media player (default enabled)])
4180 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4182 dnl
4183 dnl Fuzzer (at the end in order to don't mess dependencies FLAGS)
4184 dnl
4185 AS_VAR_IF(with_libfuzzer, no, [], [
4186 LIBS="-lstdc++ ${LIBM} ${LIBPTHREAD} -L${with_libfuzzer} -lFuzzer"
4187 AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc-guard, [
4188 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard])
4189 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard], [CXXFLAGS])
4190 AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp])
4191 AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp], [CXXFLAGS])
4192 ], [
4193 AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc, [
4194 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc])
4195 AX_APPEND_FLAG([-fsanitize-coverage=trace-pc], [CXXFLAGS])
4196 ], [
4197 AC_MSG_ERROR([Sanitizer coverage not supported by your compiler])
4198 ])
4199 ])
4200 ])
4202 dnl
4203 dnl Stuff used by the program
4204 dnl
4205 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4206 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4207 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4208 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4209 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4210 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4211 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4212 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4213 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4214 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4215 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4216 AC_SUBST(COPYRIGHT_MESSAGE)
4217 AC_SUBST(VERSION_MESSAGE)
4218 AC_SUBST(VERSION_MAJOR)
4219 AC_SUBST(VERSION_MINOR)
4220 AC_SUBST(VERSION_REVISION)
4221 AC_SUBST(VERSION_EXTRA)
4222 AC_SUBST(COPYRIGHT_YEARS)
4223 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4224 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4225 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4226 dnl
4227 dnl Handle substvars that use $(top_srcdir)
4228 dnl
4229 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4231 dnl
4232 dnl Configuration is finished
4233 dnl
4234 AC_SUBST(SYS)
4235 AC_SUBST(ARCH)
4236 AC_SUBST(ALIASES)
4237 AC_SUBST(ASM)
4238 AC_SUBST(MOC)
4239 AC_SUBST(RCC)
4240 AC_SUBST(UIC)
4241 AC_SUBST(WINDRES)
4242 AC_SUBST(WINE_SDK_PATH)
4243 AC_SUBST(LIBEXT)
4244 AC_SUBST(AM_CPPFLAGS)
4245 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4246 AC_SUBST(FILE_LIBVLCCORE_DLL)
4247 AC_SUBST(FILE_LIBVLC_DLL)
4249 AC_CONFIG_FILES([
4250 Makefile
4251 doc/Makefile
4252 modules/Makefile
4253 m4/Makefile
4254 po/Makefile.in
4255 share/Makefile
4256 compat/Makefile
4257 src/Makefile
4258 lib/Makefile
4259 bin/Makefile
4260 test/Makefile
4261 modules/hw/mmal/Makefile
4262 share/vlc.appdata.xml.in
4263 ])
4265 AM_COND_IF([HAVE_WIN32], [
4266 AC_CONFIG_FILES([
4267 extras/package/win32/NSIS/spad.nsi
4268 extras/package/win32/NSIS/vlc.win32.nsi
4269 extras/package/win32/msi/config.wxi
4270 ])
4271 ])
4273 AM_COND_IF([HAVE_DARWIN], [
4274 AC_CONFIG_FILES([
4275 modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4276 share/macosx/Info.plist:share/Info.plist.in
4277 ])
4278 ])
4280 dnl Generate makefiles
4281 AC_OUTPUT
4283 dnl Do we have to use make or gmake ?
4284 if make --version 2>&1|grep -q GNU
4285 then
4286 # GNU make, all seems good
4287 MAKE=make
4288 else
4289 # Known GNU make alias (on BSD)
4290 MAKE=gmake
4291 fi
4292 dnl Shortcut to nice compile message
4293 if test -n $SHELL; then
4294 SHELL=${CONFIG_SHELL-/bin/sh}
4295 fi
4296 rm -f compile
4297 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4298 echo "#! $SHELL
4299 rm -f .error\$\$
4300 ERROR=0
4301 export PATH=\"$PATH\" LANG=C
4302 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4303 test -f .error\$\$ && ERROR=1
4304 rm -f .error\$\$
4305 exit \$ERROR" >compile
4306 chmod a+x compile
4308 echo "
4309 libvlc configuration
4310 --------------------
4311 version : ${VERSION}
4312 system : ${SYS}
4313 architecture : ${ARCH}
4314 optimizations : ${enable_optimizations}"
4315 if test "${enable_vlc}" != "no"; then
4316 echo "vlc aliases :${ALIASES}"
4317 else
4318 echo "build vlc executable : no"
4319 fi
4320 echo "
4321 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."