plugin/vcscommand.vim

   1 " vim600: set foldmethod=marker:
   2 "
   3 " Vim plugin to assist in working with files under control of CVS or SVN.
   4 "
   5 " Version:       Beta 20
   6 " Maintainer:    Bob Hiestand <bob.hiestand@gmail.com>
   7 " License:
   8 " Copyright (c) 2007 Bob Hiestand
   9 "
  10 " Permission is hereby granted, free of charge, to any person obtaining a copy
  11 " of this software and associated documentation files (the "Software"), to
  12 " deal in the Software without restriction, including without limitation the
  13 " rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
  14 " sell copies of the Software, and to permit persons to whom the Software is
  15 " furnished to do so, subject to the following conditions:
  16 "
  17 " The above copyright notice and this permission notice shall be included in
  18 " all copies or substantial portions of the Software.
  19 "
  20 " THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  21 " IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  22 " FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  23 " AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  24 " LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  25 " FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  26 " IN THE SOFTWARE.
  27 "
  28 " Section: Documentation {{{1
  29 "
  30 " Provides functions to invoke various source control commands on the current
  31 " file (either the current buffer, or, in the case of an directory buffer, the
  32 " directory and all subdirectories associated with the current buffer).  The
  33 " output of the commands is captured in a new scratch window.
  34 "
  35 " This plugin needs additional extension plugins, each  specific to a source
  36 " control system, to function.  Those plugins should be placed in a
  37 " subdirectory of the standard plugin directory named 'vcscommand'.  Several
  38 " options include the name of the version control system in the option name.
  39 " Such options use the placeholder text '{VCSType}', which would be replaced
  40 " in actual usage with 'CVS' or 'SVN', for instance.
  41 "
  42 " Command documentation {{{2
  43 "
  44 " VCSAdd           Adds the current file to source control.
  45 "
  46 " VCSAnnotate      Displays the current file with each line annotated with the
  47 "                  version in which it was most recently changed.  If an
  48 "                  argument is given, the argument is used as a revision
  49 "                  number to display.  If not given an argument, it uses the
  50 "                  most recent version of the file on the current branch.
  51 "                  Additionally, if the current buffer is a VCSAnnotate buffer
  52 "                  already, the version number on the current line is used.
  53 "
  54 " VCSBlame         Alias for 'VCSAnnotate'.
  55 "
  56 " VCSCommit[!]     Commits changes to the current file to source control.
  57 "
  58 "                  If called with arguments, the arguments are the log message.
  59 "
  60 "                  If '!' is used, an empty log message is committed.
  61 "
  62 "                  If called with no arguments, this is a two-step command.
  63 "                  The first step opens a buffer to accept a log message.
  64 "                  When that buffer is written, it is automatically closed and
  65 "                  the file is committed using the information from that log
  66 "                  message.  The commit can be abandoned if the log message
  67 "                  buffer is deleted or wiped before being written.
  68 "
  69 " VCSDelete        Deletes the current file and removes it from source control.
  70 "
  71 " VCSDiff          With no arguments, this displays the differences between
  72 "                  the current file and its parent version under source
  73 "                  control in a new scratch buffer.
  74 "
  75 "                  With one argument, the diff is performed on the
  76 "                  current file against the specified revision.
  77 "
  78 "                  With two arguments, the diff is performed between the
  79 "                  specified revisions of the current file.
  80 "
  81 "                  This command uses the 'VCSCommand{VCSType}DiffOpt' variable
  82 "                  to specify diff options.  If that variable does not exist,
  83 "                  a plugin-specific default is used.  If you wish to have no
  84 "                  options, then set it to the empty string.
  85 "
  86 " VCSGotoOriginal  Jumps to the source buffer if the current buffer is a VCS
  87 "                  scratch buffer.  If VCSGotoOriginal[!] is used, remove all
  88 "                  VCS scratch buffers associated with the original file.
  89 "
  90 " VCSInfo          Displays extended information about the current file in a
  91 "                  new scratch buffer.
  92 "
  93 " VCSLock          Locks the current file in order to prevent other users from
  94 "                  concurrently modifying it.  The exact semantics of this
  95 "                  command depend on the underlying VCS.
  96 "
  97 " VCSLog           Displays the version history of the current file in a new
  98 "                  scratch buffer.
  99 "
 100 " VCSRemove        Alias for 'VCSDelete'.
 101 "
 102 " VCSRevert        Replaces the modified version of the current file with the
 103 "                  most recent version from the repository.
 104 "
 105 " VCSReview        Displays a particular version of the current file in a new
 106 "                  scratch buffer.  If no argument is given, the most recent
 107 "                  version of the file on the current branch is retrieved.
 108 "
 109 " VCSStatus        Displays versioning information about the current file in a
 110 "                  new scratch buffer.
 111 "
 112 " VCSUnlock        Unlocks the current file in order to allow other users from
 113 "                  concurrently modifying it.  The exact semantics of this
 114 "                  command depend on the underlying VCS.
 115 "
 116 " VCSUpdate        Updates the current file with any relevant changes from the
 117 "                  repository.
 118 "
 119 " VCSVimDiff       Uses vimdiff to display differences between versions of the
 120 "                  current file.
 121 "
 122 "                  If no revision is specified, the most recent version of the
 123 "                  file on the current branch is used.  With one argument,
 124 "                  that argument is used as the revision as above.  With two
 125 "                  arguments, the differences between the two revisions is
 126 "                  displayed using vimdiff.
 127 "
 128 "                  With either zero or one argument, the original buffer is
 129 "                  used to perform the vimdiff.  When the scratch buffer is
 130 "                  closed, the original buffer will be returned to normal
 131 "                  mode.
 132 "
 133 "                  Once vimdiff mode is started using the above methods,
 134 "                  additional vimdiff buffers may be added by passing a single
 135 "                  version argument to the command.  There may be up to 4
 136 "                  vimdiff buffers total.
 137 "
 138 "                  Using the 2-argument form of the command resets the vimdiff
 139 "                  to only those 2 versions.  Additionally, invoking the
 140 "                  command on a different file will close the previous vimdiff
 141 "                  buffers.
 142 "
 143 " Mapping documentation: {{{2
 144 "
 145 " By default, a mapping is defined for each command.  User-provided mappings
 146 " can be used instead by mapping to <Plug>CommandName, for instance:
 147 "
 148 " nmap ,ca <Plug>VCSAdd
 149 "
 150 " The default mappings are as follow:
 151 "
 152 "   <Leader>ca VCSAdd
 153 "   <Leader>cn VCSAnnotate
 154 "   <Leader>cc VCSCommit
 155 "   <Leader>cD VCSDelete
 156 "   <Leader>cd VCSDiff
 157 "   <Leader>cg VCSGotoOriginal
 158 "   <Leader>cG VCSGotoOriginal!
 159 "   <Leader>ci VCSInfo
 160 "   <Leader>cl VCSLog
 161 "   <Leader>cL VCSLock
 162 "   <Leader>cr VCSReview
 163 "   <Leader>cs VCSStatus
 164 "   <Leader>cu VCSUpdate
 165 "   <Leader>cU VCSUnlock
 166 "   <Leader>cv VCSVimDiff
 167 "
 168 " Options documentation: {{{2
 169 "
 170 " Several variables are checked by the script to determine behavior as follow:
 171 "
 172 " VCSCommandCommitOnWrite
 173 "   This variable, if set to a non-zero value, causes the pending commit to
 174 "   take place immediately as soon as the log message buffer is written.  If
 175 "   set to zero, only the VCSCommit mapping will cause the pending commit to
 176 "   occur.  If not set, it defaults to 1.
 177 "
 178 " VCSCommandDeleteOnHide
 179 "   This variable, if set to a non-zero value, causes the temporary VCS result
 180 "   buffers to automatically delete themselves when hidden.
 181 "
 182 " VCSCommand{VCSType}DiffOpt
 183 "   This variable, if set, determines the options passed to the diff command
 184 "   of the underlying VCS.  Each VCS plugin defines a default value.
 185 "
 186 " VCSCommandDiffSplit
 187 "   This variable overrides the VCSCommandSplit variable, but only for buffers
 188 "   created with VCSVimDiff.
 189 "
 190 " VCSCommandDisableMappings
 191 "   This variable, if set to a non-zero value, prevents the default command
 192 "   mappings from being set.
 193 "
 194 " VCSCommandDisableExtensionMappings
 195 "   This variable, if set to a non-zero value, prevents the default command
 196 "   mappings from being set for commands specific to an individual VCS.
 197 "
 198 " VCSCommandEdit
 199 "   This variable controls whether to split the current window to display a
 200 "   scratch buffer ('split'), or to display it in the current buffer ('edit').
 201 "   If not set, it defaults to 'split'.
 202 "
 203 " VCSCommandEnableBufferSetup
 204 "   This variable, if set to a non-zero value, activates VCS buffer management
 205 "   mode.  This mode means that the buffer variable 'VCSRevision' is set if
 206 "   the file is VCS-controlled.  This is useful for displaying version
 207 "   information in the status bar.  Additional options may be set by
 208 "   individual VCS plugins.
 209 "
 210 " VCSCommandResultBufferNameExtension
 211 "   This variable, if set to a non-blank value, is appended to the name of the
 212 "   VCS command output buffers.  For example, '.vcs'.  Using this option may
 213 "   help avoid problems caused by autocommands dependent on file extension.
 214 "
 215 " VCSCommandResultBufferNameFunction
 216 "   This variable, if set, specifies a custom function for naming VCS command
 217 "   output buffers.  This function will be passed the following arguments:
 218 "
 219 "   command - name of the VCS command being executed (such as 'Log' or
 220 "   'Diff').
 221 "
 222 "   originalBuffer - buffer number of the source file.
 223 "
 224 "   vcsType - type of VCS controlling this file (such as 'CVS' or 'SVN').
 225 "
 226 "   statusText - extra text associated with the VCS action (such as version
 227 "   numbers).
 228 "
 229 " VCSCommandSplit
 230 "   This variable controls the orientation of the various window splits that
 231 "   may occur (such as with VCSVimDiff, when using a VCS command on a VCS
 232 "   command buffer, or when the 'VCSCommandEdit' variable is set to 'split'.
 233 "   If set to 'horizontal', the resulting windows will be on stacked on top of
 234 "   one another.  If set to 'vertical', the resulting windows will be
 235 "   side-by-side.  If not set, it defaults to 'horizontal' for all but
 236 "   VCSVimDiff windows.
 237 "
 238 " Event documentation {{{2
 239 "   For additional customization, VCSCommand.vim uses User event autocommand
 240 "   hooks.  Each event is in the VCSCommand group, and different patterns
 241 "   match the various hooks.
 242 "
 243 "   For instance, the following could be added to the vimrc to provide a 'q'
 244 "   mapping to quit a VCS scratch buffer:
 245 "
 246 "   augroup VCSCommand
 247 "     au VCSCommand User VCSBufferCreated silent! nmap <unique> <buffer> q :bwipeout<cr>
 248 "   augroup END
 249 "
 250 "   The following hooks are available:
 251 "
 252 "   VCSBufferCreated           This event is fired just after a VCS command
 253 "                              output buffer is created.  It is executed
 254 "                              within the context of the new buffer.
 255 "
 256 "   VCSBufferSetup             This event is fired just after VCS buffer setup
 257 "                              occurs, if enabled.
 258 "
 259 "   VCSPluginInit              This event is fired when the VCSCommand plugin
 260 "                              first loads.
 261 "
 262 "   VCSPluginFinish            This event is fired just after the VCSCommand
 263 "                              plugin loads.
 264 "
 265 "   VCSVimDiffFinish           This event is fired just after the VCSVimDiff
 266 "                              command executes to allow customization of,
 267 "                              for instance, window placement and focus.
 268 "
 269 " Section: Plugin header {{{1
 270
 271 " loaded_VCSCommand is set to 1 when the initialization begins, and 2 when it
 272 " completes.  This allows various actions to only be taken by functions after
 273 " system initialization.
 274
 275 if exists('loaded_VCSCommand')
 276         finish
 277 endif
 278 let loaded_VCSCommand = 1
 279
 280 if v:version < 700
 281         echohl WarningMsg|echomsg 'VCSCommand requires at least VIM 7.0'|echohl None
 282         finish
 283 endif
 284
 285 let s:save_cpo=&cpo
 286 set cpo&vim
 287
 288 " Section: Event group setup {{{1
 289
 290 augroup VCSCommand
 291 augroup END
 292
 293 augroup VCSCommandCommit
 294 augroup END
 295
 296 " Section: Plugin initialization {{{1
 297 silent do VCSCommand User VCSPluginInit
 298
 299 " Section: Script variable initialization {{{1
 300
 301 " plugin-specific information:  {vcs -> [script, {command -> function}, {key -> mapping}]}
 302 let s:plugins = {}
 303
 304 " temporary values of overridden configuration variables
 305 let s:optionOverrides = {}
 306
 307 " state flag used to vary behavior of certain automated actions
 308 let s:isEditFileRunning = 0
 309
 310 " commands needed to restore diff buffers to their original state
 311 unlet! s:vimDiffRestoreCmd
 312
 313 " original buffer currently reflected in vimdiff windows
 314 unlet! s:vimDiffSourceBuffer
 315
 316 "
 317 unlet! s:vimDiffScratchList
 318
 319 " Section: Utility functions {{{1
 320
 321 " Function: s:ReportError(mapping) {{{2
 322 " Displays the given error in a consistent faction.  This is intended to be
 323 " invoked from a catch statement.
 324
 325 function! s:ReportError(error)
 326         echohl WarningMsg|echomsg 'VCSCommand:  ' . a:error|echohl None
 327 endfunction
 328
 329 " Function: s:ExecuteExtensionMapping(mapping) {{{2
 330 " Invokes the appropriate extension mapping depending on the type of the
 331 " current buffer.
 332
 333 function! s:ExecuteExtensionMapping(mapping)
 334         let buffer = bufnr('%')
 335         let vcsType = VCSCommandGetVCSType(buffer)
 336         if !has_key(s:plugins, vcsType)
 337                 throw 'Unknown VCS type:  ' . vcsType
 338         endif
 339         if !has_key(s:plugins[vcsType][2], a:mapping)
 340                 throw 'This extended mapping is not defined for ' . vcsType
 341         endif
 342         silent execute 'normal' ':' .  s:plugins[vcsType][2][a:mapping] . "\<CR>"
 343 endfunction
 344
 345 " Function: s:ExecuteVCSCommand(command, argList) {{{2
 346 " Calls the indicated plugin-specific VCS command on the current buffer.
 347 " Returns: buffer number of resulting output scratch buffer, or -1 if an error
 348 " occurs.
 349
 350 function! s:ExecuteVCSCommand(command, argList)
 351         try
 352                 let buffer = bufnr('%')
 353
 354                 let vcsType = VCSCommandGetVCSType(buffer)
 355                 if !has_key(s:plugins, vcsType)
 356                         throw 'Unknown VCS type:  ' . vcsType
 357                 endif
 358
 359                 let originalBuffer = VCSCommandGetOriginalBuffer(buffer)
 360                 let bufferName = bufname(originalBuffer)
 361
 362                 " It is already known that the directory is under VCS control.  No further
 363                 " checks are needed.  Otherwise, perform some basic sanity checks to avoid
 364                 " VCS-specific error messages from confusing things.
 365                 if !isdirectory(bufferName)
 366                         if !filereadable(bufferName)
 367                                 throw 'No such file ' . bufferName
 368                         endif
 369                 endif
 370
 371                 let functionMap = s:plugins[vcsType][1]
 372                 if !has_key(functionMap, a:command)
 373                         throw 'Command ''' . a:command . ''' not implemented for ' . vcsType
 374                 endif
 375                 return functionMap[a:command](a:argList)
 376         catch
 377                 call s:ReportError(v:exception)
 378                 return -1
 379         endtry
 380 endfunction
 381
 382 " Function: s:GenerateResultBufferName(command, originalBuffer, vcsType, statusText) {{{2
 383 " Default method of generating the name for VCS result buffers.  This can be
 384 " overridden with the VCSResultBufferNameFunction variable.
 385
 386 function! s:GenerateResultBufferName(command, originalBuffer, vcsType, statusText)
 387         let fileName = bufname(a:originalBuffer)
 388         let bufferName = a:vcsType . ' ' . a:command
 389         if strlen(a:statusText) > 0
 390                 let bufferName .= ' ' . a:statusText
 391         endif
 392         let bufferName .= ' ' . fileName
 393         let counter = 0
 394         let versionedBufferName = bufferName
 395         while buflisted(versionedBufferName)
 396                 let counter += 1
 397                 let versionedBufferName = bufferName . ' (' . counter . ')'
 398         endwhile
 399         return versionedBufferName
 400 endfunction
 401
 402 " Function: s:GenerateResultBufferNameWithExtension(command, originalBuffer, vcsType, statusText) {{{2
 403 " Method of generating the name for VCS result buffers that uses the original
 404 " file name with the VCS type and command appended as extensions.
 405
 406 function! s:GenerateResultBufferNameWithExtension(command, originalBuffer, vcsType, statusText)
 407         let fileName = bufname(a:originalBuffer)
 408         let bufferName = a:vcsType . ' ' . a:command
 409         if strlen(a:statusText) > 0
 410                 let bufferName .= ' ' . a:statusText
 411         endif
 412         let bufferName .= ' ' . fileName . VCSCommandGetOption('VCSCommandResultBufferNameExtension', '.vcs')
 413         let counter = 0
 414         let versionedBufferName = bufferName
 415         while buflisted(versionedBufferName)
 416                 let counter += 1
 417                 let versionedBufferName = '(' . counter . ') ' . bufferName
 418         endwhile
 419         return versionedBufferName
 420 endfunction
 421
 422 " Function: s:EditFile(command, originalBuffer, statusText) {{{2
 423 " Creates a new buffer of the given name and associates it with the given
 424 " original buffer.
 425
 426 function! s:EditFile(command, originalBuffer, statusText)
 427         let vcsType = getbufvar(a:originalBuffer, 'VCSCommandVCSType')
 428
 429         let nameExtension = VCSCommandGetOption('VCSCommandResultBufferNameExtension', '')
 430         if nameExtension == ''
 431                 let nameFunction = VCSCommandGetOption('VCSCommandResultBufferNameFunction', 's:GenerateResultBufferName')
 432         else
 433                 let nameFunction = VCSCommandGetOption('VCSCommandResultBufferNameFunction', 's:GenerateResultBufferNameWithExtension')
 434         endif
 435
 436         let resultBufferName = call(nameFunction, [a:command, a:originalBuffer, vcsType, a:statusText])
 437
 438         " Protect against useless buffer set-up
 439         let s:isEditFileRunning += 1
 440         try
 441                 let editCommand = VCSCommandGetOption('VCSCommandEdit', 'split')
 442                 if editCommand == 'split'
 443                         if VCSCommandGetOption('VCSCommandSplit', 'horizontal') == 'horizontal'
 444                                 rightbelow split
 445                         else
 446                                 vert rightbelow split
 447                         endif
 448                 endif
 449                 edit `=resultBufferName`
 450                 let b:VCSCommandCommand = a:command
 451                 let b:VCSCommandOriginalBuffer = a:originalBuffer
 452                 let b:VCSCommandSourceFile = bufname(a:originalBuffer)
 453                 let b:VCSCommandVCSType = vcsType
 454
 455                 set buftype=nofile
 456                 set noswapfile
 457                 let &filetype = vcsType . a:command
 458
 459                 if a:statusText != ''
 460                         let b:VCSCommandStatusText = a:statusText
 461                 endif
 462
 463                 if VCSCommandGetOption('VCSCommandDeleteOnHide', 0)
 464                         set bufhidden=delete
 465                 endif
 466         finally
 467                 let s:isEditFileRunning -= 1
 468         endtry
 469
 470 endfunction
 471
 472 " Function: s:SetupBuffer() {{{2
 473 " Attempts to set the b:VCSCommandBufferInfo variable
 474
 475 function! s:SetupBuffer()
 476         if (exists('b:VCSCommandBufferSetup') && b:VCSCommandBufferSetup)
 477                 " This buffer is already set up.
 478                 return
 479         endif
 480
 481         if !isdirectory(@%) && (strlen(&buftype) > 0 || !filereadable(@%))
 482                 " No special status for special buffers other than directory buffers.
 483                 return
 484         endif
 485
 486         if !VCSCommandGetOption('VCSCommandEnableBufferSetup', 0) || s:isEditFileRunning > 0
 487                 unlet! b:VCSCommandBufferSetup
 488                 return
 489         endif
 490
 491         try
 492                 let vcsType = VCSCommandGetVCSType(bufnr('%'))
 493                 let b:VCSCommandBufferInfo = s:plugins[vcsType][1].GetBufferInfo()
 494                 silent do VCSCommand User VCSBufferSetup
 495         catch /No suitable plugin/
 496                 " This is not a VCS-controlled file.
 497                 let b:VCSCommandBufferInfo = []
 498         endtry
 499
 500         let b:VCSCommandBufferSetup = 1
 501 endfunction
 502
 503 " Function: s:MarkOrigBufferForSetup(buffer) {{{2
 504 " Resets the buffer setup state of the original buffer for a given VCS scratch
 505 " buffer.
 506 " Returns:  The VCS buffer number in a passthrough mode.
 507
 508 function! s:MarkOrigBufferForSetup(buffer)
 509         checktime
 510         if a:buffer > 0
 511                 let origBuffer = VCSCommandGetOriginalBuffer(a:buffer)
 512                 " This should never not work, but I'm paranoid
 513                 if origBuffer != a:buffer
 514                         call setbufvar(origBuffer, 'VCSCommandBufferSetup', 0)
 515                 endif
 516         endif
 517         return a:buffer
 518 endfunction
 519
 520 " Function: s:OverrideOption(option, [value]) {{{2
 521 " Provides a temporary override for the given VCS option.  If no value is
 522 " passed, the override is disabled.
 523
 524 function! s:OverrideOption(option, ...)
 525         if a:0 == 0
 526                 call remove(s:optionOverrides[a:option], -1)
 527         else
 528                 if !has_key(s:optionOverrides, a:option)
 529                         let s:optionOverrides[a:option] = []
 530                 endif
 531                 call add(s:optionOverrides[a:option], a:1)
 532         endif
 533 endfunction
 534
 535 " Function: s:WipeoutCommandBuffers() {{{2
 536 " Clears all current VCS output buffers of the specified type for a given source.
 537
 538 function! s:WipeoutCommandBuffers(originalBuffer, VCSCommand)
 539         let buffer = 1
 540         while buffer <= bufnr('$')
 541                 if getbufvar(buffer, 'VCSCommandOriginalBuffer') == a:originalBuffer
 542                         if getbufvar(buffer, 'VCSCommandCommand') == a:VCSCommand
 543                                 execute 'bw' buffer
 544                         endif
 545                 endif
 546                 let buffer = buffer + 1
 547         endwhile
 548 endfunction
 549
 550 " Function: s:VimDiffRestore(vimDiffBuff) {{{2
 551 " Checks whether the given buffer is one whose deletion should trigger
 552 " restoration of an original buffer after it was diffed.  If so, it executes
 553 " the appropriate setting command stored with that original buffer.
 554
 555 function! s:VimDiffRestore(vimDiffBuff)
 556         let s:isEditFileRunning += 1
 557         try
 558                 if exists('s:vimDiffSourceBuffer')
 559                         if a:vimDiffBuff == s:vimDiffSourceBuffer
 560                                 " Original file is being removed.
 561                                 unlet! s:vimDiffSourceBuffer
 562                                 unlet! s:vimDiffRestoreCmd
 563                                 unlet! s:vimDiffScratchList
 564                         else
 565                                 let index = index(s:vimDiffScratchList, a:vimDiffBuff)
 566                                 if index >= 0
 567                                         call remove(s:vimDiffScratchList, index)
 568                                         if len(s:vimDiffScratchList) == 0
 569                                                 if exists('s:vimDiffRestoreCmd')
 570                                                         " All scratch buffers are gone, reset the original.
 571                                                         " Only restore if the source buffer is still in Diff mode
 572
 573                                                         let sourceWinNR = bufwinnr(s:vimDiffSourceBuffer)
 574                                                         if sourceWinNR != -1
 575                                                                 " The buffer is visible in at least one window
 576                                                                 let currentWinNR = winnr()
 577                                                                 while winbufnr(sourceWinNR) != -1
 578                                                                         if winbufnr(sourceWinNR) == s:vimDiffSourceBuffer
 579                                                                                 execute sourceWinNR . 'wincmd w'
 580                                                                                 if getwinvar(0, '&diff')
 581                                                                                         execute s:vimDiffRestoreCmd
 582                                                                                 endif
 583                                                                         endif
 584                                                                         let sourceWinNR = sourceWinNR + 1
 585                                                                 endwhile
 586                                                                 execute currentWinNR . 'wincmd w'
 587                                                         else
 588                                                                 " The buffer is hidden.  It must be visible in order to set the
 589                                                                 " diff option.
 590                                                                 let currentBufNR = bufnr('')
 591                                                                 execute 'hide buffer' s:vimDiffSourceBuffer
 592                                                                 if getwinvar(0, '&diff')
 593                                                                         execute s:vimDiffRestoreCmd
 594                                                                 endif
 595                                                                 execute 'hide buffer' currentBufNR
 596                                                         endif
 597
 598                                                         unlet s:vimDiffRestoreCmd
 599                                                 endif
 600                                                 " All buffers are gone.
 601                                                 unlet s:vimDiffSourceBuffer
 602                                                 unlet s:vimDiffScratchList
 603                                         endif
 604                                 endif
 605                         endif
 606                 endif
 607         finally
 608                 let s:isEditFileRunning -= 1
 609         endtry
 610 endfunction
 611
 612 " Section: Generic VCS command functions {{{1
 613
 614 " Function: s:VCSCommit() {{{2
 615 function! s:VCSCommit(bang, message)
 616         try
 617                 let vcsType = VCSCommandGetVCSType(bufnr('%'))
 618                 if !has_key(s:plugins, vcsType)
 619                         throw 'Unknown VCS type:  ' . vcsType
 620                 endif
 621
 622                 let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
 623
 624                 " Handle the commit message being specified.  If a message is supplied, it
 625                 " is used; if bang is supplied, an empty message is used; otherwise, the
 626                 " user is provided a buffer from which to edit the commit message.
 627
 628                 if strlen(a:message) > 0 || a:bang == '!'
 629                         return s:VCSFinishCommit([a:message], originalBuffer)
 630                 endif
 631
 632                 call s:EditFile('commitlog', originalBuffer, '')
 633                 set ft=vcscommit
 634
 635                 " Create a commit mapping.
 636
 637                 nnoremap <silent> <buffer> <Plug>VCSCommit :call <SID>VCSFinishCommitWithBuffer()<CR>
 638
 639                 silent 0put ='VCS: ----------------------------------------------------------------------'
 640                 silent put ='VCS: Please enter log message.  Lines beginning with ''VCS:'' are removed automatically.'
 641                 silent put ='VCS: To finish the commit, Type <leader>cc (or your own <Plug>VCSCommit mapping)'
 642
 643                 if VCSCommandGetOption('VCSCommandCommitOnWrite', 1) == 1
 644                         set buftype=acwrite
 645                         au VCSCommandCommit BufWriteCmd <buffer> call s:VCSFinishCommitWithBuffer()
 646                         silent put ='VCS: or write this buffer'
 647                 endif
 648
 649                 silent put ='VCS: ----------------------------------------------------------------------'
 650                 $
 651                 set nomodified
 652         catch
 653                 call s:ReportError(v:exception)
 654                 return -1
 655         endtry
 656 endfunction
 657
 658 " Function: s:VCSFinishCommitWithBuffer() {{{2
 659 " Wrapper for s:VCSFinishCommit which is called only from a commit log buffer
 660 " which removes all lines starting with 'VCS:'.
 661
 662 function! s:VCSFinishCommitWithBuffer()
 663         set nomodified
 664         let currentBuffer = bufnr('%')
 665         let logMessageList = getbufline('%', 1, '$')
 666         call filter(logMessageList, 'v:val !~ ''^\s*VCS:''')
 667         let resultBuffer = s:VCSFinishCommit(logMessageList, b:VCSCommandOriginalBuffer)
 668         if resultBuffer >= 0
 669                 execute 'bw' currentBuffer
 670         endif
 671         return resultBuffer
 672 endfunction
 673
 674 " Function: s:VCSFinishCommit(logMessageList, originalBuffer) {{{2
 675 function! s:VCSFinishCommit(logMessageList, originalBuffer)
 676         let shellSlashBak = &shellslash
 677         try
 678                 set shellslash
 679                 let messageFileName = tempname()
 680                 call writefile(a:logMessageList, messageFileName)
 681                 try
 682                         let resultBuffer = s:ExecuteVCSCommand('Commit', [messageFileName])
 683                         if resultBuffer < 0
 684                                 return resultBuffer
 685                         endif
 686                         return s:MarkOrigBufferForSetup(resultBuffer)
 687                 finally
 688                         call delete(messageFileName)
 689                 endtry
 690         finally
 691                 let &shellslash = shellSlashBak
 692         endtry
 693 endfunction
 694
 695 " Function: s:VCSGotoOriginal(bang) {{{2
 696 function! s:VCSGotoOriginal(bang)
 697         let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
 698         if originalBuffer > 0
 699                 let origWinNR = bufwinnr(originalBuffer)
 700                 if origWinNR == -1
 701                         execute 'buffer' originalBuffer
 702                 else
 703                         execute origWinNR . 'wincmd w'
 704                 endif
 705                 if a:bang == '!'
 706                         let buffnr = 1
 707                         let buffmaxnr = bufnr('$')
 708                         while buffnr <= buffmaxnr
 709                                 if getbufvar(buffnr, 'VCSCommandOriginalBuffer') == originalBuffer
 710                                         execute 'bw' buffnr
 711                                 endif
 712                                 let buffnr = buffnr + 1
 713                         endwhile
 714                 endif
 715         endif
 716 endfunction
 717
 718 " Function: s:VCSVimDiff(...) {{{2
 719 function! s:VCSVimDiff(...)
 720         try
 721                 let vcsType = VCSCommandGetVCSType(bufnr('%'))
 722                 if !has_key(s:plugins, vcsType)
 723                         throw 'Unknown VCS type:  ' . vcsType
 724                 endif
 725                 let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
 726                 let s:isEditFileRunning = s:isEditFileRunning + 1
 727                 try
 728                         " If there's already a VimDiff'ed window, restore it.
 729                         " There may only be one VCSVimDiff original window at a time.
 730
 731                         if exists('s:vimDiffSourceBuffer') && s:vimDiffSourceBuffer != originalBuffer
 732                                 " Clear the existing vimdiff setup by removing the result buffers.
 733                                 call s:WipeoutCommandBuffers(s:vimDiffSourceBuffer, 'vimdiff')
 734                         endif
 735
 736                         " Split and diff
 737                         if(a:0 == 2)
 738                                 " Reset the vimdiff system, as 2 explicit versions were provided.
 739                                 if exists('s:vimDiffSourceBuffer')
 740                                         call s:WipeoutCommandBuffers(s:vimDiffSourceBuffer, 'vimdiff')
 741                                 endif
 742                                 let resultBuffer = s:plugins[vcsType][1].Review([a:1])
 743                                 if resultBuffer < 0
 744                                         echomsg 'Can''t open revision ' . a:1
 745                                         return resultBuffer
 746                                 endif
 747                                 let b:VCSCommandCommand = 'vimdiff'
 748                                 diffthis
 749                                 let s:vimDiffScratchList = [resultBuffer]
 750                                 " If no split method is defined, cheat, and set it to vertical.
 751                                 try
 752                                         call s:OverrideOption('VCSCommandSplit', VCSCommandGetOption('VCSCommandDiffSplit', VCSCommandGetOption('VCSCommandSplit', 'vertical')))
 753                                         let resultBuffer = s:plugins[vcsType][1].Review([a:2])
 754                                 finally
 755                                         call s:OverrideOption('VCSCommandSplit')
 756                                 endtry
 757                                 if resultBuffer < 0
 758                                         echomsg 'Can''t open revision ' . a:1
 759                                         return resultBuffer
 760                                 endif
 761                                 let b:VCSCommandCommand = 'vimdiff'
 762                                 diffthis
 763                                 let s:vimDiffScratchList += [resultBuffer]
 764                         else
 765                                 " Add new buffer
 766                                 call s:OverrideOption('VCSCommandEdit', 'split')
 767                                 try
 768                                         " Force splitting behavior, otherwise why use vimdiff?
 769                                         call s:OverrideOption('VCSCommandSplit', VCSCommandGetOption('VCSCommandDiffSplit', VCSCommandGetOption('VCSCommandSplit', 'vertical')))
 770                                         try
 771                                                 if(a:0 == 0)
 772                                                         let resultBuffer = s:plugins[vcsType][1].Review([])
 773                                                 else
 774                                                         let resultBuffer = s:plugins[vcsType][1].Review([a:1])
 775                                                 endif
 776                                         finally
 777                                                 call s:OverrideOption('VCSCommandSplit')
 778                                         endtry
 779                                 finally
 780                                         call s:OverrideOption('VCSCommandEdit')
 781                                 endtry
 782                                 if resultBuffer < 0
 783                                         echomsg 'Can''t open current revision'
 784                                         return resultBuffer
 785                                 endif
 786                                 let b:VCSCommandCommand = 'vimdiff'
 787                                 diffthis
 788
 789                                 if !exists('s:vimDiffSourceBuffer')
 790                                         " New instance of vimdiff.
 791                                         let s:vimDiffScratchList = [resultBuffer]
 792
 793                                         " This could have been invoked on a VCS result buffer, not the
 794                                         " original buffer.
 795                                         wincmd W
 796                                         execute 'buffer' originalBuffer
 797                                         " Store info for later original buffer restore
 798                                         let s:vimDiffRestoreCmd =
 799                                                                 \    'call setbufvar('.originalBuffer.', ''&diff'', '.getbufvar(originalBuffer, '&diff').')'
 800                                                                 \ . '|call setbufvar('.originalBuffer.', ''&foldcolumn'', '.getbufvar(originalBuffer, '&foldcolumn').')'
 801                                                                 \ . '|call setbufvar('.originalBuffer.', ''&foldenable'', '.getbufvar(originalBuffer, '&foldenable').')'
 802                                                                 \ . '|call setbufvar('.originalBuffer.', ''&foldmethod'', '''.getbufvar(originalBuffer, '&foldmethod').''')'
 803                                                                 \ . '|call setbufvar('.originalBuffer.', ''&foldlevel'', '''.getbufvar(originalBuffer, '&foldlevel').''')'
 804                                                                 \ . '|call setbufvar('.originalBuffer.', ''&scrollbind'', '.getbufvar(originalBuffer, '&scrollbind').')'
 805                                                                 \ . '|call setbufvar('.originalBuffer.', ''&wrap'', '.getbufvar(originalBuffer, '&wrap').')'
 806                                                                 \ . '|if &foldmethod==''manual''|execute ''normal zE''|endif'
 807                                         diffthis
 808                                         wincmd w
 809                                 else
 810                                         " Adding a window to an existing vimdiff
 811                                         let s:vimDiffScratchList += [resultBuffer]
 812                                 endif
 813                         endif
 814
 815                         let s:vimDiffSourceBuffer = originalBuffer
 816
 817                         " Avoid executing the modeline in the current buffer after the autocommand.
 818
 819                         let currentBuffer = bufnr('%')
 820                         let saveModeline = getbufvar(currentBuffer, '&modeline')
 821                         try
 822                                 call setbufvar(currentBuffer, '&modeline', 0)
 823                                 silent do VCSCommand User VCSVimDiffFinish
 824                         finally
 825                                 call setbufvar(currentBuffer, '&modeline', saveModeline)
 826                         endtry
 827                         return resultBuffer
 828                 finally
 829                         let s:isEditFileRunning = s:isEditFileRunning - 1
 830                 endtry
 831         catch
 832                 call s:ReportError(v:exception)
 833                 return -1
 834         endtry
 835 endfunction
 836
 837 " Section: Public functions {{{1
 838
 839 " Function: VCSCommandGetVCSType() {{{2
 840 " Sets the b:VCSCommandVCSType variable in the given buffer to the
 841 " appropriate source control system name.
 842
 843 function! VCSCommandGetVCSType(buffer)
 844         let vcsType = getbufvar(a:buffer, 'VCSCommandVCSType')
 845         if strlen(vcsType) > 0
 846                 return vcsType
 847         endif
 848         for vcsType in keys(s:plugins)
 849                 if s:plugins[vcsType][1].Identify(a:buffer)
 850                         call setbufvar(a:buffer, 'VCSCommandVCSType', vcsType)
 851                         return vcsType
 852                 endif
 853         endfor
 854         throw 'No suitable plugin'
 855 endfunction
 856
 857 " Function: VCSCommandChdir(directory) {{{2
 858 " Changes the current directory, respecting :lcd changes.
 859
 860 function! VCSCommandChdir(directory)
 861         let command = 'cd'
 862         if exists("*haslocaldir") && haslocaldir()
 863                 let command = 'lcd'
 864         endif
 865         execute command escape(a:directory, ' ')
 866 endfunction
 867
 868 " Function: VCSCommandChangeToCurrentFileDir() {{{2
 869 " Go to the directory in which the given file is located.
 870
 871 function! VCSCommandChangeToCurrentFileDir(fileName)
 872         let oldCwd = getcwd()
 873         let newCwd = fnamemodify(resolve(a:fileName), ':p:h')
 874         if strlen(newCwd) > 0
 875                 call VCSCommandChdir(newCwd)
 876         endif
 877         return oldCwd
 878 endfunction
 879
 880 " Function: VCSCommandGetOriginalBuffer(vcsBuffer) {{{2
 881 " Attempts to locate the original file to which VCS operations were applied
 882 " for a given buffer.
 883
 884 function! VCSCommandGetOriginalBuffer(vcsBuffer)
 885         let origBuffer = getbufvar(a:vcsBuffer, 'VCSCommandOriginalBuffer')
 886         if origBuffer
 887                 if bufexists(origBuffer)
 888                         return origBuffer
 889                 else
 890                         " Original buffer no longer exists.
 891                         throw 'Original buffer for this VCS buffer no longer exists.'
 892                 endif
 893         else
 894                 " No original buffer
 895                 return a:vcsBuffer
 896         endif
 897 endfunction
 898
 899 " Function: VCSCommandRegisterModule(name, file, commandMap) {{{2
 900 " Allows VCS modules to register themselves.
 901
 902 function! VCSCommandRegisterModule(name, path, commandMap, mappingMap)
 903         let s:plugins[a:name] = [a:path, a:commandMap, a:mappingMap]
 904         if !empty(a:mappingMap)
 905                                 \ && !VCSCommandGetOption('VCSCommandDisableMappings', 0)
 906                                 \ && !VCSCommandGetOption('VCSCommandDisableExtensionMappings', 0)
 907                 for mapname in keys(a:mappingMap)
 908                         execute 'noremap <silent> <Leader>' . mapname ':call <SID>ExecuteExtensionMapping(''' . mapname . ''')<CR>'
 909                 endfor
 910         endif
 911 endfunction
 912
 913 " Function: VCSCommandDoCommand(cmd, cmdName, statusText, [options]) {{{2
 914 " General skeleton for VCS function execution.  The given command is executed
 915 " after appending the current buffer name (or substituting it for
 916 " <VCSCOMMANDFILE>, if such a token is present).  The output is captured in a
 917 " new buffer.
 918 "
 919 " The optional 'options' Dictionary may contain the following options:
 920 "       allowNonZeroExit:  if non-zero, if the underlying VCS command has a
 921 "               non-zero exit status, the command is still considered
 922 "               successfuly.  This defaults to zero.
 923 " Returns: name of the new command buffer containing the command results
 924
 925 function! VCSCommandDoCommand(cmd, cmdName, statusText, options)
 926         let allowNonZeroExit = 0
 927         if has_key(a:options, 'allowNonZeroExit')
 928                 let allowNonZeroExit = a:options.allowNonZeroExit
 929         endif
 930
 931         let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
 932         if originalBuffer == -1
 933                 throw 'Original buffer no longer exists, aborting.'
 934         endif
 935
 936         let path = resolve(bufname(originalBuffer))
 937
 938         " Work with netrw or other systems where a directory listing is displayed in
 939         " a buffer.
 940
 941         if isdirectory(path)
 942                 let fileName = '.'
 943         else
 944                 let fileName = fnamemodify(path, ':t')
 945         endif
 946
 947         if match(a:cmd, '<VCSCOMMANDFILE>') > 0
 948                 let fullCmd = substitute(a:cmd, '<VCSCOMMANDFILE>', fileName, 'g')
 949         else
 950                 let fullCmd = a:cmd . ' "' . fileName . '"'
 951         endif
 952
 953         " Change to the directory of the current buffer.  This is done for CVS, but
 954         " is left in for other systems as it does not affect them negatively.
 955
 956         let oldCwd = VCSCommandChangeToCurrentFileDir(path)
 957         try
 958                 let output = system(fullCmd)
 959         finally
 960                 call VCSCommandChdir(oldCwd)
 961         endtry
 962
 963         " HACK:  if line endings in the repository have been corrupted, the output
 964         " of the command will be confused.
 965         let output = substitute(output, "\r", '', 'g')
 966
 967         if v:shell_error && !allowNonZeroExit
 968                 if strlen(output) == 0
 969                         throw 'Version control command failed'
 970                 else
 971                         let output = substitute(output, '\n', '  ', 'g')
 972                         throw 'Version control command failed:  ' . output
 973                 endif
 974         endif
 975
 976         if strlen(output) == 0
 977                 " Handle case of no output.  In this case, it is important to check the
 978                 " file status, especially since cvs edit/unedit may change the attributes
 979                 " of the file with no visible output.
 980
 981                 checktime
 982                 return 0
 983         endif
 984
 985         call s:EditFile(a:cmdName, originalBuffer, a:statusText)
 986
 987         silent 0put=output
 988
 989         " The last command left a blank line at the end of the buffer.  If the
 990         " last line is folded (a side effect of the 'put') then the attempt to
 991         " remove the blank line will kill the last fold.
 992         "
 993         " This could be fixed by explicitly detecting whether the last line is
 994         " within a fold, but I prefer to simply unfold the result buffer altogether.
 995
 996         if has('folding')
 997                 normal zR
 998         endif
 999
1000         $d
1001         1
1002
1003         " Define the environment and execute user-defined hooks.
1004
1005         silent do VCSCommand User VCSBufferCreated
1006         return bufnr('%')
1007 endfunction
1008
1009 " Function: VCSCommandGetOption(name, default) {{{2
1010 " Grab a user-specified option to override the default provided.  Options are
1011 " searched in the window, buffer, then global spaces.
1012
1013 function! VCSCommandGetOption(name, default)
1014         if has_key(s:optionOverrides, a:name) && len(s:optionOverrides[a:name]) > 0
1015                 return s:optionOverrides[a:name][-1]
1016         elseif exists('w:' . a:name)
1017                 return w:{a:name}
1018         elseif exists('b:' . a:name)
1019                 return b:{a:name}
1020         elseif exists('g:' . a:name)
1021                 return g:{a:name}
1022         else
1023                 return a:default
1024         endif
1025 endfunction
1026
1027 " Function: VCSCommandDisableBufferSetup() {{{2
1028 " Global function for deactivating the buffer autovariables.
1029
1030 function! VCSCommandDisableBufferSetup()
1031         let g:VCSCommandEnableBufferSetup = 0
1032         silent! augroup! VCSCommandPlugin
1033 endfunction
1034
1035 " Function: VCSCommandEnableBufferSetup() {{{2
1036 " Global function for activating the buffer autovariables.
1037
1038 function! VCSCommandEnableBufferSetup()
1039         let g:VCSCommandEnableBufferSetup = 1
1040         augroup VCSCommandPlugin
1041                 au!
1042                 au BufEnter * call s:SetupBuffer()
1043         augroup END
1044
1045         " Only auto-load if the plugin is fully loaded.  This gives other plugins a
1046         " chance to run.
1047         if g:loaded_VCSCommand == 2
1048                 call s:SetupBuffer()
1049         endif
1050 endfunction
1051
1052 " Function: VCSCommandGetStatusLine() {{{2
1053 " Default (sample) status line entry for VCS-controlled files.  This is only
1054 " useful if VCS-managed buffer mode is on (see the VCSCommandEnableBufferSetup
1055 " variable for how to do this).
1056
1057 function! VCSCommandGetStatusLine()
1058         if exists('b:VCSCommandCommand')
1059                 " This is a result buffer.  Return nothing because the buffer name
1060                 " contains information already.
1061                 return ''
1062         endif
1063
1064         if exists('b:VCSCommandVCSType')
1065                                 \ && exists('g:VCSCommandEnableBufferSetup')
1066                                 \ && g:VCSCommandEnableBufferSetup
1067                                 \ && exists('b:VCSCommandBufferInfo')
1068                 return '[' . join(extend([b:VCSCommandVCSType], b:VCSCommandBufferInfo), ' ') . ']'
1069         else
1070                 return ''
1071         endif
1072 endfunction
1073
1074 " Section: Command definitions {{{1
1075 " Section: Primary commands {{{2
1076 com! -nargs=* VCSAdd call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Add', [<f-args>]))
1077 com! -nargs=* VCSAnnotate call s:ExecuteVCSCommand('Annotate', [<f-args>])
1078 com! -nargs=* VCSBlame call s:ExecuteVCSCommand('Annotate', [<f-args>])
1079 com! -nargs=? -bang VCSCommit call s:VCSCommit(<q-bang>, <q-args>)
1080 com! -nargs=* VCSDelete call s:ExecuteVCSCommand('Delete', [<f-args>])
1081 com! -nargs=* VCSDiff call s:ExecuteVCSCommand('Diff', [<f-args>])
1082 com! -nargs=0 -bang VCSGotoOriginal call s:VCSGotoOriginal(<q-bang>)
1083 com! -nargs=* VCSInfo call s:ExecuteVCSCommand('Info', [<f-args>])
1084 com! -nargs=* VCSLock call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Lock', [<f-args>]))
1085 com! -nargs=* VCSLog call s:ExecuteVCSCommand('Log', [<f-args>])
1086 com! -nargs=* VCSRemove call s:ExecuteVCSCommand('Delete', [<f-args>])
1087 com! -nargs=0 VCSRevert call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Revert', []))
1088 com! -nargs=? VCSReview call s:ExecuteVCSCommand('Review', [<f-args>])
1089 com! -nargs=* VCSStatus call s:ExecuteVCSCommand('Status', [<f-args>])
1090 com! -nargs=* VCSUnlock call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Unlock', [<f-args>]))
1091 com! -nargs=0 VCSUpdate call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Update', []))
1092 com! -nargs=* VCSVimDiff call s:VCSVimDiff(<f-args>)
1093
1094 " Section: VCS buffer management commands {{{2
1095 com! VCSCommandDisableBufferSetup call VCSCommandDisableBufferSetup()
1096 com! VCSCommandEnableBufferSetup call VCSCommandEnableBufferSetup()
1097
1098 " Allow reloading VCSCommand.vim
1099 com! VCSReload let savedPlugins = s:plugins|let s:plugins = {}|aunmenu Plugin.VCS|unlet! g:loaded_VCSCommand|runtime plugin/vcscommand.vim|for plugin in values(savedPlugins)|execute 'source' plugin[0]|endfor|unlet savedPlugins
1100
1101 " Section: Plugin command mappings {{{1
1102 nnoremap <silent> <Plug>VCSAdd :VCSAdd<CR>
1103 nnoremap <silent> <Plug>VCSAnnotate :VCSAnnotate<CR>
1104 nnoremap <silent> <Plug>VCSCommit :VCSCommit<CR>
1105 nnoremap <silent> <Plug>VCSDelete :VCSDelete<CR>
1106 nnoremap <silent> <Plug>VCSDiff :VCSDiff<CR>
1107 nnoremap <silent> <Plug>VCSGotoOriginal :VCSGotoOriginal<CR>
1108 nnoremap <silent> <Plug>VCSClearAndGotoOriginal :VCSGotoOriginal!<CR>
1109 nnoremap <silent> <Plug>VCSInfo :VCSInfo<CR>
1110 nnoremap <silent> <Plug>VCSLock :VCSLock<CR>
1111 nnoremap <silent> <Plug>VCSLog :VCSLog<CR>
1112 nnoremap <silent> <Plug>VCSRevert :VCSRevert<CR>
1113 nnoremap <silent> <Plug>VCSReview :VCSReview<CR>
1114 nnoremap <silent> <Plug>VCSStatus :VCSStatus<CR>
1115 nnoremap <silent> <Plug>VCSUnlock :VCSUnlock<CR>
1116 nnoremap <silent> <Plug>VCSUpdate :VCSUpdate<CR>
1117 nnoremap <silent> <Plug>VCSVimDiff :VCSVimDiff<CR>
1118
1119 " Section: Default mappings {{{1
1120
1121 if !VCSCommandGetOption('VCSCommandDisableMappings', 0)
1122         if !hasmapto('<Plug>VCSAdd')
1123                 nmap <unique> <Leader>ca <Plug>VCSAdd
1124         endif
1125         if !hasmapto('<Plug>VCSAnnotate')
1126                 nmap <unique> <Leader>cn <Plug>VCSAnnotate
1127         endif
1128         if !hasmapto('<Plug>VCSClearAndGotoOriginal')
1129                 nmap <unique> <Leader>cG <Plug>VCSClearAndGotoOriginal
1130         endif
1131         if !hasmapto('<Plug>VCSCommit')
1132                 nmap <unique> <Leader>cc <Plug>VCSCommit
1133         endif
1134         if !hasmapto('<Plug>VCSDelete')
1135                 nmap <unique> <Leader>cD <Plug>VCSDelete
1136         endif
1137         if !hasmapto('<Plug>VCSDiff')
1138                 nmap <unique> <Leader>cd <Plug>VCSDiff
1139         endif
1140         if !hasmapto('<Plug>VCSGotoOriginal')
1141                 nmap <unique> <Leader>cg <Plug>VCSGotoOriginal
1142         endif
1143         if !hasmapto('<Plug>VCSInfo')
1144                 nmap <unique> <Leader>ci <Plug>VCSInfo
1145         endif
1146         if !hasmapto('<Plug>VCSLock')
1147                 nmap <unique> <Leader>cL <Plug>VCSLock
1148         endif
1149         if !hasmapto('<Plug>VCSLog')
1150                 nmap <unique> <Leader>cl <Plug>VCSLog
1151         endif
1152         if !hasmapto('<Plug>VCSRevert')
1153                 nmap <unique> <Leader>cq <Plug>VCSRevert
1154         endif
1155         if !hasmapto('<Plug>VCSReview')
1156                 nmap <unique> <Leader>cr <Plug>VCSReview
1157         endif
1158         if !hasmapto('<Plug>VCSStatus')
1159                 nmap <unique> <Leader>cs <Plug>VCSStatus
1160         endif
1161         if !hasmapto('<Plug>VCSUnlock')
1162                 nmap <unique> <Leader>cU <Plug>VCSUnlock
1163         endif
1164         if !hasmapto('<Plug>VCSUpdate')
1165                 nmap <unique> <Leader>cu <Plug>VCSUpdate
1166         endif
1167         if !hasmapto('<Plug>VCSVimDiff')
1168                 nmap <unique> <Leader>cv <Plug>VCSVimDiff
1169         endif
1170 endif
1171
1172 " Section: Menu items {{{1
1173 amenu <silent> &Plugin.VCS.&Add        <Plug>VCSAdd
1174 amenu <silent> &Plugin.VCS.A&nnotate   <Plug>VCSAnnotate
1175 amenu <silent> &Plugin.VCS.&Commit     <Plug>VCSCommit
1176 amenu <silent> &Plugin.VCS.Delete      <Plug>VCSDelete
1177 amenu <silent> &Plugin.VCS.&Diff       <Plug>VCSDiff
1178 amenu <silent> &Plugin.VCS.&Info       <Plug>VCSInfo
1179 amenu <silent> &Plugin.VCS.&Log        <Plug>VCSLog
1180 amenu <silent> &Plugin.VCS.Revert      <Plug>VCSRevert
1181 amenu <silent> &Plugin.VCS.&Review     <Plug>VCSReview
1182 amenu <silent> &Plugin.VCS.&Status     <Plug>VCSStatus
1183 amenu <silent> &Plugin.VCS.&Update     <Plug>VCSUpdate
1184 amenu <silent> &Plugin.VCS.&VimDiff    <Plug>VCSVimDiff
1185
1186 " Section: Autocommands to restore vimdiff state {{{1
1187 augroup VimDiffRestore
1188         au!
1189         au BufUnload * call s:VimDiffRestore(str2nr(expand('<abuf>')))
1190 augroup END
1191
1192 " Section: Optional activation of buffer management {{{1
1193
1194 if VCSCommandGetOption('VCSCommandEnableBufferSetup', 0)
1195         call VCSCommandEnableBufferSetup()
1196 endif
1197
1198 " Section: VIM shutdown hook {{{1
1199
1200 " Close all result buffers when VIM exits, to prevent them from being restored
1201 " via viminfo.
1202
1203 " Function: s:CloseAllResultBuffers() {{{2
1204 " Closes all vcscommand result buffers.
1205 function! s:CloseAllResultBuffers()
1206         " This avoids using bufdo as that may load buffers already loaded in another
1207         " vim process, resulting in an error.
1208         let buffnr = 1
1209         let buffmaxnr = bufnr('$')
1210         while buffnr <= buffmaxnr
1211                 if getbufvar(buffnr, 'VCSCommandOriginalBuffer') != ""
1212                         execute 'bw' buffnr
1213                 endif
1214                 let buffnr = buffnr + 1
1215         endwhile
1216 endfunction
1217
1218 augroup VCSCommandVIMShutdown
1219         au!
1220         au VimLeavePre * call s:CloseAllResultBuffers()
1221 augroup END
1222
1223 " Section: Plugin completion {{{1
1224
1225 let loaded_VCSCommand = 2
1226
1227 silent do VCSCommand User VCSPluginFinish
1228
1229 let &cpo = s:save_cpo