lib/afblue.pl

   1 #! /usr/bin/perl -w
   2 # -*- Perl -*-
   3 #
   4 # afblue.pl
   5 #
   6 # Process a blue zone character data file.
   7 #
   8 # Copyright 2013 by
   9 # David Turner, Robert Wilhelm, and Werner Lemberg.
  10 #
  11 # This file is part of the FreeType project, and may only be used,
  12 # modified, and distributed under the terms of the FreeType project
  13 # license, LICENSE.TXT.  By continuing to use, modify, or distribute
  14 # this file you indicate that you have read the license and
  15 # understand and accept it fully.
  16
  17 use strict;
  18 use warnings;
  19 use English '-no_match_vars';
  20 use open ':std', ':locale';
  21
  22
  23 my $prog = $PROGRAM_NAME;
  24 $prog =~ s| .* / ||x;      # Remove path.
  25
  26 die "usage: $prog datafile < infile > outfile\n" if $#ARGV != 0;
  27
  28
  29 my $datafile = $ARGV[0];
  30
  31 my %diversions;        # The extracted and massaged data from `datafile'.
  32 my @else_stack;        # Booleans to track else-clauses.
  33 my @name_stack;        # Stack of integers used for names of aux. variables.
  34
  35 my $curr_enum;         # Name of the current enumeration.
  36 my $curr_array;        # Name of the current array.
  37 my $curr_max;          # Name of the current maximum value.
  38
  39 my $curr_enum_element; # Name of the current enumeration element.
  40 my $curr_offset;       # The offset relative to current aux. variable.
  41 my $curr_elem_size;    # The size of the current string or block.
  42
  43 my $have_sections = 0; # Boolean; set if start of a section has been seen.
  44 my $have_strings;      # Boolean; set if current section contains strings.
  45 my $have_blocks;       # Boolean; set if current section contains blocks.
  46
  47 my $have_enum_element; # Boolean; set if we have an enumeration element.
  48 my $in_string;         # Boolean; set if a string has been parsed.
  49
  50 my $num_sections = 0;  # Number of sections seen so far.
  51
  52 my $last_aux;          # Name of last auxiliary variable.
  53
  54
  55 # Regular expressions.
  56
  57 # [<ws>] <enum_name> <ws> <array_name> <ws> <max_name> [<ws>] ':' [<ws>] '\n'
  58 my $section_re = qr/ ^ \s* (\S+) \s+ (\S+) \s+ (\S+) \s* : \s* $ /x;
  59
  60 # [<ws>] <enum_element_name> [<ws>] '\n'
  61 my $enum_element_re = qr/ ^ \s* ( [A-Za-z0-9_]+ ) \s* $ /x;
  62
  63 # '#' <preprocessor directive> '\n'
  64 my $preprocessor_re = qr/ ^ \# /x;
  65
  66 # '/' '/' <comment> '\n'
  67 my $comment_re = qr| ^ // |x;
  68
  69 # empty line
  70 my $whitespace_only_re = qr/ ^ \s* $ /x;
  71
  72 # [<ws>] '"' <string> '"' [<ws>] '\n'  (<string> doesn't contain newlines)
  73 my $string_re = qr/ ^ \s*
  74                        " ( (?: [^"\\]++ | \\. )*+ ) "
  75                        \s* $ /x;
  76
  77 # [<ws>] '{' <block> '}' [<ws>] '\n'  (<block> can contain newlines)
  78 my $block_start_re = qr/ ^ \s* \{ /x;
  79
  80 # We need the capturing group for `split' to make it return the separator
  81 # tokens (i.e., the opening and closing brace) also.
  82 my $brace_re = qr/ ( [{}] ) /x;
  83
  84
  85 sub Warn
  86 {
  87   my $message = shift;
  88   warn "$datafile:$INPUT_LINE_NUMBER: warning: $message\n";
  89 }
  90
  91
  92 sub Die
  93 {
  94   my $message = shift;
  95   die "$datafile:$INPUT_LINE_NUMBER: error: $message\n";
  96 }
  97
  98
  99 my $warned_before = 0;
 100
 101 sub warn_before
 102 {
 103   Warn("data before first section gets ignored") unless $warned_before;
 104   $warned_before = 1;
 105 }
 106
 107
 108 sub strip_newline
 109 {
 110   chomp;
 111   s/ \x0D $ //x;
 112 }
 113
 114
 115 sub end_curr_string
 116 {
 117   # Append final null byte to string.
 118   if ($have_strings)
 119   {
 120     push @{$diversions{$curr_array}}, "    '\\0',\n" if $in_string;
 121
 122     $curr_offset++;
 123     $in_string = 0;
 124   }
 125 }
 126
 127
 128 sub update_max_elem_size
 129 {
 130   if ($curr_elem_size)
 131   {
 132     my $max = pop @{$diversions{$curr_max}};
 133     $max = $curr_elem_size if $curr_elem_size > $max;
 134     push @{$diversions{$curr_max}}, $max;
 135   }
 136 }
 137
 138
 139 sub convert_non_ascii_char
 140 {
 141   # A UTF-8 character outside of the printable ASCII range, with possibly a
 142   # leading backslash character.
 143   my $s = shift;
 144
 145   # Here we count characters, not bytes.
 146   $curr_elem_size += length $s;
 147
 148   utf8::encode($s);
 149   $s = uc unpack 'H*', $s;
 150
 151   $curr_offset += $s =~ s/\G(..)/'\\x$1', /sg;
 152
 153   return $s;
 154 }
 155
 156
 157 sub convert_ascii_chars
 158 {
 159   # A series of ASCII characters in the printable range.
 160   my $s = shift;
 161
 162   my $count = $s =~ s/\G(.)/'$1', /g;
 163   $curr_offset += $count;
 164   $curr_elem_size += $count;
 165
 166   return $s;
 167 }
 168
 169
 170 sub convert_literal
 171 {
 172   my $s = shift;
 173   my $orig = $s;
 174
 175   # ASCII printables and space
 176   my $safe_re = '\x20-\x7E';
 177   # ASCII printables and space, no backslash
 178   my $safe_no_backslash_re = '\x20-\x5B\x5D-\x7E';
 179
 180   $s =~ s{
 181            (?: \\? ( [^$safe_re] )
 182                | ( (?: [$safe_no_backslash_re]
 183                        | \\ [$safe_re] )+ ) )
 184          }
 185          {
 186            defined($1) ? convert_non_ascii_char($1)
 187                        : convert_ascii_chars($2)
 188          }egx;
 189
 190    # We assume that `$orig' doesn't contain `*/'
 191    return $s . " /* $orig */";
 192 }
 193
 194
 195 sub aux_name
 196 {
 197   return "af_blue_" . $num_sections. "_" . join('_', reverse @name_stack);
 198 }
 199
 200
 201 sub aux_name_next
 202 {
 203   $name_stack[$#name_stack]++;
 204   my $name = aux_name();
 205   $name_stack[$#name_stack]--;
 206
 207   return $name;
 208 }
 209
 210
 211 sub enum_val_string
 212 {
 213   # Build string which holds code to save the current offset in an
 214   # enumeration element.
 215   my $aux = shift;
 216
 217   my $add = ($last_aux eq "af_blue_" . $num_sections . "_0" )
 218               ? ""
 219               : "$last_aux + ";
 220
 221   return "    $aux = $add$curr_offset,\n";
 222 }
 223
 224
 225
 226 # Process data file.
 227
 228 open(DATA, $datafile) || die "$prog: can't open \`$datafile': $OS_ERROR\n";
 229
 230 while (<DATA>)
 231 {
 232   strip_newline();
 233
 234   next if /$comment_re/;
 235   next if /$whitespace_only_re/;
 236
 237   if (/$section_re/)
 238   {
 239     Warn("previous section is empty") if ($have_sections
 240                                           && !$have_strings
 241                                           && !$have_blocks);
 242
 243     end_curr_string();
 244     update_max_elem_size();
 245
 246     # Save captured groups from `section_re'.
 247     $curr_enum = $1;
 248     $curr_array = $2;
 249     $curr_max = $3;
 250
 251     $curr_enum_element = "";
 252     $curr_offset = 0;
 253
 254     Warn("overwriting already defined enumeration \`$curr_enum'")
 255       if exists($diversions{$curr_enum});
 256     Warn("overwriting already defined array \`$curr_array'")
 257       if exists($diversions{$curr_array});
 258     Warn("overwriting already defined maximum value \`$curr_max'")
 259       if exists($diversions{$curr_max});
 260
 261     $diversions{$curr_enum} = [];
 262     $diversions{$curr_array} = [];
 263     $diversions{$curr_max} = [];
 264
 265     push @{$diversions{$curr_max}}, 0;
 266
 267     @name_stack = ();
 268     push @name_stack, 0;
 269
 270     $have_sections = 1;
 271     $have_strings = 0;
 272     $have_blocks = 0;
 273
 274     $have_enum_element = 0;
 275     $in_string = 0;
 276
 277     $num_sections++;
 278     $curr_elem_size = 0;
 279
 280     $last_aux = aux_name();
 281
 282     next;
 283   }
 284
 285   if (/$preprocessor_re/)
 286   {
 287     if ($have_sections)
 288     {
 289       # Having preprocessor conditionals complicates the computation of
 290       # correct offset values.  We have to introduce auxiliary enumeration
 291       # elements with the name `af_blue_<s>_<n1>_<n2>_...' which store
 292       # offsets to be used in conditional clauses.  `<s>' is the number of
 293       # sections seen so far, `<n1>' is the number of `#if' and `#endif'
 294       # conditionals seen so far in the topmost level, `<n2>' the number of
 295       # `#if' and `#endif' conditionals seen so far one level deeper, etc.
 296       # As a consequence, uneven values are used within a clause, and even
 297       # values after a clause, since the C standard doesn't allow the
 298       # redefinition of an enumeration value.  For example, the name
 299       # `af_blue_5_1_6' is used to construct enumeration values in the fifth
 300       # section after the third (second-level) if-clause within the first
 301       # (top-level) if-clause.  After the first top-level clause has
 302       # finished, `af_blue_5_2' is used.  The current offset is then
 303       # relative to the value stored in the current auxiliary element.
 304
 305       if (/ ^ \# \s* if /x)
 306       {
 307         push @else_stack, 0;
 308
 309         $name_stack[$#name_stack]++;
 310
 311         push @{$diversions{$curr_enum}}, enum_val_string(aux_name());
 312         $last_aux = aux_name();
 313
 314         push @name_stack, 0;
 315
 316         $curr_offset = 0;
 317       }
 318       elsif (/ ^ \# \s* elif /x)
 319       {
 320         Die("unbalanced #elif") unless @else_stack;
 321
 322         pop @name_stack;
 323
 324         push @{$diversions{$curr_enum}}, enum_val_string(aux_name_next());
 325         $last_aux = aux_name();
 326
 327         push @name_stack, 0;
 328
 329         $curr_offset = 0;
 330       }
 331       elsif (/ ^ \# \s* else /x)
 332       {
 333         my $prev_else = pop @else_stack;
 334         Die("unbalanced #else") unless defined($prev_else);
 335         Die("#else already seen") if $prev_else;
 336         push @else_stack, 1;
 337
 338         pop @name_stack;
 339
 340         push @{$diversions{$curr_enum}}, enum_val_string(aux_name_next());
 341         $last_aux = aux_name();
 342
 343         push @name_stack, 0;
 344
 345         $curr_offset = 0;
 346       }
 347       elsif (/ ^ \# \s* endif /x)
 348       {
 349         my $prev_else = pop @else_stack;
 350         Die("unbalanced #endif") unless defined($prev_else);
 351
 352         pop @name_stack;
 353         $name_stack[$#name_stack]++;
 354
 355         # If there is no else-clause for an if-clause, we add one.  This is
 356         # necessary to have correct offsets.
 357         if (!$prev_else)
 358         {
 359           push @{$diversions{$curr_enum}}, enum_val_string(aux_name())
 360                                            . "#else\n";
 361
 362           $curr_offset = 0;
 363         }
 364
 365         push @{$diversions{$curr_enum}}, enum_val_string(aux_name());
 366         $last_aux = aux_name();
 367
 368         $curr_offset = 0;
 369       }
 370
 371       # Handle (probably continued) preprocessor lines.
 372     CONTINUED_LOOP:
 373       {
 374         do
 375         {
 376           strip_newline();
 377
 378           push @{$diversions{$curr_enum}}, $ARG . "\n";
 379           push @{$diversions{$curr_array}}, $ARG . "\n";
 380
 381           last CONTINUED_LOOP unless / \\ $ /x;
 382
 383         } while (<DATA>);
 384       }
 385     }
 386     else
 387     {
 388       warn_before();
 389     }
 390
 391     next;
 392   }
 393
 394   if (/$enum_element_re/)
 395   {
 396     end_curr_string();
 397     update_max_elem_size();
 398
 399     $curr_enum_element = $1;
 400     $have_enum_element = 1;
 401     $curr_elem_size = 0;
 402
 403     next;
 404   }
 405
 406   if (/$string_re/)
 407   {
 408     if ($have_sections)
 409     {
 410       Die("strings and blocks can't be mixed in a section") if $have_blocks;
 411
 412       # Save captured group from `string_re'.
 413       my $string = $1;
 414
 415       if ($have_enum_element)
 416       {
 417         push @{$diversions{$curr_enum}}, enum_val_string($curr_enum_element);
 418         $have_enum_element = 0;
 419       }
 420
 421       $string = convert_literal($string);
 422
 423       push @{$diversions{$curr_array}}, "    $string\n";
 424
 425       $have_strings = 1;
 426       $in_string = 1;
 427     }
 428     else
 429     {
 430       warn_before();
 431     }
 432
 433     next;
 434   }
 435
 436   if (/$block_start_re/)
 437   {
 438     if ($have_sections)
 439     {
 440       Die("strings and blocks can't be mixed in a section") if $have_strings;
 441
 442       my $depth = 0;
 443       my $block = "";
 444       my $block_end = 0;
 445
 446       # Count braces while getting the block.
 447     BRACE_LOOP:
 448       {
 449         do
 450         {
 451           strip_newline();
 452
 453           foreach my $substring (split(/$brace_re/))
 454           {
 455             if ($block_end)
 456             {
 457               Die("invalid data after last matching closing brace")
 458                 if $substring !~ /$whitespace_only_re/;
 459             }
 460
 461             $block .= $substring;
 462
 463             if ($substring eq '{')
 464             {
 465               $depth++;
 466             }
 467             elsif ($substring eq '}')
 468             {
 469               $depth--;
 470
 471               $block_end = 1 if $depth == 0;
 472             }
 473           }
 474
 475           # If we are here, we have run out of substrings, so get next line
 476           # or exit.
 477           last BRACE_LOOP if $block_end;
 478
 479           $block .= "\n";
 480
 481         } while (<DATA>);
 482       }
 483
 484       if ($have_enum_element)
 485       {
 486         push @{$diversions{$curr_enum}}, enum_val_string($curr_enum_element);
 487         $have_enum_element = 0;
 488       }
 489
 490       push @{$diversions{$curr_array}}, $block . ",\n";
 491
 492       $curr_offset++;
 493       $curr_elem_size++;
 494
 495       $have_blocks = 1;
 496     }
 497     else
 498     {
 499       warn_before();
 500     }
 501
 502     next;
 503   }
 504
 505   # Garbage.  We weren't able to parse the data.
 506   Die("syntax error");
 507 }
 508
 509 # Finalize data.
 510 end_curr_string();
 511 update_max_elem_size();
 512
 513
 514 # Filter stdin to stdout, replacing `@...@' templates.
 515
 516 sub emit_diversion
 517 {
 518   my $diversion_name = shift;
 519   return (exists($diversions{$1})) ? "@{$diversions{$1}}"
 520                                    : "@" . $diversion_name . "@";
 521 }
 522
 523
 524 $LIST_SEPARATOR = '';
 525
 526 my $s1 = "This file has been generated by the Perl script \`$prog',";
 527 my $s1len = length $s1;
 528 my $s2 = "using data from file \`$datafile'.";
 529 my $s2len = length $s2;
 530 my $slen = ($s1len > $s2len) ? $s1len : $s2len;
 531
 532 print "/* " . $s1 . " " x ($slen - $s1len) . " */\n"
 533       . "/* " . $s2 . " " x ($slen - $s2len) . " */\n"
 534       . "\n";
 535
 536 while (<STDIN>)
 537 {
 538   s/ @ ( [A-Za-z0-9_]+? ) @ / emit_diversion($1) /egx;
 539   print;
 540 }
 541
 542 # EOF