media-video/smplayer/smplayer-0.6.0_rc1.ebuild

   1 # Copyright 1999-2008 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/smplayer-0.5.62.ebuild,v 1.2 2008/02/01 09:03:04 opfer Exp $
   4
   5 inherit eutils qt4
   6
   7 MY_P=${P/_/}
   8 S=${WORKDIR}/${MY_P}
   9
  10 DESCRIPTION="Great front-end for mplayer written in Qt4"
  11 HOMEPAGE="http://smplayer.sourceforge.net"
  12 SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
  13 RESTRICT="mirror"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE=""
  19
  20 DEPEND="$(qt4_min_version 4.2)"
  21 RDEPEND="${DEPEND}
  22         >=media-video/mplayer-1.0_rc2"
  23
  24 LANGS="bg cs de en_US es fi fr hu it ja ka ko nl pl pt_BR pt_PT sk sr sv tr zh_CN zh_TW"
  25 NOLONGLANGS="el_GR ro_RO ru_RU uk_UA"
  26
  27 for X in ${LANGS}; do
  28         IUSE="${IUSE} linguas_${X}"
  29 done
  30 for X in ${NOLONGLANGS}; do
  31         IUSE="${IUSE} linguas_${X%_*}"
  32 done
  33
  34 QT4_BUILT_WITH_USE_CHECK="qt3support"
  35
  36 src_unpack() {
  37         unpack ${A}
  38         cd "${S}"
  39
  40         local MY_SVNREV="UNKNOWN"
  41         echo "#define SVN_REVISION \"SVN-r${MY_SVNREV}\"" > src/svn_revision.h
  42
  43         # Fix paths in Makefile and allow parallel building
  44         sed -i -e "/^PREFIX=/s:/usr/local:/usr:" \
  45                 -e "/^CONF_PREFIX=/s:\$(PREFIX)::" \
  46                 -e "/^DOC_PATH=/s:packages/smplayer:${PF}:" \
  47                 -e '/get_svn_revision\.sh/,+2c\
  48         cd src && $(DEFS) $(MAKE)' \
  49                 -e '/tar -C docs/d' \
  50                 "${S}"/Makefile || die "sed failed"
  51 }
  52
  53 src_compile() {
  54         eqmake4 src/${PN}.pro -o src/Makefile
  55         emake || die "emake failed"
  56
  57         # Generate translations
  58         cd "${S}"/src/translations
  59         local LANG=
  60         for LANG in ${LINGUAS}; do
  61                 if has ${LANG} ${LANGS}; then
  62                         einfo "Generating ${LANG} translation ..."
  63                         lrelease ${PN}_${LANG}.ts || die "Failed to generate ${LANG} translation!"
  64                         continue
  65                 elif [[ " ${NOLONGLANGS} " == *" ${LANG}_"* ]]; then
  66                         local X=
  67                         for X in ${NOLONGLANGS}; do
  68                                 if [[ "${LANG}" == "${X%_*}" ]]; then
  69                                         einfo "Generating ${X} translation ..."
  70                                         lrelease ${PN}_${X}.ts || die "Failed to generate ${X} translation!"
  71                                         continue 2
  72                                 fi
  73                         done
  74                 fi
  75                 ewarn "Sorry, but ${PN} does not support the ${LANG} LINGUA."
  76         done
  77 }
  78
  79 src_install() {
  80         emake DESTDIR="${D}" install || die "Installation failed!"
  81         prepalldocs
  82 }