app-crypt/qca/qca-2.0.0.ebuild

   1 # Copyright 1999-2007 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 inherit eutils qt4
   6
   7 DESCRIPTION="Qt Cryptographic Architecture (QCA)"
   8 HOMEPAGE="http://delta.affinix.com/qca/"
   9 SRC_URI="http://delta.affinix.com/download/qca/${PV%.*}/${P}.tar.bz2"
  10
  11 LICENSE="LGPL-2"
  12 SLOT="2"
  13 KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
  14 IUSE="debug doc examples"
  15 RESTRICT="test"
  16
  17 DEPEND="$(qt4_min_version 4.2.0)"
  18 RDEPEND="${DEPEND}"
  19
  20 pkg_setup() {
  21         if use debug && ! built_with_use qt debug; then
  22                 eerror
  23                 eerror "You are trying to compile ${PN} package with USE=\"debug\""
  24                 eerror "while qt4 is built without this particular flag: it will"
  25                 eerror "not work."
  26                 eerror
  27                 eerror "Possible solutions to this problem are:"
  28                 eerror "a) install package ${PN} without debug USE flag"
  29                 eerror "b) re-emerge qt4 with debug USE flag"
  30                 eerror
  31                 die "can't emerge ${PN} with debug USE flag"
  32         fi
  33 }
  34
  35 src_compile() {
  36         local myconf=
  37         if use debug; then
  38                 myconf="--debug"
  39         else
  40                 myconf="--release"
  41         fi
  42
  43         ./configure \
  44                 --prefix=/usr \
  45                 --qtdir=/usr \
  46                 --includedir="/usr/include/qca2" \
  47                 --libdir="/usr/$(get_libdir)/qca2" \
  48                 ${myconf} \
  49                 --no-separate-debug-info \
  50                 --disable-tests \
  51                 || die "configure failed"
  52
  53         eqmake4 ${PN}.pro
  54         emake || die "emake failed"
  55 }
  56
  57 src_install() {
  58         emake INSTALL_ROOT="${D}" install || die "emake install failed"
  59         dodoc README TODO
  60
  61         cat > "${T}"/44qca2 << EOF
  62 LDPATH=/usr/$(get_libdir)/qca2
  63 EOF
  64         doenvd "${T}"/44qca2
  65
  66         if use doc; then
  67                 dohtml "${S}"/apidocs/html/* || die "failed to install documentation"
  68         fi
  69
  70         if use examples; then
  71                 insinto /usr/share/doc/${PF}/
  72                 doins -r "${S}"/examples || die "failed to install examples"
  73         fi
  74 }