configure.ac

   1 dnl Autoconf settings for vlc
   2
   3 AC_COPYRIGHT([Copyright 1999-2018 VLC authors and VideoLAN])
   4
   5 AC_INIT(vlc, 4.0.0-dev)
   6 VERSION_MAJOR=4
   7 VERSION_MINOR=0
   8 VERSION_REVISION=0
   9 VERSION_EXTRA=0
  10 VERSION_DEV=dev
  11
  12 PKGDIR="vlc"
  13 AC_SUBST(PKGDIR)
  14
  15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
  16 CODENAME="Otto Chriek"
  17 COPYRIGHT_YEARS="1996-2018"
  18
  19 AC_CONFIG_SRCDIR(src/libvlc.c)
  20 AC_CONFIG_AUX_DIR(autotools)
  21 AC_CONFIG_MACRO_DIR(m4)
  22 AC_CONFIG_LIBOBJ_DIR(compat)
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_PRESERVE_HELP_ORDER
  26
  27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
  28 AC_CONFIG_HEADERS([config.h])
  29
  30 AM_SILENT_RULES([yes])
  31 AM_MAINTAINER_MODE([enable])
  32
  33 dnl
  34 dnl Check for tools
  35 dnl
  36 AC_PROG_CC
  37 AC_USE_SYSTEM_EXTENSIONS
  38 VLC_PROG_CC_C11
  39 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
  40 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
  41 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
  42 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
  43
  44 AC_PROG_CXX
  45 AC_PROG_CPP
  46 AC_PROG_OBJC
  47 AC_PROG_EGREP
  48 AC_PROG_MAKE_SET
  49 AC_PROG_INSTALL
  50 AM_PROG_AS
  51 AC_PROG_LEX
  52 AC_PROG_YACC
  53
  54 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
  55 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
  56 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
  57 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
  58 AS_IF([test "$BUILDCC" = "false"], [
  59   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
  60 ])
  61
  62 dnl Check for compiler properties
  63 AC_C_CONST
  64 AC_C_INLINE
  65 AC_C_RESTRICT
  66 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
  67
  68 dnl Extend the --help string at the current spot.
  69 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
  70
  71 dnl Allow binary package maintainer to pass a custom string to avoid
  72 dnl cache problem
  73 AC_ARG_WITH(binary-version,
  74     AS_HELP_STRING([--with-binary-version=STRING],
  75          [To avoid plugins cache problem between binary version]),[],[])
  76 AS_IF([test -n "${with_binary_version}"],[
  77     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
  78          [Binary specific version])
  79 ])
  80
  81 dnl Prevent clang from accepting unknown flags with a mere warning
  82 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CFLAGS])
  83 AX_APPEND_COMPILE_FLAGS([-Werror=unknown-warning-option -Werror=invalid-command-line-argument], [CXXFLAGS])
  84
  85 dnl
  86 dnl  Check the operating system
  87 dnl
  88 HAVE_WIN64="0"
  89 HAVE_IOS="0"
  90 HAVE_OSX="0"
  91 HAVE_TVOS="0"
  92
  93 case "${host_os}" in
  94   "")
  95     SYS=unknown
  96     ;;
  97   linux*)
  98     SYS=linux
  99     CFLAGS="${CFLAGS} -pthread"
 100     ;;
 101   bsdi*)
 102     SYS=bsdi
 103     CFLAGS="${CFLAGS} -pthread"
 104     ;;
 105   freebsd*)
 106     SYS=freebsd
 107     CFLAGS="${CFLAGS} -pthread"
 108     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
 109     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 110     ac_cv_ld_z_defs=no
 111     ;;
 112   openbsd*)
 113     SYS=openbsd
 114     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
 115     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
 116     ;;
 117   netbsd*)
 118     SYS=netbsd
 119     ;;
 120   dragonfly*)
 121     SYS=dragonfly
 122     ;;
 123   darwin*)
 124
 125     dnl Force gcc "-arch" flag
 126     ARCH_flag=""
 127     case "${host_cpu}" in
 128       i?86)
 129         ARCH_flag="-arch i386"
 130       ;;
 131       ppc64*)
 132         ARCH_flag="-arch ppc64"
 133       ;;
 134       ppc*)
 135         ARCH_flag="-arch ppc"
 136       ;;
 137       x86_64)
 138         ARCH_flag="-arch x86_64"
 139       ;;
 140       arm*)
 141         ac_cv_c_bigendian="no"
 142         ac_cv_c_attribute_packed="no"
 143       ;;
 144     esac
 145
 146     SYS=darwin
 147     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
 148     CXX="${CXX} -stdlib=libc++ -std=c++11"
 149     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
 150     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
 151     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag} -Werror=partial-availability"
 152     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
 153     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
 154     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
 155
 156     AC_EGREP_CPP(yes,
 157             [#import <TargetConditionals.h>
 158              #if TARGET_OS_IPHONE
 159              yes
 160              #endif],
 161              [HAVE_IOS="1"],
 162              [HAVE_OSX="1"])
 163
 164     AC_EGREP_CPP(yes,
 165             [#import <TargetConditionals.h>
 166              #if TARGET_OS_TV
 167              yes
 168              #endif],
 169              [HAVE_TVOS="1"
 170              HAVE_IOS="0"
 171              HAVE_OSX="0"
 172              ],)
 173
 174     dnl
 175     dnl  Handle Mac OS X SDK flags
 176     dnl
 177     AC_ARG_WITH(macosx-sdk,
 178       [AS_HELP_STRING([--with-macosx-sdk=DIR],
 179         [compile using the SDK in DIR])])
 180     if test "${with_macosx_sdk}" != "" ; then
 181         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
 182         CPP="${CPP} -isysroot ${with_macosx_sdk}"
 183         CC="${CC} -isysroot ${with_macosx_sdk}"
 184         CXX="${CXX} -isysroot ${with_macosx_sdk}"
 185         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
 186         LD="${LD} -syslibroot ${with_macosx_sdk}"
 187     fi
 188     AC_ARG_WITH(macosx-version-min,
 189       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
 190         [compile for Mac OS X VERSION and above])])
 191     if test "${with_macosx_version_min}" != "" ; then
 192         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
 193         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
 194         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
 195         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
 196         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
 197     fi
 198     ;;
 199   *mingw32* | *cygwin* | *wince* | *mingwce*)
 200     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
 201     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
 202     CXXFLAGS="${CXXFLAGS} -static-libgcc"
 203     AC_CHECK_TOOL(WINDRES, windres, :)
 204     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
 205     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 206       [[#ifdef _WIN32_WINNT
 207        # error _WIN32_WINNT already defined
 208        #endif
 209       ]],[[;]])
 210     ],[
 211       AC_DEFINE([_WIN32_WINNT], 0x0601, [Define to '0x0601' for Windows 7 APIs.])
 212     ])
 213     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
 214     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 215     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
 216     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
 217     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
 218     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
 219     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
 220     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 221     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
 222     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
 223     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
 224
 225     case "${host_os}" in
 226       *mingw32*)
 227         SYS=mingw32
 228         ;;
 229       *cygwin*)
 230         dnl Check if we are using the mno-cygwin mode in which case we are
 231         dnl actually dealing with a mingw32 compiler.
 232         AC_EGREP_CPP(yes,
 233             [#ifdef _WIN32
 234              yes
 235              #endif],
 236             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
 237         ;;
 238     esac
 239
 240     if test "${SYS}" = "mingw32"; then
 241         # DEP, ASLR, NO SEH
 242         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
 243
 244         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
 245         ac_default_prefix="`pwd`/_win32"
 246         DESTDIR="`pwd`/_win32/"
 247
 248         dnl
 249         dnl NSIS/MSI Installer prefix and WIN64
 250         dnl
 251         case "${host_cpu}" in
 252             amd64|x86_64)
 253                 HAVE_WIN64="1"
 254                 WINDOWS_ARCH="x64"
 255                 PROGRAMFILES="PROGRAMFILES64"
 256                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
 257             ;;
 258             *)
 259                 WINDOWS_ARCH="x86"
 260                 PROGRAMFILES="PROGRAMFILES"
 261             ;;
 262         esac
 263         AC_SUBST(WINDOWS_ARCH)
 264         AC_SUBST(PROGRAMFILES)
 265
 266     fi
 267     ;;
 268   *nto*)
 269     SYS=nto
 270     ;;
 271   solaris*)
 272     SYS=solaris
 273     ;;
 274   hpux*)
 275     SYS=hpux
 276     ;;
 277   *os2*)
 278     SYS=os2
 279     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
 280     AC_LIBOBJ([freeaddrinfo])
 281     AC_LIBOBJ([gai_strerror])
 282     AC_CHECK_FUNCS([if_nametoindex])
 283     ;;
 284   *nacl*)
 285     SYS=nacl
 286     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
 287     AC_LIBOBJ([sigwait])
 288     AC_LIBOBJ([recvmsg])
 289     AC_LIBOBJ([sendmsg])
 290     ;;
 291   *)
 292     SYS="${host_os}"
 293     ;;
 294 esac
 295
 296 dnl WinRT
 297 AC_ARG_ENABLE(winstore_app,
 298      AS_HELP_STRING([--enable-winstore-app],
 299                     [Build targetted for Windows Store apps (default disabled)]))
 300
 301 vlc_winstore_app=0
 302 AS_IF([test "${SYS}" = "mingw32"],[
 303   LIBCOM="-lole32"
 304   AS_IF([test "${enable_winstore_app}" = "yes"], [
 305     vlc_winstore_app=1
 306     LIBCOM=""
 307      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
 308      AC_LIBOBJ([gai_strerror])
 309     ],[])
 310   AC_SUBST(LIBCOM)
 311   ])
 312 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
 313
 314 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
 315 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
 316
 317 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
 318 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
 319 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
 320 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
 321
 322 AM_CONDITIONAL(HAVE_NACL,    test "${SYS}" = "nacl")
 323 AM_CONDITIONAL(HAVE_LIBANL,  test "${HAVE_LIBANL}" = "1")
 324
 325 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
 326 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
 327 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
 328 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
 329
 330 dnl
 331 dnl Sadly autoconf does not think about testing foo.exe when ask to test
 332 dnl for program foo on win32
 333 case "${build_os}" in
 334     cygwin|msys|mingw32)
 335         ac_executable_extensions=".exe"
 336         BUILDEXEEXT=".exe"
 337     ;;
 338     os2*)
 339         BUILDEXEEXT=".exe"
 340     ;;
 341     *)
 342     ;;
 343 esac
 344 AC_SUBST(BUILDEXEEXT)
 345
 346 dnl Android is linux, but a bit different
 347 AS_IF([test "$SYS" = linux],[
 348     AC_MSG_CHECKING([for an Android system])
 349     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 350         [[#ifndef __ANDROID__
 351          # error Not Android
 352          #endif
 353         ]],[[;]])
 354     ],[
 355       HAVE_ANDROID="1"
 356       AC_MSG_RESULT([yes])
 357     ],[
 358       AC_MSG_RESULT([no])
 359     ])
 360 ])
 361 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
 362
 363 dnl Tizen (minimum SDK version: 2.3)
 364 AS_IF([test "$SYS" = linux],[
 365     AC_MSG_CHECKING([for Tizen])
 366     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 367         [[#include <tizen.h>
 368         ]],[[;]])
 369     ],[
 370       HAVE_TIZEN="1"
 371       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
 372       AC_MSG_RESULT([yes])
 373     ],[
 374       AC_MSG_RESULT([no])
 375     ])
 376 ])
 377 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
 378
 379 dnl
 380 dnl  Check for the contrib directory
 381 dnl
 382 AC_ARG_WITH(contrib,
 383   [AS_HELP_STRING([--with-contrib[=DIR]],
 384     [search for 3rd party libraries in DIR/include and DIR/lib])
 385 ])
 386 AC_MSG_CHECKING([for 3rd party libraries path])
 387 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
 388   CONTRIB_DIR="${srcdir}/contrib/${host}"
 389   AS_IF([test ! -d "${CONTRIB_DIR}"], [
 390     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 391     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
 392     AS_IF([test ! -d "${CONTRIB_DIR}"], [
 393       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
 394       CONTRIB_DIR=""
 395       AC_MSG_RESULT([not found])
 396     ])
 397   ])
 398 ], [
 399   AS_IF([test "${with_contrib}" != "no"], [
 400     CONTRIB_DIR="${with_contrib}"
 401   ], [
 402     CONTRIB_DIR=""
 403     AC_MSG_RESULT([disabled])
 404   ])
 405 ])
 406 AS_IF([test -n "${CONTRIB_DIR}"], [
 407   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
 408     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
 409   ], [
 410     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
 411     CONTRIB_DIR=""
 412     AC_MSG_RESULT([not usable])
 413   ])
 414
 415 ])
 416 AS_IF([test -n "${CONTRIB_DIR}"], [
 417   AC_MSG_RESULT([${CONTRIB_DIR}])
 418   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
 419   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
 420   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
 421   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
 422   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
 423   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
 424
 425   AS_IF([test -z "$LUAC"], [
 426     dnl Old contribs mixed cross-tools and cross-compiled executables
 427     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
 428       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
 429     ])
 430
 431     dnl Newer contribs follow usual name space rules
 432     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
 433       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
 434     ])
 435   ])
 436
 437   AS_IF([test "${SYS}" = "darwin"], [
 438     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
 439     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
 440   ])
 441 ], [
 442   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
 443     AC_MSG_ERROR([Third party libraries not found!])
 444   ])
 445 ])
 446 AC_SUBST(CONTRIB_DIR)
 447
 448 dnl Add extras/tools to the PATH
 449 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
 450 AS_IF([test -d "${TOOLS_DIR}"], [
 451     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
 452     export PATH="${TOOLS_DIR}":$PATH
 453 ])
 454
 455 dnl
 456 dnl  Libtool
 457 dnl  It's very bad, but our former custom system was worst
 458 dnl  -- Courmisch
 459 dnl
 460
 461 dnl override platform specific check for dependent libraries
 462 dnl otherwise libtool linking of shared libraries will
 463 dnl fail on anything other than pass_all.
 464 AC_CACHE_VAL(lt_cv_deplibs_check_method,
 465     [lt_cv_deplibs_check_method=pass_all])
 466
 467 LT_INIT([dlopen win32-dll shared disable-static])
 468 LT_LANG([C++])
 469 LT_LANG([Windows Resource])
 470
 471 DOLT
 472
 473 lt_cv_deplibs_check_method=pass_all
 474
 475 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
 476   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
 477 ])
 478
 479 dnl
 480 dnl Gettext stuff
 481 dnl
 482 AM_GNU_GETTEXT_VERSION([0.19.8])
 483 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 484
 485 dnl
 486 dnl Iconv stuff
 487 dnl
 488 AM_ICONV
 489
 490 dnl
 491 dnl checks for mingw
 492 AS_IF([test "${SYS}" = "mingw32"], [
 493
 494 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 495 #if !defined(__MINGW32__)
 496 # error Not compiling with mingw
 497 #endif
 498     ])], [
 499
 500 dnl Check for broken versions of mingw-runtime compatability library
 501     AC_MSG_CHECKING(for broken mingw-runtime)
 502     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 503 #include <_mingw.h>
 504 #if defined(__MINGW64_VERSION_MAJOR)
 505 # if __MINGW64_VERSION_MAJOR < 5
 506 #  error Update your mingw-w64! This one is too old.
 507 # endif
 508 #else
 509 # error You cannot compile with Mingw. Use Mingw-w64!
 510 #endif
 511     ])], [
 512         AC_MSG_RESULT([ok])
 513     ], [
 514         AC_MSG_RESULT([present])
 515         AC_MSG_ERROR([LibVLC requires Mingw-w64 version 5.0 or higher!])
 516     ])
 517
 518     dnl force use of mingw provided c99 *printf over msvcrt
 519     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
 520
 521     dnl Check for the need to include the mingwex lib for mingw32
 522     VLC_SAVE_FLAGS
 523     AC_CHECK_LIB(mingwex,opendir,
 524         AC_CHECK_LIB(mingw32,opendir,,
 525             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
 526     )
 527     VLC_RESTORE_FLAGS
 528     ], [
 529         AC_MSG_RESULT([Not compiling with mingw])
 530     ])
 531
 532     dnl Check for fnative-struct or mms-bitfields support for mingw32
 533     AX_CHECK_COMPILE_FLAG([-mms-bitfields], [
 534         AX_APPEND_FLAG([-mms-bitfields], [CFLAGS])
 535         AX_APPEND_FLAG([-mms-bitfields], [CXXFLAGS])
 536         # Check for the warning flag without "-Wno-", GCC accepts
 537         # -Wno-<anything> for unsupported warnings, which can trigger
 538         # other warnings instead.
 539         AX_CHECK_COMPILE_FLAG([-Wincompatible-ms-struct], [
 540             AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CFLAGS])
 541             AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CXXFLAGS])
 542         ])
 543     ], [
 544         AX_CHECK_COMPILE_FLAG([-fnative-struct], [
 545             AX_APPEND_FLAG([-fnative-struct], [CFLAGS])
 546             AX_APPEND_FLAG([-fnative-struct], [CXXFLAGS])
 547         ])
 548     ])
 549 ])
 550
 551
 552 dnl
 553 dnl Buggy glibc prevention. Purposedly not cached.
 554 dnl See sourceware.org bugs 5058 and 5443.
 555 dnl Ubuntu alone has 20 bug numbers for this...
 556 dnl
 557 AC_MSG_CHECKING(for buggy GNU/libc versions)
 558 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 559 #include <limits.h>
 560 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
 561   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
 562 # error GNU/libc with dcgettext killer bug!
 563 #endif
 564 ])], [
 565   AC_MSG_RESULT([not present])
 566 ], [
 567   AC_MSG_RESULT([found])
 568   AS_IF([test "x${enable_nls}" != "xno"], [
 569     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
 570 work-around for this. Check with your distribution vendor on how to update the
 571 glibc run-time. Alternatively, build with --disable-nls.])
 572   ])
 573 ])
 574
 575 dnl Plugin compilation stuff
 576
 577 VLC_LIBRARY_SUFFIX
 578
 579 dnl Check for system libs needed
 580 need_libc=false
 581
 582 dnl Check for usual libc functions
 583 AC_CHECK_FUNCS([accept4 daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty memalign mkostemp mmap open_memstream newlocale openat pipe2 pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp strptime uselocale])
 584 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir flockfile fsync getdelim getpid lldiv memrchr nrand48 poll recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy tfind timegm timespec_get strverscmp pathconf])
 585 AC_REPLACE_FUNCS([gettimeofday])
 586 AC_CHECK_FUNC(fdatasync,,
 587   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
 588 ])
 589
 590 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
 591
 592 dnl mingw64 implements those as static inline, not functions with C linkage
 593 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
 594 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
 595 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
 596 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
 597
 598 dnl C11 static_assert()
 599 AC_MSG_CHECKING([for static_assert in assert.h])
 600 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
 601 static_assert(1, "The impossible happened.");
 602 ])], [
 603   AC_MSG_RESULT([yes])
 604   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
 605 ], [
 606   AC_MSG_RESULT([no])
 607 ])
 608
 609 # Windows CE does not have strcoll()
 610 AC_FUNC_STRCOLL
 611
 612 dnl Check for non-standard system calls
 613 case "$SYS" in
 614   "linux")
 615     AC_CHECK_FUNCS([eventfd vmsplice sched_getaffinity recvmmsg memfd_create])
 616     ;;
 617   "mingw32")
 618     AC_CHECK_FUNCS([_lock_file])
 619     ;;
 620 esac
 621
 622 AH_BOTTOM([#include <vlc_fixups.h>])
 623
 624 dnl Check for struct pollfd
 625 AC_CHECK_TYPES([struct pollfd],,,
 626 [#include <sys/types.h>
 627 #if HAVE_POLL
 628 # include <poll.h>
 629 #elif defined (_WIN32)
 630 # include <winsock2.h>
 631 #endif
 632 ])
 633
 634 dnl Check for struct timespec
 635 AC_CHECK_TYPES([struct timespec],,,
 636 [#include <time.h>])
 637
 638 dnl Check for max_align_t
 639 AC_CHECK_TYPES([max_align_t],,,
 640 [#include <stddef.h>])
 641
 642 dnl Checks for socket stuff
 643 VLC_SAVE_FLAGS
 644 SOCKET_LIBS=""
 645 AC_SEARCH_LIBS(connect, [socket], [
 646   AS_IF([test "$ac_cv_search_connect" != "none required"], [
 647     SOCKET_LIBS="$ac_cv_search_connect"
 648   ])
 649 ], [
 650   AS_IF([test "${SYS}" = "mingw32"], [
 651     SOCKET_LIBS="-lws2_32 -liphlpapi"
 652   ])
 653 ])
 654
 655 AC_SEARCH_LIBS([inet_pton], [nsl], [
 656  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
 657     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
 658   ])
 659 ],, [${SOCKET_LIBS}])
 660
 661 LIBS="${LIBS} ${SOCKET_LIBS}"
 662 AC_LINK_IFELSE([
 663     AC_LANG_PROGRAM([#ifdef _WIN32
 664         #include <ws2tcpip.h>
 665         #include <windows.h>
 666         # if _WIN32_WINNT < 0x600
 667         #  error Needs vista+
 668         # endif
 669         #else
 670         #include <sys/socket.h>
 671         #include <arpa/inet.h>
 672         #endif], [
 673         char dst[[sizeof(struct in_addr)]];
 674         inet_pton(AF_INET, "127.0.0.1", dst);
 675     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
 676 AC_CHECK_FUNCS([if_nameindex])
 677 VLC_RESTORE_FLAGS
 678 AC_SUBST(SOCKET_LIBS)
 679
 680 dnl Check for socklen_t
 681 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
 682 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
 683 ac_cv_type_socklen_t,
 684 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 685 [#include <sys/types.h>
 686 #ifdef _WIN32
 687 # include <winsock2.h>
 688 # include <ws2tcpip.h>
 689 #else
 690 # include <sys/socket.h>
 691 #endif]], [[socklen_t len; len = 0;]])],
 692 ac_cv_type_socklen_t=yes,
 693 ac_cv_type_socklen_t=no)])
 694 AS_IF([test "$ac_cv_type_socklen_t" = no],
 695  [AC_DEFINE(socklen_t, int)])
 696
 697 dnl Check for struct sockaddr_storage
 698 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 699 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
 700 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
 701   [AC_TRY_COMPILE(
 702     [#include <sys/types.h>
 703      #if defined( _WIN32 )
 704      # include <winsock2.h>
 705      #else
 706      # include <sys/socket.h>
 707      #endif], [struct sockaddr_storage addr;],
 708      ac_cv_struct_sockaddr_storage=yes,
 709      ac_cv_struct_sockaddr_storage=no)])
 710 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
 711   AC_DEFINE(sockaddr_storage, sockaddr)
 712   AC_DEFINE(ss_family, sa_family)
 713 ])
 714
 715 dnl FreeBSD has a gnugetopt library for this:
 716 GNUGETOPT_LIBS=""
 717 AC_CHECK_FUNC(getopt_long,, [
 718   AC_CHECK_LIB([gnugetopt],[getopt_long], [
 719     GNUGETOPT_LIBS="-lgnugetopt"
 720   ])
 721 ])
 722 AC_SUBST(GNUGETOPT_LIBS)
 723
 724 AC_CHECK_LIB(m,cos,[
 725   LIBM="-lm"
 726 ], [
 727   LIBM=""
 728 ])
 729 AC_SUBST(LIBM)
 730
 731 AC_CHECK_LIB(m,lrintf, [
 732   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
 733   VLC_ADD_LIBS([skins2],[-lm])
 734 ])
 735 AC_CHECK_LIB(m,nanf,
 736   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
 737 )
 738 AC_CHECK_LIB(m,sincos, [
 739   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
 740 ], [
 741   AC_LIBOBJ([sincos])
 742 ])
 743
 744 AC_MSG_CHECKING([_Thread_local support])
 745 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
 746                    int main() {}])], [
 747     AC_MSG_RESULT([ok])
 748     AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
 749 ],[ AC_MSG_RESULT([no])])
 750
 751 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
 752 dnl check for its availability explicitely
 753 AC_CHECK_HEADERS([threads.h])
 754
 755 AC_CHECK_LIB([anl],[getaddrinfo_a],[
 756   AC_DEFINE(HAVE_LIBANL, 1, [Define to 1 if you have the anl library])
 757 ])
 758
 759 dnl Check for dynamic plugins
 760 LIBDL=""
 761 have_dynamic_objects="no"
 762 VLC_SAVE_FLAGS
 763 AC_SEARCH_LIBS(dlsym, [dl svld], [
 764   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
 765     LIBDL="$ac_cv_search_dlsym"
 766   ])
 767   have_dynamic_objects="yes"
 768 ])
 769 VLC_RESTORE_FLAGS
 770
 771 # Windows
 772 AS_IF([test "${SYS}" = "mingw32"], [
 773   LIBDL=""
 774   have_dynamic_objects="yes" #assume we can use shared objects
 775 ])
 776
 777 AC_ARG_WITH([libfuzzer],
 778     [AS_HELP_STRING([--with-libfuzzer=DIR],
 779         [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)])],
 780      [],
 781      [with_libfuzzer=no])
 782 AS_VAR_IF(with_libfuzzer, no, [], [
 783     enable_shared=no
 784     enable_static=yes
 785     enable_vlc=no
 786 ])
 787 AM_CONDITIONAL(HAVE_LIBFUZZER, [test "${with_libfuzzer}" != "no"])
 788
 789 AS_IF([test "${enable_shared}" = "no"], [
 790   have_dynamic_objects=no
 791 ])
 792 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
 793
 794 AC_SUBST(LIBDL)
 795
 796 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
 797   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
 798     LIBRT="$ac_cv_search_clock_nanosleep"
 799   ])
 800 ], [
 801   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
 802     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
 803       LIBRT="$ac_cv_search_nanosleep"
 804     ])
 805   ])
 806 ])
 807 AC_SUBST(LIBRT)
 808
 809 dnl
 810 dnl Check for headers
 811 dnl
 812
 813 dnl  POSIX
 814 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
 815 AC_CHECK_HEADERS([net/if.h], [], [],
 816 [
 817 #include <sys/types.h>
 818 #include <sys/socket.h>
 819 ])
 820 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
 821 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
 822
 823 dnl  BSD
 824 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
 825
 826 dnl  GNU/Linux
 827 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
 828
 829 dnl  MacOS
 830 AC_CHECK_HEADERS([xlocale.h])
 831
 832 dnl Check if C++ headers define locale_t
 833 AC_LANG_PUSH(C++)
 834 AC_CACHE_CHECK([if C++ headers define locale_t],
 835   [ac_cv_cxx_locale_t],
 836   [ac_cv_cxx_locale_t=no
 837    AC_TRY_COMPILE([#include <locale>], [locale_t loc;],
 838                     [ac_cv_cxx_locale_t=yes])])
 839 if test "${ac_cv_cxx_locale_t}" != "no"; then
 840   AC_DEFINE(HAVE_CXX_LOCALE_T, 1, Define to 1 if C++ headers define locale_t)
 841 fi
 842 AC_LANG_POP(C++)
 843
 844 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
 845 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
 846 AC_CHECK_TYPE(ssize_t,, [
 847   AC_DEFINE(ssize_t, int)
 848 ])
 849
 850 dnl It seems that autoconf detects pkg-config only during the first
 851 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
 852 dnl it is nested within a conditional block, so it was not working right.
 853 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
 854 AC_ARG_VAR(PKG_CONFIG_PATH,
 855        [Paths where to find .pc not at the default location])
 856 PKG_PROG_PKG_CONFIG()
 857
 858 dnl On some OS we need static linking
 859 AS_IF([test -n "${PKG_CONFIG}" ],[
 860     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
 861         PKG_CONFIG="${PKG_CONFIG} --static"
 862     ])
 863 ])
 864
 865
 866 dnl
 867 dnl Check for zlib.h and -lz if available
 868 dnl
 869 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
 870 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
 871 if test "${have_zlib}" = "yes"
 872 then
 873   VLC_ADD_LIBS([sap],[-lz])
 874 fi
 875
 876
 877 dnl
 878 dnl Domain name i18n support via GNU libidn
 879 dnl
 880 PKG_CHECK_MODULES([IDN], [libidn], [
 881   have_libidn="yes"
 882   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
 883 ], [
 884   have_libidn="no"
 885 ])
 886
 887
 888 dnl Check for dbus
 889 AC_ARG_ENABLE(dbus,
 890   [AS_HELP_STRING([--enable-dbus],
 891     [compile D-Bus message bus support (default enabled)])])
 892 have_dbus="no"
 893 AS_IF([test "${enable_dbus}" != "no"], [
 894   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
 895     have_dbus="yes"
 896   ], [
 897     AS_IF([test -n "${enable_dbus}"], [
 898       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
 899     ], [
 900       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
 901     ])
 902   ])
 903 ])
 904 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
 905
 906
 907 dnl Check for systemd
 908 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
 909   have_systemd="yes"
 910 ], [
 911   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
 912 ])
 913 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
 914
 915
 916 EXTEND_HELP_STRING([Optimization options:])
 917 dnl
 918 dnl  Compiler warnings
 919 dnl
 920
 921 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security -Wduplicated-branches -Wduplicated-cond], [CFLAGS])
 922 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security -Wduplicated-branches -Wduplicated-cond], [CXXFLAGS])
 923
 924 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local -Wmultistatement-macros], [CFLAGS])
 925 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
 926
 927 dnl
 928 dnl  Debugging mode
 929 dnl
 930 AC_ARG_ENABLE(debug,
 931   [AS_HELP_STRING([--enable-debug],
 932     [build with run-time assertions (default disabled)])],,
 933   [enable_debug="no"])
 934 AH_TEMPLATE(NDEBUG,
 935             [Define to 1 if debug code should NOT be compiled])
 936 AS_IF([test "${enable_debug}" != "no"], [
 937   AC_CHECK_HEADERS([valgrind/valgrind.h])
 938 ], [
 939   AC_DEFINE(NDEBUG)
 940 ])
 941
 942 dnl
 943 dnl  Profiling
 944 dnl
 945 AC_ARG_ENABLE(gprof,
 946   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
 947   [enable_gprof="no"])
 948 AS_IF([test "${enable_gprof}" != "no"], [
 949   CFLAGS="${CFLAGS} -pg"
 950   CXXFLAGS="${CXXFLAGS} -pg"
 951   OBJCFLAGS="${OBJCFLAGS} -pg"
 952   LDFLAGS="${LDFLAGS} -pg"
 953 ])
 954
 955 AC_ARG_ENABLE(cprof,
 956   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
 957   [enable_cprof="no"])
 958 AS_IF([test "${enable_gprof}" != "no"], [
 959   CFLAGS="${CFLAGS} -finstrument-functions"
 960   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
 961   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
 962   LDFLAGS="${LDFLAGS} -finstrument-functions"
 963 ])
 964
 965 dnl
 966 dnl  Test coverage
 967 dnl
 968 AC_ARG_ENABLE(coverage,
 969   [AS_HELP_STRING([--enable-coverage],
 970     [build for test coverage (default disabled)])],,
 971   [enable_coverage="no"])
 972 AS_IF([test "${enable_coverage}" != "no"], [
 973   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
 974   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
 975   LDFLAGS="-lgcov ${LDFLAGS}"
 976 ])
 977
 978 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
 979   VLC_SAVE_FLAGS
 980   CFLAGS="${CFLAGS} -fvisibility=hidden"
 981   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
 982   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
 983   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
 984                  [ac_cv_c_visibility_hidden], [
 985     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
 986       ac_cv_c_visibility_hidden=yes
 987     ], [
 988       ac_cv_c_visibility_hidden=no
 989     ])
 990   ])
 991   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
 992 ])
 993
 994 dnl
 995 dnl Sanitizer flags
 996 dnl
 997 AC_ARG_WITH([sanitizer],
 998     [AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
 999         [build with sanitizer flags (default disabled)])],
