lib_blackfin/memmove.S

   1 /*
   2  * File: memmove.S
   3  *
   4  * Copyright 2004-2007 Analog Devices Inc.
   5  * Enter bugs at http://blackfin.uclinux.org/
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License as published by
   9  * the Free Software Foundation; either version 2 of the License, or
  10  * (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, see the file COPYING, or write
  19  * to the Free Software Foundation, Inc.,
  20  * 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
  21  */
  22
  23 .align 2
  24
  25 /*
  26  * C Library function MEMMOVE
  27  * R0 = To Address (leave unchanged to form result)
  28  * R1 = From Address
  29  * R2 = count
  30  * Data may overlap
  31  */
  32
  33 .globl _memmove;
  34 _memmove:
  35         I1 = P3;
  36         P0 = R0;                  /* P0 = To address */
  37         P3 = R1;                  /* P3 = From Address */
  38         P2 = R2 ;                 /* P2 = count */
  39         CC = P2 == 0;             /* Check zero count*/
  40         IF CC JUMP .Lfinished;    /* very unlikely */
  41
  42         CC = R1 < R0 (IU);        /* From < To */
  43         IF !CC JUMP .Lno_overlap;
  44         R3 = R1 + R2;
  45         CC = R0 <= R3 (IU);       /* (From+len) >= To */
  46         IF CC JUMP .Loverlap;
  47 .Lno_overlap:
  48         R3 = 11;
  49         CC = R2 <= R3;
  50         IF CC JUMP  .Lbytes;
  51         R3 = R1 | R0;             /* OR addresses together */
  52         R3 <<= 30;                /* check bottom two bits */
  53         CC =  AZ;                 /* AZ set if zero.*/
  54         IF !CC JUMP  .Lbytes ;    /* Jump if addrs not aligned.*/
  55
  56         I0 = P3;
  57         P1 = P2 >> 2;             /* count = n/4 */
  58         P1 += -1;
  59         R3 =  3;
  60         R2 = R2 & R3;             /* remainder */
  61         P2 = R2;                  /* set remainder */
  62         R1 = [I0++];
  63
  64         LSETUP (.Lquad_loop , .Lquad_loop) LC0=P1;
  65 .Lquad_loop: MNOP || [P0++] = R1 || R1 = [I0++];
  66         [P0++] = R1;
  67
  68         CC = P2 == 0;             /* any remaining bytes? */
  69         P3 = I0;                  /* Ammend P3 to updated ptr. */
  70         IF !CC JUMP .Lbytes;
  71         P3 = I1;
  72         RTS;
  73
  74 .Lbytes:     LSETUP (.Lbyte2_s , .Lbyte2_e) LC0=P2;
  75 .Lbyte2_s:   R1 = B[P3++](Z);
  76 .Lbyte2_e:   B[P0++] = R1;
  77
  78 .Lfinished:  P3 = I1;
  79         RTS;
  80
  81 .Loverlap:
  82         P2 += -1;
  83         P0 = P0 + P2;
  84         P3 = P3 + P2;
  85         R1 = B[P3--] (Z);
  86         CC = P2 == 0;
  87         IF CC JUMP .Lno_loop;
  88         LSETUP (.Lol_s, .Lol_e) LC0 = P2;
  89 .Lol_s:    B[P0--] = R1;
  90 .Lol_e:    R1 = B[P3--] (Z);
  91 .Lno_loop: B[P0] = R1;
  92         P3 = I1;
  93         RTS;