contrib/libjeffpc/sexpr.y

   1 /*
   2  * Copyright (c) 2015-2016 Josef 'Jeff' Sipek <jeffpc@josefsipek.net>
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to deal
   6  * in the Software without restriction, including without limitation the rights
   7  * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   8  * copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  19  * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  20  * SOFTWARE.
  21  */
  22
  23 %pure-parser
  24 %lex-param {void *scanner}
  25 %parse-param {struct sexpr_parser_state *data}
  26
  27 %{
  28 #include <jeffpc/error.h>
  29
  30 #include "sexpr_impl.h"
  31
  32 #define scanner data->scanner
  33
  34 extern int sexpr_reader_lex(void *, void *);
  35
  36 void yyerror(void *scan, char *e)
  37 {
  38         cmn_err(CE_ERROR, "Error: %s", e);
  39 }
  40
  41 void sexpr_error2(char *e, char *yytext)
  42 {
  43         cmn_err(CE_ERROR, "Error: %s (%s)", e, yytext);
  44 }
  45
  46 %}
  47
  48 %union {
  49         struct str *s;
  50         uint64_t i;
  51         bool b;
  52         struct val *lv;
  53 };
  54
  55 %token <s> SYMBOL STRING
  56 %token <i> NUMBER
  57 %token <b> BOOL
  58
  59 %type <lv> document tok list toklist
  60
  61 %%
  62 document : tok                  { data->output = $1; }
  63          ;
  64
  65 tok : SYMBOL                    { $$ = VAL_ALLOC_SYM($1); }
  66     | STRING                    { $$ = VAL_ALLOC_STR($1); }
  67     | NUMBER                    { $$ = VAL_ALLOC_INT($1); }
  68     | BOOL                      { $$ = VAL_ALLOC_BOOL($1); }
  69     | list                      { $$ = $1; }
  70     | '\'' tok                  { $$ = VAL_ALLOC_CONS(
  71                                          VAL_ALLOC_SYM_CSTR("quote"),
  72                                          VAL_ALLOC_CONS($2, NULL)); }
  73     ;
  74
  75 /*
  76  * We are not left-recursive because we want to make cons cells right
  77  * recursively.
  78  */
  79 toklist : tok toklist           { $$ = VAL_ALLOC_CONS($1, $2); }
  80         | tok                   { $$ = VAL_ALLOC_CONS($1, NULL); }
  81         ;
  82
  83 list : '(' ')'                  { $$ = NULL; }
  84      | '(' toklist ')'          { $$ = $2; }
  85      | '(' tok '.' tok ')'      { $$ = VAL_ALLOC_CONS($2, $4); }
  86      ;
  87
  88 %%