libc/sysdeps/linux/riscv64/getcontext.S

   1 /* Save current context.
   2    Copyright (C) 2009-2018 Free Software Foundation, Inc.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library.  If not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18 #include "ucontext-macros.h"
  19
  20 /* int getcontext (ucontext_t *ucp) */
  21
  22         .text
  23 LEAF (getcontext)
  24         SAVE_INT_REG (ra,   0, a0)
  25         SAVE_INT_REG (ra,   1, a0)
  26         SAVE_INT_REG (sp,   2, a0)
  27         SAVE_INT_REG (s0,   8, a0)
  28         SAVE_INT_REG (s1,   9, a0)
  29         SAVE_INT_REG (x0,  10, a0)      /* return 0 by overwriting a0.  */
  30         SAVE_INT_REG (s2,  18, a0)
  31         SAVE_INT_REG (s3,  19, a0)
  32         SAVE_INT_REG (s4,  20, a0)
  33         SAVE_INT_REG (s5,  21, a0)
  34         SAVE_INT_REG (s6,  22, a0)
  35         SAVE_INT_REG (s7,  23, a0)
  36         SAVE_INT_REG (s8,  24, a0)
  37         SAVE_INT_REG (s9,  25, a0)
  38         SAVE_INT_REG (s10, 26, a0)
  39         SAVE_INT_REG (s11, 27, a0)
  40
  41 #ifndef __riscv_float_abi_soft
  42         frsr    a1
  43
  44         SAVE_FP_REG (fs0,   8, a0)
  45         SAVE_FP_REG (fs1,   9, a0)
  46         SAVE_FP_REG (fs2,  18, a0)
  47         SAVE_FP_REG (fs3,  19, a0)
  48         SAVE_FP_REG (fs4,  20, a0)
  49         SAVE_FP_REG (fs5,  21, a0)
  50         SAVE_FP_REG (fs6,  22, a0)
  51         SAVE_FP_REG (fs7,  23, a0)
  52         SAVE_FP_REG (fs8,  24, a0)
  53         SAVE_FP_REG (fs9,  25, a0)
  54         SAVE_FP_REG (fs10, 26, a0)
  55         SAVE_FP_REG (fs11, 27, a0)
  56
  57         sw      a1, MCONTEXT_FSR(a0)
  58 #endif /* __riscv_float_abi_soft */
  59
  60 /* rt_sigprocmask (SIG_BLOCK, NULL, &ucp->uc_sigmask, _NSIG8) */
  61         li      a3, _NSIG8
  62         add     a2, a0, UCONTEXT_SIGMASK
  63         mv      a1, zero
  64         li      a0, SIG_BLOCK
  65
  66         li      a7, SYS_ify (rt_sigprocmask)
  67         scall
  68         bltz    a0, 99f
  69
  70         ret
  71
  72 99:     j       __syscall_error
  73
  74 PSEUDO_END (getcontext)