net-libs/psimedia/psimedia-1.0.2.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="2"
   6
   7 inherit multilib qt4
   8
   9 DESCRIPTION="Thick abstraction layer for audio/video RTP services"
  10 HOMEPAGE="http://delta.affinix.com/psimedia/"
  11 SRC_URI="http://delta.affinix.com/download/${PN}/${P}.tar.bz2"
  12
  13 LICENSE="LGPL-2.1"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="debug"
  17
  18 DEPEND="dev-libs/glib:2
  19         >=dev-libs/liboil-0.3
  20         >=media-libs/gst-plugins-base-0.10.22
  21         >=media-libs/gst-plugins-good-0.10.14
  22         >=media-libs/speex-1.2_rc1
  23         >=x11-libs/qt-gui-4.4:4[glib]"
  24 RDEPEND="${DEPEND}
  25         >=media-plugins/gst-plugins-alsa-0.10.22
  26         >=media-plugins/gst-plugins-jpeg-0.10.14
  27         >=media-plugins/gst-plugins-ogg-0.10.22
  28         >=media-plugins/gst-plugins-speex-0.10.14
  29         >=media-plugins/gst-plugins-theora-0.10.22
  30         >=media-plugins/gst-plugins-v4l-0.10.22
  31         >=media-plugins/gst-plugins-v4l2-0.10.14
  32         >=media-plugins/gst-plugins-vorbis-0.10.22"
  33
  34 src_configure() {
  35         # cannot use econf because of non-standard configure script
  36         local confcmd="./configure
  37                         --qtdir=/usr
  38                         --no-separate-debug-info
  39                         --$(use debug && echo debug || echo release)"
  40
  41         echo ${confcmd}
  42         ${confcmd} || die "configure failed"
  43
  44         eqmake4
  45 }
  46
  47 src_install() {
  48         exeinto /usr/$(get_libdir)/psi/plugins
  49         doexe gstprovider/libgstprovider.so
  50 }