app-crypt/qca-ossl/qca-ossl-2.0.0_beta1.ebuild

   1 # Copyright 1999-2007 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 inherit eutils qt4
   6
   7 MY_P="${P/_/-}"
   8 QCA_VER="${PV%.*}"
   9
  10 DESCRIPTION="TLS, S/MIME, PKCS#12, crypto algorithms plugin for QCA"
  11 HOMEPAGE="http://delta.affinix.com/qca/"
  12 SRC_URI="http://delta.affinix.com/download/qca/${QCA_VER}/plugins/${MY_P}.tar.bz2"
  13 RESTRICT="mirror"
  14
  15 LICENSE="LGPL-2"
  16 SLOT="2"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="debug"
  19
  20 DEPEND=">=app-crypt/qca-${QCA_VER}
  21         >=dev-libs/openssl-0.9.6"
  22 RDEPEND="${DEPEND}"
  23
  24 S="${WORKDIR}/${MY_P}"
  25
  26 pkg_setup() {
  27         if use debug && ! built_with_use ">=app-crypt/qca-${QCA_VER}" debug; then
  28                 eerror
  29                 eerror "You are trying to compile ${PN} with USE=\"debug\""
  30                 eerror "while qca is built without this flag. It will not work."
  31                 eerror
  32                 eerror "Possible solutions to this problem are:"
  33                 eerror "a) install ${PN} without debug USE flag"
  34                 eerror "b) re-emerge qca with debug USE flag"
  35                 eerror
  36                 die "can't emerge ${PN} with debug USE flag"
  37         fi
  38 }
  39
  40 src_compile() {
  41         # cannot use econf because of non-standard configure script
  42         ./configure \
  43                 --qtdir=/usr \
  44                 $(use debug && echo "--debug" || echo "--release") \
  45                 --no-separate-debug-info \
  46                 || die "configure failed"
  47
  48         eqmake4 ${PN}.pro
  49         emake || die "emake failed"
  50 }
  51
  52 src_install() {
  53         emake INSTALL_ROOT="${D}" install || die "emake install failed"
  54 }