bin/umph

   1 #!/usr/bin/perl
   2 # -*- coding: ascii -*-
   3
   4 #
   5 # Copyright (C) 2010 Toni Gundogdu <legatvs@gmail.com>.
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21 use warnings;
  22 use strict;
  23
  24 binmode( STDOUT, ":utf8" );
  25 binmode( STDERR, ":utf8" );
  26
  27 use Getopt::ArgvFile( home => 1, startupFilename => [qw(.umphrc)] );
  28 use Getopt::Long qw(:config bundling);
  29
  30 my $VERSION = "0.1.1";
  31 my %config;
  32 my @entries;
  33 my $done = 0;
  34
  35 init();
  36 main();
  37 exit 0;
  38
  39 sub init {
  40     GetOptions(
  41         \%config,
  42         'interactive|i',
  43         'version|v' => \&print_version,
  44         'help|h'    => \&print_help,
  45     ) or exit(1);
  46 }
  47
  48 sub print_version {
  49     print
  50         "umph $VERSION. Copyright (C) 2010 Toni Gundogdu. License: GNU GPL version 3
  51 or later This is free software; see the source for copying conditions. There
  52 is NO warranty;  not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR
  53 PURPOSE.
  54 ";
  55     exit(0);
  56 }
  57
  58 sub print_help {
  59     require Pod::Usage;
  60     Pod::Usage::pod2usage( -exitstatus => 0, -verbose => 1 );
  61 }
  62
  63 sub main {
  64
  65     print_help if scalar @ARGV == 0;
  66
  67     my $req_body = "http://gdata.youtube.com/feeds/api/playlists/";
  68
  69     my $url = $ARGV[0];
  70
  71     if ( $url =~ /^http:/i ) {
  72
  73         # Looks like an URL.
  74         if ( $url =~ /view_play_list\?p=(.*?)$/i ) {
  75             $url = "$req_body$1";
  76         }
  77     }
  78     else {
  79
  80         # Assume playlist id.
  81         $url = "$req_body$url";
  82     }
  83     $url .= "?v=2";
  84
  85     print STDERR "Fetch $url ...\n";
  86
  87     require XML::DOM;
  88
  89     my $p    = new XML::DOM::Parser;
  90     my $doc  = $p->parsefile($url);
  91     my $root = $doc->getDocumentElement;
  92
  93     print STDERR ":: Parse playlist for video entries ...\n";
  94
  95     for my $entry ( $root->getElementsByTagName("entry") ) {
  96
  97         my $title = to_item( $entry, "title" )->getFirstChild->getNodeValue;
  98
  99         my $link
 100             = to_item( $entry, "link" )->getAttributeNode("href")->getValue;
 101
 102         my %data = ( title => $title, url => $link, selected => 1 );
 103         push @entries, \%data;
 104     }
 105
 106     $doc->dispose;
 107
 108     print STDERR "::: Found " . scalar @entries . " video entries\n";
 109
 110     prompt() if $config{interactive};
 111
 112     foreach (@entries) {
 113         print "$_->{url}\n" if $_->{selected} || !$config{interactive};
 114     }
 115 }
 116
 117 sub to_item {
 118     my ( $entry, $name ) = @_;
 119     return $entry->getElementsByTagName($name)->item(0);
 120 }
 121
 122 sub prompt {
 123     my $p    = "(umph) ";
 124     my %cmds = (
 125         'h' => \&help,
 126         'q' => \&quit,
 127         'l' => \&list,
 128         'd' => \&dump,
 129         'a' => \&select_all,
 130         'n' => \&select_none,
 131         'r' => \&revert_selection,
 132     );
 133     print STDERR "Enter prompt\nNote: all videos selected by default\n";
 134     print STDERR "Type \"help\" to get a list of commands\n";
 135     while ( !$done ) {
 136         print STDERR $p;
 137         my $ln = <STDIN>;
 138         next if !$ln;
 139         chomp $ln;
 140         if ( $ln =~ /(\d+)/ ) {
 141             toggle_number($1);
 142         }
 143         else {
 144             next if $ln !~ /(\w)/;
 145             $cmds{$1}() if defined $cmds{$1};
 146         }
 147     }
 148 }
 149
 150 sub toggle_number {
 151     my $i = (shift) - 1;
 152     if ( $i >= 0 && exists $entries[$i] ) {
 153         $entries[$i]->{selected} = !$entries[$i]->{selected};
 154         list();
 155     }
 156     else {
 157         printf STDERR "error: out of range\n";
 158     }
 159 }
 160
 161 sub help {
 162     print STDERR "
 163 Commands:
 164   help      .. this
 165   list      .. display playlist entries (numbered, *=selected)
 166   all       .. select all videos
 167   none      .. select none
 168   revert    .. revert selection
 169   (number)  .. toggle (select, unselect) video, see list output
 170 -
 171   dump      .. dump selected video urls to stdout and exit
 172   quit      .. terminate program
 173
 174 Command name abbreviations are allowed, e.g. \"a\" instead of \"all\".
 175 ";
 176 }
 177
 178 sub quit {
 179     exit 0;
 180 }
 181
 182 sub list {
 183     my $i = 0;
 184     foreach (@entries) {
 185         printf STDERR "%2d: $_->{title}%s\n", ++$i, $_->{selected} ? "*" : "";
 186     }
 187 }
 188
 189 sub dump {
 190     $done = 1;
 191 }
 192
 193 sub select_all {
 194     $_->{selected} = 1 foreach @entries;
 195     list();
 196 }
 197
 198 sub select_none {
 199     $_->{selected} = 0 foreach @entries;
 200     list();
 201 }
 202
 203 sub revert_selection {
 204     $_->{selected} = !$_->{selected} foreach @entries;
 205     list();
 206 }
 207
 208 __END__
 209
 210 =head1 NAME
 211
 212 umph - Youtube video playlist parser for cclive and alike tools
 213
 214 =head1 SYNOPSIS
 215
 216 umph [options] [URL|PLAYLIST_ID]
 217
 218 =head1 DESCRIPTION
 219
 220 umph is a command line tool for parsing Youtube playlists.
 221 It was written to be used with cclive but other tools may
 222 use it also.
 223
 224 =head1 OPTIONS
 225
 226  -h, --help             print help and exit
 227  -v, --version          print version and exit
 228  -i, --interactive      be interactive, default is no
 229
 230 =head1 OPTIONS DESCRIPTIONS
 231
 232 =over 4
 233
 234 =item B<-h, --help>
 235
 236 Print help and exit.
 237
 238 =item B<-v, --version>
 239
 240 Print version and exit.
 241
 242 =item B<-i, --interactive>
 243
 244 Be interactive, default is no. Implies prompting, or selecting videos.
 245
 246 =back
 247
 248 =head1 EXAMPLES
 249
 250 =over 4
 251
 252 =item umph "http://www.youtube.com/view_play_list?p=AAF3A1D0CA1E304F"
 253
 254 =item umph "http://gdata.youtube.com/feeds/api/playlists/AAF3A1D0CA1E304F?v=2"
 255
 256 =item umph AAF3A1D0CA1E304F
 257
 258 All of the three above do the same.
 259
 260 =item umph AAF3A1D0CA1E304F | cclive -f mp4
 261
 262 Passes the parsed video links to cclive.
 263
 264 =back
 265
 266 =head1 EXIT STATUS
 267
 268 Exits 0 on success, otherwise 1.
 269
 270 =head1 FILES
 271
 272 =over 4
 273
 274 =item $HOME/.umphrc, for example:
 275
 276 echo "--interactive" >> ~/.umphrc
 277
 278 =back
 279
 280 =head1 OTHER
 281
 282 umph depends on XML::DOM which uses LWP::UserAgent to retrieve
 283 the playlist data. Note that LWP::UserAgent reads http_proxy
 284 environment setting.
 285
 286 Project:
 287   http://umph.googlecode.com/
 288
 289 Development repository:
 290   git clone git://repo.or.cz/umph.git
 291
 292 =head1 SEE ALSO
 293
 294 C<cclive(1)> C<clive(1)>
 295
 296 =head1 AUTHOR
 297
 298 Toni Gundogdu <legatvs@gmail.com>
 299
 300 =cut
 301
 302