coregrind/m_syswrap/syscall-ppc64be-linux.S

   1
   2 /*--------------------------------------------------------------------*/
   3 /*--- Support for doing system calls.        syscall-ppc64-linux.S ---*/
   4 /*--------------------------------------------------------------------*/
   5
   6 /*
   7   This file is part of Valgrind, a dynamic binary instrumentation
   8   framework.
   9
  10   Copyright (C) 2005-2017 Paul Mackerras <paulus@samba.org>
  11
  12   This program is free software; you can redistribute it and/or
  13   modify it under the terms of the GNU General Public License as
  14   published by the Free Software Foundation; either version 2 of the
  15   License, or (at your option) any later version.
  16
  17   This program is distributed in the hope that it will be useful, but
  18   WITHOUT ANY WARRANTY; without even the implied warranty of
  19   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20   General Public License for more details.
  21
  22   You should have received a copy of the GNU General Public License
  23   along with this program; if not, see <http://www.gnu.org/licenses/>.
  24
  25   The GNU General Public License is contained in the file COPYING.
  26 */
  27
  28 #include "pub_core_basics_asm.h"
  29
  30 #if defined(VGP_ppc64be_linux)
  31
  32 #include "pub_core_vkiscnums_asm.h"
  33 #include "libvex_guest_offsets.h"
  34
  35
  36 /*----------------------------------------------------------------*/
  37 /*
  38         Perform a syscall for the client.  This will run a syscall
  39         with the client's specific per-thread signal mask.
  40
  41         The structure of this function is such that, if the syscall is
  42         interrupted by a signal, we can determine exactly what
  43         execution state we were in with respect to the execution of
  44         the syscall by examining the value of NIP in the signal
  45         handler.  This means that we can always do the appropriate
  46         thing to precisely emulate the kernel's signal/syscall
  47         interactions.
  48
  49         The syscall number is taken from the argument, even though it
  50         should also be in regs->m_gpr[0].  The syscall result is written
  51         back to regs->m_gpr[3]/m_xer/m_result on completion.
  52
  53         Returns 0 if the syscall was successfully called (even if the
  54         syscall itself failed), or a nonzero error code in the lowest
  55         8 bits if one of the sigprocmasks failed (there's no way to
  56         determine which one failed).  And there's no obvious way to
  57         recover from that either, but nevertheless we want to know.
  58
  59         VG_(fixup_guest_state_after_syscall_interrupted) does the
  60         thread state fixup in the case where we were interrupted by a
  61         signal.
  62
  63         Prototype:
  64
  65         UWord ML_(do_syscall_for_client_WRK)(
  66                                   Int syscallno,                // r3
  67                                   void* guest_state,            // r4
  68                                   const vki_sigset_t *sysmask,  // r5
  69                                   const vki_sigset_t *postmask, // r6
  70                                   Int sigsetSzB)                // r7
  71 */
  72 /* from vki_arch.h */
  73 #define VKI_SIG_SETMASK 2
  74
  75 .align 2
  76 .globl ML_(do_syscall_for_client_WRK)
  77 .section ".opd","aw"
  78 .align 3
  79 ML_(do_syscall_for_client_WRK):
  80 .quad .ML_(do_syscall_for_client_WRK),.TOC.@tocbase,0
  81 .previous
  82 .type .ML_(do_syscall_for_client_WRK),@function
  83 .globl .ML_(do_syscall_for_client_WRK)
  84 .ML_(do_syscall_for_client_WRK):
  85         /* make a stack frame */
  86         stdu    1,-80(1)
  87         std     31,72(1)
  88         std     30,64(1)
  89         std     29,56(1)
  90         std     28,48(1)
  91         mr      31,3            /* syscall number */
  92         mr      30,4            /* guest_state */
  93         mr      29,6            /* postmask */
  94         mr      28,7            /* sigsetSzB */
  95
  96         /* set the signal mask for doing the system call */
  97         /* set up for sigprocmask(SIG_SETMASK, sysmask, postmask) */
  98 1:      li      0,__NR_rt_sigprocmask
  99         li      3,VKI_SIG_SETMASK
 100         mr      4,5
 101         mr      5,6
 102         mr      6,7
 103         sc                      /* set the mask */
 104         bso     7f              /* if the sigprocmask fails */
 105
 106         /* load up syscall args from the threadstate */
 107         ld      3,OFFSET_ppc64_GPR3(30)
 108         ld      4,OFFSET_ppc64_GPR4(30)
 109         ld      5,OFFSET_ppc64_GPR5(30)
 110         ld      6,OFFSET_ppc64_GPR6(30)
 111         ld      7,OFFSET_ppc64_GPR7(30)
 112         ld      8,OFFSET_ppc64_GPR8(30)
 113         mr      0,31            /* syscall number */
 114 2:      sc                      /* do the syscall */
 115
 116         /* put the result back in the threadstate  */
 117 3:      std     3,OFFSET_ppc64_GPR3(30)     /* gst->GPR3 = sc result */
 118         /* copy cr0.so back to simulated state */
 119         mfcr    5                           /* r5 = CR               */
 120         rlwinm  5,5,4,31,31                 /* r5 = (CR >> 28) & 1   */
 121         stb     5,OFFSET_ppc64_CR0_0(30)    /* gst->CR0.SO = cr0.so  */
 122
 123         /* block signals again */
 124         /* set up for sigprocmask(SIG_SETMASK, postmask, NULL) */
 125 4:      li      0,__NR_rt_sigprocmask
 126         li      3,VKI_SIG_SETMASK
 127         mr      4,29
 128         li      5,0
 129         mr      6,28
 130         sc                      /* set the mask */
 131         bso     7f              /* if the sigprocmask fails */
 132         /* now safe from signals */
 133         li      3,0             /* SUCCESS */
 134
 135         /* pop off stack frame */
 136 5:      ld      28,48(1)
 137         ld      29,56(1)
 138         ld      30,64(1)
 139         ld      31,72(1)
 140         addi    1,1,80
 141         blr
 142
 143         /* failure: return 0x8000 | error code */
 144 7:      ori     3,3,0x8000      /* FAILURE -- ensure return value is nonzero */
 145         b       5b
 146
 147 .section .rodata
 148 /* export the ranges so that
 149    VG_(fixup_guest_state_after_syscall_interrupted) can do the
 150    right thing */
 151
 152 .globl ML_(blksys_setup)
 153 .globl ML_(blksys_restart)
 154 .globl ML_(blksys_complete)
 155 .globl ML_(blksys_committed)
 156 .globl ML_(blksys_finished)
 157 ML_(blksys_setup):     .quad 1b
 158 ML_(blksys_restart):   .quad 2b
 159 ML_(blksys_complete):  .quad 3b
 160 ML_(blksys_committed): .quad 4b
 161 ML_(blksys_finished):  .quad 5b
 162
 163 #endif // defined(VGP_ppc64be_linux)
 164
 165 /* Let the linker know we don't need an executable stack */
 166 MARK_STACK_NO_EXEC
 167
 168 /*--------------------------------------------------------------------*/
 169 /*--- end                                                          ---*/
 170 /*--------------------------------------------------------------------*/