plugin/vcssvn.vim

   1 " vim600: set foldmethod=marker:
   2 "
   3 " SVN extension for VCSCommand.
   4 "
   5 " Version:       VCS development
   6 " Maintainer:    Bob Hiestand <bob.hiestand@gmail.com>
   7 " License:
   8 " Copyright (c) 2007 Bob Hiestand
   9 "
  10 " Permission is hereby granted, free of charge, to any person obtaining a copy
  11 " of this software and associated documentation files (the "Software"), to
  12 " deal in the Software without restriction, including without limitation the
  13 " rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
  14 " sell copies of the Software, and to permit persons to whom the Software is
  15 " furnished to do so, subject to the following conditions:
  16 "
  17 " The above copyright notice and this permission notice shall be included in
  18 " all copies or substantial portions of the Software.
  19 "
  20 " THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  21 " IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  22 " FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  23 " AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  24 " LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  25 " FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  26 " IN THE SOFTWARE.
  27 "
  28 " Section: Documentation {{{1
  29 "
  30 " Options documentation: {{{2
  31 "
  32 " VCSCommandSVNExec
  33 "   This variable specifies the SVN executable.  If not set, it defaults to
  34 "   'svn' executed from the user's executable path.
  35 "
  36 " VCSCommandSVNDiffExt
  37 "   This variable, if set, sets the external diff program used by Subversion.
  38 "
  39 " VCSCommandSVNDiffOpt
  40 "   This variable, if set, determines the options passed to the svn diff
  41 "   command (such as 'u', 'w', or 'b').
  42
  43 if v:version < 700
  44   finish
  45 endif
  46
  47 runtime plugin/vcscommand.vim
  48
  49 call system(VCSCommandGetOption('VCSCommandSVNExec', 'svn') . ' --version')
  50 if v:shell_error
  51   " SVN is not installed
  52   finish
  53 endif
  54
  55 " Section: Variable initialization {{{1
  56
  57 let s:svnFunctions = {}
  58
  59 " Section: Utility functions {{{1
  60
  61 " Function: s:DoCommand(cmd, cmdName, statusText) {{{2
  62 " Wrapper to VCSCommandDoCommand to add the name of the SVN executable to the
  63 " command argument.
  64 function! s:DoCommand(cmd, cmdName, statusText)
  65   if VCSCommandGetVCSType(expand('%')) == 'SVN'
  66     let fullCmd = VCSCommandGetOption('VCSCommandSVNExec', 'svn') . ' ' . a:cmd
  67     return VCSCommandDoCommand(fullCmd, a:cmdName, a:statusText)
  68   else
  69     throw 'SVN VCSCommand plugin called on non-SVN item.'
  70   endif
  71 endfunction
  72
  73 " Section: VCS function implementations {{{1
  74
  75 " Function: s:svnFunctions.Identify(buffer) {{{2
  76 function! s:svnFunctions.Identify(buffer)
  77   let fileName = resolve(bufname(a:buffer))
  78   if isdirectory(fileName)
  79     let directoryName = fileName
  80   else
  81     let directoryName = fnamemodify(fileName, ':h')
  82   endif
  83   if strlen(directoryName) > 0
  84     let svnDir = directoryName . '/.svn'
  85   else
  86     let svnDir = '.svn'
  87   endif
  88   if isdirectory(svnDir)
  89     return 1
  90   else
  91     return 0
  92   endif
  93 endfunction
  94
  95 " Function: s:svnFunctions.Add() {{{2
  96 function! s:svnFunctions.Add(argList)
  97   return s:DoCommand(join(['add'] + a:argList, ' '), 'add', join(a:argList, ' '))
  98 endfunction
  99
 100 " Function: s:svnFunctions.Annotate(argList) {{{2
 101 function! s:svnFunctions.Annotate(argList)
 102   if len(a:argList) == 0
 103     if &filetype == 'SVNAnnotate'
 104       " Perform annotation of the version indicated by the current line.
 105       let caption = matchstr(getline('.'),'\v^\s+\zs\d+')
 106       let options = ' -r' . caption
 107     else
 108       let caption = ''
 109       let options = ''
 110     endif
 111   elseif len(a:argList) == 1 && a:argList[0] !~ '^-'
 112     let caption = a:argList[0]
 113     let options = ' -r' . caption
 114   else
 115     let caption = join(a:argList, ' ')
 116     let options = ' ' . caption
 117   endif
 118
 119   let resultBuffer = s:DoCommand('blame' . options, 'annotate', caption)
 120   if resultBuffer > 0
 121     set filetype=SVNAnnotate
 122   endif
 123   return resultBuffer
 124 endfunction
 125
 126 " Function: s:svnFunctions.Commit(argList) {{{2
 127 function! s:svnFunctions.Commit(argList)
 128   let resultBuffer = s:DoCommand('commit -F "' . a:argList[0] . '"', 'commit', '')
 129   if resultBuffer == 0
 130     echomsg 'No commit needed.'
 131   endif
 132 endfunction
 133
 134 " Function: s:svnFunctions.Delete() {{{2
 135 function! s:svnFunctions.Delete(argList)
 136   return s:DoCommand(join(['delete'] + a:argList, ' '), 'delete', join(a:argList, ' '))
 137 endfunction
 138
 139 " Function: s:svnFunctions.Diff(argList) {{{2
 140 function! s:svnFunctions.Diff(argList)
 141   if len(a:argList) == 0
 142     let revOptions = []
 143     let caption = ''
 144   elseif len(a:argList) <= 2 && match(a:argList, '^-') == -1
 145     let revOptions = ['-r' . join(a:argList, ':')]
 146     let caption = '(' . a:argList[0] . ' : ' . get(a:argList, 1, 'current') . ')'
 147   else
 148     " Pass-through
 149     let caption = join(a:argList, ' ')
 150     let revOptions = a:argList
 151   endif
 152
 153   let svnDiffExt = VCSCommandGetOption('VCSCommandSVNDiffExt', '')
 154   if svnDiffExt == ''
 155     let diffExt = []
 156   else
 157     let diffExt = ['--diff-cmd ' . svnDiffExt]
 158   endif
 159
 160   let svnDiffOpt = VCSCommandGetOption('VCSCommandSVNDiffOpt', '')
 161   if svnDiffOpt == ''
 162     let diffOptions = []
 163   else
 164     let diffOptions = ['-x -' . svnDiffOpt]
 165   endif
 166
 167   let resultBuffer = s:DoCommand(join(['diff'] + diffExt + diffOptions + revOptions), 'diff', caption)
 168   if resultBuffer > 0
 169     set filetype=diff
 170   else
 171     if svnDiffExt == ''
 172       echomsg 'No differences found'
 173     endif
 174   endif
 175   return resultBuffer
 176 endfunction
 177
 178 " Function: s:svnFunctions.GetBufferInfo() {{{2
 179 " Provides version control details for the current file.  Current version
 180 " number and current repository version number are required to be returned by
 181 " the vcscommand plugin.
 182 " Returns: List of results:  [revision, repository, branch]
 183
 184 function! s:svnFunctions.GetBufferInfo()
 185   let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
 186   let fileName = bufname(originalBuffer)
 187   let statusText = system(VCSCommandGetOption('VCSCommandSVNExec', 'svn') . ' status -vu "' . fileName . '"')
 188   if(v:shell_error)
 189     return []
 190   endif
 191
 192   " File not under SVN control.
 193   if statusText =~ '^?'
 194     return ['Unknown']
 195   endif
 196
 197   let [flags, revision, repository] = matchlist(statusText, '^\(.\{8}\)\s\+\(\S\+\)\s\+\(\S\+\)\s\+\(\S\+\)\s')[1:3]
 198   if revision == ''
 199     " Error
 200     return ['Unknown']
 201   elseif flags =~ '^A'
 202     return ['New', 'New']
 203   else
 204     return [revision, repository]
 205   endif
 206 endfunction
 207
 208 " Function: s:svnFunctions.Info(argList) {{{2
 209 function! s:svnFunctions.Info(argList)
 210   return s:DoCommand(join(['info'] + a:argList, ' '), 'info', join(a:argList, ' '))
 211 endfunction
 212
 213 " Function: s:svnFunctions.Lock(argList) {{{2
 214 function! s:svnFunctions.Lock(argList)
 215   return s:DoCommand(join(['lock'] + a:argList, ' '), 'lock', join(a:argList, ' '))
 216 endfunction
 217
 218 " Function: s:svnFunctions.Log(argList) {{{2
 219 function! s:svnFunctions.Log(argList)
 220   if len(a:argList) == 0
 221     let options = []
 222     let caption = ''
 223   elseif len(a:argList) <= 2 && match(a:argList, '^-') == -1
 224     let options = ['-r' . join(a:argList, ':')]
 225     let caption = options[0]
 226   else
 227     " Pass-through
 228     let options = a:argList
 229     let caption = join(a:argList, ' ')
 230   endif
 231
 232   let resultBuffer = s:DoCommand(join(['log', '-v'] + options), 'log', caption)
 233   return resultBuffer
 234 endfunction
 235
 236 " Function: s:svnFunctions.Revert(argList) {{{2
 237 function! s:svnFunctions.Revert(argList)
 238   return s:DoCommand('revert', 'revert', '')
 239 endfunction
 240
 241 " Function: s:svnFunctions.Review(argList) {{{2
 242 function! s:svnFunctions.Review(argList)
 243   if len(a:argList) == 0
 244     let versiontag = '(current)'
 245     let versionOption = ''
 246   else
 247     let versiontag = a:argList[0]
 248     let versionOption = ' -r ' . versiontag . ' '
 249   endif
 250
 251   let resultBuffer = s:DoCommand('cat' . versionOption, 'review', versiontag)
 252   if resultBuffer > 0
 253     let &filetype = getbufvar(b:VCSCommandOriginalBuffer, '&filetype')
 254   endif
 255   return resultBuffer
 256 endfunction
 257
 258 " Function: s:svnFunctions.Status(argList) {{{2
 259 function! s:svnFunctions.Status(argList)
 260   let options = ['-u', '-v']
 261   if len(a:argList) == 0
 262     let options = a:argList
 263   endif
 264   return s:DoCommand(join(['status'] + options, ' '), 'status', join(options, ' '))
 265 endfunction
 266
 267 " Function: s:svnFunctions.Unlock(argList) {{{2
 268 function! s:svnFunctions.Unlock(argList)
 269   return s:DoCommand(join(['unlock'] + a:argList, ' '), 'unlock', join(a:argList, ' '))
 270 endfunction
 271 " Function: s:svnFunctions.Update(argList) {{{2
 272 function! s:svnFunctions.Update(argList)
 273   return s:DoCommand('update', 'update', '')
 274 endfunction
 275
 276 " Section: Plugin Registration {{{1
 277 call VCSCommandRegisterModule('SVN', expand('<sfile>'), s:svnFunctions, [])