media-video/smplayer/smplayer-0.5.62.ebuild

   1 # Copyright 1999-2007 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=1
   6 inherit eutils qt4
   7
   8 DESCRIPTION="Great front-end for mplayer written in Qt4"
   9 HOMEPAGE="http://smplayer.sourceforge.net"
  10 SRC_URI="http://downloads.sourceforge.net/${PN}/${P}.tar.bz2"
  11 RESTRICT="mirror"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="amd64 x86"
  16 IUSE=""
  17
  18 DEPEND="$(qt4_min_version 4.2)"
  19 RDEPEND="${DEPEND}
  20         >media-video/mplayer-1.0_rc1"
  21
  22 LANGS="bg cs de en_US es fr hu it ja ka nl pl pt_BR pt_PT sk sr sv tr zh_CN zh_TW"
  23 NOLONGLANGS="ro_RO ru_RU uk_UA"
  24 for X in ${LANGS}; do
  25         IUSE="${IUSE} linguas_${X}"
  26 done
  27 for X in ${NOLONGLANGS}; do
  28         IUSE="${IUSE} linguas_${X%_*}"
  29 done
  30
  31 pkg_setup() {
  32         if ! built_with_use x11-libs/qt:4 qt3support ; then
  33                 eerror
  34                 eerror "You have to rebuild x11-libs/qt:4 with USE=\"qt3support\""
  35                 eerror
  36                 die "Please re-emerge x11-libs/qt:4 with USE=\"qt3support\""
  37         fi
  38 }
  39
  40 src_compile() {
  41         local MY_SVNREV="UNKNOWN"
  42         echo "SVN-r${MY_SVNREV}" > svn_revision.txt
  43         echo "#define SVN_REVISION \"SVN-r${MY_SVNREV}\"" > src/svn_revision.h
  44
  45         sed -i -e "/^PREFIX=/s:/usr/local:/usr:" \
  46                 -e "/^CONF_PREFIX=/s:\$(PREFIX)::" \
  47                 -e "/^DOC_PATH=/s:packages/smplayer:${PF}:" \
  48                 -e '/get_svn_revision.sh/,+2c\
  49         cd src && $(DEFS) $(MAKE)' \
  50                 "${S}"/Makefile || die "sed failed"
  51
  52         eqmake4 src/${PN}.pro -o src/Makefile
  53         emake || die "emake failed"
  54
  55         # Generate translations
  56         cd "${S}"/src/translations
  57         local LANG=
  58         for LANG in ${LINGUAS}; do
  59                 if has ${LANG} ${LANGS}; then
  60                         einfo "Generating ${LANG} translation ..."
  61                         lrelease ${PN}_${LANG}.ts || die "Failed to generate ${LANG} translation!"
  62                         continue
  63                 elif [[ " ${NOLONGLANGS} " == *" ${LANG}_"* ]]; then
  64                         local X=
  65                         for X in ${NOLONGLANGS}; do
  66                                 if [[ "${LANG}" == "${X%_*}" ]]; then
  67                                         einfo "Generating ${X} translation ..."
  68                                         lrelease ${PN}_${X}.ts || die "Failed to generate ${X} translation!"
  69                                         continue 2
  70                                 fi
  71                         done
  72                 fi
  73                 ewarn "Sorry, but ${PN} does not support the ${LANG} LINGUA"
  74         done
  75 }
  76
  77 src_install() {
  78         emake DESTDIR="${D}" install || die "emake install failed"
  79         prepalldocs
  80 }