app-crypt/qca-logger/qca-logger-2.0.0_beta1.ebuild

   1 # Copyright 1999-2007 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 inherit eutils qt4
   6
   7 MY_P="${P/_/-}"
   8 QCA_VER="${PV%.*}"
   9
  10 DESCRIPTION="Logger plugin for QCA"
  11 HOMEPAGE="http://delta.affinix.com/qca/"
  12 SRC_URI="http://delta.affinix.com/download/qca/${QCA_VER}/plugins/${MY_P}.tar.bz2"
  13 RESTRICT="mirror"
  14
  15 LICENSE="LGPL-2"
  16 SLOT="2"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="debug"
  19
  20 DEPEND=">=app-crypt/qca-${QCA_VER}"
  21 RDEPEND="${DEPEND}"
  22
  23 S="${WORKDIR}/${MY_P}"
  24
  25 pkg_setup() {
  26         if use debug && ! built_with_use ">=app-crypt/qca-${QCA_VER}" debug; then
  27                 eerror
  28                 eerror "You are trying to compile ${PN} with USE=\"debug\""
  29                 eerror "while qca is built without this flag. It will not work."
  30                 eerror
  31                 eerror "Possible solutions to this problem are:"
  32                 eerror "a) install ${PN} without debug USE flag"
  33                 eerror "b) re-emerge qca with debug USE flag"
  34                 eerror
  35                 die "can't emerge ${PN} with debug USE flag"
  36         fi
  37 }
  38
  39 src_compile() {
  40         # cannot use econf because of non-standard configure script
  41         ./configure \
  42                 --qtdir=/usr \
  43                 $(use debug && echo "--debug" || echo "--release") \
  44                 --no-separate-debug-info \
  45                 || die "configure failed"
  46
  47         eqmake4 ${PN}.pro
  48         emake || die "make failed"
  49 }
  50
  51 src_install() {
  52         emake INSTALL_ROOT="${D}" install || die "make install failed"
  53         dodoc README
  54 }