m4/iconv.m4

   1 # iconv.m4 serial 19 (gettext-0.18.2)
   2 dnl Copyright (C) 2000-2002, 2007-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 AC_DEFUN([AM_ICONV_LINKFLAGS_BODY],
  10 [
  11   dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
  12   AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
  13   AC_REQUIRE([AC_LIB_RPATH])
  14
  15   dnl Search for libiconv and define LIBICONV, LTLIBICONV and INCICONV
  16   dnl accordingly.
  17   AC_LIB_LINKFLAGS_BODY([iconv])
  18 ])
  19
  20 AC_DEFUN([AM_ICONV_LINK],
  21 [
  22   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
  23   dnl those with the standalone portable GNU libiconv installed).
  24   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  25
  26   dnl Search for libiconv and define LIBICONV, LTLIBICONV and INCICONV
  27   dnl accordingly.
  28   AC_REQUIRE([AM_ICONV_LINKFLAGS_BODY])
  29
  30   dnl Add $INCICONV to CPPFLAGS before performing the following checks,
  31   dnl because if the user has installed libiconv and not disabled its use
  32   dnl via --without-libiconv-prefix, he wants to use it. The first
  33   dnl AC_LINK_IFELSE will then fail, the second AC_LINK_IFELSE will succeed.
  34   am_save_CPPFLAGS="$CPPFLAGS"
  35   AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCICONV])
  36
  37   AC_CACHE_CHECK([for iconv], [am_cv_func_iconv], [
  38     am_cv_func_iconv="no, consider installing GNU libiconv"
  39     am_cv_lib_iconv=no
  40     AC_LINK_IFELSE(
  41       [AC_LANG_PROGRAM(
  42          [[
  43 #include <stdlib.h>
  44 #include <iconv.h>
  45          ]],
  46          [[iconv_t cd = iconv_open("","");
  47            iconv(cd,NULL,NULL,NULL,NULL);
  48            iconv_close(cd);]])],
  49       [am_cv_func_iconv=yes])
  50     if test "$am_cv_func_iconv" != yes; then
  51       am_save_LIBS="$LIBS"
  52       LIBS="$LIBS $LIBICONV"
  53       AC_LINK_IFELSE(
  54         [AC_LANG_PROGRAM(
  55            [[
  56 #include <stdlib.h>
  57 #include <iconv.h>
  58            ]],
  59            [[iconv_t cd = iconv_open("","");
  60              iconv(cd,NULL,NULL,NULL,NULL);
  61              iconv_close(cd);]])],
  62         [am_cv_lib_iconv=yes]
  63         [am_cv_func_iconv=yes])
  64       LIBS="$am_save_LIBS"
  65     fi
  66   ])
  67   if test "$am_cv_func_iconv" = yes; then
  68     AC_CACHE_CHECK([for working iconv], [am_cv_func_iconv_works], [
  69       dnl This tests against bugs in AIX 5.1, AIX 6.1..7.1, HP-UX 11.11,
  70       dnl Solaris 10.
  71       am_save_LIBS="$LIBS"
  72       if test $am_cv_lib_iconv = yes; then
  73         LIBS="$LIBS $LIBICONV"
  74       fi
  75       am_cv_func_iconv_works=no
  76       for ac_iconv_const in '' 'const'; do
  77         AC_RUN_IFELSE(
  78           [AC_LANG_PROGRAM(
  79              [[
  80 #include <iconv.h>
  81 #include <string.h>
  82
  83 #ifndef ICONV_CONST
  84 # define ICONV_CONST $ac_iconv_const
  85 #endif
  86              ]],
  87              [[int result = 0;
  88   /* Test against AIX 5.1 bug: Failures are not distinguishable from successful
  89      returns.  */
  90   {
  91     iconv_t cd_utf8_to_88591 = iconv_open ("ISO8859-1", "UTF-8");
  92     if (cd_utf8_to_88591 != (iconv_t)(-1))
  93       {
  94         static ICONV_CONST char input[] = "\342\202\254"; /* EURO SIGN */
  95         char buf[10];
  96         ICONV_CONST char *inptr = input;
  97         size_t inbytesleft = strlen (input);
  98         char *outptr = buf;
  99         size_t outbytesleft = sizeof (buf);
 100         size_t res = iconv (cd_utf8_to_88591,
 101                             &inptr, &inbytesleft,
 102                             &outptr, &outbytesleft);
 103         if (res == 0)
 104           result |= 1;
 105         iconv_close (cd_utf8_to_88591);
 106       }
 107   }
 108   /* Test against Solaris 10 bug: Failures are not distinguishable from
 109      successful returns.  */
 110   {
 111     iconv_t cd_ascii_to_88591 = iconv_open ("ISO8859-1", "646");
 112     if (cd_ascii_to_88591 != (iconv_t)(-1))
 113       {
 114         static ICONV_CONST char input[] = "\263";
 115         char buf[10];
 116         ICONV_CONST char *inptr = input;
 117         size_t inbytesleft = strlen (input);
 118         char *outptr = buf;
 119         size_t outbytesleft = sizeof (buf);
 120         size_t res = iconv (cd_ascii_to_88591,
 121                             &inptr, &inbytesleft,
 122                             &outptr, &outbytesleft);
 123         if (res == 0)
 124           result |= 2;
 125         iconv_close (cd_ascii_to_88591);
 126       }
 127   }
 128   /* Test against AIX 6.1..7.1 bug: Buffer overrun.  */
 129   {
 130     iconv_t cd_88591_to_utf8 = iconv_open ("UTF-8", "ISO-8859-1");
 131     if (cd_88591_to_utf8 != (iconv_t)(-1))
 132       {
 133         static ICONV_CONST char input[] = "\304";
 134         static char buf[2] = { (char)0xDE, (char)0xAD };
 135         ICONV_CONST char *inptr = input;
 136         size_t inbytesleft = 1;
 137         char *outptr = buf;
 138         size_t outbytesleft = 1;
 139         size_t res = iconv (cd_88591_to_utf8,
 140                             &inptr, &inbytesleft,
 141                             &outptr, &outbytesleft);
 142         if (res != (size_t)(-1) || outptr - buf > 1 || buf[1] != (char)0xAD)
 143           result |= 4;
 144         iconv_close (cd_88591_to_utf8);
 145       }
 146   }
 147 #if 0 /* This bug could be worked around by the caller.  */
 148   /* Test against HP-UX 11.11 bug: Positive return value instead of 0.  */
 149   {
 150     iconv_t cd_88591_to_utf8 = iconv_open ("utf8", "iso88591");
 151     if (cd_88591_to_utf8 != (iconv_t)(-1))
 152       {
 153         static ICONV_CONST char input[] = "\304rger mit b\366sen B\374bchen ohne Augenma\337";
 154         char buf[50];
 155         ICONV_CONST char *inptr = input;
 156         size_t inbytesleft = strlen (input);
 157         char *outptr = buf;
 158         size_t outbytesleft = sizeof (buf);
 159         size_t res = iconv (cd_88591_to_utf8,
 160                             &inptr, &inbytesleft,
 161                             &outptr, &outbytesleft);
 162         if ((int)res > 0)
 163           result |= 8;
 164         iconv_close (cd_88591_to_utf8);
 165       }
 166   }
 167 #endif
 168 #if 0 /* This test leaks and we do not care about HP-UX. */
 169   /* Test against HP-UX 11.11 bug: No converter from EUC-JP to UTF-8 is
 170      provided.  */
 171   if (/* Try standardized names.  */
 172       iconv_open ("UTF-8", "EUC-JP") == (iconv_t)(-1)
 173       /* Try IRIX, OSF/1 names.  */
 174       && iconv_open ("UTF-8", "eucJP") == (iconv_t)(-1)
 175       /* Try AIX names.  */
 176       && iconv_open ("UTF-8", "IBM-eucJP") == (iconv_t)(-1)
 177       /* Try HP-UX names.  */
 178       && iconv_open ("utf8", "eucJP") == (iconv_t)(-1))
 179     result |= 16;
 180 #endif
 181   return result;
 182 ]])],
 183           [am_cv_func_iconv_works=yes], ,
 184           [case "$host_os" in
 185              aix* | hpux*) am_cv_func_iconv_works="guessing no" ;;
 186              *)            am_cv_func_iconv_works="guessing yes" ;;
 187            esac])
 188         test "$am_cv_func_iconv_works" = no || break
 189       done
 190       LIBS="$am_save_LIBS"
 191     ])
 192     case "$am_cv_func_iconv_works" in
 193       *no) am_func_iconv=no am_cv_lib_iconv=no ;;
 194       *)   am_func_iconv=yes ;;
 195     esac
 196   else
 197     am_func_iconv=no am_cv_lib_iconv=no
 198   fi
 199   if test "$am_func_iconv" = yes; then
 200     AC_DEFINE([HAVE_ICONV], [1],
 201       [Define if you have the iconv() function and it works.])
 202   fi
 203   if test "$am_cv_lib_iconv" = yes; then
 204     AC_MSG_CHECKING([how to link with libiconv])
 205     AC_MSG_RESULT([$LIBICONV])
 206   else
 207     dnl If $LIBICONV didn't lead to a usable library, we don't need $INCICONV
 208     dnl either.
 209     CPPFLAGS="$am_save_CPPFLAGS"
 210     LIBICONV=
 211     LTLIBICONV=
 212   fi
 213   AC_SUBST([LIBICONV])
 214   AC_SUBST([LTLIBICONV])
 215 ])
 216
 217 dnl Define AM_ICONV using AC_DEFUN_ONCE for Autoconf >= 2.64, in order to
 218 dnl avoid warnings like
 219 dnl "warning: AC_REQUIRE: `AM_ICONV' was expanded before it was required".
 220 dnl This is tricky because of the way 'aclocal' is implemented:
 221 dnl - It requires defining an auxiliary macro whose name ends in AC_DEFUN.
 222 dnl   Otherwise aclocal's initial scan pass would miss the macro definition.
 223 dnl - It requires a line break inside the AC_DEFUN_ONCE and AC_DEFUN expansions.
 224 dnl   Otherwise aclocal would emit many "Use of uninitialized value $1"
 225 dnl   warnings.
 226 m4_define([gl_iconv_AC_DEFUN],
 227   m4_version_prereq([2.64],
 228     [[AC_DEFUN_ONCE(
 229         [$1], [$2])]],
 230     [m4_ifdef([gl_00GNULIB],
 231        [[AC_DEFUN_ONCE(
 232            [$1], [$2])]],
 233        [[AC_DEFUN(
 234            [$1], [$2])]])]))
 235 gl_iconv_AC_DEFUN([AM_ICONV],
 236 [
 237   AM_ICONV_LINK
 238   if test "$am_cv_func_iconv" = yes; then
 239     AC_MSG_CHECKING([for iconv declaration])
 240     AC_CACHE_VAL([am_cv_proto_iconv], [
 241       AC_COMPILE_IFELSE(
 242         [AC_LANG_PROGRAM(
 243            [[
 244 #include <stdlib.h>
 245 #include <iconv.h>
 246 extern
 247 #ifdef __cplusplus
 248 "C"
 249 #endif
 250 #if defined(__STDC__) || defined(_MSC_VER) || defined(__cplusplus)
 251 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 252 #else
 253 size_t iconv();
 254 #endif
 255            ]],
 256            [[]])],
 257         [am_cv_proto_iconv_arg1=""],
 258         [am_cv_proto_iconv_arg1="const"])
 259       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 260     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 261     AC_MSG_RESULT([
 262          $am_cv_proto_iconv])
 263     AC_DEFINE_UNQUOTED([ICONV_CONST], [$am_cv_proto_iconv_arg1],
 264       [Define as const if the declaration of iconv() needs const.])
 265     dnl Also substitute ICONV_CONST in the gnulib generated <iconv.h>.
 266     m4_ifdef([gl_ICONV_H_DEFAULTS],
 267       [AC_REQUIRE([gl_ICONV_H_DEFAULTS])
 268        if test -n "$am_cv_proto_iconv_arg1"; then
 269          ICONV_CONST="const"
 270        fi
 271       ])
 272   fi
 273 ])