configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 2002-2014 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 3.0.0-git)
   6 VERSION_MAJOR=3
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=git
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Vetinari"
  17 COPYRIGHT_YEARS="1996-2014"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 # Disable with "./configure --disable-silent-rules" or "make V=1"
  31 AM_SILENT_RULES([yes])
  32
  33 dnl Too many people are not aware of maintainer mode:
  34 dnl If you want to use it, you definitely know what you are doing, so
  35 dnl you can specify "--disable-maintainer-mode". But if you want the default
  36 dnl automake behavior, you've likely never heard of maintainer mode, so we
  37 dnl can't expect you to enable it manually.
  38 AS_IF([test "x${enable_maintainer_mode}" != "xno"],
  39     [enable_maintainer_mode="yes"])
  40 AM_MAINTAINER_MODE
  41
  42 dnl
  43 dnl Directories
  44 dnl
  45 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
  46 dnl AC_SUBST(vlcincludedir)
  47 vlcdatadir="\${datadir}/\${PKGDIR}"
  48 AC_SUBST(vlcdatadir)
  49 vlclibdir="\${libdir}/\${PKGDIR}"
  50 AC_SUBST(vlclibdir)
  51
  52 dnl
  53 dnl Check for tools
  54 dnl
  55 AC_PROG_CC_C99
  56 AC_USE_SYSTEM_EXTENSIONS
  57 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  58 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  59 AH_TOP([
  60 #ifndef _REENTRANT
  61 # define _REENTRANT
  62 #endif
  63 ])
  64 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
  65 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  66 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  67
  68 AM_PROG_CC_C_O
  69 AC_PROG_CXX
  70 AC_PROG_CPP
  71 AC_PROG_OBJC
  72 _AM_DEPENDENCIES([OBJC])
  73 AC_PROG_EGREP
  74 AC_PROG_MAKE_SET
  75 AC_PROG_INSTALL
  76 AM_PROG_AS
  77
  78 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  79 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  80 AC_PATH_PROG(YASM, yasm)
  81
  82 dnl Check for compiler properties
  83 AC_C_CONST
  84 AC_C_INLINE
  85 AC_C_RESTRICT
  86
  87 dnl Extend the --help string at the current spot.
  88 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  89
  90 dnl Allow binary package maintainer to pass a custom string to avoid
  91 dnl cache problem
  92 AC_ARG_WITH(binary-version,
  93     AS_HELP_STRING([--with-binary-version=STRING],
  94          [To avoid plugins cache problem between binary version]),[],[])
  95 AS_IF([test -n "${with_binary_version}"],[
  96     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  97          [Binary specific version])
  98 ])
  99
 100 dnl
 101 dnl  Check the operating system
 102 dnl
 103 HAVE_WIN64="0"
 104 HAVE_IOS="0"
 105 HAVE_OSX="0"
 106
 107 YASMFLAGS=""
 108 case "${host}" in
 109     i?86*)
 110     YASMFLAGS="-f elf32"
 111         ;;
 112     x86_64*)
 113     YASMFLAGS="-f elf64"
 114         ;;
 115 esac
 116
 117
 118 case "${host_os}" in
 119   "")
 120     SYS=unknown
 121     ;;
 122   linux*)
 123     SYS=linux
 124     ;;
 125   bsdi*)
 126     SYS=bsdi
 127     CFLAGS="${CFLAGS} -pthread"
 128     ;;
 129   freebsd*)
 130     SYS=freebsd
 131     CFLAGS="${CFLAGS} -pthread"
 132     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 133     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 134     ;;
 135   openbsd*)
 136     SYS=openbsd
 137     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 138     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 139     ;;
 140   netbsd*)
 141     SYS=netbsd
 142     ;;
 143   dragonfly*)
 144     SYS=dragonfly
 145     ;;
 146   darwin*)
 147
 148     dnl Force gcc "-arch" flag
 149     ARCH_flag=""
 150     case "${host}" in
 151       i?86*)
 152         ARCH_flag="-arch i386"
 153         YASMFLAGS="-f macho32"
 154       ;;
 155       ppc64*)
 156         ARCH_flag="-arch ppc64"
 157       ;;
 158       ppc*)
 159         ARCH_flag="-arch ppc"
 160       ;;
 161       x86_64*)
 162         ARCH_flag="-arch x86_64"
 163         YASMFLAGS="-f macho64"
 164       ;;
 165       arm*)
 166         ac_cv_c_bigendian="no"
 167         ac_cv_c_attribute_packed="no"
 168       ;;
 169     esac
 170
 171     SYS=darwin
 172     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 173     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 174     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 175     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu99 ${ARCH_flag}"
 176     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 177     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 178     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 179
 180     AC_EGREP_CPP(yes,
 181             [#import <TargetConditionals.h>
 182              #if TARGET_OS_IPHONE
 183              yes
 184              #endif],
 185              [HAVE_IOS="1"],
 186              [HAVE_OSX="1"])
 187
 188     dnl Allow binaries created on Lion to run on earlier releases
 189     AC_EGREP_CPP(yes,
 190            [#import <Cocoa/Cocoa.h>
 191             #ifdef MAC_OS_X_VERSION_10_7
 192             yes
 193             #endif],
 194             [AC_MSG_RESULT([yes])
 195             AC_LIBOBJ([getdelim])
 196             AC_LIBOBJ([strndup])
 197             AC_LIBOBJ([strnlen])],)
 198
 199     dnl
 200     dnl  Handle Mac OS X SDK flags
 201     dnl
 202     AC_ARG_WITH(macosx-sdk,
 203       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 204         [compile using the SDK in DIR])])
 205     if test "${with_macosx_sdk}" != "" ; then
 206         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 207         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 208         CC="${CC} -isysroot ${with_macosx_sdk}"
 209         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 210         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 211         LD="${LD} -syslibroot ${with_macosx_sdk}"
 212     fi
 213     AC_ARG_WITH(macosx-version-min,
 214       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 215         [compile for Mac OS X VERSION and above])])
 216     if test "${with_macosx_version_min}" != "" ; then
 217         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 218         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 219         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 220         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 221         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 222     fi
 223     ;;
 224   *mingw32* | *cygwin* | *wince* | *mingwce*)
 225     AC_CHECK_TOOL(WINDRES, windres, :)
 226     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 227     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
 228     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
 229     AH_TOP([#endif])
 230     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 231     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 232     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 233     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 234     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 235     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 236     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 237     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 238     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 239     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 240     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 241
 242     case "${host_os}" in
 243       *mingw32*)
 244         SYS=mingw32
 245         ;;
 246       *cygwin*)
 247         dnl Check if we are using the mno-cygwin mode in which case we are
 248         dnl actually dealing with a mingw32 compiler.
 249         AC_EGREP_CPP(yes,
 250             [#ifdef _WIN32
 251              yes
 252              #endif],
 253             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 254         ;;
 255     esac
 256
 257     if test "${SYS}" = "mingw32"; then
 258         # DEP, ASLR, NO SEH
 259         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 260
 261         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 262         ac_default_prefix="`pwd`/_win32"
 263         DESTDIR="`pwd`/_win32/"
 264
 265         dnl
 266         dnl NSIS/MSI Installer prefix and WIN64
 267         dnl
 268         case "${host}" in
 269             amd64*|x86_64*)
 270                 HAVE_WIN64="1"
 271                 WINDOWS_ARCH="x64"
 272                 PROGRAMFILES="PROGRAMFILES64"
 273                 YASMFLAGS="-f win64"
 274             ;;
 275             *)
 276                 WINDOWS_ARCH="x86"
 277                 PROGRAMFILES="PROGRAMFILES"
 278                 YASMFLAGS="-f win32"
 279             ;;
 280         esac
 281         AC_SUBST(WINDOWS_ARCH)
 282         AC_SUBST(PROGRAMFILES)
 283
 284     fi
 285     ;;
 286   *nto*)
 287     SYS=nto
 288     ;;
 289   solaris*)
 290     SYS=solaris
 291     ;;
 292   hpux*)
 293     SYS=hpux
 294     ;;
 295   symbian*)
 296     SYS=symbian
 297     ;;
 298   *os2*)
 299     SYS=os2
 300     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 301     AC_LIBOBJ([freeaddrinfo])
 302     ;;
 303   *)
 304     SYS="${host_os}"
 305     ;;
 306 esac
 307 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 308 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 309 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 310 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 311 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
 312 AM_CONDITIONAL(HAVE_SYMBIAN, test "${SYS}" = "symbian")
 313 AM_CONDITIONAL(HAVE_IOS,   test "${HAVE_IOS}" = "1")
 314 AM_CONDITIONAL(HAVE_OSX,   test "${HAVE_OSX}" = "1")
 315
 316 AC_SUBST(YASMFLAGS)
 317
 318 dnl
 319 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 320 dnl for program foo on win32
 321 case "${build_os}" in
 322     cygwin|msys)
 323         ac_executable_extensions=".exe"
 324     ;;
 325     *)
 326     ;;
 327 esac
 328
 329 dnl Android is linux, but a bit different
 330 AS_IF([test "$SYS" = linux],[
 331     AC_MSG_CHECKING([for an Android system])
 332     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 333         [[#ifndef __ANDROID__
 334          # error Not Android
 335          #endif
 336         ]],[[;]])
 337     ],[
 338       HAVE_ANDROID="1"
 339       AC_MSG_RESULT([yes])
 340     ],[
 341       AC_MSG_RESULT([no])
 342     ])
 343 ])
 344 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 345
 346
 347 dnl
 348 dnl  Check for the contrib directory
 349 dnl
 350 AC_ARG_WITH(contrib,
 351   [AS_HELP_STRING([--with-contrib[=DIR]],
 352     [search for 3rd party libraries in DIR/include and DIR/lib])
 353 ])
 354 AC_MSG_CHECKING([for 3rd party libraries path])
 355 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 356   CONTRIB_DIR="${srcdir}/contrib/${host}"
 357   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 358     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 359     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 360     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 361       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 362       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
 363       AS_IF([test ! -d "${CONTRIB_DIR}"], [
 364         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 365         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
 366         AS_IF([test ! -d "${CONTRIB_DIR}"], [
 367           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 368           CONTRIB_DIR=""
 369           AC_MSG_RESULT([not found])
 370         ])
 371       ])
 372     ])
 373   ])
 374 ], [
 375   AS_IF([test "${with_contrib}" != "no"], [
 376     CONTRIB_DIR="${with_contrib}"
 377   ], [
 378     CONTRIB_DIR=""
 379     AC_MSG_RESULT([disabled])
 380   ])
 381 ])
 382 AS_IF([test -n "${CONTRIB_DIR}"], [
 383   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 384     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 385   ], [
 386     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 387     CONTRIB_DIR=""
 388     AC_MSG_RESULT([not usable])
 389   ])
 390
 391 ])
 392 AS_IF([test -n "${CONTRIB_DIR}"], [
 393   AC_MSG_RESULT([${CONTRIB_DIR}])
 394   export PATH=${CONTRIB_DIR}/bin:$PATH
 395   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 396   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 397   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 398   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
 399   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 400   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 401
 402   AS_IF([test "${SYS}" = "darwin"], [
 403     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 404     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 405   ])
 406 ], [
 407   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 408     AC_MSG_ERROR([Third party libraries not found!])
 409   ])
 410 ])
 411 AC_SUBST(CONTRIB_DIR)
 412
 413 dnl Add extras/tools to the PATH
 414 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 415 AS_IF([test -d "${TOOLS_DIR}"], [
 416     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 417     export PATH="${TOOLS_DIR}":$PATH
 418 ])
 419
 420 dnl
 421 dnl  Libtool
 422 dnl  It's very bad, but our former custom system was worst
 423 dnl  -- Courmisch
 424 dnl
 425
 426 dnl override platform specific check for dependent libraries
 427 dnl otherwise libtool linking of shared libraries will
 428 dnl fail on anything other than pass_all.
 429 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 430     [lt_cv_deplibs_check_method=pass_all])
 431
 432 LT_INIT([dlopen win32-dll shared disable-static])
 433 LT_LANG([C++])
 434 LT_LANG([Windows Resource])
 435
 436 DOLT
 437
 438 lt_cv_deplibs_check_method=pass_all
 439
 440 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 441   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 442 ])
 443
 444 dnl
 445 dnl Gettext stuff
 446 dnl
 447 AM_GNU_GETTEXT_VERSION([0.19.2])
 448 AM_GNU_GETTEXT([external], [need-ngettext])
 449
 450 dnl
 451 dnl Iconv stuff
 452 dnl
 453 AM_ICONV
 454
 455 dnl
 456 dnl checks for mingw
 457 AS_IF([test "${SYS}" = "mingw32"], [
 458
 459 dnl Check for broken versions of mingw-runtime compatability library
 460     AC_MSG_CHECKING(for broken mingw-runtime)
 461     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 462 #include <_mingw.h>
 463 #if defined(__MINGW64_VERSION_MAJOR)
 464 # if __MINGW64_VERSION_MAJOR < 3
 465 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
 466 # endif
 467 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
 468 # error Attempting to use mingw-runtime with broken vsnprintf support
 469 #endif
 470     ])], [
 471         AC_MSG_RESULT([ok])
 472     ], [
 473         AC_MSG_RESULT([present])
 474         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
 475     ])
 476
 477     dnl force use of mingw provided c99 *printf over msvcrt
 478     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 479
 480     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
 481     VLC_ADD_LDFLAGS([vlc],[-mwindows])
 482
 483     dnl Check for the need to include the mingwex lib for mingw32
 484     VLC_SAVE_FLAGS
 485     AC_CHECK_LIB(mingwex,opendir,
 486         AC_CHECK_LIB(mingw32,opendir,,
 487             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 488     )
 489     VLC_RESTORE_FLAGS
 490
 491     dnl Check for fnative-struct or mms-bitfields support for mingw32
 492     VLC_SAVE_FLAGS
 493     CFLAGS="${CFLAGS} -mms-bitfields"
 494     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
 495     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
 496         [ac_cv_c_mms_bitfields],
 497         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
 498     if test "${ac_cv_c_mms_bitfields}" = "no"; then
 499         VLC_RESTORE_FLAGS
 500         CFLAGS="${CFLAGS} -fnative-struct"
 501         CXXFLAGS="${CXXFLAGS} -fnative-struct"
 502         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
 503             [ac_cv_c_fnative_struct],
 504             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
 505         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
 506     fi
 507 ])
 508
 509 AC_ARG_ENABLE(winstore_app,
 510      AS_HELP_STRING([--enable-winstore-app],
 511                     [Build targetted for Windows Store apps (default disabled)]))
 512
 513 vlc_winstore_app=0
 514 AS_IF([test "${SYS}" = "mingw32"],[
 515   AS_IF([test "${enable_winstore_app}" = "yes"], [
 516     vlc_winstore_app=1
 517      VLC_ADD_LIBS([libvlccore], [-lole32 -lruntimeobject])
 518     ],[
 519      VLC_ADD_LIBS([win32text],[-lgdi32])
 520      VLC_ADD_LIBS([libvlccore],[-lwinmm])
 521     ])
 522   ])
 523 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 524 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 525
 526
 527 dnl
 528 dnl Buggy glibc prevention. Purposedly not cached.
 529 dnl See sourceware.org bugs 5058 and 5443.
 530 dnl Ubuntu alone has 20 bug numbers for this...
 531 dnl
 532 AC_MSG_CHECKING(for buggy GNU/libc versions)
 533 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 534 #include <limits.h>
 535 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 536   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 537 # error GNU/libc with dcgettext killer bug!
 538 #endif
 539 ])], [
 540   AC_MSG_RESULT([not present])
 541 ], [
 542   AC_MSG_RESULT([found])
 543   AS_IF([test "x${enable_nls}" != "xno"], [
 544     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 545 work-around for this. Check with your distribution vendor on how to update the
 546 glibc run-time. Alternatively, build with --disable-nls.])
 547   ])
 548 ])
 549
 550 dnl Plugin compilation stuff
 551
 552 VLC_LIBRARY_SUFFIX
 553
 554 dnl Check for system libs needed
 555 need_libc=false
 556
 557 dnl Check for usual libc functions
 558 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
 559 AC_CHECK_FUNCS([daemon fcntl fstatvfs fork getenv getpwuid_r isatty lstat memalign mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale pthread_cond_timedwait_monotonic_np pthread_condattr_setclock])
 560 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir flockfile fsync getdelim getpid gmtime_r lldiv localtime_r nrand48 poll posix_memalign rewind setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strsep strtof strtok_r strtoll swab tdestroy strverscmp])
 561 AC_CHECK_FUNCS(fdatasync,,
 562   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 563 ])
 564
 565 dnl mingw64 implements those as static inline, not functions with C linkage
 566 AC_LINK_IFELSE([
 567     AC_LANG_PROGRAM([#include <stdio.h>], [
 568         char *c;
 569         if (asprintf(&c, "%s %d", "string", 1) == -1)
 570             c = NULL;
 571     ])],[AC_DEFINE([HAVE_ASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([asprintf])])
 572 AC_LINK_IFELSE([
 573     AC_LANG_PROGRAM([#include <stdio.h>
 574                      #include <stdarg.h>], [
 575         char *c;
 576         va_list ap;
 577         if (vasprintf(&c, "%s %d", ap) == -1)
 578             c = NULL;
 579     ])],[AC_DEFINE([HAVE_VASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([vasprintf])])
 580
 581 dnl C11 static_assert()
 582 AC_MSG_CHECKING([for static_assert in assert.h])
 583 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 584 static_assert(1, "The impossible happened.");
 585 ])], [
 586   AC_MSG_RESULT([yes])
 587   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 588 ], [
 589   AC_MSG_RESULT([no])
 590 ])
 591
 592 # Windows CE does not have strcoll()
 593 AC_FUNC_STRCOLL
 594
 595 dnl Check for non-standard system calls
 596 case "$SYS" in
 597   "linux")
 598     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
 599     ;;
 600   "mingw32")
 601     AC_CHECK_FUNCS([_lock_file])
 602     ;;
 603 esac
 604
 605 AH_BOTTOM([#include <vlc_fixups.h>])
 606
 607 dnl Check for struct pollfd
 608 AC_CHECK_TYPES([struct pollfd],,,
 609 [#include <sys/types.h>
 610 #if HAVE_POLL
 611 # include <poll.h>
 612 #elif defined (_WIN32)
 613 # include <winsock2.h>
 614 #endif
 615 ])
 616
 617 dnl Checks for socket stuff
 618 VLC_SAVE_FLAGS
 619 SOCKET_LIBS=""
 620 AC_SEARCH_LIBS(connect, [socket], [
 621   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 622     SOCKET_LIBS="$ac_cv_search_connect"
 623   ])
 624 ], [
 625   AS_IF([test "${SYS}" = "mingw32"], [
 626     SOCKET_LIBS="-lws2_32"
 627   ])
 628 ])
 629
 630 AC_SEARCH_LIBS([inet_pton], [nsl], [
 631  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 632     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 633   ])
 634 ],, [${SOCKET_LIBS}])
 635
 636 LIBS="${LIBS} ${SOCKET_LIBS}"
 637 AC_LINK_IFELSE([
 638     AC_LANG_PROGRAM([#ifdef _WIN32
 639         # if _WIN32_WINNT < 0x600
 640         #  error Needs vista+
 641         # endif
 642         #include <ws2tcpip.h>
 643         #else
 644         #include <sys/socket.h>
 645         #include <arpa/inet.h>
 646         #endif], [
 647         char dst[[sizeof(struct in_addr)]];
 648         inet_pton(AF_INET, "127.0.0.1", dst);
 649     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 650 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
 651 VLC_RESTORE_FLAGS
 652
 653 AS_IF([test -n "$SOCKET_LIBS"], [
 654   VLC_ADD_LIBS([access_rtmp access_output_shout sap stream_out_standard stream_out_rtp stream_out_raop stream_out_chromecast oldrc netsync ts remoteosd audiobargraph_a],[${SOCKET_LIBS}])
 655 ])
 656 AC_SUBST(SOCKET_LIBS)
 657
 658 dnl Check for socklen_t
 659 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 660 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 661 ac_cv_type_socklen_t,
 662 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 663 [#include <sys/types.h>
 664 #ifdef _WIN32
 665 # include <winsock2.h>
 666 # include <ws2tcpip.h>
 667 #else
 668 # include <sys/socket.h>
 669 #endif]], [[socklen_t len; len = 0;]])],
 670 ac_cv_type_socklen_t=yes,
 671 ac_cv_type_socklen_t=no)])
 672 AS_IF([test "$ac_cv_type_socklen_t" = no],
 673  [AC_DEFINE(socklen_t, int)])
 674
 675 dnl Check for struct sockaddr_storage
 676 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 677 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 678 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 679   [AC_TRY_COMPILE(
 680     [#include <sys/types.h>
 681      #if defined( _WIN32 )
 682      # include <winsock2.h>
 683      #else
 684      # include <sys/socket.h>
 685      #endif], [struct sockaddr_storage addr;],
 686      ac_cv_struct_sockaddr_storage=yes,
 687      ac_cv_struct_sockaddr_storage=no)])
 688 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 689   AC_DEFINE(sockaddr_storage, sockaddr)
 690   AC_DEFINE(ss_family, sa_family)
 691 ])
 692
 693 dnl FreeBSD has a gnugetopt library for this:
 694 GNUGETOPT_LIBS=""
 695 AC_CHECK_FUNC(getopt_long,, [
 696   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 697     GNUGETOPT_LIBS="-lgnugetopt"
 698   ])
 699 ])
 700 AC_SUBST(GNUGETOPT_LIBS)
 701
 702 AC_CHECK_LIB(m,cos,[
 703   VLC_ADD_LIBS([adjust wave ripple psychedelic gradient a52tofloat32 dtstofloat32 x264 goom noise grain scene chorus_flanger freetype swscale postproc equalizer spatializer param_eq samplerate freetype mpc qt4 compressor headphone_channel_mixer normvol audiobargraph_a audiobargraph_v mono colorthres extract ball hotkeys mosaic gaussianblur x262 x26410b hqdn3d anaglyph oldrc ncurses oldmovie glspectrum smooth],[-lm])
 704   LIBM="-lm"
 705 ], [
 706   LIBM=""
 707 ])
 708 AC_SUBST(LIBM)
 709
 710 AC_CHECK_LIB(m,lrintf, [
 711   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 712   VLC_ADD_LIBS([skins2],[-lm])
 713 ])
 714 AC_CHECK_LIB(m,nanf,
 715   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 716 )
 717
 718 dnl Check for dynamic plugins
 719 LIBDL=""
 720 have_dynamic_objects="no"
 721 VLC_SAVE_FLAGS
 722 AC_SEARCH_LIBS(dlsym, [dl svld], [
 723   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 724     LIBDL="$ac_cv_search_dlsym"
 725   ])
 726   have_dynamic_objects="yes"
 727 ])
 728 VLC_RESTORE_FLAGS
 729
 730 # Windows
 731 AS_IF([test "${SYS}" = "mingw32"], [
 732   LIBDL=""
 733   have_dynamic_objects="yes" #assume we can use shared objects
 734 ])
 735
 736 AS_IF([test "${enable_shared}" = "no"], [
 737   have_dynamic_objects=no
 738 ])
 739 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 740
 741 AC_SUBST(LIBDL)
 742
 743 dnl Check for thread library
 744 LIBPTHREAD=""
 745 AS_IF([test "${SYS}" != "mingw32"], [
 746   VLC_SAVE_FLAGS
 747   LIBS=""
 748   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
 749     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
 750       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
 751     ])
 752   ])
 753   VLC_RESTORE_FLAGS
 754
 755   AC_CHECK_LIB(rt, clock_nanosleep, [
 756     VLC_ADD_LIBS([libvlccore],[-lrt])
 757   ], [
 758     AC_CHECK_FUNC(nanosleep,,[
 759       AC_CHECK_LIB(rt,nanosleep, [
 760         VLC_ADD_LIBS([libvlccore],[-lrt])
 761       ], [
 762         AC_CHECK_LIB(posix4,nanosleep, [
 763           VLC_ADD_LIBS([libvlccore],[-lposix4])
 764         ])
 765       ])
 766     ])
 767     dnl HP/UX port
 768     AC_CHECK_LIB(rt,sem_init, [VLC_ADD_LIBS([libvlccore],[-lrt])])
 769   ])
 770 ])
 771 AC_SUBST(LIBPTHREAD)
 772
 773 dnl Check for headers
 774 dnl  POSIX
 775 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h syslog.h sys/shm.h sys/socket.h])
 776 AC_CHECK_HEADERS([net/if.h], [], [],
 777 [
 778 #include <sys/types.h>
 779 #include <sys/socket.h>
 780 ])
 781 dnl  BSD
 782 AC_CHECK_HEADERS([netinet/udplite.h sys/param.h sys/mount.h])
 783 dnl  GNU/Linux
 784 AC_CHECK_HEADERS([getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 785 dnl  MacOS
 786 AC_CHECK_HEADERS([xlocale.h])
 787
 788 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 789 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 790 AC_CHECK_TYPE(ssize_t,, [
 791   AC_DEFINE(ssize_t, int)
 792 ])
 793
 794 dnl It seems that autoconf detects pkg-config only during the first
 795 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 796 dnl it is nested within a conditional block, so it was not working right.
 797 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 798 AC_ARG_VAR(PKG_CONFIG_PATH,
 799        [Paths where to find .pc not at the default location])
 800 PKG_PROG_PKG_CONFIG()
 801
 802 dnl On some OS we need static linking
 803 AS_IF([test -n "${PKG_CONFIG}" ],[
 804     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 805         PKG_CONFIG="${PKG_CONFIG} --static"
 806     ])
 807 ])
 808
 809
 810 dnl
 811 dnl Check for zlib.h and -lz along with system -lminizip if available
 812 dnl
 813 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 814 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 815 if test "${have_zlib}" = "yes"
 816 then
 817   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
 818   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
 819     AC_CHECK_HEADERS([unzip.h], [
 820       have_minizip=yes
 821       MINIZIP_LIBS="-lminizip -lz"
 822     ], [
 823       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
 824       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
 825       have_minizip=no
 826     ])
 827   ])
 828   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
 829   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
 830 fi
 831 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
 832
 833
 834 dnl
 835 dnl Domain name i18n support via GNU libidn
 836 dnl
 837 PKG_CHECK_MODULES([IDN], [libidn], [
 838   have_libidn="yes"
 839   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 840 ], [
 841   have_libidn="no"
 842 ])
 843
 844
 845 dnl Check for dbus
 846 AC_ARG_ENABLE(dbus,
 847   [AS_HELP_STRING([--enable-dbus],
 848     [compile D-Bus message bus support (default enabled)])])
 849 have_dbus="no"
 850 AS_IF([test "${enable_dbus}" != "no"], [
 851   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 852     have_dbus="yes"
 853   ], [
 854     AS_IF([test -n "${enable_dbus}"], [
 855       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 856     ], [
 857       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 858     ])
 859   ])
 860 ])
 861 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 862
 863 dnl Check for ntohl, etc.
 864 VLC_SAVE_FLAGS
 865 CFLAGS="${CFLAGS} -Wall -Werror"
 866 AC_CACHE_CHECK([for ntohl in sys/param.h],
 867     [ac_cv_c_ntohl_sys_param_h],
 868     [     AC_TRY_COMPILE([#include <sys/param.h>],
 869         [int meuh; ntohl(meuh);],
 870         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
 871 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
 872     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
 873 fi
 874 VLC_RESTORE_FLAGS
 875
 876 EXTEND_HELP_STRING([Optimization options:])
 877 dnl
 878 dnl  Compiler warnings
 879 dnl
 880
 881 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op])
 882 RDC_PROG_CC_FLAGS([-pipe])
 883 AC_LANG_PUSH([C++])
 884 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var])
 885 AC_LANG_POP([C++])
 886
 887 dnl
 888 dnl  Debugging mode
 889 dnl
 890 AC_ARG_ENABLE(debug,
 891   [AS_HELP_STRING([--enable-debug],
 892     [build with run-time assertions (default disabled)])],,
 893   [enable_debug="no"])
 894 AH_TEMPLATE(NDEBUG,
 895             [Define to 1 if debug code should NOT be compiled])
 896 AS_IF([test "${enable_debug}" != "no"], [
 897   AC_CHECK_HEADERS([valgrind/valgrind.h])
 898 ], [
 899   AC_DEFINE(NDEBUG)
 900 ])
 901
 902 dnl
 903 dnl  Profiling
 904 dnl
 905 AC_ARG_ENABLE(gprof,
 906   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 907   [enable_gprof="no"])
 908 AS_IF([test "${enable_gprof}" != "no"], [
 909   CFLAGS="${CFLAGS} -pg"
 910   CXXFLAGS="${CXXFLAGS} -pg"
 911   OBJCFLAGS="${OBJCFLAGS} -pg"
 912   LDFLAGS="${LDFLAGS} -pg"
 913 ])
 914
 915 AC_ARG_ENABLE(cprof,
 916   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 917   [enable_cprof="no"])
 918 AS_IF([test "${enable_gprof}" != "no"], [
 919   CFLAGS="${CFLAGS} -finstrument-functions"
 920   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 921   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 922   LDFLAGS="${LDFLAGS} -finstrument-functions"
 923 ])
 924
 925 dnl
 926 dnl  Test coverage
 927 dnl
 928 AC_ARG_ENABLE(coverage,
 929   [AS_HELP_STRING([--enable-coverage],
 930     [build for test coverage (default disabled)])],,
 931   [enable_coverage="no"])
 932 AS_IF([test "${enable_coverage}" != "no"], [
 933   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 934   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 935   LDFLAGS="-lgcov ${LDFLAGS}"
 936 ])
 937
 938 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 939   VLC_SAVE_FLAGS
 940   CFLAGS="${CFLAGS} -fvisibility=hidden"
 941   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 942   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 943   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 944                  [ac_cv_c_visibility_hidden], [
 945     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 946       ac_cv_c_visibility_hidden=yes
 947     ], [
 948       ac_cv_c_visibility_hidden=no
 949     ])
 950   ])
 951   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
 952 ])
 953
 954
 955 dnl
 956 dnl  Enable/disable optimizations
 957 dnl
 958 AC_ARG_ENABLE(optimizations,
 959   [AS_HELP_STRING([--disable-optimizations],
 960     [disable compiler optimizations (default enabled)])],,
 961   [enable_optimizations="yes"])
 962
 963 dnl Check for various optimization flags
 964 AS_IF([test "${enable_optimizations}" != "no"], [
 965
 966   dnl -O3 only in production builds
 967   AS_IF([test "${enable_debug}" = "no"], [
 968     VLC_SAVE_FLAGS
 969     CFLAGS="${CFLAGS} -O3"
 970     CXXFLAGS="${CXXFLAGS} -O3"
 971     OBJCFLAGS="${OBJCFLAGS} -O3"
 972     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
 973       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 974         ac_cv_c_o3=yes
 975       ], [
 976         ac_cv_c_o3=no
 977       ])
 978     ])
 979     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
 980   ])
 981
 982   dnl Check for -ffast-math
 983   VLC_SAVE_FLAGS
 984   CFLAGS="${CFLAGS} -ffast-math"
 985   CXXFLAGS="${CXXFLAGS} -ffast-math"
 986   OBJCFLAGS="${OBJCFLAGS} -ffast-math"
 987   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
 988     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 989       ac_cv_c_fast_math=yes
 990     ], [
 991       ac_cv_c_fast_math=no
 992     ])
 993   ])
 994   AS_IF([test "${ac_cv_c_fast_math}" = "no"], [VLC_RESTORE_FLAGS])
 995   AH_BOTTOM([
 996 #ifndef __FAST_MATH__
 997 # ifndef _MSC_VER
 998 #  pragma STDC FENV_ACCESS OFF
 999 #  pragma STDC FP_CONTRACT ON
1000 # else
1001 #  pragma fenv_access(off)
1002 #  pragma fp_contract(on)
1003 # endif
1004 #endif
1005 ])
1006
1007   dnl Check for -funroll-loops
1008   VLC_SAVE_FLAGS
1009   CFLAGS="${CFLAGS} -funroll-loops"
1010   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1011   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1012   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1013     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1014       ac_cv_c_unroll_loops=yes
1015     ], [
1016       ac_cv_c_unroll_loops=no
1017     ])
1018   ])
1019   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1020
1021   AS_IF([test "$enable_debug" = "no"], [
1022     dnl Check for -fomit-frame-pointer
1023     VLC_SAVE_FLAGS
1024     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1025     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1026     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1027     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1028       [ac_cv_c_omit_frame_pointer], [
1029       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1030         ac_cv_c_omit_frame_pointer=yes
1031       ], [
1032         ac_cv_c_omit_frame_pointer=no
1033       ])
1034     ])
1035     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1036   ])
1037 ])
1038
1039 VLC_SAVE_FLAGS
1040 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1041 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1042   AC_TRY_LINK([],, [
1043     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1044   ], [
1045     ac_cv_ld_bsymbolic=""
1046   ])
1047 ])
1048 VLC_RESTORE_FLAGS
1049 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1050 AC_SUBST(SYMBOLIC_LDFLAGS)
1051
1052 dnl Checks for __attribute__(aligned()) directive
1053 VLC_SAVE_FLAGS
1054 CFLAGS="${CFLAGS} -Werror"
1055 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1056     [ac_cv_c_attribute_aligned],
1057     [ac_cv_c_attribute_aligned=0
1058     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1059         AC_TRY_COMPILE([],
1060         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1061         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1062     done])
1063 VLC_RESTORE_FLAGS
1064 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1065     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1066         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1067 fi
1068
1069 dnl Check for __attribute__((packed))
1070 AC_CACHE_CHECK([for __attribute__((packed))],
1071   [ac_cv_c_attribute_packed],
1072   [ac_cv_c_attribute_packed=no
1073    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1074                     [ac_cv_c_attribute_packed=yes])])
1075 if test "${ac_cv_c_attribute_packed}" != "no"; then
1076   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1077 fi
1078
1079 dnl
1080 dnl  Check the CPU
1081 dnl
1082 case "${host_cpu}" in
1083   "")
1084     ARCH=unknown
1085     ;;
1086   *)
1087     ARCH="${host_cpu}"
1088     ;;
1089 esac
1090
1091 dnl Check for backtrace() support
1092 AC_CHECK_HEADERS(execinfo.h)
1093 AC_CHECK_FUNCS(backtrace)
1094
1095 dnl
1096 dnl  default modules
1097 dnl
1098 ALIASES="${ALIASES} cvlc rvlc"
1099
1100 dnl
1101 dnl  Accelerated modules
1102 dnl
1103
1104 dnl  Check for fully working MMX intrinsics
1105 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1106 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1107 AC_ARG_ENABLE(mmx,
1108   [AS_HELP_STRING([--disable-mmx],
1109     [disable MMX optimizations (default auto)])],,[
1110   case "${host_cpu}" in
1111     i?86|x86_64)
1112       enable_mmx="yes"
1113       ;;
1114     *)
1115       enable_mmx="no"
1116       ;;
1117   esac
1118 ])
1119 have_mmx="no"
1120 have_mmxext="no"
1121 AS_IF([test "${enable_mmx}" != "no"], [
1122   ARCH="${ARCH} mmx"
1123   VLC_SAVE_FLAGS
1124   CFLAGS="${CFLAGS} -mmmx"
1125   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1126     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1127 [#include <mmintrin.h>
1128 #include <stdint.h>
1129 uint64_t frobzor;]], [
1130 [__m64 a, b, c;
1131 a = b = c = (__m64)frobzor;
1132 a = _mm_slli_pi16(a, 3);
1133 a = _mm_adds_pi16(a, b);
1134 c = _mm_srli_pi16(c, 8);
1135 c = _mm_slli_pi16(c, 3);
1136 b = _mm_adds_pi16(b, c);
1137 a = _mm_unpacklo_pi8(a, b);
1138 frobzor = (uint64_t)a;]])], [
1139       ac_cv_c_mmx_intrinsics=yes
1140     ], [
1141       ac_cv_c_mmx_intrinsics=no
1142     ])
1143   ])
1144   VLC_RESTORE_FLAGS
1145   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1146     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1147   ])
1148
1149   VLC_SAVE_FLAGS
1150   CFLAGS="${CFLAGS} -mmmx"
1151   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1152     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1153 void *p;
1154 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1155 ]])
1156     ], [
1157       ac_cv_mmx_inline=yes
1158     ], [
1159       ac_cv_mmx_inline=no
1160     ])
1161   ])
1162   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1163     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1164     have_mmx="yes"
1165   ])
1166
1167   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1168                  [ac_cv_mmxext_inline], [
1169     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1170 void *p;
1171 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1172 ]])
1173     ], [
1174       ac_cv_mmxext_inline=yes
1175     ], [
1176       ac_cv_mmxext_inline=no
1177     ])
1178   ])
1179   VLC_RESTORE_FLAGS
1180   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1181     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1182     have_mmxext="yes"
1183   ])
1184 ])
1185 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1186 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1187
1188 dnl  Check for fully workin SSE2 intrinsics
1189 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1190 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1191 AC_ARG_ENABLE(sse,
1192   [AS_HELP_STRING([--disable-sse],
1193     [disable SSE (1-4) optimizations (default auto)])],, [
1194   case "${host_cpu}" in
1195     i?86|x86_64)
1196       enable_sse=yes
1197       ;;
1198     *)
1199       enable_sse=no
1200       ;;
1201   esac
1202 ])
1203 have_sse2="no"
1204 AS_IF([test "${enable_sse}" != "no"], [
1205   ARCH="${ARCH} sse sse2"
1206
1207   VLC_SAVE_FLAGS
1208   CFLAGS="${CFLAGS} -msse2"
1209   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1210     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1211 [#include <emmintrin.h>
1212 #include <stdint.h>
1213 uint64_t frobzor;]], [
1214 [__m128i a, b, c;
1215 a = b = c = _mm_set1_epi64((__m64)frobzor);
1216 a = _mm_slli_epi16(a, 3);
1217 a = _mm_adds_epi16(a, b);
1218 c = _mm_srli_epi16(c, 8);
1219 c = _mm_slli_epi16(c, 3);
1220 b = _mm_adds_epi16(b, c);
1221 a = _mm_unpacklo_epi8(a, b);
1222 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1223       ac_cv_c_sse2_intrinsics=yes
1224     ], [
1225       ac_cv_c_sse2_intrinsics=no
1226     ])
1227   ])
1228   VLC_RESTORE_FLAGS
1229   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1230     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1231   ])
1232
1233   VLC_SAVE_FLAGS
1234   CFLAGS="${CFLAGS} -msse"
1235   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1236     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1237 void *p;
1238 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1239 ]])
1240     ], [
1241       ac_cv_sse_inline=yes
1242     ], [
1243       ac_cv_sse_inline=no
1244     ])
1245   ])
1246
1247   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1248     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1249   ])
1250
1251   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1252     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1253 void *p;
1254 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1255 ]])
1256     ], [
1257       ac_cv_sse2_inline=yes
1258     ], [
1259       ac_cv_sse2_inline=no
1260     ])
1261   ])
1262   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1263     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1264     have_sse2="yes"
1265   ])
1266
1267   # SSE3
1268   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1269     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1270 void *p;
1271 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1272 ]])
1273     ], [
1274       ac_cv_sse3_inline=yes
1275     ], [
1276       ac_cv_sse3_inline=no
1277     ])
1278   ])
1279
1280   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1281     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1282   # SSSE3
1283   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1284     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1285 void *p;
1286 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1287 ]])
1288     ], [
1289       ac_cv_ssse3_inline=yes
1290     ], [
1291       ac_cv_ssse3_inline=no
1292     ])
1293   ])
1294
1295   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1296     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1297
1298   # SSE4.1
1299   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1300                  [ac_cv_sse4_1_inline], [
1301     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1302 void *p;
1303 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1304 ]])
1305     ], [
1306       ac_cv_sse4_1_inline=yes
1307     ], [
1308       ac_cv_sse4_1_inline=no
1309     ])
1310   ])
1311
1312   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1313     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1314
1315   # SSE4.2
1316   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1317                  [ac_cv_sse4_2_inline], [
1318     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1319 void *p;
1320 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1321 ]])
1322     ], [
1323       ac_cv_sse4_2_inline=yes
1324     ], [
1325       ac_cv_sse4_2_inline=no
1326     ])
1327   ])
1328
1329   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1330     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1331
1332   # SSE4A
1333   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1334     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1335 void *p;
1336 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1337 ]])
1338     ], [
1339       ac_cv_sse4a_inline=yes
1340     ], [
1341       ac_cv_sse4a_inline=no
1342     ])
1343   ])
1344   VLC_RESTORE_FLAGS
1345   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1346     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1347 ])
1348 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1349
1350 VLC_SAVE_FLAGS
1351 CFLAGS="${CFLAGS} -mmmx"
1352 have_3dnow="no"
1353 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1354   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1355 void *p;
1356 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1357 ]])
1358   ], [
1359     ac_cv_3dnow_inline=yes
1360   ], [
1361     ac_cv_3dnow_inline=no
1362   ])
1363 ])
1364 VLC_RESTORE_FLAGS
1365 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1366   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1367             [Define to 1 if 3D Now! inline assembly is available.])
1368   have_3dnow="yes"
1369 ])
1370 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1371
1372
1373 AC_ARG_ENABLE(neon,
1374   [AS_HELP_STRING([--disable-neon],
1375     [disable NEON optimizations (default auto)])],, [
1376   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1377 ])
1378 AS_IF([test "${enable_neon}" != "no"], [
1379   VLC_SAVE_FLAGS
1380   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1381   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1382     AC_COMPILE_IFELSE([
1383       AC_LANG_PROGRAM(,[[
1384 asm volatile("vqmovun.s64 d0, q1":::"d0");
1385 ]])
1386     ], [
1387       ac_cv_arm_neon="yes"
1388     ], [
1389       ac_cv_arm_neon="no"
1390     ])
1391   ])
1392   VLC_RESTORE_FLAGS
1393 ])
1394 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1395
1396
1397 AC_ARG_ENABLE(altivec,
1398   [AS_HELP_STRING([--disable-altivec],
1399     [disable AltiVec optimizations (default auto)])],, [
1400   AS_CASE("${host_cpu}", [powerpc*],
1401         [enable_altivec=yes], [enable_altivec=no])
1402 ])
1403 have_altivec="no"
1404 ALTIVEC_CFLAGS=""
1405 AS_IF([test "${enable_altivec}" = "yes"], [
1406   ARCH="${ARCH} altivec";
1407   VLC_SAVE_FLAGS
1408   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1409     [ac_cv_altivec_inline],
1410     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1411          ac_cv_altivec_inline="yes",
1412          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1413           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1414             [ac_cv_altivec_inline="-Wa,-maltivec"],
1415             ac_cv_altivec_inline=no)
1416          ])])
1417   VLC_RESTORE_FLAGS
1418   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1419     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1420               [Define to 1 if AltiVec inline assembly is available.])
1421     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1422       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1423       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1424     ])
1425     have_altivec="yes"
1426   ])
1427
1428   VLC_SAVE_FLAGS
1429   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1430   [ac_cv_c_altivec], [
1431     CFLAGS="${CFLAGS} -maltivec"
1432     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1433 [#include <altivec.h>]], [
1434 [vec_ld(0, (unsigned char *)0);]])], [
1435       ac_cv_c_altivec="-maltivec"
1436     ], [
1437       ac_cv_c_altivec="no"
1438     ])
1439   ])
1440   VLC_RESTORE_FLAGS
1441   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1442     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1443     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1444     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1445     ALTIVEC_CFLAGS="$ALTIVEC_FLAGS ${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}"
1446     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1447     have_altivec="yes"
1448   ])
1449   AC_CHECK_HEADERS(altivec.h)
1450
1451   VLC_SAVE_FLAGS
1452   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1453   AC_CACHE_CHECK([if linker needs -framework vecLib],
1454     [ac_cv_ld_altivec],
1455     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1456   VLC_RESTORE_FLAGS
1457   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1458     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1459   ])
1460 ])
1461 AC_SUBST(ALTIVEC_CFLAGS)
1462 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1463
1464 dnl
1465 dnl  Memory usage
1466 dnl
1467 AC_ARG_ENABLE(optimize-memory,
1468   [AS_HELP_STRING([--enable-optimize-memory],
1469     [optimize memory usage over performance])])
1470 if test "${enable_optimize_memory}" = "yes"; then
1471   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1472 fi
1473
1474 dnl
1475 dnl Allow running as root (useful for people running on embedded platforms)
1476 dnl
1477 AC_ARG_ENABLE(run-as-root,
1478   [AS_HELP_STRING([--enable-run-as-root],
1479     [allow running VLC as root (default disabled)])])
1480 AS_IF([test "${enable_run_as_root}" = "yes"],[
1481     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1482               [Define to 1 to allow running VLC as root (uid 0).])
1483 ])
1484
1485 dnl
1486 dnl Stream output
1487 dnl
1488 AC_ARG_ENABLE(sout,
1489   [AS_HELP_STRING([--disable-sout],
1490     [disable streaming output (default enabled)])])
1491 AS_IF([test "${enable_sout}" != "no"], [
1492   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1493 ])
1494 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1495
1496 dnl Lua modules
1497 AC_ARG_ENABLE(lua,
1498   [AS_HELP_STRING([--disable-lua],
1499     [disable LUA scripting support (default enabled)])])
1500 if test "${enable_lua}" != "no"
1501 then
1502   PKG_CHECK_MODULES(LUA, lua5.2,
1503     [ have_lua=yes ],
1504     [
1505     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1506
1507     PKG_CHECK_MODULES(LUA, lua5.1,
1508       [ have_lua=yes ],
1509       [
1510       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1511       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1512         [ have_lua=yes ],
1513         [
1514           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1515           have_lua=yes
1516           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1517             [],
1518             [ have_lua=no ] )
1519           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1520             [LUA_LIBS="-llua5.2"],
1521           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1522             [LUA_LIBS="-llua5.1"],
1523             AC_CHECK_LIB( lua51 , luaL_newstate,
1524               [LUA_LIBS="-llua51"],
1525               AC_CHECK_LIB( lua , luaL_newstate,
1526                 [LUA_LIBS="-llua"],
1527                 [ have_lua=no
1528                 ], [-lm])
1529             )))
1530         ])
1531       ])
1532     ])
1533   if test "x${have_lua}" != "xyes" ;  then
1534       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1535   fi
1536   AC_ARG_VAR([LUAC], [LUA byte compiler])
1537   AC_PATH_PROGS(LUAC,[${LUAC} luac], [false])
1538   AS_IF([test "${LUAC}" = "false"], [
1539     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1540   ])
1541   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1542     AC_MSG_ERROR([You need 32-bits luac when using using lua from contrib.])
1543   ])
1544 fi
1545 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1546
1547
1548 dnl
1549 dnl HTTP daemon
1550 dnl
1551 AC_ARG_ENABLE(httpd,
1552   [AS_HELP_STRING([--disable-httpd],
1553     [disable the built-in HTTP server (default enabled)])])
1554 if test "${enable_httpd}" != "no"
1555 then
1556   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1557 fi
1558 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1559
1560
1561 dnl
1562 dnl VideoLAN manager
1563 dnl
1564 AC_ARG_ENABLE(vlm,
1565   [AS_HELP_STRING([--disable-vlm],
1566     [disable the stream manager (default enabled)])],,
1567   [enable_vlm="${enable_sout}"])
1568 AS_IF([test "${enable_vlm}" != "no"], [
1569   AS_IF([test "${enable_sout}" = "no"], [
1570     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1571   ])
1572   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1573 ])
1574 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1575
1576
1577 dnl
1578 dnl Addons manager storage and repositories modules
1579 dnl
1580 AC_ARG_ENABLE(addonmanagermodules,
1581   [AS_HELP_STRING([--disable-addonmanagermodules],
1582     [disable the addons manager modules (default enabled)])])
1583 if test "${enable_addonmanagermodules}" != "no"
1584 then
1585   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1586 fi
1587 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1588
1589
1590 dnl
1591 dnl  Input plugins
1592 dnl
1593
1594 EXTEND_HELP_STRING([Input plugins:])
1595
1596 dnl
1597 dnl  libarchive access module
1598 dnl
1599 PKG_ENABLE_MODULES_VLC([ARCHIVE], [access_archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1600
1601 dnl
1602 dnl  live555 input
1603 dnl
1604 AC_ARG_ENABLE(live555,
1605   [AS_HELP_STRING([--enable-live555],
1606     [enable RTSP input through live555 (default enabled)])])
1607
1608 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1609   PKG_CHECK_MODULES(LIVE555, live555, [
1610     VLC_ADD_PLUGIN([live555])
1611     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1612     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1613   ], [
1614     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1615
1616     AC_LANG_PUSH(C++)
1617     VLC_SAVE_FLAGS
1618
1619     dnl detect include paths
1620     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1621       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1622     ], [
1623       AS_IF([test "${SYS}" != "os2"], [
1624         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1625         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1626       ], [
1627         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1628         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1629         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1630       ])
1631     ])
1632
1633     dnl CPP Flags
1634     AS_IF([test "${SYS}" = "solaris"], [
1635       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1636     ])
1637     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1638     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1639
1640     dnl version check
1641     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1642       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1643 [#include <liveMedia_version.hh>
1644 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1645 # error BOOM
1646 #endif]])
1647       ], [
1648         ac_cv_live555="yes"
1649       ], [
1650         ac_cv_live555="no"
1651       ])
1652     ])
1653
1654     AS_IF([test "$ac_cv_live555" = "no"], [
1655       AC_MSG_WARN([live555 is missing or its installed version is too old:
1656 Version 2011.12.23 or later is required to proceed.
1657 You can get an updated one from http://www.live555.com/liveMedia .])
1658       AS_IF([test -n "${enable_live555}"], [
1659         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1660       ])
1661     ], [
1662       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1663       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1664       AS_IF([test "${SYS}" = "mingw32"], [
1665         # add ws2_32 for closesocket, select, recv
1666         other_libs="$other_libs -lws2_32"
1667       ])
1668
1669       dnl We need to check for pic because live555 don't provide shared libs
1670       dnl and we want to build a plugins so we need -fPIC on some arch.
1671       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1672       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1673       AC_CHECK_LIB(liveMedia_pic, main, [
1674         VLC_ADD_PLUGIN([live555])
1675         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1676       ],[
1677         AC_CHECK_LIB(liveMedia, main, [
1678           VLC_ADD_PLUGIN([live555])
1679           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1680         ],[],[${other_libs}])
1681       ],[${other_libs_pic}])
1682     ])
1683     VLC_RESTORE_FLAGS
1684     AC_LANG_POP(C++)
1685   ])
1686 ])
1687
1688 dnl
1689 dnl IIDC and DV FireWire input modules
1690 dnl
1691 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1692 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1693
1694 dnl
1695 dnl - linsys modules: access module check for libzvbi
1696 dnl
1697 AC_ARG_ENABLE(linsys,
1698   [AS_HELP_STRING([--enable-linsys],
1699     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1700 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1701   VLC_ADD_PLUGIN([linsys_hdsdi])
1702   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1703     VLC_ADD_PLUGIN([linsys_sdi])
1704   ], [
1705     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1706   ])
1707 ])
1708
1709 dnl
1710 dnl dvdread module: check for libdvdread
1711 dnl
1712 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1713
1714 dnl
1715 dnl libdvdnav plugin
1716 dnl
1717 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1718
1719 dnl
1720 dnl  Blu-ray Disc Support with libbluray
1721 dnl
1722 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.3.0], (libbluray for Blu-ray disc support ) )
1723
1724 dnl
1725 dnl  OpenCV wrapper and example filters
1726 dnl
1727 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1728
1729
1730 dnl
1731 dnl  libsmbclient plugin
1732 dnl
1733 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1734 AS_IF([test "${SYS}" = "mingw32"], [ VLC_ADD_PLUGIN([access_smb]) ])
1735
1736 dnl
1737 dnl  liBDSM access module
1738 dnl
1739 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.0.3], [libdsm SMB/CIFS access/sd module], [auto])
1740
1741 dnl
1742 dnl sftp access support
1743 dnl
1744 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1745
1746 dnl
1747 dnl  Video4Linux 2
1748 dnl
1749 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1750   [disable Video4Linux version 2 (default auto)])])
1751 have_v4l2="no"
1752 AS_IF([test "$enable_v4l2" != "no"], [
1753   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1754     have_v4l2="yes"
1755   ])
1756 ])
1757 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1758
1759 dnl
1760 dnl special access module for Blackmagic SDI cards
1761 dnl
1762 AC_ARG_ENABLE(decklink,
1763   [AS_HELP_STRING([--disable-decklink],
1764     [disable Blackmagic DeckLink SDI input (default auto)])])
1765 AC_ARG_WITH(decklink_sdk,
1766   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1767     [                        location of Blackmagic DeckLink SDI SDK])])
1768 have_decklink=no
1769 if test "${enable_decklink}" != "no"
1770 then
1771   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1772   then
1773     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1774   fi
1775   VLC_SAVE_FLAGS
1776   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1777   AC_LANG_PUSH(C++)
1778   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1779       have_decklink=yes
1780   ], [
1781       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1782   ])
1783   AC_LANG_POP(C++)
1784   VLC_RESTORE_FLAGS
1785 fi
1786 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1787
1788
1789 dnl
1790 dnl  gnomeVFS access module
1791 dnl
1792 PKG_ENABLE_MODULES_VLC([GNOMEVFS], [gnomevfs], [gnome-vfs-2.0], [GnomeVFS access module], [auto])
1793
1794 dnl
1795 dnl  VCDX modules
1796 dnl
1797 PKG_ENABLE_MODULES_VLC([VCDX], [vcdx], [libcdio >= 0.78.2 libiso9660 >= 0.72 libvcdinfo >= 0.7.22], [navigate VCD with libvcdinfo], [no])
1798
1799 dnl
1800 dnl  Built-in CD-DA and VCD module
1801 dnl
1802 AC_ARG_ENABLE(vcd,
1803   [AS_HELP_STRING([--disable-vcd],
1804     [disable built-in VCD and CD-DA support (default enabled)])])
1805
1806 AC_ARG_ENABLE(libcddb,
1807   [AS_HELP_STRING([--disable-libcddb],
1808     [disable CDDB for Audio CD (default enabled)])])
1809
1810 if test "${enable_vcd}" != "no"
1811 then
1812   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1813   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1814     AC_MSG_RESULT(yes)
1815     VLC_ADD_PLUGIN([vcd cdda])
1816   ],[
1817     AC_MSG_RESULT(no)
1818   ])
1819
1820   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1821   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1822     AC_MSG_RESULT(yes)
1823     VLC_ADD_PLUGIN([vcd cdda])
1824     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1825   ],[
1826     AC_MSG_RESULT(no)
1827   ])
1828
1829   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1830   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1831     AC_MSG_RESULT(yes)
1832     VLC_ADD_PLUGIN([vcd cdda])
1833     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1834   ],[
1835     AC_MSG_RESULT(no)
1836   ])
1837
1838   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1839   then
1840     VLC_ADD_PLUGIN([vcd cdda])
1841   fi
1842
1843   if test "$enable_libcddb" != "no"; then
1844     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1845       HAVE_LIBCDDB=yes
1846       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1847       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1848       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1849       ],:
1850       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1851       HAVE_LIBCDDB=no])
1852   fi
1853 fi
1854
1855 dnl
1856 dnl Linux DVB
1857 dnl
1858 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1859   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1860 [#include <linux/dvb/version.h>
1861 #if (DVB_API_VERSION < 5)
1862 # error Linux DVB API v3.2 and older are not supported.
1863 #endif
1864 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1865 # error Linux DVB API v5.0 is unsupported. Please update.
1866 #endif
1867 ]])], [
1868   ac_cv_linux_dvb_5_1=yes
1869 ], [
1870   ac_cv_linux_dvb_5_1=no
1871 ])])
1872 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1873
1874 dnl
1875 dnl  Screen capture module
1876 dnl
1877 AC_ARG_ENABLE(screen,
1878   [AS_HELP_STRING([--enable-screen],
1879     [disable screen capture (default enabled)])])
1880 if test "${enable_screen}" != "no"; then
1881   if test "${SYS}" = "darwin"; then
1882     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1883       VLC_ADD_PLUGIN([screen])
1884     ])
1885   fi
1886 fi
1887 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1888
1889 dnl
1890 dnl  VNC/RFB access module
1891 dnl
1892 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1893
1894 dnl  RDP/Remote Desktop access module
1895 dnl
1896 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1897
1898 dnl
1899 dnl  Real RTSP plugin
1900 dnl
1901 AC_ARG_ENABLE(realrtsp,
1902   [  --enable-realrtsp       Real RTSP module (default disabled)])
1903 if test "${enable_realrtsp}" = "yes"; then
1904   VLC_ADD_PLUGIN([access_realrtsp])
1905 fi
1906
1907 dnl
1908 dnl MacOS eyeTV
1909 AC_ARG_ENABLE(macosx-eyetv,
1910   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1911 if test "x${enable_macosx_eyetv}" != "xno" &&
1912   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1913 then
1914   VLC_ADD_PLUGIN([access_eyetv])
1915 fi
1916
1917 dnl
1918 dnl QTKit
1919 AC_ARG_ENABLE(macosx-qtkit,
1920   [  --enable-macosx-qtkit Mac OS X qtcapture (video) and qtsound (audio) module (default enabled on Mac OS X)])
1921 if test "x${enable_macosx_qtkit}" != "xno" &&
1922   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1923 then
1924   VLC_ADD_PLUGIN([qtcapture])
1925   VLC_ADD_PLUGIN([qtsound])
1926 fi
1927 AM_CONDITIONAL(HAVE_QTKIT, [test "${SYS}" = "darwin" -a "x${enable_macosx_qtkit}" != "xno"])
1928
1929 dnl
1930 dnl AVFoundation
1931 AC_SUBST(have_avfoundation, ["no"])
1932 AC_ARG_ENABLE(macosx-avfoundation,
1933   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1934 if test "x${enable_macosx_avfoundation}" != "xno" &&
1935   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1936 then
1937   SAVED_LIBS="${LIBS}"
1938   LIBS="-framework AVFoundation"
1939   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1940   LIBS="${SAVED_LIBS}"
1941   if test "${have_avfoundation}" != "no"
1942   then
1943     VLC_ADD_PLUGIN([avcapture])
1944   fi
1945 fi
1946 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
1947
1948 dnl
1949 dnl  DCP plugin (using asdcplib)
1950 dnl
1951 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
1952 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
1953
1954 dnl
1955 dnl  Demux plugins
1956 dnl
1957
1958 EXTEND_HELP_STRING([Mux/Demux plugins:])
1959
1960 dnl
1961 dnl  libdvbpsi check for ts mux/demux
1962 dnl
1963 have_dvbpsi="no"
1964 PKG_WITH_MODULES([DVBPSI], [libdvbpsi], [have_dvbpsi="yes"])
1965 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
1966
1967
1968 dnl
1969 dnl  GME demux plugin
1970 dnl
1971 AC_ARG_ENABLE(gme,
1972   [AS_HELP_STRING([--enable-gme],
1973     [use Game Music Emu (default auto)])])
1974 AS_IF([test "${enable_gme}" != "no"], [
1975   AC_CHECK_HEADER([gme/gme.h], [
1976     VLC_ADD_LIBS([gme], [-lgme])
1977     VLC_ADD_PLUGIN([gme])
1978   ], [
1979     AS_IF([test "x${enable_gme}" != "x"], [
1980       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
1981     ])
1982   ])
1983 ])
1984
1985
1986 dnl
1987 dnl  SIDPlay plugin
1988 dnl
1989 AC_ARG_ENABLE(sid,
1990     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
1991 AS_IF([test "${enable_sid}" != "no"], [
1992     PKG_CHECK_MODULES(SID, [libsidplay2], [
1993         AC_LANG_PUSH(C++)
1994         oldCPPFLAGS="$CPPFLAGS"
1995         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
1996         AC_CHECK_HEADER([sidplay/builders/resid.h], [
1997             VLC_ADD_PLUGIN([sid])
1998             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
1999             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2000         ], [
2001             AS_IF([test -n "${enable_sid}"],
2002                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2003                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2004                 )
2005         ])
2006         CPPFLAGS="$oldCPPFLAGS"
2007         AC_LANG_POP(C++)
2008     ], [
2009         AS_IF([test "x${enable_sid}" = "xyes"],
2010             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2011             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2012             )
2013     ])
2014 ])
2015
2016
2017 dnl
2018 dnl  ogg demux plugin
2019 dnl
2020 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto])
2021 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2022     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2023 ],[true])
2024 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2025 if test "${enable_sout}" != "no"; then
2026     PKG_ENABLE_MODULES_VLC([MUX_OGG], [], [ogg >= 1.0], [Ogg mux support], [auto])
2027 dnl Check for libshout
2028     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2029 fi
2030
2031 dnl
2032 dnl  matroska demux plugin
2033 dnl
2034 AC_ARG_ENABLE(mkv,
2035   [AS_HELP_STRING([--disable-mkv],
2036     [do not use libmatroska (default auto)])])
2037 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2038   AC_LANG_PUSH(C++)
2039   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2040     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2041     AC_EGREP_CPP(yes,
2042       [#include <ebml/EbmlVersion.h>
2043        #ifdef LIBEBML_VERSION
2044        #if LIBEBML_VERSION >= 0x010000
2045        yes
2046        #endif
2047        #endif],
2048       [AC_MSG_RESULT([yes])
2049         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2050           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2051           AC_EGREP_CPP(yes,
2052             [#include <matroska/KaxVersion.h>
2053              #ifdef LIBMATROSKA_VERSION
2054              #if LIBMATROSKA_VERSION >= 0x010000
2055              yes
2056              #endif
2057              #endif],
2058             [AC_MSG_RESULT([yes])
2059               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2060               AC_CHECK_LIB(ebml_pic, main, [
2061                 VLC_ADD_PLUGIN([mkv])
2062                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2063               ],[
2064                 AC_CHECK_LIB(ebml, main, [
2065                   VLC_ADD_PLUGIN([mkv])
2066                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2067                 ])
2068               ])
2069             ], [
2070               AC_MSG_RESULT([no])
2071               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2072           ])
2073         ])
2074       ],
2075       [AC_MSG_RESULT([no])
2076         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2077     ])
2078   ])
2079   AC_LANG_POP(C++)
2080 fi
2081
2082 dnl
2083 dnl  modplug demux plugin
2084 dnl
2085 AC_ARG_ENABLE(mod,
2086   [AS_HELP_STRING([--disable-mod],
2087     [do not use libmodplug (default auto)])])
2088 if test "${enable_mod}" != "no" ; then
2089     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2090           VLC_ADD_PLUGIN([mod])
2091           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2092           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2093           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2094     ],[
2095        AS_IF([test -n "${enable_mod}"],
2096          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2097          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2098     ])
2099 fi
2100
2101 dnl
2102 dnl  mpc demux plugin
2103 dnl
2104 AC_ARG_ENABLE(mpc,
2105   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2106 if test "${enable_mpc}" != "no"
2107 then
2108   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2109     VLC_ADD_PLUGIN([mpc])
2110     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2111     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2112     VLC_ADD_PLUGIN([mpc])
2113     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2114 fi
2115
2116 dnl
2117 dnl  Codec plugins
2118 dnl
2119
2120 EXTEND_HELP_STRING([Codec plugins:])
2121
2122 dnl
2123 dnl wmafixed plugin
2124 dnl
2125 AC_ARG_ENABLE(wma-fixed,
2126   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2127 if test "${enable_wma_fixed}" = "yes"
2128 then
2129   VLC_ADD_PLUGIN([wma_fixed])
2130 fi
2131
2132 dnl
2133 dnl shine encoder plugin
2134 dnl
2135 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2136
2137
2138 dnl
2139 dnl openmax il codec plugin
2140 dnl
2141 AC_ARG_ENABLE(omxil,
2142   [  --enable-omxil          openmax il codec module (default disabled)])
2143 if test "${enable_omxil}" = "yes"
2144 then
2145   VLC_ADD_PLUGIN([omxil])
2146 fi
2147
2148 dnl
2149 dnl openmax il vout plugin
2150 dnl
2151 AC_ARG_ENABLE(omxil-vout,
2152   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2153 if test "${enable_omxil_vout}" = "yes"
2154 then
2155   VLC_ADD_PLUGIN([omxil_vout])
2156 fi
2157
2158 dnl
2159 dnl raspberry pi openmax il configuration
2160 dnl
2161 AC_ARG_ENABLE(rpi-omxil,
2162   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2163 if test "${enable_rpi_omxil}" = "yes"
2164 then
2165   VLC_ADD_PLUGIN([omxil omxil_vout])
2166   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2167 fi
2168
2169 dnl
2170 dnl CrystalHD codec plugin
2171 dnl
2172 AC_ARG_ENABLE(crystalhd,
2173   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2174 if test "${enable_crystalhd}" != "no"; then
2175     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2176       VLC_ADD_PLUGIN([crystalhd])
2177       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2178     ],[
2179       if test "${SYS}" = "mingw32" ; then
2180         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2181           VLC_ADD_PLUGIN([crystalhd])
2182           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2183             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2184             ])
2185         ],[
2186           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2187                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2188                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2189         ],[#define __LINUX_USER__
2190                #include <libcrystalhd/bc_dts_types.h>
2191         ])
2192       fi
2193     ],[
2194        #include <libcrystalhd/bc_dts_types.h>
2195       ])
2196 fi
2197
2198 dnl
2199 dnl  mad plugin
2200 dnl
2201 have_mad="no"
2202 MAD_CFLAGS=""
2203 MAD_LIBS=""
2204
2205 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2206   enable_mad="yes"
2207 ], [
2208   with_mad="no"
2209 ])
2210 AS_IF([test "${with_mad}" != "no"], [
2211   MAD_CFLAGS="-I${with_mad}/include"
2212   MAD_LIBS="-L${with_mad}/lib"
2213 ])
2214
2215 AC_ARG_ENABLE(mad,
2216   [  --enable-mad            libmad module (default enabled)])
2217 AS_IF([test "${enable_mad}" != "no"], [
2218   VLC_SAVE_FLAGS
2219   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2220   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2221   AC_CHECK_HEADERS(mad.h, [
2222     AC_CHECK_LIB(mad, mad_bit_init, [
2223       have_mad="yes"
2224       MAD_LIBS="${MAD_LIBS} -lmad"
2225     ])
2226   ])
2227   VLC_RESTORE_FLAGS
2228   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2229     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2230   ])
2231 ])
2232 AC_SUBST(MAD_CFLAGS)
2233 AC_SUBST(MAD_LIBS)
2234 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2235
2236 dnl  mpg123 plugin
2237 dnl
2238 dnl
2239 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2240
2241
2242 AC_ARG_ENABLE(merge-ffmpeg,
2243 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2244   enable_merge_ffmpeg="no"
2245 ])
2246 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2247
2248 AC_MSG_CHECKING([for libavutil variant])
2249 PKG_CHECK_EXISTS([libavutil], [
2250   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2251   libavutil_micro="${libavutil_version##*.}"
2252   AS_IF([test ${libavutil_micro} -le 99], [
2253     avfork="libav"
2254   ], [
2255     avfork="ffmpeg"
2256   ])
2257 ], [
2258   avfork="none"
2259 ])
2260 AC_MSG_RESULT([${avfork}])
2261
2262 dnl
2263 dnl gstreamer stuff
2264 dnl
2265 AC_ARG_ENABLE(gst-decode,
2266   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2267
2268 have_gst_decode="no"
2269 AS_IF([test "${enable_gst_decode}" != "no"], [
2270   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2271     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2272       have_gst_decode="yes"
2273     ], [
2274       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2275     ])
2276   ], [
2277     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2278   ])
2279 ])
2280 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2281
2282 dnl
2283 dnl  avcodec decoder/encoder plugin
2284 dnl
2285 AC_ARG_ENABLE(avcodec,
2286 [  --enable-avcodec        libavcodec codec (default enabled)])
2287 AS_IF([test "${enable_avcodec}" != "no"], [
2288   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 54.25.0 libavutil >= 52.0.0], [
2289     dnl PKG_CHECK_EXISTS([libavcodec < 56],, [
2290     dnl   AC_MSG_ERROR([libavcodec versions 56 and later are not supported yet.])
2291     dnl ])
2292     VLC_SAVE_FLAGS
2293     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2294     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2295     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2296     AC_CHECK_HEADERS(libavutil/avutil.h)
2297     VLC_RESTORE_FLAGS
2298     have_avcodec="yes"
2299   ],[
2300     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2301   ])
2302 ], [
2303   have_avcodec="no"
2304 ])
2305 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2306
2307 dnl
2308 dnl libva needs avcodec
2309 dnl
2310 AC_ARG_ENABLE(libva,
2311   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2312
2313 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2314   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2315 ])
2316
2317 have_vaapi="no"
2318 have_vaapi_drm="no"
2319 have_vaapi_x11="no"
2320 AS_IF([test "${enable_libva}" != "no"], [
2321   PKG_CHECK_EXISTS([libva], [
2322     have_vaapi="yes"
2323   ], [
2324     AS_IF([test -n "${enable_libva}"], [
2325       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2326     ], [
2327       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2328     ])
2329   ])
2330   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2331     have_vaapi_drm="yes"
2332   ], [
2333     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2334   ])
2335   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2336     have_vaapi_x11="yes"
2337   ], [
2338     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2339   ])
2340 ])
2341 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2342 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2343
2344 have_avcodec_vaapi="no"
2345 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2346   VLC_SAVE_FLAGS
2347   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2348   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2349   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2350     AC_MSG_NOTICE([VAAPI acceleration activated])
2351     have_avcodec_vaapi="yes"
2352   ],[
2353     AS_IF([test -n "${enable_libva}"], [
2354       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2355     ], [
2356       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2357     ])
2358   ])
2359   VLC_RESTORE_FLAGS
2360 ])
2361 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2362
2363 dnl
2364 dnl dxva2 needs avcodec
2365 dnl
2366 AC_ARG_ENABLE(dxva2,
2367   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2368
2369 have_avcodec_dxva2="no"
2370 AS_IF([test "${enable_dxva2}" != "no"], [
2371   if test "${SYS}" = "mingw32"; then
2372   AS_IF([test "x${have_avcodec}" = "xyes"], [
2373     AC_CHECK_HEADERS(dxva2api.h,
2374       [
2375         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2376            AC_MSG_NOTICE([DxVA2 acceleration activated])
2377            have_avcodec_dxva2="yes"
2378         ],[
2379     AS_IF([test "${enable_dxva2}" = "yes"],
2380           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2381               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2382         ], [#undef _WIN32_WINNT
2383             /* DXVA2 is only available in Vista and above */
2384             #define _WIN32_WINNT 0x600])
2385       ],[
2386     AS_IF([test "${enable_dxva2}" = "yes"],
2387               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2388               [AC_MSG_WARN([dxva2api.h not found])])
2389       ])
2390   ],[
2391     AS_IF([test "x${enable_dxva2}" != "x"], [
2392       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2393     ])
2394   ])
2395   fi
2396 ])
2397 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2398
2399 dnl
2400 dnl vda needs avcodec
2401 dnl
2402 AC_ARG_ENABLE(vda,
2403   [  --enable-vda          VDA  support (default auto)])
2404
2405 have_avcodec_vda="no"
2406 AS_IF([test "${enable_vda}" != "no"], [
2407   if test "${SYS}" = "darwin"; then
2408   AS_IF([test "x${have_avcodec}" = "xyes"], [
2409     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2410       [
2411         AC_CHECK_HEADERS(libavcodec/vda.h, [
2412            have_avcodec_vda="yes"
2413         ],[
2414         AS_IF([test "${enable_vda}" = "yes"],
2415               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2416               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2417         ])
2418   ],[
2419         AS_IF([test "${enable_vda}" = "yes"],
2420               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2421               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2422       ])
2423   ],[
2424     AS_IF([test "x${enable_vda}" != "x"], [
2425       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2426     ])
2427  ])
2428  AS_IF([test "${have_avcodec_vda}" = "yes"], [
2429      SAVE_LIBS=$LIBS
2430      LIBS="$LIBS $AVCODEC_LIBS"
2431      AC_CHECK_FUNCS([av_vda_alloc_context])
2432      LIBS=$SAVE_LIBS
2433  ])
2434  fi
2435 ])
2436 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2437
2438 dnl
2439 dnl  avformat demuxer/muxer plugin
2440 dnl
2441
2442 AC_ARG_ENABLE(avformat,
2443 [  --enable-avformat       libavformat containers (default enabled)],, [
2444   enable_avformat="${have_avcodec}"
2445 ])
2446 have_avformat="no"
2447 AS_IF([test "${enable_avformat}" != "no"], [
2448   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2449       have_avformat="yes"
2450       VLC_SAVE_FLAGS
2451       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2452       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2453       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2454       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2455       AC_CHECK_HEADERS(libavutil/avutil.h)
2456       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2457         have_avformat="no"
2458       ])
2459       VLC_RESTORE_FLAGS
2460     ],[
2461       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2462   ])
2463 ])
2464 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2465
2466 dnl
2467 dnl  swscale image scaling and conversion plugin
2468 dnl
2469
2470 AC_ARG_ENABLE(swscale,
2471   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2472           (default enabled)]))
2473 if test "${enable_swscale}" != "no"
2474 then
2475   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2476     [
2477       VLC_SAVE_FLAGS
2478       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2479       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2480       AC_CHECK_HEADERS(libswscale/swscale.h)
2481       AC_CHECK_HEADERS(libavutil/avutil.h)
2482       VLC_ADD_PLUGIN([swscale])
2483       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2484       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2485       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2486         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2487       ])
2488       VLC_RESTORE_FLAGS
2489     ],[
2490       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2491   ])
2492 fi
2493
2494 dnl
2495 dnl  postproc plugin
2496 dnl
2497
2498 AC_ARG_ENABLE(postproc,
2499 [  --enable-postproc       libpostproc image post-processing (default auto)])
2500 if test "${enable_postproc}" != "no"
2501 then
2502   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2503     [
2504       VLC_SAVE_FLAGS
2505       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2506       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2507       AC_CHECK_HEADERS(postproc/postprocess.h)
2508       VLC_ADD_PLUGIN([postproc])
2509       VLC_ADD_LIBS([postproc],[$POSTPROC_LIBS $AVUTIL_LIBS])
2510       VLC_ADD_CFLAGS([postproc],[$POSTPROC_CFLAGS $AVUTIL_CFLAGS])
2511       VLC_RESTORE_FLAGS
2512     ],[
2513       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2514   ])
2515 fi
2516
2517 dnl
2518 dnl  faad decoder plugin
2519 dnl
2520 AC_ARG_ENABLE(faad,
2521 [  --enable-faad           faad codec (default auto)])
2522 have_faad="no"
2523 AS_IF([test "${enable_faad}" != "no"], [
2524   AC_CHECK_HEADERS([faad.h], [
2525     AC_CHECK_LIB(faad, faacDecOpen, [have_faad="yes"],, [$LIBM])
2526     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2527
2528     AS_IF([test "${have_faad}" = "yes"], [
2529       VLC_ADD_PLUGIN([faad])
2530       VLC_ADD_LIBS([faad],[-lfaad])
2531     ], [
2532       AS_IF([test "${enable_faad}" = "yes"], [
2533         AC_MSG_ERROR([cannot find FAAD library])
2534       ], [
2535         AC_MSG_WARN([cannot find FAAD library])
2536       ])
2537     ])
2538   ])
2539 ])
2540
2541 dnl
2542 dnl libvpx decoder plugin
2543 dnl
2544 AC_ARG_ENABLE(vpx,
2545     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 decoder (default auto)]))
2546 AS_IF([test "${enable_vpx}" != "no"],[
2547     PKG_CHECK_MODULES([VPX], [vpx] , [
2548         VLC_ADD_PLUGIN([vpx])
2549         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2550         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2551         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2552             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2553         ], [], [${VPX_LIBS}])
2554         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2555             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2556         ], [], [${VPX_LIBS}])
2557     ], [
2558     AS_IF([test "${enable_vpx}" = "yes"],[
2559         AC_MSG_ERROR([libvpx was not found])
2560     ])])
2561 ])
2562
2563 dnl
2564 dnl twolame encoder plugin
2565 dnl
2566 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2567
2568 dnl
2569 dnl fdk-aac encoder plugin
2570 dnl
2571 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2572
2573 dnl
2574 dnl  QuickTime plugin
2575 dnl
2576 AC_ARG_ENABLE(quicktime,
2577   [  --enable-quicktime      QuickTime module (deprecated)])
2578 if test "${enable_quicktime}" = "yes"; then
2579   if test "${SYS}" = "mingw32"; then
2580     VLC_ADD_PLUGIN([quicktime])
2581   else
2582   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2583     [ VLC_ADD_PLUGIN([quicktime])
2584       VLC_ADD_LIBS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2585     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2586   fi
2587 fi
2588
2589 dnl
2590 dnl A52/AC3 decoder plugin
2591 dnl
2592 AC_ARG_ENABLE(a52,
2593   [  --enable-a52            A/52 support with liba52 (default enabled)])
2594 if test "${enable_a52}" != "no"
2595 then
2596   AC_ARG_WITH(a52,
2597     [  --with-a52=PATH         a52 headers and libraries])
2598     if test -z "${with_a52}"
2599     then
2600       LDFLAGS_test=""
2601       CPPFLAGS_test=""
2602     else
2603       LDFLAGS_test="-L${with_a52}/lib"
2604       CPPFLAGS_test="-I${with_a52}/include"
2605     fi
2606     VLC_SAVE_FLAGS
2607     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2608     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2609     AC_CHECK_HEADERS(a52dec/a52.h, [
2610       AC_CHECK_LIB(a52, a52_free, [
2611         VLC_ADD_PLUGIN([a52tofloat32])
2612         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2613         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2614       ],[
2615         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2616         ], [$LIBM])
2617     ],[
2618       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2619     ])
2620     VLC_RESTORE_FLAGS
2621 fi
2622
2623 dnl
2624 dnl DTS Coherent Acoustics decoder plugin
2625 dnl
2626 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2627
2628 dnl
2629 dnl  Flac plugin
2630 dnl
2631 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2632
2633 dnl
2634 dnl  Libmpeg2 plugin
2635 dnl
2636 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2637
2638 dnl
2639 dnl  Vorbis plugin
2640 dnl
2641 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2642
2643 dnl
2644 dnl  Tremor plugin
2645 dnl
2646 AC_ARG_ENABLE(tremor,
2647   [  --enable-tremor         Tremor decoder support (default disabled)])
2648 if test "${enable_tremor}" = "yes"
2649 then
2650   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2651     VLC_ADD_PLUGIN([tremor])
2652    ],[])
2653 fi
2654
2655 dnl
2656 dnl  Speex plugins
2657 dnl
2658 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2659 have_speexdsp="no"
2660 AS_IF([test "${enable_speex}" != "no"], [
2661   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2662     have_speexdsp="yes"
2663   ], [
2664     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2665   ])
2666 ])
2667 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2668
2669 dnl
2670 dnl  Opus plugin
2671 dnl
2672 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2673
2674 dnl
2675 dnl  theora decoder plugin
2676 dnl
2677 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2678
2679 dnl
2680 dnl  Daala decoder plugin
2681 dnl
2682 PKG_ENABLE_MODULES_VLC([DAALA], [], [ogg daaladec daalaenc], [experimental daala codec], [disabled])
2683
2684 dnl
2685 dnl  schroedinger decoder plugin (for dirac format video)
2686 dnl
2687 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2688
2689 dnl
2690 dnl  PNG decoder module
2691 dnl
2692 AC_ARG_ENABLE(png,
2693   [  --enable-png            PNG support (default enabled)])
2694 AS_IF([test "${enable_png}" != "no"], [
2695 AC_CHECK_HEADERS(png.h, [
2696   VLC_SAVE_FLAGS
2697   LDFLAGS="${LDFLAGS} -lz $LIBM"
2698   AC_CHECK_LIB(png, png_set_rows, [
2699     VLC_ADD_PLUGIN([png])
2700   ], [], [-lz $LIBM])
2701   VLC_RESTORE_FLAGS
2702   ])
2703 ])
2704
2705 dnl
2706 dnl  JPEG decoder module
2707 dnl
2708 AC_ARG_ENABLE(jpeg,
2709   [  --enable-jpeg           JPEG support (default enabled)])
2710 AS_IF([test "${enable_jpeg}" != "no"], [
2711 AC_CHECK_HEADERS(jpeglib.h, [
2712   VLC_ADD_PLUGIN([jpeg])
2713   ])
2714 ])
2715
2716 dnl
2717 dnl  BPG decoder module
2718 dnl
2719 AC_ARG_ENABLE(bpg,
2720   [  --enable-bpg           BPG support (default disabled)])
2721 AS_IF([test "${enable_bpg}" != "no"], [
2722 AC_CHECK_HEADERS(libbpg.h, [
2723   VLC_ADD_PLUGIN([bpg])
2724   ])
2725 ])
2726
2727 dnl
2728 dnl H262 encoder plugin (lib262)
2729 dnl
2730 AC_ARG_ENABLE(x262,
2731   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2732 if test "${enable_x262}" != "no"; then
2733     PKG_CHECK_MODULES(X262, x262, [
2734         VLC_ADD_PLUGIN([x262])
2735         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2736         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2737           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2738         ])
2739         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2740         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2741           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2742         fi
2743     ], [
2744        if test "${enable_x262}" = "yes"; then
2745         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2746        fi
2747     ])
2748 fi
2749
2750 dnl x265 encoder
2751 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2752
2753 dnl
2754 dnl H264 encoder plugin (10-bit lib264)
2755 dnl
2756 AC_ARG_ENABLE(x26410b,
2757   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2758 if test "${enable_x26410b}" != "no"; then
2759     PKG_CHECK_MODULES(X26410B, x26410b, [
2760         VLC_ADD_PLUGIN([x26410b])
2761         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2762         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2763           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2764         ])
2765         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2766         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2767           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2768         fi
2769     ], [
2770        if test "${enable_x26410b}" = "yes"; then
2771         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2772        fi
2773     ])
2774 fi
2775
2776
2777 dnl
2778 dnl H264 encoder plugin (using libx264)
2779 dnl
2780 AC_ARG_ENABLE(x264,
2781   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2782 if test "${enable_x264}" != "no"; then
2783       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2784         VLC_ADD_PLUGIN([x264])
2785         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2786
2787         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2788           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2789         ])
2790
2791         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2792         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2793           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2794         fi
2795       ],[
2796         if test "${enable_x264}" = "yes"; then
2797             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2798           fi
2799       ])
2800 fi
2801
2802 dnl
2803 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2804 dnl
2805 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2806
2807 dnl
2808 dnl libfluidsynth (MIDI synthetizer) plugin
2809 dnl
2810 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2811
2812 dnl
2813 dnl Teletext Modules
2814 dnl vbi decoder plugin (using libzbvi)
2815 dnl telx module
2816 dnl uncompatible
2817 dnl
2818 AC_ARG_ENABLE(zvbi,
2819   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2820                   libzvbi (default enabled)]))
2821 AC_ARG_ENABLE(telx,
2822   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2823                   zvbi) (default enabled if zvbi is absent)]))
2824
2825 AS_IF( [test "${enable_zvbi}" != "no"],[
2826     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2827         [
2828           VLC_ADD_PLUGIN([zvbi])
2829           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2830           AS_IF( [test "${enable_telx}" = "yes"],[
2831                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2832                   ])
2833         ],[
2834           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2835         ])
2836     ])
2837 AS_IF( [test "${enable_telx}" != "no" ],[
2838   VLC_ADD_PLUGIN([telx])
2839   ])
2840
2841 dnl
2842 dnl libass subtitle rendering module
2843 dnl
2844 AC_ARG_ENABLE(libass,
2845   [  --enable-libass         Subtitle support using libass (default enabled)])
2846 AS_IF( [test "${enable_libass}" != "no"], [
2847   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2848       [
2849         VLC_ADD_PLUGIN([libass])
2850
2851         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2852           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2853            VLC_ADD_LIBS([libass],[-lfontconfig])
2854        ])
2855       ],[
2856         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2857       ])
2858   ])
2859
2860 dnl
2861 dnl ARIB subtitles rendering module
2862 dnl
2863 AC_ARG_ENABLE(aribsub,
2864   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2865 AS_IF( [test "${enable_aribsub}" != "no" ],[
2866   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2867       have_aribb24="yes"
2868       VLC_ADD_PLUGIN([aribsub])
2869       VLC_ADD_LIBS([aribsub],[-laribb24])
2870       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2871     ],[
2872       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2873       have_aribb24="no"
2874   ])
2875 ])
2876 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2877
2878 dnl
2879 dnl ARIB B25
2880 dnl
2881 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2882
2883 dnl
2884 dnl  kate decoder plugin
2885 dnl
2886 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2887
2888 dnl
2889 dnl  tiger rendering for kate decoder plugin
2890 dnl
2891 AC_ARG_ENABLE(tiger,
2892 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2893 AS_IF([test "${enable_tiger}" != "no"], [
2894   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2895       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2896         AS_IF([test -n "${enable_tiger}"], [
2897           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2898         ])
2899   ])
2900 ])
2901
2902
2903 dnl
2904 dnl  Video plugins
2905 dnl
2906
2907 EXTEND_HELP_STRING([Video plugins:])
2908
2909 dnl
2910 dnl  OpenGL
2911 dnl
2912 PKG_CHECK_MODULES([EGL], [egl], [
2913   have_egl="yes"
2914 ], [
2915   have_egl="no"
2916 ])
2917 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2918
2919 have_gl="no"
2920 PKG_CHECK_MODULES([GL], [gl], [
2921   have_gl="yes"
2922 ], [
2923   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2924 #ifdef _WIN32
2925 # include <GL/glew.h>
2926 #endif
2927 #include <GL/gl.h>
2928 ]], [
2929     [int t0 = GL_TEXTURE0;]])
2930   ], [
2931     GL_CFLAGS=""
2932     have_gl="yes"
2933     AS_IF([test "${SYS}" != "mingw32"], [
2934       GL_LIBS="-lGL"
2935     ], [
2936       GL_LIBS="-lopengl32"
2937     ])
2938   ])
2939 ])
2940 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
2941
2942 dnl OpenGL ES 2: depends on EGL 1.1
2943 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
2944 dnl OpenGL ES 1: depends on EGL 1.0
2945 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
2946
2947 dnl
2948 dnl  Xlib
2949 dnl
2950
2951 AC_PATH_XTRA()
2952 AC_CHECK_HEADERS(X11/Xlib.h)
2953
2954 dnl
2955 dnl  X C Bindings modules
2956 dnl
2957 AC_ARG_ENABLE(xcb,
2958   [  --enable-xcb            X11 support with XCB (default enabled)],, [
2959   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" -a "${SYS}" != "symbian"], [
2960     enable_xcb="yes"
2961   ], [
2962     enable_xcb="no"
2963   ])
2964 ])
2965 AC_ARG_ENABLE(xvideo,
2966   [  --enable-xvideo         XVideo support (default enabled)],, [
2967     enable_xvideo="$enable_xcb"
2968 ])
2969 AC_ARG_ENABLE(glx,
2970   [  --enable-glx            OpenGL support through GLX (default enabled)],, [
2971   enable_glx="$enable_xcb"
2972 ])
2973
2974 have_xcb="no"
2975 have_xcb_keysyms="no"
2976 have_xcb_randr="no"
2977 have_xcb_xvideo="no"
2978 AS_IF([test "${enable_xcb}" != "no"], [
2979   dnl libxcb
2980   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
2981   have_xcb="yes"
2982   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
2983   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
2984   PKG_CHECK_MODULES(XPROTO, [xproto])
2985
2986   AS_IF([test "${enable_xvideo}" != "no"], [
2987     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
2988   ])
2989
2990   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
2991
2992   dnl xcb-utils
2993   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
2994     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
2995   ])
2996 ])
2997 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
2998 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
2999 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3000 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3001
3002
3003 dnl
3004 dnl VDPAU needs X11
3005 dnl
3006 AC_ARG_ENABLE(vdpau,
3007   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3008 have_vdpau="no"
3009 AS_IF([test "${enable_vdpau}" != "no"], [
3010   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3011     have_vdpau="yes"
3012     AS_IF([test "${no_x}" = "yes"], [
3013       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3014     ])
3015   ], [
3016     AS_IF([test -n "${enable_vdpau}"], [
3017       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3018     ])
3019   ])
3020 ])
3021 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3022
3023 have_avcodec_vdpau="no"
3024 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3025   case "${avfork}" in
3026     libav) av_vdpau_ver="55.26.0" ;;
3027     ffmpeg) av_vdpau_ver="55.42.100" ;;
3028   esac
3029   PKG_CHECK_EXISTS([libavutil >= 52.4.0 libavcodec >= ${av_vdpau_ver}], [
3030     have_avcodec_vdpau="yes"
3031     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3032   ], [
3033     AS_IF([test -n "${enable_vdpau}"], [
3034       AC_MSG_ERROR([libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3035     ], [
3036       AC_MSG_WARN([libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3037     ])
3038   ])
3039 ])
3040 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3041
3042
3043 dnl
3044 dnl  Wayland
3045 dnl
3046 AC_ARG_ENABLE(wayland,
3047   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3048 have_wayland="no"
3049 AC_ARG_VAR([WAYLAND_SCANNER], [Wayland scanner utility])
3050
3051 AS_IF([test "${enable_wayland}" != "no"], [
3052   AC_MSG_CHECKING([for the Wayland scanner])
3053   AS_IF([test -z "$WAYLAND_SCANNER"], [
3054     PKG_CHECK_EXISTS([wayland-scanner], [
3055       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3056     ], [
3057       WAYLAND_SCANNER="wayland-scanner"
3058     ])
3059   ])
3060   AC_MSG_RESULT([$WAYLAND_SCANNER])
3061
3062   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3063     have_wayland="yes"
3064   ], [
3065     AS_IF([test -n "${enable_wayland}"], [
3066       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3067     ])
3068   ])
3069
3070   AS_IF([test "${have_egl}" = "yes"], [
3071     PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3072       have_wayland_egl="yes"
3073     ], [
3074       AS_IF([test -n "${enable_wayland}"], [
3075         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3076       ])
3077     ])
3078   ])
3079 ])
3080 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3081 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3082
3083
3084 dnl
3085 dnl  SDL module
3086 dnl
3087 AC_ARG_ENABLE(sdl,
3088   [  --enable-sdl            SDL support (default enabled)])
3089 AC_ARG_ENABLE(sdl-image,
3090   [  --enable-sdl-image      SDL image support (default enabled)])
3091 if test "${enable_sdl}" != "no"
3092 then
3093    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3094       # SDL on Darwin is heavily patched and can only run SDL_image
3095       if test "${SYS}" != "darwin"; then
3096         VLC_ADD_PLUGIN([vout_sdl])
3097       fi
3098
3099       # SDL_image
3100       AS_IF([ test "${enable_sdl_image}" != "no"],[
3101         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3102           VLC_ADD_PLUGIN([sdl_image])],
3103           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3104           ])
3105       ])
3106    ],[
3107      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3108    ])
3109 fi
3110
3111 dnl
3112 dnl  freetype module
3113 dnl
3114 AC_ARG_ENABLE(freetype,
3115   [  --enable-freetype       freetype support   (default auto)])
3116 AC_ARG_ENABLE(fribidi,
3117   [  --enable-fribidi        fribidi support    (default auto)])
3118 AC_ARG_ENABLE(fontconfig,
3119   [  --enable-fontconfig     fontconfig support (default auto)])
3120
3121 AC_ARG_WITH([default-font],
3122     AS_HELP_STRING([--with-default-font=PATH],
3123         [Path to the default font]),
3124         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3125             "$withval", [Default font])])
3126 AC_ARG_WITH([default-monospace-font],
3127     AS_HELP_STRING([--with-default-monospace-font=PATH],
3128         [Path to the default font]),
3129         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3130             "$withval", [Default monospace font])])
3131
3132 AC_ARG_WITH([default-font-family],
3133     AS_HELP_STRING([--with-default-font-family=NAME],
3134         [Path to the default font family]),
3135         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3136             "$withval", [Default font family])])
3137 AC_ARG_WITH([default-monospace-font-family],
3138     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3139         [Path to the default font family]),
3140         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3141             "$withval", [Default monospace font family])])
3142
3143 if test "${enable_freetype}" != "no"; then
3144    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3145       have_freetype=yes
3146       VLC_ADD_PLUGIN([freetype])
3147       VLC_ADD_CPPFLAGS([freetype skins2],[${FREETYPE_CFLAGS}])
3148       if test "${SYS}" = "mingw32"; then
3149         VLC_ADD_LIBS([freetype],[-liconv -lz])
3150       fi
3151       VLC_ADD_LIBS([freetype skins2],[${FREETYPE_LIBS}])
3152
3153       AC_CHECK_HEADERS(Carbon/Carbon.h,
3154                        [VLC_ADD_LIBS([freetype],[-Wl,-framework,Carbon])])
3155
3156       dnl fontconfig support
3157       if test "${SYS}" != "mingw32"; then
3158           if test "${enable_fontconfig}" != "no"; then
3159             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3160               VLC_ADD_CPPFLAGS([freetype],[-DHAVE_FONTCONFIG])
3161               VLC_ADD_LIBS([freetype],[-lfontconfig])
3162             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3163           fi
3164       else
3165           AS_IF([test "$vlc_winstore_app" != "1"],[
3166             VLC_ADD_LIBS([freetype],[-lgdi32])
3167           ])
3168       fi
3169
3170       dnl fribidi support
3171       if test "${enable_fribidi}" != "no"; then
3172         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3173           VLC_ADD_CPPFLAGS([freetype skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3174           VLC_ADD_LIBS([freetype skins2], [${FRIBIDI_LIBS}])
3175         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional support will be disabled in FreeType.])])
3176       fi
3177
3178   ],[
3179   have_freetype=no
3180   AS_IF([test -n "${enable_freetype}"],[
3181     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3182     ])
3183   ])
3184 fi
3185
3186
3187 dnl
3188 dnl  QuartzText vout module (iOS/Mac OS)
3189 dnl
3190 AC_ARG_ENABLE(macosx-quartztext,
3191   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3192 if test "x${enable_macosx_quartztext}" != "xno" &&
3193   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3194 then
3195   VLC_ADD_PLUGIN([quartztext])
3196   VLC_ADD_LIBS([quartztext],[-Wl,-framework,ApplicationServices])
3197 fi
3198
3199 dnl
3200 dnl  SVG module (text rendering and image decoding)
3201 dnl
3202 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3203 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3204
3205 dnl
3206 dnl  android surface module
3207 dnl
3208 AC_ARG_ENABLE(android-surface,
3209   [  --enable-android-surface   Android Surface video output module (default disabled)])
3210 if test "${enable_android_surface}" = "yes"; then
3211      VLC_ADD_PLUGIN([android_surface])
3212      VLC_ADD_PLUGIN([android_window])
3213 fi
3214
3215 dnl
3216 dnl  Windows DirectX module
3217 dnl
3218
3219 AC_ARG_ENABLE(directx,
3220   [AS_HELP_STRING([--enable-directx],
3221     [Microsoft DirectX support (default enabled on Windows)])],, [
3222   AS_IF([test "${SYS}" = "mingw32"], [
3223     enable_directx="yes"
3224   ], [
3225     enable_directx="no"
3226   ])
3227 ])
3228 have_directx="no"
3229 AS_IF([test "${enable_directx}" != "no"], [
3230   dnl DirectDraw
3231   AC_CHECK_HEADERS(ddraw.h, [
3232     have_directx="yes"
3233   ], [
3234     AC_MSG_ERROR([Cannot find DirectX headers!])
3235   ])
3236
3237   dnl OpenGL
3238   AC_CHECK_HEADERS(GL/wglew.h, [
3239     VLC_ADD_PLUGIN([glwin32])
3240   ],, [
3241     #include <windows.h>
3242     #include <GL/gl.h>
3243   ])
3244
3245   dnl Direct3D
3246   AC_CHECK_HEADERS(d3d9.h, [
3247     VLC_ADD_PLUGIN([direct3d9])
3248   ])
3249
3250   dnl Direct2D
3251   AC_CHECK_HEADERS(d2d1.h, [
3252     VLC_ADD_PLUGIN([direct2d])
3253   ])
3254 ])
3255 AM_CONDITIONAL([HAVE_DIRECTX], [test "$have_directx" = "yes"])
3256
3257 dnl
3258 dnl  Linux framebuffer module
3259 dnl
3260 AC_CHECK_HEADER([linux/fb.h], [
3261   VLC_ADD_PLUGIN([fb])
3262 ])
3263
3264
3265 dnl
3266 dnl  DirectFB module
3267 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3268 dnl  TODO: support for static linking
3269 dnl
3270 AC_ARG_ENABLE(directfb,
3271   [  --enable-directfb       DirectFB support (default disabled)])
3272 AC_ARG_WITH(directfb,
3273   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3274
3275 if test "${enable_directfb}" = "yes"; then
3276     have_directfb="false"
3277     CPPFLAGS_mydirectfb=
3278     LIBS_mydirectfb=
3279     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3280         dnl Trying the given location
3281         VLC_SAVE_FLAGS
3282
3283         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3284         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3285
3286         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3287         LIBS="${LIBS} ${LIBS_new}"
3288
3289         dnl FIXME: too obscure
3290         AC_CHECK_HEADER([directfb.h], [
3291             AC_CHECK_LIB([direct],[direct_initialize], [
3292                 AC_CHECK_LIB([fusion], [fusion_enter], [
3293                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3294                 ], have_directfb="false")
3295             ], have_directfb="false")
3296         ], have_directfb="false")
3297
3298         VLC_RESTORE_FLAGS
3299
3300         if test "${have_directfb}" = "true"; then
3301             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3302             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3303         fi
3304     else
3305         dnl Look for directfb-config
3306         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3307         if test "${DIRECTFB_CONFIG}" != "no"; then
3308             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3309             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3310             have_directfb="true"
3311         else
3312             dnl Trying with pkg-config
3313             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3314                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3315                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3316                 have_directfb="true"
3317                 ], [have_directfb="false"])
3318         fi
3319     fi
3320     if test "${have_directfb}" = "true"; then
3321         VLC_ADD_PLUGIN([directfb])
3322         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3323         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3324     else
3325         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3326     fi
3327 fi
3328
3329 dnl
3330 dnl  AA plugin
3331 dnl
3332 AC_ARG_ENABLE(aa,
3333   [  --enable-aa             aalib output (default disabled)])
3334 if test "${enable_aa}" = "yes"
3335 then
3336   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3337   if test "${have_aa}" = "true"
3338   then
3339     VLC_ADD_PLUGIN([aa])
3340   fi
3341 fi
3342
3343 dnl
3344 dnl  libcaca plugin
3345 dnl
3346 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3347
3348 dnl
3349 dnl  OS/2 KVA plugin
3350 dnl
3351 AC_ARG_ENABLE(kva,
3352   [AS_HELP_STRING([--enable-kva],
3353     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3354   AS_IF([test "$SYS" = "os2"], [
3355     enable_kva="yes"
3356   ])
3357 ])
3358 have_kva="no"
3359 KVA_LIBS=""
3360 AS_IF([test "$enable_kva" != "no"], [
3361   AC_CHECK_HEADERS([kva.h], [
3362     have_kva="yes"
3363     AC_CHECK_LIB(kva, main, [
3364       KVA_LIBS="-lkva"
3365     ])
3366   ])
3367 ])
3368 AC_SUBST(KVA_LIBS)
3369 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3370
3371 dnl
3372 dnl MMAL plugin
3373 dnl
3374 AC_ARG_ENABLE(mmal,
3375   AS_HELP_STRING([--enable-mmal],
3376     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3377 if test "${enable_mmal}" != "no"; then
3378   VLC_SAVE_FLAGS
3379   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3380   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3381   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3382     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3383         have_mmal="yes"
3384         VLC_ADD_PLUGIN([mmal])
3385         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3386         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3387         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3388           AS_IF([test "${enable_mmal}" = "yes"],
3389             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3390             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3391           ],
3392         [])
3393     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3394       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3395       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3396   VLC_RESTORE_FLAGS
3397 fi
3398 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3399
3400 dnl
3401 dnl  Audio plugins
3402 dnl
3403
3404 EXTEND_HELP_STRING([Audio plugins:])
3405
3406 dnl
3407 dnl  Pulseaudio module
3408 dnl
3409 AC_ARG_ENABLE(pulse,
3410   [AS_HELP_STRING([--enable-pulse],
3411     [use the PulseAudio client library (default auto)])])
3412 have_pulse="no"
3413 AS_IF([test "${enable_pulse}" != "no"], [
3414   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3415     have_pulse="yes"
3416   ], [
3417     AS_IF([test "x${enable_pulse}" != "x"], [
3418       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3419     ])
3420   ])
3421 ])
3422 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3423
3424 dnl
3425 dnl  ALSA module
3426 dnl
3427 AC_ARG_ENABLE(alsa,
3428   [AS_HELP_STRING([--enable-alsa],
3429     [support the Advanced Linux Sound Architecture (default auto)])],, [
3430   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3431     enable_alsa="yes"
3432   ])
3433 ])
3434 have_alsa="no"
3435 AS_IF([test "${enable_alsa}" != "no"], [
3436   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3437     have_alsa="yes"
3438   ], [
3439     AS_IF([test "x${enable_alsa}" != "x"], [
3440       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3441     ])
3442   ])
3443 ])
3444 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3445
3446 dnl
3447 dnl  Open Sound System module
3448 dnl
3449 AC_ARG_ENABLE(oss,
3450   [AS_HELP_STRING([--enable-oss],
3451     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3452   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3453     enable_oss="no"
3454   ])
3455 ])
3456 have_oss="no"
3457 OSS_LIBS=""
3458 AS_IF([test "$enable_oss" != "no"], [
3459   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3460     have_oss="yes"
3461     AC_CHECK_LIB(ossaudio, main, [
3462       OSS_LIBS="-lossaudio"
3463     ])
3464   ])
3465 ])
3466 AC_SUBST(OSS_LIBS)
3467 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3468
3469 dnl
3470 dnl  OpenBSD sndio module
3471 dnl
3472 AC_ARG_ENABLE([sndio],
3473   [AS_HELP_STRING([--disable-sndio],
3474     [support the OpenBSD sndio (default auto)])],, [
3475   AS_IF([test "$SYS" = "openbsd"], [
3476     enable_sndio="yes"
3477   ])
3478 ])
3479 have_sndio="no"
3480 AS_IF([test "$enable_sndio" != "no"], [
3481   AC_CHECK_HEADER([sndio.h], [
3482     have_sndio="yes"
3483   ])
3484 ])
3485 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3486
3487 dnl
3488 dnl  Windows Audio Session plugin
3489 dnl
3490 AC_ARG_ENABLE([wasapi],
3491   [AS_HELP_STRING([--enable-wasapi],
3492     [use the Windows Audio Session API (default auto)])
3493 ])
3494 have_wasapi="no"
3495 AS_IF([test "$enable_wasapi" != "no"], [
3496   AC_CHECK_HEADER([audioclient.h], [
3497     have_wasapi="yes"
3498   ], [
3499     AS_IF([test "x${enable_wasapi}" != "x"], [
3500       AC_MSG_ERROR([Windows Audio Session API not found.])
3501     ])
3502   ])
3503 ])
3504 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3505
3506 dnl
3507 dnl  AudioQueue plugin
3508 dnl
3509 AC_ARG_ENABLE(audioqueue,
3510   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3511 if test "${enable_audioqueue}" = "yes"
3512 then
3513   VLC_ADD_PLUGIN([audioqueue])
3514 fi
3515
3516 dnl
3517 dnl  JACK modules
3518 dnl
3519 AC_ARG_ENABLE(jack,
3520   [AS_HELP_STRING([--disable-jack],
3521     [do not use jack (default auto)])])
3522 have_jack="no"
3523 AS_IF([test "${enable_jack}" != "no"], [
3524     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3525       [ have_jack=yes ],
3526       [
3527       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3528
3529       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3530       [ have_jack=yes ],
3531       [
3532       AS_IF([test -n "${enable_jack}"],
3533          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3534          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3535       ])
3536     ])
3537 ])
3538 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3539
3540 dnl
3541 dnl  OpenSLES Android
3542 dnl
3543 AC_ARG_ENABLE(opensles,
3544   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3545 if test "${HAVE_ANDROID}" = "1"; then
3546   if test "${enable_opensles}" = "yes"; then
3547       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3548         [ VLC_ADD_PLUGIN([opensles_android]) ],
3549         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3550   fi
3551 fi
3552
3553 dnl
3554 dnl libsamplerate plugin
3555 dnl
3556 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3557
3558 dnl
3559 dnl  OS/2 KAI plugin
3560 dnl
3561 AC_ARG_ENABLE(kai,
3562   [AS_HELP_STRING([--enable-kai],
3563     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3564   AS_IF([test "$SYS" = "os2"], [
3565     enable_kai="yes"
3566   ])
3567 ])
3568 have_kai="no"
3569 KAI_LIBS=""
3570 AS_IF([test "$enable_kai" != "no"], [
3571   AC_CHECK_HEADERS([kai.h], [
3572     have_kai="yes"
3573     AC_CHECK_LIB(kai, main, [
3574       KAI_LIBS="-lkai"
3575     ])
3576   ])
3577 ])
3578 AC_SUBST(KAI_LIBS)
3579 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3580
3581 dnl
3582 dnl  chromaprint audio track fingerprinter
3583 dnl
3584 m4_pushdef([libchromaprint_version], 0.6.0)
3585 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3586     VLC_ADD_PLUGIN([stream_out_chromaprint])
3587     VLC_ADD_CFLAGS([stream_out_chromaprint],[${CHROMAPRINT_CFLAGS}] [-I./webservices -I../stream_out])
3588     VLC_ADD_LIBS([stream_out_chromaprint],[${CHROMAPRINT_LIBS}]),
3589     AS_IF([test "${enable_chromaprint}" = "yes"],
3590         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3591         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3592          ),
3593     [(Chromaprint based audio fingerprinter)],[auto])
3594 m4_popdef([libchromaprint_version])
3595
3596 dnl
3597 dnl  Chromecast streaming support
3598 dnl
3599 m4_pushdef([protobuf_lite_version], 2.5.0)
3600 AC_ARG_VAR(PROTOC, [protobuf compiler])
3601 AC_PATH_PROGS(PROTOC, protoc, no)
3602 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3603     AS_IF([test "x${PROTOC}" != "xno"], [
3604         VLC_ADD_PLUGIN([stream_out_chromecast])
3605         VLC_ADD_CXXFLAGS([stream_out_chromecast],[${CHROMECAST_CFLAGS}] [-I./chromecast])
3606         VLC_ADD_LIBS([stream_out_chromecast],[${CHROMECAST_LIBS}])
3607         build_chromecast="yes"
3608     ], [
3609     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3610     ])
3611 ], [
3612     AS_IF([test "${enable_chromecast}" = "yes"],
3613         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3614         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3615     )
3616     enable_chromecast="no"
3617 ], [(Chromecast streaming support)], [auto])
3618 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3619 m4_popdef([protobuf_lite_version])
3620
3621 dnl
3622 dnl  Interface plugins
3623 dnl
3624
3625 EXTEND_HELP_STRING([Interface plugins:])
3626
3627 dnl
3628 dnl QT
3629 dnl
3630 AC_ARG_ENABLE(qt, [
3631   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3632   AS_IF([test "${SYS}" = "darwin"], [
3633     enable_qt="no"
3634   ])
3635 ])
3636 AS_IF([test "${enable_qt}" != "no"], [
3637   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.1.0 Qt5Widgets Qt5Gui], [
3638       PKG_CHECK_MODULES([QTX11], [Qt5X11Extras], [
3639           VLC_ADD_LIBS([qt4],[${QTX11_LIBS}])
3640           VLC_ADD_CXXFLAGS([qt4],[${QTX11_CFLAGS} -DQT5_HAS_X11])
3641       ],[
3642           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3643       ])
3644       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3645       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3646       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3647       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3648       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3649     ], [
3650       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.6.0],, [
3651         AS_IF([test -n "${enable_qt}"],[
3652           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3653         ],[
3654           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3655         ])
3656         enable_qt="no"
3657       ])
3658       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3659       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3660       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3661       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3662     ])
3663 ])
3664 AS_IF([test "${enable_qt}" != "no"], [
3665   VLC_ADD_PLUGIN([qt4])
3666   ALIASES="${ALIASES} qvlc"
3667 ])
3668 AM_CONDITIONAL(ENABLE_QT4, [test "$enable_qt" != "no"])
3669
3670 dnl
3671 dnl Simple test for skins2 dependency
3672 dnl
3673 AS_IF([test "$enable_qt" = "no"], [
3674   AS_IF([test "${enable_skins2}" = "yes"], [
3675     AC_MSG_ERROR([The skins2 module depends on the Qt4 interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt4 development package or alternatively you can also configure with: --disable-qt4 --disable-skins2.])
3676   ], [
3677     enable_skins2="no"
3678     AC_MSG_WARN([The skins2 module depends on the Qt4 interface, Qt4 is not built so skins2 is disabled.])
3679   ])
3680 ])
3681
3682 dnl
3683 dnl Skins2 module
3684 dnl
3685 AC_ARG_ENABLE(skins2,
3686   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3687 AS_IF([test "${enable_skins2}" != "no"], [
3688   have_skins_deps="yes"
3689
3690   dnl Win32
3691   AS_IF([test "${SYS}" = "mingw32"], [
3692     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3693     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3694   dnl MacOS
3695   ], [test "${SYS}" = "darwin"], [
3696     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3697     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3698   dnl OS/2
3699   ], [test "${SYS}" = "os2"], [
3700     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3701   dnl Linux/Unix
3702   ], [
3703     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3704     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3705     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3706     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3707     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3708   ])
3709
3710   dnl for All OSes
3711   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3712
3713   dnl we need freetype
3714   AS_IF([test "${have_freetype}" != "yes"], [
3715     have_skins_deps="no"
3716   ])
3717
3718   AS_IF([test "${have_skins_deps}" = "no"], [
3719     AS_IF([test "x${enable_skins2}" = "x"], [
3720       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3721     ], [
3722       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3723     ])
3724     enable_skins2="no"
3725   ], [
3726     VLC_ADD_PLUGIN([skins2])
3727     ALIASES="${ALIASES} svlc"
3728     enable_skins2="yes"
3729   ])
3730 ])
3731 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3732
3733 AC_ARG_ENABLE(libtar,
3734   [  --enable-libtar         libtar support for skins2 (default auto)])
3735 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3736   AC_CHECK_HEADERS(libtar.h, [
3737     VLC_ADD_LIBS([skins2],[-ltar])
3738   ])
3739 ])
3740
3741 dnl
3742 dnl  MacOS X gui module
3743 dnl
3744 AC_ARG_ENABLE(macosx,
3745   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3746 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3747 then
3748   VLC_ADD_LIBS([macosx], [-Wl,-framework,Cocoa -Wl,-framework,Carbon -Wl,-framework,CoreServices])
3749   VLC_ADD_OBJCFLAGS([macosx], [-fobjc-exceptions] )
3750   VLC_ADD_PLUGIN([macosx])
3751
3752   VLC_ADD_LIBS([macosx], [-Wl,-framework,QTKit -Wl,-framework,IOKit -Wl,-framework,AddressBook -Wl,-framework,WebKit -Wl,-framework,CoreAudio -Wl,-framework,SystemConfiguration -Wl,-framework,ScriptingBridge])
3753
3754   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3755   then
3756     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3757   fi
3758   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,Sparkle])
3759   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3760
3761   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3762   then
3763     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3764   fi
3765   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,BGHUDAppKit])
3766   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3767 fi
3768 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3769
3770 dnl
3771 dnl  Minimal Mac OS X module
3772 dnl
3773 AC_ARG_ENABLE(minimal-macosx,
3774   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3775 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3776 then
3777   VLC_ADD_LIBS([minimal_macosx], [-Wl,-framework,Cocoa])
3778   VLC_ADD_OBJCFLAGS([minimal_macosx], [-fobjc-exceptions] )
3779   VLC_ADD_PLUGIN([minimal_macosx])
3780 fi
3781 AM_CONDITIONAL(ENABLE_MINIMAL_MACOSX, [test "$enable_minimal_macosx" != "no"])
3782
3783 dnl
3784 dnl  MacOS X dialog provider
3785 dnl
3786 AC_ARG_ENABLE(macosx-dialog-provider,
3787   [  --enable-macosx-dialog-provider Mac OS X dialog module (default enabled on Mac OS X)])
3788 if test "x${enable_macosx_dialog_provider}" != "xno" &&
3789   (test "${SYS}" = "darwin" || test "${enable_macosx_dialog_provider}" = "yes")
3790 then
3791   VLC_ADD_LIBS([macosx_dialog_provider],[-Wl,-framework,Cocoa])
3792   VLC_ADD_PLUGIN([macosx_dialog_provider])
3793 fi
3794 AM_CONDITIONAL(ENABLE_MACOSX_DIALOG_PROVIDER, [test "$enable_macosx_dialog_provider" != "no"])
3795
3796 dnl
3797 dnl  ncurses module
3798 dnl
3799 AC_ARG_ENABLE(ncurses,
3800 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3801 AS_IF([test "${enable_ncurses}" != "no"] ,[
3802   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3803     VLC_ADD_PLUGIN([ncurses])
3804     VLC_ADD_CFLAGS([ncurses],[${NCURSES_CFLAGS}])
3805     VLC_ADD_LIBS([ncurses],[${NCURSES_LIBS} ${LIBPTHREAD}])
3806     ALIASES="${ALIASES} nvlc"
3807   ], [
3808     AS_IF([test -n "${enable_ncurses}"], [
3809       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3810     ])
3811   ])
3812 ])
3813
3814 dnl
3815 dnl  Lirc plugin
3816 dnl
3817 AC_ARG_ENABLE(lirc,
3818   [  --enable-lirc           lirc support (default disabled)])
3819 if test "${enable_lirc}" = "yes"
3820 then
3821   AC_CHECK_HEADER(lirc/lirc_client.h, AC_CHECK_LIB(lirc_client, lirc_init, have_lirc="true", have_lirc="false"),have_lirc="false")
3822   if test "${have_lirc}" = "true"
3823   then
3824     VLC_ADD_PLUGIN([lirc])
3825     VLC_ADD_LIBS([lirc],[-llirc_client])
3826   fi
3827 fi
3828
3829 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3830 dnl
3831 dnl  goom visualization plugin
3832 dnl
3833 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3834
3835 dnl
3836 dnl libprojectM visualization plugin
3837 dnl
3838 AC_ARG_ENABLE(projectm,
3839   [  --enable-projectm       projectM visualization plugin (default enabled)])
3840 AS_IF([test "${enable_projectm}" != "no"],
3841   [
3842     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3843     [
3844       VLC_ADD_PLUGIN([projectm])
3845       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3846         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3847         [ AC_MSG_WARN( [Using libprojectM version 1] )
3848       ])
3849     ],[
3850       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3851     ])
3852   ])
3853
3854 dnl
3855 dnl Vovoid VSXu visualization plugin
3856 dnl
3857 AC_ARG_ENABLE(vsxu,
3858   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3859 AS_IF([test "${enable_vsxu}" != "no"],
3860   [
3861     PKG_CHECK_MODULES(VSXU, libvsxu,
3862     [
3863       VLC_ADD_PLUGIN([vsxu])
3864       VLC_ADD_CXXFLAGS([vsxu],[$VSXU_CFLAGS])
3865       VLC_ADD_LIBS([vsxu],[$VSXU_LIBS])
3866     ],[
3867       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3868     ])
3869   ])
3870
3871 dnl
3872 dnl  AtmoLight (homemade Philips Ambilight clone)
3873 dnl
3874 AC_ARG_ENABLE(atmo,
3875 AS_HELP_STRING([--disable-atmo],[AtmoLight (homemade Philips Ambilight clone)
3876                 (default enabled)]),, [enable_atmo="yes"])
3877 AS_IF([test "${enable_atmo}" != no], [
3878   AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "linux"], [
3879     AC_LANG_PUSH(C++)
3880     VLC_ADD_PLUGIN([atmo])
3881     AC_LANG_POP(C++)
3882   ])
3883 ])
3884
3885 dnl
3886 dnl  glSpectrum
3887 dnl
3888 AC_ARG_ENABLE(glspectrum,
3889   [  --enable-glspectrum    3D OpenGL spectrum visualization (default auto)])
3890 if test "${enable_glspectrum}" != "no" && test "${have_gl}" = "yes"
3891 then
3892     VLC_ADD_PLUGIN([glspectrum])
3893     VLC_ADD_LIBS([glspectrum],[$GL_LIBS])
3894 fi
3895
3896 EXTEND_HELP_STRING([Service Discovery plugins:])
3897 dnl
3898 dnl  Bonjour services discovery
3899 PKG_ENABLE_MODULES_VLC([BONJOUR], [], [avahi-client >= 0.6], [Bonjour services discovery], [auto])
3900
3901 dnl
3902 dnl  libudev services discovery
3903 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3904
3905 dnl
3906 dnl MTP devices services discovery
3907 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3908
3909 dnl
3910 dnl UPnP Plugin (Intel SDK)
3911 dnl
3912 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3913
3914 EXTEND_HELP_STRING([Misc options:])
3915
3916 dnl
3917 dnl  libxml2 module
3918 dnl
3919 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3920
3921
3922 dnl
3923 dnl libgcrypt
3924 dnl
3925 AC_ARG_ENABLE(libgcrypt,
3926   [  --disable-libgcrypt     gcrypt support (default enabled)])
3927 AS_IF([test "${enable_libgcrypt}" != "no"], [
3928   AC_CHECK_DECL([GCRYCTL_SET_THREAD_CBS], [
3929     libgcrypt-config --version >/dev/null || \
3930         AC_MSG_ERROR([gcrypt.h present but libgcrypt-config could not be found])
3931     AC_CHECK_LIB(gcrypt, gcry_control, [
3932       have_libgcrypt="yes"
3933       GCRYPT_CFLAGS="`libgcrypt-config --cflags`"
3934       GCRYPT_LIBS="`libgcrypt-config --libs`"
3935     ], [
3936       AC_MSG_ERROR([libgcrypt not found. Install libgcrypt or pass --disable-libgcrypt.])
3937     ], [`libgcrypt-config --libs`])
3938   ], [
3939     AC_MSG_ERROR([libgcrypt version 1.1.94 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
3940   ], [#include <gcrypt.h>]
3941   )
3942 ])
3943
3944 AC_SUBST(GCRYPT_CFLAGS)
3945 AC_SUBST(GCRYPT_LIBS)
3946 AM_CONDITIONAL([HAVE_GCRYPT], [test "${have_libgcrypt}" = "yes"])
3947
3948 dnl
3949 dnl TLS/SSL
3950 dnl
3951 AC_ARG_ENABLE(gnutls,
3952   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
3953 AS_IF([test "${enable_gnutls}" != "no"], [
3954   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.2.0], [
3955     VLC_ADD_PLUGIN([gnutls])
3956   ], [
3957     AS_IF([test -n "${enable_gnutls}"], [
3958       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
3959     ])
3960   ])
3961 ])
3962
3963
3964 dnl
3965 dnl Taglib plugin
3966 dnl
3967 AC_ARG_ENABLE(taglib,
3968   [AS_HELP_STRING([--disable-taglib],
3969     [do not use TagLib (default enabled)])])
3970 AS_IF([test "${enable_taglib}" != "no"], [
3971   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
3972     VLC_ADD_PLUGIN([taglib])
3973   ], [
3974     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
3975 ])
3976
3977
3978 dnl
3979 dnl update checking system
3980 dnl
3981 AC_ARG_ENABLE(update-check,
3982   [  --enable-update-check   update checking system (default disabled)])
3983 if test "${enable_update_check}" = "yes"
3984 then
3985   if test "${have_libgcrypt}" != "yes"
3986   then
3987     AC_MSG_ERROR([libgcrypt is required for update checking system])
3988   fi
3989   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
3990   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
3991   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
3992 fi
3993
3994 dnl
3995 dnl Growl notification plugin
3996 dnl
3997 AC_ARG_ENABLE(growl,
3998   [  --enable-growl          growl notification plugin (default disabled)],,
3999   [enable_growl=no])
4000 AS_IF([test "${enable_growl}" != "no"], [
4001     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4002       VLC_ADD_PLUGIN([growl])
4003       VLC_ADD_LIBS([growl], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
4004       VLC_ADD_OBJCFLAGS([growl], [-F${CONTRIB_DIR}])
4005       VLC_ADD_OBJCFLAGS([growl], [-fobjc-exceptions] )
4006     ])
4007   ]
4008 )
4009
4010 dnl
4011 dnl Libnotify notification plugin
4012 dnl
4013 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4014
4015 dnl
4016 dnl  Endianness check
4017 dnl
4018 AC_C_BIGENDIAN
4019 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4020   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4021 ], [
4022   DEFS_BIGENDIAN=""
4023 ])
4024 AC_SUBST(DEFS_BIGENDIAN)
4025
4026 dnl
4027 dnl Where to install KDE solid .desktop
4028 dnl
4029 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
4030 AS_IF([test "x$KDE4_CONFIG" = "x"], [
4031   KDE4_CONFIG="kde4-config"
4032 ])
4033
4034 AC_ARG_WITH(kde-solid,
4035   AS_HELP_STRING([--with-kde-solid=PATH],
4036                  [KDE Solid actions directory (auto)]),, [
4037
4038 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4039   with_kde_solid="yes"
4040 fi
4041 ])
4042 soliddatadir=""
4043 AS_IF([test "${with_kde_solid}" != "no"], [
4044   AS_IF([test "${with_kde_solid}" = "yes"], [
4045     kde4datadir="`${KDE4_CONFIG} --install data`"
4046     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4047     soliddatadir="${kde4datadir}/solid/actions"
4048   ], [
4049     soliddatadir="${with_kde_solid}"
4050   ])
4051 ])
4052 AC_SUBST(soliddatadir)
4053 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4054
4055 EXTEND_HELP_STRING([Components:])
4056
4057 dnl
4058 dnl  the VLC binary
4059 dnl
4060 AC_ARG_ENABLE(vlc,
4061   [  --enable-vlc            build the VLC media player (default enabled)])
4062 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4063
4064 AC_ARG_ENABLE(macosx-vlc-app,
4065   [  --enable-macosx-vlc-app build the VLC media player (default enabled on Mac OS X)])
4066 AM_CONDITIONAL(BUILD_MACOSX_VLC_APP, [test "${enable_macosx_vlc_app}" != "no" &&
4067     (test "${SYS}" = "darwin" || test "${enable_macosx_vlc_app}" = "yes") ])
4068
4069 dnl
4070 dnl  Stuff used by the program
4071 dnl
4072 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4073 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4074 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4075 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4076 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4077 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4078 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4079 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4080 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4081 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4082 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4083 AC_SUBST(COPYRIGHT_MESSAGE)
4084 AC_SUBST(VERSION_MESSAGE)
4085 AC_SUBST(VERSION_MAJOR)
4086 AC_SUBST(VERSION_MINOR)
4087 AC_SUBST(VERSION_REVISION)
4088 AC_SUBST(VERSION_EXTRA)
4089 AC_SUBST(COPYRIGHT_YEARS)
4090 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4091 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4092 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4093 dnl
4094 dnl  Handle substvars that use $(top_srcdir)
4095 dnl
4096 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4097
4098 dnl
4099 dnl  Configuration is finished
4100 dnl
4101 AC_SUBST(SYS)
4102 AC_SUBST(ARCH)
4103 AC_SUBST(ALIASES)
4104 AC_SUBST(ASM)
4105 AC_SUBST(MOC)
4106 AC_SUBST(RCC)
4107 AC_SUBST(UIC)
4108 AC_SUBST(WINDRES)
4109 AC_SUBST(WINE_SDK_PATH)
4110 AC_SUBST(LIBEXT)
4111 AC_SUBST(AM_CPPFLAGS)
4112 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4113 AC_SUBST(FILE_LIBVLCCORE_DLL)
4114 AC_SUBST(FILE_LIBVLC_DLL)
4115
4116 AC_CONFIG_FILES([
4117   Makefile
4118   doc/Makefile
4119   modules/Makefile
4120   m4/Makefile
4121   po/Makefile.in
4122   share/Makefile
4123   compat/Makefile
4124   src/Makefile
4125   lib/Makefile
4126   bin/Makefile
4127   test/Makefile
4128   modules/access_output/Makefile
4129   modules/audio_filter/Makefile
4130   modules/control/Makefile
4131   modules/gui/Makefile
4132   modules/gui/ios_dialog_provider/Makefile
4133   modules/gui/macosx/Makefile
4134   modules/gui/minimal_macosx/Makefile
4135   modules/gui/macosx_dialog_provider/Makefile
4136   modules/gui/qt4/Makefile
4137   modules/gui/skins2/Makefile
4138   modules/mux/Makefile
4139   modules/packetizer/Makefile
4140   modules/stream_out/Makefile
4141   modules/text_renderer/Makefile
4142   modules/video_filter/Makefile
4143   modules/visualization/Makefile
4144   modules/hw/mmal/Makefile
4145 ])
4146
4147 AM_COND_IF([HAVE_WIN32], [
4148   AC_CONFIG_FILES([
4149     extras/package/win32/NSIS/spad.nsi
4150     extras/package/win32/NSIS/vlc.win32.nsi
4151     extras/package/win32/msi/config.wxi
4152   ])
4153 ])
4154
4155 AM_COND_IF([HAVE_DARWIN], [
4156   AC_CONFIG_FILES([
4157     extras/package/macosx/Info.plist
4158     extras/package/macosx/Resources/English.lproj/InfoPlist.strings
4159   ])
4160 ])
4161
4162 dnl Generate makefiles
4163 AC_OUTPUT
4164
4165 dnl Do we have to use make or gmake ?
4166 if make --version 2>&1|grep -q GNU
4167 then
4168     # GNU make, all seems good
4169     MAKE=make
4170 else
4171     # Known GNU make alias (on BSD)
4172     MAKE=gmake
4173 fi
4174 dnl Shortcut to nice compile message
4175 if test -n $SHELL; then
4176   SHELL=${CONFIG_SHELL-/bin/sh}
4177 fi
4178 rm -f compile
4179 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4180 echo "#! $SHELL
4181 rm -f .error\$\$
4182 ERROR=0
4183 export PATH=\"$PATH\" LANG=C
4184 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4185 test -f .error\$\$ && ERROR=1
4186 rm -f .error\$\$
4187 exit \$ERROR" >compile
4188 chmod a+x compile
4189
4190 echo "
4191 libvlc configuration
4192 --------------------
4193 version               : ${VERSION}
4194 system                : ${SYS}
4195 architecture          : ${ARCH}
4196 optimizations         : ${enable_optimizations}"
4197 if test "${enable_vlc}" != "no"; then
4198 echo "vlc aliases           :${ALIASES}"
4199 else
4200 echo "build vlc executable  : no"
4201 fi
4202 echo "
4203 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."