1000      [],
1001      [with_sanitizer=no])
1002
1003 AS_VAR_IF(with_sanitizer, no, [], [
1004     AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1005         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1006         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1007         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1008     ], [
1009         AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1010     ])
1011     AX_APPEND_FLAG([-g])
1012     AX_APPEND_FLAG([-g], [CXXFLAGS])
1013
1014     AS_IF([test -z "${with_sanitizer##*address*}" ], [
1015        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer -fsanitize=pointer-compare -fsanitize=pointer-subtract])
1016        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer -fsanitize=pointer-compare -fsanitize=pointer-subtract], [CXXFLAGS])
1017     ])
1018     AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1019         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1020         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1021     ])
1022     AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1023         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1024         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1025     ])
1026 ])
1027
1028 dnl
1029 dnl  Enable/disable optimizations
1030 dnl
1031 AC_ARG_ENABLE(optimizations,
1032   [AS_HELP_STRING([--disable-optimizations],
1033     [disable compiler optimizations (default enabled)])],,
1034   [enable_optimizations="yes"])
1035
1036 dnl Check for various optimization flags
1037 AS_IF([test "${enable_optimizations}" != "no"], [
1038
1039   dnl -O3 only in production builds
1040   AS_IF([test "${enable_debug}" = "no"], [
1041     VLC_SAVE_FLAGS
1042     CFLAGS="${CFLAGS} -O3"
1043     CXXFLAGS="${CXXFLAGS} -O3"
1044     OBJCFLAGS="${OBJCFLAGS} -O3"
1045     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1046       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1047         ac_cv_c_o3=yes
1048       ], [
1049         ac_cv_c_o3=no
1050       ])
1051     ])
1052     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1053   ])
1054
1055   dnl Check for fast maths
1056   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1057   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1058
1059 AH_BOTTOM([
1060 #if defined(_MSC_VER) && !defined(__clang__)
1061 # pragma fenv_access(off)
1062 # pragma fp_contract(on)
1063 #elif defined(__GNUC__)
1064 /* Not supported so far */
1065 #else
1066 # pragma STDC FENV_ACCESS OFF
1067 # pragma STDC FP_CONTRACT ON
1068 #endif
1069 ])
1070
1071   dnl Check for -funroll-loops
1072   VLC_SAVE_FLAGS
1073   CFLAGS="${CFLAGS} -funroll-loops"
1074   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1075   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1076   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1077     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1078       ac_cv_c_unroll_loops=yes
1079     ], [
1080       ac_cv_c_unroll_loops=no
1081     ])
1082   ])
1083   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1084
1085   AS_IF([test "$enable_debug" = "no"], [
1086     dnl Check for -fomit-frame-pointer
1087     VLC_SAVE_FLAGS
1088     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1089     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1090     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1091     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1092       [ac_cv_c_omit_frame_pointer], [
1093       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1094         ac_cv_c_omit_frame_pointer=yes
1095       ], [
1096         ac_cv_c_omit_frame_pointer=no
1097       ])
1098     ])
1099     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1100   ])
1101
1102 ])
1103
1104 AC_ARG_ENABLE(ssp, [
1105   AS_HELP_STRING([--disable-ssp],
1106   [disable stack smashing protection (default enabled for optimized builds)])
1107 ],,[enable_ssp="yes"])
1108
1109 AS_IF([test "${enable_ssp}" != "no" -a "${enable_optimizations}" != "no"], [
1110   VLC_SAVE_FLAGS
1111   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1112   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1113   dnl Win32 requires linking to ssp for stack-protection
1114   AS_IF([test "${SYS}" = "mingw32"], [
1115       LDFLAGS="${LDFLAGS} -lssp"
1116       AC_CACHE_CHECK([if linker supports stack protectors], [ac_cv_ld_ssp], [
1117         AC_TRY_LINK([#include <stdio.h>],[char buf[100]; fgets(buf, sizeof(buf), stdin);], [
1118           ac_cv_ld_ssp="yes"
1119         ], [
1120           ac_cv_ld_ssp="no"
1121         ])
1122       ])
1123       AS_IF([test "${ac_cv_ld_ssp}" = "no"], [VLC_RESTORE_FLAGS])
1124   ])
1125 ])
1126
1127 AS_IF([test "${SYS}" = "mingw32"], [
1128     dnl library for BCrypt APIs
1129     AS_IF([test "${vlc_winstore_app}" = 1],
1130           [LDFLAGS="${LDFLAGS} -lbcrypt"])
1131 ])
1132
1133 VLC_SAVE_FLAGS
1134 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1135 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1136   AC_TRY_LINK([],, [
1137     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1138   ], [
1139     ac_cv_ld_bsymbolic=""
1140   ])
1141 ])
1142 VLC_RESTORE_FLAGS
1143 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1144 AC_SUBST(SYMBOLIC_LDFLAGS)
1145
1146 VLC_SAVE_FLAGS
1147 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1148 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1149   AC_TRY_LINK([],, [
1150     ac_cv_ld_z_defs="yes"
1151   ], [
1152     ac_cv_ld_z_defs="no"
1153   ])
1154 ])
1155 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1156
1157 dnl Check for __attribute__((packed))
1158 AC_CACHE_CHECK([for __attribute__((packed))],
1159   [ac_cv_c_attribute_packed],
1160   [ac_cv_c_attribute_packed=no
1161    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1162                     [ac_cv_c_attribute_packed=yes])])
1163 if test "${ac_cv_c_attribute_packed}" != "no"; then
1164   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1165 fi
1166
1167 dnl
1168 dnl  Check the CPU
1169 dnl
1170 case "${host_cpu}" in
1171   "")
1172     ARCH=unknown
1173     ;;
1174   armv*)
1175     ARCH="arm"
1176     host_cpu="arm"
1177     ;;
1178   *)
1179     ARCH="${host_cpu}"
1180     ;;
1181 esac
1182
1183 dnl Check for backtrace() support
1184 AC_CHECK_HEADERS(execinfo.h)
1185 AC_CHECK_FUNCS(backtrace)
1186
1187 dnl
1188 dnl  default modules
1189 dnl
1190 ALIASES="${ALIASES} cvlc rvlc"
1191
1192 dnl
1193 dnl  Accelerated modules
1194 dnl
1195
1196 dnl  Check for fully working MMX intrinsics
1197 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1198 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1199 AC_ARG_ENABLE(mmx,
1200   [AS_HELP_STRING([--disable-mmx],
1201     [disable MMX optimizations (default auto)])],,[
1202   case "${host_cpu}" in
1203     i?86|x86_64)
1204       enable_mmx="yes"
1205       ;;
1206     *)
1207       enable_mmx="no"
1208       ;;
1209   esac
1210 ])
1211 have_mmx="no"
1212 have_mmxext="no"
1213 AS_IF([test "${enable_mmx}" != "no"], [
1214   ARCH="${ARCH} mmx"
1215   VLC_SAVE_FLAGS
1216   CFLAGS="${CFLAGS} -mmmx"
1217   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1218     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1219 [#include <mmintrin.h>
1220 #include <stdint.h>
1221 uint64_t frobzor;]], [
1222 [__m64 a, b, c;
1223 a = b = c = (__m64)frobzor;
1224 a = _mm_slli_pi16(a, 3);
1225 a = _mm_adds_pi16(a, b);
1226 c = _mm_srli_pi16(c, 8);
1227 c = _mm_slli_pi16(c, 3);
1228 b = _mm_adds_pi16(b, c);
1229 a = _mm_unpacklo_pi8(a, b);
1230 frobzor = (uint64_t)a;]])], [
1231       ac_cv_c_mmx_intrinsics=yes
1232     ], [
1233       ac_cv_c_mmx_intrinsics=no
1234     ])
1235   ])
1236   VLC_RESTORE_FLAGS
1237   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1238     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1239   ])
1240
1241   VLC_SAVE_FLAGS
1242   CFLAGS="${CFLAGS} -mmmx"
1243   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1244     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1245 void *p;
1246 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1247 ]])
1248     ], [
1249       ac_cv_mmx_inline=yes
1250     ], [
1251       ac_cv_mmx_inline=no
1252     ])
1253   ])
1254   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1255     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1256     have_mmx="yes"
1257   ])
1258
1259   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1260                  [ac_cv_mmxext_inline], [
1261     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1262 void *p;
1263 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1264 ]])
1265     ], [
1266       ac_cv_mmxext_inline=yes
1267     ], [
1268       ac_cv_mmxext_inline=no
1269     ])
1270   ])
1271   VLC_RESTORE_FLAGS
1272   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1273     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1274     have_mmxext="yes"
1275   ])
1276 ])
1277 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1278 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1279
1280 dnl  Check for fully workin SSE2 intrinsics
1281 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1282 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1283 AC_ARG_ENABLE(sse,
1284   [AS_HELP_STRING([--disable-sse],
1285     [disable SSE (1-4) optimizations (default auto)])],, [
1286   case "${host_cpu}" in
1287     i?86|x86_64)
1288       enable_sse=yes
1289       ;;
1290     *)
1291       enable_sse=no
1292       ;;
1293   esac
1294 ])
1295 have_sse2="no"
1296 AS_IF([test "${enable_sse}" != "no"], [
1297   ARCH="${ARCH} sse sse2"
1298
1299   VLC_SAVE_FLAGS
1300   CFLAGS="${CFLAGS} -msse2"
1301   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1302     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1303 [#include <emmintrin.h>
1304 #include <stdint.h>
1305 uint64_t frobzor;]], [
1306 [__m128i a, b, c;
1307 a = b = c = _mm_set1_epi64((__m64)frobzor);
1308 a = _mm_slli_epi16(a, 3);
1309 a = _mm_adds_epi16(a, b);
1310 c = _mm_srli_epi16(c, 8);
1311 c = _mm_slli_epi16(c, 3);
1312 b = _mm_adds_epi16(b, c);
1313 a = _mm_unpacklo_epi8(a, b);
1314 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1315       ac_cv_c_sse2_intrinsics=yes
1316     ], [
1317       ac_cv_c_sse2_intrinsics=no
1318     ])
1319   ])
1320   VLC_RESTORE_FLAGS
1321   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1322     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1323   ])
1324
1325   VLC_SAVE_FLAGS
1326   CFLAGS="${CFLAGS} -msse"
1327   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1328     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1329 void *p;
1330 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1331 ]])
1332     ], [
1333       ac_cv_sse_inline=yes
1334     ], [
1335       ac_cv_sse_inline=no
1336     ])
1337   ])
1338
1339   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1340     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1341   ])
1342
1343   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1344     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1345 void *p;
1346 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1347 ]])
1348     ], [
1349       ac_cv_sse2_inline=yes
1350     ], [
1351       ac_cv_sse2_inline=no
1352     ])
1353   ])
1354   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1355     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1356     have_sse2="yes"
1357   ])
1358
1359   # SSE3
1360   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1361     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1362 void *p;
1363 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1364 ]])
1365     ], [
1366       ac_cv_sse3_inline=yes
1367     ], [
1368       ac_cv_sse3_inline=no
1369     ])
1370   ])
1371
1372   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1373     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1374   # SSSE3
1375   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1376     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1377 void *p;
1378 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1379 ]])
1380     ], [
1381       ac_cv_ssse3_inline=yes
1382     ], [
1383       ac_cv_ssse3_inline=no
1384     ])
1385   ])
1386
1387   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1388     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1389
1390   # SSE4.1
1391   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1392                  [ac_cv_sse4_1_inline], [
1393     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1394 void *p;
1395 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1396 ]])
1397     ], [
1398       ac_cv_sse4_1_inline=yes
1399     ], [
1400       ac_cv_sse4_1_inline=no
1401     ])
1402   ])
1403
1404   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1405     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1406
1407   # SSE4.2
1408   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1409                  [ac_cv_sse4_2_inline], [
1410     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1411 void *p;
1412 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1413 ]])
1414     ], [
1415       ac_cv_sse4_2_inline=yes
1416     ], [
1417       ac_cv_sse4_2_inline=no
1418     ])
1419   ])
1420
1421   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1422     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1423
1424   # SSE4A
1425   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1426     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1427 void *p;
1428 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1429 ]])
1430     ], [
1431       ac_cv_sse4a_inline=yes
1432     ], [
1433       ac_cv_sse4a_inline=no
1434     ])
1435   ])
1436   VLC_RESTORE_FLAGS
1437   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1438     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1439 ])
1440 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1441
1442 VLC_SAVE_FLAGS
1443 CFLAGS="${CFLAGS} -mmmx"
1444 have_3dnow="no"
1445 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1446   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1447 void *p;
1448 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1449 ]])
1450   ], [
1451     ac_cv_3dnow_inline=yes
1452   ], [
1453     ac_cv_3dnow_inline=no
1454   ])
1455 ])
1456 VLC_RESTORE_FLAGS
1457 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1458   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1459             [Define to 1 if 3D Now! inline assembly is available.])
1460   have_3dnow="yes"
1461 ])
1462 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1463
1464
1465 AC_ARG_ENABLE(neon,
1466   [AS_HELP_STRING([--disable-neon],
1467     [disable NEON optimizations (default auto)])],, [
1468   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1469 ])
1470 AS_IF([test "${enable_neon}" != "no"], [
1471   VLC_SAVE_FLAGS
1472   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1473   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1474     AC_COMPILE_IFELSE([
1475       AC_LANG_PROGRAM(,[[
1476 asm volatile("vqmovun.s64 d0, q1":::"d0");
1477 ]])
1478     ], [
1479       ac_cv_arm_neon="yes"
1480     ], [
1481       ac_cv_arm_neon="no"
1482     ])
1483   ])
1484   VLC_RESTORE_FLAGS
1485 ])
1486 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1487
1488 AC_ARG_ENABLE(arm64,
1489   [AS_HELP_STRING([--disable-arm64],
1490     [disable arm 64-bit optimizations (default auto)])],, [
1491   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1492 ])
1493 AS_IF([test "${enable_arm64}" != "no"], [
1494   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1495     AC_COMPILE_IFELSE([
1496       AC_LANG_PROGRAM(,[[
1497 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1498 ]])
1499     ], [
1500       ac_cv_arm64="yes"
1501     ], [
1502       ac_cv_arm64="no"
1503     ])
1504   ])
1505 ])
1506 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1507
1508
1509 AC_ARG_ENABLE(altivec,
1510   [AS_HELP_STRING([--disable-altivec],
1511     [disable AltiVec optimizations (default auto)])],, [
1512   AS_CASE("${host_cpu}", [powerpc*],
1513         [enable_altivec=yes], [enable_altivec=no])
1514 ])
1515 have_altivec="no"
1516 ALTIVEC_CFLAGS=""
1517 AS_IF([test "${enable_altivec}" = "yes"], [
1518   ARCH="${ARCH} altivec";
1519   VLC_SAVE_FLAGS
1520   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1521     [ac_cv_altivec_inline],
1522     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1523          ac_cv_altivec_inline="yes",
1524          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1525           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1526             [ac_cv_altivec_inline="-Wa,-maltivec"],
1527             ac_cv_altivec_inline=no)
1528          ])])
1529   VLC_RESTORE_FLAGS
1530   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1531     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1532               [Define to 1 if AltiVec inline assembly is available.])
1533     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1534       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1535       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1536     ])
1537     have_altivec="yes"
1538   ])
1539
1540   VLC_SAVE_FLAGS
1541   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1542   [ac_cv_c_altivec], [
1543     CFLAGS="${CFLAGS} -maltivec"
1544     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1545 [#include <altivec.h>]], [
1546 [vec_ld(0, (unsigned char *)0);]])], [
1547       ac_cv_c_altivec="-maltivec"
1548     ], [
1549       ac_cv_c_altivec="no"
1550     ])
1551   ])
1552   VLC_RESTORE_FLAGS
1553   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1554     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1555     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1556     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1557     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1558     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1559     have_altivec="yes"
1560   ])
1561   AC_CHECK_HEADERS(altivec.h)
1562
1563   VLC_SAVE_FLAGS
1564   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1565   AC_CACHE_CHECK([if linker needs -framework vecLib],
1566     [ac_cv_ld_altivec],
1567     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1568   VLC_RESTORE_FLAGS
1569   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1570     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1571   ])
1572 ])
1573 AC_SUBST(ALTIVEC_CFLAGS)
1574 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1575
1576 dnl
1577 dnl  Memory usage
1578 dnl
1579 AC_ARG_ENABLE(optimize-memory,
1580   [AS_HELP_STRING([--enable-optimize-memory],
1581     [optimize memory usage over performance])])
1582 if test "${enable_optimize_memory}" = "yes"; then
1583   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1584 fi
1585
1586 dnl
1587 dnl Allow running as root (useful for people running on embedded platforms)
1588 dnl
1589 AC_ARG_ENABLE(run-as-root,
1590   [AS_HELP_STRING([--enable-run-as-root],
1591     [allow running VLC as root (default disabled)])])
1592 AS_IF([test "${enable_run_as_root}" = "yes"],[
1593     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1594               [Define to 1 to allow running VLC as root (uid 0).])
1595 ])
1596
1597 dnl
1598 dnl Stream output
1599 dnl
1600 AC_ARG_ENABLE(sout,
1601   [AS_HELP_STRING([--disable-sout],
1602     [disable streaming output (default enabled)])])
1603 AS_IF([test "${enable_sout}" != "no"], [
1604   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1605 ])
1606 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1607
1608 dnl Lua modules
1609 AC_ARG_ENABLE(lua,
1610   [AS_HELP_STRING([--disable-lua],
1611     [disable LUA scripting support (default enabled)])])
1612 if test "${enable_lua}" != "no"
1613 then
1614   PKG_CHECK_MODULES(LUA, lua5.2,
1615     [ have_lua=yes ],
1616     [
1617     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1618
1619     PKG_CHECK_MODULES(LUA, lua5.1,
1620       [ have_lua=yes ],
1621       [
1622       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1623       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1624         [ have_lua=yes ],
1625         [
1626           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1627           have_lua=yes
1628           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1629             [],
1630             [ have_lua=no ] )
1631           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1632             [LUA_LIBS="-llua5.2"],
1633           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1634             [LUA_LIBS="-llua5.1"],
1635             AC_CHECK_LIB( lua51 , luaL_newstate,
1636               [LUA_LIBS="-llua51"],
1637               AC_CHECK_LIB( lua , luaL_newstate,
1638                 [LUA_LIBS="-llua"],
1639                 [ have_lua=no
1640                 ], [-lm])
1641             )))
1642         ])
1643       ])
1644     ])
1645   if test "x${have_lua}" != "xyes" ;  then
1646       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1647   fi
1648   AC_ARG_VAR([LUAC], [LUA byte compiler])
1649   AS_IF([test -z "$LUAC"], [
1650      AC_CHECK_TOOL(LUAC, [luac], [false])
1651   ])
1652   AS_IF([test "${LUAC}" = "false"], [
1653     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1654   ])
1655   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1656     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1657   ])
1658 fi
1659 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1660
1661
1662 dnl
1663 dnl VideoLAN manager
1664 dnl
1665 AC_ARG_ENABLE(vlm,
1666   [AS_HELP_STRING([--disable-vlm],
1667     [disable the stream manager (default enabled)])],,
1668   [enable_vlm="${enable_sout}"])
1669 AS_IF([test "${enable_vlm}" != "no"], [
1670   AS_IF([test "${enable_sout}" = "no"], [
1671     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1672   ])
1673   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1674 ])
1675 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1676
1677
1678 dnl
1679 dnl Addons manager storage and repositories modules
1680 dnl
1681 AC_ARG_ENABLE(addonmanagermodules,
1682   [AS_HELP_STRING([--disable-addonmanagermodules],
1683     [disable the addons manager modules (default enabled)])])
1684 if test "${enable_addonmanagermodules}" != "no"
1685 then
1686   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1687 fi
1688 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1689
1690
1691 dnl
1692 dnl  Input plugins
1693 dnl
1694
1695 EXTEND_HELP_STRING([Input plugins:])
1696
1697 dnl
1698 dnl  libarchive access module
1699 dnl
1700 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1701
1702 dnl
1703 dnl  live555 input
1704 dnl
1705 AC_ARG_ENABLE(live555,
1706   [AS_HELP_STRING([--enable-live555],
1707     [enable RTSP input through live555 (default enabled)])])
1708
1709 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1710   PKG_CHECK_MODULES(LIVE555, live555, [
1711     VLC_ADD_PLUGIN([live555])
1712     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1713     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1714   ], [
1715     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1716
1717     AC_LANG_PUSH(C++)
1718     VLC_SAVE_FLAGS
1719
1720     dnl detect include paths
1721     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
1722       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1723     ], [
1724       AS_IF([test "${SYS}" != "os2"], [
1725         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1726         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1727       ], [
1728         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1729         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1730         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1731       ])
1732     ])
1733
1734     dnl CPP Flags
1735     AS_IF([test "${SYS}" = "solaris"], [
1736       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1737     ])
1738     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1739     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1740
1741     dnl version check
1742     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1743       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1744 [#include <liveMedia_version.hh>
1745 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1746 # error BOOM
1747 #endif]])
1748       ], [
1749         ac_cv_live555="yes"
1750       ], [
1751         ac_cv_live555="no"
1752       ])
1753     ])
1754
1755     AS_IF([test "$ac_cv_live555" = "no"], [
1756       AC_MSG_WARN([live555 is missing or its installed version is too old:
1757 Version 2011.12.23 or later is required to proceed.
1758 You can get an updated one from http://www.live555.com/liveMedia .])
1759       AS_IF([test -n "${enable_live555}"], [
1760         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1761       ])
1762     ], [
1763       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1764       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1765       AS_IF([test "${SYS}" = "mingw32"], [
1766         # add ws2_32 for closesocket, select, recv
1767         other_libs="$other_libs -lws2_32"
1768       ])
1769
1770       dnl We need to check for pic because live555 don't provide shared libs
1771       dnl and we want to build a plugins so we need -fPIC on some arch.
1772       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1773       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1774       AC_CHECK_LIB(liveMedia_pic, main, [
1775         VLC_ADD_PLUGIN([live555])
1776         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1777       ],[
1778         AC_CHECK_LIB(liveMedia, main, [
1779           VLC_ADD_PLUGIN([live555])
1780           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1781         ],[],[${other_libs}])
1782       ],[${other_libs_pic}])
1783     ])
1784     VLC_RESTORE_FLAGS
1785     AC_LANG_POP(C++)
1786   ])
1787 ])
1788
1789 dnl
1790 dnl IIDC and DV FireWire input modules
1791 dnl
1792 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1793 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1794
1795 dnl
1796 dnl - linsys modules: access module check for libzvbi
1797 dnl
1798 AC_ARG_ENABLE(linsys,
1799   [AS_HELP_STRING([--enable-linsys],
1800     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1801 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1802   VLC_ADD_PLUGIN([linsys_hdsdi])
1803   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1804     VLC_ADD_PLUGIN([linsys_sdi])
1805   ], [
1806     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1807   ])
1808 ])
1809
1810 dnl
1811 dnl dvdread module: check for libdvdread
1812 dnl
1813 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1814
1815 dnl
1816 dnl libdvdnav plugin
1817 dnl
1818 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1819 AS_IF([test "${enable_dvdnav}" != "no"], [
1820   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1821     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1822       AC_MSG_RESULT(yes)
1823       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1824       ],[
1825       AC_MSG_RESULT(no)
1826     ])
1827 ])
1828
1829 dnl
1830 dnl  Blu-ray Disc Support with libbluray
1831 dnl
1832 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1833
1834 dnl
1835 dnl  OpenCV wrapper and example filters
1836 dnl
1837 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1838
1839
1840 dnl
1841 dnl  libsmbclient plugin
1842 dnl
1843 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smbc], [smbclient], (SMB/CIFS support), [auto])
1844
1845 dnl
1846 dnl  liBDSM access module
1847 dnl
1848 AM_CONDITIONAL(HAVE_DSM, [test "$AS_TR_SH(with_dsm)" = "yes"])
1849 PKG_WITH_MODULES([DSM], [libdsm >= 0.2.0], [
1850        VLC_ADD_PLUGIN([dsm])
1851        VLC_ADD_CFLAGS([dsm], [$DSM_CFLAGS])
1852        VLC_ADD_LIBS([dsm], [$DSM_LIBS])
1853        have_dsm="yes"
1854    ],,[libdsm SMB/CIFS access/sd module], [auto])
1855 AM_CONDITIONAL([HAVE_DSM], [test "${have_dsm}" = "yes"])
1856
1857 dnl
1858 dnl sftp access support
1859 dnl
1860 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1861
1862 dnl
1863 dnl nfs access support
1864 dnl
1865 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1866
1867 dnl
1868 dnl smb2 access support
1869 dnl
1870 PKG_ENABLE_MODULES_VLC([SMB2], [smb2], [libsmb2 >= 2.0.0], (support smb2 protocol via libsmb2), [auto])
1871
1872 dnl
1873 dnl  Video4Linux 2
1874 dnl
1875 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1876   [disable Video4Linux version 2 (default auto)])])
1877 have_v4l2="no"
1878 AS_IF([test "$enable_v4l2" != "no"], [
1879   AC_CHECK_HEADERS([linux/videodev2.h], [
1880     have_v4l2="yes"
1881   ])
1882 ])
1883 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1884
1885 dnl
1886 dnl special access module for Blackmagic SDI cards
1887 dnl
1888 AC_ARG_ENABLE(decklink,
1889   [AS_HELP_STRING([--disable-decklink],
1890     [disable Blackmagic DeckLink SDI input (default auto)])])
1891 AC_ARG_WITH(decklink_sdk,
1892   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1893     [                        location of Blackmagic DeckLink SDI SDK])])
1894 have_decklink=no
1895 if test "${enable_decklink}" != "no"
1896 then
1897   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1898   then
1899     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1900   fi
1901   VLC_SAVE_FLAGS
1902   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1903   AC_LANG_PUSH(C++)
1904   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1905       have_decklink=yes
1906   ], [
1907       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1908   ])
1909   AC_LANG_POP(C++)
1910   VLC_RESTORE_FLAGS
1911 fi
1912 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1913
1914
1915 dnl
1916 dnl  Built-in CD-DA and VCD module
1917 dnl
1918 AC_ARG_ENABLE(vcd,
1919   [AS_HELP_STRING([--disable-vcd],
1920     [disable built-in VCD and CD-DA support (default enabled)])])
1921
1922 AC_ARG_ENABLE(libcddb,
1923   [AS_HELP_STRING([--disable-libcddb],
1924     [disable CDDB for Audio CD (default enabled)])])
1925
1926 if test "${enable_vcd}" != "no"
1927 then
1928   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1929   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1930     AC_MSG_RESULT(yes)
1931     VLC_ADD_PLUGIN([vcd cdda])
1932   ],[
1933     AC_MSG_RESULT(no)
1934   ])
1935
1936   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1937   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1938     AC_MSG_RESULT(yes)
1939     VLC_ADD_PLUGIN([vcd cdda])
1940     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1941   ],[
1942     AC_MSG_RESULT(no)
1943   ])
1944
1945   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1946   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1947     AC_MSG_RESULT(yes)
1948     VLC_ADD_PLUGIN([vcd cdda])
1949     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1950   ],[
1951     AC_MSG_RESULT(no)
1952   ])
1953
1954   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1955   then
1956     VLC_ADD_PLUGIN([vcd cdda])
1957   fi
1958
1959   if test "$enable_libcddb" != "no"; then
1960     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1961       HAVE_LIBCDDB=yes
1962       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1963       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1964       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1965       ],:
1966       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1967       HAVE_LIBCDDB=no])
1968   fi
1969 fi
1970
1971 dnl
1972 dnl Linux DVB
1973 dnl
1974 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1975   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1976 [#include <linux/dvb/version.h>
1977 #if (DVB_API_VERSION < 5)
1978 # error Linux DVB API v3.2 and older are not supported.
1979 #endif
1980 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1981 # error Linux DVB API v5.0 is unsupported. Please update.
1982 #endif
1983 ]])], [
1984   ac_cv_linux_dvb_5_1=yes
1985 ], [
1986   ac_cv_linux_dvb_5_1=no
1987 ])])
1988 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1989
1990 dnl
1991 dnl  Screen capture module
1992 dnl
1993 AC_ARG_ENABLE(screen,
1994   [AS_HELP_STRING([--enable-screen],
1995     [disable screen capture (default enabled)])])
1996 if test "${enable_screen}" != "no"; then
1997   if test "${SYS}" = "darwin"; then
1998     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1999       VLC_ADD_PLUGIN([screen])
2000     ])
2001   fi
2002 fi
2003 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
2004
2005 dnl
2006 dnl  VNC/RFB access module
2007 dnl
2008 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
2009
2010 dnl  RDP/Remote Desktop access module
2011 dnl
2012 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
2013
2014 dnl
2015 dnl QTKit
2016 AC_ARG_ENABLE(macosx-qtkit,
2017   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
2018 if test "x${enable_macosx_qtkit}" != "xno" &&
2019   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2020 then
2021   AC_CHECK_HEADERS(QTKit/QTKit.h, [
2022       VLC_ADD_PLUGIN([qtsound])
2023     ])
2024 fi
2025
2026 dnl
2027 dnl AVFoundation
2028 AC_SUBST(have_avfoundation, ["no"])
2029 AC_ARG_ENABLE(macosx-avfoundation,
2030   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2031 if test "x${enable_macosx_avfoundation}" != "xno" &&
2032   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2033 then
2034   SAVED_LIBS="${LIBS}"
2035   LIBS="-framework AVFoundation"
2036   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2037   LIBS="${SAVED_LIBS}"
2038   if test "${have_avfoundation}" != "no"
2039   then
2040     VLC_ADD_PLUGIN([avcapture])
2041   fi
2042 fi
2043 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2044
2045 dnl
2046 dnl  DCP plugin (using asdcplib)
2047 dnl
2048 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2049 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2050
2051 dnl
2052 dnl  Demux plugins
2053 dnl
2054
2055 EXTEND_HELP_STRING([Mux/Demux plugins:])
2056
2057 dnl
2058 dnl  libdvbpsi check for ts mux/demux
2059 dnl
2060 have_dvbpsi="no"
2061 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2062 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2063
2064
2065 dnl
2066 dnl  GME demux plugin
2067 dnl
2068 AC_ARG_ENABLE(gme,
2069   [AS_HELP_STRING([--enable-gme],
2070     [use Game Music Emu (default auto)])])
2071 AS_IF([test "${enable_gme}" != "no"], [
2072   AC_CHECK_HEADER([gme/gme.h], [
2073     AC_CHECK_LIB([gme], [gme_identify_header], [
2074       VLC_ADD_PLUGIN([gme])
2075     ], [
2076       AC_CHECK_LIB([gme], [gme_identify_extension], [
2077          VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2078          VLC_ADD_PLUGIN([gme])
2079       ],, [-lstdc++ $LIBM])
2080     ])
2081     VLC_ADD_LIBS([gme], [-lgme])
2082   ], [
2083     AS_IF([test "x${enable_gme}" != "x"], [
2084       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2085     ])
2086   ])
2087 ])
2088
2089
2090 dnl
2091 dnl  SIDPlay plugin
2092 dnl
2093 AC_ARG_ENABLE(sid,
2094     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2095 AS_IF([test "${enable_sid}" != "no"], [
2096     PKG_CHECK_MODULES(SID, [libsidplay2], [
2097         AC_LANG_PUSH(C++)
2098         oldCPPFLAGS="$CPPFLAGS"
2099         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2100         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2101             VLC_ADD_PLUGIN([sid])
2102             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2103             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2104         ], [
2105             AS_IF([test -n "${enable_sid}"],
2106                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2107                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2108                 )
2109         ])
2110         CPPFLAGS="$oldCPPFLAGS"
2111         AC_LANG_POP(C++)
2112     ], [
2113         AS_IF([test "x${enable_sid}" = "xyes"],
2114             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2115             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2116             )
2117     ])
2118 ])
2119
2120
2121 dnl
2122 dnl  ogg demux plugin
2123 dnl
2124 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2125 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2126     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2127 ],[true])
2128 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2129 if test "${enable_sout}" != "no"; then
2130 dnl Check for libshout
2131     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2132 fi
2133
2134 dnl
2135 dnl  matroska demux plugin
2136 dnl
2137 PKG_WITH_MODULES([MATROSKA], [libebml libmatroska], [
2138        VLC_ADD_PLUGIN([mkv])
2139        VLC_ADD_CFLAGS([mkv], [$MATROSKA_CFLAGS])
2140        VLC_ADD_LIBS([mkv], [$MATROSKA_LIBS])
2141        have_matroska="yes"
2142    ],,[MKV format support], [auto])
2143 AM_CONDITIONAL([HAVE_MATROSKA], [test "${have_matroska}" = "yes"])
2144
2145 dnl
2146 dnl  modplug demux plugin
2147 dnl
2148 AC_ARG_ENABLE(mod,
2149   [AS_HELP_STRING([--disable-mod],
2150     [do not use libmodplug (default auto)])])
2151 if test "${enable_mod}" != "no" ; then
2152     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2153           VLC_ADD_PLUGIN([mod])
2154           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2155           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2156           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2157     ],[
2158        AS_IF([test -n "${enable_mod}"],
2159          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2160          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2161     ])
2162 fi
2163
2164 dnl
2165 dnl  mpc demux plugin
2166 dnl
2167 AC_ARG_ENABLE(mpc,
2168   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2169 if test "${enable_mpc}" != "no"
2170 then
2171     AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2172     VLC_ADD_PLUGIN([mpc])
2173     VLC_ADD_LIBS([mpc],[-lmpcdec])])
2174 fi
2175
2176 dnl
2177 dnl  Codec plugins
2178 dnl
2179
2180 EXTEND_HELP_STRING([Codec plugins:])
2181
2182 dnl
2183 dnl wmafixed plugin
2184 dnl
2185 AC_ARG_ENABLE(wma-fixed,
2186   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2187 if test "${enable_wma_fixed}" = "yes"
2188 then
2189   VLC_ADD_PLUGIN([wma_fixed])
2190 fi
2191
2192 dnl
2193 dnl shine encoder plugin
2194 dnl
2195 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2196
2197
2198 dnl
2199 dnl openmax il codec plugin
2200 dnl
2201 AC_ARG_ENABLE(omxil,
2202   [  --enable-omxil          openmax il codec module (default disabled)])
2203 if test "${enable_omxil}" = "yes"
2204 then
2205   VLC_ADD_PLUGIN([omxil])
2206 fi
2207
2208 dnl
2209 dnl raspberry pi openmax il configuration
2210 dnl
2211 AC_ARG_ENABLE(rpi-omxil,
2212   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2213 if test "${enable_rpi_omxil}" = "yes"
2214 then
2215   VLC_ADD_PLUGIN([omxil])
2216   VLC_ADD_CFLAGS([omxil],[-DRPI_OMX])
2217 fi
2218
2219 dnl
2220 dnl CrystalHD codec plugin
2221 dnl
2222 AC_ARG_ENABLE(crystalhd,
2223   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2224 if test "${enable_crystalhd}" != "no"; then
2225     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2226       VLC_ADD_PLUGIN([crystalhd])
2227       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2228     ],[
2229       if test "${SYS}" = "mingw32" ; then
2230         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2231           VLC_ADD_PLUGIN([crystalhd])
2232           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2233             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2234             ])
2235         ],[
2236           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2237                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2238                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2239         ],[#define __LINUX_USER__
2240                #include <libcrystalhd/bc_dts_types.h>
2241         ])
2242       fi
2243     ],[
2244        #include <libcrystalhd/bc_dts_types.h>
2245       ])
2246 fi
2247
2248 dnl
2249 dnl  mad plugin
2250 dnl
2251 have_mad="no"
2252 MAD_CFLAGS=""
2253 MAD_LIBS=""
2254
2255 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2256   enable_mad="yes"
2257 ], [
2258   with_mad="no"
2259 ])
2260 AS_IF([test "${with_mad}" != "no"], [
2261   MAD_CFLAGS="-I${with_mad}/include"
2262   MAD_LIBS="-L${with_mad}/lib"
2263 ])
2264
2265 AC_ARG_ENABLE(mad,
2266   [  --enable-mad            libmad module (default enabled)])
2267 AS_IF([test "${enable_mad}" != "no"], [
2268   VLC_SAVE_FLAGS
2269   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2270   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2271   AC_CHECK_HEADERS(mad.h, [
2272     AC_CHECK_LIB(mad, mad_bit_init, [
2273       have_mad="yes"
2274       MAD_LIBS="${MAD_LIBS} -lmad"
2275     ])
2276   ])
2277   VLC_RESTORE_FLAGS
2278   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2279     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2280   ])
2281 ])
2282 AC_SUBST(MAD_CFLAGS)
2283 AC_SUBST(MAD_LIBS)
2284 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2285
2286 dnl  mpg123 plugin
2287 dnl
2288 dnl
2289 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2290
2291 dnl
2292 dnl gstreamer stuff
2293 dnl
2294 AC_ARG_ENABLE(gst-decode,
2295   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2296
2297 have_gst_decode="no"
2298 AS_IF([test "${enable_gst_decode}" != "no"], [
2299   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2300     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2301       have_gst_decode="yes"
2302     ], [
2303       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2304     ])
2305   ], [
2306     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2307   ])
2308 ])
2309 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2310
2311 dnl
2312 dnl  avcodec decoder/encoder plugin
2313 dnl
2314 AC_ARG_ENABLE(merge-ffmpeg,
2315 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2316   enable_merge_ffmpeg="no"
2317 ])
2318 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2319
2320 AC_MSG_CHECKING([for libavutil variant])
2321 PKG_CHECK_EXISTS([libavutil], [
2322   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2323   libavutil_micro="${libavutil_version##*.}"
2324   AS_IF([test ${libavutil_micro} -le 99], [
2325     avfork="libav"
2326   ], [
2327     avfork="ffmpeg"
2328   ])
2329 ], [
2330   avfork="none"
2331 ])
2332 AC_MSG_RESULT([${avfork}])
2333
2334 AC_ARG_ENABLE(avcodec,
2335 [  --enable-avcodec        libavcodec codec (default enabled)])
2336 AS_IF([test "${enable_avcodec}" != "no"], [
2337   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2338   case "${avfork}" in
2339     libav) av_codec_ver="57.16.0" ;;
2340     ffmpeg) av_codec_ver="57.37.100" ;;
2341     *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2342   esac
2343   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2344     VLC_SAVE_FLAGS
2345     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2346     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2347     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2348     AC_CHECK_HEADERS(libavutil/avutil.h)
2349     VLC_RESTORE_FLAGS
2350     have_avcodec="yes"
2351   ],[
2352     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2353   ])
2354 ], [
2355   have_avcodec="no"
2356 ])
2357 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2358
2359 dnl
2360 dnl libva needs avcodec
2361 dnl
2362 AC_ARG_ENABLE(libva,
2363   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2364
2365 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2366   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2367 ])
2368
2369 have_vaapi="no"
2370 have_vaapi_drm="no"
2371 have_vaapi_x11="no"
2372 have_vaapi_wl="no"
2373 AS_IF([test "${enable_libva}" != "no"], [
2374   PKG_CHECK_MODULES([LIBVA], [libva >= 0.38], [
2375     have_vaapi="yes"
2376   ], [
2377     AS_IF([test -n "${enable_libva}"], [
2378       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2379     ], [
2380       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2381     ])
2382   ])
2383   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2384     have_vaapi_drm="yes"
2385   ], [
2386     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2387   ])
2388   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2389     have_vaapi_x11="yes"
2390   ], [
2391     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2392   ])
2393   PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2394     have_vaapi_wl="yes"
2395   ], [
2396     AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2397   ])
2398 ])
2399 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2400 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2401 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2402 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2403
2404 have_avcodec_vaapi="no"
2405 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2406   VLC_SAVE_FLAGS
2407   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2408   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2409   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2410     AC_MSG_NOTICE([VA API acceleration activated])
2411     have_avcodec_vaapi="yes"
2412   ],[
2413     AS_IF([test -n "${enable_libva}"], [
2414       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2415     ], [
2416       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2417     ])
2418   ])
2419   VLC_RESTORE_FLAGS
2420 ])
2421 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2422
2423 dnl
2424 dnl dxva2 needs avcodec
2425 dnl
2426 AC_ARG_ENABLE(dxva2,
2427   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2428
2429 have_avcodec_dxva2="no"
2430 AS_IF([test "${enable_dxva2}" != "no"], [
2431   if test "${SYS}" = "mingw32"; then
2432   AS_IF([test "x${have_avcodec}" = "xyes"], [
2433     AC_CHECK_HEADERS(dxva2api.h,
2434       [
2435         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2436            AC_MSG_NOTICE([DxVA2 acceleration activated])
2437            have_avcodec_dxva2="yes"
2438         ],[
2439     AS_IF([test "${enable_dxva2}" = "yes"],
2440           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2441               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2442         ], [#undef _WIN32_WINNT
2443             /* DXVA2 is only available in Vista and above */
2444             #define _WIN32_WINNT 0x600])
2445       ],[
2446     AS_IF([test "${enable_dxva2}" = "yes"],
2447               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2448               [AC_MSG_WARN([dxva2api.h not found])])
2449       ],[#include <d3d9.h>])
2450   ],[
2451     AS_IF([test "x${enable_dxva2}" != "x"], [
2452       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2453     ])
2454   ])
2455   fi
2456 ])
2457 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2458
2459 dnl
2460 dnl d3d11va needs avcodec
2461 dnl
2462 AC_ARG_ENABLE(d3d11va,
2463   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2464
2465 have_avcodec_d3d11va="no"
2466 AS_IF([test "${enable_d3d11va}" != "no"], [
2467   if test "${SYS}" = "mingw32"; then
2468   AS_IF([test "x${have_avcodec}" = "xyes"], [
2469         AC_CHECK_TYPES([ID3D11VideoDecoder],
2470           [
2471             AC_CHECK_HEADERS(dxva2api.h,
2472               [
2473                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2474                    AC_MSG_NOTICE([D3D11 acceleration activated])
2475                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2476                    have_avcodec_d3d11va="yes"
2477                 ],[
2478                   AS_IF([test "${enable_d3d11va}" = "yes"],
2479                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2480                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2481                   ], [#undef _WIN32_WINNT
2482                       /* D3D11 is only available in Vista and above */
2483                       #define _WIN32_WINNT 0x600])
2484                   ],[
2485                     AS_IF([test "${enable_d3d11va}" = "yes"],
2486                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2487                           [AC_MSG_WARN([dxva2api.h not found])])
2488                   ],[#include <d3d9.h>])
2489           ],[
2490             AS_IF([test "${enable_d3d11va}" = "yes"],
2491                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2492                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2493           ], [#include <d3d11.h>])
2494   ],[
2495     AS_IF([test "x${enable_d3d11va}" != "x"], [
2496       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2497     ])
2498   ])
2499   fi
2500 ])
2501 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2502
2503 dnl
2504 dnl DXGI debug
2505 dnl
2506 AC_CHECK_HEADERS(dxgidebug.h dxgi1_6.h)
2507
2508 dnl
2509 dnl  avformat demuxer/muxer plugin
2510 dnl
2511
2512 AC_ARG_ENABLE(avformat,
2513 [  --enable-avformat       libavformat containers (default enabled)],, [
2514   enable_avformat="${have_avcodec}"
2515 ])
2516 have_avformat="no"
2517 AS_IF([test "${enable_avformat}" != "no"], [
2518   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2519       have_avformat="yes"
2520       VLC_SAVE_FLAGS
2521       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2522       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2523       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2524       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2525       AC_CHECK_HEADERS(libavutil/avutil.h)
2526       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2527         have_avformat="no"
2528       ])
2529       VLC_RESTORE_FLAGS
2530     ],[
2531       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2532   ])
2533 ])
2534 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2535
2536 dnl
2537 dnl  swscale image scaling and conversion plugin
2538 dnl
2539
2540 AC_ARG_ENABLE(swscale,
2541   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2542           (default enabled)]))
2543 if test "${enable_swscale}" != "no"
2544 then
2545   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2546     [
2547       VLC_SAVE_FLAGS
2548       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2549       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2550       AC_CHECK_HEADERS(libswscale/swscale.h)
2551       AC_CHECK_HEADERS(libavutil/avutil.h)
2552       VLC_ADD_PLUGIN([swscale])
2553       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2554       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2555       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2556         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2557       ])
2558       VLC_RESTORE_FLAGS
2559     ],[
2560       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2561   ])
2562 fi
2563
2564 dnl
2565 dnl  postproc plugin
2566 dnl
2567
2568 AC_ARG_ENABLE(postproc,
2569 [  --enable-postproc       libpostproc image post-processing (default auto)])
2570 if test "${enable_postproc}" != "no"
2571 then
2572   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2573     [
2574       VLC_SAVE_FLAGS
2575       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2576       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2577       AC_CHECK_HEADERS(postproc/postprocess.h)
2578       VLC_ADD_PLUGIN([postproc])
2579       VLC_RESTORE_FLAGS
2580     ],[
2581       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2582   ])
2583 fi
2584
2585 dnl
2586 dnl  faad decoder plugin
2587 dnl
2588 AC_ARG_ENABLE(faad,
2589 [  --enable-faad           faad codec (default auto)])
2590 have_faad="no"
2591 AS_IF([test "${enable_faad}" != "no"], [
2592   AC_CHECK_HEADERS([neaacdec.h], [
2593     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2594
2595     AS_IF([test "${have_faad}" = "yes"], [
2596       VLC_ADD_PLUGIN([faad])
2597       VLC_ADD_LIBS([faad],[-lfaad])
2598     ], [
2599       AS_IF([test "${enable_faad}" = "yes"], [
2600         AC_MSG_ERROR([cannot find FAAD library])
2601       ], [
2602         AC_MSG_WARN([cannot find FAAD library])
2603       ])
2604     ])
2605   ])
2606 ])
2607
2608 dnl
2609 dnl  AOM decoder plugin
2610 dnl
2611 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec (default auto)])
2612
2613 dnl
2614 dnl libvpx decoder plugin
2615 dnl
2616 AC_ARG_ENABLE(vpx,
2617     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2618 AS_IF([test "${enable_vpx}" != "no"],[
2619     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2620         VLC_ADD_PLUGIN([vpx])
2621         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2622         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2623         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2624             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2625         ], [], [${VPX_LIBS}])
2626         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2627             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2628         ], [], [${VPX_LIBS}])
2629         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2630             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2631         ], [], [${VPX_LIBS}])
2632         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2633             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2634         ], [], [${VPX_LIBS}])
2635     ], [
2636     AS_IF([test "${enable_vpx}" = "yes"],[
2637         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2638     ])])
2639 ])
2640
2641 dnl
2642 dnl twolame encoder plugin
2643 dnl
2644 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2645
2646 dnl
2647 dnl fdk-aac encoder plugin
2648 dnl
2649 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2650
2651
2652 dnl
2653 dnl A52/AC3 decoder plugin
2654 dnl
2655 AC_ARG_ENABLE(a52,
2656   [  --enable-a52            A/52 support with liba52 (default enabled)])
2657 if test "${enable_a52}" != "no"
2658 then
2659   AC_ARG_WITH(a52,
2660     [  --with-a52=PATH         a52 headers and libraries])
2661     if test -z "${with_a52}"
2662     then
2663       LDFLAGS_test=""
2664       CPPFLAGS_test=""
2665     else
2666       LDFLAGS_test="-L${with_a52}/lib"
2667       CPPFLAGS_test="-I${with_a52}/include"
2668     fi
2669     VLC_SAVE_FLAGS
2670     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2671     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2672     AC_CHECK_HEADERS(a52dec/a52.h, [
2673       AC_CHECK_LIB(a52, a52_free, [
2674         VLC_ADD_PLUGIN([a52])
2675         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2676         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2677       ],[
2678         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2679         ], [$LIBM])
2680     ],[
2681       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2682     ])
2683     VLC_RESTORE_FLAGS
2684 fi
2685
2686 dnl
2687 dnl DTS Coherent Acoustics decoder plugin
2688 dnl
2689 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2690
2691 dnl
2692 dnl  Flac plugin
2693 dnl
2694 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2695
2696 dnl
2697 dnl  Libmpeg2 plugin
2698 dnl
2699 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2700
2701 dnl
2702 dnl  Vorbis plugin
2703 dnl
2704 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2705
2706 dnl
2707 dnl  Tremor plugin
2708 dnl
2709 AC_ARG_ENABLE(tremor,
2710   [  --enable-tremor         Tremor decoder support (default disabled)])
2711 if test "${enable_tremor}" = "yes"
2712 then
2713   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2714     VLC_ADD_PLUGIN([tremor])
2715    ],[])
2716 fi
2717
2718 dnl
2719 dnl  Speex plugins
2720 dnl
2721 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2722 have_speexdsp="no"
2723 AS_IF([test "${enable_speex}" != "no"], [
2724   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2725     have_speexdsp="yes"
2726   ], [
2727     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2728   ])
2729 ])
2730 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2731
2732 dnl
2733 dnl  Opus plugin
2734 dnl
2735 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2736
2737 dnl
2738 dnl  Ambisonic channel mixer and binauralizer plugin
2739 dnl
2740 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
2741
2742 dnl
2743 dnl  theora decoder plugin
2744 dnl
2745 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2746
2747 dnl
2748 dnl  OggSpots decoder plugin
2749 dnl
2750 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2751
2752 dnl
2753 dnl  Daala decoder plugin
2754 dnl
2755 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2756
2757 dnl
2758 dnl  schroedinger decoder plugin (for dirac format video)
2759 dnl
2760 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2761
2762 dnl
2763 dnl  PNG decoder module
2764 dnl
2765 AC_ARG_ENABLE(png,
2766   [  --enable-png            PNG support (default enabled)])
2767 AS_IF([test "${enable_png}" != "no"], [
2768 AC_CHECK_HEADERS(png.h, [
2769   VLC_SAVE_FLAGS
2770   LDFLAGS="${LDFLAGS} -lz $LIBM"
2771   AC_CHECK_LIB(png, png_set_alpha_mode, [
2772     VLC_ADD_PLUGIN([png])
2773   ], [], [-lz $LIBM])
2774   VLC_RESTORE_FLAGS
2775   ])
2776 ])
2777
2778 dnl
2779 dnl  JPEG decoder module
2780 dnl
2781 AC_ARG_ENABLE(jpeg,
2782   [  --enable-jpeg           JPEG support (default enabled)])
2783 AS_IF([test "${enable_jpeg}" != "no"], [
2784 AC_CHECK_HEADERS(jpeglib.h, [
2785   VLC_ADD_PLUGIN([jpeg])
2786   ])
2787 ])
2788
2789 dnl
2790 dnl  BPG decoder module
2791 dnl
2792 AC_ARG_ENABLE(bpg,
2793   [  --enable-bpg           BPG support (default disabled)])
2794 AS_IF([test "${enable_bpg}" != "no"], [
2795 AC_CHECK_HEADERS(libbpg.h, [
2796   VLC_ADD_PLUGIN([bpg])
2797   ])
2798 ])
2799
2800 dnl
2801 dnl H262 encoder plugin (lib262)
2802 dnl
2803 AC_ARG_ENABLE(x262,
2804   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2805 if test "${enable_x262}" != "no"; then
2806     PKG_CHECK_MODULES(X262, x262, [
2807         VLC_ADD_PLUGIN([x262])
2808         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2809         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2810           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2811         ])
2812         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2813         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2814           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2815         fi
2816     ], [
2817        if test "${enable_x262}" = "yes"; then
2818         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2819        fi
2820     ])
2821 fi
2822
2823 dnl x265 encoder
2824 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2825
2826 dnl
2827 dnl H264 encoder plugin (using libx264)
2828 dnl
2829 AC_ARG_ENABLE(x264,
2830   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2831 if test "${enable_x264}" != "no"; then
2832       PKG_CHECK_MODULES(X264,x264 >= 0.148, [
2833         VLC_ADD_PLUGIN([x264])
2834         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2835
2836         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2837           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2838         ])
2839
2840         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2841         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2842           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2843         fi
2844       ],[
2845         if test "${enable_x264}" = "yes"; then
2846             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2847           fi
2848       ])
2849 fi
2850
2851 dnl
2852 dnl H264 encoder plugin (libx264 > 153)
2853 dnl
2854 AC_ARG_ENABLE(x26410b,
2855   [  --enable-x26410b           H264 10-bit encoding support with libx264 (default enabled)])
2856 if test "${enable_x26410b}" != "no"; then
2857       PKG_CHECK_MODULES(X26410b,x264 >= 0.153, [
2858         VLC_ADD_PLUGIN([x26410b])
2859         VLC_ADD_LIBS([x26410b],[${X264_LIBS}])
2860
2861         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2862           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2863         ])
2864
2865         VLC_ADD_CFLAGS([x26410b],[${X264_CFLAGS}])
2866         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2867           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2868         fi
2869       ],[
2870         if test "${enable_x26410b}" = "yes"; then
2871             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2872           fi
2873       ])
2874 fi
2875
2876
2877 dnl
2878 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2879 dnl
2880 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2881
2882 dnl
2883 dnl libfluidsynth (MIDI synthetizer) plugin
2884 dnl
2885 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2886 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2887 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2888
2889 dnl
2890 dnl Teletext Modules
2891 dnl vbi decoder plugin (using libzbvi)
2892 dnl telx module
2893 dnl uncompatible
2894 dnl
2895 AC_ARG_ENABLE(zvbi,
2896   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2897                   libzvbi (default enabled)]))
2898 AC_ARG_ENABLE(telx,
2899   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2900                   zvbi) (default enabled if zvbi is absent)]))
2901
2902 AS_IF( [test "${enable_zvbi}" != "no"],[
2903     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2904         [
2905           VLC_ADD_PLUGIN([zvbi])
2906           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2907           AS_IF( [test "${enable_telx}" = "yes"],[
2908                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2909                   ])
2910         ],[
2911           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2912         ])
2913     ])
2914 AS_IF( [test "${enable_telx}" != "no" ],[
2915   VLC_ADD_PLUGIN([telx])
2916   ])
2917
2918 dnl
2919 dnl ARIB subtitles rendering module
2920 dnl
2921 AC_ARG_ENABLE(aribsub,
2922   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2923 AS_IF( [test "${enable_aribsub}" != "no" ],[
2924   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2925       have_aribb24="yes"
2926       VLC_ADD_PLUGIN([aribsub])
2927       VLC_ADD_LIBS([aribsub],[-laribb24])
2928       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2929     ],[
2930       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2931       have_aribb24="no"
2932   ])
2933 ])
2934 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2935
2936 dnl
2937 dnl ARIB B25
2938 dnl
2939 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2940
2941 dnl
2942 dnl  kate decoder plugin
2943 dnl
2944 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2945
2946 dnl
2947 dnl  tiger rendering for kate decoder plugin
2948 dnl
2949 AC_ARG_ENABLE(tiger,
2950 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2951 AS_IF([test "${enable_tiger}" != "no"], [
2952   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2953       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2954         AS_IF([test -n "${enable_tiger}"], [
2955           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2956         ])
2957   ])
2958 ])
2959
2960 dnl
2961 dnl  check if we can build the css selector engine
2962 dnl
2963 AC_ARG_ENABLE(css,
2964 [  --enable-css            CSS selector engine (default auto)])
2965 AS_IF([test "${enable_css}" != "no"], [
2966   with_css="yes"
2967   AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
2968 ])
2969 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
2970
2971
2972 dnl
2973 dnl  Video plugins
2974 dnl
2975
2976 EXTEND_HELP_STRING([Video plugins:])
2977
2978 dnl
2979 dnl  OpenGL
2980 dnl
2981 PKG_CHECK_MODULES([EGL], [egl], [
2982   have_egl="yes"
2983 ], [
2984   have_egl="no"
2985 ])
2986 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2987
2988 have_gl="no"
2989 PKG_CHECK_MODULES([GL], [gl], [
2990   have_gl="yes"
2991 ], [
2992   AC_MSG_CHECKING([for OpenGL])
2993   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2994 #ifdef _WIN32
2995 # include <GL/glew.h>
2996 #endif
2997 #include <GL/gl.h>
2998 ]], [
2999     [int t0 = GL_TEXTURE0;]])
3000   ], [
3001     GL_CFLAGS=""
3002     have_gl="yes"
3003     AS_IF([test "${SYS}" != "mingw32"], [
3004       GL_LIBS="-lGL"
3005     ], [
3006       GL_LIBS="-lopengl32"
3007     ])
3008   ])
3009   AC_MSG_RESULT([${have_gl}])
3010 ])
3011 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3012 AS_IF([test "${have_gl}" = "yes"], [
3013   AC_DEFINE([HAVE_GL], 1, [Defined if having OpenGL])
3014 ])
3015
3016 dnl OpenGL ES 2: depends on EGL 1.1
3017 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3018
3019 dnl
3020 dnl  Xlib
3021 dnl
3022
3023 AC_PATH_XTRA()
3024 AC_CHECK_HEADERS(X11/Xlib.h)
3025
3026 dnl
3027 dnl  X C Bindings modules
3028 dnl
3029 AC_ARG_ENABLE(xcb,
3030   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3031   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3032     enable_xcb="yes"
3033   ], [
3034     enable_xcb="no"
3035   ])
3036 ])
3037
3038 have_xcb="no"
3039 have_xkbcommon_x11="no"
3040 have_xcb_keysyms="no"
3041 AS_IF([test "${enable_xcb}" != "no"], [
3042   xcb_err=""
3043
3044   dnl libxcb
3045   PKG_CHECK_MODULES([XCB], [xcb >= 1.6],, [
3046     xcb_err="$xcb_err ${XCB_PKG_ERRORS}."])
3047   PKG_CHECK_MODULES([XCB_COMPOSITE], [xcb-composite],, [
3048     xcb_err="$xcb_err ${XCB_COMPOSITE_PKG_ERRORS}."])
3049   PKG_CHECK_MODULES([XCB_RANDR], [xcb-randr >= 1.3],, [
3050     xcb_err="$xcb_err ${XCB_RANDR_PKG_ERRORS}."])
3051   PKG_CHECK_MODULES([XCB_SHM], [xcb-shm],, [
3052     xcb_err="$xcb_err ${XCB_SHM_PKG_ERRORS}."])
3053   PKG_CHECK_MODULES([XCB_XKB], [xcb-xkb],, [
3054     xcb_err="$xcb_err ${XCB_XKB_PKG_ERRORS}."])
3055   PKG_CHECK_MODULES([XCB_XV], [xcb-xv >= 1.1.90.1],, [
3056     xcb_err="$xcb_err ${XCB_XV_PKG_ERRORS}."])
3057
3058   dnl xproto
3059   PKG_CHECK_MODULES(XPROTO, [xproto],, [
3060     xcb_err="$xcb_err ${XPROTO_PKG_ERRORS}."])
3061
3062   AS_IF([test -n "$xcb_err"], [
3063     AC_MSG_ERROR([$xcb_err Pass --disable-xcb to skip X11 support.])
3064   ])
3065
3066   dnl xkbcommon
3067   PKG_CHECK_MODULES([XKBCOMMON_X11], [xkbcommon-x11], [
3068     have_xkbcommon_x11="yes"
3069   ], [
3070     AC_MSG_WARN([${XKBCOMMON_X11_PKG_ERRORS}. Hotkeys are disabled.])
3071   ])
3072
3073   dnl xcb-utils
3074   PKG_CHECK_MODULES([XCB_KEYSYMS], [xcb-keysyms >= 0.3.4], [
3075     have_xcb_keysyms="yes"
3076   ], [
3077     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Global hotkeys are disabled.])
3078   ])
3079
3080   have_xcb="yes"
3081 ])
3082 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3083 AM_CONDITIONAL([HAVE_XKBCOMMON_X11], [test "${have_xkbcommon_x11}" = "yes"])
3084 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3085
3086
3087 dnl
3088 dnl VDPAU needs X11
3089 dnl
3090 AC_ARG_ENABLE(vdpau,
3091   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3092 have_vdpau="no"
3093 AS_IF([test "${enable_vdpau}" != "no"], [
3094   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3095     have_vdpau="yes"
3096     AS_IF([test "${no_x}" = "yes"], [
3097       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3098     ])
3099   ], [
3100     AS_IF([test -n "${enable_vdpau}"], [
3101       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3102     ])
3103   ])
3104 ])
3105 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3106
3107 have_avcodec_vdpau="no"
3108 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3109   case "${avfork}" in
3110     libav) av_vdpau_ver="56.10.0" ;;
3111     ffmpeg) av_vdpau_ver="56.19.100" ;;
3112   esac
3113   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3114     have_avcodec_vdpau="yes"
3115     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3116   ], [
3117     AS_IF([test -n "${enable_vdpau}"], [
3118       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3119     ], [
3120       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3121     ])
3122   ])
3123 ])
3124 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3125
3126
3127 dnl
3128 dnl  Wayland
3129 dnl
3130 AC_ARG_ENABLE(wayland,
3131   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3132
3133 have_wayland="no"
3134 AS_IF([test "${enable_wayland}" != "no"], [
3135   wl_err=""
3136
3137   dnl wayland
3138   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91],, [
3139     wl_err="$wl_err ${WAYLAND_CLIENT_PKG_ERRORS}."
3140   ])
3141   PKG_CHECK_MODULES([WAYLAND_CURSOR], [wayland-cursor],, [
3142     wl_err="$wl_err ${WAYLAND_CURSOR_PKG_ERRORS}."
3143   ])
3144   PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl],, [
3145     wl_err="$wl_err ${WAYLAND_EGL_PKG_ERRORS}."
3146   ])
3147   PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner >= 1.15], [
3148     WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3149   ], [
3150     wl_err="$wl_err ${WAYLAND_SCANNER_PKG_ERRORS}."
3151   ])
3152
3153   dnl wayland-protocols
3154   PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= 1.12], [
3155     WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3156   ], [
3157     wl_err="$wl_err ${WAYLAND_PROTOCOLS_PKG_ERRORS}."
3158   ])
3159
3160   AS_IF([test -n "$wl_err"], [
3161     AS_IF([test -n "$enable_wayland"], [
3162       AC_MSG_ERROR([$wl_err])
3163     ], [
3164       AC_MSG_WARN([$wl_err])
3165     ])
3166   ], [
3167     have_wayland="yes"
3168   ])
3169
3170   dnl xkbcommon
3171   PKG_CHECK_MODULES([XKBCOMMON], [xkbcommon], [
3172     have_xkbcommon="yes"
3173   ], [
3174     AC_MSG_WARN([${XKBCOMMON_PKG_ERRORS}. Hotkeys are disabled.])
3175   ])
3176 ])
3177 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3178 AC_SUBST([WAYLAND_PROTOCOLS])
3179 AC_SUBST([WAYLAND_SCANNER])
3180 AM_CONDITIONAL([HAVE_XKBCOMMON], [test "${have_xkbcommon}" = "yes"])
3181
3182
3183 dnl
3184 dnl  SDL image decoder module
3185 dnl
3186 AC_ARG_ENABLE(sdl-image,
3187   [  --enable-sdl-image      SDL image support (default enabled)])
3188 AS_IF([test "${enable_sdl_image}" != "no"],[
3189   PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3190     VLC_ADD_PLUGIN([sdl_image])
3191   ], [
3192     AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3193   ])
3194 ])
3195
3196 dnl
3197 dnl  freetype module
3198 dnl
3199 AC_ARG_ENABLE(freetype,
3200   [  --enable-freetype       freetype support   (default auto)])
3201 AC_ARG_ENABLE(fribidi,
3202   [  --enable-fribidi        fribidi support    (default auto)])
3203 AC_ARG_ENABLE(harfbuzz,
3204   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3205 AC_ARG_ENABLE(fontconfig,
3206   [  --enable-fontconfig     fontconfig support (default auto)])
3207
3208 AC_ARG_WITH([default-font],
3209     AS_HELP_STRING([--with-default-font=PATH],
3210         [Path to the default font]),
3211         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3212             "$withval", [Default font])])
3213 AC_ARG_WITH([default-monospace-font],
3214     AS_HELP_STRING([--with-default-monospace-font=PATH],
3215         [Path to the default font]),
3216         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3217             "$withval", [Default monospace font])])
3218
3219 AC_ARG_WITH([default-font-family],
3220     AS_HELP_STRING([--with-default-font-family=NAME],
3221         [Name of the default font family]),
3222         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3223             "$withval", [Default font family])])
3224 AC_ARG_WITH([default-monospace-font-family],
3225     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3226         [Name of the default font family]),
3227         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3228             "$withval", [Default monospace font family])])
3229
3230 have_freetype="no"
3231 have_fontconfig="no"
3232 have_fribidi="no"
3233 have_harfbuzz="no"
3234
3235 if test "${enable_freetype}" != "no"; then
3236    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3237       have_freetype="yes"
3238       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3239       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3240
3241     dnl fontconfig support
3242     AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3243       PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3244         have_fontconfig="yes"
3245       ], [
3246         AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3247       ])
3248     ])
3249
3250       dnl fribidi support
3251       if test "${enable_fribidi}" != "no"; then
3252         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3253           have_fribidi="yes"
3254           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3255           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3256         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3257       fi
3258
3259       dnl harfbuzz support
3260       if test "${have_fribidi}" != "no"; then
3261         if test "${enable_harfbuzz}" != "no"; then
3262           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3263             have_harfbuzz="yes"
3264             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3265             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3266           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3267         fi
3268       fi
3269   ],[
3270   AS_IF([test -n "${enable_freetype}"],[
3271     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3272     ])
3273   ])
3274 fi
3275
3276 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3277 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3278 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3279 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3280
3281 dnl
3282 dnl libass subtitle rendering module
3283 dnl
3284 AC_ARG_ENABLE(libass,
3285   [  --enable-libass         Subtitle support using libass (default enabled)])
3286 AS_IF( [test "${enable_libass}" != "no"], [
3287   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
3288       [
3289         VLC_ADD_PLUGIN([libass])
3290
3291         if test "${have_fontconfig}" != "no"; then
3292             VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
3293             VLC_ADD_LIBS([libass],[${FONTCONFIG_LIBS}])
3294         fi
3295       ],[
3296         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
3297       ])
3298   ])
3299
3300 dnl
3301 dnl SAPI (text to Speech renderer for Windows)
3302 dnl
3303 AC_LANG_PUSH([C++])
3304 AC_CHECK_TYPES([ISpObjectToken],[
3305               have_sapi="yes"
3306             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3307               [#include <windows.h>
3308                #include <sapi.h>
3309                #include <sphelper.h>])
3310 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3311 AC_LANG_POP([C++])
3312
3313 dnl
3314 dnl  SVG module (text rendering and image decoding)
3315 dnl
3316 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3317 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3318
3319 dnl
3320 dnl  Windows DirectX module
3321 dnl
3322
3323 AC_ARG_ENABLE(directx,
3324   [AS_HELP_STRING([--enable-directx],
3325     [Microsoft DirectX support (default enabled on Windows)])],, [
3326   AS_IF([test "${SYS}" = "mingw32"], [
3327     enable_directx="yes"
3328   ], [
3329     enable_directx="no"
3330   ])
3331 ])
3332 AS_IF([test "${enable_directx}" != "no"], [
3333   dnl DirectDraw
3334   AC_CHECK_HEADERS(ddraw.h, [
3335     VLC_ADD_PLUGIN([directdraw])
3336   ])
3337
3338   dnl OpenGL
3339   AC_CHECK_HEADERS(GL/wglew.h, [
3340     VLC_ADD_PLUGIN([glwin32 wgl])
3341   ],, [
3342     #include <windows.h>
3343     #include <GL/gl.h>
3344   ])
3345
3346   dnl Direct3D11
3347   AC_CHECK_HEADERS(d3d11.h, [
3348     VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3349   ])
3350
3351   dnl Direct3D9
3352   AC_CHECK_HEADERS(d3d9.h, [
3353     VLC_ADD_PLUGIN([direct3d9])
3354     AC_CHECK_HEADERS(d3dx9effect.h)
3355
3356     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3357         [[#define COBJMACROS
3358           #include <d3d9.h>
3359           #include <dxva2api.h>
3360           #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3361           # error dxva2 too old
3362           #endif
3363         ]],[[;]])
3364       ],[
3365         VLC_ADD_PLUGIN([direct3d9_filters])
3366       ],
3367       [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3368
3369   ])
3370 ])
3371
3372 dnl
3373 dnl  Linux framebuffer module
3374 dnl
3375 AC_CHECK_HEADER([linux/fb.h], [
3376   VLC_ADD_PLUGIN([fb])
3377 ])
3378
3379 dnl
3380 dnl  Linux kernel mode setting module
3381 dnl
3382 PKG_ENABLE_MODULES_VLC([KMS], [], [libdrm >= 2.4.83], [Linux kernel mode setting output], [auto])
3383
3384 dnl
3385 dnl  libcaca plugin
3386 dnl
3387 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3388
3389 dnl
3390 dnl  OS/2 KVA plugin
3391 dnl
3392 AC_ARG_ENABLE(kva,
3393   [AS_HELP_STRING([--enable-kva],
3394     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3395   AS_IF([test "$SYS" = "os2"], [
3396     enable_kva="yes"
3397   ])
3398 ])
3399 have_kva="no"
3400 KVA_LIBS=""
3401 AS_IF([test "$enable_kva" != "no"], [
3402   AC_CHECK_HEADERS([kva.h], [
3403     have_kva="yes"
3404     AC_CHECK_LIB(kva, main, [
3405       KVA_LIBS="-lkva"
3406     ])
3407   ])
3408 ])
3409 AC_SUBST(KVA_LIBS)
3410 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3411
3412 dnl
3413 dnl MMAL plugin
3414 dnl
3415 AC_ARG_ENABLE(mmal,
3416   AS_HELP_STRING([--enable-mmal],
3417     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3418 if test "${enable_mmal}" != "no"; then
3419   VLC_SAVE_FLAGS
3420   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3421   CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3422   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3423     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3424         have_mmal="yes"
3425         VLC_ADD_PLUGIN([mmal])
3426         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3427         VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3428         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif ]) ], [
3429           AS_IF([test "${enable_mmal}" = "yes"],
3430             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3431             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3432           ],
3433         [])
3434     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3435       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3436       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3437   VLC_RESTORE_FLAGS
3438 fi
3439 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3440
3441 dnl
3442 dnl  Audio plugins
3443 dnl
3444
3445 EXTEND_HELP_STRING([Audio plugins:])
3446
3447 dnl
3448 dnl  Pulseaudio module
3449 dnl
3450 AC_ARG_ENABLE(pulse,
3451   [AS_HELP_STRING([--enable-pulse],
3452     [use the PulseAudio client library (default auto)])])
3453 have_pulse="no"
3454 AS_IF([test "${enable_pulse}" != "no"], [
3455   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3456     have_pulse="yes"
3457   ], [
3458     AS_IF([test "x${enable_pulse}" != "x"], [
3459       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3460     ])
3461   ])
3462 ])
3463 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3464
3465 dnl
3466 dnl  ALSA module
3467 dnl
3468 AC_ARG_ENABLE(alsa,
3469   [AS_HELP_STRING([--enable-alsa],
3470     [support the Advanced Linux Sound Architecture (default auto)])],, [
3471   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3472     enable_alsa="yes"
3473   ])
3474 ])
3475 have_alsa="no"
3476 AS_IF([test "${enable_alsa}" != "no"], [
3477   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3478     have_alsa="yes"
3479   ], [
3480     AS_IF([test "x${enable_alsa}" != "x"], [
3481       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3482     ])
3483   ])
3484 ])
3485 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3486
3487 dnl
3488 dnl  Open Sound System module
3489 dnl
3490 AC_ARG_ENABLE(oss,
3491   [AS_HELP_STRING([--enable-oss],
3492     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3493   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3494     enable_oss="no"
3495   ])
3496 ])
3497 have_oss="no"
3498 OSS_LIBS=""
3499 AS_IF([test "$enable_oss" != "no"], [
3500   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3501     have_oss="yes"
3502     AC_CHECK_LIB(ossaudio, main, [
3503       OSS_LIBS="-lossaudio"
3504     ])
3505   ])
3506 ])
3507 AC_SUBST(OSS_LIBS)
3508 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3509
3510 dnl
3511 dnl  OpenBSD sndio module
3512 dnl
3513 AC_ARG_ENABLE([sndio],
3514   [AS_HELP_STRING([--disable-sndio],
3515     [support the OpenBSD sndio (default auto)])],, [
3516   AS_IF([test "$SYS" = "openbsd"], [
3517     enable_sndio="yes"
3518   ])
3519 ])
3520 have_sndio="no"
3521 AS_IF([test "$enable_sndio" != "no"], [
3522   AC_CHECK_HEADER([sndio.h], [
3523     have_sndio="yes"
3524   ])
3525 ])
3526 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3527
3528 dnl
3529 dnl  Windows Audio Session plugin
3530 dnl
3531 AC_ARG_ENABLE([wasapi],
3532   [AS_HELP_STRING([--enable-wasapi],
3533     [use the Windows Audio Session API (default auto)])
3534 ])
3535 have_wasapi="no"
3536 AS_IF([test "$enable_wasapi" != "no"], [
3537   AC_CHECK_HEADER([audioclient.h], [
3538     have_wasapi="yes"
3539   ], [
3540     AS_IF([test "x${enable_wasapi}" != "x"], [
3541       AC_MSG_ERROR([Windows Audio Session API not found.])
3542     ])
3543   ])
3544 ])
3545 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3546
3547 dnl
3548 dnl  JACK modules
3549 dnl
3550 AC_ARG_ENABLE(jack,
3551   [AS_HELP_STRING([--disable-jack],
3552     [do not use jack (default auto)])])
3553 have_jack="no"
3554 AS_IF([test "${enable_jack}" != "no"], [
3555     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3556       [ have_jack=yes ],
3557       [
3558       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3559
3560       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3561       [ have_jack=yes ],
3562       [
3563       AS_IF([test -n "${enable_jack}"],
3564          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3565          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3566       ])
3567     ])
3568 ])
3569 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3570
3571 dnl
3572 dnl  OpenSLES Android
3573 dnl
3574 AC_ARG_ENABLE(opensles,
3575   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3576 if test "${HAVE_ANDROID}" = "1"; then
3577   if test "${enable_opensles}" = "yes"; then
3578       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3579         [ VLC_ADD_PLUGIN([opensles_android]) ],
3580         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3581   fi
3582 fi
3583
3584 dnl
3585 dnl  Tizen audio
3586 dnl
3587 AC_ARG_ENABLE(tizen_audio,
3588   [AS_HELP_STRING([--enable-tizen-audio],
3589     [Tizen audio module (default enabled on Tizen)])],, [
3590   AS_IF([test "$HAVE_TIZEN" = "1"], [
3591     enable_tizen_audio="yes"
3592   ])
3593 ])
3594 if test "${enable_tizen_audio}" = "yes"; then
3595   AC_CHECK_HEADERS(audio_io.h,
3596     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3597     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3598 fi
3599
3600 dnl
3601 dnl libsamplerate plugin
3602 dnl
3603 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3604
3605 dnl
3606 dnl  soxr module
3607 dnl
3608 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3609
3610 dnl
3611 dnl  OS/2 KAI plugin
3612 dnl
3613 AC_ARG_ENABLE(kai,
3614   [AS_HELP_STRING([--enable-kai],
3615     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3616   AS_IF([test "$SYS" = "os2"], [
3617     enable_kai="yes"
3618   ])
3619 ])
3620 have_kai="no"
3621 KAI_LIBS=""
3622 AS_IF([test "$enable_kai" != "no"], [
3623   AC_CHECK_HEADERS([kai.h], [
3624     have_kai="yes"
3625     AC_CHECK_LIB(kai, main, [
3626       KAI_LIBS="-lkai"
3627     ])
3628   ])
3629 ])
3630 AC_SUBST(KAI_LIBS)
3631 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3632
3633 dnl
3634 dnl  chromaprint audio track fingerprinter
3635 dnl
3636 m4_pushdef([libchromaprint_version], 0.6.0)
3637 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3638     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3639     AS_IF([test "${enable_chromaprint}" = "yes"],
3640         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3641         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3642          ),
3643     [(Chromaprint based audio fingerprinter)],[auto])
3644 m4_popdef([libchromaprint_version])
3645
3646 dnl
3647 dnl  Chromecast streaming support
3648 dnl
3649 m4_pushdef([protobuf_lite_version], 2.5.0)
3650 AC_ARG_VAR(PROTOC, [protobuf compiler])
3651 AC_CHECK_PROGS(PROTOC, protoc, no)
3652 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3653     AS_IF([test "x${PROTOC}" != "xno"], [
3654         build_chromecast="yes"
3655     ], [
3656     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3657     ])
3658 ], [
3659     AS_IF([test "${enable_chromecast}" = "yes"],
3660         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3661         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3662     )
3663     enable_chromecast="no"
3664 ], [(Chromecast streaming support)], [auto])
3665 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3666 m4_popdef([protobuf_lite_version])
3667
3668 dnl
3669 dnl  Interface plugins
3670 dnl
3671
3672 EXTEND_HELP_STRING([Interface plugins:])
3673
3674 dnl
3675 dnl QT
3676 dnl
3677 AC_ARG_ENABLE(qt, [
3678   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3679   AS_IF([test "${SYS}" = "darwin"], [
3680     enable_qt="no"
3681   ])
3682 ])
3683 have_qt5_x11="no"
3684 AS_IF([test "${enable_qt}" != "no"], [
3685   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.9.0 Qt5Widgets Qt5Gui Qt5Svg], [
3686       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
3687           have_qt5_x11="yes"
3688       ],[
3689           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3690       ])
3691       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3692       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3693       QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
3694       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3695       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3696       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3697     ], [
3698       AS_IF([test -n "${enable_qt}"],[
3699         AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3700       ],[
3701         AC_MSG_WARN([${QT_PKG_ERRORS}.])
3702       ])
3703       enable_qt="no"
3704     ])
3705 ])
3706
3707 AS_IF([test "${enable_qt}" != "no"], [
3708   ALIASES="${ALIASES} qvlc"
3709 ])
3710 AC_SUBST(QT_VERSION)
3711 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3712 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
3713
3714 dnl
3715 dnl detect kde4-config patch (used for kde solids).
3716 dnl
3717 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3718 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3719   KDE4_CONFIG="kde4-config"
3720 ])
3721
3722 dnl
3723 dnl Simple test for skins2 dependency
3724 dnl
3725 AS_IF([test "$enable_qt" = "no"], [
3726   AS_IF([test "${enable_skins2}" = "yes"], [
3727     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3728   ], [
3729     enable_skins2="no"
3730     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3731   ])
3732 ])
3733
3734 dnl
3735 dnl Skins2 module
3736 dnl
3737 AC_ARG_ENABLE(skins2,
3738   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3739 AS_IF([test "${enable_skins2}" != "no"], [
3740   have_skins_deps="yes"
3741
3742   dnl Win32
3743   AS_IF([test "${SYS}" = "mingw32"], [
3744     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3745     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3746   dnl OS/2
3747   ], [test "${SYS}" = "os2"], [
3748     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3749   dnl Linux/Unix
3750   ], [
3751     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3752     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3753     PKG_CHECK_MODULES([XCURSOR], [xcursor],, [have_skins_deps="no"])
3754     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3755     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3756     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} ${XCURSOR_LIBS} -lX11])
3757   ])
3758
3759   dnl we need freetype
3760   AS_IF([test "${have_freetype}" != "yes"], [
3761     have_skins_deps="no"
3762   ])
3763
3764   AS_IF([test "${have_skins_deps}" = "no"], [
3765     AS_IF([test "x${enable_skins2}" = "x"], [
3766       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3767     ], [
3768       AC_MSG_ERROR([Skins2 interface requires FreeType, libxcursor, libxpm, libxext and libxinerama])
3769     ])
3770     enable_skins2="no"
3771   ], [
3772     ALIASES="${ALIASES} svlc"
3773     enable_skins2="yes"
3774   ])
3775 ])
3776 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3777
3778 AC_ARG_ENABLE(libtar,
3779   [  --enable-libtar         libtar support for skins2 (default auto)])
3780 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3781   AC_CHECK_HEADERS(libtar.h, [
3782     VLC_ADD_LIBS([skins2],[-ltar])
3783   ])
3784 ])
3785
3786 dnl
3787 dnl  MacOS X gui module
3788 dnl
3789 AC_ARG_ENABLE(macosx,
3790   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3791 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3792 then
3793
3794   dnl
3795   dnl If possible, use xcrun to find the right ibtool
3796   dnl
3797
3798   AC_PATH_PROG([XCRUN], [xcrun], [no])
3799   AS_IF([test ! "x${XCRUN}" = "xno"], [
3800     AC_MSG_CHECKING([for ibtool (using xcrun)])
3801     XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
3802     AC_MSG_RESULT([${XIB}])
3803   ], [
3804     AC_MSG_WARN([Looking for tools without using xcrun])
3805   ])
3806
3807   AS_IF([test "x${XIB}" = "xno"], [
3808     AC_PATH_PROG(XIB, [ibtool], [no])
3809     AS_IF([test "x${XIB}" = "xno"], [
3810       AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
3811     ])
3812   ])
3813 fi
3814 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
3815
3816 dnl
3817 dnl  MacOS X sparkle update support
3818 dnl
3819 AC_ARG_ENABLE(sparkle,
3820   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3821 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3822 then
3823   if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
3824   then
3825     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3826   fi
3827
3828   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3829 fi
3830 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3831
3832 dnl
3833 dnl  MacOS X breakpad creash reporter support
3834 dnl
3835 AC_ARG_WITH([breakpad],
3836   AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
3837
3838 AS_IF([test "$with_breakpad" != "no"], [
3839
3840   AS_IF([test "$with_breakpad" = "yes"], [
3841     AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
3842   ])
3843
3844   AS_IF([test "$HAVE_OSX" = "1"], [
3845     AC_MSG_CHECKING([for Breakpad framework])
3846     AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
3847                 ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
3848       AC_MSG_RESULT([no])
3849       with_breakpad="no"
3850       AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
3851     ], [
3852       AC_MSG_RESULT([yes])
3853     ])
3854   ],[
3855     PKG_CHECK_MODULES([BREAKPAD], [breakpad-client], [
3856       LDFLAGS="${LDFLAGS} -Wl,--build-id"
3857     ], [
3858       AC_MSG_ERROR(["breakpad not found"])
3859     ])
3860   ])
3861 ])
3862
3863 AM_CONDITIONAL(HAVE_BREAKPAD, [test "$with_breakpad" != "no"])
3864 AS_IF([test "$with_breakpad" != "no"], [
3865   AC_SUBST(BREAKPAD_URL, ["${with_breakpad}"])
3866 ])
3867
3868 dnl
3869 dnl  Minimal Mac OS X module
3870 dnl
3871 AC_ARG_ENABLE(minimal-macosx,
3872   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3873 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3874 then
3875   VLC_ADD_PLUGIN([minimal_macosx])
3876 fi
3877
3878 dnl
3879 dnl Mac OS X fancy dmg build tool
3880 dnl
3881 if test "${HAVE_OSX}" = "1"
3882 then
3883   AC_PATH_PROG(DMGBUILD, dmgbuild, no)
3884   AS_IF([test "x${DMGBUILD}" = "xno"], [
3885     AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
3886   ])
3887 fi
3888 AM_CONDITIONAL(HAVE_DMGBUILD, [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
3889
3890 dnl
3891 dnl  VideoToolbox plugins
3892 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3893     VLC_ADD_PLUGIN([videotoolbox])
3894     VLC_ADD_PLUGIN([cvpx])
3895   ])
3896
3897 dnl
3898 dnl  AudioToolbox MIDI plugin
3899 AC_CHECK_HEADERS([AudioToolbox/AudioToolbox.h], [
3900   VLC_ADD_PLUGIN([audiotoolboxmidi])
3901 ])
3902
3903 dnl
3904 dnl  ncurses module
3905 dnl
3906 AC_ARG_ENABLE(ncurses,
3907 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3908 have_ncurses="no"
3909 AS_IF([test "${enable_ncurses}" != "no"] ,[
3910   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3911     have_ncurses="yes"
3912     ALIASES="${ALIASES} nvlc"
3913   ], [
3914     AS_IF([test -n "${enable_ncurses}"], [
3915       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3916     ])
3917   ])
3918 ])
3919 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3920
3921 dnl
3922 dnl  Lirc plugin
3923 dnl
3924 AC_ARG_ENABLE(lirc,
3925   [  --enable-lirc           lirc support (default disabled)])
3926 have_lirc="no"
3927 AS_IF([test "${enable_lirc}" = "yes"], [
3928   AC_CHECK_HEADER(lirc/lirc_client.h, [
3929     AC_CHECK_LIB(lirc_client, lirc_init, [
3930       have_lirc="yes"
3931     ])
3932   ])
3933 ])
3934 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3935
3936 dnl
3937 dnl  SRT plugin
3938 dnl
3939 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.2.2], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
3940
3941 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3942 dnl
3943 dnl  goom visualization plugin
3944 dnl
3945 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3946
3947 dnl
3948 dnl libprojectM visualization plugin
3949 dnl
3950 AC_ARG_ENABLE(projectm,
3951   [  --enable-projectm       projectM visualization plugin (default enabled)])
3952 AS_IF([test "${enable_projectm}" != "no"],
3953   [
3954     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3955     [
3956       VLC_ADD_PLUGIN([projectm])
3957       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3958         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3959         [ AC_MSG_WARN( [Using libprojectM version 1] )
3960       ])
3961     ],[
3962       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3963     ])
3964   ])
3965
3966 dnl
3967 dnl Vovoid VSXu visualization plugin
3968 dnl
3969 AC_ARG_ENABLE(vsxu,
3970   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3971 AS_IF([test "${enable_vsxu}" != "no"],
3972   [
3973     PKG_CHECK_MODULES(VSXU, libvsxu,
3974     [
3975       VLC_ADD_PLUGIN([vsxu])
3976     ],[
3977       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3978     ])
3979   ])
3980
3981 EXTEND_HELP_STRING([Service Discovery plugins:])
3982 dnl
3983 dnl  Avahi-Zeroconf services discovery
3984 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
3985
3986 dnl
3987 dnl  libudev services discovery
3988 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3989
3990 dnl
3991 dnl MTP devices services discovery
3992 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3993
3994 dnl
3995 dnl UPnP Plugin (Intel SDK)
3996 dnl
3997 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3998
3999 dnl
4000 dnl mDNS using libmicrodns
4001 dnl
4002 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4003
4004
4005 EXTEND_HELP_STRING([Misc options:])
4006
4007 dnl
4008 dnl  libxml2 module
4009 dnl
4010 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4011
4012
4013 dnl
4014 dnl libgcrypt
4015 dnl
4016 AC_ARG_ENABLE(libgcrypt,
4017   [  --disable-libgcrypt     gcrypt support (default enabled)])
4018 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4019 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4020
4021 # require libgcrypt >= 1.6.0
4022 AS_IF([test "${enable_libgcrypt}" != "no"], [
4023   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4024     VLC_SAVE_FLAGS
4025     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4026     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4027 [#include <gcrypt.h>
4028 #if GCRYPT_VERSION_NUMBER < 0x010600
4029 #error
4030 #endif]])], [
4031       ac_cv_lib_gcrypt=yes
4032     ], [
4033       ac_cv_lib_gcrypt=no
4034     ])
4035     VLC_RESTORE_FLAGS
4036   ])
4037
4038   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4039     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4040   ], [
4041     AS_IF([test "${enable_libgcrypt}" = "yes"], [
4042       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4043     ])
4044   ])
4045 ])
4046
4047 AS_IF([test -z "$GCRYPT_LIBS"], [
4048   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4049 ])
4050
4051 AC_SUBST(GCRYPT_CFLAGS)
4052 AC_SUBST(GCRYPT_LIBS)
4053 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4054
4055 dnl
4056 dnl TLS/SSL
4057 dnl
4058 AC_ARG_ENABLE(gnutls,
4059   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4060 AS_IF([test "${enable_gnutls}" != "no"], [
4061   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.3.6], [
4062     VLC_ADD_PLUGIN([gnutls])
4063   ], [
4064     AS_IF([test -n "${enable_gnutls}"], [
4065       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4066     ])
4067   ])
4068 ])
4069
4070
4071 dnl
4072 dnl Taglib plugin
4073 dnl
4074 AC_ARG_ENABLE(taglib,
4075   [AS_HELP_STRING([--disable-taglib],
4076     [do not use TagLib (default enabled)])])
4077 AS_IF([test "${enable_taglib}" != "no"], [
4078   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4079     VLC_ADD_PLUGIN([taglib])
4080   ], [
4081     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4082 ])
4083
4084 dnl
4085 dnl  libsecret
4086 dnl
4087 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4088
4089 dnl
4090 dnl  kwallet
4091 dnl
4092 AC_ARG_ENABLE(kwallet,
4093   [AS_HELP_STRING([--enable-kwallet],
4094     [use kwallet (via D-Bus) for keystore (default enabled)])])
4095 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4096   VLC_ADD_PLUGIN([kwallet])
4097 ])
4098
4099 dnl
4100 dnl update checking system
4101 dnl
4102 AC_ARG_ENABLE(update-check,
4103   [  --enable-update-check   update checking system (default disabled)])
4104 if test "${enable_update_check}" = "yes"
4105 then
4106  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4107     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4108 fi
4109 AM_CONDITIONAL(UPDATE_CHECK, [test "${enable_update_check}" = "yes"])
4110
4111 dnl
4112 dnl OS X notification plugin
4113 dnl
4114 AC_ARG_ENABLE(osx_notifications,
4115   [AS_HELP_STRING([--enable-osx-notifications],
4116     [macOS notification plugin (default disabled)])],,
4117   [enable_osx_notifications=no])
4118 AS_IF([test "${enable_osx_notifications}" != "no"], [
4119   VLC_ADD_PLUGIN([osx_notifications])
4120 ])
4121
4122 dnl
4123 dnl Libnotify notification plugin
4124 dnl
4125 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-3.0], [libnotify notification], [auto])
4126
4127 dnl
4128 dnl  libplacebo support
4129 dnl
4130 AC_ARG_ENABLE(libplacebo,
4131   [AS_HELP_STRING([--disable-libplacebo],
4132       [disable libplacebo support (default auto)])])
4133
4134 AS_IF([test "$enable_libplacebo" != "no"], [
4135   PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.2.1], [
4136     AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
4137   ], [
4138     AS_IF([test -n "${enable_libplacebo}"], [
4139       AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
4140     ])
4141     enable_libplacebo="no"
4142   ])
4143 ])
4144 AM_CONDITIONAL(HAVE_LIBPLACEBO, [test "$enable_libplacebo" != "no"])
4145
4146 PKG_ENABLE_MODULES_VLC([MEDIALIBRARY], [medialibrary], [medialibrary], (medialibrary support), [auto])
4147
4148 dnl
4149 dnl  Endianness check
4150 dnl
4151 AC_C_BIGENDIAN
4152 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4153   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4154 ], [
4155   DEFS_BIGENDIAN=""
4156 ])
4157 AC_SUBST(DEFS_BIGENDIAN)
4158
4159 dnl
4160 dnl Where to install KDE solid .desktop
4161 dnl
4162 AC_ARG_WITH(kde-solid,
4163   AS_HELP_STRING([--with-kde-solid=PATH],
4164                  [KDE Solid actions directory (auto)]),, [
4165
4166 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4167   with_kde_solid="yes"
4168 fi
4169 ])
4170 soliddatadir=""
4171 AS_IF([test "${with_kde_solid}" != "no"], [
4172   AS_IF([test "${with_kde_solid}" = "yes"], [
4173     kde4datadir="`${KDE4_CONFIG} --install data`"
4174     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4175     soliddatadir="${kde4datadir}/solid/actions"
4176   ], [
4177     soliddatadir="${with_kde_solid}"
4178   ])
4179 ])
4180 AC_SUBST(soliddatadir)
4181 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4182
4183 dnl
4184 dnl  Find tools for win32 packaging
4185 dnl
4186 AS_IF([test "${SYS}" = "mingw32"], [
4187     dnl
4188     dnl Find makensis required to build the NSIS installer
4189     dnl
4190     nsis_major_required="3"
4191     nsis_version_ok="no"
4192     AC_PATH_PROG([MAKENSIS], [makensis], [no])
4193     AS_IF([test "$MAKENSIS" != "no"], [
4194         # Check version
4195         AC_MSG_CHECKING([makensis version])
4196         nsis_version=$($MAKENSIS -VERSION)
4197         AC_MSG_RESULT([$nsis_version])
4198         nsis_version_major=$(echo "$nsis_version" | awk -F \. '{print $1}' | sed 's/v//')
4199         # Check if major version is a valid number
4200         AS_IF([test -n "$nsis_version_major" && \
4201                test "$nsis_version_major" -eq "$nsis_version_major" 2> /dev/null], [
4202             # Do the version check using major version
4203             AS_IF([test "$nsis_version_major" -lt "$nsis_major_required"], [
4204                 AC_MSG_WARN([makensis too old, (needs ${nsis_major_required}.x, have ${nsis_version_major}.x)])
4205             ], [
4206                 nsis_version_ok="yes"
4207             ])
4208         ], [
4209             AC_MSG_WARN([failed to check the makensis version])
4210         ])
4211     ])
4212     dnl
4213     dnl Find 7zip
4214     dnl
4215     AC_PATH_PROG([SEVENZIP], [7z], [7z])
4216 ])
4217 AM_CONDITIONAL(HAVE_MAKENSIS, [test "x$MAKENSIS" != "xno" && test "$nsis_version_ok" = "yes"])
4218
4219 dnl
4220 dnl Check wether we have the PROCESS_MITIGATION_IMAGE_LOAD_POLICY
4221 dnl It should only be available when building for win10, but some SDKs define it unconditionnaly
4222 dnl
4223 if test "${SYS}" = "mingw32"; then
4224     AC_CHECK_TYPES([PROCESS_MITIGATION_IMAGE_LOAD_POLICY],,,[#include <windows.h>])
4225 fi
4226
4227 EXTEND_HELP_STRING([Components:])
4228
4229 dnl
4230 dnl  the VLC binary
4231 dnl
4232 AC_ARG_ENABLE(vlc,
4233   [  --enable-vlc            build the VLC media player (default enabled)])
4234 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4235
4236 dnl
4237 dnl Fuzzer (at the end in order to don't mess dependencies FLAGS)
4238 dnl
4239 AS_VAR_IF(with_libfuzzer, no, [], [
4240     LIBS="-lstdc++ ${LIBM} -L${with_libfuzzer} -lFuzzer"
4241     AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc-guard, [
4242         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard])
4243         AX_APPEND_FLAG([-fsanitize-coverage=trace-pc-guard], [CXXFLAGS])
4244         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp])
4245         AX_APPEND_COMPILE_FLAGS([-fsanitize-coverage=trace-cmp], [CXXFLAGS])
4246     ], [
4247         AX_CHECK_COMPILE_FLAG(-fsanitize-coverage=trace-pc, [
4248             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc])
4249             AX_APPEND_FLAG([-fsanitize-coverage=trace-pc], [CXXFLAGS])
4250         ], [
4251             AC_MSG_ERROR([Sanitizer coverage not supported by your compiler])
4252         ])
4253     ])
4254 ])
4255
4256 dnl
4257 dnl  Stuff used by the program
4258 dnl
4259 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4260 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4261 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4262 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4263 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4264 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4265 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4266 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4267 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4268 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4269 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4270 AC_SUBST(COPYRIGHT_MESSAGE)
4271 AC_SUBST(VERSION_MESSAGE)
4272 AC_SUBST(VERSION_MAJOR)
4273 AC_SUBST(VERSION_MINOR)
4274 AC_SUBST(VERSION_REVISION)
4275 AC_SUBST(VERSION_EXTRA)
4276 AC_SUBST(COPYRIGHT_YEARS)
4277 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4278 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4279 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4280 dnl
4281 dnl  Handle substvars that use $(top_srcdir)
4282 dnl
4283 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4284
4285 dnl
4286 dnl  Configuration is finished
4287 dnl
4288 AC_SUBST(SYS)
4289 AC_SUBST(ARCH)
4290 AC_SUBST(ALIASES)
4291 AC_SUBST(ASM)
4292 AC_SUBST(MOC)
4293 AC_SUBST(RCC)
4294 AC_SUBST(UIC)
4295 AC_SUBST(WINDRES)
4296 AC_SUBST(WINE_SDK_PATH)
4297 AC_SUBST(LIBEXT)
4298 AC_SUBST(AM_CPPFLAGS)
4299 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4300 AC_SUBST(FILE_LIBVLCCORE_DLL)
4301 AC_SUBST(FILE_LIBVLC_DLL)
4302
4303 AC_CONFIG_FILES([
4304   Makefile
4305   doc/Makefile
4306   modules/Makefile
4307   m4/Makefile
4308   po/Makefile.in
4309   share/Makefile
4310   compat/Makefile
4311   src/Makefile
4312   lib/Makefile
4313   bin/Makefile
4314   test/Makefile
4315   modules/hw/mmal/Makefile
4316   share/vlc.appdata.xml.in
4317 ])
4318
4319 AM_COND_IF([HAVE_WIN32], [
4320   AC_CONFIG_FILES([
4321     extras/package/win32/NSIS/spad.nsi
4322     extras/package/win32/NSIS/vlc.win32.nsi
4323     extras/package/win32/msi/config.wxi
4324   ])
4325 ])
4326
4327 AM_COND_IF([HAVE_DARWIN], [
4328   AC_CONFIG_FILES([
4329     modules/gui/macosx/UI/InfoPlist.strings:modules/gui/macosx/Resources/InfoPlist.strings.in
4330     share/macosx/Info.plist:share/Info.plist.in
4331   ])
4332 ])
4333
4334 dnl Generate makefiles
4335 AC_OUTPUT
4336
4337 dnl Do we have to use make or gmake ?
4338 if make --version 2>&1|grep -q GNU
4339 then
4340     # GNU make, all seems good
4341     MAKE=make
4342 else
4343     # Known GNU make alias (on BSD)
4344     MAKE=gmake
4345 fi
4346 dnl Shortcut to nice compile message
4347 if test -n $SHELL; then
4348   SHELL=${CONFIG_SHELL-/bin/sh}
4349 fi
4350 rm -f compile
4351 compile_top_srcdir=`sed -ne "s/^top_srcdir *= *//p" < Makefile`
4352 echo "#! $SHELL
4353 rm -f .error\$\$
4354 ERROR=0
4355 export PATH=\"$PATH\" LANG=C
4356 ($MAKE V=1 \$@ 2>&1 || touch .error\$\$)| $compile_top_srcdir/extras/buildsystem/make.pl
4357 test -f .error\$\$ && ERROR=1
4358 rm -f .error\$\$
4359 exit \$ERROR" >compile
4360 chmod a+x compile
4361
4362 echo "
4363 libvlc configuration
4364 --------------------
4365 version               : ${VERSION}
4366 system                : ${SYS}
4367 architecture          : ${ARCH}
4368 optimizations         : ${enable_optimizations}"
4369 if test "${enable_vlc}" != "no"; then
4370 echo "vlc aliases           :${ALIASES}"
4371 else
4372 echo "build vlc executable  : no"
4373 fi
4374 echo "
4375 To build vlc and its plugins, type \`$MAKE', or \`./compile' if you like nice colors."