configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([spice-vdagent], [0.17.0])
   3 AC_CONFIG_SRCDIR([configure.ac])
   4
   5 AM_CONFIG_HEADER([src/config.h])
   6
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip subdir-objects])
   8 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   9
  10 AC_PROG_CC
  11 AM_PROG_CC_C_O
  12 AC_HEADER_STDC
  13 AC_SYS_LARGEFILE
  14 AC_PROG_INSTALL
  15 AC_PROG_LN_S
  16 AC_DEFINE(_GNU_SOURCE, [1], [Enable GNU extensions])
  17 PKG_PROG_PKG_CONFIG
  18
  19 AC_ARG_WITH([session-info],
  20   [AS_HELP_STRING([--with-session-info=@<:@auto/console-kit/systemd/none@:>@],
  21                   [Session-info source to use @<:@default=auto@:>@])],
  22   [case "$with_session_info" in
  23      auto|console-kit|systemd|none) ;;
  24      *) AC_MSG_ERROR([invalid session-info type specified]) ;;
  25    esac],
  26   [with_session_info="auto"])
  27
  28 dnl based on libvirt configure --init-script
  29 AC_MSG_CHECKING([for init script flavor])
  30 AC_ARG_WITH([init-script],
  31   [AC_HELP_STRING(
  32      [--with-init-script=@<:@redhat/systemd/systemd+redhat/check@:>@],
  33      [Style of init script to install @<:@default=check@:>@])],
  34      [],[with_init_script=check])
  35 init_redhat=no
  36 init_systemd=no
  37 case "$with_init_script" in
  38     systemd+redhat)
  39        init_redhat=yes
  40        init_systemd=yes
  41        ;;
  42     systemd)
  43        init_systemd=yes
  44        ;;
  45     redhat)
  46        init_redhat=yes
  47        ;;
  48     none)
  49        ;;
  50     check)
  51        with_init_script=none
  52        if test "$cross_compiling" != yes && test -f /etc/redhat-release; then
  53           init_redhat=yes
  54           with_init_script=redhat
  55        fi
  56        ;;
  57     *)
  58        AC_MSG_ERROR([Unknown initscript flavour $with_init_script])
  59     ;;
  60 esac
  61 AM_CONDITIONAL([INIT_SCRIPT_RED_HAT], test "$init_redhat" = "yes")
  62 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], test "$init_systemd" = "yes")
  63 AC_MSG_RESULT($with_init_script)
  64
  65 if test "x$init_systemd" = "xyes"; then
  66   SYSTEMDSYSTEMUNITDIR=`${PKG_CONFIG} systemd --variable=systemdsystemunitdir`
  67   AC_SUBST(SYSTEMDSYSTEMUNITDIR)
  68 fi
  69
  70 AC_ARG_ENABLE([pciaccess],
  71               [AS_HELP_STRING([--enable-pciaccess], [Enable libpciaccess use for auto generation of Xinerama xorg.conf (default: yes)])],
  72               [enable_pciaccess="$enableval"],
  73               [enable_pciaccess="yes"])
  74
  75 AC_ARG_ENABLE([static-uinput],
  76               [AS_HELP_STRING([--enable-static-uinput], [Enable use of a fixed, static uinput device for X-servers without hotplug support (default: no)])],
  77               [enable_static_uinput="$enableval"],
  78               [enable_static_uinput="no"])
  79
  80 PKG_CHECK_MODULES([GLIB2], [glib-2.0 >= 2.28])
  81 PKG_CHECK_MODULES(X, [xfixes xrandr >= 1.3 xinerama x11])
  82 PKG_CHECK_MODULES(SPICE, [spice-protocol >= 0.12.8])
  83 PKG_CHECK_MODULES(ALSA, [alsa >= 1.0.22])
  84 PKG_CHECK_MODULES([DBUS], [dbus-1])
  85
  86 if test "$with_session_info" = "auto" || test "$with_session_info" = "systemd"; then
  87     PKG_CHECK_MODULES([LIBSYSTEMD_LOGIN],
  88                       [libsystemd >= 209],
  89                       [have_libsystemd_login="yes"],
  90                       [have_libsystemd_login="no"])
  91     if test "$have_libsystemd_login" = "no"; then
  92         # for backward compatibility with older systemd versions
  93         PKG_CHECK_MODULES([LIBSYSTEMD_LOGIN],
  94                           [libsystemd-login >= 42],
  95                           [have_libsystemd_login="yes"],
  96                           [have_libsystemd_login="no"])
  97     fi
  98     if test x"$have_libsystemd_login" = "xno" && test "$with_session_info" = "systemd"; then
  99         AC_MSG_ERROR([libsystemd-login support explicitly requested, but some required packages are not available])
 100     fi
 101     if test x"$have_libsystemd_login" = "xyes"; then
 102         AC_DEFINE(HAVE_LIBSYSTEMD_LOGIN, [1], [If defined, vdagentd will be compiled with libsystemd-login support])
 103         with_session_info="systemd"
 104     fi
 105 else
 106     have_libsystemd_login="no"
 107 fi
 108 AM_CONDITIONAL(HAVE_LIBSYSTEMD_LOGIN, test x"$have_libsystemd_login" = "xyes")
 109
 110 if test "$with_session_info" = "auto" || test "$with_session_info" = "console-kit"; then
 111     AC_DEFINE([HAVE_CONSOLE_KIT], [1], [If defined, vdagentd will be compiled with ConsoleKit support])
 112     have_console_kit="yes"
 113     with_session_info="console-kit"
 114 else
 115     have_console_kit="no"
 116 fi
 117 AM_CONDITIONAL(HAVE_CONSOLE_KIT, test x"$have_console_kit" = "xyes")
 118
 119 if test x"$enable_pciaccess" = "xyes" ; then
 120     PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
 121     AC_DEFINE([HAVE_PCIACCESS], [1], [If defined, vdagentd will be compiled with pciaccess support] )
 122 fi
 123 AM_CONDITIONAL(HAVE_PCIACCESS, test x"$enable_pciaccess" = "xyes")
 124
 125 if test x"$enable_static_uinput" = "xyes" ; then
 126     AC_DEFINE([WITH_STATIC_UINPUT], [1], [If defined, vdagentd will use a static uinput device] )
 127 fi
 128
 129 # If no CFLAGS are set, set some sane default CFLAGS
 130 if test "$ac_test_CFLAGS" != set; then
 131   DEFAULT_CFLAGS="-Wall -Werror -Wp,-D_FORTIFY_SOURCE=2 -fno-strict-aliasing -fstack-protector --param=ssp-buffer-size=4"
 132   for F in $DEFAULT_CFLAGS; do
 133     AC_MSG_CHECKING([whether $CC supports $F])
 134     save_CFLAGS="$CFLAGS"
 135     CFLAGS="$CFLAGS $F"
 136     AC_COMPILE_IFELSE([AC_LANG_SOURCE([ ])], [cc_flag=yes], [cc_flag=no])
 137     if test "x$cc_flag" != "xyes"; then
 138       CFLAGS="$save_CFLAGS"
 139     fi
 140     AC_MSG_RESULT([$cc_flag])
 141   done
 142 fi
 143
 144 AC_ARG_ENABLE([pie],
 145   AS_HELP_STRING([--enable-pie=@<:@auto/yes/no@:>@],
 146                  [Enable position-independent-executable support (for spice-vdagentd)@<:@default=auto@:>@]),
 147   [],
 148   [enable_pie="auto"])
 149
 150 if test "x$enable_pie" != "xno"; then
 151   save_CFLAGS="$CFLAGS"
 152   save_LDFLAGS="$LDFLAGS"
 153   CFLAGS="$CFLAGS -fPIE"
 154   LDFLAGS="$LDFLAGS -pie -Wl,-z,relro -Wl,-z,now"
 155   AC_MSG_CHECKING([for PIE support])
 156   AC_LINK_IFELSE([AC_LANG_SOURCE([int main () { return 0; }])],
 157                  [have_pie=yes],
 158                  [have_pie=no])
 159   AC_MSG_RESULT([$have_pie])
 160   if test "x$have_pie" = "xno" && test "x$enable_pie" = "xyes"; then
 161     AC_MSG_ERROR([pie support explicitly requested, but your toolchain does not support it])
 162   fi
 163   if test "x$have_pie" = "xyes"; then
 164     PIE_CFLAGS="-fPIE"
 165     PIE_LDFLAGS="-pie -Wl,-z,relro -Wl,-z,now"
 166     AC_SUBST(PIE_CFLAGS)
 167     AC_SUBST(PIE_LDFLAGS)
 168   fi
 169   CFLAGS="$save_CFLAGS"
 170   LDFLAGS="$save_LDFLAGS"
 171 else
 172   have_pie=no
 173 fi
 174
 175 AC_CONFIG_FILES([
 176 Makefile
 177 data/spice-vdagent.1
 178 data/spice-vdagentd.1
 179 ])
 180 AC_OUTPUT
 181
 182 dnl ==========================================================================
 183 AC_MSG_NOTICE([
 184
 185         spice-vdagent $VERSION
 186         ====================
 187
 188         prefix:                   ${prefix}
 189         c compiler:               ${CC}
 190
 191         session-info:             ${with_session_info}
 192         pciaccess:                ${enable_pciaccess}
 193         static uinput:            ${enable_static_uinput}
 194         vdagentd pie + relro:     ${have_pie}
 195
 196         install RH initscript:    ${init_redhat}
 197         install systemd service:  ${init_systemd}
 198
 199         Now type 'make' to build $PACKAGE
 200
 201 ])