libc/sysdeps/linux/powerpc/crt1.S

   1 /*
   2  * Copyright (C) 2003 by Erik Andersen
   3  *
   4  * This program is free software; you can redistribute it and/or modify it
   5  * under the terms of the GNU Library General Public License as published by
   6  * the Free Software Foundation; either version 2 of the License, or (at your
   7  * option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful, but WITHOUT
  10  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  11  * FITNESS FOR A PARTICULAR PURPOSE. See the GNU Library General Public License
  12  * for more details.
  13  *
  14  * You should have received a copy of the GNU Library General Public License
  15  * along with this program; see the file COPYING.LIB.  If not, see
  16  * <http://www.gnu.org/licenses/>.
  17  */
  18
  19 #include <features.h>
  20 /* Integer registers.  */
  21 #define r0      0
  22 #define r1      1
  23 #define r2      2
  24 #define r3      3
  25 #define r4      4
  26 #define r5      5
  27 #define r6      6
  28 #define r7      7
  29 #define r8      8
  30 #define r9      9
  31 #define r10     10
  32 #define r13     13
  33 #define r31     31
  34
  35 .text
  36         .globl  _start
  37         .type   _start,%function
  38         .type   _init,%function
  39         .type   _fini,%function
  40 #ifndef __UCLIBC_CTOR_DTOR__
  41         .weak _init
  42         .weak _fini
  43 #endif
  44 #ifdef L_rcrt1
  45         .type reloc_static_pie,%function
  46 #endif
  47         .type   main,%function
  48         .type   __uClibc_main,%function
  49
  50 _start:
  51         mr      r9,r1   /* Save the stack pointer and pass it to __uClibc_main */
  52         clrrwi  r1,r1,4 /* Align stack ptr to 16 bytes */
  53 #ifdef __PIC__
  54 # ifdef HAVE_ASM_PPC_REL16
  55         bcl     20,31,1f
  56 1:      mflr    r31
  57         addis   r31,r31,_GLOBAL_OFFSET_TABLE_-1b@ha
  58         addi    r31,r31,_GLOBAL_OFFSET_TABLE_-1b@l
  59 # else
  60         bl      _GLOBAL_OFFSET_TABLE_-4@local
  61         mflr    r31
  62 # endif
  63         /* in PIC/PIE, plt stubs need r30 to point to the GOT if using secure-plt */
  64 # ifdef PPC_HAS_SECUREPLT
  65         mr      30,31
  66 # endif
  67 #ifdef L_rcrt1
  68         stwu r3, -4(r1)                                 /* Save r3 */
  69         stwu r9, -16(r1)                                /* Save r9 */
  70         bcl 20,31,2f                                    /* Jump to label 2 */
  71 2:      mflr r3                                                 /* Load lr into r3 */
  72         addis r3, r3, _DYNAMIC-2b@ha    /* Add high half of _DYNAMIC to r3 */
  73         addi r3,r3,_DYNAMIC-2b@l                /* Add low half of _DYNAMIC */
  74         lwz r4, 0(r31)                                  /* load _DYNAMIC from the GOT */
  75         subf r3, r4, r3                                 /* sub _DYNAMIC@got and it's actual address */
  76         bl reloc_static_pie                             /* Call reloc_static_pie */
  77         lwzu r9, 0(r1)                                  /* restore r9 */
  78         addi r1, r1, 16                                 /* update stack pointer */
  79         lwzu r3, 0(r1)                                  /* restore r3 */
  80         addi r1, r1, 4                                  /* update stack pointer */
  81         li r5, 0                                                /* zero r5 */
  82 #endif
  83 #endif
  84         /* Set up the small data pointer in r13.  */
  85 #ifdef __PIC__
  86         lwz     r13,_SDA_BASE_@got(r31)
  87 #else
  88         lis     r13,_SDA_BASE_@ha
  89         addi    r13,r13,_SDA_BASE_@l
  90 #endif
  91         /* Set up an initial stack frame, and clear the LR.  */
  92         li      r0,0
  93         stwu    r1,-16(r1)
  94         mtlr    r0
  95         stw     r0,0(r1)
  96         /* find argc from the stack pointer */
  97         lwz     r4,0(r9)
  98         /* find argv one word offset from the stack pointer */
  99         addi    r5,r9,4
 100         mr      r8,r3 /* Pass _dl_fini from ldso or NULL if statically linked */
 101                       /* Note: PPC depends on the kernel to zero r3 before */
 102                       /* handing over to user space, otherwise static apps */
 103                       /* will SEGV during exit() */
 104
 105         /* Ok, now run uClibc's main() -- shouldn't return */
 106 #ifdef __PIC__
 107         lwz     r6,_init@got(r31)
 108         lwz     r7,_fini@got(r31)
 109         lwz     r3,main@got(r31)
 110         b       __uClibc_main@plt
 111 #else
 112         lis     r6,_init@ha     # load top 16 bits
 113         addi    r6,r6,_init@l   # load bottom 16 bits
 114         lis     r7,_fini@ha     # load top 16 bits
 115         addi    r7,r7,_fini@l   # load bottom 16 bits
 116         lis     r3,main@ha      # load top 16 bits
 117         addi    r3,r3,main@l    # load bottom 16 bits
 118         b       __uClibc_main
 119 #endif
 120
 121 .size _start,.-_start
 122
 123 /* Define a symbol for the first piece of initialized data.  */
 124         .data
 125         .globl __data_start
 126 __data_start:
 127         .long 0
 128         .weak data_start
 129         data_start = __data_start
 130