CMakeLists.txt

   1 if(WITH_UBUNTU)
   2     set(WITH_DESKTOP OFF)
   3     set(WITH_QT5 ON)
   4 endif()
   5
   6 if(UBUNTU_CLICK_MODE)
   7     find_program(DPKG_ARCHITECTURE_EXECUTABLE dpkg-architecture)
   8     if(DPKG_ARCHITECTURE_EXECUTABLE)
   9         execute_process(
  10             COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_MULTIARCH
  11             OUTPUT_VARIABLE ARCH_TRIPLET
  12             OUTPUT_STRIP_TRAILING_WHITESPACE
  13             # Get the build host arch and test it is armhf, since
  14             # CMAKE_LIBRARY_ARCHITECTURE and CMAKE_SYSTEM_PROCESSOR don't contain
  15             # any value inside the click chroot?? query the DEB_HOST_ARCH
  16             COMMAND ${DPKG_ARCHITECTURE_EXECUTABLE} -qDEB_HOST_ARCH
  17             OUTPUT_VARIABLE HOST_ARCH
  18             OUTPUT_STRIP_TRAILING_WHITESPACE
  19         )
  20     else()
  21         message(FATAL_ERROR "Ubuntu click mode requires dpkg-architecture be installed, stopping build")
  22     endif()
  23 endif()
  24
  25 if(WITH_QT5)
  26     # The Qt5's qt5_use_modules is only available on 2.8.9 or later -- sweet, isn't it?
  27     cmake_minimum_required(VERSION 2.8.9)
  28 else()
  29     cmake_minimum_required(VERSION 2.8.7)
  30 endif()
  31 project(trojita)
  32 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  33
  34 # POSITION_INDEPENDENT_CODE is only available on cmake 2.8.9 or later
  35 # Add needed flags for supported compilers which simulate POSITION_INDEPENDENT_CODE property
  36 if(CMAKE_VERSION VERSION_LESS "2.8.9")
  37     if(CMAKE_COMPILER_IS_GNUCXX OR "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  38         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
  39     else()
  40         message(FATAL_ERROR "Needs GNU or Clang C++ compiler or CMake 2.8.9 (or later)")
  41     endif()
  42 else()
  43     set(CMAKE_POSITION_INDEPENDENT_CODE ON)
  44 endif()
  45
  46 include(FindCXXFeatures)
  47 if(NOT CXXFeatures_auto_FOUND)
  48     message(SEND_ERROR "Your compiler doesn't support C++11's auto")
  49 endif()
  50 if(NOT CXXFeatures_static_assert_FOUND)
  51     message(SEND_ERROR "Your compiler doesn't support C++11's static_assert")
  52 endif()
  53 if(NOT CXXFeatures_alignof_FOUND)
  54     if(NOT CMAKE_COMPILER_IS_GNUCXX AND NOT MSVC)
  55         message(SEND_ERROR "Your compiler doesn't support C++11's alignof and it also isn't gcc or MSVC. Either would work.")
  56     endif()
  57 endif()
  58 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${CXX11_COMPILER_FLAGS}")
  59
  60 include(TrojitaOption)
  61
  62 trojita_option(WITH_DESKTOP "Build desktop version" ON)
  63 trojita_option(WITH_HARMATTAN "Build MeeGo Harmattan version" OFF "NOT WITH_DESKTOP")
  64 trojita_option(WITH_UBUNTU "Build for the Ubuntu SDK" OFF "NOT WITH_DESKTOP;WITH_QT5")
  65 trojita_option(UBUNTU_CLICK_MODE "Installs Ubuntu UI to a contained location" OFF "WITH_UBUNTU")
  66 trojita_option(WITH_QT5 "Build with Qt5 library" OFF)
  67 trojita_option(WITH_DBUS "Build with DBus library" AUTO)
  68 trojita_option(WITH_RAGEL "Build with Ragel library" AUTO)
  69 trojita_option(WITH_ZLIB "Build with zlib library" AUTO)
  70 trojita_option(WITH_SHARED_PLUGINS "Enable shared dynamic plugins" ON "NOT UBUNTU_CLICK_MODE")
  71 trojita_option(WITH_TESTS "Build tests" ON "NOT WITH_HARMATTAN")
  72 trojita_option(DEV_FATAL_WARNINGS "Turn build warnings into errors (developers only)" OFF)
  73
  74 if(WIN32)
  75     trojita_option(WITH_NSIS "Build Windows NSIS installer" AUTO)
  76 endif()
  77
  78 if(UNIX AND NOT APPLE)
  79     set(QTKEYCHAIN_DEPENDS ";WITH_DBUS")
  80 else()
  81     set(QTKEYCHAIN_DEPENDS "")
  82 endif()
  83
  84 trojita_plugin_option(WITH_CLEARTEXT_PLUGIN "Build Cleartext password plugin" STATIC)
  85 trojita_plugin_option(WITH_QTKEYCHAIN_PLUGIN "Build Qtkeychain password plugin" "NOT WITH_HARMATTAN;NOT WITH_UBUNTU${QTKEYCHAIN_DEPENDS}")
  86
  87 if(WITH_QT5)
  88     message(STATUS "Building the Qt5 version")
  89     find_package(Qt5Core 5.2 REQUIRED)
  90     find_package(Qt5Gui REQUIRED)
  91     find_package(Qt5Network REQUIRED)
  92     find_package(Qt5Sql REQUIRED)
  93     find_package(Qt5WebKitWidgets REQUIRED)
  94     find_package(Qt5Widgets REQUIRED)
  95     find_package(Qt5LinguistTools)
  96     if(WITH_DBUS)
  97         find_package(Qt5DBus REQUIRED)
  98     endif()
  99     if(WITH_TESTS)
 100         find_package(Qt5Test REQUIRED)
 101     endif()
 102     if(Qt5LinguistTools_FOUND)
 103         find_package(Qt5LinguistForTrojita)
 104     endif()
 105     if(WITH_UBUNTU)
 106         message(STATUS "Building the Ubuntu Components GUI")
 107         find_package(Qt5Quick REQUIRED)
 108         find_package(Qt5Qml REQUIRED)
 109     endif()
 110 else()
 111     message(STATUS "Building the Qt4 version")
 112     set(QT_USE_QTNETWORK 1)
 113     set(QT_USE_QTSQL 1)
 114     set(QT_USE_QTWEBKIT 1)
 115     if(WITH_DBUS)
 116         set(QT_USE_QTDBUS 1)
 117     endif()
 118     if(WITH_TESTS)
 119         set(QT_USE_QTTEST 1)
 120     endif()
 121     if(WITH_HARMATTAN)
 122         set(QT_USE_QTDECLARATIVE 1)
 123     endif()
 124     trojita_find_package(Qt4 4.6 "http://qt-project.org" "Qt4" "Needed for building" REQUIRED)
 125     include(${QT_USE_FILE})
 126     trojita_check_qt4_module(QTCORE REQUIRED)
 127     trojita_check_qt4_module(QTGUI REQUIRED)
 128     trojita_check_qt4_module(QTNETWORK REQUIRED)
 129     trojita_check_qt4_module(QTSQL REQUIRED)
 130     trojita_check_qt4_module(QTWEBKIT REQUIRED)
 131     trojita_check_qt4_module(QTDBUS WITH_DBUS)
 132     trojita_check_qt4_module(QTTEST WITH_TESTS)
 133     trojita_check_qt4_module(QTDECLARATIVE WITH_HARMATTAN)
 134     trojita_find_package(LinguistForTrojita "" "" "" "")
 135     if(NOT QT_QCONFIG MATCHES "openssl" OR QT_QCONFIG MATCHES "no-openssl")
 136         message(FATAL_ERROR "Your copy of Qt was build without SSL support. Please get openssl and rebuild Qt or a Qt binary with SSL support compiled in")
 137     endif()
 138 endif()
 139
 140 trojita_find_package(Git "" "" "" "")
 141
 142 if(WIN32)
 143     trojita_find_package(MakeNSIS "" "http://nsis.sourceforge.net" "Nullsoft Scriptable Install System" "Needed for building Windows installer" WITH_NSIS)
 144 endif()
 145
 146 # Add support for Mingw RC compiler
 147 if(WIN32)
 148     enable_language(RC)
 149     include(CMakeDetermineRCCompiler)
 150
 151     if(MINGW)
 152         set(CMAKE_RC_COMPILER_INIT windres)
 153         set(CMAKE_RC_COMPILE_OBJECT "<CMAKE_RC_COMPILER> <FLAGS> -O coff <DEFINES> -i <SOURCE> -o <OBJECT>")
 154     endif()
 155 endif()
 156
 157 if (WITH_QT5)
 158     trojita_find_package(Qt5Keychain "" "https://github.com/frankosterfeld/qtkeychain" "QtKeychain library (Qt5 version)" "Needed for QtKeychain password plugin" WITH_QTKEYCHAIN_PLUGIN)
 159 else()
 160     trojita_find_package(QtKeychain "" "https://github.com/frankosterfeld/qtkeychain" "QtKeychain library" "Needed for QtKeychain password plugin" WITH_QTKEYCHAIN_PLUGIN)
 161 endif()
 162 if(Qt5Keychain_FOUND OR QtKeychain_FOUND)
 163     message(STATUS "Found QtKeychain library (includes at ${QTKEYCHAIN_INCLUDE_DIRS}, lib at ${QTKEYCHAIN_LIBRARIES})")
 164 endif()
 165
 166 if(NOT DEFINED CMAKE_INSTALL_LIBDIR)
 167     set(CMAKE_INSTALL_LIBDIR "lib${LIB_SUFFIX}")
 168 endif()
 169 mark_as_advanced(CMAKE_INSTALL_LIBDIR)
 170
 171 if(NOT CMAKE_INSTALL_PLUGIN_DIR)
 172     set(CMAKE_INSTALL_PLUGIN_DIR "${CMAKE_INSTALL_LIBDIR}/trojita")
 173 endif()
 174 mark_as_advanced(CMAKE_INSTALL_PLUGIN_DIR)
 175
 176 if(NOT PLUGIN_DIR)
 177     if(IS_ABSOLUTE ${CMAKE_INSTALL_PLUGIN_DIR})
 178         set(PLUGIN_DIR "${CMAKE_INSTALL_PLUGIN_DIR}")
 179     else()
 180         set(PLUGIN_DIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_PLUGIN_DIR}")
 181     endif()
 182 endif()
 183 mark_as_advanced(PLUGIN_DIR)
 184
 185 if(NOT WIN32 AND NOT MSVC)
 186     # Check if we are NOT on Windows and don't use MSVC since -g is not supported by VC
 187     # and Wall makes the build very noisy.
 188     # At first, enable optimizations. In my testing, these do *not* make debugging any harder than no optimization and
 189     # they (of course) optimize away stuff like QByteArray::operator[] etc.
 190     # We put the user's CXXFLAGS *after* that so that they take priority.
 191     set(CMAKE_CXX_FLAGS "-O2 -g ${CMAKE_CXX_FLAGS}")
 192     # Now enable build warnings; these are useful tools (and Trojita should be warning-free anyway). We do not set
 193     # -Werror for sanity reasons, though (one cannot know what warnings a future compiler might bring along).
 194     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wsign-compare")
 195 endif(NOT WIN32 AND NOT MSVC)
 196 if(DEV_FATAL_WARNINGS)
 197     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Werror")
 198 endif()
 199
 200 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/src)
 201 # The following is required so that the moc_*.cpp and ui_*.h are found
 202 include_directories(${CMAKE_CURRENT_BINARY_DIR})
 203 add_definitions(-DQT_STRICT_ITERATORS)
 204
 205 # Make sure that plugins not export all symbols, only that which are explicitly marked
 206 include(GenerateExportHeader)
 207 add_compiler_export_flags()
 208
 209 if(NOT WITH_QT5 AND CMAKE_VERSION VERSION_LESS 2.8.10)
 210     set(SUPPORTS_TARGET_INCLUDES 0)
 211     include_directories(
 212         ${QT_MKSPECS_DIR}/default
 213         ${CMAKE_CURRENT_SOURCE_DIR}/src/Gui/
 214         ${CMAKE_CURRENT_SOURCE_DIR}/src/mimetypes-qt4/io/
 215         ${CMAKE_CURRENT_SOURCE_DIR}/src/Harmattan/qmlapplicationviewer
 216         ${CMAKE_CURRENT_SOURCE_DIR}/tests
 217         ${CMAKE_CURRENT_SOURCE_DIR}/tests/test_LibMailboxSync)
 218 else()
 219     set(SUPPORTS_TARGET_INCLUDES 1)
 220 endif()
 221
 222 set(CMAKE_AUTOMOC True)
 223
 224 trojita_find_package(RagelForTrojita "" "" "" "" WITH_RAGEL)
 225
 226 if(WIN32) # Check if we are on Windows
 227     # On win32, qt can statically link to zlib and export their symbols.
 228     # We check if we can find the string " zlib " in the QT_CONFIG list in
 229     # ${QT_MKSPECS_DIR}/qconfig.pri and include on success ${QT_QTCORE_LIBRARY}
 230     # and ${QTDIR}/src/3rdparty/zlib as lib and include folder
 231     if(QT_QTCORE_FOUND)
 232         message(STATUS "We are on Windows with Qt. Checking if zlib is built into Qt")
 233
 234         if(EXISTS "${QT_MKSPECS_DIR}/qconfig.pri")
 235             file(READ ${QT_MKSPECS_DIR}/qconfig.pri _qconfig_FILE_contents_ZLIB_CHECK)
 236             string(REGEX MATCH "QT_CONFIG[^\n]+" QT_CONFIG_ZLIB_CHECK ${_qconfig_FILE_contents_ZLIB_CHECK})
 237
 238             set(ENV_QTDIR $ENV{QTDIR})
 239             if(NOT DEFINED ENV_QTDIR)
 240                 message(STATUS "QTDIR not specified in environment, will not use zlib")
 241             elseif(QT_CONFIG_ZLIB_CHECK)
 242                 if(QT_CONFIG_ZLIB_CHECK MATCHES " zlib ")
 243                     message(STATUS "Found zlib in QT_QCONFIG. zlib seems to be built into Qt")
 244                     set(ZLIB_LIBRARY_RELEASE ${QT_QTCORE_LIBRARY_RELEASE})
 245                     set(ZLIB_LIBRARY_DEBUG ${QT_QTCORE_LIBRARY_DEBUG})
 246                     set(ZLIB_LIBRARY ${QT_QTCORE_LIBRARY})
 247
 248                     string(REGEX REPLACE "\\\\" "/" QTDIR ${ENV_QTDIR})
 249                     set(ZLIB_INCLUDE_DIR "${QTDIR}/src/3rdparty/zlib")
 250
 251                     set(ZLIB_FOUND TRUE)
 252                     set(ZLIB_LIBRARIES ${ZLIB_LIBRARY} )
 253                     mark_as_advanced(ZLIB_LIBRARY ZLIB_INCLUDE_DIR ZLIB_FOUND)
 254                 else(QT_CONFIG_ZLIB_CHECK MATCHES " zlib ")
 255                     message(STATUS "Could not determine if Qt was built with zlib support.")
 256                 endif(QT_CONFIG_ZLIB_CHECK MATCHES " zlib ")
 257
 258             endif()
 259         endif(EXISTS "${QT_MKSPECS_DIR}/qconfig.pri")
 260     endif(QT_QTCORE_FOUND)
 261 endif()
 262
 263 if(NOT ZLIB_FOUND)
 264     trojita_find_package(ZLIB "" "" "" "" WITH_ZLIB)
 265 endif()
 266
 267 if(WITH_ZLIB)
 268     set(TROJITA_HAVE_ZLIB True)
 269     message(STATUS "Support for COMPRESS=DEFLATE enabled")
 270 else()
 271     set(TROJITA_HAVE_ZLIB False)
 272     message(STATUS "Disabling COMPRESS=DEFLATE, zlib is not available")
 273 endif()
 274
 275 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/configure.cmake.in
 276     ${CMAKE_CURRENT_BINARY_DIR}/configure.cmake.h)
 277
 278 feature_summary(FATAL_ON_MISSING_REQUIRED_PACKAGES DESCRIPTION "\n" WHAT ALL)
 279
 280 set(path_Common ${CMAKE_CURRENT_SOURCE_DIR}/src/Common)
 281 set(libCommon_SOURCES
 282     ${path_Common}/Application.cpp
 283     ${path_Common}/ConnectionId.cpp
 284     ${path_Common}/DeleteAfter.cpp
 285     ${path_Common}/FileLogger.cpp
 286     ${path_Common}/MetaTypes.cpp
 287     ${path_Common}/Paths.cpp
 288     ${path_Common}/SettingsNames.cpp
 289 )
 290
 291 set(path_Plugins ${CMAKE_CURRENT_SOURCE_DIR}/src/Plugins)
 292 set(libPlugins_SOURCES
 293     ${path_Plugins}/AddressbookPlugin.cpp
 294     ${path_Plugins}/PasswordPlugin.cpp
 295     ${path_Plugins}/PluginJob.cpp
 296     ${path_Plugins}/PluginManager.cpp
 297 )
 298
 299 set(path_UiUtils ${CMAKE_CURRENT_SOURCE_DIR}/src/UiUtils)
 300 set(libUiUtils_SOURCES
 301     ${path_UiUtils}/Color.cpp
 302     ${path_UiUtils}/Formatting.cpp
 303     ${path_UiUtils}/PasswordWatcher.cpp
 304     ${path_UiUtils}/PlainTextFormatter.cpp
 305 )
 306
 307 set(path_Composer ${CMAKE_CURRENT_SOURCE_DIR}/src/Composer)
 308 set(libComposer_SOURCES
 309     ${path_Composer}/ComposerAttachments.cpp
 310     ${path_Composer}/Mailto.cpp
 311     ${path_Composer}/MessageComposer.cpp
 312     ${path_Composer}/QuoteText.cpp
 313     ${path_Composer}/Recipients.cpp
 314     ${path_Composer}/ReplaceSignature.cpp
 315     ${path_Composer}/SenderIdentitiesModel.cpp
 316     ${path_Composer}/SubjectMangling.cpp
 317     ${path_Composer}/Submission.cpp
 318 )
 319
 320 set(path_MSA ${CMAKE_CURRENT_SOURCE_DIR}/src/MSA)
 321 set(libMSA_SOURCES
 322     ${path_MSA}/AbstractMSA.cpp
 323     ${path_MSA}/Account.cpp
 324     ${path_MSA}/FakeMSA.cpp
 325     ${path_MSA}/ImapSubmit.cpp
 326     ${path_MSA}/SMTP.cpp
 327     ${path_MSA}/Sendmail.cpp
 328 )
 329
 330 set(path_Streams ${CMAKE_CURRENT_SOURCE_DIR}/src/Streams)
 331 set(libStreams_SOURCES
 332     ${path_Streams}/DeletionWatcher.cpp
 333     ${path_Streams}/FakeSocket.cpp
 334     ${path_Streams}/IODeviceSocket.cpp
 335     ${path_Streams}/Socket.cpp
 336     ${path_Streams}/SocketFactory.cpp
 337 )
 338
 339 if(WITH_ZLIB)
 340     set(libStreams_SOURCES ${libStreams_SOURCES}
 341         ${path_Streams}/3rdparty/rfc1951.cpp)
 342     include_directories(${ZLIB_INCLUDE_DIR})
 343 endif()
 344
 345 if(NOT WITH_QT5)
 346     set(path_mimetypesqt4 ${CMAKE_CURRENT_SOURCE_DIR}/src/mimetypes-qt4)
 347     set(libMimetypesQt4_SOURCES
 348         ${path_mimetypesqt4}/io/qstandardpaths.cpp
 349         ${path_mimetypesqt4}/mimetypes/qmimedatabase.cpp
 350         ${path_mimetypesqt4}/mimetypes/qmimeglobpattern.cpp
 351         ${path_mimetypesqt4}/mimetypes/qmimemagicrule.cpp
 352         ${path_mimetypesqt4}/mimetypes/qmimemagicrulematcher.cpp
 353         ${path_mimetypesqt4}/mimetypes/qmimetype.cpp
 354         ${path_mimetypesqt4}/mimetypes/qmimetypeparser.cpp
 355         ${path_mimetypesqt4}/mimetypes/qmimeprovider.cpp
 356     )
 357     if(WIN32)
 358         set(libMimetypesQt4_SOURCES ${libMimetypesQt4_SOURCES}
 359             ${path_mimetypesqt4}/io/qstandardpaths_win.cpp)
 360     elseif(APPLE)
 361         set(libMimetypesQt4_SOURCES ${libMimetypesQt4_SOURCES}
 362             ${path_mimetypesqt4}/io/qstandardpaths_mac.cpp)
 363     elseif (OS2)
 364         set(libMimetypesQt4_SOURCES ${libMimetypesQt4_SOURCES}
 365             ${path_mimetypesqt4}/io/qstandardpaths_os2.cpp)
 366     elseif (UNIX)
 367         set(libMimetypesQt4_SOURCES ${libMimetypesQt4_SOURCES}
 368             ${path_mimetypesqt4}/io/qstandardpaths_unix.cpp)
 369     else()
 370         message(FATAL_ERROR "Unsupported platform -- mimetypes-Qt4 support only Unix, MacOSX, Windows and OS/2")
 371     endif()
 372 endif()
 373
 374 set(path_DesktopGui ${CMAKE_CURRENT_SOURCE_DIR}/src/Gui)
 375 set(libDesktopGui_SOURCES
 376     ${path_DesktopGui}/AttachmentView.cpp
 377     ${path_DesktopGui}/AutoCompletion.cpp
 378     ${path_DesktopGui}/CompleteMessageWidget.cpp
 379     ${path_DesktopGui}/ComposeWidget.cpp
 380     ${path_DesktopGui}/ComposerAttachmentsList.cpp
 381     ${path_DesktopGui}/ComposerTextEdit.cpp
 382     ${path_DesktopGui}/EmbeddedWebView.cpp
 383     ${path_DesktopGui}/EnvelopeView.cpp
 384     ${path_DesktopGui}/ExternalElementsWidget.cpp
 385     ${path_DesktopGui}/FindBar.cpp
 386     ${path_DesktopGui}/FlowLayout.cpp
 387     ${path_DesktopGui}/FromAddressProxyModel.cpp
 388     ${path_DesktopGui}/LineEdit.cpp
 389     ${path_DesktopGui}/LoadablePartWidget.cpp
 390     ${path_DesktopGui}/MailBoxTreeView.cpp
 391     ${path_DesktopGui}/MessageListWidget.cpp
 392     ${path_DesktopGui}/MessageSourceWidget.cpp
 393     ${path_DesktopGui}/MessageView.cpp
 394     ${path_DesktopGui}/MsgListView.cpp
 395     ${path_DesktopGui}/OnePanelAtTimeWidget.cpp
 396     ${path_DesktopGui}/OverlayWidget.cpp
 397     ${path_DesktopGui}/PartWalker.cpp
 398     ${path_DesktopGui}/PartWidget.cpp
 399     ${path_DesktopGui}/PartWidgetFactoryVisitor.cpp
 400     ${path_DesktopGui}/PasswordDialog.cpp
 401     ${path_DesktopGui}/ProgressPopUp.cpp
 402     ${path_DesktopGui}/ProtocolLoggerWidget.cpp
 403     ${path_DesktopGui}/ReplaceCharValidator.cpp
 404     ${path_DesktopGui}/SettingsDialog.cpp
 405     ${path_DesktopGui}/SimplePartWidget.cpp
 406     ${path_DesktopGui}/Spinner.cpp
 407     ${path_DesktopGui}/TagListWidget.cpp
 408     ${path_DesktopGui}/TagWidget.cpp
 409     ${path_DesktopGui}/TaskProgressIndicator.cpp
 410     ${path_DesktopGui}/UserAgentWebPage.cpp
 411     ${path_DesktopGui}/Util.cpp
 412     ${path_DesktopGui}/Window.cpp
 413     ${path_DesktopGui}/ShortcutHandler/ShortcutConfigDialog.cpp
 414     ${path_DesktopGui}/ShortcutHandler/ShortcutConfigWidget.cpp
 415     ${path_DesktopGui}/ShortcutHandler/ShortcutHandler.cpp
 416 )
 417 set(libDesktopGui_UI
 418     ${path_DesktopGui}/AboutDialog.ui
 419     ${path_DesktopGui}/ComposeWidget.ui
 420     ${path_DesktopGui}/CreateMailboxDialog.ui
 421     ${path_DesktopGui}/EditIdentity.ui
 422     ${path_DesktopGui}/PasswordDialog.ui
 423     ${path_DesktopGui}/ProgressPopUp.ui
 424     ${path_DesktopGui}/SettingsCachePage.ui
 425     ${path_DesktopGui}/SettingsGeneralPage.ui
 426     ${path_DesktopGui}/SettingsImapPage.ui
 427     ${path_DesktopGui}/SettingsOutgoingPage.ui
 428     ${path_DesktopGui}/ShortcutHandler/ShortcutConfigWidget.ui
 429 )
 430 set(libDesktopGui_RESOURCES
 431     ${CMAKE_CURRENT_SOURCE_DIR}/src/icons.qrc
 432     ${CMAKE_CURRENT_SOURCE_DIR}/src/license.qrc
 433 )
 434
 435 set(libqwwsmtpclient_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/src/qwwsmtpclient/qwwsmtpclient.cpp)
 436
 437 set(libAppVersion_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/src/AppVersion/SetCoreApplication.cpp)
 438
 439 set(path_Imap ${CMAKE_CURRENT_SOURCE_DIR}/src/Imap)
 440 set(libImap_SOURCES
 441     ${path_Imap}/ConnectionState.cpp
 442     ${path_Imap}/Encoders.cpp
 443     ${path_Imap}/Exceptions.cpp
 444     ${path_Imap}/Parser/3rdparty/kcodecs.cpp
 445     ${path_Imap}/Parser/3rdparty/rfccodecs.cpp
 446
 447     ${path_Imap}/Parser/Command.cpp
 448     ${path_Imap}/Parser/Data.cpp
 449     ${path_Imap}/Parser/LowLevelParser.cpp
 450     ${path_Imap}/Parser/MailAddress.cpp
 451     ${path_Imap}/Parser/Message.cpp
 452     ${path_Imap}/Parser/Parser.cpp
 453     ${path_Imap}/Parser/Response.cpp
 454     ${path_Imap}/Parser/Sequence.cpp
 455     ${path_Imap}/Parser/ThreadingNode.cpp
 456
 457     ${path_Imap}/Network/FileDownloadManager.cpp
 458     ${path_Imap}/Network/ForbiddenReply.cpp
 459     ${path_Imap}/Network/MsgPartNetAccessManager.cpp
 460     ${path_Imap}/Network/MsgPartNetworkReply.cpp
 461     ${path_Imap}/Network/QQuickNetworkReplyWrapper.cpp
 462
 463     ${path_Imap}/Model/Cache.cpp
 464     ${path_Imap}/Model/CombinedCache.cpp
 465     ${path_Imap}/Model/DragAndDrop.cpp
 466     ${path_Imap}/Model/DiskPartCache.cpp
 467     ${path_Imap}/Model/DummyNetworkWatcher.cpp
 468     ${path_Imap}/Model/FindInterestingPart.cpp
 469     ${path_Imap}/Model/FlagsOperation.cpp
 470     ${path_Imap}/Model/FullMessageCombiner.cpp
 471     ${path_Imap}/Model/ImapAccess.cpp
 472     ${path_Imap}/Model/MailboxFinder.cpp
 473     ${path_Imap}/Model/MailboxMetadata.cpp
 474     ${path_Imap}/Model/MailboxModel.cpp
 475     ${path_Imap}/Model/MailboxTree.cpp
 476     ${path_Imap}/Model/MemoryCache.cpp
 477     ${path_Imap}/Model/Model.cpp
 478     ${path_Imap}/Model/MsgListModel.cpp
 479     ${path_Imap}/Model/NetworkWatcher.cpp
 480     ${path_Imap}/Model/OneMessageModel.cpp
 481     ${path_Imap}/Model/ParserState.cpp
 482     ${path_Imap}/Model/PrettyMailboxModel.cpp
 483     ${path_Imap}/Model/PrettyMsgListModel.cpp
 484     ${path_Imap}/Model/SpecialFlagNames.cpp
 485     ${path_Imap}/Model/SQLCache.cpp
 486     ${path_Imap}/Model/SubtreeModel.cpp
 487     ${path_Imap}/Model/SystemNetworkWatcher.cpp
 488     ${path_Imap}/Model/TaskFactory.cpp
 489     ${path_Imap}/Model/TaskPresentationModel.cpp
 490     ${path_Imap}/Model/ThreadingMsgListModel.cpp
 491     ${path_Imap}/Model/Utils.cpp
 492     ${path_Imap}/Model/VisibleTasksModel.cpp
 493
 494     # The ModelTest is only needed when debugging manually
 495     #${path_Imap}/Model/ModelTest/modeltest.cpp
 496     # The ModelWatcher is another debugging aid
 497     ${path_Imap}/Model/ModelWatcher.cpp
 498
 499     ${path_Imap}/Model/kdeui-itemviews/kdescendantsproxymodel.cpp
 500
 501     ${path_Imap}/Tasks/AppendTask.cpp
 502     ${path_Imap}/Tasks/CopyMoveMessagesTask.cpp
 503     ${path_Imap}/Tasks/CreateMailboxTask.cpp
 504     ${path_Imap}/Tasks/DeleteMailboxTask.cpp
 505     ${path_Imap}/Tasks/EnableTask.cpp
 506     ${path_Imap}/Tasks/ExpungeMailboxTask.cpp
 507     ${path_Imap}/Tasks/ExpungeMessagesTask.cpp
 508     ${path_Imap}/Tasks/Fake_ListChildMailboxesTask.cpp
 509     ${path_Imap}/Tasks/Fake_OpenConnectionTask.cpp
 510     ${path_Imap}/Tasks/FetchMsgMetadataTask.cpp
 511     ${path_Imap}/Tasks/FetchMsgPartTask.cpp
 512     ${path_Imap}/Tasks/GenUrlAuthTask.cpp
 513     ${path_Imap}/Tasks/GetAnyConnectionTask.cpp
 514     ${path_Imap}/Tasks/IdTask.cpp
 515     ${path_Imap}/Tasks/IdleLauncher.cpp
 516     ${path_Imap}/Tasks/ImapTask.cpp
 517     ${path_Imap}/Tasks/KeepMailboxOpenTask.cpp
 518     ${path_Imap}/Tasks/ListChildMailboxesTask.cpp
 519     ${path_Imap}/Tasks/NoopTask.cpp
 520     ${path_Imap}/Tasks/NumberOfMessagesTask.cpp
 521     ${path_Imap}/Tasks/ObtainSynchronizedMailboxTask.cpp
 522     ${path_Imap}/Tasks/OfflineConnectionTask.cpp
 523     ${path_Imap}/Tasks/OpenConnectionTask.cpp
 524     ${path_Imap}/Tasks/SortTask.cpp
 525     ${path_Imap}/Tasks/SubscribeUnsubscribeTask.cpp
 526     ${path_Imap}/Tasks/ThreadTask.cpp
 527     ${path_Imap}/Tasks/UidSubmitTask.cpp
 528     ${path_Imap}/Tasks/UnSelectTask.cpp
 529     ${path_Imap}/Tasks/UpdateFlagsTask.cpp
 530     ${path_Imap}/Tasks/UpdateFlagsOfAllMessagesTask.cpp
 531 )
 532
 533 if(WITH_RAGEL)
 534     message(STATUS "Using Ragel for the RFC 5322 parser")
 535     ragel_parser(${path_Imap}/Parser/Rfc5322HeaderParser.cpp)
 536     set(libImap_SOURCES ${libImap_SOURCES}
 537         ${CMAKE_CURRENT_BINARY_DIR}/Rfc5322HeaderParser.generated.cpp)
 538 else()
 539     message(STATUS "Using pregenerated RFC 5322 parser")
 540     set(libImap_SOURCES ${libImap_SOURCES}
 541         ${path_Imap}/Parser/Rfc5322HeaderParser.generated.cpp)
 542 endif()
 543
 544 set(path_AbookAddressbook ${CMAKE_CURRENT_SOURCE_DIR}/src/AbookAddressbook)
 545 set(libAbookAddressbook_SOURCES
 546     ${path_AbookAddressbook}/AbookAddressbook.cpp
 547     ${path_AbookAddressbook}/be-contacts.cpp
 548 )
 549 set(libAbookAddressbook_UI
 550     ${path_AbookAddressbook}/be-contacts.ui
 551     ${path_AbookAddressbook}/onecontact.ui
 552 )
 553
 554 set(trojita_desktop_SOURCES
 555     ${path_DesktopGui}/main.cpp
 556 )
 557
 558 if(WIN32)
 559     list(APPEND trojita_desktop_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/src/trojita_win32.rc)
 560 endif()
 561
 562 set(be_contacts_SOURCES
 563     ${CMAKE_CURRENT_SOURCE_DIR}/src/be.contacts/main.cpp
 564 )
 565
 566 set(libQNAMWebView_SOURCES
 567     ${CMAKE_CURRENT_SOURCE_DIR}/src/QmlSupport/QNAMWebView/plugin.cpp
 568     ${CMAKE_CURRENT_SOURCE_DIR}/src/QmlSupport/QNAMWebView/qdeclarativewebview.cpp
 569 )
 570
 571 set(trojitaHarmattan_SOURCES
 572     ${CMAKE_CURRENT_SOURCE_DIR}/src/Harmattan/main.cpp
 573     ${CMAKE_CURRENT_SOURCE_DIR}/src/Harmattan/qmlapplicationviewer/qmlapplicationviewer.cpp
 574 )
 575
 576 set(trojitaUbuntu_SOURCES
 577         ${CMAKE_CURRENT_SOURCE_DIR}/src/Ubuntu/main.cpp
 578 )
 579
 580 if(LinguistForTrojita_FOUND OR Qt5LinguistForTrojita_FOUND)
 581     file(GLOB_RECURSE lang_PO "${CMAKE_CURRENT_SOURCE_DIR}/po/trojita_common_*.po")
 582     if(WITH_QT5)
 583         qt5_wrap_po(trojita_QM ${lang_PO})
 584     else()
 585         qt4_wrap_po(trojita_QM ${lang_PO})
 586     endif()
 587     set(language_summary "")
 588     foreach(po ${lang_PO})
 589         string(REGEX REPLACE "^(.*)/trojita_common_(.*).po" "\\2" lang ${po})
 590         list(APPEND language_summary ${lang})
 591     endforeach()
 592     list(SORT language_summary)
 593     list(LENGTH language_summary num_languages)
 594     if(num_languages)
 595         message(STATUS "Available languages: ${language_summary}")
 596         if(WITH_DESKTOP)
 597             install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/locale/ DESTINATION share/trojita/locale REGEX "(x_test)|(.*\\.ts)" EXCLUDE)
 598         endif()
 599     else()
 600         message(STATUS "No .po files found, will not install any languages")
 601     endif()
 602 else()
 603     message(STATUS "Qt Linguist (lupdate/lrelease/lconvert) not found, disabling localization support")
 604 endif()
 605
 606 set(version_files ${CMAKE_CURRENT_BINARY_DIR}/trojita-version.h ${CMAKE_CURRENT_BINARY_DIR}/trojita-git-version.h)
 607 if(WITH_NSIS)
 608     set(version_files ${version_files} ${CMAKE_CURRENT_BINARY_DIR}/trojita-version.nsi)
 609     set(NSIS TRUE)
 610 endif()
 611
 612 add_custom_target(version DEPENDS version_fake_file)
 613 add_custom_command(OUTPUT version_fake_file ${version_files}
 614     COMMAND ${CMAKE_COMMAND} -DGIT_EXECUTABLE=${GIT_EXECUTABLE} -DNSIS=${NSIS} -DUBUNTU_CLICK_MODE=${UBUNTU_CLICK_MODE} -DHOST_ARCH=${HOST_ARCH} -DSOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/TrojitaVersion.cmake)
 615 set_source_files_properties(${version_files}
 616     PROPERTIES GENERATED TRUE
 617     HEADER_FILE_ONLY TRUE)
 618
 619 add_library(Common STATIC ${libCommon_SOURCES})
 620 set_property(TARGET Common APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 621 add_dependencies(Common version)
 622 target_link_libraries(Common ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY})
 623
 624 add_library(AppVersion STATIC ${libAppVersion_SOURCES})
 625 set_property(TARGET AppVersion APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 626 add_dependencies(AppVersion version)
 627 target_link_libraries(AppVersion Common ${QT_QTCORE_LIBRARY})
 628
 629 if(WITH_SHARED_PLUGINS)
 630     add_library(Plugins SHARED ${libPlugins_SOURCES})
 631 else()
 632     add_library(Plugins STATIC ${libPlugins_SOURCES})
 633     set_property(TARGET Plugins APPEND PROPERTY COMPILE_DEFINITIONS QT_STATICPLUGIN)
 634 endif()
 635 set_target_properties(Plugins PROPERTIES OUTPUT_NAME trojita_plugins)
 636 set_property(TARGET Plugins APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 637 if(WITH_QT5)
 638     qt5_use_modules(Plugins Core)
 639 else()
 640     target_link_libraries(Plugins ${QT_QTCORE_LIBRARY})
 641 endif()
 642
 643 add_library(UiUtils STATIC ${libUiUtils_SOURCES})
 644 set_property(TARGET UiUtils APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 645 target_link_libraries(UiUtils Plugins Common ${QT_QTCORE_LIBRARY})
 646
 647 add_library(Streams STATIC ${libStreams_SOURCES})
 648 set_property(TARGET Streams APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 649 target_link_libraries(Streams ${QT_QTNETWORK_LIBRARY} ${QT_QTCORE_LIBRARY})
 650 if(WITH_ZLIB)
 651     target_link_libraries(Streams ${ZLIB_LIBRARIES})
 652 endif()
 653
 654 add_library(qwwsmtpclient STATIC ${libqwwsmtpclient_SOURCES})
 655 target_link_libraries(qwwsmtpclient ${QT_QTNETWORK_LIBRARY} ${QT_QTCORE_LIBRARY})
 656
 657 add_library(MSA STATIC ${libMSA_SOURCES})
 658 set_property(TARGET MSA APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 659 target_link_libraries(MSA Imap Streams qwwsmtpclient ${QT_QTCORE_LIBRARY})
 660
 661 add_library(Composer STATIC ${libComposer_SOURCES})
 662 set_property(TARGET Composer APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 663 target_link_libraries(Composer Common MSA Streams UiUtils qwwsmtpclient ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY})
 664 if(NOT WITH_QT5)
 665     target_link_libraries(Composer MimetypesQt4)
 666 endif()
 667
 668 add_library(Imap STATIC ${libImap_SOURCES})
 669 set_property(TARGET Imap APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 670 target_link_libraries(Imap Common Streams UiUtils ${QT_QTNETWORK_LIBRARY} ${QT_QTSQL_LIBRARY} ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY})
 671 if(WITH_ZLIB)
 672     target_link_libraries(Imap ${ZLIB_LIBRARIES})
 673 endif()
 674
 675 if(NOT WITH_QT5)
 676     add_library(MimetypesQt4 STATIC ${libMimetypesQt4_SOURCES})
 677     if(SUPPORTS_TARGET_INCLUDES)
 678         set_property(TARGET MimetypesQt4 APPEND PROPERTY INCLUDE_DIRECTORIES
 679             ${QT_MKSPECS_DIR}/default ${path_mimetypesqt4}/io/)
 680     endif()
 681     target_link_libraries(MimetypesQt4 ${QT_QTCORE_LIBRARY})
 682     if(APPLE)
 683         find_library(CARBON_LIBRARY Carbon REQUIRED)
 684         target_link_libraries(MimetypesQt4 ${CARBON_LIBRARY})
 685     endif()
 686 endif()
 687
 688 ## ClearText password plugin
 689 if(WITH_CLEARTEXT_PLUGIN)
 690     trojita_add_plugin(trojita_plugin_ClearTextPasswordPlugin WITH_CLEARTEXT_PLUGIN src/Plugins/ClearTextPassword/ClearTextPassword.cpp)
 691 endif()
 692
 693 ## QtKeyChain plugin
 694 if(WITH_QTKEYCHAIN_PLUGIN)
 695     trojita_add_plugin(trojita_plugin_QtKeychainPasswordPlugin WITH_QTKEYCHAIN_PLUGIN src/Plugins/QtKeyChain/QtKeyChainPassword.cpp)
 696     if(WITH_QT5)
 697         qt5_use_modules(trojita_plugin_QtKeychainPasswordPlugin Core DBus)
 698     else()
 699         target_link_libraries(trojita_plugin_QtKeychainPasswordPlugin ${QT_QTCORE_LIBRARY} ${QT_QTDBUS_LIBRARY})
 700     endif()
 701     target_link_libraries(trojita_plugin_QtKeychainPasswordPlugin ${QTKEYCHAIN_LIBRARIES})
 702     if(SUPPORTS_TARGET_INCLUDES)
 703         set_property(TARGET trojita_plugin_QtKeychainPasswordPlugin APPEND PROPERTY INCLUDE_DIRECTORIES ${QTKEYCHAIN_INCLUDE_DIRS})
 704     else()
 705         include_directories(${QTKEYCHAIN_INCLUDE_DIRS})
 706     endif()
 707 endif()
 708
 709 # Generate file static_plugins.h.in
 710 get_property(STATIC_PLUGINS GLOBAL PROPERTY TROJITA_STATIC_PLUGINS)
 711 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h.in "#include <QtPlugin>\n")
 712 foreach(PLUGIN ${STATIC_PLUGINS})
 713     file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h.in "Q_IMPORT_PLUGIN(${PLUGIN})\n")
 714 endforeach()
 715 execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h.in ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h)
 716
 717 if(WITH_DESKTOP)
 718     if(WITH_QT5)
 719         qt5_wrap_ui(libAbookAddressbook_UI_OUT ${libAbookAddressbook_UI})
 720         qt5_wrap_ui(libDesktopGui_UI_OUT ${libDesktopGui_UI})
 721         qt5_add_resources(libDesktopGui_RESOURCES_OUT ${libDesktopGui_RESOURCES})
 722     else()
 723         qt4_wrap_ui(libAbookAddressbook_UI_OUT ${libAbookAddressbook_UI})
 724         qt4_wrap_ui(libDesktopGui_UI_OUT ${libDesktopGui_UI})
 725         qt4_add_resources(libDesktopGui_RESOURCES_OUT ${libDesktopGui_RESOURCES})
 726     endif()
 727
 728     add_library(AbookAddressbook STATIC ${libAbookAddressbook_SOURCES} ${libAbookAddressbook_UI_OUT})
 729     set_property(TARGET AbookAddressbook APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 730     target_link_libraries(AbookAddressbook ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY})
 731
 732     add_library(DesktopGui STATIC ${libDesktopGui_SOURCES} ${libDesktopGui_UI_OUT} ${libDesktopGui_RESOURCES_OUT})
 733     set_property(TARGET DesktopGui APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 734     # The following is needed for the LineEdit widget within the .ui files.
 735     # The ${path_DesktopGui} is needed so that the generated ui_*.h file can find the headers of the custom widgets
 736     if(SUPPORTS_TARGET_INCLUDES)
 737         set_property(TARGET DesktopGui APPEND PROPERTY INCLUDE_DIRECTORIES ${path_DesktopGui})
 738     endif()
 739     target_link_libraries(DesktopGui Common UiUtils Composer Imap MSA Plugins Streams qwwsmtpclient AbookAddressbook ${QT_QTWEBKIT_LIBRARY} ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY})
 740
 741     # On Windows build a real Win32 GUI application without console window
 742     # On other platforms WIN32 flag is ignored
 743     add_executable(trojita WIN32 ${trojita_desktop_SOURCES} ${trojita_QM})
 744     set_property(TARGET trojita APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 745     target_link_libraries(trojita AppVersion Common UiUtils DesktopGui ${STATIC_PLUGINS} ${QT_QTMAIN_LIBRARY} ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY})
 746     if(NOT WITH_QT5)
 747         target_link_libraries(trojita MimetypesQt4)
 748     endif()
 749     if(WITH_ZLIB)
 750         target_link_libraries(trojita ${ZLIB_LIBRARIES})
 751     endif()
 752
 753     add_executable(be.contacts ${be_contacts_SOURCES})
 754     set_property(TARGET be.contacts APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 755     target_link_libraries(be.contacts AbookAddressbook ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY})
 756 elseif(WITH_HARMATTAN)
 757     add_library(trojitaqnamwebviewplugin SHARED ${libQNAMWebView_SOURCES})
 758     add_executable(trojita-tp ${trojitaHarmattan_SOURCES})
 759     set_property(TARGET trojita-tp APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 760     if(SUPPORTS_TARGET_INCLUDES)
 761         set_property(TARGET trojita-tp APPEND PROPERTY INCLUDE_DIRECTORIES
 762             ${QT_MKSPECS_DIR}/default ${CMAKE_CURRENT_SOURCE_DIR}/src/Harmattan/qmlapplicationviewer)
 763     endif()
 764     target_link_libraries(trojita-tp AppVersion Imap MSA Streams qwwsmtpclient Common Composer MimetypesQt4
 765         ${QT_QTSQL_LIBRARY} ${QT_QTNETWORK_LIBRARY} ${QT_QTWEBKIT_LIBRARY} ${QT_QTDECLARATIVE_LIBRARY})
 766 endif()
 767
 768 #// add the Ubuntu Libs Here ALSO
 769 if(WITH_UBUNTU)
 770     add_executable(trojita-ubu ${trojitaUbuntu_SOURCES})
 771     set_property(TARGET trojita-ubu APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 772
 773     set_property(TARGET trojita-ubu APPEND PROPERTY INCLUDE_DIRECTORIES
 774         ${QT_MKSPECS_DIR}/default ${CMAKE_CURRENT_SOURCE_DIR}/src/Ubuntu)
 775
 776     target_link_libraries(trojita-ubu AppVersion Imap MSA Streams qwwsmtpclient Common Composer Plugins ${STATIC_PLUGINS})
 777 endif()
 778
 779 if(WITH_QT5)
 780     qt5_use_modules(AppVersion Core)
 781     qt5_use_modules(Common Core Network)
 782     qt5_use_modules(UiUtils Core Gui Network)
 783     qt5_use_modules(Streams Network)
 784     qt5_use_modules(qwwsmtpclient Network)
 785     qt5_use_modules(MSA Network)
 786     qt5_use_modules(Composer Gui Network)
 787     qt5_use_modules(Imap Gui Network Sql)
 788     if (WITH_DESKTOP)
 789         qt5_use_modules(DesktopGui Network WebKitWidgets)
 790         qt5_use_modules(AbookAddressbook Widgets)
 791         qt5_use_modules(be.contacts Widgets)
 792         qt5_use_modules(trojita Widgets Network)
 793     elseif(WITH_UBUNTU)
 794         qt5_use_modules(trojita-ubu Network Core Qml Quick)
 795     endif()
 796 endif()
 797
 798
 799 if(WITH_SHARED_PLUGINS)
 800     install(TARGETS Plugins DESTINATION ${CMAKE_INSTALL_LIBDIR})
 801 endif()
 802
 803 include(SanitizedDesktopFile)
 804
 805 if(WITH_DESKTOP)
 806     copy_desktop_file_without_cruft("${CMAKE_CURRENT_SOURCE_DIR}/src/Gui/trojita.desktop" "${CMAKE_CURRENT_BINARY_DIR}/trojita-DesktopGui.desktop")
 807     install(TARGETS trojita be.contacts RUNTIME DESTINATION bin)
 808     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/trojita-DesktopGui.desktop DESTINATION share/applications/ RENAME trojita.desktop)
 809     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/Gui/trojita.appdata.xml DESTINATION share/appdata/)
 810     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/icons/trojita.png DESTINATION share/icons/hicolor/32x32/apps/)
 811     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/icons/trojita.svg DESTINATION share/icons/hicolor/scalable/apps/)
 812 endif()
 813
 814 if(WITH_UBUNTU)
 815
 816     set(TROJITA_UBUNTU_PATH ${CMAKE_CURRENT_SOURCE_DIR}/src/Ubuntu)
 817     set(AUTOPILOT_DIR ${CMAKE_CURRENT_SOURCE_DIR}/tests/autopilot/trojita)
 818     set(CLICK_MANIFESTS
 819         ${CMAKE_CURRENT_SOURCE_DIR}/qtc_packaging/click_ubuntu/trojita.json
 820         ${CMAKE_CURRENT_SOURCE_DIR}/qtc_packaging/click_ubuntu/.excludes
 821     )
 822     set(CLICK_PKG_MANIFEST ${CMAKE_CURRENT_SOURCE_DIR}/qtc_packaging/click_ubuntu/manifest.json)
 823     set(TROJITA_DESKTOP_FILE ${TROJITA_UBUNTU_PATH}/trojita-ubu.desktop)
 824
 825     set(UBUNTU_QMLS
 826         ${TROJITA_UBUNTU_PATH}/qml/trojita/AddressWidget.qml
 827         ${TROJITA_UBUNTU_PATH}/qml/trojita/OneMessagePage.qml
 828         ${TROJITA_UBUNTU_PATH}/qml/trojita/icon-m-settings-keychain.svg
 829         ${TROJITA_UBUNTU_PATH}/qml/trojita/ImapSettings.qml
 830         ${TROJITA_UBUNTU_PATH}/qml/trojita/PasswordInputSheet.qml
 831         ${TROJITA_UBUNTU_PATH}/qml/trojita/MailboxListPage.qml
 832         ${TROJITA_UBUNTU_PATH}/qml/trojita/PercentageSectionScroller.qml
 833         ${TROJITA_UBUNTU_PATH}/qml/trojita/TrojitaWebView.qml
 834         ${TROJITA_UBUNTU_PATH}/qml/trojita/SslSheet.qml
 835         ${TROJITA_UBUNTU_PATH}/qml/trojita/SettingsToolbar.qml
 836         ${TROJITA_UBUNTU_PATH}/qml/trojita/SettingsTabs.qml
 837         ${TROJITA_UBUNTU_PATH}/qml/trojita/SmtpSettings.qml
 838         ${TROJITA_UBUNTU_PATH}/qml/trojita/HeaderComponent.qml
 839         ${TROJITA_UBUNTU_PATH}/qml/trojita/dropdown-menu.svg
 840         ${TROJITA_UBUNTU_PATH}/qml/trojita/main.qml
 841         ${TROJITA_UBUNTU_PATH}/qml/trojita/MessageListPage.qml
 842         ${TROJITA_UBUNTU_PATH}/qml/trojita/MessageListToolbar.qml
 843         ${TROJITA_UBUNTU_PATH}/qml/trojita/InfoDialog.qml
 844         ${TROJITA_UBUNTU_PATH}/qml/trojita/Utils.js
 845         ${TROJITA_UBUNTU_PATH}/qml/trojita/contact.svg
 846         ${TROJITA_UBUNTU_PATH}/qml/trojita/contact_grey.svg
 847         ${TROJITA_UBUNTU_PATH}/qml/trojita/delete.svg
 848         ${TROJITA_UBUNTU_PATH}/qml/trojita/email.svg
 849         ${TROJITA_UBUNTU_PATH}/qml/trojita/favorite-selected.svg
 850         ${TROJITA_UBUNTU_PATH}/qml/trojita/favorite-unselected.svg
 851         ${TROJITA_UBUNTU_PATH}/qml/trojita/attach.svg
 852         ${TROJITA_UBUNTU_PATH}/qml/trojita/back.svg
 853         ${TROJITA_UBUNTU_PATH}/qml/trojita/key.svg
 854         ${TROJITA_UBUNTU_PATH}/qml/trojita/settings.svg
 855         ${TROJITA_UBUNTU_PATH}/qml/trojita/save.svg
 856         ${TROJITA_UBUNTU_PATH}/qml/trojita/cancel.svg
 857         ${TROJITA_UBUNTU_PATH}/qml/trojita/language-chooser.svg
 858         ${TROJITA_UBUNTU_PATH}/qml/trojita/navigation-menu.svg
 859     )
 860     set(AUTOPILOT_FILES
 861         ${AUTOPILOT_DIR}/__init__.py
 862         ${AUTOPILOT_DIR}/emulators.py
 863         ${AUTOPILOT_DIR}/tests/__init__.py
 864         ${AUTOPILOT_DIR}/tests/test_trojita.py
 865     )
 866
 867     #make files visible to QtCreator
 868     add_custom_target(
 869         ubuntu_Files
 870         ALL SOURCES
 871         ${CLICK_MANIFESTS}
 872         ${CLICK_PKG_MANIFEST}
 873         ${UBUNTU_QMLS}
 874         ${TROJITA_DESKTOP_FILE}
 875         ${AUTOPILOT_FILES}
 876     )
 877
 878     add_custom_target(ubuntu_QmlComponents ALL
 879         COMMAND ${CMAKE_COMMAND} -E copy_directory
 880             ${TROJITA_UBUNTU_PATH}/qml/trojita
 881             ${CMAKE_CURRENT_BINARY_DIR}/qml/trojita
 882         COMMENT "Copying QML files to build tree"
 883     )
 884
 885     if(UBUNTU_CLICK_MODE)
 886         if(NOT "${CMAKE_INSTALL_PREFIX}" STREQUAL "/")
 887             message(FATAL_ERROR "For Click packaging CMAKE_INSTALL_PREFIX needs to be set to: / and not: ${CMAKE_INSTALL_PREFIX}")
 888         endif()
 889         set(DATA_DIR ${CMAKE_INSTALL_PREFIX})
 890         # This magic variable is set by the qtc_chroot_cmake2 script in the ubuntu sdk plugin
 891         # http://bazaar.launchpad.net/~ubuntu-sdk-team/qtcreator-plugin-ubuntu/trunk/view/head:/share/qtcreator/ubuntu/scripts/qtc_chroot_cmake2
 892         # It doesn't hurt to ignore this if we are not building from QtCreator.
 893         if(QT_IMPORTS_DIR)
 894             set(QT_IMPORTS_DIR ${QT_IMPORTS_DIR})
 895         endif()
 896         set(BIN_DIR lib/${ARCH_TRIPLET}/bin)
 897         set(ICON trojita-ubu.png)
 898         set(ICON_DIR ${DATA_DIR})
 899         set(DESKTOP_DIR ${DATA_DIR})
 900     else()
 901         set(BIN_DIR bin)
 902         set(DATA_DIR share/trojita-ubu)
 903         set(ICON /usr/share/icons/hicolor/64x64/apps/trojita-ubu.png)
 904         set(ICON_DIR share/icons/hicolor/64x64/apps)
 905         set(DESKTOP_DIR share/applications)
 906     endif()
 907
 908     configure_file(${TROJITA_DESKTOP_FILE} ${CMAKE_CURRENT_BINARY_DIR}/trojita-ubu.desktop)
 909
 910     install(
 911         FILES ${CMAKE_CURRENT_BINARY_DIR}/trojita-ubu.desktop
 912         DESTINATION ${DESKTOP_DIR}
 913     )
 914
 915     install(
 916         FILES ${TROJITA_UBUNTU_PATH}/trojita-ubu.png
 917         DESTINATION ${ICON_DIR}
 918     )
 919
 920     install(
 921         DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/qml
 922         DESTINATION ${DATA_DIR}
 923     )
 924
 925     install(
 926         TARGETS trojita-ubu
 927         DESTINATION ${BIN_DIR}
 928     )
 929     if(UBUNTU_CLICK_MODE)
 930         install(FILES
 931             ${CLICK_PKG_MANIFEST}
 932             ${CLICK_MANIFESTS}
 933             DESTINATION ${DATA_DIR}
 934         )
 935     endif()
 936
 937 endif()
 938
 939 if(WITH_HARMATTAN)
 940     set(trojita_harmattan_path ${CMAKE_CURRENT_SOURCE_DIR}/src/Harmattan)
 941     install(TARGETS trojita-tp RUNTIME DESTINATION bin)
 942     install(TARGETS trojitaqnamwebviewplugin LIBRARY DESTINATION bin/net/flaska/QNAMWebView)
 943     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/QmlSupport/QNAMWebView/qmldir DESTINATION bin/net/flaska/QNAMWebView)
 944     install(DIRECTORY ${trojita_harmattan_path}/qml DESTINATION ${CMAKE_INSTALL_PREFIX})
 945     install(FILES ${trojita_harmattan_path}/trojita-tp.desktop DESTINATION share/applications)
 946     install(FILES ${trojita_harmattan_path}/trojita-tp80.png DESTINATION share/icons/hicolor/80x80/apps)
 947 endif()
 948
 949 if(WITH_NSIS)
 950     if(CMAKE_SIZEOF_VOID_P STREQUAL 4)
 951         set(MAKENSIS_OUTPUT Trojita-installer.exe)
 952     else()
 953         set(MAKENSIS_FLAGS -DX86_64 ${MAKENSIS_FLAGS})
 954         set(MAKENSIS_OUTPUT Trojita-installer-x86_64.exe)
 955     endif()
 956
 957     if(NOT CMAKE_VERBOSE_MAKEFILE)
 958         set(MAKENSIS_FLAGS -V2 -DQUIET ${MAKENSIS_FLAGS})
 959     endif()
 960
 961     set(MAKENSIS_FLAGS ${MAKENSIS_FLAGS} -NOCD)
 962
 963     add_custom_command(OUTPUT ${MAKENSIS_OUTPUT}
 964         COMMAND ${MAKENSIS}
 965         ARGS ${MAKENSIS_FLAGS} ${CMAKE_CURRENT_SOURCE_DIR}/packaging/trojita.nsi
 966         DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/packaging/trojita.nsi ${CMAKE_CURRENT_BINARY_DIR}/trojita.exe version)
 967     add_custom_target(installer ALL DEPENDS ${MAKENSIS_OUTPUT})
 968 endif()
 969
 970
 971 if(WITH_TESTS)
 972     set(test_LibMailboxSync_SOURCES
 973         tests/Utils/ModelEvents.cpp
 974         tests/Utils/LibMailboxSync.cpp
 975     )
 976     add_library(test_LibMailboxSync STATIC ${test_LibMailboxSync_SOURCES})
 977     if(WITH_QT5)
 978         qt5_use_modules(test_LibMailboxSync Test Network)
 979     endif()
 980     if(SUPPORTS_TARGET_INCLUDES)
 981         set_property(TARGET test_LibMailboxSync APPEND PROPERTY INCLUDE_DIRECTORIES
 982             ${CMAKE_CURRENT_SOURCE_DIR}/tests
 983             ${CMAKE_CURRENT_SOURCE_DIR}/tests/Utils)
 984     endif()
 985     target_link_libraries(test_LibMailboxSync Imap MSA Streams Common Composer ${QT_QTTEST_LIBRARY} ${QT_QTCORE_LIBRARY})
 986
 987     macro(trojita_test dir fname)
 988         set(test_${fname}_SOURCES tests/${dir}/test_${fname}.cpp)
 989         add_executable(test_${fname} ${test_${fname}_SOURCES})
 990         target_link_libraries(test_${fname} Imap MSA Streams Common Composer test_LibMailboxSync)
 991         if(WITH_QT5)
 992             qt5_use_modules(test_${fname} Network Sql Test Widgets)
 993         else()
 994             target_link_libraries(test_${fname} ${QT_QTSQL_LIBRARY} ${QT_QTTEST_LIBRARY} ${QT_QTGUI_LIBRARY} ${QT_QTCORE_LIBRARY} ${QT_QTNETWORK_LIBRARY})
 995         endif()
 996         if(WITH_ZLIB)
 997             target_link_libraries(test_${fname} ${ZLIB_LIBRARIES})
 998         endif()
 999         if(SUPPORTS_TARGET_INCLUDES)
