vala/valacastexpression.vala

   1 /* valacastexpression.vala
   2  *
   3  * Copyright (C) 2006-2011  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23
  24 /**
  25  * Represents a type cast in the source code.
  26  */
  27 public class Vala.CastExpression : Expression {
  28         /**
  29          * The expression to be cast.
  30          */
  31         public Expression inner {
  32                 get {
  33                         return _inner;
  34                 }
  35                 set {
  36                         _inner = value;
  37                         _inner.parent_node = this;
  38                 }
  39         }
  40
  41         /**
  42          * The target type.
  43          */
  44         public DataType type_reference {
  45                 get { return _data_type; }
  46                 set {
  47                         _data_type = value;
  48                         _data_type.parent_node = this;
  49                 }
  50         }
  51
  52         /**
  53          * Checked casts return NULL instead of raising an error.
  54          */
  55         public bool is_silent_cast { get; set; }
  56
  57         public bool is_non_null_cast { get; set; }
  58
  59         private Expression _inner;
  60
  61         private DataType _data_type;
  62
  63         /**
  64          * Creates a new cast expression.
  65          *
  66          * @param inner           expression to be cast
  67          * @param type_reference  target type
  68          * @return                newly created cast expression
  69          */
  70         public CastExpression (Expression inner, DataType type_reference, SourceReference source_reference, bool is_silent_cast) {
  71                 this.type_reference = type_reference;
  72                 this.source_reference = source_reference;
  73                 this.is_silent_cast = is_silent_cast;
  74                 this.inner = inner;
  75         }
  76
  77         public CastExpression.non_null (Expression inner, SourceReference source_reference) {
  78                 this.inner = inner;
  79                 this.is_non_null_cast = true;
  80                 this.source_reference = source_reference;
  81         }
  82
  83         public override void accept (CodeVisitor visitor) {
  84                 visitor.visit_cast_expression (this);
  85
  86                 visitor.visit_expression (this);
  87         }
  88
  89         public override void accept_children (CodeVisitor visitor) {
  90                 inner.accept (visitor);
  91                 if (!is_non_null_cast) {
  92                         type_reference.accept (visitor);
  93                 }
  94         }
  95
  96         public override void replace_expression (Expression old_node, Expression new_node) {
  97                 if (inner == old_node) {
  98                         inner = new_node;
  99                 }
 100         }
 101
 102         public override bool is_pure () {
 103                 return inner.is_pure ();
 104         }
 105
 106         public override bool is_accessible (Symbol sym) {
 107                 return inner.is_accessible (sym);
 108         }
 109
 110         public override void replace_type (DataType old_type, DataType new_type) {
 111                 if (type_reference == old_type) {
 112                         type_reference = new_type;
 113                 }
 114         }
 115
 116         public override bool check (CodeContext context) {
 117                 if (checked) {
 118                         return !error;
 119                 }
 120
 121                 checked = true;
 122
 123                 if (!inner.check (context)) {
 124                         error = true;
 125                         return false;
 126                 }
 127
 128                 if (inner.value_type == null) {
 129                         Report.error (source_reference, "Invalid cast expression");
 130                         error = true;
 131                         return false;
 132                 }
 133
 134                 if (is_non_null_cast) {
 135                         // (!) non-null cast
 136                         type_reference = inner.value_type.copy ();
 137                         type_reference.nullable = false;
 138                 }
 139
 140                 type_reference.check (context);
 141
 142                 // FIXME: check whether cast is allowed
 143
 144                 if (type_reference is DelegateType && inner.value_type is MethodType) {
 145                         if (target_type != null) {
 146                                 inner.value_type.value_owned = target_type.value_owned;
 147                         } else {
 148                                 inner.value_type.value_owned = true;
 149                         }
 150                 }
 151
 152                 value_type = type_reference;
 153                 value_type.value_owned = inner.value_type.value_owned;
 154
 155                 if (is_silent_cast) {
 156                         value_type.nullable = true;
 157                 }
 158
 159                 if (is_gvariant (context, inner.value_type) && !is_gvariant (context, value_type)) {
 160                         // GVariant unboxing returns owned value
 161                         value_type.value_owned = true;
 162                 }
 163
 164                 inner.target_type = inner.value_type.copy ();
 165
 166                 return !error;
 167         }
 168
 169         bool is_gvariant (CodeContext context, DataType type) {
 170                 return type.data_type != null && type.data_type.is_subtype_of (context.analyzer.gvariant_type.data_type);
 171         }
 172
 173         public override void emit (CodeGenerator codegen) {
 174                 inner.emit (codegen);
 175
 176                 codegen.visit_cast_expression (this);
 177
 178                 codegen.visit_expression (this);
 179         }
 180
 181         public override void get_defined_variables (Collection<Variable> collection) {
 182                 inner.get_defined_variables (collection);
 183         }
 184
 185         public override void get_used_variables (Collection<Variable> collection) {
 186                 inner.get_used_variables (collection);
 187         }
 188
 189         public override bool is_constant () {
 190                 return inner.is_constant ();
 191         }
 192 }