bin/umph

   1 #!/usr/bin/perl
   2 #
   3 # umph
   4 # Copyright (C) 2010-2011  Toni Gundogdu <legatvs@gmail.com>
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 #
  19
  20 use feature 'say';
  21
  22 use warnings;
  23 use strict;
  24
  25 binmode STDOUT, ":utf8";
  26 binmode STDERR, ":utf8";
  27
  28 use version 0.77 (); our $VERSION = version->declare("0.2.0");
  29
  30 use Getopt::ArgvFile(home => 1, startupFilename => [qw(.umphrc)]);
  31 use Getopt::Long qw(:config bundling);
  32 use Carp qw(croak);
  33
  34 exit main();
  35
  36 sub print_version
  37 {
  38   eval "require Umph::Prompt";
  39   my $p = $@ ? "" : ", Umph::Prompt version $Umph::Prompt::VERSION";
  40   say "umph version $VERSION$p
  41 Copyright (C) 2010-2011  Toni Gundogdu
  42 This is free software; see the source for copying conditions.  There is NO
  43 warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.";
  44   exit 0;
  45 }
  46
  47 sub print_help
  48 {
  49   require Pod::Usage;
  50   Pod::Usage::pod2usage(-exitstatus => 0, -verbose => 1);
  51 }
  52
  53 use constant MAX_RESULTS_LIMIT => 50;    # Refer to http://is.gd/OcSjwU
  54 my %config;
  55
  56 sub check_max_results_value
  57 {
  58   if ($config{max_results} > MAX_RESULTS_LIMIT)
  59   {
  60     say STDERR
  61       "WARNING --max-results exceeds max. accepted value, using "
  62       . MAX_RESULTS_LIMIT
  63       . " instead";
  64     $config{max_results} = MAX_RESULTS_LIMIT;
  65   }
  66 }
  67
  68 sub check_umph_prompt
  69 {
  70   if ($config{'interactive'} and not eval 'require Umph::Prompt')
  71   {
  72     say STDERR
  73       qq/WARNING Umph::Prompt not found, ignoring --interactive option/;
  74     $config{interactive} = 0;
  75   }
  76 }
  77
  78 sub init
  79 {
  80   GetOptions(
  81              \%config,
  82              'type|t=s',
  83              'start_index|start-index|s=i',
  84              'max_results|max-results|m=i',
  85              'interactive|i',
  86              'all|a',
  87              'json',
  88              'csv',
  89              'proxy=s',
  90              'no_proxy|no-proxy',
  91              'quiet|q',
  92              'version' => \&print_version,
  93              'help'    => \&print_help,
  94             ) or exit 1;
  95
  96   print_help if scalar @ARGV == 0;
  97
  98   $config{type}        ||= 'p';    # Default to "playlist".
  99   $config{start_index} ||= 1;      # Default to 1.
 100   $config{max_results} ||= 25;     # Default 25.
 101
 102   check_max_results_value;
 103   check_umph_prompt;
 104 }
 105
 106 sub spew_qe {print STDERR @_ unless $config{quiet}}
 107
 108 my @items;
 109
 110 sub main
 111 {
 112   init;
 113   spew_qe "Checking ... ";
 114
 115   require LWP;
 116   my $a = new LWP::UserAgent;
 117   $a->env_proxy;    # http://search.cpan.org/perldoc?LWP::UserAgent
 118   $a->proxy('http', $config{proxy}) if $config{proxy};
 119   $a->no_proxy('') if $config{no_proxy};
 120
 121   require XML::DOM;
 122   my $p = new XML::DOM::Parser(LWP_UserAgent => $a);
 123   my $s = $config{start_index};
 124   my $m = $config{all} ? MAX_RESULTS_LIMIT : $config{max_results};
 125
 126   while (1)
 127   {
 128     my $doc  = $p->parsefile(from_arg($ARGV[0], $s, $m));
 129     my $root = $doc->getDocumentElement;
 130     my $n    = 0;
 131     for my $entry ($root->getElementsByTagName("entry"))
 132     {
 133       my $t = to_item($entry, "title")->getFirstChild->getNodeValue;
 134       my $l =
 135         to_item($entry, "link")->getAttributeNode("href")->getValue;
 136       my %data = (title => $t, url => $l, selected => 1);
 137       push @items, \%data;
 138       spew_qe((++$n % 5 == 0) ? " " : ".");
 139       ++$s;
 140     }
 141     $doc->dispose;
 142
 143     last if $n == 0 or not $config{all};
 144   }
 145
 146   spew_qe "done.\n";
 147
 148   croak "error: nothing found\n" if scalar @items == 0;
 149
 150   open_prompt() if $config{interactive};
 151
 152   say qq/{\n  "video": [/ if $config{json};
 153
 154   my $i = 0;
 155
 156   foreach (@items)
 157   {
 158     if ($_->{selected} or not $config{interactive})
 159     {
 160       ++$i;
 161
 162       my $t = $_->{title} || "";
 163       $t =~ s/"/\\"/g;
 164
 165       if ($config{json})
 166       {
 167         say "," if $i > 1;
 168         say "    {";
 169         say qq/      "title": "$t",/;
 170         say qq/      "url": "$_->{url}"/;
 171         print "    }";
 172       }
 173       elsif ($config{csv}) {say qq/"$t","$_->{url}"/}
 174       else                 {say "$_->{url}"}
 175     }
 176   }
 177
 178   say "\n  ]\n}" if $config{json};
 179   0;
 180 }
 181
 182 use constant GURL => "http://gdata.youtube.com/feeds/api";
 183
 184 sub from_arg
 185 {
 186   my ($arg0, $s, $m) = @_;
 187
 188   my $u;
 189   if ($config{type} eq "u" or $config{type} eq "uploads")
 190   {
 191     $u = GURL . "/users/$arg0/uploads?v=2";
 192   }
 193   elsif ($config{type} eq "f" or $config{type} eq "favorites")
 194   {
 195     $u = GURL . "/users/$arg0/favorites?v=2";
 196   }
 197   else
 198   {
 199     $u = GURL . "/playlists/$arg0?v=2";
 200   }
 201
 202   $u .= "&start-index=$s";
 203   $u .= "&max-results=$m";
 204 }
 205
 206 sub to_item
 207 {
 208   my ($entry, $name) = @_;
 209   $entry->getElementsByTagName($name)->item(0);
 210 }
 211
 212 sub open_prompt
 213 {
 214   my $p = new Umph::Prompt(
 215
 216     # Commands.
 217     commands => {
 218       q => sub {
 219         my ($p, $args) = @_;
 220         $p->exit(\@items, $args);
 221       },
 222       d => sub {
 223         my ($p, $args) = @_;
 224         $p->display(\@items, $args);
 225       },
 226       m => sub {
 227         my ($p, $args) = @_;
 228         $p->max_shown_items(@{$args});
 229       },
 230       s => sub {
 231         my ($p, $args) = @_;
 232         $p->select(\@items, $args);
 233       },
 234       h => sub {
 235         my ($p, $args) = @_;
 236         my @a;
 237         push @a,
 238           {cmd => 'normal', desc => 'print results in default format'};
 239         push @a, {cmd => 'json', desc => 'print results in json'};
 240         push @a, {cmd => 'csv',  desc => 'print results in csv'};
 241         $p->help(\@a);
 242       },
 243       n => sub {
 244         $config{json} = 0;
 245         $config{csv}  = 0;
 246         say STDERR "=> print in default format";
 247       },
 248       j => sub {
 249         $config{json} = 1;
 250         $config{csv}  = 0;
 251         say STDERR "=> print in json";
 252       },
 253       c => sub {
 254         $config{json} = 0;
 255         $config{csv}  = 1;
 256         say STDERR "=> print in csv";
 257       },
 258     },
 259
 260     # Callbacks. All of these are optional.
 261     ontoggle => sub {
 262       my ($p, $args) = @_;
 263       $p->toggle(\@items, $args);
 264     },
 265     onitems  => sub {return \@items},
 266     onloaded => sub {
 267       my ($p, $args) = @_;
 268       $p->display(\@items, $args);
 269     },
 270
 271     # Other (required) settings
 272     total_items     => scalar @items,
 273     prompt_msg      => 'umph',
 274     max_shown_items => 20
 275   );
 276
 277   say STDERR qq/Enter prompt. Type "help" to get a list of commands./;
 278   $p->exec;
 279 }
 280
 281 __END__
 282
 283 =head1 SYNOPSIS
 284
 285 umph [-q] [-i] [-a] [--csv | --json] [-t E<lt>typeE<gt>]
 286      [--proxy E<lt>addrE<gt> | --no-proxy]
 287      [E<lt>playlist_idE<gt> | E<lt>usernameE<gt>]
 288
 289 =head2 OPTIONS
 290
 291      --help                     Print help and exit
 292      --version                  Print version and exit
 293  -q, --quiet                    Be quiet
 294  -i, --interactive              Run in interactive mode
 295  -t, --type arg (=p)            Get feed type
 296  -s, --start-index arg (=1)     Index of first matching result
 297  -m, --max-results arg (=25)    Max number of results included
 298  -a, --all                      Get all items
 299      --json                     Print details in JSON
 300      --csv                      Print details in CSV
 301      --proxy arg (=http_proxy)  Use proxy for HTTP connections
 302      --no-proxy                 Disable use of HTTP proxy
 303
 304 =cut
 305
 306 # vim: set ts=2 sw=2 tw=72 expandtab: