vala/valapointerindirection.vala

   1 /* valapointerindirection.vala
   2  *
   3  * Copyright (C) 2007-2010  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23
  24 /**
  25  * Represents a pointer indirection in the source code, e.g. `*pointer`.
  26  */
  27 public class Vala.PointerIndirection : Expression {
  28         /**
  29          * The pointer to dereference.
  30          */
  31         public Expression inner {
  32                 get {
  33                         return _inner;
  34                 }
  35                 set {
  36                         _inner = value;
  37                         _inner.parent_node = this;
  38                 }
  39         }
  40
  41         private Expression _inner;
  42
  43         /**
  44          * Creates a new pointer indirection.
  45          *
  46          * @param inner pointer to be dereferenced
  47          * @return      newly created pointer indirection
  48          */
  49         public PointerIndirection (Expression inner, SourceReference? source_reference = null) {
  50                 this.source_reference = source_reference;
  51                 this.inner = inner;
  52         }
  53
  54         public override void accept (CodeVisitor visitor) {
  55                 inner.accept (visitor);
  56
  57                 visitor.visit_pointer_indirection (this);
  58
  59                 visitor.visit_expression (this);
  60         }
  61
  62         public override void replace_expression (Expression old_node, Expression new_node) {
  63                 if (inner == old_node) {
  64                         inner = new_node;
  65                 }
  66         }
  67
  68         public override bool is_pure () {
  69                 return inner.is_pure ();
  70         }
  71
  72         public override bool is_accessible (Symbol sym) {
  73                 return inner.is_accessible (sym);
  74         }
  75
  76         public override bool check (CodeContext context) {
  77                 if (checked) {
  78                         return !error;
  79                 }
  80
  81                 checked = true;
  82
  83                 if (!inner.check (context)) {
  84                         return false;
  85                 }
  86                 if (inner.value_type == null) {
  87                         error = true;
  88                         Report.error (source_reference, "internal error: unknown type of inner expression");
  89                         return false;
  90                 }
  91                 if (inner.value_type is PointerType) {
  92                         var pointer_type = (PointerType) inner.value_type;
  93                         if (pointer_type.base_type is ReferenceType || pointer_type.base_type is VoidType) {
  94                                 error = true;
  95                                 Report.error (source_reference, "Pointer indirection not supported for this expression");
  96                                 return false;
  97                         }
  98                         value_type = pointer_type.base_type;
  99                 } else {
 100                         error = true;
 101                         Report.error (source_reference, "Pointer indirection not supported for this expression");
 102                         return false;
 103                 }
 104
 105                 return !error;
 106         }
 107
 108         public override void emit (CodeGenerator codegen) {
 109                 inner.emit (codegen);
 110
 111                 codegen.visit_pointer_indirection (this);
 112
 113                 codegen.visit_expression (this);
 114         }
 115
 116         public override void get_defined_variables (Collection<Variable> collection) {
 117                 inner.get_defined_variables (collection);
 118         }
 119
 120         public override void get_used_variables (Collection<Variable> collection) {
 121                 inner.get_used_variables (collection);
 122         }
 123 }