configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 2002-2013 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 2.2.0-git)
   6 VERSION_MAJOR=2
   7 VERSION_MINOR=2
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Weatherwax"
  17 COPYRIGHT_YEARS="1996-2013"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 # Disable with "./configure --disable-silent-rules" or "make V=1"
  31 AM_SILENT_RULES([yes])
  32
  33 dnl Too many people are not aware of maintainer mode:
  34 dnl If you want to use it, you definitely know what you are doing, so
  35 dnl you can specify "--disable-maintainer-mode". But if you want the default
  36 dnl automake behavior, you've likely never heard of maintainer mode, so we
  37 dnl can't expect you to enable it manually.
  38 AS_IF([test "x${enable_maintainer_mode}" != "xno"],
  39     [enable_maintainer_mode="yes"])
  40 AM_MAINTAINER_MODE
  41
  42 dnl
  43 dnl Directories
  44 dnl
  45 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  46 dnl AC_SUBST(vlcincludedir)
  47 vlcdatadir="\${datadir}/\${PKGDIR}"
  48 AC_SUBST(vlcdatadir)
  49 vlclibdir="\${libdir}/\${PKGDIR}"
  50 AC_SUBST(vlclibdir)
  51
  52 dnl
  53 dnl Check for tools
  54 dnl
  55 AC_PROG_CC_C99
  56 AC_USE_SYSTEM_EXTENSIONS
  57 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  58 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  59 AC_DEFINE([_REENTRANT],, [Define to expose reentrant functions.])
  60 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  61 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  62 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  63
  64 AM_PROG_CC_C_O
  65 AC_PROG_CXX
  66 AC_PROG_CPP
  67 AC_PROG_OBJC
  68 _AM_DEPENDENCIES([OBJC])
  69 AC_PROG_EGREP
  70 AC_PROG_MAKE_SET
  71 AC_PROG_INSTALL
  72 AM_PROG_AS
  73
  74 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  75 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  76 AC_CHECK_PROGS(YASM, yasm)
  77
  78 dnl Check for compiler properties
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AC_C_RESTRICT
  82
  83 dnl Extend the --help string at the current spot.
  84 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  85
  86 dnl Allow binary package maintainer to pass a custom string to avoid
  87 dnl cache problem
  88 AC_ARG_WITH(binary-version,
  89     AS_HELP_STRING([--with-binary-version=STRING],
  90          [To avoid plugins cache problem between binary version]),[],[])
  91 AS_IF([test -n "${with_binary_version}"],[
  92     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  93          [Binary specific version])
  94 ])
  95
  96 dnl
  97 dnl  Check the operating system
  98 dnl
  99 HAVE_WIN64="0"
 100
 101 YASMFLAGS=""
 102 case "${host}" in
 103     i?86*)
 104     YASMFLAGS="-f elf32"
 105         ;;
 106     x86_64*)
 107     YASMFLAGS="-f elf64"
 108         ;;
 109 esac
 110
 111
 112 case "${host_os}" in
 113   "")
 114     SYS=unknown
 115     ;;
 116   linux*)
 117     SYS=linux
 118     ;;
 119   bsdi*)
 120     SYS=bsdi
 121     CFLAGS="${CFLAGS} -pthread"
 122     ;;
 123   freebsd*)
 124     SYS=freebsd
 125     CFLAGS="${CFLAGS} -pthread"
 126     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 127     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 128     ;;
 129   openbsd*)
 130     SYS=openbsd
 131     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 132     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 133     ;;
 134   netbsd*)
 135     SYS=netbsd
 136     ;;
 137   dragonfly*)
 138     SYS=dragonfly
 139     ;;
 140   darwin*)
 141
 142     dnl Force gcc "-arch" flag
 143     ARCH_flag=""
 144     case "${host}" in
 145       i?86*)
 146         ARCH_flag="-arch i386"
 147         YASMFLAGS="-f macho32"
 148       ;;
 149       ppc64*)
 150         ARCH_flag="-arch ppc64"
 151       ;;
 152       ppc*)
 153         ARCH_flag="-arch ppc"
 154       ;;
 155       x86_64*)
 156         ARCH_flag="-arch x86_64"
 157         YASMFLAGS="-f macho64"
 158       ;;
 159       arm*)
 160         ac_cv_c_bigendian="no"
 161         ac_cv_c_attribute_packed="no"
 162       ;;
 163     esac
 164
 165     SYS=darwin
 166     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 167     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 168     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 169     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu99 ${ARCH_flag}"
 170     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 171     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 172     VLC_ADD_LIBS([avcodec access_avio swscale postproc i420_rgb_mmx x262 x264 x26410b],[-Wl,-read_only_relocs,suppress])
 173     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 174
 175     dnl Allow binaries created on Lion to run on earlier releases
 176     AC_EGREP_CPP(yes,
 177            [#import <Cocoa/Cocoa.h>
 178             #ifdef MAC_OS_X_VERSION_10_7
 179             yes
 180             #endif],
 181             [AC_MSG_RESULT([yes])
 182             AC_LIBOBJ([getdelim])
 183             AC_LIBOBJ([strndup])
 184             AC_LIBOBJ([strnlen])],)
 185
 186     dnl
 187     dnl  Handle Mac OS X SDK flags
 188     dnl
 189     AC_ARG_WITH(macosx-sdk,
 190       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 191         [compile using the SDK in DIR])])
 192     if test "${with_macosx_sdk}" != "" ; then
 193         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 194         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 195         CC="${CC} -isysroot ${with_macosx_sdk}"
 196         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 197         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 198         LD="${LD} -syslibroot ${with_macosx_sdk}"
 199     fi
 200     AC_ARG_WITH(macosx-version-min,
 201       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 202         [compile for Mac OS X VERSION and above])])
 203     if test "${with_macosx_version_min}" != "" ; then
 204         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 205         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 206         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 207         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 208         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 209     fi
 210     ;;
 211   *mingw32* | *cygwin* | *wince* | *mingwce*)
 212     AC_CHECK_TOOL(WINDRES, windres, :)
 213     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 214     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 215     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
 216     AH_TOP([#endif])
 217     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 218     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 219     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 220
 221     case "${host_os}" in
 222       *mingw32*)
 223         SYS=mingw32
 224         ;;
 225       *cygwin*)
 226         dnl Check if we are using the mno-cygwin mode in which case we are
 227         dnl actually dealing with a mingw32 compiler.
 228         AC_EGREP_CPP(yes,
 229             [#ifdef _WIN32
 230              yes
 231              #endif],
 232             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 233         ;;
 234     esac
 235
 236     if test "${SYS}" = "mingw32"; then
 237         # DEP, ASLR, NO SEH
 238         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 239
 240         VLC_ADD_LIBS([libvlccore],[-lwinmm])
 241         VLC_ADD_LDFLAGS([vlc],[-mwindows])
 242         VLC_ADD_LIBS([win32text],[-lgdi32])
 243         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 244         ac_default_prefix="`pwd`/_win32"
 245         DESTDIR="`pwd`/_win32/"
 246
 247         dnl
 248         dnl NSIS/MSI Installer prefix and WIN64
 249         dnl
 250         case "${host}" in
 251             amd64*|x86_64*)
 252                 HAVE_WIN64="1"
 253                 WINDOWS_ARCH="x64"
 254                 PROGRAMFILES="PROGRAMFILES64"
 255                 YASMFLAGS="-f win64"
 256             ;;
 257             *)
 258                 WINDOWS_ARCH="x86"
 259                 PROGRAMFILES="PROGRAMFILES"
 260                 YASMFLAGS="-f win32"
 261             ;;
 262         esac
 263         AC_SUBST(WINDOWS_ARCH)
 264         AC_SUBST(PROGRAMFILES)
 265
 266     fi
 267     ;;
 268   *nto*)
 269     SYS=nto
 270     ;;
 271   solaris*)
 272     SYS=solaris
 273     ;;
 274   hpux*)
 275     SYS=hpux
 276     ;;
 277   symbian*)
 278     SYS=symbian
 279     ;;
 280   *os2*)
 281     SYS=os2
 282     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild"
 283     ;;
 284   *)
 285     SYS="${host_os}"
 286     ;;
 287 esac
 288 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 289 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 290 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 291 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 292 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
 293 AM_CONDITIONAL(HAVE_SYMBIAN, test "${SYS}" = "symbian")
 294
 295 AC_SUBST(YASMFLAGS)
 296
 297 dnl
 298 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 299 dnl for program foo on win32
 300 case "${build_os}" in
 301     cygwin|msys)
 302         ac_executable_extensions=".exe"
 303     ;;
 304     *)
 305     ;;
 306 esac
 307
 308 dnl Android is linux, but a bit different
 309 AS_IF([test "$SYS" = linux],[
 310     AC_MSG_CHECKING([for an Android system])
 311     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 312         [[#ifndef __ANDROID__
 313          # error Not Android
 314          #endif
 315         ]],[[;]])
 316     ],[
 317       HAVE_ANDROID="1"
 318       AC_MSG_RESULT([yes])
 319     ],[
 320       AC_MSG_RESULT([no])
 321     ])
 322 ])
 323 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 324
 325
 326 dnl
 327 dnl  Check for the contrib directory
 328 dnl
 329 AC_ARG_WITH(contrib,
 330   [AS_HELP_STRING([--with-contrib[=DIR]],
 331     [search for 3rd party libraries in DIR/include and DIR/lib])
 332 ])
 333 AC_MSG_CHECKING([for 3rd party libraries path])
 334 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 335   CONTRIB_DIR="${srcdir}/contrib/${host}"
 336   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 337     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 338     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 339     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 340       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 341       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
 342       AS_IF([test ! -d "${CONTRIB_DIR}"], [
 343         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 344         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
 345         AS_IF([test ! -d "${CONTRIB_DIR}"], [
 346           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 347           CONTRIB_DIR=""
 348           AC_MSG_RESULT([not found])
 349         ])
 350       ])
 351     ])
 352   ])
 353 ], [
 354   AS_IF([test "${with_contrib}" != "no"], [
 355     CONTRIB_DIR="${with_contrib}"
 356   ], [
 357     CONTRIB_DIR=""
 358     AC_MSG_RESULT([disabled])
 359   ])
 360 ])
 361 AS_IF([test -n "${CONTRIB_DIR}"], [
 362   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 363     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 364   ], [
 365     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 366     CONTRIB_DIR=""
 367     AC_MSG_RESULT([not usable])
 368   ])
 369
 370 ])
 371 AS_IF([test -n "${CONTRIB_DIR}"], [
 372   AC_MSG_RESULT([${CONTRIB_DIR}])
 373   export PATH=${CONTRIB_DIR}/bin:$PATH
 374   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 375   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 376   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 377   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
 378   AS_IF([test "$build" = "$host" -o "$PKG_CONFIG_LIBDIR"], [
 379     export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 380   ], [
 381     export PKG_CONFIG_LIBDIR="${CONTRIB_DIR}/lib/pkgconfig"
 382   ])
 383   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 384
 385   AS_IF([test "${SYS}" = "darwin"], [
 386     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 387     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 388   ])
 389 ], [
 390   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 391     AC_MSG_ERROR([Third party libraries not found!])
 392   ])
 393 ])
 394 AC_SUBST(CONTRIB_DIR)
 395
 396 dnl
 397 dnl  Libtool
 398 dnl  It's very bad, but our former custom system was worst
 399 dnl  -- Courmisch
 400 dnl
 401
 402 dnl override platform specific check for dependent libraries
 403 dnl otherwise libtool linking of shared libraries will
 404 dnl fail on anything other than pass_all.
 405 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 406     [lt_cv_deplibs_check_method=pass_all])
 407
 408 LT_INIT([dlopen win32-dll shared disable-static])
 409 LT_LANG([C++])
 410 LT_LANG([Windows Resource])
 411
 412 DOLT
 413
 414 lt_cv_deplibs_check_method=pass_all
 415
 416 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 417   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 418 ])
 419
 420 dnl
 421 dnl Gettext stuff
 422 dnl
 423 AM_GNU_GETTEXT_VERSION([0.18.3])
 424 AM_GNU_GETTEXT([external], [need-ngettext])
 425
 426 dnl
 427 dnl Iconv stuff
 428 dnl
 429 AM_ICONV
 430
 431 dnl
 432 dnl checks for mingw
 433 AS_IF([test "${SYS}" = "mingw32"], [
 434 dnl Check for broken versions of mingw-runtime compatability library
 435     AC_MSG_CHECKING(for broken mingw-runtime)
 436     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 437 #include <_mingw.h>
 438 #if defined(__MINGW64_VERSION_MAJOR)
 439 # if __MINGW64_VERSION_MAJOR < 3
 440 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
 441 # endif
 442 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 443 # error Attempting to use mingw-runtime with broken vsnprintf support
 444 #endif
 445     ])], [
 446         AC_MSG_RESULT([ok])
 447     ], [
 448         AC_MSG_RESULT([present])
 449         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 450     ])
 451     dnl force use of mingw provided c99 *printf over msvcrt
 452     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 453
 454 dnl Check for the need to include the mingwex lib for mingw32
 455     VLC_SAVE_FLAGS
 456     AC_CHECK_LIB(mingwex,opendir,
 457         AC_CHECK_LIB(mingw32,opendir,,
 458             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 459     )
 460     VLC_RESTORE_FLAGS
 461
 462 dnl Check for fnative-struct or mms-bitfields support for mingw32
 463     VLC_SAVE_FLAGS
 464     CFLAGS="${CFLAGS} -mms-bitfields"
 465     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 466     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 467         [ac_cv_c_mms_bitfields],
 468         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 469     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 470         VLC_RESTORE_FLAGS
 471         CFLAGS="${CFLAGS} -fnative-struct"
 472         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 473         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 474             [ac_cv_c_fnative_struct],
 475             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 476         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 477     fi
 478 ])
 479
 480 AC_ARG_ENABLE(winstore_app,
 481      AS_HELP_STRING([--enable-winstore-app],
 482                     [Build targetted for Windows Store apps (default disabled)]))
 483
 484 vlc_winstore_app=0
 485 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" = "yes"], [
 486     vlc_winstore_app=1
 487     VLC_ADD_LIBS([libvlccore], [-lole32 -lruntimeobject])
 488     ])
 489 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 490
 491
 492 dnl
 493 dnl Buggy glibc prevention. Purposedly not cached.
 494 dnl See sourceware.org bugs 5058 and 5443.
 495 dnl Ubuntu alone has 20 bug numbers for this...
 496 dnl
 497 AC_MSG_CHECKING(for buggy GNU/libc versions)
 498 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 499 #include <limits.h>
 500 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 501   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 502 # error GNU/libc with dcgettext killer bug!
 503 #endif
 504 ])], [
 505   AC_MSG_RESULT([not present])
 506 ], [
 507   AC_MSG_RESULT([found])
 508   AS_IF([test "x${enable_nls}" != "xno"], [
 509     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 510 work-around for this. Check with your distribution vendor on how to update the
 511 glibc run-time. Alternatively, build with --disable-nls.])
 512   ])
 513 ])
 514
 515 dnl Plugin compilation stuff
 516
 517 VLC_LIBRARY_SUFFIX
 518
 519 dnl Check for system libs needed
 520 need_libc=false
 521
 522 dnl Check for usual libc functions
 523 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
 524 AC_CHECK_FUNCS([daemon fcntl fstatvfs fork getenv getpwuid_r isatty lstat memalign mmap openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale])
 525 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir flockfile fsync getdelim getpid gmtime_r lldiv localtime_r nrand48 poll posix_memalign rewind setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strsep strtof strtok_r strtoll swab tdestroy strverscmp])
 526 AC_CHECK_FUNCS(fdatasync,,
 527   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 528 ])
 529
 530 dnl mingw64 implements those as static inline, not functions with C linkage
 531 AC_LINK_IFELSE([
 532     AC_LANG_PROGRAM([#include <stdio.h>], [
 533         char *c;
 534         if (asprintf(&c, "%s %d", "string", 1) == -1)
 535             c = NULL;
 536     ])],[AC_DEFINE([HAVE_ASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([asprintf])])
 537 AC_LINK_IFELSE([
 538     AC_LANG_PROGRAM([#include <stdio.h>
 539                      #include <stdarg.h>], [
 540         char *c;
 541         va_list ap;
 542         if (vasprintf(&c, "%s %d", ap) == -1)
 543             c = NULL;
 544     ])],[AC_DEFINE([HAVE_VASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([vasprintf])])
 545
 546 dnl C11 static_assert()
 547 AC_MSG_CHECKING([for static_assert in assert.h])
 548 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 549 static_assert(1, "The impossible happened.");
 550 ])], [
 551   AC_MSG_RESULT([yes])
 552   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 553 ], [
 554   AC_MSG_RESULT([no])
 555 ])
 556
 557 # Windows CE does not have strcoll()
 558 AC_FUNC_STRCOLL
 559
 560 dnl Check for non-standard system calls
 561 case "$SYS" in
 562   "linux")
 563     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
 564     ;;
 565   "mingw32")
 566     AC_CHECK_FUNCS([_lock_file])
 567     ;;
 568 esac
 569
 570 AH_BOTTOM([#include <vlc_fixups.h>])
 571
 572 dnl Check for struct pollfd
 573 AC_CHECK_TYPES([struct pollfd],,,
 574 [#include <sys/types.h>
 575 #if HAVE_POLL
 576 # include <poll.h>
 577 #elif defined (_WIN32)
 578 # include <winsock2.h>
 579 #endif
 580 ])
 581
 582 dnl Checks for socket stuff
 583 VLC_SAVE_FLAGS
 584 SOCKET_LIBS=""
 585 AC_SEARCH_LIBS(connect, [socket], [
 586   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 587     SOCKET_LIBS="$ac_cv_search_connect"
 588   ])
 589 ], [
 590   AS_IF([test "${SYS}" = "mingw32"], [
 591     SOCKET_LIBS="-lws2_32"
 592   ])
 593 ])
 594
 595 AC_SEARCH_LIBS([getaddrinfo], [nsl], [
 596  AS_IF([test "$ac_cv_search_getaddrinfo" != "none required"], [
 597     SOCKET_LIBS="$ac_cv_search_getaddrinfo $SOCKET_LIBS"
 598   ])
 599 ],, [${SOCKET_LIBS}])
 600
 601 LIBS="${LIBS} ${SOCKET_LIBS}"
 602 AC_LINK_IFELSE([
 603     AC_LANG_PROGRAM([#ifdef _WIN32
 604         # if _WIN32_WINNT < 0x600
 605         #  error Needs vista+
 606         # endif
 607         #include <ws2tcpip.h>
 608         #else
 609         #include <sys/socket.h>
 610         #include <arpa/inet.h>
 611         #endif], [
 612         char dst[[sizeof(struct in_addr)]];
 613         inet_pton(AF_INET, "127.0.0.1", dst);
 614     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 615 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 616 VLC_RESTORE_FLAGS
 617
 618 AS_IF([test -n "$SOCKET_LIBS"], [
 619   VLC_ADD_LIBS([access_rtmp access_output_shout sap stream_out_standard stream_out_rtp stream_out_raop vod_rtsp oldrc netsync gnutls ts remoteosd audiobargraph_a],[${SOCKET_LIBS}])
 620 ])
 621 AC_SUBST(SOCKET_LIBS)
 622
 623 dnl Check for socklen_t
 624 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 625 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 626 ac_cv_type_socklen_t,
 627 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 628 [#include <sys/types.h>
 629 #ifdef _WIN32
 630 # include <winsock2.h>
 631 # include <ws2tcpip.h>
 632 #else
 633 # include <sys/socket.h>
 634 #endif]], [[socklen_t len; len = 0;]])],
 635 ac_cv_type_socklen_t=yes,
 636 ac_cv_type_socklen_t=no)])
 637 AS_IF([test "$ac_cv_type_socklen_t" = no],
 638  [AC_DEFINE(socklen_t, int)])
 639
 640 dnl Check for struct sockaddr_storage
 641 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 642 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 643 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 644   [AC_TRY_COMPILE(
 645     [#include <sys/types.h>
 646      #if defined( _WIN32 )
 647      # include <winsock2.h>
 648      #else
 649      # include <sys/socket.h>
 650      #endif], [struct sockaddr_storage addr;],
 651      ac_cv_struct_sockaddr_storage=yes,
 652      ac_cv_struct_sockaddr_storage=no)])
 653 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 654   AC_DEFINE(sockaddr_storage, sockaddr)
 655   AC_DEFINE(ss_family, sa_family)
 656 ])
 657
 658 dnl FreeBSD has a gnugetopt library for this:
 659 GNUGETOPT_LIBS=""
 660 AC_CHECK_FUNC(getopt_long,, [
 661   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 662     GNUGETOPT_LIBS="-lgnugetopt"
 663   ])
 664 ])
 665 AC_SUBST(GNUGETOPT_LIBS)
 666
 667 AC_CHECK_LIB(m,cos,[
 668   VLC_ADD_LIBS([adjust wave ripple psychedelic gradient a52tofloat32 dtstofloat32 x264 goom noise grain scene chorus_flanger freetype swscale postproc equalizer spatializer param_eq samplerate freetype mpc qt4 compressor headphone_channel_mixer normvol audiobargraph_a audiobargraph_v mono colorthres extract ball hotkeys mosaic gaussianblur x262 x26410b hqdn3d anaglyph oldrc ncurses oldmovie glspectrum],[-lm])
 669   LIBM="-lm"
 670 ], [
 671   LIBM=""
 672 ])
 673 AC_SUBST(LIBM)
 674
 675 AC_CHECK_LIB(m,lrintf, [
 676   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 677   VLC_ADD_LIBS([skins2],[-lm])
 678 ])
 679
 680 dnl Check for dynamic plugins
 681 LIBDL=""
 682 have_dynamic_objects="no"
 683 VLC_SAVE_FLAGS
 684 AC_SEARCH_LIBS(dlopen, [dl svld], [
 685   AS_IF([test "$ac_cv_search_dlopen" != "none required"], [
 686     LIBDL="$ac_cv_search_dlopen"
 687   ])
 688   have_dynamic_objects="yes"
 689 ])
 690 VLC_RESTORE_FLAGS
 691
 692 # Windows
 693 AS_IF([test "${SYS}" = "mingw32"], [
 694   LIBDL=""
 695   have_dynamic_objects="yes" #assume we can use shared objects
 696 ])
 697
 698 AS_IF([test "${enable_shared}" = "no"], [
 699   have_dynamic_objects=no
 700 ])
 701 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 702
 703 AC_SUBST(LIBDL)
 704
 705 dnl Check for thread library
 706 LIBPTHREAD=""
 707 AS_IF([test "${SYS}" != "mingw32"], [
 708   VLC_SAVE_FLAGS
 709   LIBS=""
 710   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 711     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 712       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 713     ])
 714   ])
 715   VLC_RESTORE_FLAGS
 716
 717   AC_CHECK_LIB(rt, clock_nanosleep, [
 718     VLC_ADD_LIBS([libvlccore],[-lrt])
 719   ], [
 720     AC_CHECK_FUNC(nanosleep,,[
 721       AC_CHECK_LIB(rt,nanosleep, [
 722         VLC_ADD_LIBS([libvlccore],[-lrt])
 723       ], [
 724         AC_CHECK_LIB(posix4,nanosleep, [
 725           VLC_ADD_LIBS([libvlccore],[-lposix4])
 726         ])
 727       ])
 728     ])
 729     dnl HP/UX port
 730     AC_CHECK_LIB(rt,sem_init, [VLC_ADD_LIBS([libvlccore],[-lrt])])
 731   ])
 732 ])
 733 AC_SUBST(LIBPTHREAD)
 734
 735 dnl Check for headers
 736 AC_CHECK_HEADERS([search.h])
 737 AC_CHECK_HEADERS(getopt.h locale.h xlocale.h)
 738 AC_CHECK_HEADERS([sys/time.h sys/ioctl.h])
 739 AC_CHECK_HEADERS([arpa/inet.h netinet/udplite.h sys/eventfd.h])
 740 AC_CHECK_HEADERS([net/if.h], [], [],
 741   [
 742     #include <sys/types.h>
 743     #include <sys/socket.h>
 744   ])
 745 AC_CHECK_HEADERS([sys/mount.h], [], [],
 746   [
 747     #include <sys/param.h>
 748   ])
 749
 750 if test "${SYS}" != "mingw32"; then
 751   AC_CHECK_HEADERS(machine/param.h sys/shm.h)
 752   AC_CHECK_HEADERS([linux/version.h linux/dccp.h scsi/scsi.h linux/magic.h])
 753   AC_CHECK_HEADERS(syslog.h mntent.h)
 754 fi # end "${SYS}" != "mingw32"
 755
 756 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 757 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 758 AC_CHECK_TYPE(ssize_t,, [
 759   AC_DEFINE(ssize_t, int)
 760 ])
 761
 762 dnl Check for threads library
 763 if test "${SYS}" != "mingw32"; then
 764   AC_CHECK_HEADERS(pthread.h)
 765 fi # end "${SYS}" != "mingw32"
 766
 767 dnl It seems that autoconf detects pkg-config only during the first
 768 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 769 dnl it is nested within a conditional block, so it was not working right.
 770 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 771 AC_ARG_VAR(PKG_CONFIG_PATH,
 772        [Paths where to find .pc not at the default location])
 773 PKG_PROG_PKG_CONFIG()
 774
 775 dnl On some OS we need static linking
 776 AS_IF([test -n "${PKG_CONFIG}" ],[
 777     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 778         PKG_CONFIG="${PKG_CONFIG} --static"
 779     ])
 780 ])
 781
 782
 783 dnl
 784 dnl Check for zlib.h and -lz along with system -lminizip if available
 785 dnl
 786 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 787 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 788 if test "${have_zlib}" = "yes"
 789 then
 790   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
 791   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 792     AC_CHECK_HEADERS([unzip.h], [
 793       have_minizip=yes
 794       MINIZIP_LIBS="-lminizip -lz"
 795     ], [
 796       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
 797       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
 798       have_minizip=no
 799     ])
 800   ])
 801   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
 802   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
 803 fi
 804 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 805
 806
 807 dnl
 808 dnl Domain name i18n support via GNU libidn
 809 dnl
 810 PKG_CHECK_MODULES([IDN], [libidn], [
 811   have_libidn="yes"
 812   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 813 ], [
 814   have_libidn="no"
 815 ])
 816
 817
 818 dnl Check for dbus
 819 AC_ARG_ENABLE(dbus,
 820   [AS_HELP_STRING([--enable-dbus],
 821     [compile D-Bus message bus support (default enabled)])])
 822 have_dbus="no"
 823 AS_IF([test "${enable_dbus}" != "no"], [
 824   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 825     have_dbus="yes"
 826   ], [
 827     AS_IF([test -n "${enable_dbus}"], [
 828       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 829     ], [
 830       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 831     ])
 832   ])
 833 ])
 834 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 835
 836 dnl Check for ntohl, etc.
 837 VLC_SAVE_FLAGS
 838 CFLAGS="${CFLAGS} -Wall -Werror"
 839 AC_CACHE_CHECK([for ntohl in sys/param.h],
 840     [ac_cv_c_ntohl_sys_param_h],
 841     [     AC_TRY_COMPILE([#include <sys/param.h>],
 842         [int meuh; ntohl(meuh);],
 843         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 844 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 845     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 846 fi
 847 VLC_RESTORE_FLAGS
 848
 849 EXTEND_HELP_STRING([Optimization options:])
 850 dnl
 851 dnl  Compiler warnings
 852 dnl
 853
 854 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration])
 855 RDC_PROG_CC_FLAGS([-pipe])
 856 AC_LANG_PUSH([C++])
 857 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var])
 858 AC_LANG_POP([C++])
 859
 860 dnl
 861 dnl  Debugging mode
 862 dnl
 863 AC_ARG_ENABLE(debug,
 864   [AS_HELP_STRING([--enable-debug],
 865     [build with run-time assertions (default disabled)])],,
 866   [enable_debug="no"])
 867 AH_TEMPLATE(NDEBUG,
 868             [Define to 1 if debug code should NOT be compiled])
 869 AS_IF([test "${enable_debug}" != "no"], [
 870   AC_CHECK_HEADERS([valgrind/valgrind.h])
 871 ], [
 872   AC_DEFINE(NDEBUG)
 873 ])
 874
 875 dnl
 876 dnl  Profiling
 877 dnl
 878 AC_ARG_ENABLE(gprof,
 879   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 880   [enable_gprof="no"])
 881 AS_IF([test "${enable_gprof}" != "no"], [
 882   CFLAGS="${CFLAGS} -pg"
 883   CXXFLAGS="${CXXFLAGS} -pg"
 884   OBJCFLAGS="${OBJCFLAGS} -pg"
 885   LDFLAGS="${LDFLAGS} -pg"
 886 ])
 887
 888 AC_ARG_ENABLE(cprof,
 889   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 890   [enable_cprof="no"])
 891 AS_IF([test "${enable_gprof}" != "no"], [
 892   CFLAGS="${CFLAGS} -finstrument-functions"
 893   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 894   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 895   LDFLAGS="${LDFLAGS} -finstrument-functions"
 896 ])
 897
 898 dnl
 899 dnl  Test coverage
 900 dnl
 901 AC_ARG_ENABLE(coverage,
 902   [AS_HELP_STRING([--enable-coverage],
 903     [build for test coverage (default disabled)])],,
 904   [enable_coverage="no"])
 905 AS_IF([test "${enable_coverage}" != "no"], [
 906   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 907   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 908   LDFLAGS="-lgcov ${LDFLAGS}"
 909 ])
 910
 911 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 912   VLC_SAVE_FLAGS
 913   CFLAGS="${CFLAGS} -fvisibility=hidden"
 914   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 915   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 916   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 917                  [ac_cv_c_visibility_hidden], [
 918     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 919       ac_cv_c_visibility_hidden=yes
 920     ], [
 921       ac_cv_c_visibility_hidden=no
 922     ])
 923   ])
 924   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
 925 ])
 926
 927
 928 dnl
 929 dnl  Enable/disable optimizations
 930 dnl
 931 AC_ARG_ENABLE(optimizations,
 932   [AS_HELP_STRING([--disable-optimizations],
 933     [disable compiler optimizations (default enabled)])],,
 934   [enable_optimizations="yes"])
 935
 936 dnl Check for various optimization flags
 937 AS_IF([test "${enable_optimizations}" != "no"], [
 938
 939   dnl -O4 and -O3 only in production builds
 940   AS_IF([test "{enable_debug}" = "no"], [
 941     VLC_SAVE_FLAGS
 942     CFLAGS="${CFLAGS} -O4"
 943     CXXFLAGS="${CXXFLAGS} -O4"
 944     OBJCFLAGS="${OBJCFLAGS} -O4"
 945     AC_CACHE_CHECK([if $CC accepts -O4], [ac_cv_c_o4], [
 946       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 947         ac_cv_c_o4=yes
 948       ], [
 949         ac_cv_c_o4=no
 950       ])
 951     ])
 952     AS_IF([test "${ac_cv_c_o4}" = "no"], [
 953       VLC_RESTORE_FLAGS
 954       CFLAGS="${CFLAGS} -O3"
 955       CXXFLAGS="${CXXFLAGS} -O3"
 956       OBJCFLAGS="${OBJCFLAGS} -O3"
 957       AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
 958         AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 959           ac_cv_c_o3=yes
 960         ], [
 961           ac_cv_c_o3=no
 962         ])
 963       ])
 964       AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
 965     ])
 966   ])
 967
 968   dnl Check for -ffast-math
 969   VLC_SAVE_FLAGS
 970   CFLAGS="${CFLAGS} -ffast-math"
 971   CXXFLAGS="${CXXFLAGS} -ffast-math"
 972   OBJCFLAGS="${OBJCFLAGS} -ffast-math"
 973   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
 974     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 975       ac_cv_c_fast_math=yes
 976     ], [
 977       ac_cv_c_fast_math=no
 978     ])
 979   ])
 980   AS_IF([test "${ac_cv_c_fast_math}" = "no"], [VLC_RESTORE_FLAGS])
 981   AH_BOTTOM([
 982 #ifndef __FAST_MATH__
 983 # pragma STDC FENV_ACCESS OFF
 984 # pragma STDC FP_CONTRACT ON
 985 #endif
 986 ])
 987
 988   dnl Check for -funroll-loops
 989   VLC_SAVE_FLAGS
 990   CFLAGS="${CFLAGS} -funroll-loops"
 991   CXXFLAGS="${CXXFLAGS} -funroll-loops"
 992   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
 993   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
 994     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 995       ac_cv_c_unroll_loops=yes
 996     ], [
 997       ac_cv_c_unroll_loops=no
 998     ])
 999   ])
