app-crypt/qca-cyrus-sasl/qca-cyrus-sasl-0.1_p20070829.ebuild

   1 # Copyright 1999-2007 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 inherit eutils qt4
   6
   7 QCA_VER="2.0-test4"
   8 MY_P="${P/_p/-}"
   9
  10 DESCRIPTION="SASL plugin for QCA"
  11 HOMEPAGE="http://delta.affinix.com/qca/"
  12 SRC_URI="http://delta.affinix.com/download/qca/${QCA_VER/-*/}/${QCA_VER/*-/}/${MY_P}.tar.bz2"
  13
  14 LICENSE="LGPL-2"
  15 SLOT="2"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE="debug"
  18
  19 RDEPEND="=app-crypt/qca-2*
  20         dev-libs/cyrus-sasl"
  21 DEPEND="${RDEPEND}"
  22
  23 S="${WORKDIR}/${MY_P}"
  24
  25 pkg_setup() {
  26         if use debug && ! built_with_use '=app-crypt/qca-2*' debug; then
  27                 einfo
  28                 einfo "You are trying to compile ${PN} package with active USE=\"debug\""
  29                 einfo "while qca is build without this particular flag. It will not"
  30                 einfo "work."
  31                 einfo
  32                 einfo "Possible solutions to this problem are:"
  33                 einfo "a) install package ${PN} without debug USE flag"
  34                 einfo "b) re-emerge qca with debug USE flag"
  35                 einfo
  36                 die "can't emerge ${PN} with debug USE flag"
  37         fi
  38 }
  39
  40 src_compile() {
  41         local myconf="--release"
  42         use debug && myconf="--debug"
  43
  44         ./configure \
  45                 --qtdir=/usr \
  46                 --no-separate-debug-info \
  47                 ${myconf} || die "configure failed"
  48
  49         eqmake4 ${PN}.pro
  50         emake || die "make failed"
  51 }
  52
  53 src_install() {
  54         emake INSTALL_ROOT="${D}" install || die "make install failed"
  55 }