1000             set_property(TARGET test_${fname} APPEND PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_SOURCE_DIR}/tests)
1001         endif()
1002         if(NOT CMAKE_CROSSCOMPILING)
1003             add_test(test_${fname} test_${fname})
1004         endif()
1005     endmacro()
1006
1007     enable_testing()
1008     trojita_test(Composer Composer_Submission)
1009     trojita_test(Composer Composer_responses)
1010     trojita_test(Composer Html_formatting)
1011     if(WITH_QT5)
1012         qt5_use_modules(test_Composer_responses WebKitWidgets)
1013         qt5_use_modules(test_Html_formatting WebKitWidgets)
1014     else()
1015         target_link_libraries(test_Html_formatting ${QT_QTWEBKIT_LIBRARY})
1016     endif()
1017     trojita_test(Imap Imap_DisappearingMailboxes)
1018     trojita_test(Imap Imap_Idle)
1019     trojita_test(Imap Imap_LowLevelParser)
1020     trojita_test(Imap Imap_Message)
1021     trojita_test(Imap Imap_Model)
1022     trojita_test(Imap Imap_MsgPartNetAccessManager)
1023     trojita_test(Imap Imap_Parser_parse)
1024     trojita_test(Imap Imap_Responses)
1025     trojita_test(Imap Imap_SelectedMailboxUpdates)
1026     trojita_test(Imap Imap_Tasks_CreateMailbox)
1027     trojita_test(Imap Imap_Tasks_DeleteMailbox)
1028     trojita_test(Imap Imap_Tasks_ListChildMailboxes)
1029     trojita_test(Imap Imap_Tasks_ObtainSynchronizedMailbox)
1030     trojita_test(Imap Imap_Tasks_OpenConnection)
1031     trojita_test(Imap Imap_Threading)
1032     trojita_test(Imap Imap_BodyParts)
1033     trojita_test(Imap Imap_Offline)
1034     trojita_test(Imap Imap_CopyAndFlagOperations)
1035     trojita_test(Misc Rfc5322)
1036     trojita_test(Misc RingBuffer)
1037     trojita_test(Misc SenderIdentitiesModel)
1038     trojita_test(Misc SqlCache)
1039     trojita_test(Misc algorithms)
1040     trojita_test(Misc rfccodecs)
1041
1042     if(WITH_UBUNTU)
1043         find_program(PYTHON3_EXECUTABLE python3)
1044         if(PYTHON3_EXECUTABLE)
1045             execute_process(COMMAND ${PYTHON3_EXECUTABLE} -c "from distutils.sysconfig import get_python_lib; print(get_python_lib())"
1046                 OUTPUT_VARIABLE PYTHON_PACKAGE_DIR OUTPUT_STRIP_TRAILING_WHITESPACE
1047             )
1048             install(DIRECTORY ${AUTOPILOT_DIR}
1049                 DESTINATION ${PYTHON_PACKAGE_DIR}
1050             )
1051         else()
1052             message(SEND_ERROR "Python3 executable not found, autopilot tests will not been installed")
1053         endif()
1054     endif()
1055 endif()
1056
1057 if(WIN32) # Check if we are on Windows
1058     if(MSVC10) # Check if we are using the Visual Studio compiler 2010
1059         # Because of linker errors (see http://stackoverflow.com/questions/5625884/conversion-of-stdwstring-to-qstring-throws-linker-error)
1060         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Zc:wchar_t-")
1061     elseif(MINGW)
1062     else()
1063         message(WARNING "You are using a compiler which we have not tested yet (not MSVC10 or MINGW).")
1064         message(WARNING "Please let us know how well it works.")
1065     endif()
1066 endif()