vala/valaconstant.vala

   1 /* valaconstant.vala
   2  *
   3  * Copyright (C) 2006-2011  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents a type member with a constant value.
  27  */
  28 public class Vala.Constant : Symbol, Lockable {
  29         /**
  30          * The data type of this constant.
  31          */
  32         public DataType type_reference {
  33                 get { return _data_type; }
  34                 set {
  35                         _data_type = value;
  36                         _data_type.parent_node = this;
  37                 }
  38         }
  39
  40         /**
  41          * The value of this constant.
  42          */
  43         public Expression? value {
  44                 get { return _value; }
  45                 set {
  46                         _value = value;
  47                         if (_value != null) {
  48                                 _value.parent_node = this;
  49                         }
  50                 }
  51         }
  52
  53         private bool lock_used = false;
  54
  55         private DataType _data_type;
  56
  57         private Expression _value;
  58
  59         /**
  60          * Creates a new constant.
  61          *
  62          * @param name             constant name
  63          * @param type_reference   constant type
  64          * @param value            constant value
  65          * @param source_reference reference to source code
  66          * @return                 newly created constant
  67          */
  68         public Constant (string name, DataType? type_reference, Expression? value, SourceReference? source_reference, Comment? comment = null) {
  69                 base (name, source_reference, comment);
  70                 if (type_reference != null) {
  71                         this.type_reference = type_reference;
  72                 }
  73                 this.value = value;
  74         }
  75
  76         public override void accept (CodeVisitor visitor) {
  77                 visitor.visit_constant (this);
  78         }
  79
  80         public override void accept_children (CodeVisitor visitor) {
  81                 type_reference.accept (visitor);
  82
  83                 if (value != null) {
  84                         value.accept (visitor);
  85                 }
  86         }
  87
  88         public bool get_lock_used () {
  89                 return lock_used;
  90         }
  91
  92         public void set_lock_used (bool used) {
  93                 lock_used = used;
  94         }
  95
  96         public override void replace_expression (Expression old_node, Expression new_node) {
  97                 if (value == old_node) {
  98                         value = new_node;
  99                 }
 100         }
 101
 102         public override void replace_type (DataType old_type, DataType new_type) {
 103                 if (type_reference == old_type) {
 104                         type_reference = new_type;
 105                 }
 106         }
 107
 108         public override bool check (CodeContext context) {
 109                 if (checked) {
 110                         return !error;
 111                 }
 112
 113                 checked = true;
 114
 115                 var old_source_file = context.analyzer.current_source_file;
 116                 var old_symbol = context.analyzer.current_symbol;
 117
 118                 if (source_reference != null) {
 119                         context.analyzer.current_source_file = source_reference.file;
 120                 }
 121                 if (!(parent_symbol is Block)) {
 122                         // non-local constant
 123                         context.analyzer.current_symbol = this;
 124                 }
 125
 126                 type_reference.check (context);
 127
 128                 if (!check_const_type (type_reference, context)) {
 129                         error = true;
 130                         Report.error (source_reference, "`%s' not supported as type for constants".printf (type_reference.to_string ()));
 131                         return false;
 132                 }
 133
 134                 if (!external) {
 135                         if (value == null) {
 136                                 error = true;
 137                                 Report.error (source_reference, "A const field requires a value to be provided");
 138                         } else {
 139                                 value.target_type = type_reference;
 140
 141                                 if (!value.check (context)) {
 142                                         error = true;
 143                                         return false;
 144                                 }
 145
 146                                 if (!value.value_type.compatible (type_reference)) {
 147                                         error = true;
 148                                         Report.error (source_reference, "Cannot convert from `%s' to `%s'".printf (value.value_type.to_string (), type_reference.to_string ()));
 149                                         return false;
 150                                 }
 151
 152                                 // support translated string constants for efficiency / convenience
 153                                 // even though the expression is not a compile-time constant
 154                                 var call = value as MethodCall;
 155                                 if (call != null) {
 156                                         var method_type = call.call.value_type as MethodType;
 157                                         if (method_type != null && method_type.method_symbol.get_full_name () == "GLib._") {
 158                                                 // first argument is string
 159                                                 var literal = call.get_argument_list ().get (0) as StringLiteral;
 160                                                 if (literal != null) {
 161                                                         value = literal;
 162                                                         literal.translate = true;
 163                                                 }
 164                                         }
 165                                 }
 166
 167                                 if (!value.is_constant ()) {
 168                                         error = true;
 169                                         Report.error (value.source_reference, "Value must be constant");
 170                                         return false;
 171                                 }
 172                         }
 173                 } else {
 174                         if (value != null) {
 175                                 error = true;
 176                                 Report.error (source_reference, "External constants cannot use values");
 177                         }
 178                 }
 179
 180                 if (!external_package && !hides && get_hidden_member () != null) {
 181                         Report.warning (source_reference, "%s hides inherited constant `%s'. Use the `new' keyword if hiding was intentional".printf (get_full_name (), get_hidden_member ().get_full_name ()));
 182                 }
 183
 184                 context.analyzer.current_source_file = old_source_file;
 185                 context.analyzer.current_symbol = old_symbol;
 186
 187                 active = true;
 188
 189                 return !error;
 190         }
 191
 192         bool check_const_type (DataType type, CodeContext context) {
 193                 if (type is ValueType) {
 194                         return true;
 195                 } else if (type is ArrayType) {
 196                         var array_type = type as ArrayType;
 197                         return check_const_type (array_type.element_type, context);
 198                 } else if (type.data_type == context.analyzer.string_type.data_type) {
 199                         return true;
 200                 } else {
 201                         return false;
 202                 }
 203         }
 204 }