CMakeLists.txt

   1 project(trojita)
   2 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
   3
   4 # Qt5's qt5_use_modules need 2.8.9+
   5 # On win32, we need QtMain linking, which means 2.8.11+
   6 # EL7 ships 2.8.11, Debian 8 ships 3.0.2, and Ubuntu 14.04 LTS has 2.8.12
   7 cmake_minimum_required(VERSION 2.8.11)
   8 cmake_policy(SET CMP0020 NEW)
   9
  10 if(POLICY CMP0054)
  11     # Silence warnings in TrojitaOption.cmake; we are fine with only doing the
  12     # expansion by hand
  13     cmake_policy(SET CMP0054 NEW)
  14 endif()
  15
  16 if(POLICY CMP0043)
  17     # We make use of CMAKE_CXXFLAGS_DEBUG...
  18     cmake_policy(SET CMP0043 OLD)
  19 endif()
  20
  21 # Set a default build type if none was specified. This was shamelessly stolen
  22 # from VTK's cmake setup because these guys produce both CMake and a project that
  23 # manipulates this variable, and the web is full of posts where people say that
  24 # it is apparently evil to just set the build type in a way an earlier version of
  25 # this patch did. Oh, and the location of this check/update matters, apparently.
  26 #
  27 # Yes, this is just plain crazy.
  28 if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  29     message(STATUS "Setting build type to 'RelWithDebInfo' as none was specified.")
  30     set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING "Choose the type of build." FORCE)
  31     # Set the possible values of build type for cmake-gui
  32     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
  33 endif()
  34
  35 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
  36
  37 include(FindCXXFeatures)
  38 if(NOT CXXFeatures_auto_FOUND)
  39     message(SEND_ERROR "Your compiler doesn't support C++11's auto")
  40 endif()
  41 if(NOT CXXFeatures_static_assert_FOUND)
  42     message(SEND_ERROR "Your compiler doesn't support C++11's static_assert")
  43 endif()
  44 if(NOT CXXFeatures_alignof_FOUND)
  45     message(SEND_ERROR "Your compiler doesn't support C++11's alignof")
  46 endif()
  47 if(NOT CXXFeatures_nullptr_FOUND)
  48     message(SEND_ERROR "Your compiler doesn't support C++11's nullptr")
  49 endif()
  50 if(NOT CXXFeatures_lambda_FOUND)
  51     message(SEND_ERROR "Your compiler doesn't support C++11's lambda functions")
  52 endif()
  53 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${CXX11_COMPILER_FLAGS}")
  54
  55 include(TrojitaOption)
  56
  57 trojita_option(WITH_DESKTOP "Build desktop version" ON)
  58 trojita_option(WITH_DBUS "Build with DBus library" AUTO)
  59 trojita_option(WITH_RAGEL "Build with Ragel library" AUTO)
  60 trojita_option(WITH_ZLIB "Build with zlib library" AUTO)
  61 trojita_option(WITH_SHARED_PLUGINS "Enable shared dynamic plugins" ON)
  62 trojita_option(WITH_TESTS "Build tests" ON)
  63 trojita_option(WITH_MIMETIC "Build with client-side MIME parsing" AUTO)
  64 trojita_option(WITH_GPGMEPP "Build with the GpgME++ library for cryptography" AUTO)
  65
  66 if(WIN32)
  67     trojita_option(WITH_NSIS "Build Windows NSIS installer" AUTO "WITH_DESKTOP")
  68 endif()
  69
  70 if(UNIX AND NOT APPLE)
  71     set(QTKEYCHAIN_DEPENDS ";WITH_DBUS")
  72 else()
  73     set(QTKEYCHAIN_DEPENDS "")
  74 endif()
  75
  76 find_package(Qt5Core 5.2 REQUIRED)
  77 find_package(Qt5Gui REQUIRED)
  78 find_package(Qt5Network REQUIRED)
  79 find_package(Qt5Sql REQUIRED)
  80 find_package(Qt5WebKitWidgets REQUIRED)
  81 find_package(Qt5Widgets REQUIRED)
  82 find_package(Qt5LinguistTools)
  83 find_package(Qt5Svg REQUIRED)
  84 trojita_find_package(Qt5DBus "" "http://qt-project.org" "Qt5 D-Bus support" "Needed for IPC and for some plugins" WITH_DBUS)
  85 trojita_find_package(Qt5Test "" "http://qt-project.org" "Qt5 QTest library" "Needed for automated tests" WITH_TESTS)
  86 if(Qt5LinguistTools_FOUND)
  87     find_package(Qt5LinguistForTrojita)
  88 endif()
  89
  90 trojita_plugin_option(WITH_ABOOKADDRESSBOOK_PLUGIN "Build AbookAddressbook plugin" STATIC)
  91 trojita_plugin_option(WITH_CLEARTEXT_PLUGIN "Build Cleartext password plugin" STATIC)
  92 trojita_plugin_option(WITH_QTKEYCHAIN_PLUGIN "Build Qtkeychain password plugin" "${QTKEYCHAIN_DEPENDS}")
  93
  94 trojita_find_package(Git "" "" "" "")
  95
  96 trojita_find_package(Mimetic "" "http://www.codesink.org/mimetic_mime_library.html" "C++ MIME Library" "Required for client-side MIME parsing" WITH_MIMETIC)
  97 trojita_find_package(KF5Gpgmepp "" "https://quickgit.kde.org/?p=gpgmepp.git" "C++ bindings for gpgme" "Needed for encrypted/signed e-mails" WITH_GPGMEPP)
  98 trojita_option(WITH_CRYPTO_MESSAGES "Enable support for encrypted messages" AUTO "WITH_MIMETIC;WITH_GPGMEPP")
  99
 100 if(WIN32)
 101     trojita_find_package(MakeNSIS "" "http://nsis.sourceforge.net" "Nullsoft Scriptable Install System" "Needed for building Windows installer" WITH_NSIS)
 102 endif()
 103
 104 # Add support for Mingw RC compiler
 105 if(WIN32)
 106     enable_language(RC)
 107     include(CMakeDetermineRCCompiler)
 108
 109     if(MINGW)
 110         set(CMAKE_RC_COMPILER_INIT windres)
 111         set(CMAKE_RC_COMPILE_OBJECT "<CMAKE_RC_COMPILER> <FLAGS> -O coff <DEFINES> -I${CMAKE_CURRENT_BINARY_DIR} -i <SOURCE> -o <OBJECT>")
 112     endif()
 113 endif()
 114
 115 trojita_find_package(Qt5Keychain QUIET "https://github.com/frankosterfeld/qtkeychain" "QtKeychain library (Qt5 version)" "Needed for QtKeychain password plugin" WITH_QTKEYCHAIN_PLUGIN)
 116 if(Qt5Keychain_FOUND OR QtKeychain_FOUND)
 117     message(STATUS "Found QtKeychain library (includes at ${QTKEYCHAIN_INCLUDE_DIRS}, lib at ${QTKEYCHAIN_LIBRARIES})")
 118 else()
 119     message(STATUS "Could not find QtKeychain library")
 120 endif()
 121
 122 if(NOT DEFINED CMAKE_INSTALL_LIBDIR)
 123     set(CMAKE_INSTALL_LIBDIR "lib${LIB_SUFFIX}")
 124 endif()
 125 mark_as_advanced(CMAKE_INSTALL_LIBDIR)
 126
 127 if(NOT CMAKE_INSTALL_PLUGIN_DIR)
 128     set(CMAKE_INSTALL_PLUGIN_DIR "${CMAKE_INSTALL_LIBDIR}/trojita")
 129 endif()
 130 mark_as_advanced(CMAKE_INSTALL_PLUGIN_DIR)
 131
 132 if(NOT PLUGIN_DIR)
 133     if(IS_ABSOLUTE ${CMAKE_INSTALL_PLUGIN_DIR})
 134         set(PLUGIN_DIR "${CMAKE_INSTALL_PLUGIN_DIR}")
 135     else()
 136         set(PLUGIN_DIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_PLUGIN_DIR}")
 137     endif()
 138 endif()
 139 mark_as_advanced(PLUGIN_DIR)
 140
 141 include(GNUInstallDirs)
 142
 143 # When manipulating CXXFLAGS, we put the user's CXXFLAGS *after* that so that they take priority.
 144 if(MSVC)
 145     # See below for some reationale for these optimizations
 146     set(CMAKE_CXX_FLAGS "/O2 ${CMAKE_CXX_FLAGS}")
 147
 148     # We have no information about the warnings and their usefullness. Reports are welcome.
 149     # We might enable warnings on MSVC in future.
 150 else()
 151     # -Werror is not a default for sanity reasons (one cannot know what warnings a future compiler
 152     # might bring along), but it's a default in debug mode. The idea is that developers should care
 153     # about a warning-free build, and that this is easier than messing with yet another configure option.
 154     set(CMAKE_CXX_FLAGS_DEBUG "-Werror ${CMAKE_CXX_FLAGS_DEBUG}")
 155     # Also see CMP0043...
 156
 157     # Optimizations are enabled unconditionally because they make a big difference in the speed of the
 158     # resulting binaries, and that it is better to allow an opt-out from them by adjusting CXXFLAGS through
 159     # an env var at cmake time if needed.
 160     # The reason for not manipulating just CMAKE_CXX_FLAGS_DEBUG is that unrecognized build types ("DebugFull")
 161     # should still benefit from these optimizations. Yup, it would be even better if CMake did a sane thing
 162     # and warned when users set an unrecognized and unused build type, but that just isn't the case.
 163     set(CMAKE_CXX_FLAGS "-O2 ${CMAKE_CXX_FLAGS}")
 164
 165     # Build warnings are useful tools (and Trojita should be warning-free anyway), enable them on all
 166     # configurations. They are warnings, not errors.
 167     set(CMAKE_CXX_FLAGS "-Wall -Wsign-compare ${CMAKE_CXX_FLAGS}")
 168 endif()
 169
 170 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/src)
 171 # The following is required so that the moc_*.cpp and ui_*.h are found
 172 include_directories(${CMAKE_CURRENT_BINARY_DIR})
 173
 174 add_definitions(-DQT_STRICT_ITERATORS)
 175 add_definitions(-DQT_USE_QSTRINGBUILDER)
 176 add_definitions(-DQT_USE_FAST_OPERATOR_PLUS)
 177 add_definitions(-DQT_USE_FAST_CONCATENATION)
 178
 179 if(NOT MSVC)
 180   # We're using C++11's threading features (std::async in particular), and that requires "some threading". With GCC and
 181   # Clang, this is implemented through the -pthread build flag. Without using these bits, linking fails on Fedora 23,
 182   # and this is apparently a slightly different failure than the Kf5::Gpgmepp-pthread one in commit
 183   # 12e41101070f7073caec653185c0504763672ee7.
 184   #
 185   # Apparently, there's been various methods on how to enable this in the most-cmakeish-way throughout the years, with
 186   # cmake-3.1+ supporting some magic linking via the Threads::Threads option on a per-library basis. However, I am not
 187   # really looking into that wonderful fun of mixing -pthread and non-pthread translation units, so let's use a big
 188   # hammer and set it unconditionally on platforms which use it anyway.
 189   #
 190   # And because we also support MinGW and its `windres` compiler, we have to avoid passing -pthread to *that* thing, so,
 191   # well, let's cheat and put it into the CXXFLAGS.
 192   set(CMAKE_CXX_FLAGS "-pthread ${CMAKE_CXX_FLAGS}")
 193 endif()
 194
 195 # Make sure that plugins not export all symbols, only that which are explicitly marked
 196 include(GenerateExportHeader)
 197 add_compiler_export_flags()
 198
 199 set(CMAKE_AUTOMOC True)
 200
 201 trojita_find_package(RagelForTrojita "" "" "" "" WITH_RAGEL)
 202 trojita_find_package(ZLIB "" "" "" "" WITH_ZLIB)
 203
 204 if(WITH_MIMETIC)
 205   set(TROJITA_HAVE_MIMETIC True)
 206 else()
 207   set(TROJITA_HAVE_MIMETIC False)
 208 endif()
 209
 210 if(WITH_GPGMEPP)
 211   set(TROJITA_HAVE_GPGMEPP True)
 212 else()
 213   set(TROJITA_HAVE_GPGMEPP False)
 214 endif()
 215
 216 if(WITH_CRYPTO_MESSAGES)
 217   set(TROJITA_HAVE_CRYPTO_MESSAGES True)
 218 else()
 219   set(TROJITA_HAVE_CRYPTO_MESSAGES False)
 220 endif()
 221
 222 if(WITH_ZLIB)
 223     set(TROJITA_HAVE_ZLIB True)
 224     message(STATUS "Support for COMPRESS=DEFLATE enabled")
 225 else()
 226     set(TROJITA_HAVE_ZLIB False)
 227     message(STATUS "Disabling COMPRESS=DEFLATE, zlib is not available")
 228 endif()
 229
 230 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/configure.cmake.in
 231     ${CMAKE_CURRENT_BINARY_DIR}/configure.cmake.h)
 232 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/configure-plugins.cmake.in
 233     ${CMAKE_CURRENT_BINARY_DIR}/configure-plugins.cmake.h)
 234
 235 feature_summary(FATAL_ON_MISSING_REQUIRED_PACKAGES INCLUDE_QUIET_PACKAGES DESCRIPTION "\n" WHAT ALL)
 236
 237 set(path_Common ${CMAKE_CURRENT_SOURCE_DIR}/src/Common)
 238 set(libCommon_SOURCES
 239     ${path_Common}/Application.cpp
 240     ${path_Common}/ConnectionId.cpp
 241     ${path_Common}/DeleteAfter.cpp
 242     ${path_Common}/FileLogger.cpp
 243     ${path_Common}/MetaTypes.cpp
 244     ${path_Common}/Paths.cpp
 245     ${path_Common}/SettingsNames.cpp
 246 )
 247
 248 set(path_Plugins ${CMAKE_CURRENT_SOURCE_DIR}/src/Plugins)
 249 set(libPlugins_SOURCES
 250     ${path_Plugins}/AddressbookPlugin.cpp
 251     ${path_Plugins}/PasswordPlugin.cpp
 252     ${path_Plugins}/PluginJob.cpp
 253     ${path_Plugins}/PluginManager.cpp
 254 )
 255
 256 set(path_UiUtils ${CMAKE_CURRENT_SOURCE_DIR}/src/UiUtils)
 257 set(libUiUtils_SOURCES
 258     ${path_UiUtils}/Color.cpp
 259     ${path_UiUtils}/Formatting.cpp
 260     ${path_UiUtils}/IconLoader.cpp
 261     ${path_UiUtils}/PasswordWatcher.cpp
 262     ${path_UiUtils}/PlainTextFormatter.cpp
 263 )
 264
 265 set(path_IPC ${CMAKE_CURRENT_SOURCE_DIR}/src/IPC)
 266
 267 if(WITH_DBUS)
 268     set(libIPC_SOURCES
 269         ${path_IPC}/DBusInterface.cpp
 270         ${path_IPC}/MainWindowBridge.cpp
 271     )
 272 else()
 273     set(libIPC_SOURCES
 274         ${path_IPC}/None.cpp
 275     )
 276 endif()
 277
 278 set(path_Composer ${CMAKE_CURRENT_SOURCE_DIR}/src/Composer)
 279 set(libComposer_SOURCES
 280     ${path_Composer}/ComposerAttachments.cpp
 281     ${path_Composer}/Mailto.cpp
 282     ${path_Composer}/MessageComposer.cpp
 283     ${path_Composer}/QuoteText.cpp
 284     ${path_Composer}/Recipients.cpp
 285     ${path_Composer}/ReplaceSignature.cpp
 286     ${path_Composer}/SenderIdentitiesModel.cpp
 287     ${path_Composer}/SubjectMangling.cpp
 288     ${path_Composer}/Submission.cpp
 289 )
 290
 291 set(path_MSA ${CMAKE_CURRENT_SOURCE_DIR}/src/MSA)
 292 set(libMSA_SOURCES
 293     ${path_MSA}/AbstractMSA.cpp
 294     ${path_MSA}/Account.cpp
 295     ${path_MSA}/FakeMSA.cpp
 296     ${path_MSA}/ImapSubmit.cpp
 297     ${path_MSA}/SMTP.cpp
 298     ${path_MSA}/Sendmail.cpp
 299 )
 300
 301 set(path_Streams ${CMAKE_CURRENT_SOURCE_DIR}/src/Streams)
 302 set(libStreams_SOURCES
 303     ${path_Streams}/DeletionWatcher.cpp
 304     ${path_Streams}/FakeSocket.cpp
 305     ${path_Streams}/IODeviceSocket.cpp
 306     ${path_Streams}/Socket.cpp
 307     ${path_Streams}/SocketFactory.cpp
 308 )
 309
 310 set(path_Cryptography ${CMAKE_CURRENT_SOURCE_DIR}/src/Cryptography)
 311 set(libCryptography_SOURCES
 312     ${path_Cryptography}/MessageModel.cpp
 313     ${path_Cryptography}/MessagePart.cpp
 314     ${path_Cryptography}/PartReplacer.cpp
 315 )
 316 if(WITH_MIMETIC)
 317     set(libCryptography_SOURCES
 318         ${libCryptography_SOURCES}
 319         ${path_Cryptography}/LocalMimeParser.cpp
 320         ${path_Cryptography}/MimeticUtils.cpp
 321     )
 322 endif()
 323 if(WITH_CRYPTO_MESSAGES)
 324   if(WITH_GPGMEPP)
 325     set(libCryptography_SOURCES
 326         ${libCryptography_SOURCES}
 327         ${path_Cryptography}/GpgMe++.cpp
 328     )
 329   endif()
 330 endif()
 331
 332 if(WITH_ZLIB)
 333     set(libStreams_SOURCES ${libStreams_SOURCES}
 334         ${path_Streams}/3rdparty/rfc1951.cpp)
 335 endif()
 336
 337 set(path_DesktopGui ${CMAKE_CURRENT_SOURCE_DIR}/src/Gui)
 338 set(libDesktopGui_SOURCES
 339     ${path_DesktopGui}/AddressRowWidget.cpp
 340     ${path_DesktopGui}/AttachmentView.cpp
 341     ${path_DesktopGui}/CompleteMessageWidget.cpp
 342     ${path_DesktopGui}/ComposeWidget.cpp
 343     ${path_DesktopGui}/ComposerAttachmentsList.cpp
 344     ${path_DesktopGui}/ComposerTextEdit.cpp
 345     ${path_DesktopGui}/EmbeddedWebView.cpp
 346     ${path_DesktopGui}/EnvelopeView.cpp
 347     ${path_DesktopGui}/ExternalElementsWidget.cpp
 348     ${path_DesktopGui}/FindBar.cpp
 349     ${path_DesktopGui}/FindBarMixin.cpp
 350     ${path_DesktopGui}/FlowLayout.cpp
 351     ${path_DesktopGui}/FromAddressProxyModel.cpp
 352     ${path_DesktopGui}/LineEdit.cpp
 353     ${path_DesktopGui}/LoadablePartWidget.cpp
 354     ${path_DesktopGui}/MailBoxTreeView.cpp
 355     ${path_DesktopGui}/MessageHeadersWidget.cpp
 356     ${path_DesktopGui}/MessageListWidget.cpp
 357     ${path_DesktopGui}/MessageSourceWidget.cpp
 358     ${path_DesktopGui}/MessageView.cpp
 359     ${path_DesktopGui}/MsgListView.cpp
 360     ${path_DesktopGui}/OnePanelAtTimeWidget.cpp
 361     ${path_DesktopGui}/OneEnvelopeAddress.cpp
 362     ${path_DesktopGui}/OverlayWidget.cpp
 363     ${path_DesktopGui}/PartWalker.cpp
 364     ${path_DesktopGui}/PartWidget.cpp
 365     ${path_DesktopGui}/PartWidgetFactoryVisitor.cpp
 366     ${path_DesktopGui}/PasswordDialog.cpp
 367     ${path_DesktopGui}/ProgressPopUp.cpp
 368     ${path_DesktopGui}/ProtocolLoggerWidget.cpp
 369     ${path_DesktopGui}/ReplaceCharValidator.cpp
 370     ${path_DesktopGui}/SettingsDialog.cpp
 371     ${path_DesktopGui}/SimplePartWidget.cpp
 372     ${path_DesktopGui}/Spinner.cpp
 373     ${path_DesktopGui}/TagListWidget.cpp
 374     ${path_DesktopGui}/TagWidget.cpp
 375     ${path_DesktopGui}/TaskProgressIndicator.cpp
 376     ${path_DesktopGui}/UserAgentWebPage.cpp
 377     ${path_DesktopGui}/Util.cpp
 378     ${path_DesktopGui}/Window.cpp
 379     ${path_DesktopGui}/ShortcutHandler/ShortcutConfigDialog.cpp
 380     ${path_DesktopGui}/ShortcutHandler/ShortcutConfigWidget.cpp
 381     ${path_DesktopGui}/ShortcutHandler/ShortcutHandler.cpp
 382 )
 383 set(libDesktopGui_UI
 384     ${path_DesktopGui}/AboutDialog.ui
 385     ${path_DesktopGui}/ComposeWidget.ui
 386     ${path_DesktopGui}/CreateMailboxDialog.ui
 387     ${path_DesktopGui}/EditIdentity.ui
 388     ${path_DesktopGui}/PasswordDialog.ui
 389     ${path_DesktopGui}/ProgressPopUp.ui
 390     ${path_DesktopGui}/SettingsCachePage.ui
 391     ${path_DesktopGui}/SettingsGeneralPage.ui
 392     ${path_DesktopGui}/SettingsImapPage.ui
 393     ${path_DesktopGui}/SettingsOutgoingPage.ui
 394     ${path_DesktopGui}/ShortcutHandler/ShortcutConfigWidget.ui
 395 )
 396 set(libDesktopGui_RESOURCES
 397     ${CMAKE_CURRENT_SOURCE_DIR}/src/icons.qrc
 398     ${CMAKE_CURRENT_SOURCE_DIR}/src/license.qrc
 399 )
 400
 401 set(libqwwsmtpclient_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/src/qwwsmtpclient/qwwsmtpclient.cpp)
 402
 403 set(libAppVersion_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/src/AppVersion/SetCoreApplication.cpp)
 404
 405 set(path_Imap ${CMAKE_CURRENT_SOURCE_DIR}/src/Imap)
 406 set(libImap_SOURCES
 407     ${path_Imap}/ConnectionState.cpp
 408     ${path_Imap}/Encoders.cpp
 409     ${path_Imap}/Exceptions.cpp
 410     ${path_Imap}/Parser/3rdparty/kcodecs.cpp
 411     ${path_Imap}/Parser/3rdparty/rfccodecs.cpp
 412
 413     ${path_Imap}/Parser/Command.cpp
 414     ${path_Imap}/Parser/Data.cpp
 415     ${path_Imap}/Parser/LowLevelParser.cpp
 416     ${path_Imap}/Parser/MailAddress.cpp
 417     ${path_Imap}/Parser/Message.cpp
 418     ${path_Imap}/Parser/Parser.cpp
 419     ${path_Imap}/Parser/Response.cpp
 420     ${path_Imap}/Parser/Sequence.cpp
 421     ${path_Imap}/Parser/ThreadingNode.cpp
 422
 423     ${path_Imap}/Network/FileDownloadManager.cpp
 424     ${path_Imap}/Network/ForbiddenReply.cpp
 425     ${path_Imap}/Network/MsgPartNetAccessManager.cpp
 426     ${path_Imap}/Network/MsgPartNetworkReply.cpp
 427     ${path_Imap}/Network/QQuickNetworkReplyWrapper.cpp
 428
 429     ${path_Imap}/Model/Cache.cpp
 430     ${path_Imap}/Model/CombinedCache.cpp
 431     ${path_Imap}/Model/DragAndDrop.cpp
 432     ${path_Imap}/Model/DiskPartCache.cpp
 433     ${path_Imap}/Model/DummyNetworkWatcher.cpp
 434     ${path_Imap}/Model/FindInterestingPart.cpp
 435     ${path_Imap}/Model/FlagsOperation.cpp
 436     ${path_Imap}/Model/FullMessageCombiner.cpp
 437     ${path_Imap}/Model/ImapAccess.cpp
 438     ${path_Imap}/Model/MailboxFinder.cpp
 439     ${path_Imap}/Model/MailboxMetadata.cpp
 440     ${path_Imap}/Model/MailboxModel.cpp
 441     ${path_Imap}/Model/MailboxTree.cpp
 442     ${path_Imap}/Model/MemoryCache.cpp
 443     ${path_Imap}/Model/Model.cpp
 444     ${path_Imap}/Model/MsgListModel.cpp
 445     ${path_Imap}/Model/NetworkWatcher.cpp
 446     ${path_Imap}/Model/OneMessageModel.cpp
 447     ${path_Imap}/Model/ParserState.cpp
 448     ${path_Imap}/Model/PrettyMailboxModel.cpp
 449     ${path_Imap}/Model/PrettyMsgListModel.cpp
 450     ${path_Imap}/Model/SpecialFlagNames.cpp
 451     ${path_Imap}/Model/SQLCache.cpp
 452     ${path_Imap}/Model/SubtreeModel.cpp
 453     ${path_Imap}/Model/SystemNetworkWatcher.cpp
 454     ${path_Imap}/Model/TaskFactory.cpp
 455     ${path_Imap}/Model/TaskPresentationModel.cpp
 456     ${path_Imap}/Model/ThreadingMsgListModel.cpp
 457     ${path_Imap}/Model/Utils.cpp
 458     ${path_Imap}/Model/VisibleTasksModel.cpp
 459
 460     # The ModelTest is only needed when debugging manually
 461     #${path_Imap}/Model/ModelTest/modeltest.cpp
 462     # The ModelWatcher is another debugging aid
 463     ${path_Imap}/Model/ModelWatcher.cpp
 464
 465     ${path_Imap}/Model/kdeui-itemviews/kdescendantsproxymodel.cpp
 466
 467     ${path_Imap}/Tasks/AppendTask.cpp
 468     ${path_Imap}/Tasks/CopyMoveMessagesTask.cpp
 469     ${path_Imap}/Tasks/CreateMailboxTask.cpp
 470     ${path_Imap}/Tasks/DeleteMailboxTask.cpp
 471     ${path_Imap}/Tasks/EnableTask.cpp
 472     ${path_Imap}/Tasks/ExpungeMailboxTask.cpp
 473     ${path_Imap}/Tasks/ExpungeMessagesTask.cpp
 474     ${path_Imap}/Tasks/Fake_ListChildMailboxesTask.cpp
 475     ${path_Imap}/Tasks/Fake_OpenConnectionTask.cpp
 476     ${path_Imap}/Tasks/FetchMsgMetadataTask.cpp
 477     ${path_Imap}/Tasks/FetchMsgPartTask.cpp
 478     ${path_Imap}/Tasks/GenUrlAuthTask.cpp
 479     ${path_Imap}/Tasks/GetAnyConnectionTask.cpp
 480     ${path_Imap}/Tasks/IdTask.cpp
 481     ${path_Imap}/Tasks/IdleLauncher.cpp
 482     ${path_Imap}/Tasks/ImapTask.cpp
 483     ${path_Imap}/Tasks/KeepMailboxOpenTask.cpp
 484     ${path_Imap}/Tasks/ListChildMailboxesTask.cpp
 485     ${path_Imap}/Tasks/NoopTask.cpp
 486     ${path_Imap}/Tasks/NumberOfMessagesTask.cpp
 487     ${path_Imap}/Tasks/ObtainSynchronizedMailboxTask.cpp
 488     ${path_Imap}/Tasks/OfflineConnectionTask.cpp
 489     ${path_Imap}/Tasks/OpenConnectionTask.cpp
 490     ${path_Imap}/Tasks/SortTask.cpp
 491     ${path_Imap}/Tasks/SubscribeUnsubscribeTask.cpp
 492     ${path_Imap}/Tasks/ThreadTask.cpp
 493     ${path_Imap}/Tasks/UidSubmitTask.cpp
 494     ${path_Imap}/Tasks/UnSelectTask.cpp
 495     ${path_Imap}/Tasks/UpdateFlagsTask.cpp
 496     ${path_Imap}/Tasks/UpdateFlagsOfAllMessagesTask.cpp
 497 )
 498
 499 if(WITH_RAGEL)
 500     message(STATUS "Using Ragel for the RFC 5322 parser")
 501     ragel_parser(${path_Imap}/Parser/Rfc5322HeaderParser.cpp)
 502     set(libImap_SOURCES ${libImap_SOURCES}
 503         ${CMAKE_CURRENT_BINARY_DIR}/Rfc5322HeaderParser.generated.cpp)
 504 else()
 505     message(STATUS "Using pregenerated RFC 5322 parser")
 506     set(libImap_SOURCES ${libImap_SOURCES}
 507         ${path_Imap}/Parser/Rfc5322HeaderParser.generated.cpp)
 508 endif()
 509
 510 set(trojita_desktop_SOURCES
 511     ${path_DesktopGui}/main.cpp
 512 )
 513
 514 if(WIN32)
 515     list(APPEND trojita_desktop_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/src/trojita_win32.rc)
 516     set_property(SOURCE ${CMAKE_CURRENT_SOURCE_DIR}/src/trojita_win32.rc APPEND PROPERTY OBJECT_DEPENDS
 517         ${CMAKE_CURRENT_SOURCE_DIR}/src/icons/trojita.ico
 518         ${CMAKE_CURRENT_BINARY_DIR}/trojita-git-version.h
 519         ${CMAKE_CURRENT_BINARY_DIR}/trojita-version.h
 520     )
 521 endif()
 522
 523 if(Qt5LinguistForTrojita_FOUND)
 524     file(GLOB_RECURSE lang_PO "${CMAKE_CURRENT_SOURCE_DIR}/po/trojita_common_*.po")
 525     qt5_wrap_po(trojita_QM ${lang_PO})
 526     set(language_summary "")
 527     foreach(po ${lang_PO})
 528         string(REGEX REPLACE "^(.*)/trojita_common_(.*).po" "\\2" lang ${po})
 529         list(APPEND language_summary ${lang})
 530     endforeach()
 531     list(SORT language_summary)
 532     list(LENGTH language_summary num_languages)
 533     if(num_languages)
 534         message(STATUS "Available languages: ${language_summary}")
 535         if(WITH_DESKTOP)
 536             install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/locale/ DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/trojita/locale" REGEX "(x_test)|(.*\\.ts)" EXCLUDE)
 537         endif()
 538     else()
 539         message(STATUS "No .po files found, will not install any languages")
 540     endif()
 541 else()
 542     message(STATUS "Qt Linguist (lupdate/lrelease/lconvert) not found, disabling localization support")
 543 endif()
 544
 545 set(version_files ${CMAKE_CURRENT_BINARY_DIR}/trojita-version.h ${CMAKE_CURRENT_BINARY_DIR}/trojita-git-version.h)
 546 if(WITH_NSIS)
 547     set(version_files ${version_files} ${CMAKE_CURRENT_BINARY_DIR}/trojita-version.nsi)
 548     set(NSIS TRUE)
 549 endif()
 550
 551 add_custom_target(version DEPENDS version_fake_file)
 552 add_custom_command(OUTPUT version_fake_file ${version_files}
 553     COMMAND ${CMAKE_COMMAND} -DGIT_EXECUTABLE=${GIT_EXECUTABLE} -DNSIS=${NSIS} -DHOST_ARCH=${HOST_ARCH} -DSOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/TrojitaVersion.cmake)
 554 set_source_files_properties(${version_files}
 555     PROPERTIES GENERATED TRUE
 556     HEADER_FILE_ONLY TRUE)
 557
 558 add_library(Common STATIC ${libCommon_SOURCES})
 559 set_property(TARGET Common APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 560 add_dependencies(Common version)
 561 qt5_use_modules(Common Core Network)
 562
 563 add_library(AppVersion STATIC ${libAppVersion_SOURCES})
 564 set_property(TARGET AppVersion APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 565 add_dependencies(AppVersion version)
 566 target_link_libraries(AppVersion Common)
 567 qt5_use_modules(AppVersion Core)
 568
 569 if(WITH_SHARED_PLUGINS)
 570     add_library(Plugins SHARED ${libPlugins_SOURCES})
 571     set_property(TARGET Plugins APPEND PROPERTY COMPILE_DEFINITIONS BUILDING_LIBTROJITA_PLUGINS)
 572 else()
 573     add_library(Plugins STATIC ${libPlugins_SOURCES})
 574     set_property(TARGET Plugins APPEND PROPERTY COMPILE_DEFINITIONS QT_STATICPLUGIN)
 575 endif()
 576 set_target_properties(Plugins PROPERTIES OUTPUT_NAME trojita_plugins)
 577 set_property(TARGET Plugins APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 578 qt5_use_modules(Plugins Core)
 579
 580 add_library(UiUtils STATIC ${libUiUtils_SOURCES})
 581 set_property(TARGET UiUtils APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 582 target_link_libraries(UiUtils Plugins Common)
 583 qt5_use_modules(UiUtils Core Gui Network)
 584
 585 add_library(Streams STATIC ${libStreams_SOURCES})
 586 set_property(TARGET Streams APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 587 if(WITH_ZLIB)
 588     set_property(TARGET Streams APPEND PROPERTY INCLUDE_DIRECTORIES ${ZLIB_INCLUDE_DIR})
 589     target_link_libraries(Streams ${ZLIB_LIBRARIES})
 590 endif()
 591 qt5_use_modules(Streams Network)
 592
 593 add_library(IPC STATIC ${libIPC_SOURCES})
 594 set_property(TARGET IPC APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 595 if(WITH_DBUS)
 596     qt5_use_modules(IPC DBus Widgets)
 597 else()
 598     qt5_use_modules(IPC Core)
 599 endif()
 600
 601 add_library(qwwsmtpclient STATIC ${libqwwsmtpclient_SOURCES})
 602 qt5_use_modules(qwwsmtpclient Network)
 603
 604 add_library(MSA STATIC ${libMSA_SOURCES})
 605 set_property(TARGET MSA APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 606 target_link_libraries(MSA Imap Streams qwwsmtpclient)
 607 qt5_use_modules(MSA Network)
 608
 609 add_library(Composer STATIC ${libComposer_SOURCES})
 610 set_property(TARGET Composer APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 611 target_link_libraries(Composer Common MSA Streams UiUtils qwwsmtpclient)
 612 qt5_use_modules(Composer Gui Network)
 613
 614 add_library(Imap STATIC ${libImap_SOURCES})
 615 set_property(TARGET Imap APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 616 target_link_libraries(Imap Common Streams UiUtils)
 617 qt5_use_modules(Imap Gui Network Sql)
 618
 619 add_library(Cryptography STATIC ${libCryptography_SOURCES})
 620 qt5_use_modules(Cryptography Core)
 621 set_property(TARGET Cryptography APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 622 target_link_libraries(Cryptography Common Imap)
 623 if(WITH_MIMETIC)
 624     target_link_libraries(Cryptography ${MIMETIC_LIBRARIES})
 625     set_property(TARGET Cryptography APPEND PROPERTY INCLUDE_DIRECTORIES ${MIMETIC_INCLUDE_DIRS})
 626 endif()
 627 if(WITH_CRYPTO_MESSAGES)
 628   if(WITH_GPGMEPP)
 629     if (WIN32)
 630       target_link_libraries(Cryptography KF5::Gpgmepp KF5::QGpgme)
 631     else()
 632       target_link_libraries(Cryptography KF5::Gpgmepp-pthread KF5::QGpgme)
 633     endif()
 634   endif()
 635 endif()
 636
 637 ## ClearText password plugin
 638 if(WITH_CLEARTEXT_PLUGIN)
 639     trojita_add_plugin(trojita_plugin_ClearTextPasswordPlugin WITH_CLEARTEXT_PLUGIN src/Plugins/ClearTextPassword/ClearTextPassword.cpp)
 640 endif()
 641
 642 ## QtKeyChain plugin
 643 if(WITH_QTKEYCHAIN_PLUGIN)
 644     trojita_add_plugin(trojita_plugin_QtKeychainPasswordPlugin WITH_QTKEYCHAIN_PLUGIN src/Plugins/QtKeyChain/QtKeyChainPassword.cpp)
 645     qt5_use_modules(trojita_plugin_QtKeychainPasswordPlugin Core DBus)
 646     target_link_libraries(trojita_plugin_QtKeychainPasswordPlugin ${QTKEYCHAIN_LIBRARIES})
 647     set_property(TARGET trojita_plugin_QtKeychainPasswordPlugin APPEND PROPERTY INCLUDE_DIRECTORIES ${QTKEYCHAIN_INCLUDE_DIRS})
 648 endif()
 649
 650 ## AbookAddressbook plugin
 651 if(WITH_ABOOKADDRESSBOOK_PLUGIN)
 652     set(path_AbookAddressbook ${CMAKE_CURRENT_SOURCE_DIR}/src/Plugins/AbookAddressbook)
 653     set(libAbookAddressbook_HEADERS
 654         ${path_AbookAddressbook}/AbookAddressbook.h
 655         ${path_AbookAddressbook}/be-contacts.h
 656     )
 657     set(libAbookAddressbook_SOURCES
 658         ${path_AbookAddressbook}/AbookAddressbook.cpp
 659         ${path_AbookAddressbook}/be-contacts.cpp
 660     )
 661     set(libAbookAddressbook_UI
 662         ${path_AbookAddressbook}/be-contacts.ui
 663         ${path_AbookAddressbook}/onecontact.ui
 664     )
 665
 666     qt5_wrap_ui(libAbookAddressbook_UI_OUT ${libAbookAddressbook_UI})
 667
 668     trojita_add_plugin(trojita_plugin_AbookAddressbookPlugin WITH_ABOOKADDRESSBOOK_PLUGIN ${libAbookAddressbook_SOURCES} ${libAbookAddressbook_UI_OUT})
 669     set_property(TARGET trojita_plugin_AbookAddressbookPlugin APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 670
 671     qt5_use_modules(trojita_plugin_AbookAddressbookPlugin Widgets)
 672
 673     set(be_contacts_SOURCES
 674         ${path_AbookAddressbook}/main.cpp
 675     )
 676
 677     add_executable(be.contacts WIN32 ${be_contacts_SOURCES})
 678     set_property(TARGET be.contacts APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 679     target_link_libraries(be.contacts Plugins)
 680     if("${WITH_ABOOKADDRESSBOOK_PLUGIN}" STREQUAL "STATIC")
 681         set_property(TARGET be.contacts APPEND PROPERTY COMPILE_DEFINITIONS QT_STATICPLUGIN)
 682         target_link_libraries(be.contacts trojita_plugin_AbookAddressbookPlugin)
 683     endif()
 684     qt5_use_modules(be.contacts Widgets)
 685 endif()
 686
 687 # Generate file static_plugins.h.in
 688 get_property(STATIC_PLUGINS GLOBAL PROPERTY TROJITA_STATIC_PLUGINS)
 689 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h.in "#include <QtPlugin>\n")
 690 foreach(PLUGIN ${STATIC_PLUGINS})
 691     file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h.in "Q_IMPORT_PLUGIN(${PLUGIN})\n")
 692 endforeach()
 693 execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h.in ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h)
 694
 695 if(WITH_DESKTOP)
 696     qt5_wrap_ui(libDesktopGui_UI_OUT ${libDesktopGui_UI})
 697     qt5_add_resources(libDesktopGui_RESOURCES_OUT ${libDesktopGui_RESOURCES})
 698
 699     add_library(DesktopGui STATIC ${libDesktopGui_SOURCES} ${libDesktopGui_UI_OUT} ${libDesktopGui_RESOURCES_OUT})
 700     set_property(TARGET DesktopGui APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 701     # The following is needed for the LineEdit widget within the .ui files.
 702     # The ${path_DesktopGui} is needed so that the generated ui_*.h file can find the headers of the custom widgets
 703     set_property(TARGET DesktopGui APPEND PROPERTY INCLUDE_DIRECTORIES ${path_DesktopGui})
 704     target_link_libraries(DesktopGui Common UiUtils Composer Cryptography Imap IPC MSA Plugins Streams qwwsmtpclient)
 705
 706     # On Windows build a real Win32 GUI application without console window
 707     # On other platforms WIN32 flag is ignored
 708     add_executable(trojita WIN32 ${trojita_desktop_SOURCES} ${trojita_QM})
 709     set_property(TARGET trojita APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 710     target_link_libraries(trojita AppVersion Common UiUtils DesktopGui ${STATIC_PLUGINS})
 711     qt5_use_modules(DesktopGui Network WebKitWidgets)
 712     qt5_use_modules(trojita Widgets Network)
 713 endif()
 714
 715
 716 if(WITH_SHARED_PLUGINS)
 717     install(TARGETS Plugins DESTINATION ${CMAKE_INSTALL_LIBDIR})
 718 endif()
 719
 720 include(SanitizedDesktopFile)
 721
 722 if(WITH_ABOOKADDRESSBOOK_PLUGIN)
 723     install(TARGETS be.contacts RUNTIME DESTINATION bin)
 724 endif()
 725
 726 if(WITH_DESKTOP)
 727     copy_desktop_file_without_cruft("${CMAKE_CURRENT_SOURCE_DIR}/src/Gui/trojita.desktop" "${CMAKE_CURRENT_BINARY_DIR}/trojita-DesktopGui.desktop")
 728     install(TARGETS trojita RUNTIME DESTINATION bin)
 729     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/trojita-DesktopGui.desktop DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/applications/" RENAME trojita.desktop)
 730     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/Gui/trojita.appdata.xml DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/appdata/")
 731     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/icons/trojita.png DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/32x32/apps/")
 732     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/icons/trojita.svg DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/scalable/apps/")
 733 endif()
 734
 735 if(WITH_NSIS)
 736     include(TrojitaNSIS)
 737 endif()
 738
 739
 740 if(WITH_TESTS)
 741     set(test_LibMailboxSync_SOURCES
 742         tests/Utils/ModelEvents.cpp
 743         tests/Utils/LibMailboxSync.cpp
 744     )
 745     add_library(test_LibMailboxSync STATIC ${test_LibMailboxSync_SOURCES})
 746     qt5_use_modules(test_LibMailboxSync Test Network)
 747     set_property(TARGET test_LibMailboxSync APPEND PROPERTY INCLUDE_DIRECTORIES
 748         ${CMAKE_CURRENT_SOURCE_DIR}/tests
 749         ${CMAKE_CURRENT_SOURCE_DIR}/tests/Utils)
 750     target_link_libraries(test_LibMailboxSync Imap MSA Streams Common Composer)
 751
 752     macro(trojita_test dir fname)
 753         set(test_${fname}_SOURCES tests/${dir}/test_${fname}.cpp)
 754         add_executable(test_${fname} ${test_${fname}_SOURCES})
 755         target_link_libraries(test_${fname} Imap MSA Streams Common Composer Cryptography test_LibMailboxSync)
 756         qt5_use_modules(test_${fname} Network Sql Test Widgets)
 757         set_property(TARGET test_${fname} APPEND PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_SOURCE_DIR}/tests)
 758         if(NOT CMAKE_CROSSCOMPILING)
 759             add_test(test_${fname} test_${fname})
 760         endif()
 761     endmacro()
 762
 763     enable_testing()
 764     trojita_test(Composer Composer_Submission)
 765     trojita_test(Composer Composer_responses)
 766     trojita_test(Composer Html_formatting)
 767     qt5_use_modules(test_Composer_responses WebKitWidgets)
 768     qt5_use_modules(test_Html_formatting WebKitWidgets)
 769     trojita_test(Imap Imap_DisappearingMailboxes)
 770     trojita_test(Imap Imap_Idle)
 771     trojita_test(Imap Imap_LowLevelParser)
 772     trojita_test(Imap Imap_Message)
 773     trojita_test(Imap Imap_Model)
 774     trojita_test(Imap Imap_MsgPartNetAccessManager)
 775     trojita_test(Imap Imap_Parser_parse)
 776     trojita_test(Imap Imap_Parser_write)
 777     trojita_test(Imap Imap_Responses)
 778     trojita_test(Imap Imap_SelectedMailboxUpdates)
 779     trojita_test(Imap Imap_Tasks_CreateMailbox)
 780     trojita_test(Imap Imap_Tasks_DeleteMailbox)
 781     trojita_test(Imap Imap_Tasks_ListChildMailboxes)
 782     trojita_test(Imap Imap_Tasks_ObtainSynchronizedMailbox)
 783     trojita_test(Imap Imap_Tasks_OpenConnection)
 784     trojita_test(Imap Imap_Threading)
 785     trojita_test(Imap Imap_BodyParts)
 786     trojita_test(Imap Imap_Offline)
 787     trojita_test(Imap Imap_CopyAndFlagOperations)
 788     trojita_test(Cryptography Cryptography_MessageModel)
 789
 790     if(WITH_CRYPTO_MESSAGES)
 791       find_program(GPGCONF_BINARY NAMES gpgconf)
 792       if(GPGCONF_BINARY_NOTFOUND)
 793         message(SEND_ERROR "The `gpgconf` binary from GnuPG not found, this is needed for crypto tests.")
 794       endif()
 795
 796       if(NOT UNIX)
 797         message(SEND_ERROR "The Cryptography unit tests really need Unix. Patches welcome.")
 798       endif()
 799
 800       add_library(fake-dev-random SHARED ${CMAKE_CURRENT_SOURCE_DIR}/tests/Utils/fake-dev-random.c)
 801       set_target_properties(fake-dev-random PROPERTIES AUTOMOC off)
 802       target_link_libraries(fake-dev-random dl)
 803
 804       # FIXME: it would be nice to depend on the contents of keys/, but in my testing it produces Makefiles
 805       # which suffer from races (the keygen.sh is run multiple times in parallel within the CI environment).
 806       # I wasn't able to track down the root cause behind this; it affected all cmake versions within the CI
 807       # as of Feb 2016, which is 3.1.something up to 3.3.something.
 808       add_custom_command(OUTPUT crypto_test_data.h
 809         COMMAND bash ${CMAKE_CURRENT_SOURCE_DIR}/tests/Cryptography/keygen.sh ${CMAKE_CURRENT_SOURCE_DIR}
 810         DEPENDS fake-dev-random tests/Cryptography/keygen.sh tests/Cryptography/batch-keygen)
 811       add_custom_target(crypto_test_data DEPENDS crypto_test_data.h)
 812
 813       trojita_test(Cryptography Cryptography_PGP)
 814       add_dependencies(test_Cryptography_PGP crypto_test_data)
 815     endif()
 816
 817     trojita_test(Misc Rfc5322)
 818     trojita_test(Misc RingBuffer)
 819     trojita_test(Misc SenderIdentitiesModel)
 820     trojita_test(Misc SqlCache)
 821     trojita_test(Misc algorithms)
 822     trojita_test(Misc rfccodecs)
 823     trojita_test(Misc prettySize)
 824     trojita_test(Misc Formatting)
 825
 826 endif()
 827
 828 if(WIN32) # Check if we are on Windows
 829     if(MSVC10) # Check if we are using the Visual Studio compiler 2010
 830         # Because of linker errors (see http://stackoverflow.com/questions/5625884/conversion-of-stdwstring-to-qstring-throws-linker-error)
 831         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Zc:wchar_t-")
 832     elseif(MINGW)
 833     else()
 834         message(WARNING "You are using a compiler which we have not tested yet (not MSVC10 or MINGW).")
 835         message(WARNING "Please let us know how well it works.")
 836     endif()
 837 endif()