app-crypt/qca-ossl/qca-ossl-0.1_p20070904.ebuild

   1 # Copyright 1999-2007 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header:
   4
   5 inherit eutils qt4
   6
   7 QCA_VER="2.0-test3"
   8 MY_PV="${PV/_p/-}"
   9 MY_P="${PN}-${MY_PV}"
  10
  11 DESCRIPTION="TLS, S/MIME, PKCS#12, crypto algorithms plugin for QCA"
  12 HOMEPAGE="http://delta.affinix.com/qca/"
  13 SRC_URI="http://delta.affinix.com/download/qca/${QCA_VER/-*/}/${QCA_VER/*-/}/${MY_P}.tar.bz2"
  14
  15 LICENSE="LGPL-2"
  16 SLOT="2"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="debug"
  19
  20 RDEPEND=">=app-crypt/qca-2.0.0_rc3
  21         dev-libs/openssl"
  22 DEPEND="${RDEPEND}"
  23
  24 S="${WORKDIR}/${MY_P}"
  25
  26 pkg_setup() {
  27         if use debug && ! built_with_use '>=app-crypt/qca-2.0.0_rc' debug; then
  28                 einfo
  29                 einfo "You are trying to compile ${PN} package with active USE=\"debug\""
  30                 einfo "while qca is build without this particular flag. It will not"
  31                 einfo "work."
  32                 einfo
  33                 einfo "Possible solutions to this problem are:"
  34                 einfo "a) install package ${PN} without debug USE flag"
  35                 einfo "b) re-emerge qca with debug USE flag"
  36                 einfo
  37                 die "can't emerge ${PN} with debug USE flag"
  38         fi
  39 }
  40
  41 src_compile() {
  42         local myconf="--release"
  43         use debug && myconf="--debug"
  44
  45         ./configure \
  46                 --qtdir=/usr \
  47                 --no-separate-debug-info \
  48                 ${myconf} || die "configure failed"
  49
  50         eqmake4 ${PN}.pro
  51         emake || die "emake failed"
  52 }
  53
  54 src_install() {
  55         emake INSTALL_ROOT="${D}" install || die "emake install failed"
  56         dodoc README TODO
  57 }