1000   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1001
1002   AS_IF([test "$enable_debug" = "no"], [
1003     dnl Check for -fomit-frame-pointer
1004     VLC_SAVE_FLAGS
1005     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1006     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1007     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1008     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1009       [ac_cv_c_omit_frame_pointer], [
1010       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1011         ac_cv_c_omit_frame_pointer=yes
1012       ], [
1013         ac_cv_c_omit_frame_pointer=no
1014       ])
1015     ])
1016     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1017   ])
1018 ])
1019
1020 VLC_SAVE_FLAGS
1021 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1022 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1023   AC_TRY_LINK([],, [
1024     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1025   ], [
1026     ac_cv_ld_bsymbolic=""
1027   ])
1028 ])
1029 VLC_RESTORE_FLAGS
1030 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1031 AC_SUBST(SYMBOLIC_LDFLAGS)
1032
1033 dnl Checks for __attribute__(aligned()) directive
1034 VLC_SAVE_FLAGS
1035 CFLAGS="${CFLAGS} -Werror"
1036 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1037     [ac_cv_c_attribute_aligned],
1038     [ac_cv_c_attribute_aligned=0
1039     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1040         AC_TRY_COMPILE([],
1041         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1042         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1043     done])
1044 VLC_RESTORE_FLAGS
1045 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1046     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1047         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1048 fi
1049
1050 dnl Check for __attribute__((packed))
1051 AC_CACHE_CHECK([for __attribute__((packed))],
1052   [ac_cv_c_attribute_packed],
1053   [ac_cv_c_attribute_packed=no
1054    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1055                     [ac_cv_c_attribute_packed=yes])])
1056 if test "${ac_cv_c_attribute_packed}" != "no"; then
1057   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1058 fi
1059
1060 dnl
1061 dnl  Check the CPU
1062 dnl
1063 case "${host_cpu}" in
1064   "")
1065     ARCH=unknown
1066     ;;
1067   *)
1068     ARCH="${host_cpu}"
1069     ;;
1070 esac
1071
1072 dnl Check for backtrace() support
1073 AC_CHECK_HEADERS(execinfo.h)
1074 AC_CHECK_FUNCS(backtrace)
1075
1076 dnl
1077 dnl  default modules
1078 dnl
1079 ALIASES="${ALIASES} cvlc rvlc"
1080
1081 dnl
1082 dnl  Accelerated modules
1083 dnl
1084
1085 dnl  Check for fully working MMX intrinsics
1086 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1087 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1088 AC_ARG_ENABLE(mmx,
1089   [AS_HELP_STRING([--disable-mmx],
1090     [disable MMX optimizations (default auto)])],,[
1091   case "${host_cpu}" in
1092     i?86|x86_64)
1093       enable_mmx="yes"
1094       ;;
1095     *)
1096       enable_mmx="no"
1097       ;;
1098   esac
1099 ])
1100 have_mmx="no"
1101 have_mmxext="no"
1102 AS_IF([test "${enable_mmx}" != "no"], [
1103   ARCH="${ARCH} mmx"
1104   VLC_SAVE_FLAGS
1105   CFLAGS="${CFLAGS} -mmmx"
1106   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1107     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1108 [#include <mmintrin.h>
1109 #include <stdint.h>
1110 uint64_t frobzor;]], [
1111 [__m64 a, b, c;
1112 a = b = c = (__m64)frobzor;
1113 a = _mm_slli_pi16(a, 3);
1114 a = _mm_adds_pi16(a, b);
1115 c = _mm_srli_pi16(c, 8);
1116 c = _mm_slli_pi16(c, 3);
1117 b = _mm_adds_pi16(b, c);
1118 a = _mm_unpacklo_pi8(a, b);
1119 frobzor = (uint64_t)a;]])], [
1120       ac_cv_c_mmx_intrinsics=yes
1121     ], [
1122       ac_cv_c_mmx_intrinsics=no
1123     ])
1124   ])
1125   VLC_RESTORE_FLAGS
1126   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1127     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1128   ])
1129
1130   VLC_SAVE_FLAGS
1131   CFLAGS="${CFLAGS} -mmmx"
1132   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1133     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1134 void *p;
1135 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1136 ]])
1137     ], [
1138       ac_cv_mmx_inline=yes
1139     ], [
1140       ac_cv_mmx_inline=no
1141     ])
1142   ])
1143   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1144     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1145     have_mmx="yes"
1146   ])
1147
1148   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1149                  [ac_cv_mmxext_inline], [
1150     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1151 void *p;
1152 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1153 ]])
1154     ], [
1155       ac_cv_mmxext_inline=yes
1156     ], [
1157       ac_cv_mmxext_inline=no
1158     ])
1159   ])
1160   VLC_RESTORE_FLAGS
1161   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1162     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1163     have_mmxext="yes"
1164   ])
1165 ])
1166 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1167 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1168
1169 dnl  Check for fully workin SSE2 intrinsics
1170 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1171 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1172 AC_ARG_ENABLE(sse,
1173   [AS_HELP_STRING([--disable-sse],
1174     [disable SSE (1-4) optimizations (default auto)])],, [
1175   case "${host_cpu}" in
1176     i?86|x86_64)
1177       enable_sse=yes
1178       ;;
1179     *)
1180       enable_sse=no
1181       ;;
1182   esac
1183 ])
1184 have_sse2="no"
1185 AS_IF([test "${enable_sse}" != "no"], [
1186   ARCH="${ARCH} sse sse2"
1187
1188   VLC_SAVE_FLAGS
1189   CFLAGS="${CFLAGS} -msse2"
1190   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1191     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1192 [#include <emmintrin.h>
1193 #include <stdint.h>
1194 uint64_t frobzor;]], [
1195 [__m128i a, b, c;
1196 a = b = c = _mm_set1_epi64((__m64)frobzor);
1197 a = _mm_slli_epi16(a, 3);
1198 a = _mm_adds_epi16(a, b);
1199 c = _mm_srli_epi16(c, 8);
1200 c = _mm_slli_epi16(c, 3);
1201 b = _mm_adds_epi16(b, c);
1202 a = _mm_unpacklo_epi8(a, b);
1203 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1204       ac_cv_c_sse2_intrinsics=yes
1205     ], [
1206       ac_cv_c_sse2_intrinsics=no
1207     ])
1208   ])
1209   VLC_RESTORE_FLAGS
1210   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1211     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1212   ])
1213
1214   VLC_SAVE_FLAGS
1215   CFLAGS="${CFLAGS} -msse"
1216   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1217     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1218 void *p;
1219 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1220 ]])
1221     ], [
1222       ac_cv_sse_inline=yes
1223     ], [
1224       ac_cv_sse_inline=no
1225     ])
1226   ])
1227
1228   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1229     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1230   ])
1231
1232   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1233     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1234 void *p;
1235 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1236 ]])
1237     ], [
1238       ac_cv_sse2_inline=yes
1239     ], [
1240       ac_cv_sse2_inline=no
1241     ])
1242   ])
1243   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1244     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1245     have_sse2="yes"
1246   ])
1247
1248   # SSE3
1249   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1250     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1251 void *p;
1252 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1253 ]])
1254     ], [
1255       ac_cv_sse3_inline=yes
1256     ], [
1257       ac_cv_sse3_inline=no
1258     ])
1259   ])
1260
1261   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1262     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1263   # SSSE3
1264   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1265     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1266 void *p;
1267 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1268 ]])
1269     ], [
1270       ac_cv_ssse3_inline=yes
1271     ], [
1272       ac_cv_ssse3_inline=no
1273     ])
1274   ])
1275
1276   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1277     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1278
1279   # SSE4.1
1280   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1281                  [ac_cv_sse4_1_inline], [
1282     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1283 void *p;
1284 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1285 ]])
1286     ], [
1287       ac_cv_sse4_1_inline=yes
1288     ], [
1289       ac_cv_sse4_1_inline=no
1290     ])
1291   ])
1292
1293   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1294     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1295
1296   # SSE4.2
1297   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1298                  [ac_cv_sse4_2_inline], [
1299     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1300 void *p;
1301 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1302 ]])
1303     ], [
1304       ac_cv_sse4_2_inline=yes
1305     ], [
1306       ac_cv_sse4_2_inline=no
1307     ])
1308   ])
1309
1310   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1311     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1312
1313   # SSE4A
1314   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1315     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1316 void *p;
1317 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1318 ]])
1319     ], [
1320       ac_cv_sse4a_inline=yes
1321     ], [
1322       ac_cv_sse4a_inline=no
1323     ])
1324   ])
1325   VLC_RESTORE_FLAGS
1326   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1327     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1328 ])
1329 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1330
1331 VLC_SAVE_FLAGS
1332 CFLAGS="${CFLAGS} -mmmx"
1333 have_3dnow="no"
1334 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1335   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1336 void *p;
1337 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1338 ]])
1339   ], [
1340     ac_cv_3dnow_inline=yes
1341   ], [
1342     ac_cv_3dnow_inline=no
1343   ])
1344 ])
1345 VLC_RESTORE_FLAGS
1346 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1347   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1348             [Define to 1 if 3D Now! inline assembly is available.])
1349   have_3dnow="yes"
1350 ])
1351 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1352
1353
1354 AC_ARG_ENABLE(neon,
1355   [AS_HELP_STRING([--disable-neon],
1356     [disable NEON optimizations (default auto)])],, [
1357   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1358 ])
1359 AS_IF([test "${enable_neon}" != "no"], [
1360   VLC_SAVE_FLAGS
1361   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1362   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1363     AC_COMPILE_IFELSE([
1364       AC_LANG_PROGRAM(,[[
1365 asm volatile("vqmovun.s64 d0, q1":::"d0");
1366 ]])
1367     ], [
1368       ac_cv_arm_neon="yes"
1369     ], [
1370       ac_cv_arm_neon="no"
1371     ])
1372   ])
1373   VLC_RESTORE_FLAGS
1374 ])
1375 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1376
1377
1378 AC_ARG_ENABLE(altivec,
1379   [AS_HELP_STRING([--disable-altivec],
1380     [disable AltiVec optimizations (default auto)])],, [
1381   AS_CASE("${host_cpu}", [powerpc*],
1382         [enable_altivec=yes], [enable_altivec=no])
1383 ])
1384 have_altivec="no"
1385 ALTIVEC_CFLAGS=""
1386 AS_IF([test "${enable_altivec}" = "yes"], [
1387   ARCH="${ARCH} altivec";
1388   VLC_SAVE_FLAGS
1389   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1390     [ac_cv_altivec_inline],
1391     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1392          ac_cv_altivec_inline="yes",
1393          [CFLAGS="${CFLAGS} -Wa,-m7400"
1394           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1395             [ac_cv_altivec_inline="-Wa,-m7400"],
1396             ac_cv_altivec_inline=no)
1397          ])])
1398   VLC_RESTORE_FLAGS
1399   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1400     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1401               [Define to 1 if AltiVec inline assembly is available.])
1402     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1403       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1404       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1405     ])
1406     have_altivec="yes"
1407   ])
1408
1409   VLC_SAVE_FLAGS
1410   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1411   [ac_cv_c_altivec], [
1412     CFLAGS="${CFLAGS} -maltivec"
1413     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1414 [#include <altivec.h>]], [
1415 [vec_ld(0, (unsigned char *)0);]])], [
1416       ac_cv_c_altivec="-maltivec"
1417     ], [
1418       ac_cv_c_altivec="no"
1419     ])
1420   ])
1421   VLC_RESTORE_FLAGS
1422   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1423     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1424     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1425     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1426     ALTIVEC_CFLAGS="$ALTIVEC_FLAGS ${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}"
1427     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1428     have_altivec="yes"
1429   ])
1430   AC_CHECK_HEADERS(altivec.h)
1431
1432   VLC_SAVE_FLAGS
1433   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1434   AC_CACHE_CHECK([if linker needs -framework vecLib],
1435     [ac_cv_ld_altivec],
1436     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1437   VLC_RESTORE_FLAGS
1438   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1439     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1440   ])
1441 ])
1442 AC_SUBST(ALTIVEC_CFLAGS)
1443 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1444
1445 dnl
1446 dnl  Memory usage
1447 dnl
1448 AC_ARG_ENABLE(optimize-memory,
1449   [AS_HELP_STRING([--enable-optimize-memory],
1450     [optimize memory usage over performance])])
1451 if test "${enable_optimize_memory}" = "yes"; then
1452   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1453 fi
1454
1455 dnl
1456 dnl Allow running as root (useful for people running on embedded platforms)
1457 dnl
1458 AC_ARG_ENABLE(run-as-root,
1459   [AS_HELP_STRING([--enable-run-as-root],
1460     [allow running VLC as root (default disabled)])])
1461 AS_IF([test "${enable_run_as_root}" = "yes"],[
1462     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1463               [Define to 1 to allow running VLC as root (uid 0).])
1464 ])
1465
1466 dnl
1467 dnl Stream output
1468 dnl
1469 AC_ARG_ENABLE(sout,
1470   [AS_HELP_STRING([--disable-sout],
1471     [disable streaming output (default enabled)])])
1472 AS_IF([test "${enable_sout}" != "no"], [
1473   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1474 ])
1475 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1476
1477 dnl Lua modules
1478 AC_ARG_ENABLE(lua,
1479   [AS_HELP_STRING([--disable-lua],
1480     [disable LUA scripting support (default enabled)])])
1481 if test "${enable_lua}" != "no"
1482 then
1483   PKG_CHECK_MODULES(LUA, lua5.2,
1484     [ have_lua=yes ],
1485     [
1486     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1487
1488     PKG_CHECK_MODULES(LUA, lua5.1,
1489       [ have_lua=yes ],
1490       [
1491       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1492       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1493         [ have_lua=yes ],
1494         [
1495           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1496           have_lua=yes
1497           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1498             [],
1499             [ have_lua=no ] )
1500           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1501             [LUA_LIBS="-llua5.2"],
1502           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1503             [LUA_LIBS="-llua5.1"],
1504             AC_CHECK_LIB( lua51 , luaL_newstate,
1505               [LUA_LIBS="-llua51"],
1506               AC_CHECK_LIB( lua , luaL_newstate,
1507                 [LUA_LIBS="-llua"],
1508                 [ have_lua=no
1509                 ], [-lm])
1510             )))
1511         ])
1512       ])
1513     ])
1514   if test "x${have_lua}" != "xyes" ;  then
1515       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1516   fi
1517   AC_ARG_VAR([LUAC], [LUA byte compiler])
1518   AC_PATH_PROGS(LUAC,[${LUAC} luac], [false])
1519   AS_IF([test "${LUAC}" = "false"], [
1520     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1521   ])
1522   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}"/lib/liblua.a -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|cut -d' ' -f2` != 0404], [
1523     AC_MSG_ERROR([You need 32-bits luac when using using lua from contrib.])
1524   ])
1525 fi
1526 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1527
1528
1529 dnl
1530 dnl HTTP daemon
1531 dnl
1532 AC_ARG_ENABLE(httpd,
1533   [AS_HELP_STRING([--disable-httpd],
1534     [disable the built-in HTTP server (default enabled)])])
1535 if test "${enable_httpd}" != "no"
1536 then
1537   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1538 fi
1539 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1540
1541
1542 dnl
1543 dnl VideoLAN manager
1544 dnl
1545 AC_ARG_ENABLE(vlm,
1546   [AS_HELP_STRING([--disable-vlm],
1547     [disable the stream manager (default enabled)])],,
1548   [enable_vlm="${enable_sout}"])
1549 AS_IF([test "${enable_vlm}" != "no"], [
1550   AS_IF([test "${enable_sout}" = "no"], [
1551     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1552   ])
1553   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1554 ])
1555 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1556
1557
1558 dnl
1559 dnl  Input plugins
1560 dnl
1561
1562 EXTEND_HELP_STRING([Input plugins:])
1563
1564 dnl
1565 dnl  live555 input
1566 dnl
1567 AC_ARG_ENABLE(live555,
1568   [AS_HELP_STRING([--enable-live555],
1569     [enable RTSP input through live555 (default enabled)])])
1570
1571 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1572   PKG_CHECK_MODULES(LIVE555, live555, [
1573     VLC_ADD_PLUGIN([live555])
1574     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1575     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1576   ], [
1577     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1578
1579     AC_LANG_PUSH(C++)
1580     VLC_SAVE_FLAGS
1581
1582     dnl detect include paths
1583     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1584       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1585     ], [
1586       AS_IF([test "${SYS}" != "os2"], [
1587         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1588         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1589       ], [
1590         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1591         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1592         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1593       ])
1594     ])
1595
1596     dnl CPP Flags
1597     AS_IF([test "${SYS}" = "solaris"], [
1598       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1599     ])
1600     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1601     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1602
1603     dnl version check
1604     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1605       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1606 [#include <liveMedia_version.hh>
1607 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1608 # error BOOM
1609 #endif]])
1610       ], [
1611         ac_cv_live555="yes"
1612       ], [
1613         ac_cv_live555="no"
1614       ])
1615     ])
1616
1617     AS_IF([test "$ac_cv_live555" = "no"], [
1618       AC_MSG_WARN([live555 is missing or its installed version is too old:
1619 Version 2011.12.23 or later is required to proceed.
1620 You can get an updated one from http://www.live555.com/liveMedia .])
1621       AS_IF([test -n "${enable_live555}"], [
1622         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1623       ])
1624     ], [
1625       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1626       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1627       AS_IF([test "${SYS}" = "mingw32"], [
1628         # add ws2_32 for closesocket, select, recv
1629         other_libs="$other_libs -lws2_32"
1630       ])
1631
1632       dnl We need to check for pic because live555 don't provide shared libs
1633       dnl and we want to build a plugins so we need -fPIC on some arch.
1634       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1635       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1636       AC_CHECK_LIB(liveMedia_pic, main, [
1637         VLC_ADD_PLUGIN([live555])
1638         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1639       ],[
1640         AC_CHECK_LIB(liveMedia, main, [
1641           VLC_ADD_PLUGIN([live555])
1642           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1643         ],[],[${other_libs}])
1644       ],[${other_libs_pic}])
1645     ])
1646     VLC_RESTORE_FLAGS
1647     AC_LANG_POP(C++)
1648   ])
1649 ])
1650
1651 dnl
1652 dnl IIDC and DV FireWire input modules
1653 dnl
1654 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1655 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1656
1657 dnl
1658 dnl - linsys modules: access module check for libzvbi
1659 dnl
1660 AC_ARG_ENABLE(linsys,
1661   [AS_HELP_STRING([--enable-linsys],
1662     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1663 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1664   VLC_ADD_PLUGIN([linsys_hdsdi])
1665   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1666     VLC_ADD_PLUGIN([linsys_sdi])
1667   ], [
1668     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1669   ])
1670 ])
1671
1672 dnl
1673 dnl dvdread module: check for libdvdread
1674 dnl
1675 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread], [dvdread input module], [auto])
1676
1677 dnl
1678 dnl libdvdnav plugin
1679 dnl
1680 AC_ARG_ENABLE(dvdnav,
1681   [AS_HELP_STRING([--disable-dvdnav],
1682     [disable DVD navigation with libdvdnav (default auto)])])
1683 AS_IF([test "${enable_dvdnav}" != "no"], [
1684   PKG_CHECK_MODULES(DVDNAV, dvdnav, [
1685     VLC_ADD_PLUGIN([dvdnav])
1686     AC_CHECK_LIB(dvdnav, dvdnav_get_video_resolution,
1687       AC_DEFINE(HAVE_DVDNAV_GET_VIDEO_RESOLUTION, 1, [Define if you have dvdnav_get_video_resolution.]),
1688         [], [${LIBS_dvdnav}])
1689     AC_CHECK_LIB(dvdnav, dvdnav_describe_title_chapters,
1690       AC_DEFINE(HAVE_DVDNAV_DESCRIBE_TITLE_CHAPTERS, 1, [Define if you have dvdnav_describe_title_chapters.]),
1691         [], [${LIBS_dvdnav}])],
1692       [AC_MSG_WARN([${DVDNAV_PKG_ERRORS}.])])
1693 ])
1694
1695 dnl
1696 dnl  Blu-ray Disc Support with libbluray
1697 dnl
1698 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.2.1], (libbluray for Blu-ray disc support ) )
1699
1700 dnl
1701 dnl  OpenCV wrapper and example filters
1702 dnl
1703 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1704
1705
1706 dnl
1707 dnl  libsmbclient plugin
1708 dnl
1709 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1710 AS_IF([test "${SYS}" = "mingw32"], [ VLC_ADD_PLUGIN([access_smb]) ])
1711
1712
1713 dnl
1714 dnl sftp access support
1715 dnl
1716 PKG_ENABLE_MODULES_VLC([SFTP], [access_sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1717
1718 dnl
1719 dnl  Video4Linux 2
1720 dnl
1721 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1722   [disable Video4Linux version 2 (default auto)])])
1723 have_v4l2="no"
1724 AS_IF([test "$enable_v4l2" != "no"], [
1725   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1726     have_v4l2="yes"
1727   ])
1728 ])
1729 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1730
1731 dnl
1732 dnl special access module for Blackmagic SDI cards
1733 dnl
1734 AC_ARG_ENABLE(decklink,
1735   [AS_HELP_STRING([--disable-decklink],
1736     [disable Blackmagic DeckLink SDI input (default auto)])])
1737 AC_ARG_WITH(decklink_sdk,
1738   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1739     [                        location of Blackmagic DeckLink SDI SDK])])
1740 have_decklink=no
1741 if test "${enable_decklink}" != "no"
1742 then
1743   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1744   then
1745     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1746   fi
1747   VLC_SAVE_FLAGS
1748   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1749   AC_LANG_PUSH(C++)
1750   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1751       have_decklink=yes
1752   ], [
1753       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1754   ])
1755   AC_LANG_POP(C++)
1756   VLC_RESTORE_FLAGS
1757 fi
1758 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1759
1760
1761 dnl
1762 dnl  gnomeVFS access module
1763 dnl
1764 PKG_ENABLE_MODULES_VLC([GNOMEVFS], [gnomevfs], [gnome-vfs-2.0], [GnomeVFS access module], [auto])
1765
1766 dnl
1767 dnl  VCDX modules
1768 dnl
1769 PKG_ENABLE_MODULES_VLC([VCDX], [vcdx], [libcdio >= 0.78.2 libiso9660 >= 0.72 libvcdinfo >= 0.7.22], [navigate VCD with libvcdinfo], [no])
1770
1771 dnl
1772 dnl  Built-in CD-DA and VCD module
1773 dnl
1774 AC_ARG_ENABLE(vcd,
1775   [AS_HELP_STRING([--disable-vcd],
1776     [disable built-in VCD and CD-DA support (default enabled)])])
1777
1778 AC_ARG_ENABLE(libcddb,
1779   [AS_HELP_STRING([--disable-libcddb],
1780     [disable CDDB for Audio CD (default enabled)])])
1781
1782 if test "${enable_vcd}" != "no"
1783 then
1784   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1785   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1786     AC_MSG_RESULT(yes)
1787     VLC_ADD_PLUGIN([vcd cdda])
1788   ],[
1789     AC_MSG_RESULT(no)
1790   ])
1791
1792   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1793   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1794     AC_MSG_RESULT(yes)
1795     VLC_ADD_PLUGIN([vcd cdda])
1796     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1797   ],[
1798     AC_MSG_RESULT(no)
1799   ])
1800
1801   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1802   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1803     AC_MSG_RESULT(yes)
1804     VLC_ADD_PLUGIN([vcd cdda])
1805     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1806   ],[
1807     AC_MSG_RESULT(no)
1808   ])
1809
1810   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1811   then
1812     VLC_ADD_PLUGIN([vcd cdda])
1813   fi
1814
1815   if test "$enable_libcddb" != "no"; then
1816     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1817       HAVE_LIBCDDB=yes
1818       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1819       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1820       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1821       ],:
1822       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1823       HAVE_LIBCDDB=no])
1824   fi
1825 fi
1826
1827 dnl
1828 dnl Linux DVB
1829 dnl
1830 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1831   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1832 [#include <linux/dvb/version.h>
1833 #if (DVB_API_VERSION < 5)
1834 # error Linux DVB API v3.2 and older are not supported.
1835 #endif
1836 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1837 # error Linux DVB API v5.0 is unsupported. Please update.
1838 #endif
1839 ]])], [
1840   ac_cv_linux_dvb_5_1=yes
1841 ], [
1842   ac_cv_linux_dvb_5_1=no
1843 ])])
1844 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1845
1846 dnl
1847 dnl  Screen capture module
1848 dnl
1849 AC_ARG_ENABLE(screen,
1850   [AS_HELP_STRING([--enable-screen],
1851     [disable screen capture (default enabled)])])
1852 if test "${enable_screen}" != "no"; then
1853   if test "${SYS}" = "darwin"; then
1854     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1855       VLC_ADD_PLUGIN([screen])
1856     ])
1857   fi
1858 fi
1859 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1860
1861 dnl
1862 dnl  VNC/RFB access module
1863 dnl
1864 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1865
1866 dnl  RDP/Remote Desktop access module
1867 dnl
1868 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1869
1870 dnl
1871 dnl  Real RTSP plugin
1872 dnl
1873 AC_ARG_ENABLE(realrtsp,
1874   [  --enable-realrtsp       Real RTSP module (default disabled)])
1875 if test "${enable_realrtsp}" = "yes"; then
1876   VLC_ADD_PLUGIN([access_realrtsp])
1877 fi
1878
1879 dnl
1880 dnl MacOS eyeTV
1881 AC_ARG_ENABLE(macosx-eyetv,
1882   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1883 if test "x${enable_macosx_eyetv}" != "xno" &&
1884   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1885 then
1886   VLC_ADD_PLUGIN([access_eyetv])
1887 fi
1888
1889 dnl
1890 dnl QTKit
1891 AC_ARG_ENABLE(macosx-qtkit,
1892   [  --enable-macosx-qtkit Mac OS X qtcapture (video) and qtsound (audio) module (default enabled on Mac OS X)])
1893 if test "x${enable_macosx_qtkit}" != "xno" &&
1894   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1895 then
1896   VLC_ADD_PLUGIN([qtcapture])
1897   VLC_ADD_PLUGIN([qtsound])
1898 fi
1899 AM_CONDITIONAL(HAVE_QTKIT, [test "${SYS}" = "darwin" -a "x${enable_macosx_qtkit}" != "xno"])
1900
1901 dnl
1902 dnl AVFoundation
1903 AC_SUBST(have_avfoundation, ["no"])
1904 AC_ARG_ENABLE(macosx-avfoundation,
1905   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1906 if test "x${enable_macosx_avfoundation}" != "xno" &&
1907   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1908 then
1909   SAVED_LIBS="${LIBS}"
1910   LIBS="-framework AVFoundation"
1911   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1912   LIBS="${SAVED_LIBS}"
1913   if test "${have_avfoundation}" != "no"
1914   then
1915     VLC_ADD_PLUGIN([avcapture])
1916   fi
1917 fi
1918 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
1919
1920 dnl
1921 dnl  Demux plugins
1922 dnl
1923
1924 EXTEND_HELP_STRING([Mux/Demux plugins:])
1925
1926 dnl
1927 dnl  libdvbpsi check for ts mux/demux
1928 dnl
1929 have_dvbpsi="no"
1930 PKG_WITH_MODULES([DVBPSI], [libdvbpsi], [have_dvbpsi="yes"])
1931 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
1932
1933
1934 dnl
1935 dnl  GME demux plugin
1936 dnl
1937 AC_ARG_ENABLE(gme,
1938   [AS_HELP_STRING([--enable-gme],
1939     [use Game Music Emu (default auto)])])
1940 AS_IF([test "${enable_gme}" != "no"], [
1941   AC_CHECK_HEADER([gme/gme.h], [
1942     VLC_ADD_LIBS([gme], [-lgme])
1943     VLC_ADD_PLUGIN([gme])
1944   ], [
1945     AS_IF([test "x${enable_gme}" != "x"], [
1946       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
1947     ])
1948   ])
1949 ])
1950
1951
1952 dnl
1953 dnl  SIDPlay plugin
1954 dnl
1955 AC_ARG_ENABLE(sid,
1956     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
1957 AS_IF([test "${enable_sid}" != "no"], [
1958     PKG_CHECK_MODULES(SID, [libsidplay2], [
1959         AC_LANG_PUSH(C++)
1960         oldCPPFLAGS="$CPPFLAGS"
1961         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
1962         AC_CHECK_HEADER([sidplay/builders/resid.h], [
1963             VLC_ADD_PLUGIN([sid])
1964             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
1965             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
1966         ], [
1967             AS_IF([test -n "${enable_sid}"],
1968                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
1969                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
1970                 )
1971         ])
1972         CPPFLAGS="$oldCPPFLAGS"
1973         AC_LANG_POP(C++)
1974     ], [
1975         AS_IF([test "x${enable_sid}" = "xyes"],
1976             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
1977             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
1978             )
1979     ])
1980 ])
1981
1982
1983 dnl
1984 dnl  ogg demux plugin
1985 dnl
1986 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto])
1987 if test "${enable_sout}" != "no"; then
1988     PKG_ENABLE_MODULES_VLC([MUX_OGG], [], [ogg >= 1.0], [Ogg mux support], [auto])
1989 dnl Check for libshout
1990     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
1991 fi
1992
1993 dnl
1994 dnl  matroska demux plugin
1995 dnl
1996 AC_ARG_ENABLE(mkv,
1997   [AS_HELP_STRING([--disable-mkv],
1998     [do not use libmatroska (default auto)])])
1999 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2000   AC_LANG_PUSH(C++)
2001   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2002     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2003     AC_EGREP_CPP(yes,
2004       [#include <ebml/EbmlVersion.h>
2005        #ifdef LIBEBML_VERSION
2006        #if LIBEBML_VERSION >= 0x010000
2007        yes
2008        #endif
2009        #endif],
2010       [AC_MSG_RESULT([yes])
2011         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2012           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2013           AC_EGREP_CPP(yes,
2014             [#include <matroska/KaxVersion.h>
2015              #ifdef LIBMATROSKA_VERSION
2016              #if LIBMATROSKA_VERSION >= 0x010000
2017              yes
2018              #endif
2019              #endif],
2020             [AC_MSG_RESULT([yes])
2021               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2022               AC_CHECK_LIB(ebml_pic, main, [
2023                 VLC_ADD_PLUGIN([mkv])
2024                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2025               ],[
2026                 AC_CHECK_LIB(ebml, main, [
2027                   VLC_ADD_PLUGIN([mkv])
2028                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2029                 ])
2030               ])
2031             ], [
2032               AC_MSG_RESULT([no])
2033               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2034           ])
2035         ])
2036       ],
2037       [AC_MSG_RESULT([no])
2038         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2039     ])
2040   ])
2041   AC_LANG_POP(C++)
2042 fi
2043
2044 dnl
2045 dnl  modplug demux plugin
2046 dnl
2047 AC_ARG_ENABLE(mod,
2048   [AS_HELP_STRING([--disable-mod],
2049     [do not use libmodplug (default auto)])])
2050 if test "${enable_mod}" != "no" ; then
2051     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2052           VLC_ADD_PLUGIN([mod])
2053           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2054           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2055     ],[
2056        AS_IF([test -n "${enable_mod}"],
2057          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2058          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2059     ])
2060 fi
2061
2062 dnl
2063 dnl  mpc demux plugin
2064 dnl
2065 AC_ARG_ENABLE(mpc,
2066   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2067 if test "${enable_mpc}" != "no"
2068 then
2069   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2070     VLC_ADD_PLUGIN([mpc])
2071     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2072     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2073     VLC_ADD_PLUGIN([mpc])
2074     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2075 fi
2076
2077 dnl
2078 dnl  Codec plugins
2079 dnl
2080
2081 EXTEND_HELP_STRING([Codec plugins:])
2082
2083 dnl
2084 dnl wmafixed plugin
2085 dnl
2086 AC_ARG_ENABLE(wma-fixed,
2087   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2088 if test "${enable_wma_fixed}" = "yes"
2089 then
2090   VLC_ADD_PLUGIN([wma_fixed])
2091 fi
2092
2093 dnl
2094 dnl shine encoder plugin
2095 dnl
2096 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2097
2098
2099 dnl
2100 dnl openmax il codec plugin
2101 dnl
2102 AC_ARG_ENABLE(omxil,
2103   [  --enable-omxil          openmax il codec module (default disabled)])
2104 if test "${enable_omxil}" = "yes"
2105 then
2106   VLC_ADD_PLUGIN([omxil])
2107 fi
2108
2109 dnl
2110 dnl openmax il vout plugin
2111 dnl
2112 AC_ARG_ENABLE(omxil-vout,
2113   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2114 if test "${enable_omxil_vout}" = "yes"
2115 then
2116   VLC_ADD_PLUGIN([omxil_vout])
2117 fi
2118
2119 dnl
2120 dnl raspberry pi openmax il configuration
2121 dnl
2122 AC_ARG_ENABLE(rpi-omxil,
2123   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2124 if test "${enable_rpi_omxil}" = "yes"
2125 then
2126   VLC_ADD_PLUGIN([omxil omxil_vout])
2127   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2128 fi
2129
2130 dnl
2131 dnl CrystalHD codec plugin
2132 dnl
2133 AC_ARG_ENABLE(crystalhd,
2134   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2135 if test "${enable_crystalhd}" != "no"; then
2136     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2137       VLC_ADD_PLUGIN([crystalhd])
2138       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2139     ],[
2140       if test "${SYS}" = "mingw32" ; then
2141         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2142           VLC_ADD_PLUGIN([crystalhd])
2143           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2144             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2145             ])
2146         ],[
2147           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2148                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2149                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2150         ],[#define __LINUX_USER__
2151                #include <libcrystalhd/bc_dts_types.h>
2152         ])
2153       fi
2154     ],[
2155        #include <libcrystalhd/bc_dts_types.h>
2156       ])
2157 fi
2158
2159 dnl
2160 dnl  mad plugin
2161 dnl
2162 AC_ARG_ENABLE(mad,
2163   [  --enable-mad            libmad module (default enabled)])
2164 if test "${enable_mad}" != "no"
2165 then
2166   AC_ARG_WITH(mad,
2167     [  --with-mad=PATH         path to libmad],[],[])
2168   if test "${with_mad}" != "no" -a -n "${with_mad}"
2169   then
2170     VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${with_mad}/include])
2171     VLC_ADD_LIBS([mpgatofixed32],[-L${with_mad}/lib])
2172   fi
2173
2174   AC_ARG_WITH(mad-tree,
2175     [  --with-mad-tree=PATH    mad tree for static linking],[],[])
2176   if test "${with_mad_tree}" != "no" -a -n "${with_mad_tree}"
2177   then
2178     real_mad_tree="`cd ${with_mad_tree} 2>/dev/null && pwd`"
2179     if test -z "${real_mad_tree}"
2180     then
2181       dnl  The given directory can't be found
2182       AC_MSG_RESULT(no)
2183       AC_MSG_ERROR([${with_mad_tree} directory does not exist])
2184     fi
2185     dnl  Use a custom libmad
2186     AC_MSG_CHECKING(for mad.h in ${real_mad_tree})
2187     if test -f ${real_mad_tree}/mad.h
2188     then
2189       AC_MSG_RESULT(yes)
2190       VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${real_mad_tree}])
2191       VLC_ADD_LIBS([mpgatofixed32],[-L${real_mad_tree}/.libs])
2192       VLC_SAVE_FLAGS
2193       LDFLAGS="${LDFLAGS} ${LIBS_mpgatofixed32}"
2194       AC_CHECK_LIB(mad, mad_bit_init, [
2195         VLC_ADD_PLUGIN([mpgatofixed32])
2196         VLC_ADD_LIBS([mpgatofixed32],[-lmad])
2197         ],[ AC_MSG_ERROR([the specified tree has not been compiled ])
2198       ],[])
2199       VLC_RESTORE_FLAGS
2200     else
2201       AC_MSG_RESULT(no)
2202       AC_MSG_ERROR([the specified tree does not have mad.h])
2203     fi
2204   else
2205     VLC_SAVE_FLAGS
2206     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_mpgatofixed32}"
2207     LDFLAGS="${LDFLAGS} ${LIBS_mpgatofixed32}"
2208     AC_CHECK_HEADERS(mad.h, ,
2209       [ AC_MSG_ERROR([Could not find libmad on your system: you may get it from http://www.underbit.com/products/mad/. Alternatively you can use --disable-mad to disable the mad plugin.]) ])
2210     AC_CHECK_LIB(mad, mad_bit_init, [
2211       VLC_ADD_PLUGIN([mpgatofixed32])
2212       VLC_ADD_LIBS([mpgatofixed32],[-lmad])],
2213       [ AC_MSG_ERROR([Cannot find libmad library...]) ])
2214     VLC_RESTORE_FLAGS
2215   fi
2216 fi
2217
2218
2219 AC_ARG_ENABLE(merge-ffmpeg,
2220 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2221   enable_merge_ffmpeg="no"
2222 ])
2223 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2224
2225 dnl
2226 dnl  avcodec decoder/encoder plugin
2227 dnl
2228 AC_ARG_ENABLE(avcodec,
2229 [  --enable-avcodec        libavcodec codec (default enabled)])
2230 AS_IF([test "${enable_avcodec}" != "no"], [
2231   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 53.34.0 libavutil >= 51.22.0], [
2232     dnl PKG_CHECK_EXISTS([libavcodec < 56],, [
2233     dnl   AC_MSG_ERROR([libavcodec versions 56 and later are not supported yet.])
2234     dnl ])
2235     VLC_SAVE_FLAGS
2236     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2237     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2238     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2239     AC_CHECK_HEADERS(libavutil/avutil.h)
2240     VLC_RESTORE_FLAGS
2241     have_avcodec="yes"
2242   ],[
2243     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2244   ])
2245 ], [
2246   have_avcodec="no"
2247 ])
2248 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2249
2250 dnl
2251 dnl libva needs avcodec
2252 dnl
2253 AC_ARG_ENABLE(libva,
2254   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2255
2256 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2257   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2258 ])
2259 have_avcodec_vaapi="no"
2260 AS_IF([test "${enable_libva}" != "no" -a "${have_avcodec}" = "yes"], [
2261   PKG_CHECK_MODULES(LIBVA, [libva libva-x11], [
2262     VLC_SAVE_FLAGS
2263     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2264     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2265     AC_CHECK_HEADERS(libavcodec/vaapi.h, [
2266       AC_MSG_NOTICE([VAAPI acceleration activated])
2267       have_avcodec_vaapi="yes"
2268     ],[
2269       AS_IF([test -n "${enable_libva}"], [
2270         AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2271       ], [
2272         AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2273       ])
2274     ])
2275     VLC_RESTORE_FLAGS
2276   ],[
2277     AS_IF([test -n "${enable_libva}"], [
2278       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2279     ], [
2280       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2281     ])
2282   ])
2283 ])
2284 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2285
2286 dnl
2287 dnl dxva2 needs avcodec
2288 dnl
2289 AC_ARG_ENABLE(dxva2,
2290   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2291
2292 have_avcodec_dxva2="no"
2293 AS_IF([test "${enable_dxva2}" != "no"], [
2294   if test "${SYS}" = "mingw32"; then
2295   AS_IF([test "x${have_avcodec}" = "xyes"], [
2296     AC_CHECK_HEADERS(dxva2api.h,
2297       [
2298         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2299            AC_MSG_NOTICE([DxVA2 acceleration activated])
2300            have_avcodec_dxva2="yes"
2301         ],[
2302     AS_IF([test "${enable_dxva2}" = "yes"],
2303           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2304               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2305         ], [#undef _WIN32_WINNT
2306             /* DXVA2 is only available in Vista and above */
2307             #define _WIN32_WINNT 0x600])
2308       ],[
2309     AS_IF([test "${enable_dxva2}" = "yes"],
2310               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2311               [AC_MSG_WARN([dxva2api.h not found])])
2312       ])
2313   ],[
2314     AS_IF([test "x${enable_dxva2}" != "x"], [
2315       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2316     ])
2317   ])
2318   fi
2319 ])
2320 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2321
2322 dnl
2323 dnl vda needs avcodec
2324 dnl
2325 AC_ARG_ENABLE(vda,
2326   [  --enable-vda          VDA  support (default auto)])
2327
2328 have_avcodec_vda="no"
2329 AS_IF([test "${enable_vda}" != "no"], [
2330   if test "${SYS}" = "darwin"; then
2331   AS_IF([test "x${have_avcodec}" = "xyes"], [
2332     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2333       [
2334         AC_CHECK_HEADERS(libavcodec/vda.h, [
2335            have_avcodec_vda="yes"
2336         ],[
2337         AS_IF([test "${enable_vda}" = "yes"],
2338               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2339               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2340         ])
2341   ],[
2342         AS_IF([test "${enable_vda}" = "yes"],
2343               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2344               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2345       ])
2346   ],[
2347     AS_IF([test "x${enable_vda}" != "x"], [
2348       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2349     ])
2350  ])
2351   fi
2352 ])
2353 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2354
2355 dnl
2356 dnl  avformat demuxer/muxer plugin
2357 dnl
2358
2359 AC_ARG_ENABLE(avformat,
2360 [  --enable-avformat       libavformat containers (default enabled)],, [
2361   enable_avformat="${have_avcodec}"
2362 ])
2363 have_avformat="no"
2364 AS_IF([test "${enable_avformat}" != "no"], [
2365   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2366       have_avformat="yes"
2367       VLC_SAVE_FLAGS
2368       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2369       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2370       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2371       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2372       AC_CHECK_HEADERS(libavutil/avutil.h)
2373       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2374         have_avformat="no"
2375       ])
2376       VLC_RESTORE_FLAGS
2377     ],[
2378       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2379   ])
2380 ])
2381 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2382
2383 dnl
2384 dnl  swscale image scaling and conversion plugin
2385 dnl
2386
2387 AC_ARG_ENABLE(swscale,
2388   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2389           (default enabled)]))
2390 if test "${enable_swscale}" != "no"
2391 then
2392   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2393     [
2394       VLC_SAVE_FLAGS
2395       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2396       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2397       AC_CHECK_HEADERS(libswscale/swscale.h)
2398       VLC_ADD_PLUGIN([swscale])
2399       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2400       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2401       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2402         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2403       ])
2404       VLC_RESTORE_FLAGS
2405     ],[
2406       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2407   ])
2408 fi
2409
2410 dnl
2411 dnl  postproc plugin
2412 dnl
2413
2414 AC_ARG_ENABLE(postproc,
2415 [  --enable-postproc       libpostproc image post-processing (default auto)])
2416 if test "${enable_postproc}" != "no"
2417 then
2418   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2419     [
2420       VLC_SAVE_FLAGS
2421       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2422       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2423       AC_CHECK_HEADERS(postproc/postprocess.h)
2424       VLC_ADD_PLUGIN([postproc])
2425       VLC_ADD_LIBS([postproc],[$POSTPROC_LIBS $AVUTIL_LIBS])
2426       VLC_ADD_CFLAGS([postproc],[$POSTPROC_CFLAGS $AVUTIL_CFLAGS])
2427       VLC_RESTORE_FLAGS
2428     ],[
2429       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2430   ])
2431 fi
2432
2433 dnl
2434 dnl  faad decoder plugin
2435 dnl
2436 AC_ARG_ENABLE(faad,
2437 [  --enable-faad           faad codec (default auto)])
2438 if test "${enable_faad}" != "no"; then
2439   AC_ARG_WITH(faad-tree,  [  --with-faad-tree=PATH   faad tree for static linking])
2440   if test -n "${with_faad_tree}"; then
2441     AC_MSG_CHECKING(for libfaad.a in ${with_faad_tree})
2442     real_faad_tree="`cd ${with_faad_tree} 2>/dev/null && pwd`"
2443     if test -z "${real_faad_tree}"; then
2444       dnl  The given directory can't be found
2445       AC_MSG_RESULT(no)
2446       AC_MSG_ERROR([cannot cd to ${with_faad_tree}])
2447     fi
2448     if test -f "${real_faad_tree}/libfaad/.libs/libfaad.a"; then
2449       dnl  Use the custom faad
2450       AC_MSG_RESULT(${real_faad_tree}/libfaad/.libs/libfaad.a)
2451       VLC_ADD_PLUGIN([faad])
2452       VLC_ADD_LIBS([faad],[${real_faad_tree}/libfaad/.libs/libfaad.a])
2453       VLC_ADD_CPPFLAGS([faad],[-I${real_faad_tree}/include])
2454     else
2455       dnl  The given libfaad wasn't built
2456       AC_MSG_RESULT(no)
2457       AC_MSG_ERROR([cannot find ${real_faad_tree}/libfaad/.libs/libfaad.a, make sure you compiled libfaad in ${with_faad_tree}])
2458     fi
2459   else
2460     VLC_SAVE_FLAGS
2461     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_faad}"
2462     LDFLAGS="${LDFLAGS} ${LIBS_faad}"
2463     AC_CHECK_HEADERS(faad.h,
2464       [ AC_CHECK_LIB(faad, faacDecOpen, [
2465           VLC_ADD_PLUGIN([faad])
2466           VLC_ADD_LIBS([faad],[-lfaad]) ], [
2467             AC_CHECK_LIB(faad, NeAACDecOpen, [
2468               VLC_ADD_PLUGIN([faad])
2469               VLC_ADD_LIBS([faad],[-lfaad]) ], [
2470                 AS_IF([test "${enable_faad}" = "yes"],
2471                 [ AC_MSG_ERROR([Cannot find libfaad library...]) ],
2472                 [ AC_MSG_WARN([Cannot find libfaad library...]) ]) ]) ])
2473       ] , [ AS_IF([test "${enable_faad}" = "yes"],
2474         [ AC_MSG_ERROR([Cannot find development headers for libfaad...]) ],
2475         [ AC_MSG_WARN([Cannot find development headers for libfaad...]) ]) ])
2476     VLC_RESTORE_FLAGS
2477   fi
2478 fi
2479
2480 dnl
2481 dnl libvpx decoder plugin
2482 dnl
2483 AC_ARG_ENABLE(vpx,
2484     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 decoder (default auto)]))
2485 AS_IF([test "${enable_vpx}" != "no"],[
2486     PKG_CHECK_MODULES([VPX], [vpx] , [
2487         VLC_ADD_PLUGIN([vpx])
2488         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2489         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2490         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2491             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2492         ], [], [${VPX_LIBS}])
2493     ], [
2494     AS_IF([test "${enable_vpx}" = "yes"],[
2495         AC_MSG_ERROR([libvpx was not found])
2496     ])])
2497 ])
2498
2499 dnl
2500 dnl twolame encoder plugin
2501 dnl
2502 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2503
2504 dnl
2505 dnl fdk-aac encoder plugin
2506 dnl
2507 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2508
2509 dnl
2510 dnl  QuickTime plugin
2511 dnl
2512 AC_ARG_ENABLE(quicktime,
2513   [  --enable-quicktime      QuickTime module (deprecated)])
2514 if test "${enable_quicktime}" = "yes"; then
2515   if test "${SYS}" = "mingw32"; then
2516     VLC_ADD_PLUGIN([quicktime])
2517   else
2518   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2519     [ VLC_ADD_PLUGIN([quicktime])
2520       VLC_ADD_LIBS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2521     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2522   fi
2523 fi
2524
2525 dnl
2526 dnl A52/AC3 decoder plugin
2527 dnl
2528 AC_ARG_ENABLE(a52,
2529   [  --enable-a52            A/52 support with liba52 (default enabled)])
2530 if test "${enable_a52}" != "no"
2531 then
2532   AC_ARG_WITH(a52,
2533     [  --with-a52=PATH         a52 headers and libraries])
2534   AC_ARG_WITH(a52-tree,
2535     [  --with-a52-tree=PATH    a52dec tree for static linking ],[],[])
2536   if test "${with_a52_tree}" != "no" -a -n "${with_a52_tree}"
2537   then
2538     real_a52_tree="`cd ${with_a52_tree} 2>/dev/null && pwd`"
2539     if test -z "${real_a52_tree}"
2540     then
2541       dnl  The given directory can't be found
2542       AC_MSG_RESULT(no)
2543       AC_MSG_ERROR([${with_a52_tree} directory does not exist])
2544     fi
2545     dnl  Use a custom a52dec
2546     AC_MSG_CHECKING(for a52.h in ${real_a52_tree}/include)
2547     if test -f ${real_a52_tree}/include/a52.h
2548     then
2549       AC_MSG_RESULT(yes)
2550       VLC_ADD_CPPFLAGS([a52tofloat32],[-I${real_a52_tree}])
2551       VLC_ADD_LIBS([a52tofloat32],[-L${real_a52_tree}/liba52/.libs])
2552       VLC_SAVE_FLAGS
2553       LDFLAGS="${LDFLAGS} ${LIBS_a52tofloat32}"
2554       AC_CHECK_LIB(a52, a52_free, [
2555         VLC_ADD_PLUGIN([a52tofloat32])
2556         VLC_ADD_CPPFLAGS([a52tofloat32],[-DUSE_A52DEC_TREE])
2557         VLC_ADD_LIBS([a52tofloat32],[-la52])
2558         ],[
2559         if test -f ${real_a52_tree}/liba52/.libs/liba52.a
2560         then
2561           AC_MSG_ERROR([make sure you have at least a52dec-0.7.3 ($real_a52_tree)])
2562         else
2563           AC_MSG_ERROR([the specified tree has not been compiled])
2564         fi
2565       ])
2566     else
2567       AC_MSG_RESULT(no)
2568       AC_MSG_ERROR([the specified tree does not have a52.h])
2569     fi
2570   else
2571     if test -z "${with_a52}"
2572     then
2573       LDFLAGS_test=""
2574       CPPFLAGS_test=""
2575     else
2576       LDFLAGS_test="-L${with_a52}/lib"
2577       CPPFLAGS_test="-I${with_a52}/include"
2578     fi
2579     VLC_SAVE_FLAGS
2580     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2581     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2582     AC_CHECK_HEADERS(a52dec/a52.h, [
2583       AC_CHECK_LIB(a52, a52_free, [
2584         VLC_ADD_PLUGIN([a52tofloat32])
2585         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2586         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2587       ],[
2588         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2589         ], [$LIBM])
2590     ],[
2591       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2592     ])
2593     VLC_RESTORE_FLAGS
2594   fi
2595 fi
2596
2597 dnl
2598 dnl DTS Coherent Acoustics decoder plugin
2599 dnl
2600 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2601
2602 dnl
2603 dnl  Flac plugin
2604 dnl
2605 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2606
2607 dnl
2608 dnl  Libmpeg2 plugin
2609 dnl
2610 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2611
2612 dnl
2613 dnl  Vorbis plugin
2614 dnl
2615 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2616
2617 dnl
2618 dnl  Tremor plugin
2619 dnl
2620 AC_ARG_ENABLE(tremor,
2621   [  --enable-tremor         Tremor decoder support (default disabled)])
2622 if test "${enable_tremor}" = "yes"
2623 then
2624   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2625     VLC_ADD_PLUGIN([tremor])
2626    ],[])
2627 fi
2628
2629 dnl
2630 dnl  Speex plugins
2631 dnl
2632 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2633 have_speexdsp="no"
2634 AS_IF([test "${enable_speex}" != "no"], [
2635   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2636     have_speexdsp="yes"
2637   ], [
2638     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2639   ])
2640 ])
2641 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2642
2643 dnl
2644 dnl  Opus plugin
2645 dnl
2646 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2647
2648 dnl
2649 dnl  theora decoder plugin
2650 dnl
2651 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2652
2653 dnl
2654 dnl  dirac encoder plugin
2655 dnl
2656 PKG_ENABLE_MODULES_VLC([DIRAC], [], [dirac >= 0.10.0], [dirac encoder], [auto])
2657
2658 dnl
2659 dnl  schroedinger decoder plugin (for dirac format video)
2660 dnl
2661 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2662
2663 dnl
2664 dnl  PNG decoder module
2665 dnl
2666 AC_ARG_ENABLE(png,
2667   [  --enable-png            PNG support (default enabled)])
2668 AS_IF([test "${enable_png}" != "no"], [
2669 AC_CHECK_HEADERS(png.h, [
2670   VLC_SAVE_FLAGS
2671   LDFLAGS="${LDFLAGS} -lz $LIBM"
2672   AC_CHECK_LIB(png, png_set_rows, [
2673     VLC_ADD_PLUGIN([png])
2674   ], [], [-lz $LIBM])
2675   VLC_RESTORE_FLAGS
2676   ])
2677 ])
2678
2679 dnl
2680 dnl H262 encoder plugin (lib262)
2681 dnl
2682 AC_ARG_ENABLE(x262,
2683   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2684 if test "${enable_x262}" != "no"; then
2685 AC_ARG_WITH(x262-tree,
2686   [ --with-x262-tree=PATH      H262 encoding module with libx262 (static linking)],[],[])
2687   if test "${with_x262_tree}" != "no" -a -n "${with_x262_tree}"
2688   then
2689     real_x262_tree="̧`cd ${with_x262_tree} 2>/dev/null && pwd`"
2690     if test -z "${real_x262_tree}"
2691     then
2692       AC_MSG_RESULT(no)
2693       AC_MSG_ERROR([${with_x262_tree} directory does not exist])
2694     fi
2695     AC_MSG_CHECKING(for x262.h in ${real_x262_tree})
2696     if test -f ${with_x262_tree}/x262_config.h
2697     then
2698       VLC_ADD_PLUGIN([x262])
2699       VLC_ADD_CFLAGS([x262],[-I${with_x262_tree}])
2700       VLC_ADD_LIBS([x262],[-L${with_x262_tree} -lm -lpthread -lx262])
2701     else
2702       AC_MSG_RESULT(no)
2703       AC_MSG_ERROR([${with_x262_tree} doesnt have x262_config.h])
2704     fi
2705   else
2706     PKG_CHECK_MODULES(X262, x262, [
2707         VLC_ADD_PLUGIN([x262])
2708         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2709         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2710           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2711         ])
2712         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2713         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2714           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2715         fi
2716     ], [
2717        if test "${enable_x262}" = "yes"; then
2718         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2719        fi
2720     ])
2721   fi
2722 fi
2723
2724 dnl x265 encoder
2725 AC_ARG_ENABLE(x265,
2726   AS_HELP_STRING([--enable-x265],[H265 / HEVC encoding support with libx265 (default enabled)]))
2727 AS_IF( [test "${enable_x265}" != "no"],[
2728   AC_PREPROC_IFELSE([AC_LANG_SOURCE([
2729 #include <x265.h>
2730 #if X265_BUILD != 1
2731 # error Fail
2732 #endif
2733   ])], [
2734     AC_CHECK_LIB([x265],[x265_encoder_open_1], [
2735       VLC_ADD_PLUGIN([x265])
2736       VLC_ADD_LIBS([x265], [-lx265 -lstdc++ -lm -lpthread])
2737     ], [
2738       AC_MSG_ERROR([x265 library not found])
2739     ], [-lstdc++ -lm -lpthread])
2740   ], [
2741     AS_IF([test "${enable_x265}" = "yes"], [
2742         AC_MSG_ERROR([x265.h not found])
2743     ])
2744   ])
2745 ])
2746
2747
2748 dnl
2749 dnl H264 encoder plugin (10-bit lib264)
2750 dnl
2751 AC_ARG_ENABLE(x26410b,
2752   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2753 if test "${enable_x26410b}" != "no"; then
2754 AC_ARG_WITH(x26410b-tree,
2755   [ --with-x26410b-tree=PATH      H264 10-bit encoding module with libx264 (static linking)],[],[])
2756   if test "${with_x26410b_tree}" != "no" -a -n "${with_x26410b_tree}"
2757   then
2758     real_x26410b_tree="̧`cd ${with_x26410b_tree} 2>/dev/null && pwd`"
2759     if test -z "${real_x26410b_tree}"
2760     then
2761       AC_MSG_RESULT(no)
2762       AC_MSG_ERROR([${with_x26410b_tree} directory does not exist])
2763     fi
2764     AC_MSG_CHECKING(for x264.h in ${real_x26410b_tree})
2765     if test -f ${with_x26410b_tree}/x264_config.h
2766     then
2767       AC_MSG_RESULT(yes)
2768       AC_MSG_CHECKING(for 10-bit build of x264)
2769       if grep -q "BIT_DEPTH.*10"  ${with_x26410b_tree}/x264_config.h ;then
2770         AC_MSG_RESULT(yes)
2771         VLC_ADD_PLUGIN([x26410b])
2772         VLC_ADD_CFLAGS([x26410b],[-I${with_x26410b_tree}])
2773         VLC_ADD_LIBS([x26410b],[-L${with_x26410b_tree} -lm -lpthread -lx264])
2774       else
2775         AC_MSG_RESULT(no)
2776         AC_MSG_ERROR([${with_x26410b_tree} isnt build 10-bit])
2777       fi
2778     else
2779       AC_MSG_RESULT(no)
2780       AC_MSG_ERROR([${with_x26410b_tree} doesnt have x264_config.h])
2781     fi
2782   else
2783     PKG_CHECK_MODULES(X26410B, x26410b, [
2784         VLC_ADD_PLUGIN([x26410b])
2785         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2786         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2787           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2788         ])
2789         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2790         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2791           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2792         fi
2793     ], [
2794        if test "${enable_x26410b}" = "yes"; then
2795         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2796        fi
2797     ])
2798   fi
2799 fi
2800
2801
2802 dnl
2803 dnl H264 encoder plugin (using libx264)
2804 dnl
2805 AC_ARG_ENABLE(x264,
2806   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2807 if test "${enable_x264}" != "no"; then
2808   AC_ARG_WITH(x264-tree,
2809     [  --with-x264-tree=PATH   x264 tree for static linking ],[],[])
2810   if test "${with_x264_tree}" != "no" -a -n "${with_x264_tree}"
2811   then
2812     real_x264_tree="`cd ${with_x264_tree} 2>/dev/null && pwd`"
2813     if test -z "${real_x264_tree}"
2814     then
2815       dnl  The given directory can't be found
2816       AC_MSG_RESULT(no)
2817       AC_MSG_ERROR([${with_x264_tree} directory does not exist])
2818     fi
2819     dnl  Use a custom libx264
2820     AC_MSG_CHECKING(for x264.h in ${real_x264_tree})
2821     if test -f ${real_x264_tree}/x264.h
2822     then
2823       AC_MSG_RESULT(yes)
2824       VLC_ADD_CPPFLAGS([x264],[-I${real_x264_tree}])
2825       VLC_ADD_LIBS([x264],[-L${real_x264_tree}])
2826       PKG_CHECK_MODULES(X264,x264, [
2827         VLC_ADD_PLUGIN([x264])
2828         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2829         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2830         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2831           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2832         fi
2833       ],[
2834         AC_MSG_ERROR([the specified tree has not been compiled])
2835       ])
2836     else
2837       AC_MSG_RESULT(no)
2838       AC_MSG_ERROR([the specified tree does not have x264.h])
2839     fi
2840   else
2841       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2842         VLC_ADD_PLUGIN([x264])
2843         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2844
2845         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2846           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2847         ])
2848
2849         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2850         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2851           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2852         fi
2853       ],[
2854         if test "${enable_x264}" = "yes"; then
2855             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2856           fi
2857       ])
2858   fi
2859 fi
2860
2861 dnl
2862 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2863 dnl
2864 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2865
2866 dnl
2867 dnl libfluidsynth (MIDI synthetizer) plugin
2868 dnl
2869 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2870
2871 dnl
2872 dnl Teletext Modules
2873 dnl vbi decoder plugin (using libzbvi)
2874 dnl telx module
2875 dnl uncompatible
2876 dnl
2877 AC_ARG_ENABLE(zvbi,
2878   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2879                   libzvbi (default enabled)]))
2880 AC_ARG_ENABLE(telx,
2881   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2882                   zvbi) (default enabled if zvbi is absent)]))
2883
2884 AS_IF( [test "${enable_zvbi}" != "no"],[
2885     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2886         [
2887           VLC_ADD_PLUGIN([zvbi])
2888           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2889           AS_IF( [test "${enable_telx}" = "yes"],[
2890                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2891                   ])
2892         ],[
2893           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2894         ])
2895     ])
2896 AS_IF( [test "${enable_telx}" != "no" ],[
2897   VLC_ADD_PLUGIN([telx])
2898   ])
2899
2900 dnl
2901 dnl libass subtitle rendering module
2902 dnl
2903 AC_ARG_ENABLE(libass,
2904   [  --enable-libass         Subtitle support using libass (default enabled)])
2905 AS_IF( [test "${enable_libass}" != "no"], [
2906   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2907       [
2908         VLC_ADD_PLUGIN([libass])
2909
2910         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2911           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2912            VLC_ADD_LIBS([libass],[-lfontconfig])
2913        ])
2914       ],[
2915         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2916       ])
2917   ])
2918
2919 dnl
2920 dnl  kate decoder plugin
2921 dnl
2922 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2923
2924 dnl
2925 dnl  tiger rendering for kate decoder plugin
2926 dnl
2927 AC_ARG_ENABLE(tiger,
2928 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2929 AS_IF([test "${enable_tiger}" != "no"], [
2930   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2931       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2932         AS_IF([test -n "${enable_tiger}"], [
2933           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2934         ])
2935   ])
2936 ])
2937
2938
2939 dnl
2940 dnl  Video plugins
2941 dnl
2942
2943 EXTEND_HELP_STRING([Video plugins:])
2944
2945 dnl
2946 dnl  OpenGL
2947 dnl
2948 PKG_CHECK_MODULES([EGL], [egl], [
2949   have_egl="yes"
2950 ], [
2951   have_egl="no"
2952 ])
2953 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2954
2955 PKG_CHECK_MODULES([GL], [gl], [
2956   have_gl="yes"
2957 ], [
2958   AC_CHECK_HEADER([GL/gl.h], [
2959     have_gl="yes"
2960     GL_CFLAGS=""
2961     AS_IF([test "${SYS}" = "mingw32"], [
2962       AC_CHECK_HEADER([GL/glew.h], [
2963       ], [
2964         have_gl="no"
2965       ])
2966       GL_LIBS="-lopengl32"
2967     ], [
2968       GL_LIBS="-lGL"
2969     ])
2970   ], [
2971     have_gl="no"
2972   ])
2973 ])
2974 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
2975
2976 dnl OpenGL ES 2: depends on EGL 1.1
2977 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
2978 dnl OpenGL ES 1: depends on EGL 1.0
2979 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
2980
2981 dnl
2982 dnl  Xlib
2983 dnl
2984
2985 AC_PATH_XTRA()
2986 AC_CHECK_HEADERS(X11/Xlib.h)
2987
2988 dnl
2989 dnl  X C Bindings modules
2990 dnl
2991 AC_ARG_ENABLE(xcb,
2992   [  --enable-xcb            X11 support with XCB (default enabled)],, [
2993   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" -a "${SYS}" != "symbian"], [
2994     enable_xcb="yes"
2995   ], [
2996     enable_xcb="no"
2997   ])
2998 ])
2999 AC_ARG_ENABLE(xvideo,
3000   [  --enable-xvideo         XVideo support (default enabled)],, [
3001     enable_xvideo="$enable_xcb"
3002 ])
3003 AC_ARG_ENABLE(glx,
3004   [  --enable-glx            OpenGL support through GLX (default enabled)],, [
3005   enable_glx="$enable_xcb"
3006 ])
3007
3008 have_xcb="no"
3009 have_xcb_keysyms="no"
3010 have_xcb_randr="no"
3011 have_xcb_xvideo="no"
3012 AS_IF([test "${enable_xcb}" != "no"], [
3013   dnl libxcb
3014   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3015   have_xcb="yes"
3016   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3017   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3018   PKG_CHECK_MODULES(XPROTO, [xproto])
3019
3020   AS_IF([test "${enable_xvideo}" != "no"], [
3021     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3022   ])
3023
3024   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3025
3026   dnl xcb-utils
3027   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3028     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3029   ])
3030 ])
3031 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3032 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3033 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3034 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3035
3036
3037 dnl
3038 dnl VDPAU needs X11
3039 dnl
3040 AC_ARG_ENABLE(vdpau,
3041   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3042 have_vdpau="no"
3043 AS_IF([test "${enable_vdpau}" != "no"], [
3044   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3045     have_vdpau="yes"
3046     AS_IF([test "${no_x}" = "yes"], [
3047       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3048     ])
3049   ], [
3050     AS_IF([test -n "${enable_vdpau}"], [
3051       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3052     ])
3053   ])
3054 ])
3055 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3056
3057 have_avcodec_vdpau="no"
3058 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3059   PKG_CHECK_EXISTS([libavutil >= 0.52.4 libavcodec >= 54.36.0], [
3060     have_avcodec_vdpau="yes"
3061     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3062   ], [
3063     AS_IF([test -n "${enable_vdpau}"], [
3064       AC_MSG_ERROR([libavutil >= 0.52.4 and libavcodec >= 54.36.0 are required for VDPAU decoding.])
3065     ], [
3066       AC_MSG_WARN([libavutil >= 0.52.4 and libavcodec >= 54.36.0 are required for VDPAU decoding.])
3067     ])
3068   ])
3069 ])
3070 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3071
3072
3073 dnl
3074 dnl  SDL module
3075 dnl
3076 AC_ARG_ENABLE(sdl,
3077   [  --enable-sdl            SDL support (default enabled)])
3078 AC_ARG_ENABLE(sdl-image,
3079   [  --enable-sdl-image      SDL image support (default enabled)])
3080 if test "${enable_sdl}" != "no"
3081 then
3082    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3083       # SDL on Darwin is heavily patched and can only run SDL_image
3084       if test "${SYS}" != "darwin"; then
3085         VLC_ADD_PLUGIN([vout_sdl])
3086       fi
3087       if test "${SYS}" != "mingw32" -a "${SYS}" != "os2"; then
3088         VLC_ADD_LIBS([vout_sdl],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3089       fi
3090       VLC_ADD_CFLAGS([vout_sdl],[${SDL_CFLAGS}])
3091       VLC_ADD_LIBS([vout_sdl],[${SDL_LIBS}])
3092
3093       # SDL_image
3094       AS_IF([ test "${enable_sdl_image}" != "no"],[
3095         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3096           VLC_ADD_PLUGIN([sdl_image])],
3097           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3098           ])
3099       ])
3100    ],[
3101      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3102    ])
3103 fi
3104
3105
3106 dnl
3107 dnl Mac Vout
3108 AC_ARG_ENABLE(macosx-vout,
3109   [  --enable-macosx-vout    Mac OS X video output module (default enabled on Mac OS X)])
3110 if test "x${enable_macosx_vout}" != "xno" &&
3111   (test "${SYS}" = "darwin" || test "${enable_macosx_vout}" = "yes")
3112 then
3113   VLC_ADD_LIBS([vout_macosx],[-Wl,-framework,Cocoa])
3114   VLC_ADD_LIBS([vout_macosx],[-Wl,-framework,OpenGL])
3115   VLC_ADD_PLUGIN([vout_macosx])
3116 fi
3117
3118 dnl
3119 dnl Mac CoreGraphics Layer Vout
3120 AC_ARG_ENABLE(coregraphicslayer-vout,
3121   [  --enable-coregraphicslayer-vout CoreGraphics layered video output module (default disabled)])
3122 if test "${enable_coregraphicslayer_vout}" = "yes"; then
3123   VLC_ADD_LIBS([vout_coregraphicslayer],[-Wl,-framework,Cocoa])
3124   VLC_ADD_LIBS([vout_coregraphicslayer],[-Wl,-framework,QuartzCore])
3125   VLC_ADD_PLUGIN([vout_coregraphicslayer])
3126 fi
3127
3128 dnl
3129 dnl  freetype module
3130 dnl
3131 AC_ARG_ENABLE(freetype,
3132   [  --enable-freetype       freetype support   (default auto)])
3133 AC_ARG_ENABLE(fribidi,
3134   [  --enable-fribidi        fribidi support    (default auto)])
3135 AC_ARG_ENABLE(fontconfig,
3136   [  --enable-fontconfig     fontconfig support (default auto)])
3137
3138 AC_ARG_WITH([default-font],
3139     AS_HELP_STRING([--with-default-font=PATH],
3140         [Path to the default font]),
3141         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3142             "$withval", [Default font])])
3143 AC_ARG_WITH([default-monospace-font],
3144     AS_HELP_STRING([--with-default-monospace-font=PATH],
3145         [Path to the default font]),
3146         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3147             "$withval", [Default monospace font])])
3148
3149 AC_ARG_WITH([default-font-family],
3150     AS_HELP_STRING([--with-default-font-family=NAME],
3151         [Path to the default font family]),
3152         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3153             "$withval", [Default font family])])
3154 AC_ARG_WITH([default-monospace-font-family],
3155     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3156         [Path to the default font family]),
3157         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3158             "$withval", [Default monospace font family])])
3159
3160 if test "${enable_freetype}" != "no"; then
3161    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3162       have_freetype=yes
3163       VLC_ADD_PLUGIN([freetype])
3164       VLC_ADD_CPPFLAGS([freetype skins2],[${FREETYPE_CFLAGS}])
3165       if test "${SYS}" = "mingw32"; then
3166         VLC_ADD_LIBS([freetype],[-liconv -lz])
3167       fi
3168       VLC_ADD_LIBS([freetype skins2],[${FREETYPE_LIBS}])
3169
3170       AC_CHECK_HEADERS(Carbon/Carbon.h,
3171                        [VLC_ADD_LIBS([freetype],[-Wl,-framework,Carbon])])
3172
3173       dnl fontconfig support
3174       if test "${SYS}" != "mingw32"; then
3175           if test "${enable_fontconfig}" != "no"; then
3176             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3177               VLC_ADD_CPPFLAGS([freetype],[-DHAVE_FONTCONFIG])
3178               VLC_ADD_LIBS([freetype],[-lfontconfig])
3179             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3180           fi
3181       else
3182           VLC_ADD_LIBS([freetype],[-lgdi32])
3183       fi
3184
3185       dnl fribidi support
3186       if test "${enable_fribidi}" != "no"; then
3187         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3188           VLC_ADD_CPPFLAGS([freetype skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3189           VLC_ADD_LIBS([freetype skins2], [${FRIBIDI_LIBS}])
3190         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional support will be disabled in FreeType.])])
3191       fi
3192
3193   ],[
3194   have_freetype=no
3195   AS_IF([test -n "${enable_freetype}"],[
3196     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3197     ])
3198   ])
3199 fi
3200
3201
3202 dnl
3203 dnl  QuartzText vout module (iOS/Mac OS)
3204 dnl
3205 AC_ARG_ENABLE(macosx-quartztext,
3206   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3207 if test "x${enable_macosx_quartztext}" != "xno" &&
3208   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3209 then
3210   VLC_ADD_PLUGIN([quartztext])
3211   VLC_ADD_LIBS([quartztext],[-Wl,-framework,ApplicationServices])
3212 fi
3213
3214 dnl
3215 dnl  SVG module
3216 dnl
3217 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3218
3219 dnl
3220 dnl  android surface module
3221 dnl
3222 AC_ARG_ENABLE(android-surface,
3223   [  --enable-android-surface   Android Surface video output module (default disabled)])
3224 if test "${enable_android_surface}" = "yes"; then
3225   if test "${HAVE_ANDROID}" = "1"; then
3226      VLC_ADD_PLUGIN([android_surface])
3227      VLC_ADD_LIBS([android_surface], [-ldl])
3228   fi
3229 fi
3230
3231
3232 dnl
3233 dnl  iOS vout module
3234 dnl
3235 AC_ARG_ENABLE(ios-vout,
3236   [  --enable-ios-vout    iOS video output module (default disabled)])
3237 if test "${enable_ios_vout}" = "yes"
3238 then
3239   VLC_ADD_PLUGIN([vout_ios])
3240   VLC_ADD_LIBS([vout_ios], [-Wl,-framework,OpenGLES,-framework,QuartzCore,-framework,UIKit,-framework,Foundation])
3241 fi
3242
3243 dnl
3244 dnl  iOS ES2 vout module
3245 dnl
3246 AC_ARG_ENABLE(ios-vout2,
3247   [  --enable-ios-vout2    iOS video output module (default disabled)])
3248 if test "${enable_ios_vout2}" = "yes"
3249 then
3250   VLC_ADD_PLUGIN([vout_ios2])
3251   VLC_ADD_LIBS([vout_ios2], [-Wl,-framework,OpenGLES,-framework,QuartzCore,-framework,UIKit])
3252 fi
3253
3254
3255 dnl
3256 dnl  Windows DirectX module
3257 dnl
3258
3259 AC_ARG_ENABLE(directx,
3260   [AS_HELP_STRING([--enable-directx],
3261     [Microsoft DirectX support (default enabled on Windows)])],, [
3262   AS_IF([test "${SYS}" = "mingw32"], [
3263     enable_directx="yes"
3264   ], [
3265     enable_directx="no"
3266   ])
3267 ])
3268 have_directx="no"
3269 AS_IF([test "${enable_directx}" != "no"], [
3270   dnl DirectDraw
3271   AC_CHECK_HEADERS(ddraw.h, [
3272     have_directx="yes"
3273   ], [
3274     AC_MSG_ERROR([Cannot find DirectX headers!])
3275   ])
3276
3277   dnl OpenGL
3278   AC_CHECK_HEADERS(GL/wglew.h, [
3279     VLC_ADD_PLUGIN([glwin32])
3280   ],, [
3281     #include <windows.h>
3282     #include <GL/gl.h>
3283   ])
3284
3285   dnl Direct3D
3286   AC_CHECK_HEADERS(d3d9.h, [
3287     VLC_ADD_PLUGIN([direct3d])
3288   ])
3289
3290   dnl Direct2D
3291   AC_CHECK_HEADERS(d2d1.h, [
3292     VLC_ADD_PLUGIN([direct2d])
3293   ])
3294 ])
3295 AM_CONDITIONAL([HAVE_DIRECTX], [test "$have_directx" = "yes"])
3296
3297 dnl
3298 dnl  Linux framebuffer module
3299 dnl
3300 AC_CHECK_HEADER([linux/fb.h], [
3301   VLC_ADD_PLUGIN([fb])
3302 ])
3303
3304
3305 dnl
3306 dnl  DirectFB module
3307 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3308 dnl  TODO: support for static linking
3309 dnl
3310 AC_ARG_ENABLE(directfb,
3311   [  --enable-directfb       DirectFB support (default disabled)])
3312 AC_ARG_WITH(directfb,
3313   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3314
3315 if test "${enable_directfb}" = "yes"; then
3316     have_directfb="false"
3317     CPPFLAGS_mydirectfb=
3318     LIBS_mydirectfb=
3319     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3320         dnl Trying the given location
3321         VLC_SAVE_FLAGS
3322
3323         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3324         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3325
3326         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3327         LIBS="${LIBS} ${LIBS_new}"
3328
3329         dnl FIXME: too obscure
3330         AC_CHECK_HEADER([directfb.h], [
3331             AC_CHECK_LIB([direct],[direct_initialize], [
3332                 AC_CHECK_LIB([fusion], [fusion_enter], [
3333                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3334                 ], have_directfb="false")
3335             ], have_directfb="false")
3336         ], have_directfb="false")
3337
3338         VLC_RESTORE_FLAGS
3339
3340         if test "${have_directfb}" = "true"; then
3341             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3342             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3343         fi
3344     else
3345         dnl Look for directfb-config
3346         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3347         if test "${DIRECTFB_CONFIG}" != "no"; then
3348             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3349             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3350             have_directfb="true"
3351         else
3352             dnl Trying with pkg-config
3353             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3354                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3355                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3356                 have_directfb="true"
3357                 ], [have_directfb="false"])
3358         fi
3359     fi
3360     if test "${have_directfb}" = "true"; then
3361         VLC_ADD_PLUGIN([directfb])
3362         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3363         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3364     else
3365         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3366     fi
3367 fi
3368
3369 dnl
3370 dnl  AA plugin
3371 dnl
3372 AC_ARG_ENABLE(aa,
3373   [  --enable-aa             aalib output (default disabled)])
3374 if test "${enable_aa}" = "yes"
3375 then
3376   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3377   if test "${have_aa}" = "true"
3378   then
3379     VLC_ADD_PLUGIN([aa])
3380     VLC_ADD_LIBS([aa],[-laa])
3381     if test "${SYS}" != "mingw32"; then
3382       VLC_ADD_LIBS([aa],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3383     fi
3384   fi
3385 fi
3386
3387 dnl
3388 dnl  libcaca plugin
3389 dnl
3390 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3391
3392 dnl
3393 dnl  OS/2 KVA plugin
3394 dnl
3395 AC_ARG_ENABLE(kva,
3396   [AS_HELP_STRING([--enable-kva],
3397     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3398   AS_IF([test "$SYS" = "os2"], [
3399     enable_kva="yes"
3400   ])
3401 ])
3402 have_kva="no"
3403 KVA_LIBS=""
3404 AS_IF([test "$enable_kva" != "no"], [
3405   AC_CHECK_HEADERS([kva.h], [
3406     have_kva="yes"
3407     AC_CHECK_LIB(kva, main, [
3408       KVA_LIBS="-lkva"
3409     ])
3410   ])
3411 ])
3412 AC_SUBST(KVA_LIBS)
3413 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3414
3415 dnl
3416 dnl  Audio plugins
3417 dnl
3418
3419 EXTEND_HELP_STRING([Audio plugins:])
3420
3421 dnl
3422 dnl  Pulseaudio module
3423 dnl
3424 AC_ARG_ENABLE(pulse,
3425   [AS_HELP_STRING([--enable-pulse],
3426     [use the PulseAudio client library (default auto)])])
3427 have_pulse="no"
3428 AS_IF([test "${enable_pulse}" != "no"], [
3429   PKG_CHECK_MODULES([PULSE], [libpulse >= 0.9.22], [
3430     have_pulse="yes"
3431   ], [
3432     PKG_CHECK_MODULES([PULSE], [libpulse >= 0.9.16], [
3433       AS_IF([test "${no_x}" != "yes"], [
3434         have_pulse="yes"
3435         PULSE_LIBS="$PULSE_LIBS ${X_LIBS} ${X_PRE_LIBS} -lX11"
3436       ], [
3437         AS_IF([test "${enable_pulse}" = "yes"], [
3438           AC_MSG_ERROR([Xlib is required with PulseAudio pre-0.9.22 versions
3439 (see http://www.pulseaudio.org/ticket/799 for further reference).])
3440         ])
3441       ])
3442     ], [
3443       AS_IF([test "x${enable_pulse}" != "x"], [
3444         AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 0.9.22 or later required.])
3445       ])
3446     ])
3447   ])
3448 ])
3449 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3450
3451 dnl
3452 dnl  ALSA module
3453 dnl
3454 AC_ARG_ENABLE(alsa,
3455   [AS_HELP_STRING([--enable-alsa],
3456     [support the Advanced Linux Sound Architecture (default auto)])],, [
3457   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3458     enable_alsa="yes"
3459   ])
3460 ])
3461 have_alsa="no"
3462 AS_IF([test "${enable_alsa}" != "no"], [
3463   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3464     have_alsa="yes"
3465   ], [
3466     AS_IF([test "x${enable_alsa}" != "x"], [
3467       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3468     ])
3469   ])
3470 ])
3471 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3472
3473 dnl
3474 dnl  Open Sound System module
3475 dnl
3476 AC_ARG_ENABLE(oss,
3477   [AS_HELP_STRING([--enable-oss],
3478     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3479   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3480     enable_oss="no"
3481   ])
3482 ])
3483 have_oss="no"
3484 OSS_LIBS=""
3485 AS_IF([test "$enable_oss" != "no"], [
3486   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3487     have_oss="yes"
3488     AC_CHECK_LIB(ossaudio, main, [
3489       OSS_LIBS="-lossaudio"
3490     ])
3491   ])
3492 ])
3493 AC_SUBST(OSS_LIBS)
3494 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3495
3496 dnl
3497 dnl  OpenBSD sndio module
3498 dnl
3499 AC_ARG_ENABLE([sndio],
3500   [AS_HELP_STRING([--disable-sndio],
3501     [support the OpenBSD sndio (default auto)])],, [
3502   AS_IF([test "$SYS" = "openbsd"], [
3503     enable_sndio="yes"
3504   ])
3505 ])
3506 have_sndio="no"
3507 AS_IF([test "$enable_sndio" != "no"], [
3508   AC_CHECK_HEADER([sndio.h], [
3509     have_sndio="yes"
3510   ])
3511 ])
3512 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3513
3514 dnl
3515 dnl  Windows Audio Session plugin
3516 dnl
3517 AC_ARG_ENABLE([wasapi],
3518   [AS_HELP_STRING([--enable-wasapi],
3519     [use the Windows Audio Session API (default auto)])
3520 ])
3521 have_wasapi="no"
3522 AS_IF([test "$enable_wasapi" != "no"], [
3523   AC_CHECK_HEADER([audioclient.h], [
3524     have_wasapi="yes"
3525   ], [
3526     AS_IF([test "x${enable_wasapi}" != "x"], [
3527       AC_MSG_ERROR([Windows Audio Session API not found.])
3528     ])
3529   ])
3530 ])
3531 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3532
3533 dnl
3534 dnl  CoreAudio plugin
3535 dnl
3536 AC_ARG_ENABLE(macosx-audio,
3537   [  --enable-macosx-audio   Mac OS X audio module (default enabled on MacOS X)])
3538 if test "x${enable_macosx_audio}" != "xno" &&
3539   (test "${SYS}" = "darwin" || test "${enable_macosx_audio}" = "yes")
3540 then
3541   AC_CHECK_HEADER([CoreAudio/CoreAudio.h],
3542     [ VLC_ADD_PLUGIN([auhal])
3543     ], [ AC_MSG_ERROR([cannot find CoreAudio headers]) ])
3544 fi
3545
3546 dnl
3547 dnl  iOS CoreAudio plugin
3548 dnl
3549 AC_ARG_ENABLE(ios-audio,
3550   [  --enable-ios-audio       Audio module for iOS (default disabled)])
3551 if test "${enable_ios_audio}" = "yes"
3552 then
3553   AC_CHECK_HEADER([AudioUnit/AudioUnit.h],
3554     [ VLC_ADD_PLUGIN([audiounit_ios])
3555     ], [ AC_MSG_ERROR([cannot find AudioUnit headers]) ])
3556 fi
3557
3558 dnl
3559 dnl  AudioQueue plugin
3560 dnl
3561 AC_ARG_ENABLE(audioqueue,
3562   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3563 if test "${enable_audioqueue}" = "yes"
3564 then
3565   VLC_ADD_PLUGIN([audioqueue])
3566 fi
3567
3568 dnl
3569 dnl  JACK modules
3570 dnl
3571 AC_ARG_ENABLE(jack,
3572   [AS_HELP_STRING([--disable-jack],
3573     [do not use jack (default auto)])])
3574 have_jack="no"
3575 AS_IF([test "${enable_jack}" != "no"], [
3576     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3577       [ have_jack=yes ],
3578       [
3579       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3580
3581       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3582       [ have_jack=yes ],
3583       [
3584       AS_IF([test -n "${enable_jack}"],
3585          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3586          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3587       ])
3588     ])
3589 ])
3590 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3591
3592 dnl
3593 dnl  OpenSLES Android
3594 dnl
3595 AC_ARG_ENABLE(opensles,
3596   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3597 if test "${HAVE_ANDROID}" = "1"; then
3598   if test "${enable_opensles}" = "yes"; then
3599       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3600         [ VLC_ADD_PLUGIN([opensles_android]) ],
3601         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3602   fi
3603 fi
3604
3605 dnl
3606 dnl libsamplerate plugin
3607 dnl
3608 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3609
3610 dnl
3611 dnl  OS/2 KAI plugin
3612 dnl
3613 AC_ARG_ENABLE(kai,
3614   [AS_HELP_STRING([--enable-kai],
3615     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3616   AS_IF([test "$SYS" = "os2"], [
3617     enable_kai="yes"
3618   ])
3619 ])
3620 have_kai="no"
3621 KAI_LIBS=""
3622 AS_IF([test "$enable_kai" != "no"], [
3623   AC_CHECK_HEADERS([kai.h], [
3624     have_kai="yes"
3625     AC_CHECK_LIB(kai, main, [
3626       KAI_LIBS="-lkai"
3627     ])
3628   ])
3629 ])
3630 AC_SUBST(KAI_LIBS)
3631 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3632
3633 dnl
3634 dnl  chromaprint audio track fingerprinter
3635 dnl
3636 m4_pushdef([libchromaprint_version], 0.6.0)
3637 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3638     VLC_ADD_PLUGIN([stream_out_chromaprint])
3639     VLC_ADD_CFLAGS([stream_out_chromaprint],[${CHROMAPRINT_CFLAGS}] [-I./webservices -I../stream_out])
3640     VLC_ADD_LIBS([stream_out_chromaprint],[${CHROMAPRINT_LIBS}]),
3641     AS_IF([test "${enable_chromaprint}" = "yes"],
3642         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3643         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3644          ),
3645     [(Chromaprint based audio fingerprinter)],[auto])
3646 m4_popdef([libchromaprint_version])
3647
3648 dnl
3649 dnl  Interface plugins
3650 dnl
3651
3652 EXTEND_HELP_STRING([Interface plugins:])
3653
3654 dnl
3655 dnl QT
3656 dnl
3657 AC_ARG_ENABLE(qt, [
3658   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3659   AS_IF([test "${SYS}" = "darwin"], [
3660     enable_qt="no"
3661   ])
3662 ])
3663 AS_IF([test "${enable_qt}" != "no"], [
3664   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.1.0 Qt5Widgets Qt5Gui], [
3665       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3666       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3667       AC_PATH_PROG(RCC, [rcc-qt5 rcc], rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3668       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3669     ], [
3670       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.6.0],, [
3671         AS_IF([test -n "${enable_qt}"],[
3672           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3673         ],[
3674           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3675         ])
3676         enable_qt="no"
3677       ])
3678       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3679       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3680       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3681       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3682     ])
3683 ])
3684 AS_IF([test "${enable_qt}" != "no"], [
3685   VLC_ADD_PLUGIN([qt4])
3686   ALIASES="${ALIASES} qvlc"
3687
3688   AC_LANG_PUSH([C++])
3689   VLC_SAVE_FLAGS
3690
3691   AC_MSG_CHECKING([whether Qt uses Xlib])
3692   CPPFLAGS="${CPPFLAGS} ${QT_CFLAGS}"
3693   AC_PREPROC_IFELSE([AC_LANG_SOURCE([
3694 #include <QWidget>
3695 #if !defined (Q_WS_X11)
3696 # error Fail
3697 #endif
3698   ])], [
3699     AC_MSG_RESULT([yes])
3700   ], [
3701     AC_MSG_RESULT([no])
3702   ])
3703
3704   VLC_RESTORE_FLAGS
3705   AC_LANG_POP([C++])
3706
3707 ])
3708 AM_CONDITIONAL(ENABLE_QT4, [test "$enable_qt" != "no"])
3709
3710 dnl
3711 dnl Simple test for skins2 dependency
3712 dnl
3713 AS_IF([test "$enable_qt" = "no"], [
3714   AS_IF([test "${enable_skins2}" = "yes"], [
3715     AC_MSG_ERROR([The skins2 module depends on the Qt4 interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt4 development package or alternatively you can also configure with: --disable-qt4 --disable-skins2.])
3716   ], [
3717     enable_skins2="no"
3718     AC_MSG_WARN([The skins2 module depends on the Qt4 interface, Qt4 is not built so skins2 is disabled.])
3719   ])
3720 ])
3721
3722 dnl
3723 dnl Skins2 module
3724 dnl
3725 AC_ARG_ENABLE(skins2,
3726   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3727 AS_IF([test "${enable_skins2}" != "no"], [
3728   have_skins_deps="yes"
3729
3730   dnl Win32
3731   AS_IF([test "${SYS}" = "mingw32"], [
3732     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3733     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3734   dnl MacOS
3735   ], [test "${SYS}" = "darwin"], [
3736     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3737     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3738   dnl OS/2
3739   ], [test "${SYS}" = "os2"], [
3740     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3741   dnl Linux/Unix
3742   ], [
3743     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3744     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3745     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3746     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3747     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3748   ])
3749
3750   dnl for All OSes
3751   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3752
3753   dnl we need freetype
3754   AS_IF([test "${have_freetype}" != "yes"], [
3755     have_skins_deps="no"
3756   ])
3757
3758   AS_IF([test "${have_skins_deps}" = "no"], [
3759     AS_IF([test "x${enable_skins2}" = "x"], [
3760       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3761     ], [
3762       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3763     ])
3764     enable_skins2="no"
3765   ], [
3766     VLC_ADD_PLUGIN([skins2])
3767     ALIASES="${ALIASES} svlc"
3768     enable_skins2="yes"
3769   ])
3770 ])
3771 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3772
3773 AC_ARG_ENABLE(libtar,
3774   [  --enable-libtar         libtar support for skins2 (default auto)])
3775 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3776   AC_CHECK_HEADERS(libtar.h, [
3777     VLC_ADD_LIBS([skins2],[-ltar])
3778   ])
3779 ])
3780
3781 dnl
3782 dnl  MacOS X gui module
3783 dnl
3784 AC_ARG_ENABLE(macosx,
3785   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3786 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3787 then
3788   VLC_ADD_LIBS([macosx], [-Wl,-framework,Cocoa -Wl,-framework,Carbon -Wl,-framework,CoreServices])
3789   VLC_ADD_OBJCFLAGS([macosx], [-fobjc-exceptions] )
3790   VLC_ADD_PLUGIN([macosx])
3791
3792   VLC_ADD_LIBS([macosx], [-Wl,-framework,QTKit -Wl,-framework,IOKit -Wl,-framework,AddressBook -Wl,-framework,WebKit -Wl,-framework,CoreAudio -Wl,-framework,SystemConfiguration -Wl,-framework,ScriptingBridge])
3793
3794   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3795   then
3796     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3797   fi
3798   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,Sparkle])
3799   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3800
3801   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3802   then
3803     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3804   fi
3805   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,BGHUDAppKit])
3806   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3807 fi
3808 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3809
3810 dnl
3811 dnl  Minimal Mac OS X module
3812 dnl
3813 AC_ARG_ENABLE(minimal-macosx,
3814   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3815 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3816 then
3817   VLC_ADD_LIBS([minimal_macosx], [-Wl,-framework,Cocoa])
3818   VLC_ADD_OBJCFLAGS([minimal_macosx], [-fobjc-exceptions] )
3819   VLC_ADD_PLUGIN([minimal_macosx])
3820 fi
3821 AM_CONDITIONAL(ENABLE_MINIMAL_MACOSX, [test "$enable_minimal_macosx" != "no"])
3822
3823 dnl
3824 dnl  MacOS X dialog provider
3825 dnl
3826 AC_ARG_ENABLE(macosx-dialog-provider,
3827   [  --enable-macosx-dialog-provider Mac OS X dialog module (default enabled on Mac OS X)])
3828 if test "x${enable_macosx_dialog_provider}" != "xno" &&
3829   (test "${SYS}" = "darwin" || test "${enable_macosx_dialog_provider}" = "yes")
3830 then
3831   VLC_ADD_LIBS([macosx_dialog_provider],[-Wl,-framework,Cocoa])
3832   VLC_ADD_PLUGIN([macosx_dialog_provider])
3833 fi
3834 AM_CONDITIONAL(ENABLE_MACOSX_DIALOG_PROVIDER, [test "$enable_macosx_dialog_provider" != "no"])
3835
3836 dnl
3837 dnl  ncurses module
3838 dnl
3839 AC_ARG_ENABLE(ncurses,
3840 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3841 AS_IF([test "${enable_ncurses}" != "no"] ,[
3842   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3843     VLC_ADD_PLUGIN([ncurses])
3844     VLC_ADD_CFLAGS([ncurses],[${NCURSES_CFLAGS}])
3845     VLC_ADD_LIBS([ncurses],[${NCURSES_LIBS}])
3846     ALIASES="${ALIASES} nvlc"
3847   ], [
3848     AS_IF([test -n "${enable_ncurses}"], [
3849       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3850     ])
3851   ])
3852 ])
3853
3854 dnl
3855 dnl  Lirc plugin
3856 dnl
3857 AC_ARG_ENABLE(lirc,
3858   [  --enable-lirc           lirc support (default disabled)])
3859 if test "${enable_lirc}" = "yes"
3860 then
3861   AC_CHECK_HEADER(lirc/lirc_client.h, AC_CHECK_LIB(lirc_client, lirc_init, have_lirc="true", have_lirc="false"),have_lirc="false")
3862   if test "${have_lirc}" = "true"
3863   then
3864     VLC_ADD_PLUGIN([lirc])
3865     VLC_ADD_LIBS([lirc],[-llirc_client])
3866   fi
3867 fi
3868
3869 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3870 dnl
3871 dnl  goom visualization plugin
3872 dnl
3873 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3874
3875 dnl
3876 dnl libprojectM visualization plugin
3877 dnl
3878 AC_ARG_ENABLE(projectm,
3879   [  --enable-projectm       projectM visualization plugin (default enabled)])
3880 AS_IF([test "${enable_projectm}" != "no"],
3881   [
3882     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3883     [
3884       VLC_ADD_PLUGIN([projectm])
3885       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3886         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3887         [ AC_MSG_WARN( [Using libprojectM version 1] )
3888       ])
3889     ],[
3890       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3891     ])
3892   ])
3893
3894 dnl
3895 dnl Vovoid VSXu visualization plugin
3896 dnl
3897 AC_ARG_ENABLE(vsxu,
3898   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3899 AS_IF([test "${enable_vsxu}" != "no"],
3900   [
3901     PKG_CHECK_MODULES(VSXU, libvsxu,
3902     [
3903       VLC_ADD_PLUGIN([vsxu])
3904       VLC_ADD_CXXFLAGS([vsxu],[$VSXU_CFLAGS])
3905       VLC_ADD_LIBS([vsxu],[$VSXU_LIBS])
3906     ],[
3907       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3908     ])
3909   ])
3910
3911 dnl
3912 dnl  AtmoLight (homemade Philips Ambilight clone)
3913 dnl
3914 AC_ARG_ENABLE(atmo,
3915 AS_HELP_STRING([--disable-atmo],[AtmoLight (homemade Philips Ambilight clone)
3916                 (default enabled)]),, [enable_atmo="yes"])
3917 AS_IF([test "${enable_atmo}" != no], [
3918   AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "linux"], [
3919     AC_LANG_PUSH(C++)
3920     VLC_ADD_PLUGIN([atmo])
3921     AC_LANG_POP(C++)
3922   ])
3923 ])
3924
3925 dnl
3926 dnl  glSpectrum
3927 dnl
3928 AC_ARG_ENABLE(glspectrum,
3929   [  --enable-glspectrum    3D OpenGL spectrum visualization (default auto)])
3930 if test "${enable_glspectrum}" != "no" && test "${have_gl}" = "yes"
3931 then
3932     VLC_ADD_PLUGIN([glspectrum])
3933     VLC_ADD_LIBS([glspectrum],[$GL_LIBS])
3934 fi
3935
3936 EXTEND_HELP_STRING([Service Discovery plugins:])
3937 dnl
3938 dnl  Bonjour services discovery
3939 PKG_ENABLE_MODULES_VLC([BONJOUR], [], [avahi-client >= 0.6], [Bonjour services discovery], [auto])
3940
3941 dnl
3942 dnl  libudev services discovery
3943 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3944
3945 dnl
3946 dnl MTP devices services discovery
3947 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3948
3949 dnl
3950 dnl UPnP Plugin (Intel SDK)
3951 dnl
3952 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3953
3954 EXTEND_HELP_STRING([Misc options:])
3955
3956 dnl
3957 dnl  libxml2 module
3958 dnl
3959 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3960
3961
3962 dnl
3963 dnl libgcrypt
3964 dnl
3965 AC_ARG_ENABLE(libgcrypt,
3966   [  --disable-libgcrypt     gcrypt support (default enabled)])
3967 AS_IF([test "${enable_libgcrypt}" != "no"], [
3968   AC_CHECK_DECL([GCRYCTL_SET_THREAD_CBS], [
3969     libgcrypt-config --version >/dev/null || \
3970         AC_MSG_ERROR([gcrypt.h present but libgcrypt-config could not be found])
3971     AC_CHECK_LIB(gcrypt, gcry_control, [
3972       have_libgcrypt="yes"
3973       GCRYPT_CFLAGS="`libgcrypt-config --cflags`"
3974       GCRYPT_LIBS="`libgcrypt-config --libs`"
3975     ], [
3976       AC_MSG_ERROR([libgcrypt not found. Install libgcrypt or use --disable-libgcrypt. Have a nice day.])
3977     ], [`libgcrypt-config --libs`])
3978   ], [
3979     AC_MSG_ERROR([libgcrypt version 1.1.94 or higher not found. Install libgcrypt or use --disable-libgcrypt. Have a nice day.])
3980   ], [#include <gcrypt.h>]
3981   )
3982 ])
3983
3984 AC_SUBST(GCRYPT_CFLAGS)
3985 AC_SUBST(GCRYPT_LIBS)
3986 AM_CONDITIONAL([HAVE_GCRYPT], [test "${have_libgcrypt}" = "yes"])
3987
3988 dnl
3989 dnl TLS/SSL
3990 dnl
3991 AC_ARG_ENABLE(gnutls,
3992   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
3993 AS_IF([test "${enable_gnutls}" != "no"], [
3994   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.0.20], [
3995     VLC_ADD_PLUGIN([gnutls])
3996   ], [
3997     AS_IF([test -n "${enable_gnutls}"], [
3998       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
3999     ])
4000   ])
4001 ])
4002
4003
4004 dnl
4005 dnl Taglib plugin
4006 dnl
4007 AC_ARG_ENABLE(taglib,
4008   [AS_HELP_STRING([--disable-taglib],
4009     [do not use TagLib (default enabled)])])
4010 AS_IF([test "${enable_taglib}" != "no"], [
4011   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.6.1, [
4012     VLC_ADD_PLUGIN([taglib])
4013   ], [
4014     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4015 ])
4016
4017
4018 dnl
4019 dnl update checking system
4020 dnl
4021 AC_ARG_ENABLE(update-check,
4022   [  --enable-update-check   update checking system (default disabled)])
4023 if test "${enable_update_check}" = "yes"
4024 then
4025   if test "${have_libgcrypt}" != "yes"
4026   then
4027     AC_MSG_ERROR([libgcrypt is required for update checking system])
4028   fi
4029   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4030   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4031   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
4032 fi
4033
4034 dnl
4035 dnl Growl notification plugin
4036 dnl
4037 AC_ARG_ENABLE(growl,
4038   [  --enable-growl          growl notification plugin (default disabled)],,
4039   [enable_growl=no])
4040 AS_IF([test "${enable_growl}" != "no"], [
4041     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4042       VLC_ADD_PLUGIN([growl])
4043       VLC_ADD_LIBS([growl], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
4044       VLC_ADD_OBJCFLAGS([growl], [-F${CONTRIB_DIR}])
4045       VLC_ADD_OBJCFLAGS([growl], [-fobjc-exceptions] )
4046     ])
4047   ]
4048 )
4049
4050 dnl
4051 dnl Libnotify notification plugin
4052 dnl
4053 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4054
4055 dnl
4056 dnl  Endianness check
4057 dnl
4058 AC_C_BIGENDIAN
4059 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4060   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4061 ], [
4062   DEFS_BIGENDIAN=""
4063 ])
4064 AC_SUBST(DEFS_BIGENDIAN)
4065
4066 dnl
4067 dnl Where to install KDE solid .desktop
4068 dnl
4069 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
4070 AS_IF([test "x$KDE4_CONFIG" = "x"], [
4071   KDE4_CONFIG="kde4-config"
4072 ])
4073
4074 AC_ARG_WITH(kde-solid,
4075   AS_HELP_STRING([--with-kde-solid=PATH],
4076                  [KDE Solid actions directory (auto)]),, [
4077
4078 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4079   with_kde_solid="yes"
4080 fi
4081 ])
4082 soliddatadir=""
4083 AS_IF([test "${with_kde_solid}" != "no"], [
4084   AS_IF([test "${with_kde_solid}" = "yes"], [
4085     kde4datadir="`${KDE4_CONFIG} --install data`"
4086     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4087     soliddatadir="${kde4datadir}/solid/actions"
4088   ], [
4089     soliddatadir="${with_kde_solid}"
4090   ])
4091 ])
4092 AC_SUBST(soliddatadir)
4093 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4094
4095 EXTEND_HELP_STRING([Components:])
4096
4097 dnl
4098 dnl  the VLC binary
4099 dnl
4100 AC_ARG_ENABLE(vlc,
4101   [  --enable-vlc            build the VLC media player (default enabled)])
4102 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4103
4104 AC_ARG_ENABLE(macosx-vlc-app,
4105   [  --enable-macosx-vlc-app build the VLC media player (default enabled on Mac OS X)])
4106 AM_CONDITIONAL(BUILD_MACOSX_VLC_APP, [test "${enable_macosx_vlc_app}" != "no" &&
4107     (test "${SYS}" = "darwin" || test "${enable_macosx_vlc_app}" = "yes") ])
4108
4109 dnl
4110 dnl  Stuff used by the program
4111 dnl
4112 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4113 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4114 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4115 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4116 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4117 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4118 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4119 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4120 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4121 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4122 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4123 AC_SUBST(COPYRIGHT_MESSAGE)
4124 AC_SUBST(VERSION_MESSAGE)
4125 AC_SUBST(VERSION_MAJOR)
4126 AC_SUBST(VERSION_MINOR)
4127 AC_SUBST(VERSION_REVISION)
4128 AC_SUBST(VERSION_EXTRA)
4129 AC_SUBST(COPYRIGHT_YEARS)
4130 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4131 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4132 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4133 dnl
4134 dnl  Handle substvars that use $(top_srcdir)
4135 dnl
4136 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4137
4138 dnl
4139 dnl  Configuration is finished
4140 dnl
4141 AC_SUBST(SYS)
4142 AC_SUBST(ARCH)
4143 AC_SUBST(ALIASES)
4144 AC_SUBST(ASM)
4145 AC_SUBST(MOC)
4146 AC_SUBST(RCC)
4147 AC_SUBST(UIC)
4148 AC_SUBST(WINDRES)
4149 AC_SUBST(WINE_SDK_PATH)
4150 AC_SUBST(LIBEXT)
4151 AC_SUBST(AM_CPPFLAGS)
4152 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4153 AC_SUBST(FILE_LIBVLCCORE_DLL)
4154 AC_SUBST(FILE_LIBVLC_DLL)
4155
4156 AC_CONFIG_FILES([
4157   Makefile
4158   doc/Makefile
4159   modules/Makefile
4160   m4/Makefile
4161   po/Makefile.in
4162   share/Makefile
4163   compat/Makefile
4164   src/Makefile
4165   lib/Makefile
4166   bin/Makefile
4167   test/Makefile
4168   modules/access_output/Makefile
4169   modules/audio_filter/Makefile
4170   modules/control/Makefile
4171   modules/gui/Makefile
4172   modules/gui/macosx/Makefile
4173   modules/gui/minimal_macosx/Makefile
4174   modules/gui/macosx_dialog_provider/Makefile
4175   modules/gui/qt4/Makefile
4176   modules/gui/skins2/Makefile
4177   modules/misc/Makefile
4178   modules/mux/Makefile
4179   modules/packetizer/Makefile
4180   modules/stream_out/Makefile
4181   modules/text_renderer/Makefile
4182   modules/video_filter/Makefile
4183   modules/video_output/Makefile
4184   modules/visualization/Makefile
4185   modules/hw/vdpau/Makefile
4186 ])
4187
4188 AM_COND_IF([HAVE_WIN32], [
4189   AC_CONFIG_FILES([
4190     extras/package/win32/NSIS/spad.nsi
4191     extras/package/win32/NSIS/vlc.win32.nsi
4192     extras/package/win32/msi/config.wxi
4193   ])
4194 ])
4195
4196 AM_COND_IF([HAVE_DARWIN], [
4197   AC_CONFIG_FILES([
4198     extras/package/macosx/Info.plist
4199     extras/package/macosx/Resources/English.lproj/InfoPlist.strings
4200   ])
4201 ])
4202
4203 dnl Generate makefiles
4204 AC_OUTPUT
4205
4206 dnl Do we have to use make or gmake ?
4207 if make --version 2>&1|grep -q GNU
4208 then
4209     # GNU make, all seems good
4210     MAKE=make
4211 else
4212     # Known GNU make alias (on BSD)
4213     MAKE=gmake
4214 fi
4215 dnl Shortcut to nice compile message
4216 if test -n $SHELL; then
4217   SHELL=${CONFIG_SHELL-/bin/sh}
4218 fi
4219 rm -f compile
4220 echo "#! $SHELL
4221 rm -f .error\$\$
4222 ERROR=0
4223 export PATH=\"$PATH\" LANG=C
4224 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| `sed -ne \"s/^top_srcdir *= *//p\" < Makefile`/extras/buildsystem/make.pl
4225 test -f .error\$\$ && ERROR=1
4226 rm -f .error\$\$
4227 exit \$ERROR" >compile
4228 chmod a+x compile
4229
4230 echo "
4231 libvlc configuration
4232 --------------------
4233 version               : ${VERSION}
4234 system                : ${SYS}
4235 architecture          : ${ARCH}
4236 optimizations         : ${enable_optimizations}"
4237 if test "${enable_vlc}" != "no"; then
4238 echo "vlc aliases           :${ALIASES}"
4239 else
4240 echo "build vlc executable  : no"
4241 fi
4242 echo "
4243 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."