CMakeLists.txt

   1 project(trojita)
   2 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
   3
   4 if(WIN32)
   5     # Due to QtMain linking
   6     cmake_minimum_required(VERSION 2.8.11)
   7     if(POLICY CMP0020)
   8         cmake_policy(SET CMP0020 NEW)
   9     endif()
  10 elseif(WITH_QT5)
  11     # The Qt5's qt5_use_modules is only available on 2.8.9 or later -- sweet, isn't it?
  12     cmake_minimum_required(VERSION 2.8.9)
  13 else()
  14     cmake_minimum_required(VERSION 2.8.7)
  15 endif()
  16
  17 if(POLICY CMP0054)
  18     # Silence warnings in TrojitaOption.cmake; we are fine with only doing the
  19     # expansion by hand
  20     cmake_policy(SET CMP0054 NEW)
  21 endif()
  22
  23 if(POLICY CMP0043)
  24     # We make use of CMAKE_CXXFLAGS_DEBUG...
  25     cmake_policy(SET CMP0043 OLD)
  26 endif()
  27
  28 # Set a default build type if none was specified. This was shamelessly stolen
  29 # from VTK's cmake setup because these guys produce both CMake and a project that
  30 # manipulates this variable, and the web is full of posts where people say that
  31 # it is apparently evil to just set the build type in a way an earlier version of
  32 # this patch did. Oh, and the location of this check/update matters, apparently.
  33 #
  34 # Yes, this is just plain crazy.
  35 if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  36     message(STATUS "Setting build type to 'RelWithDebInfo' as none was specified.")
  37     set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING "Choose the type of build." FORCE)
  38     # Set the possible values of build type for cmake-gui
  39     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
  40 endif()
  41
  42 # POSITION_INDEPENDENT_CODE is only available on cmake 2.8.9 or later
  43 # Add needed flags for supported compilers which simulate POSITION_INDEPENDENT_CODE property
  44 if(CMAKE_VERSION VERSION_LESS "2.8.9")
  45     if(CMAKE_COMPILER_IS_GNUCXX OR "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  46         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
  47     else()
  48         message(FATAL_ERROR "Needs GNU or Clang C++ compiler or CMake 2.8.9 (or later)")
  49     endif()
  50 else()
  51     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
  52 endif()
  53
  54 include(FindCXXFeatures)
  55 if(NOT CXXFeatures_auto_FOUND)
  56     message(SEND_ERROR "Your compiler doesn't support C++11's auto")
  57 endif()
  58 if(NOT CXXFeatures_static_assert_FOUND)
  59     message(SEND_ERROR "Your compiler doesn't support C++11's static_assert")
  60 endif()
  61 if(NOT CXXFeatures_alignof_FOUND)
  62     if(NOT CMAKE_COMPILER_IS_GNUCXX AND NOT MSVC)
  63         message(SEND_ERROR "Your compiler doesn't support C++11's alignof and it also isn't gcc or MSVC. Either would work.")
  64     endif()
  65 endif()
  66 if(NOT CXXFeatures_nullptr_FOUND)
  67     # Yes, this is extremely fragile; it will break on any code which wants to
  68     # distinguish between an int and nullptr_t. So far, we don't have anything
  69     # like that in Trojita. Let's just pretend that it won't ever happen, and
  70     # if it happens, then let's hope that an "ambiguous overload" would come up.
  71     add_definitions(-Dnullptr=0)
  72     message(WARNING "Your C++ compiler doesn't support C++11's nullptr. Activating a very hackish workaround "
  73             "which can break existing code because nullptr is not plain 0.")
  74 endif()
  75 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${CXX11_COMPILER_FLAGS}")
  76
  77 include(TrojitaOption)
  78
  79 trojita_option(WITH_DESKTOP "Build desktop version" ON)
  80 trojita_option(WITH_HARMATTAN "Build MeeGo Harmattan version" OFF "NOT WITH_DESKTOP")
  81 trojita_option(WITH_QT5 "Build with Qt5 library" OFF)
  82 trojita_option(WITH_DBUS "Build with DBus library" AUTO)
  83 trojita_option(WITH_RAGEL "Build with Ragel library" AUTO)
  84 trojita_option(WITH_ZLIB "Build with zlib library" AUTO)
  85 trojita_option(WITH_SHARED_PLUGINS "Enable shared dynamic plugins" ON)
  86 trojita_option(WITH_KDE "Enable KDE support" AUTO "WITH_DESKTOP;NOT WITH_QT5;WITH_DBUS")
  87 trojita_option(WITH_TESTS "Build tests" ON "NOT WITH_HARMATTAN")
  88
  89 if(WIN32)
  90     trojita_option(WITH_NSIS "Build Windows NSIS installer" AUTO "WITH_DESKTOP")
  91 endif()
  92
  93 if(UNIX AND NOT APPLE)
  94     set(QTKEYCHAIN_DEPENDS ";WITH_DBUS")
  95 else()
  96     set(QTKEYCHAIN_DEPENDS "")
  97 endif()
  98
  99 if(WITH_QT5)
 100     message(STATUS "Building the Qt5 version")
 101     find_package(Qt5Core 5.2 REQUIRED)
 102     find_package(Qt5Gui REQUIRED)
 103     find_package(Qt5Network REQUIRED)
 104     find_package(Qt5Sql REQUIRED)
 105     find_package(Qt5WebKitWidgets REQUIRED)
 106     find_package(Qt5Widgets REQUIRED)
 107     find_package(Qt5LinguistTools)
 108     trojita_find_package(Qt5DBus "" "http://qt-project.org" "Qt5 D-Bus support" "Needed for IPC and for some plugins" WITH_DBUS)
 109     trojita_find_package(Qt5Test "" "http://qt-project.org" "Qt5 QTest library" "Needed for automated tests" WITH_TESTS)
 110     if(Qt5LinguistTools_FOUND)
 111         find_package(Qt5LinguistForTrojita)
 112     endif()
 113 else()
 114     message(STATUS "Building the Qt4 version")
 115     set(QT_USE_QTNETWORK 1)
 116     set(QT_USE_QTSQL 1)
 117     set(QT_USE_QTWEBKIT 1)
 118     if(WITH_DBUS)
 119         set(QT_USE_QTDBUS 1)
 120     endif()
 121     if(WITH_TESTS)
 122         set(QT_USE_QTTEST 1)
 123     endif()
 124     if(WITH_HARMATTAN)
 125         set(QT_USE_QTDECLARATIVE 1)
 126     endif()
 127     trojita_find_package(Qt4 4.6 "http://qt-project.org" "Qt4" "Needed for building" REQUIRED)
 128     include(${QT_USE_FILE})
 129     trojita_check_qt4_module(QTCORE REQUIRED)
 130     trojita_check_qt4_module(QTGUI REQUIRED)
 131     trojita_check_qt4_module(QTNETWORK REQUIRED)
 132     trojita_check_qt4_module(QTSQL REQUIRED)
 133     trojita_check_qt4_module(QTWEBKIT REQUIRED)
 134     trojita_check_qt4_module(QTDBUS WITH_DBUS)
 135     trojita_check_qt4_module(QTTEST WITH_TESTS)
 136     trojita_check_qt4_module(QTDECLARATIVE WITH_HARMATTAN)
 137     trojita_find_package(LinguistForTrojita "" "" "" "")
 138     if(NOT QT_QCONFIG MATCHES "openssl" OR QT_QCONFIG MATCHES "no-openssl")
 139         message(FATAL_ERROR "Your copy of Qt was build without SSL support. Please get openssl and rebuild Qt or a Qt binary with SSL support compiled in")
 140     endif()
 141 endif()
 142
 143 trojita_plugin_option(WITH_ABOOKADDRESSBOOK_PLUGIN "Build AbookAddressbook plugin" "NOT WITH_HARMATTAN" STATIC)
 144 trojita_plugin_option(WITH_CLEARTEXT_PLUGIN "Build Cleartext password plugin" STATIC)
 145 trojita_plugin_option(WITH_QTKEYCHAIN_PLUGIN "Build Qtkeychain password plugin" "NOT WITH_HARMATTAN${QTKEYCHAIN_DEPENDS}")
 146 trojita_plugin_option(WITH_KRESOURCE_PLUGIN "Build KDE Kresource addressbook plugin" "WITH_KDE")
 147 trojita_plugin_option(WITH_AKONADI_PLUGIN "Build KDE Akonadi addressbook plugin" "WITH_KDE")
 148
 149 trojita_find_package(Git "" "" "" "")
 150
 151 if(WIN32)
 152     trojita_find_package(MakeNSIS "" "http://nsis.sourceforge.net" "Nullsoft Scriptable Install System" "Needed for building Windows installer" WITH_NSIS)
 153 endif()
 154
 155 # Add support for Mingw RC compiler
 156 if(WIN32)
 157     enable_language(RC)
 158     include(CMakeDetermineRCCompiler)
 159
 160     if(MINGW)
 161         set(CMAKE_RC_COMPILER_INIT windres)
 162         set(CMAKE_RC_COMPILE_OBJECT "<CMAKE_RC_COMPILER> <FLAGS> -O coff <DEFINES> -i <SOURCE> -o <OBJECT>")
 163     endif()
 164 endif()
 165
 166 if (WITH_QT5)
 167     trojita_find_package(Qt5Keychain QUIET "https://github.com/frankosterfeld/qtkeychain" "QtKeychain library (Qt5 version)" "Needed for QtKeychain password plugin" WITH_QTKEYCHAIN_PLUGIN)
 168 else()
 169     trojita_find_package(QtKeychain QUIET "https://github.com/frankosterfeld/qtkeychain" "QtKeychain library" "Needed for QtKeychain password plugin" WITH_QTKEYCHAIN_PLUGIN)
 170 endif()
 171 if(Qt5Keychain_FOUND OR QtKeychain_FOUND)
 172     message(STATUS "Found QtKeychain library (includes at ${QTKEYCHAIN_INCLUDE_DIRS}, lib at ${QTKEYCHAIN_LIBRARIES})")
 173 else()
 174     message(STATUS "Could not find QtKeychain library")
 175 endif()
 176
 177 if(WITH_KDE)
 178     # Store cmake variables which FindKDE4.cmake changes
 179     set(OLD_LIBRARY_OUTPUT_PATH ${LIBRARY_OUTPUT_PATH})
 180     set(OLD_EXECUTABLE_OUTPUT_PATH ${EXECUTABLE_OUTPUT_PATH})
 181     set(OLD_CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 182     set(OLD_CMAKE_MODULE_LINKER_FLAGS ${CMAKE_MODULE_LINKER_FLAGS})
 183
 184     trojita_find_package(KDE4 "" "http://www.kde.org/" "KDE4 libraries" "Needed for KDE plugins" WITH_KDE)
 185
 186     # KDE4_DATA_DIR is set when KDE4 is found
 187     if(KDE4_DATA_DIR)
 188         include(KDE4Defaults)
 189
 190         # FindKDE4.cmake disables c++ exceptions, need to reenable them for compiling trojita
 191         add_definitions(${KDE4_ENABLE_EXCEPTIONS})
 192
 193         # FindKDE4.cmake changes cmake output paths and some linker flags which cause that some (KDE too) plugins do not compile, change them back to defaults
 194         set(LIBRARY_OUTPUT_PATH ${OLD_LIBRARY_OUTPUT_PATH})
 195         set(EXECUTABLE_OUTPUT_PATH ${OLD_EXECUTABLE_OUTPUT_PATH})
 196         set(CMAKE_SHARED_LINKER_FLAGS ${OLD_CMAKE_SHARED_LINKER_FLAGS})
 197         set(CMAKE_MODULE_LINKER_FLAGS ${OLD_CMAKE_MODULE_LINKER_FLAGS})
 198     endif()
 199 endif()
 200
 201 # Akonadi was added to KdepimLibs 4.5
 202 if(WITH_AKONADI_PLUGIN)
 203     set(KdepimLibsVersion 4.5)
 204 else()
 205     set(KdepimLibsVersion)
 206 endif()
 207 trojita_find_package(KdepimLibs "${KdepimLibsVersion}" "http://www.kde.org/" "KdepimLibs libraries" "Needed for KDE Kresource and Akonadi addressbook plugins" WITH_AKONADI_PLUGIN WITH_KRESOURCE_PLUGIN)
 208
 209 if(NOT DEFINED CMAKE_INSTALL_LIBDIR)
 210     set(CMAKE_INSTALL_LIBDIR "lib${LIB_SUFFIX}")
 211 endif()
 212 mark_as_advanced(CMAKE_INSTALL_LIBDIR)
 213
 214 if(NOT CMAKE_INSTALL_PLUGIN_DIR)
 215     set(CMAKE_INSTALL_PLUGIN_DIR "${CMAKE_INSTALL_LIBDIR}/trojita")
 216 endif()
 217 mark_as_advanced(CMAKE_INSTALL_PLUGIN_DIR)
 218
 219 if(NOT PLUGIN_DIR)
 220     if(IS_ABSOLUTE ${CMAKE_INSTALL_PLUGIN_DIR})
 221         set(PLUGIN_DIR "${CMAKE_INSTALL_PLUGIN_DIR}")
 222     else()
 223         set(PLUGIN_DIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_PLUGIN_DIR}")
 224     endif()
 225 endif()
 226 mark_as_advanced(PLUGIN_DIR)
 227
 228 include(GNUInstallDirs)
 229
 230 # When manipulating CXXFLAGS, we put the user's CXXFLAGS *after* that so that they take priority.
 231 if(MSVC)
 232     # See below for some reationale for these optimizations
 233     set(CMAKE_CXX_FLAGS "/O2 ${CMAKE_CXX_FLAGS}")
 234
 235     # We have no information about the warnings and their usefullness. Reports are welcome.
 236     # We might enable warnings on MSVC in future.
 237 else()
 238     # -Werror is not a default for sanity reasons (one cannot know what warnings a future compiler
 239     # might bring along), but it's a default in debug mode. The idea is that developers should care
 240     # about a warning-free build, and that this is easier than messing with yet another configure option.
 241     set(CMAKE_CXX_FLAGS_DEBUG "-Werror ${CMAKE_CXX_FLAGS_DEBUG}")
 242     # Also see CMP0043...
 243
 244     # Optimizations are enabled unconditionally because they make a big difference in the speed of the
 245     # resulting binaries, and that it is better to allow an opt-out from them by adjusting CXXFLAGS through
 246     # an env var at cmake time if needed.
 247     # The reason for not manipulating just CMAKE_CXX_FLAGS_DEBUG is that unrecognized build types ("DebugFull")
 248     # should still benefit from these optimizations. Yup, it would be even better if CMake did a sane thing
 249     # and warned when users set an unrecognized and unused build type, but that just isn't the case.
 250     set(CMAKE_CXX_FLAGS "-O2 ${CMAKE_CXX_FLAGS}")
 251
 252     # Build warnings are useful tools (and Trojita should be warning-free anyway), enable them on all
 253     # configurations. They are warnings, not errors.
 254     set(CMAKE_CXX_FLAGS "-Wall -Wsign-compare ${CMAKE_CXX_FLAGS}")
 255 endif()
 256
 257 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/src)
 258 # The following is required so that the moc_*.cpp and ui_*.h are found
 259 include_directories(${CMAKE_CURRENT_BINARY_DIR})
 260 add_definitions(-DQT_STRICT_ITERATORS)
 261
 262 # Make sure that plugins not export all symbols, only that which are explicitly marked
 263 include(GenerateExportHeader)
 264 add_compiler_export_flags()
 265
 266 if(NOT WITH_QT5 AND CMAKE_VERSION VERSION_LESS 2.8.10)
 267     set(SUPPORTS_TARGET_INCLUDES 0)
 268     include_directories(
 269         ${QT_MKSPECS_DIR}/default
 270         ${CMAKE_CURRENT_SOURCE_DIR}/src/Gui/
 271         ${CMAKE_CURRENT_SOURCE_DIR}/src/mimetypes-qt4/io/
 272         ${CMAKE_CURRENT_SOURCE_DIR}/src/Harmattan/qmlapplicationviewer
 273         ${CMAKE_CURRENT_SOURCE_DIR}/tests
 274         ${CMAKE_CURRENT_SOURCE_DIR}/tests/test_LibMailboxSync)
 275 else()
 276     set(SUPPORTS_TARGET_INCLUDES 1)
 277 endif()
 278
 279 set(CMAKE_AUTOMOC True)
 280
 281 trojita_find_package(RagelForTrojita "" "" "" "" WITH_RAGEL)
 282
 283 if(WIN32) # Check if we are on Windows
 284     # On win32, qt can statically link to zlib and export their symbols.
 285     # We check if we can find the string " zlib " in the QT_CONFIG list in
 286     # ${QT_MKSPECS_DIR}/qconfig.pri and include on success ${QT_QTCORE_LIBRARY}
 287     # and ${QTDIR}/src/3rdparty/zlib as lib and include folder
 288     if(QT_QTCORE_FOUND)
 289         message(STATUS "We are on Windows with Qt. Checking if zlib is built into Qt")
 290
 291         if(EXISTS "${QT_MKSPECS_DIR}/qconfig.pri")
 292             file(READ ${QT_MKSPECS_DIR}/qconfig.pri _qconfig_FILE_contents_ZLIB_CHECK)
 293             string(REGEX MATCH "QT_CONFIG[^\n]+" QT_CONFIG_ZLIB_CHECK ${_qconfig_FILE_contents_ZLIB_CHECK})
 294
 295             set(ENV_QTDIR $ENV{QTDIR})
 296             if(NOT DEFINED ENV_QTDIR)
 297                 message(STATUS "QTDIR not specified in environment, will not use zlib")
 298             elseif(QT_CONFIG_ZLIB_CHECK)
 299                 if(QT_CONFIG_ZLIB_CHECK MATCHES " zlib ")
 300                     message(STATUS "Found zlib in QT_QCONFIG. zlib seems to be built into Qt")
 301                     set(ZLIB_LIBRARY_RELEASE ${QT_QTCORE_LIBRARY_RELEASE})
 302                     set(ZLIB_LIBRARY_DEBUG ${QT_QTCORE_LIBRARY_DEBUG})
 303                     set(ZLIB_LIBRARY ${QT_QTCORE_LIBRARY})
 304
 305                     string(REGEX REPLACE "\\\\" "/" QTDIR ${ENV_QTDIR})
 306                     set(ZLIB_INCLUDE_DIR "${QTDIR}/src/3rdparty/zlib")
 307
 308                     set(ZLIB_FOUND TRUE)
 309                     set(ZLIB_LIBRARIES ${ZLIB_LIBRARY} )
 310                     mark_as_advanced(ZLIB_LIBRARY ZLIB_INCLUDE_DIR ZLIB_FOUND)
 311                 else(QT_CONFIG_ZLIB_CHECK MATCHES " zlib ")
 312                     message(STATUS "Could not determine if Qt was built with zlib support.")
 313                 endif(QT_CONFIG_ZLIB_CHECK MATCHES " zlib ")
 314
 315             endif()
 316         endif(EXISTS "${QT_MKSPECS_DIR}/qconfig.pri")
 317     endif(QT_QTCORE_FOUND)
 318 endif()
 319
 320 if(NOT ZLIB_FOUND)
 321     trojita_find_package(ZLIB "" "" "" "" WITH_ZLIB)
 322 endif()
 323
 324 if(WITH_ZLIB)
 325     set(TROJITA_HAVE_ZLIB True)
 326     message(STATUS "Support for COMPRESS=DEFLATE enabled")
 327 else()
 328     set(TROJITA_HAVE_ZLIB False)
 329     message(STATUS "Disabling COMPRESS=DEFLATE, zlib is not available")
 330 endif()
 331
 332 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/configure.cmake.in
 333     ${CMAKE_CURRENT_BINARY_DIR}/configure.cmake.h)
 334
 335 feature_summary(FATAL_ON_MISSING_REQUIRED_PACKAGES INCLUDE_QUIET_PACKAGES DESCRIPTION "\n" WHAT ALL)
 336
 337 set(path_Common ${CMAKE_CURRENT_SOURCE_DIR}/src/Common)
 338 set(libCommon_SOURCES
 339     ${path_Common}/Application.cpp
 340     ${path_Common}/ConnectionId.cpp
 341     ${path_Common}/DeleteAfter.cpp
 342     ${path_Common}/FileLogger.cpp
 343     ${path_Common}/MetaTypes.cpp
 344     ${path_Common}/Paths.cpp
 345     ${path_Common}/SettingsNames.cpp
 346 )
 347
 348 set(path_Plugins ${CMAKE_CURRENT_SOURCE_DIR}/src/Plugins)
 349 set(libPlugins_SOURCES
 350     ${path_Plugins}/AddressbookPlugin.cpp
 351     ${path_Plugins}/PasswordPlugin.cpp
 352     ${path_Plugins}/PluginJob.cpp
 353     ${path_Plugins}/PluginManager.cpp
 354 )
 355
 356 set(path_UiUtils ${CMAKE_CURRENT_SOURCE_DIR}/src/UiUtils)
 357 set(libUiUtils_SOURCES
 358     ${path_UiUtils}/Color.cpp
 359     ${path_UiUtils}/Formatting.cpp
 360     ${path_UiUtils}/IconLoader.cpp
 361     ${path_UiUtils}/PasswordWatcher.cpp
 362     ${path_UiUtils}/PlainTextFormatter.cpp
 363 )
 364
 365 set(path_IPC ${CMAKE_CURRENT_SOURCE_DIR}/src/IPC)
 366
 367 if(WITH_DBUS)
 368     set(libIPC_SOURCES
 369         ${path_IPC}/DBusInterface.cpp
 370         ${path_IPC}/MainWindowBridge.cpp
 371     )
 372 else()
 373     set(libIPC_SOURCES
 374         ${path_IPC}/None.cpp
 375     )
 376 endif()
 377
 378 set(path_Composer ${CMAKE_CURRENT_SOURCE_DIR}/src/Composer)
 379 set(libComposer_SOURCES
 380     ${path_Composer}/ComposerAttachments.cpp
 381     ${path_Composer}/Mailto.cpp
 382     ${path_Composer}/MessageComposer.cpp
 383     ${path_Composer}/QuoteText.cpp
 384     ${path_Composer}/Recipients.cpp
 385     ${path_Composer}/ReplaceSignature.cpp
 386     ${path_Composer}/SenderIdentitiesModel.cpp
 387     ${path_Composer}/SubjectMangling.cpp
 388     ${path_Composer}/Submission.cpp
 389 )
 390
 391 set(path_MSA ${CMAKE_CURRENT_SOURCE_DIR}/src/MSA)
 392 set(libMSA_SOURCES
 393     ${path_MSA}/AbstractMSA.cpp
 394     ${path_MSA}/Account.cpp
 395     ${path_MSA}/FakeMSA.cpp
 396     ${path_MSA}/ImapSubmit.cpp
 397     ${path_MSA}/SMTP.cpp
 398     ${path_MSA}/Sendmail.cpp
 399 )
 400
 401 set(path_Streams ${CMAKE_CURRENT_SOURCE_DIR}/src/Streams)
 402 set(libStreams_SOURCES
 403     ${path_Streams}/DeletionWatcher.cpp
 404     ${path_Streams}/FakeSocket.cpp
 405     ${path_Streams}/IODeviceSocket.cpp
 406     ${path_Streams}/Socket.cpp
 407     ${path_Streams}/SocketFactory.cpp
 408 )
 409
 410 if(WITH_ZLIB)
 411     set(libStreams_SOURCES ${libStreams_SOURCES}
 412         ${path_Streams}/3rdparty/rfc1951.cpp)
 413     include_directories(${ZLIB_INCLUDE_DIR})
 414 endif()
 415
 416 if(NOT WITH_QT5)
 417     set(path_mimetypesqt4 ${CMAKE_CURRENT_SOURCE_DIR}/src/mimetypes-qt4)
 418     set(libMimetypesQt4_SOURCES
 419         ${path_mimetypesqt4}/io/qstandardpaths.cpp
 420         ${path_mimetypesqt4}/mimetypes/qmimedatabase.cpp
 421         ${path_mimetypesqt4}/mimetypes/qmimeglobpattern.cpp
 422         ${path_mimetypesqt4}/mimetypes/qmimemagicrule.cpp
 423         ${path_mimetypesqt4}/mimetypes/qmimemagicrulematcher.cpp
 424         ${path_mimetypesqt4}/mimetypes/qmimetype.cpp
 425         ${path_mimetypesqt4}/mimetypes/qmimetypeparser.cpp
 426         ${path_mimetypesqt4}/mimetypes/qmimeprovider.cpp
 427     )
 428     if(WIN32)
 429         set(libMimetypesQt4_SOURCES ${libMimetypesQt4_SOURCES}
 430             ${path_mimetypesqt4}/io/qstandardpaths_win.cpp)
 431     elseif(APPLE)
 432         set(libMimetypesQt4_SOURCES ${libMimetypesQt4_SOURCES}
 433             ${path_mimetypesqt4}/io/qstandardpaths_mac.cpp)
 434     elseif (OS2)
 435         set(libMimetypesQt4_SOURCES ${libMimetypesQt4_SOURCES}
 436             ${path_mimetypesqt4}/io/qstandardpaths_os2.cpp)
 437     elseif (UNIX)
 438         set(libMimetypesQt4_SOURCES ${libMimetypesQt4_SOURCES}
 439             ${path_mimetypesqt4}/io/qstandardpaths_unix.cpp)
 440     else()
 441         message(FATAL_ERROR "Unsupported platform -- mimetypes-Qt4 support only Unix, MacOSX, Windows and OS/2")
 442     endif()
 443 endif()
 444
 445 set(path_DesktopGui ${CMAKE_CURRENT_SOURCE_DIR}/src/Gui)
 446 set(libDesktopGui_SOURCES
 447     ${path_DesktopGui}/AddressRowWidget.cpp
 448     ${path_DesktopGui}/AttachmentView.cpp
 449     ${path_DesktopGui}/CompleteMessageWidget.cpp
 450     ${path_DesktopGui}/ComposeWidget.cpp
 451     ${path_DesktopGui}/ComposerAttachmentsList.cpp
 452     ${path_DesktopGui}/ComposerTextEdit.cpp
 453     ${path_DesktopGui}/EmbeddedWebView.cpp
 454     ${path_DesktopGui}/EnvelopeView.cpp
 455     ${path_DesktopGui}/ExternalElementsWidget.cpp
 456     ${path_DesktopGui}/FindBar.cpp
 457     ${path_DesktopGui}/FlowLayout.cpp
 458     ${path_DesktopGui}/FromAddressProxyModel.cpp
 459     ${path_DesktopGui}/LineEdit.cpp
 460     ${path_DesktopGui}/LoadablePartWidget.cpp
 461     ${path_DesktopGui}/MailBoxTreeView.cpp
 462     ${path_DesktopGui}/MessageListWidget.cpp
 463     ${path_DesktopGui}/MessageSourceWidget.cpp
 464     ${path_DesktopGui}/MessageView.cpp
 465     ${path_DesktopGui}/MsgListView.cpp
 466     ${path_DesktopGui}/OnePanelAtTimeWidget.cpp
 467     ${path_DesktopGui}/OneEnvelopeAddress.cpp
 468     ${path_DesktopGui}/OverlayWidget.cpp
 469     ${path_DesktopGui}/PartWalker.cpp
 470     ${path_DesktopGui}/PartWidget.cpp
 471     ${path_DesktopGui}/PartWidgetFactoryVisitor.cpp
 472     ${path_DesktopGui}/PasswordDialog.cpp
 473     ${path_DesktopGui}/ProgressPopUp.cpp
 474     ${path_DesktopGui}/ProtocolLoggerWidget.cpp
 475     ${path_DesktopGui}/ReplaceCharValidator.cpp
 476     ${path_DesktopGui}/SettingsDialog.cpp
 477     ${path_DesktopGui}/SimplePartWidget.cpp
 478     ${path_DesktopGui}/Spinner.cpp
 479     ${path_DesktopGui}/TagListWidget.cpp
 480     ${path_DesktopGui}/TagWidget.cpp
 481     ${path_DesktopGui}/TaskProgressIndicator.cpp
 482     ${path_DesktopGui}/UserAgentWebPage.cpp
 483     ${path_DesktopGui}/Util.cpp
 484     ${path_DesktopGui}/Window.cpp
 485     ${path_DesktopGui}/ShortcutHandler/ShortcutConfigDialog.cpp
 486     ${path_DesktopGui}/ShortcutHandler/ShortcutConfigWidget.cpp
 487     ${path_DesktopGui}/ShortcutHandler/ShortcutHandler.cpp
 488 )
 489 set(libDesktopGui_UI
 490     ${path_DesktopGui}/AboutDialog.ui
 491     ${path_DesktopGui}/ComposeWidget.ui
 492     ${path_DesktopGui}/CreateMailboxDialog.ui
 493     ${path_DesktopGui}/EditIdentity.ui
 494     ${path_DesktopGui}/PasswordDialog.ui
 495     ${path_DesktopGui}/ProgressPopUp.ui
 496     ${path_DesktopGui}/SettingsCachePage.ui
 497     ${path_DesktopGui}/SettingsGeneralPage.ui
 498     ${path_DesktopGui}/SettingsImapPage.ui
 499     ${path_DesktopGui}/SettingsOutgoingPage.ui
 500     ${path_DesktopGui}/ShortcutHandler/ShortcutConfigWidget.ui
 501 )
 502 set(libDesktopGui_RESOURCES
 503     ${CMAKE_CURRENT_SOURCE_DIR}/src/icons.qrc
 504     ${CMAKE_CURRENT_SOURCE_DIR}/src/license.qrc
 505 )
 506
 507 set(libqwwsmtpclient_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/src/qwwsmtpclient/qwwsmtpclient.cpp)
 508
 509 set(libAppVersion_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/src/AppVersion/SetCoreApplication.cpp)
 510
 511 set(path_Imap ${CMAKE_CURRENT_SOURCE_DIR}/src/Imap)
 512 set(libImap_SOURCES
 513     ${path_Imap}/ConnectionState.cpp
 514     ${path_Imap}/Encoders.cpp
 515     ${path_Imap}/Exceptions.cpp
 516     ${path_Imap}/Parser/3rdparty/kcodecs.cpp
 517     ${path_Imap}/Parser/3rdparty/rfccodecs.cpp
 518
 519     ${path_Imap}/Parser/Command.cpp
 520     ${path_Imap}/Parser/Data.cpp
 521     ${path_Imap}/Parser/LowLevelParser.cpp
 522     ${path_Imap}/Parser/MailAddress.cpp
 523     ${path_Imap}/Parser/Message.cpp
 524     ${path_Imap}/Parser/Parser.cpp
 525     ${path_Imap}/Parser/Response.cpp
 526     ${path_Imap}/Parser/Sequence.cpp
 527     ${path_Imap}/Parser/ThreadingNode.cpp
 528
 529     ${path_Imap}/Network/FileDownloadManager.cpp
 530     ${path_Imap}/Network/ForbiddenReply.cpp
 531     ${path_Imap}/Network/MsgPartNetAccessManager.cpp
 532     ${path_Imap}/Network/MsgPartNetworkReply.cpp
 533     ${path_Imap}/Network/QQuickNetworkReplyWrapper.cpp
 534
 535     ${path_Imap}/Model/Cache.cpp
 536     ${path_Imap}/Model/CombinedCache.cpp
 537     ${path_Imap}/Model/DragAndDrop.cpp
 538     ${path_Imap}/Model/DiskPartCache.cpp
 539     ${path_Imap}/Model/DummyNetworkWatcher.cpp
 540     ${path_Imap}/Model/FindInterestingPart.cpp
 541     ${path_Imap}/Model/FlagsOperation.cpp
 542     ${path_Imap}/Model/FullMessageCombiner.cpp
 543     ${path_Imap}/Model/ImapAccess.cpp
 544     ${path_Imap}/Model/MailboxFinder.cpp
 545     ${path_Imap}/Model/MailboxMetadata.cpp
 546     ${path_Imap}/Model/MailboxModel.cpp
 547     ${path_Imap}/Model/MailboxTree.cpp
 548     ${path_Imap}/Model/MemoryCache.cpp
 549     ${path_Imap}/Model/Model.cpp
 550     ${path_Imap}/Model/MsgListModel.cpp
 551     ${path_Imap}/Model/NetworkWatcher.cpp
 552     ${path_Imap}/Model/OneMessageModel.cpp
 553     ${path_Imap}/Model/ParserState.cpp
 554     ${path_Imap}/Model/PrettyMailboxModel.cpp
 555     ${path_Imap}/Model/PrettyMsgListModel.cpp
 556     ${path_Imap}/Model/SpecialFlagNames.cpp
 557     ${path_Imap}/Model/SQLCache.cpp
 558     ${path_Imap}/Model/SubtreeModel.cpp
 559     ${path_Imap}/Model/SystemNetworkWatcher.cpp
 560     ${path_Imap}/Model/TaskFactory.cpp
 561     ${path_Imap}/Model/TaskPresentationModel.cpp
 562     ${path_Imap}/Model/ThreadingMsgListModel.cpp
 563     ${path_Imap}/Model/Utils.cpp
 564     ${path_Imap}/Model/VisibleTasksModel.cpp
 565
 566     # The ModelTest is only needed when debugging manually
 567     #${path_Imap}/Model/ModelTest/modeltest.cpp
 568     # The ModelWatcher is another debugging aid
 569     ${path_Imap}/Model/ModelWatcher.cpp
 570
 571     ${path_Imap}/Model/kdeui-itemviews/kdescendantsproxymodel.cpp
 572
 573     ${path_Imap}/Tasks/AppendTask.cpp
 574     ${path_Imap}/Tasks/CopyMoveMessagesTask.cpp
 575     ${path_Imap}/Tasks/CreateMailboxTask.cpp
 576     ${path_Imap}/Tasks/DeleteMailboxTask.cpp
 577     ${path_Imap}/Tasks/EnableTask.cpp
 578     ${path_Imap}/Tasks/ExpungeMailboxTask.cpp
 579     ${path_Imap}/Tasks/ExpungeMessagesTask.cpp
 580     ${path_Imap}/Tasks/Fake_ListChildMailboxesTask.cpp
 581     ${path_Imap}/Tasks/Fake_OpenConnectionTask.cpp
 582     ${path_Imap}/Tasks/FetchMsgMetadataTask.cpp
 583     ${path_Imap}/Tasks/FetchMsgPartTask.cpp
 584     ${path_Imap}/Tasks/GenUrlAuthTask.cpp
 585     ${path_Imap}/Tasks/GetAnyConnectionTask.cpp
 586     ${path_Imap}/Tasks/IdTask.cpp
 587     ${path_Imap}/Tasks/IdleLauncher.cpp
 588     ${path_Imap}/Tasks/ImapTask.cpp
 589     ${path_Imap}/Tasks/KeepMailboxOpenTask.cpp
 590     ${path_Imap}/Tasks/ListChildMailboxesTask.cpp
 591     ${path_Imap}/Tasks/NoopTask.cpp
 592     ${path_Imap}/Tasks/NumberOfMessagesTask.cpp
 593     ${path_Imap}/Tasks/ObtainSynchronizedMailboxTask.cpp
 594     ${path_Imap}/Tasks/OfflineConnectionTask.cpp
 595     ${path_Imap}/Tasks/OpenConnectionTask.cpp
 596     ${path_Imap}/Tasks/SortTask.cpp
 597     ${path_Imap}/Tasks/SubscribeUnsubscribeTask.cpp
 598     ${path_Imap}/Tasks/ThreadTask.cpp
 599     ${path_Imap}/Tasks/UidSubmitTask.cpp
 600     ${path_Imap}/Tasks/UnSelectTask.cpp
 601     ${path_Imap}/Tasks/UpdateFlagsTask.cpp
 602     ${path_Imap}/Tasks/UpdateFlagsOfAllMessagesTask.cpp
 603 )
 604
 605 if(WITH_RAGEL)
 606     message(STATUS "Using Ragel for the RFC 5322 parser")
 607     ragel_parser(${path_Imap}/Parser/Rfc5322HeaderParser.cpp)
 608     set(libImap_SOURCES ${libImap_SOURCES}
 609         ${CMAKE_CURRENT_BINARY_DIR}/Rfc5322HeaderParser.generated.cpp)
 610 else()
 611     message(STATUS "Using pregenerated RFC 5322 parser")
 612     set(libImap_SOURCES ${libImap_SOURCES}
 613         ${path_Imap}/Parser/Rfc5322HeaderParser.generated.cpp)
 614 endif()
 615
 616 set(trojita_desktop_SOURCES
 617     ${path_DesktopGui}/main.cpp
 618 )
 619
 620 if(WIN32)
 621     list(APPEND trojita_desktop_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/src/trojita_win32.rc)
 622     set_property(SOURCE ${CMAKE_CURRENT_SOURCE_DIR}/src/trojita_win32.rc APPEND PROPERTY OBJECT_DEPENDS
 623         ${CMAKE_CURRENT_SOURCE_DIR}/src/icons/trojita.ico
 624         ${CMAKE_CURRENT_BINARY_DIR}/trojita-git-version.h
 625         ${CMAKE_CURRENT_BINARY_DIR}/trojita-version.h
 626     )
 627 endif()
 628
 629 set(libQNAMWebView_SOURCES
 630     ${CMAKE_CURRENT_SOURCE_DIR}/src/QmlSupport/QNAMWebView/plugin.cpp
 631     ${CMAKE_CURRENT_SOURCE_DIR}/src/QmlSupport/QNAMWebView/qdeclarativewebview.cpp
 632 )
 633
 634 set(trojitaHarmattan_SOURCES
 635     ${CMAKE_CURRENT_SOURCE_DIR}/src/Harmattan/main.cpp
 636     ${CMAKE_CURRENT_SOURCE_DIR}/src/Harmattan/qmlapplicationviewer/qmlapplicationviewer.cpp
 637 )
 638
 639 if(LinguistForTrojita_FOUND OR Qt5LinguistForTrojita_FOUND)
 640     file(GLOB_RECURSE lang_PO "${CMAKE_CURRENT_SOURCE_DIR}/po/trojita_common_*.po")
 641     if(WITH_QT5)
 642         qt5_wrap_po(trojita_QM ${lang_PO})
 643     else()
 644         qt4_wrap_po(trojita_QM ${lang_PO})
 645     endif()
 646     set(language_summary "")
 647     foreach(po ${lang_PO})
 648         string(REGEX REPLACE "^(.*)/trojita_common_(.*).po" "\\2" lang ${po})
 649         list(APPEND language_summary ${lang})
 650     endforeach()
 651     list(SORT language_summary)
 652     list(LENGTH language_summary num_languages)
 653     if(num_languages)
 654         message(STATUS "Available languages: ${language_summary}")
 655         if(WITH_DESKTOP)
 656             install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/locale/ DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/trojita/locale" REGEX "(x_test)|(.*\\.ts)" EXCLUDE)
 657         endif()
 658     else()
 659         message(STATUS "No .po files found, will not install any languages")
 660     endif()
 661 else()
 662     message(STATUS "Qt Linguist (lupdate/lrelease/lconvert) not found, disabling localization support")
 663 endif()
 664
 665 set(version_files ${CMAKE_CURRENT_BINARY_DIR}/trojita-version.h ${CMAKE_CURRENT_BINARY_DIR}/trojita-git-version.h)
 666 if(WITH_NSIS)
 667     set(version_files ${version_files} ${CMAKE_CURRENT_BINARY_DIR}/trojita-version.nsi)
 668     set(NSIS TRUE)
 669 endif()
 670
 671 add_custom_target(version DEPENDS version_fake_file)
 672 add_custom_command(OUTPUT version_fake_file ${version_files}
 673     COMMAND ${CMAKE_COMMAND} -DGIT_EXECUTABLE=${GIT_EXECUTABLE} -DNSIS=${NSIS} -DHOST_ARCH=${HOST_ARCH} -DSOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/TrojitaVersion.cmake)
 674 set_source_files_properties(${version_files}
 675     PROPERTIES GENERATED TRUE
 676     HEADER_FILE_ONLY TRUE)
 677
 678 add_library(Common STATIC ${libCommon_SOURCES})
 679 set_property(TARGET Common APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 680 add_dependencies(Common version)
 681 target_link_libraries(Common ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY})
 682
 683 add_library(AppVersion STATIC ${libAppVersion_SOURCES})
 684 set_property(TARGET AppVersion APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 685 add_dependencies(AppVersion version)
 686 target_link_libraries(AppVersion Common ${QT_QTCORE_LIBRARY})
 687
 688 if(WITH_SHARED_PLUGINS)
 689     add_library(Plugins SHARED ${libPlugins_SOURCES})
 690 else()
 691     add_library(Plugins STATIC ${libPlugins_SOURCES})
 692     set_property(TARGET Plugins APPEND PROPERTY COMPILE_DEFINITIONS QT_STATICPLUGIN)
 693 endif()
 694 set_target_properties(Plugins PROPERTIES OUTPUT_NAME trojita_plugins)
 695 set_property(TARGET Plugins APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 696 if(WITH_QT5)
 697     qt5_use_modules(Plugins Core)
 698 else()
 699     target_link_libraries(Plugins ${QT_QTCORE_LIBRARY})
 700 endif()
 701
 702 add_library(UiUtils STATIC ${libUiUtils_SOURCES})
 703 set_property(TARGET UiUtils APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 704 target_link_libraries(UiUtils Plugins Common ${QT_QTCORE_LIBRARY})
 705
 706 add_library(Streams STATIC ${libStreams_SOURCES})
 707 set_property(TARGET Streams APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 708 target_link_libraries(Streams ${QT_QTNETWORK_LIBRARY} ${QT_QTCORE_LIBRARY})
 709 if(WITH_ZLIB)
 710     target_link_libraries(Streams ${ZLIB_LIBRARIES})
 711 endif()
 712
 713 add_library(IPC STATIC ${libIPC_SOURCES})
 714 set_property(TARGET IPC APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 715 if(WITH_DBUS)
 716     target_link_libraries(IPC ${QT_QTDBUS_LIBRARY})
 717     if(WITH_QT5)
 718         qt5_use_modules(IPC DBus Widgets)
 719     endif()
 720 else()
 721     if(WITH_QT5)
 722         qt5_use_modules(IPC Core)
 723     endif()
 724 endif()
 725
 726 add_library(qwwsmtpclient STATIC ${libqwwsmtpclient_SOURCES})
 727 target_link_libraries(qwwsmtpclient ${QT_QTNETWORK_LIBRARY} ${QT_QTCORE_LIBRARY})
 728
 729 add_library(MSA STATIC ${libMSA_SOURCES})
 730 set_property(TARGET MSA APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 731 target_link_libraries(MSA Imap Streams qwwsmtpclient ${QT_QTCORE_LIBRARY})
 732
 733 add_library(Composer STATIC ${libComposer_SOURCES})
 734 set_property(TARGET Composer APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 735 target_link_libraries(Composer Common MSA Streams UiUtils qwwsmtpclient ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY})
 736 if(NOT WITH_QT5)
 737     target_link_libraries(Composer MimetypesQt4)
 738 endif()
 739
 740 add_library(Imap STATIC ${libImap_SOURCES})
 741 set_property(TARGET Imap APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 742 target_link_libraries(Imap Common Streams UiUtils ${QT_QTNETWORK_LIBRARY} ${QT_QTSQL_LIBRARY} ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY})
 743 if(WITH_ZLIB)
 744     target_link_libraries(Imap ${ZLIB_LIBRARIES})
 745 endif()
 746
 747 if(NOT WITH_QT5)
 748     add_library(MimetypesQt4 STATIC ${libMimetypesQt4_SOURCES})
 749     if(SUPPORTS_TARGET_INCLUDES)
 750         set_property(TARGET MimetypesQt4 APPEND PROPERTY INCLUDE_DIRECTORIES
 751             ${QT_MKSPECS_DIR}/default ${path_mimetypesqt4}/io/)
 752     endif()
 753     target_link_libraries(MimetypesQt4 ${QT_QTCORE_LIBRARY})
 754     if(APPLE)
 755         find_library(CARBON_LIBRARY Carbon REQUIRED)
 756         target_link_libraries(MimetypesQt4 ${CARBON_LIBRARY})
 757     endif()
 758 endif()
 759
 760 ## ClearText password plugin
 761 if(WITH_CLEARTEXT_PLUGIN)
 762     trojita_add_plugin(trojita_plugin_ClearTextPasswordPlugin WITH_CLEARTEXT_PLUGIN src/Plugins/ClearTextPassword/ClearTextPassword.cpp)
 763 endif()
 764
 765 ## QtKeyChain plugin
 766 if(WITH_QTKEYCHAIN_PLUGIN)
 767     trojita_add_plugin(trojita_plugin_QtKeychainPasswordPlugin WITH_QTKEYCHAIN_PLUGIN src/Plugins/QtKeyChain/QtKeyChainPassword.cpp)
 768     if(WITH_QT5)
 769         qt5_use_modules(trojita_plugin_QtKeychainPasswordPlugin Core DBus)
 770     else()
 771         target_link_libraries(trojita_plugin_QtKeychainPasswordPlugin ${QT_QTCORE_LIBRARY} ${QT_QTDBUS_LIBRARY})
 772     endif()
 773     target_link_libraries(trojita_plugin_QtKeychainPasswordPlugin ${QTKEYCHAIN_LIBRARIES})
 774     if(SUPPORTS_TARGET_INCLUDES)
 775         set_property(TARGET trojita_plugin_QtKeychainPasswordPlugin APPEND PROPERTY INCLUDE_DIRECTORIES ${QTKEYCHAIN_INCLUDE_DIRS})
 776     else()
 777         include_directories(${QTKEYCHAIN_INCLUDE_DIRS})
 778     endif()
 779 endif()
 780
 781 ## AbookAddressbook plugin
 782 if(WITH_ABOOKADDRESSBOOK_PLUGIN)
 783     set(path_AbookAddressbook ${CMAKE_CURRENT_SOURCE_DIR}/src/Plugins/AbookAddressbook)
 784     set(libAbookAddressbook_HEADERS
 785         ${path_AbookAddressbook}/AbookAddressbook.h
 786         ${path_AbookAddressbook}/be-contacts.h
 787     )
 788     set(libAbookAddressbook_SOURCES
 789         ${path_AbookAddressbook}/AbookAddressbook.cpp
 790         ${path_AbookAddressbook}/be-contacts.cpp
 791     )
 792     set(libAbookAddressbook_UI
 793         ${path_AbookAddressbook}/be-contacts.ui
 794         ${path_AbookAddressbook}/onecontact.ui
 795     )
 796
 797     if(WITH_QT5)
 798         qt5_wrap_ui(libAbookAddressbook_UI_OUT ${libAbookAddressbook_UI})
 799     else()
 800         qt4_wrap_ui(libAbookAddressbook_UI_OUT ${libAbookAddressbook_UI})
 801     endif()
 802
 803     trojita_add_plugin(trojita_plugin_AbookAddressbookPlugin WITH_ABOOKADDRESSBOOK_PLUGIN ${libAbookAddressbook_SOURCES} ${libAbookAddressbook_UI_OUT})
 804     set_property(TARGET trojita_plugin_AbookAddressbookPlugin APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 805     target_link_libraries(trojita_plugin_AbookAddressbookPlugin ${QT_QTCORE_LIBRARY} ${QT_QTGUI_LIBRARY})
 806
 807     if(WITH_QT5)
 808         qt5_use_modules(trojita_plugin_AbookAddressbookPlugin Widgets)
 809     endif()
 810
 811     set(be_contacts_SOURCES
 812         ${path_AbookAddressbook}/main.cpp
 813     )
 814
 815     add_executable(be.contacts WIN32 ${be_contacts_SOURCES})
 816     set_property(TARGET be.contacts APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 817     target_link_libraries(be.contacts Plugins ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY})
 818     if("${WITH_ABOOKADDRESSBOOK_PLUGIN}" STREQUAL "STATIC")
 819         set_property(TARGET be.contacts APPEND PROPERTY COMPILE_DEFINITIONS QT_STATICPLUGIN)
 820         target_link_libraries(be.contacts trojita_plugin_AbookAddressbookPlugin)
 821     endif()
 822     if(WITH_QT5)
 823         qt5_use_modules(be.contacts Widgets)
 824     endif()
 825 endif()
 826
 827 ## KDE plugins
 828 if(WITH_KDE)
 829     include_directories(
 830         ${KDE4_INCLUDES}
 831         ${KDEPIMLIBS_INCLUDE_DIRS}
 832     )
 833 endif()
 834
 835 ## KResource addressbook plugin
 836 if(WITH_KRESOURCE_PLUGIN)
 837     trojita_add_plugin(trojita_plugin_kresourceaddressbook WITH_KRESOURCE_PLUGIN src/Plugins/KDE/KResourceAddressbook.cpp)
 838     target_link_libraries(trojita_plugin_kresourceaddressbook ${QT_QTCORE_LIBRARY} ${QT_QTDBUS_LIBRARY} ${KDEPIMLIBS_KABC_LIBS})
 839 endif()
 840
 841 ## Akonadi addressbook plugin
 842 if(WITH_AKONADI_PLUGIN)
 843     trojita_add_plugin(trojita_plugin_akonadiaddressbook WITH_AKONADI_PLUGIN src/Plugins/KDE/AkonadiAddressbook.cpp)
 844     target_link_libraries(trojita_plugin_akonadiaddressbook ${QT_QTCORE_LIBRARY} ${QT_QTDBUS_LIBRARY} ${KDEPIMLIBS_AKONADI_CONTACT_LIBS})
 845 endif()
 846
 847 # Generate file static_plugins.h.in
 848 get_property(STATIC_PLUGINS GLOBAL PROPERTY TROJITA_STATIC_PLUGINS)
 849 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h.in "#include <QtPlugin>\n")
 850 foreach(PLUGIN ${STATIC_PLUGINS})
 851     file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h.in "Q_IMPORT_PLUGIN(${PLUGIN})\n")
 852 endforeach()
 853 execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h.in ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h)
 854
 855 if(WITH_DESKTOP)
 856     if(WITH_QT5)
 857         qt5_wrap_ui(libDesktopGui_UI_OUT ${libDesktopGui_UI})
 858         qt5_add_resources(libDesktopGui_RESOURCES_OUT ${libDesktopGui_RESOURCES})
 859     else()
 860         qt4_wrap_ui(libDesktopGui_UI_OUT ${libDesktopGui_UI})
 861         qt4_add_resources(libDesktopGui_RESOURCES_OUT ${libDesktopGui_RESOURCES})
 862     endif()
 863
 864     add_library(DesktopGui STATIC ${libDesktopGui_SOURCES} ${libDesktopGui_UI_OUT} ${libDesktopGui_RESOURCES_OUT})
 865     set_property(TARGET DesktopGui APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 866     # The following is needed for the LineEdit widget within the .ui files.
 867     # The ${path_DesktopGui} is needed so that the generated ui_*.h file can find the headers of the custom widgets
 868     if(SUPPORTS_TARGET_INCLUDES)
 869         set_property(TARGET DesktopGui APPEND PROPERTY INCLUDE_DIRECTORIES ${path_DesktopGui})
 870     endif()
 871     target_link_libraries(DesktopGui Common UiUtils Composer Imap IPC MSA Plugins Streams qwwsmtpclient ${QT_QTWEBKIT_LIBRARY} ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY})
 872
 873     # On Windows build a real Win32 GUI application without console window
 874     # On other platforms WIN32 flag is ignored
 875     add_executable(trojita WIN32 ${trojita_desktop_SOURCES} ${trojita_QM})
 876     set_property(TARGET trojita APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 877     target_link_libraries(trojita AppVersion Common UiUtils DesktopGui ${STATIC_PLUGINS} ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY})
 878     if(NOT WITH_QT5)
 879         target_link_libraries(trojita MimetypesQt4)
 880     endif()
 881     if(WITH_ZLIB)
 882         target_link_libraries(trojita ${ZLIB_LIBRARIES})
 883     endif()
 884 elseif(WITH_HARMATTAN)
 885     add_library(trojitaqnamwebviewplugin SHARED ${libQNAMWebView_SOURCES})
 886     add_executable(trojita-tp ${trojitaHarmattan_SOURCES})
 887     set_property(TARGET trojita-tp APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 888     if(SUPPORTS_TARGET_INCLUDES)
 889         set_property(TARGET trojita-tp APPEND PROPERTY INCLUDE_DIRECTORIES
 890             ${QT_MKSPECS_DIR}/default ${CMAKE_CURRENT_SOURCE_DIR}/src/Harmattan/qmlapplicationviewer)
 891     endif()
 892     target_link_libraries(trojita-tp AppVersion Imap MSA Streams qwwsmtpclient Common Composer MimetypesQt4
 893         ${QT_QTSQL_LIBRARY} ${QT_QTNETWORK_LIBRARY} ${QT_QTWEBKIT_LIBRARY} ${QT_QTDECLARATIVE_LIBRARY})
 894 endif()
 895
 896 if(WITH_QT5)
 897     qt5_use_modules(AppVersion Core)
 898     qt5_use_modules(Common Core Network)
 899     qt5_use_modules(UiUtils Core Gui Network)
 900     qt5_use_modules(Streams Network)
 901     qt5_use_modules(qwwsmtpclient Network)
 902     qt5_use_modules(MSA Network)
 903     qt5_use_modules(Composer Gui Network)
 904     qt5_use_modules(Imap Gui Network Sql)
 905     if (WITH_DESKTOP)
 906         qt5_use_modules(DesktopGui Network WebKitWidgets)
 907         qt5_use_modules(trojita Widgets Network)
 908     endif()
 909 endif()
 910
 911
 912 if(WITH_SHARED_PLUGINS)
 913     install(TARGETS Plugins DESTINATION ${CMAKE_INSTALL_LIBDIR})
 914 endif()
 915
 916 include(SanitizedDesktopFile)
 917
 918 if(WITH_ABOOKADDRESSBOOK_PLUGIN)
 919     install(TARGETS be.contacts RUNTIME DESTINATION bin)
 920 endif()
 921
 922 if(WITH_DESKTOP)
 923     copy_desktop_file_without_cruft("${CMAKE_CURRENT_SOURCE_DIR}/src/Gui/trojita.desktop" "${CMAKE_CURRENT_BINARY_DIR}/trojita-DesktopGui.desktop")
 924     install(TARGETS trojita RUNTIME DESTINATION bin)
 925     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/trojita-DesktopGui.desktop DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/applications/" RENAME trojita.desktop)
 926     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/Gui/trojita.appdata.xml DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/appdata/")
 927     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/icons/trojita.png DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/32x32/apps/")
 928     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/icons/trojita.svg DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/scalable/apps/")
 929 endif()
 930
 931 if(WITH_HARMATTAN)
 932     set(trojita_harmattan_path ${CMAKE_CURRENT_SOURCE_DIR}/src/Harmattan)
 933     install(TARGETS trojita-tp RUNTIME DESTINATION bin)
 934     install(TARGETS trojitaqnamwebviewplugin LIBRARY DESTINATION bin/net/flaska/QNAMWebView)
 935     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/QmlSupport/QNAMWebView/qmldir DESTINATION bin/net/flaska/QNAMWebView)
 936     install(DIRECTORY ${trojita_harmattan_path}/qml DESTINATION ${CMAKE_INSTALL_PREFIX})
 937     install(FILES ${trojita_harmattan_path}/trojita-tp.desktop DESTINATION share/applications)
 938     install(FILES ${trojita_harmattan_path}/trojita-tp80.png DESTINATION share/icons/hicolor/80x80/apps)
 939 endif()
 940
 941 if(WITH_NSIS)
 942     include(TrojitaNSIS)
 943 endif()
 944
 945
 946 if(WITH_TESTS)
 947     set(test_LibMailboxSync_SOURCES
 948         tests/Utils/ModelEvents.cpp
 949         tests/Utils/LibMailboxSync.cpp
 950     )
 951     add_library(test_LibMailboxSync STATIC ${test_LibMailboxSync_SOURCES})
 952     if(WITH_QT5)
 953         qt5_use_modules(test_LibMailboxSync Test Network)
 954     endif()
 955     if(SUPPORTS_TARGET_INCLUDES)
 956         set_property(TARGET test_LibMailboxSync APPEND PROPERTY INCLUDE_DIRECTORIES
 957             ${CMAKE_CURRENT_SOURCE_DIR}/tests
 958             ${CMAKE_CURRENT_SOURCE_DIR}/tests/Utils)
 959     endif()
 960     target_link_libraries(test_LibMailboxSync Imap MSA Streams Common Composer ${QT_QTTEST_LIBRARY} ${QT_QTCORE_LIBRARY})
 961
 962     macro(trojita_test dir fname)
 963         set(test_${fname}_SOURCES tests/${dir}/test_${fname}.cpp)
 964         add_executable(test_${fname} ${test_${fname}_SOURCES})
 965         target_link_libraries(test_${fname} Imap MSA Streams Common Composer test_LibMailboxSync)
 966         if(WITH_QT5)
 967             qt5_use_modules(test_${fname} Network Sql Test Widgets)
 968         else()
 969             target_link_libraries(test_${fname} ${QT_QTSQL_LIBRARY} ${QT_QTTEST_LIBRARY} ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY} ${QT_QTNETWORK_LIBRARY})
 970         endif()
 971         if(WITH_ZLIB)
 972             target_link_libraries(test_${fname} ${ZLIB_LIBRARIES})
 973         endif()
 974         if(SUPPORTS_TARGET_INCLUDES)
 975             set_property(TARGET test_${fname} APPEND PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_SOURCE_DIR}/tests)
 976         endif()
 977         if(NOT CMAKE_CROSSCOMPILING)
 978             add_test(test_${fname} test_${fname})
 979         endif()
 980     endmacro()
 981
 982     enable_testing()
 983     trojita_test(Composer Composer_Submission)
 984     trojita_test(Composer Composer_responses)
 985     trojita_test(Composer Html_formatting)
 986     if(WITH_QT5)
 987         qt5_use_modules(test_Composer_responses WebKitWidgets)
 988         qt5_use_modules(test_Html_formatting WebKitWidgets)
 989     else()
 990         target_link_libraries(test_Html_formatting ${QT_QTWEBKIT_LIBRARY})
 991     endif()
 992     trojita_test(Imap Imap_DisappearingMailboxes)
 993     trojita_test(Imap Imap_Idle)
 994     trojita_test(Imap Imap_LowLevelParser)
 995     trojita_test(Imap Imap_Message)
 996     trojita_test(Imap Imap_Model)
 997     trojita_test(Imap Imap_MsgPartNetAccessManager)
 998     trojita_test(Imap Imap_Parser_parse)
 999     trojita_test(Imap Imap_Responses)
1000     trojita_test(Imap Imap_SelectedMailboxUpdates)
1001     trojita_test(Imap Imap_Tasks_CreateMailbox)
1002     trojita_test(Imap Imap_Tasks_DeleteMailbox)
1003     trojita_test(Imap Imap_Tasks_ListChildMailboxes)
1004     trojita_test(Imap Imap_Tasks_ObtainSynchronizedMailbox)
1005     trojita_test(Imap Imap_Tasks_OpenConnection)
1006     trojita_test(Imap Imap_Threading)
1007     trojita_test(Imap Imap_BodyParts)
1008     trojita_test(Imap Imap_Offline)
1009     trojita_test(Imap Imap_CopyAndFlagOperations)
1010     trojita_test(Misc Rfc5322)
1011     trojita_test(Misc RingBuffer)
1012     trojita_test(Misc SenderIdentitiesModel)
1013     trojita_test(Misc SqlCache)
1014     trojita_test(Misc algorithms)
1015     trojita_test(Misc rfccodecs)
1016
1017 endif()
1018
1019 if(WIN32) # Check if we are on Windows
1020     if(MSVC10) # Check if we are using the Visual Studio compiler 2010
1021         # Because of linker errors (see http://stackoverflow.com/questions/5625884/conversion-of-stdwstring-to-qstring-throws-linker-error)
1022         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Zc:wchar_t-")
1023     elseif(MINGW)
1024     else()
1025         message(WARNING "You are using a compiler which we have not tested yet (not MSVC10 or MINGW).")
1026         message(WARNING "Please let us know how well it works.")
1027     endif()
1028 endif()