usr/src/boot/sys/boot/efi/loader/arch/amd64/ldscript.amd64

   1 OUTPUT_FORMAT("elf64-x86-64-sol2", "elf64-x86-64-sol2", "elf64-x86-64-sol2")
   2 OUTPUT_ARCH(i386:x86-64)
   3 ENTRY(_start)
   4 SECTIONS
   5 {
   6   /* Read-only sections, merged into text segment: */
   7   . = 0;
   8   ImageBase = .;
   9   .hash : { *(.hash) }  /* this MUST come first! */
  10   . = ALIGN(4096);
  11   .eh_frame :
  12   {
  13     *(.eh_frame)
  14   }
  15   . = ALIGN(4096);
  16   .text         : {
  17     *(.text .stub .text.* .gnu.linkonce.t.*)
  18     /* .gnu.warning sections are handled specially by elf32.em. */
  19     *(.gnu.warning)
  20     *(.plt)
  21   } =0xCCCCCCCC
  22   . = ALIGN(4096);
  23   .data         : {
  24     *(.rodata .rodata.* .gnu.linkonce.r.*)
  25     *(.rodata1)
  26     *(.sdata2 .sdata2.* .gnu.linkonce.s2.*)
  27     *(.sbss2 .sbss2.* .gnu.linkonce.sb2.*)
  28     *(.opd)
  29     *(.data .data.* .gnu.linkonce.d.*)
  30     *(.data1)
  31     *(.plabel)
  32     *(.dynbss)
  33     *(.bss .bss.* .gnu.linkonce.b.*)
  34     *(COMMON)
  35   }
  36   . = ALIGN(4096);
  37   set_Xcommand_set      : {
  38     __start_set_Xcommand_set = .;
  39     *(set_Xcommand_set)
  40     __stop_set_Xcommand_set = .;
  41   }
  42   set_Xficl_compile_set : {
  43     __start_set_Xficl_compile_set = .;
  44     *(set_Xficl_compile_set)
  45     __stop_set_Xficl_compile_set = .;
  46   }
  47   . = ALIGN(4096);
  48   __gp = .;
  49   .sdata        : {
  50     *(.got.plt .got)
  51     *(.sdata .sdata.* .gnu.linkonce.s.*)
  52     *(dynsbss)
  53     *(.sbss .sbss.* .gnu.linkonce.sb.*)
  54     *(.scommon)
  55   }
  56   . = ALIGN(4096);
  57   .dynamic      : { *(.dynamic) }
  58   . = ALIGN(4096);
  59   .rela.dyn     : {
  60     *(.rela.data*)
  61     *(.rela.got)
  62     *(.rela.stab)
  63     *(.relaset_*)
  64   }
  65   . = ALIGN(4096);
  66   .reloc        : { *(.reloc) }
  67   . = ALIGN(4096);
  68   .dynsym       : { *(.dynsym) }
  69   . = ALIGN(4096);
  70   .dynstr       : { *(.dynstr) }
  71 }