CMakeLists.txt

   1 project(trojita)
   2 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
   3
   4 # Qt5's qt5_use_modules need 2.8.9+
   5 # On win32, we need QtMain linking, which means 2.8.11+
   6 # EL7 ships 2.8.11, Debian 8 ships 3.0.2, and Ubuntu 14.04 LTS has 2.8.12
   7 cmake_minimum_required(VERSION 2.8.11)
   8 cmake_policy(SET CMP0020 NEW)
   9
  10 if(POLICY CMP0054)
  11     # Silence warnings in TrojitaOption.cmake; we are fine with only doing the
  12     # expansion by hand
  13     cmake_policy(SET CMP0054 NEW)
  14 endif()
  15
  16 if(POLICY CMP0043)
  17     # We make use of CMAKE_CXXFLAGS_DEBUG...
  18     cmake_policy(SET CMP0043 OLD)
  19 endif()
  20
  21 if(CMAKE_VERSION VERSION_LESS "3.1")
  22     # If you aren't using and old Linux with an old GCC and old CMake, please just upgrade.
  23     set(CMAKE_CXX_FLAGS "--std=c++11 ${CMAKE_CXX_FLAGS}")
  24 else()
  25     set(CMAKE_CXX_STANDARD 11)
  26     set(CMAKE_CXX_STANDARD_REQUIRED ON)
  27 endif()
  28
  29 # Set a default build type if none was specified. This was shamelessly stolen
  30 # from VTK's cmake setup because these guys produce both CMake and a project that
  31 # manipulates this variable, and the web is full of posts where people say that
  32 # it is apparently evil to just set the build type in a way an earlier version of
  33 # this patch did. Oh, and the location of this check/update matters, apparently.
  34 #
  35 # Yes, this is just plain crazy.
  36 if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  37     message(STATUS "Setting build type to 'RelWithDebInfo' as none was specified.")
  38     set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING "Choose the type of build." FORCE)
  39     # Set the possible values of build type for cmake-gui
  40     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
  41 endif()
  42
  43 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
  44
  45 include(TrojitaOption)
  46
  47 trojita_option(WITH_DESKTOP "Build desktop version" ON)
  48 trojita_option(WITH_DBUS "Build with DBus library" AUTO)
  49 trojita_option(WITH_RAGEL "Build with Ragel library" AUTO)
  50 trojita_option(WITH_ZLIB "Build with zlib library" AUTO)
  51 trojita_option(WITH_SHARED_PLUGINS "Enable shared dynamic plugins" ON)
  52 trojita_option(BUILD_TESTING "Build tests" ON)
  53 trojita_option(WITH_MIMETIC "Build with client-side MIME parsing" AUTO)
  54 trojita_option(WITH_GPGMEPP "Use GpgME's native C++ bindings" AUTO)
  55 trojita_option(WITH_KF5_GPGMEPP "Use legacy discontinued GpgME++ library from KDE frameworks" AUTO)
  56
  57 if(WIN32)
  58     trojita_option(WITH_NSIS "Build Windows NSIS installer" AUTO "WITH_DESKTOP")
  59 endif()
  60
  61 if(UNIX AND NOT APPLE)
  62     set(QTKEYCHAIN_DEPENDS ";WITH_DBUS")
  63 else()
  64     set(QTKEYCHAIN_DEPENDS "")
  65 endif()
  66
  67 find_package(Qt5Core 5.2 REQUIRED)
  68 find_package(Qt5Gui REQUIRED)
  69 find_package(Qt5Network REQUIRED)
  70 find_package(Qt5Sql REQUIRED)
  71 find_package(Qt5WebKitWidgets REQUIRED)
  72 find_package(Qt5Widgets REQUIRED)
  73 find_package(Qt5LinguistTools)
  74 find_package(Qt5Svg REQUIRED)
  75 trojita_find_package(Qt5DBus "" "http://qt-project.org" "Qt5 D-Bus support" "Needed for IPC and for some plugins" WITH_DBUS)
  76 trojita_find_package(Qt5Test "" "http://qt-project.org" "Qt5 QTest library" "Needed for automated tests" BUILD_TESTING)
  77 if(Qt5LinguistTools_FOUND)
  78     find_package(Qt5LinguistForTrojita)
  79 endif()
  80
  81 trojita_plugin_option(WITH_ABOOKADDRESSBOOK_PLUGIN "Build AbookAddressbook plugin" STATIC)
  82 trojita_plugin_option(WITH_CLEARTEXT_PLUGIN "Build Cleartext password plugin" STATIC)
  83 trojita_plugin_option(WITH_QTKEYCHAIN_PLUGIN "Build Qtkeychain password plugin" "${QTKEYCHAIN_DEPENDS}")
  84
  85 trojita_find_package(Git "" "" "" "")
  86
  87 trojita_find_package(Mimetic "" "http://www.codesink.org/mimetic_mime_library.html" "C++ MIME Library" "Required for client-side MIME parsing" WITH_MIMETIC)
  88 trojita_find_package(Gpgmepp "1.8.0" "https://gnupg.org/related_software/gpgme/index.html" "C++/Qt bindings for gpgme" "Needed for encrypted/signed e-mails" WITH_GPGMEPP)
  89 if(NOT WITH_GPGMEPP)
  90     trojita_find_package(KF5Gpgmepp "" "https://commits.kde.org/gpgmepp?path=/" "C++ bindings for gpgme" "Needed for encrypted/signed e-mails" WITH_KF5_GPGMEPP)
  91     trojita_option(WITH_CRYPTO_MESSAGES "Enable support for encrypted messages" AUTO "WITH_MIMETIC;WITH_KF5_GPGMEPP")
  92 else()
  93     trojita_option(WITH_CRYPTO_MESSAGES "Enable support for encrypted messages" AUTO "WITH_MIMETIC;WITH_GPGMEPP")
  94 endif()
  95
  96 if(WIN32)
  97     trojita_find_package(MakeNSIS "" "http://nsis.sourceforge.net" "Nullsoft Scriptable Install System" "Needed for building Windows installer" WITH_NSIS)
  98 endif()
  99
 100 # Add support for Mingw RC compiler
 101 if(WIN32)
 102     enable_language(RC)
 103     include(CMakeDetermineRCCompiler)
 104
 105     if(MINGW)
 106         set(CMAKE_RC_COMPILER_INIT windres)
 107         set(CMAKE_RC_COMPILE_OBJECT "<CMAKE_RC_COMPILER> <FLAGS> -O coff <DEFINES> -I${CMAKE_CURRENT_BINARY_DIR} -i <SOURCE> -o <OBJECT>")
 108     endif()
 109 endif()
 110
 111 trojita_find_package(Qt5Keychain QUIET "https://github.com/frankosterfeld/qtkeychain" "QtKeychain library (Qt5 version)" "Needed for QtKeychain password plugin" WITH_QTKEYCHAIN_PLUGIN)
 112 if(Qt5Keychain_FOUND OR QtKeychain_FOUND)
 113     message(STATUS "Found QtKeychain library (includes at ${QTKEYCHAIN_INCLUDE_DIRS}, lib at ${QTKEYCHAIN_LIBRARIES})")
 114 else()
 115     message(STATUS "Could not find QtKeychain library")
 116 endif()
 117
 118 if(NOT DEFINED CMAKE_INSTALL_LIBDIR)
 119     set(CMAKE_INSTALL_LIBDIR "lib${LIB_SUFFIX}")
 120 endif()
 121 mark_as_advanced(CMAKE_INSTALL_LIBDIR)
 122
 123 if(NOT CMAKE_INSTALL_PLUGIN_DIR)
 124     set(CMAKE_INSTALL_PLUGIN_DIR "${CMAKE_INSTALL_LIBDIR}/trojita")
 125 endif()
 126 mark_as_advanced(CMAKE_INSTALL_PLUGIN_DIR)
 127
 128 if(NOT PLUGIN_DIR)
 129     if(IS_ABSOLUTE ${CMAKE_INSTALL_PLUGIN_DIR})
 130         set(PLUGIN_DIR "${CMAKE_INSTALL_PLUGIN_DIR}")
 131     else()
 132         set(PLUGIN_DIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_PLUGIN_DIR}")
 133     endif()
 134 endif()
 135 mark_as_advanced(PLUGIN_DIR)
 136
 137 include(GNUInstallDirs)
 138
 139 # When manipulating CXXFLAGS, we put the user's CXXFLAGS *after* that so that they take priority.
 140 if(MSVC)
 141     # See below for some reationale for these optimizations
 142     set(CMAKE_CXX_FLAGS "/O2 ${CMAKE_CXX_FLAGS}")
 143
 144     # We have no information about the warnings and their usefullness. Reports are welcome.
 145     # We might enable warnings on MSVC in future.
 146 else()
 147     # -Werror is not a default for sanity reasons (one cannot know what warnings a future compiler
 148     # might bring along), but it's a default in debug mode. The idea is that developers should care
 149     # about a warning-free build, and that this is easier than messing with yet another configure option.
 150     set(CMAKE_CXX_FLAGS_DEBUG "-Werror ${CMAKE_CXX_FLAGS_DEBUG}")
 151     # Also see CMP0043...
 152
 153     # Optimizations are enabled unconditionally because they make a big difference in the speed of the
 154     # resulting binaries, and that it is better to allow an opt-out from them by adjusting CXXFLAGS through
 155     # an env var at cmake time if needed.
 156     # The reason for not manipulating just CMAKE_CXX_FLAGS_DEBUG is that unrecognized build types ("DebugFull")
 157     # should still benefit from these optimizations. Yup, it would be even better if CMake did a sane thing
 158     # and warned when users set an unrecognized and unused build type, but that just isn't the case.
 159     set(CMAKE_CXX_FLAGS "-O2 ${CMAKE_CXX_FLAGS}")
 160
 161     # Build warnings are useful tools (and Trojita should be warning-free anyway), enable them on all
 162     # configurations. They are warnings, not errors.
 163     set(CMAKE_CXX_FLAGS "-Wall -Wsign-compare ${CMAKE_CXX_FLAGS}")
 164 endif()
 165
 166 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/src)
 167 # The following is required so that the moc_*.cpp and ui_*.h are found
 168 include_directories(${CMAKE_CURRENT_BINARY_DIR})
 169
 170 add_definitions(-DQT_STRICT_ITERATORS)
 171 add_definitions(-DQT_USE_QSTRINGBUILDER)
 172 add_definitions(-DQT_USE_FAST_OPERATOR_PLUS)
 173 add_definitions(-DQT_USE_FAST_CONCATENATION)
 174
 175 if(NOT MSVC)
 176   # We're using C++11's threading features (std::async in particular), and that requires "some threading". With GCC and
 177   # Clang, this is implemented through the -pthread build flag. Without using these bits, linking fails on Fedora 23,
 178   # and this is apparently a slightly different failure than the Kf5::Gpgmepp-pthread one in commit
 179   # 12e41101070f7073caec653185c0504763672ee7.
 180   #
 181   # Apparently, there's been various methods on how to enable this in the most-cmakeish-way throughout the years, with
 182   # cmake-3.1+ supporting some magic linking via the Threads::Threads option on a per-library basis. However, I am not
 183   # really looking into that wonderful fun of mixing -pthread and non-pthread translation units, so let's use a big
 184   # hammer and set it unconditionally on platforms which use it anyway.
 185   #
 186   # And because we also support MinGW and its `windres` compiler, we have to avoid passing -pthread to *that* thing, so,
 187   # well, let's cheat and put it into the CXXFLAGS.
 188   set(CMAKE_CXX_FLAGS "-pthread ${CMAKE_CXX_FLAGS}")
 189 endif()
 190
 191 # Make sure that plugins not export all symbols, only that which are explicitly marked
 192 include(GenerateExportHeader)
 193 add_compiler_export_flags()
 194
 195 set(CMAKE_AUTOMOC True)
 196
 197 trojita_find_package(RagelForTrojita "" "" "" "" WITH_RAGEL)
 198 trojita_find_package(ZLIB "" "" "" "" WITH_ZLIB)
 199
 200 if(WITH_MIMETIC)
 201   set(TROJITA_HAVE_MIMETIC True)
 202 else()
 203   set(TROJITA_HAVE_MIMETIC False)
 204 endif()
 205
 206 if(WITH_GPGMEPP OR WITH_KF5_GPGMEPP)
 207   set(TROJITA_HAVE_GPGMEPP True)
 208 else()
 209   set(TROJITA_HAVE_GPGMEPP False)
 210 endif()
 211
 212 if(WITH_CRYPTO_MESSAGES)
 213   set(TROJITA_HAVE_CRYPTO_MESSAGES True)
 214 else()
 215   set(TROJITA_HAVE_CRYPTO_MESSAGES False)
 216 endif()
 217
 218 if(WITH_ZLIB)
 219     set(TROJITA_HAVE_ZLIB True)
 220     message(STATUS "Support for COMPRESS=DEFLATE enabled")
 221 else()
 222     set(TROJITA_HAVE_ZLIB False)
 223     message(STATUS "Disabling COMPRESS=DEFLATE, zlib is not available")
 224 endif()
 225
 226 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/configure.cmake.in
 227     ${CMAKE_CURRENT_BINARY_DIR}/configure.cmake.h)
 228 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/configure-plugins.cmake.in
 229     ${CMAKE_CURRENT_BINARY_DIR}/configure-plugins.cmake.h)
 230
 231 feature_summary(FATAL_ON_MISSING_REQUIRED_PACKAGES INCLUDE_QUIET_PACKAGES DESCRIPTION "\n" WHAT ALL)
 232
 233 set(path_Common ${CMAKE_CURRENT_SOURCE_DIR}/src/Common)
 234 set(libCommon_SOURCES
 235     ${path_Common}/Application.cpp
 236     ${path_Common}/ConnectionId.cpp
 237     ${path_Common}/DeleteAfter.cpp
 238     ${path_Common}/FileLogger.cpp
 239     ${path_Common}/MetaTypes.cpp
 240     ${path_Common}/Paths.cpp
 241     ${path_Common}/SettingsNames.cpp
 242 )
 243
 244 set(path_Plugins ${CMAKE_CURRENT_SOURCE_DIR}/src/Plugins)
 245 set(libPlugins_SOURCES
 246     ${path_Plugins}/AddressbookPlugin.cpp
 247     ${path_Plugins}/PasswordPlugin.cpp
 248     ${path_Plugins}/PluginJob.cpp
 249     ${path_Plugins}/PluginManager.cpp
 250 )
 251
 252 set(path_UiUtils ${CMAKE_CURRENT_SOURCE_DIR}/src/UiUtils)
 253 set(libUiUtils_SOURCES
 254     ${path_UiUtils}/Color.cpp
 255     ${path_UiUtils}/Formatting.cpp
 256     ${path_UiUtils}/IconLoader.cpp
 257     ${path_UiUtils}/PartLoadingOptions.h
 258     ${path_UiUtils}/PartVisitor.h
 259     ${path_UiUtils}/PartWalker.h
 260     ${path_UiUtils}/PartWalker_impl.h
 261     ${path_UiUtils}/PasswordWatcher.cpp
 262     ${path_UiUtils}/PlainTextFormatter.cpp
 263 )
 264
 265 set(path_IPC ${CMAKE_CURRENT_SOURCE_DIR}/src/IPC)
 266
 267 if(WITH_DBUS)
 268     set(libIPC_SOURCES
 269         ${path_IPC}/DBusInterface.cpp
 270         ${path_IPC}/MainWindowBridge.cpp
 271     )
 272 else()
 273     set(libIPC_SOURCES
 274         ${path_IPC}/None.cpp
 275     )
 276 endif()
 277
 278 set(path_Composer ${CMAKE_CURRENT_SOURCE_DIR}/src/Composer)
 279 set(libComposer_SOURCES
 280     ${path_Composer}/ComposerAttachments.cpp
 281     ${path_Composer}/Mailto.cpp
 282     ${path_Composer}/MessageComposer.cpp
 283     ${path_Composer}/QuoteText.cpp
 284     ${path_Composer}/Recipients.cpp
 285     ${path_Composer}/ReplaceSignature.cpp
 286     ${path_Composer}/SenderIdentitiesModel.cpp
 287     ${path_Composer}/SubjectMangling.cpp
 288     ${path_Composer}/Submission.cpp
 289 )
 290
 291 set(path_MSA ${CMAKE_CURRENT_SOURCE_DIR}/src/MSA)
 292 set(libMSA_SOURCES
 293     ${path_MSA}/AbstractMSA.cpp
 294     ${path_MSA}/Account.cpp
 295     ${path_MSA}/FakeMSA.cpp
 296     ${path_MSA}/ImapSubmit.cpp
 297     ${path_MSA}/SMTP.cpp
 298     ${path_MSA}/Sendmail.cpp
 299 )
 300
 301 set(path_Streams ${CMAKE_CURRENT_SOURCE_DIR}/src/Streams)
 302 set(libStreams_SOURCES
 303     ${path_Streams}/DeletionWatcher.cpp
 304     ${path_Streams}/FakeSocket.cpp
 305     ${path_Streams}/IODeviceSocket.cpp
 306     ${path_Streams}/Socket.cpp
 307     ${path_Streams}/SocketFactory.cpp
 308 )
 309
 310 set(path_Cryptography ${CMAKE_CURRENT_SOURCE_DIR}/src/Cryptography)
 311 set(libCryptography_SOURCES
 312     ${path_Cryptography}/MessageModel.cpp
 313     ${path_Cryptography}/MessagePart.cpp
 314     ${path_Cryptography}/PartReplacer.cpp
 315 )
 316 if(WITH_MIMETIC)
 317     set(libCryptography_SOURCES
 318         ${libCryptography_SOURCES}
 319         ${path_Cryptography}/LocalMimeParser.cpp
 320         ${path_Cryptography}/MimeticUtils.cpp
 321     )
 322 endif()
 323 if(WITH_CRYPTO_MESSAGES)
 324     set(libCryptography_SOURCES
 325         ${libCryptography_SOURCES}
 326         ${path_Cryptography}/GpgMe++.cpp
 327     )
 328 endif()
 329
 330 if(WITH_ZLIB)
 331     set(libStreams_SOURCES ${libStreams_SOURCES}
 332         ${path_Streams}/3rdparty/rfc1951.cpp)
 333 endif()
 334
 335 set(path_DesktopGui ${CMAKE_CURRENT_SOURCE_DIR}/src/Gui)
 336 set(libDesktopGui_SOURCES
 337     ${path_DesktopGui}/AddressRowWidget.cpp
 338     ${path_DesktopGui}/AttachmentView.cpp
 339     ${path_DesktopGui}/CompleteMessageWidget.cpp
 340     ${path_DesktopGui}/ComposeWidget.cpp
 341     ${path_DesktopGui}/ComposerAttachmentsList.cpp
 342     ${path_DesktopGui}/ComposerTextEdit.cpp
 343     ${path_DesktopGui}/EmbeddedWebView.cpp
 344     ${path_DesktopGui}/EnvelopeView.cpp
 345     ${path_DesktopGui}/ExternalElementsWidget.cpp
 346     ${path_DesktopGui}/FindBar.cpp
 347     ${path_DesktopGui}/FindBarMixin.cpp
 348     ${path_DesktopGui}/FlowLayout.cpp
 349     ${path_DesktopGui}/FromAddressProxyModel.cpp
 350     ${path_DesktopGui}/LineEdit.cpp
 351     ${path_DesktopGui}/LoadablePartWidget.cpp
 352     ${path_DesktopGui}/MailBoxTreeView.cpp
 353     ${path_DesktopGui}/MessageHeadersWidget.cpp
 354     ${path_DesktopGui}/MessageListWidget.cpp
 355     ${path_DesktopGui}/MessageSourceWidget.cpp
 356     ${path_DesktopGui}/MessageView.cpp
 357     ${path_DesktopGui}/MsgListView.cpp
 358     ${path_DesktopGui}/OnePanelAtTimeWidget.cpp
 359     ${path_DesktopGui}/OneEnvelopeAddress.cpp
 360     ${path_DesktopGui}/OverlayWidget.cpp
 361     ${path_DesktopGui}/PartWalker.cpp
 362     ${path_DesktopGui}/PartWidget.cpp
 363     ${path_DesktopGui}/PartWidgetFactoryVisitor.cpp
 364     ${path_DesktopGui}/PasswordDialog.cpp
 365     ${path_DesktopGui}/ProgressPopUp.cpp
 366     ${path_DesktopGui}/ProtocolLoggerWidget.cpp
 367     ${path_DesktopGui}/ReplaceCharValidator.cpp
 368     ${path_DesktopGui}/SettingsDialog.cpp
 369     ${path_DesktopGui}/SimplePartWidget.cpp
 370     ${path_DesktopGui}/Spinner.cpp
 371     ${path_DesktopGui}/TagListWidget.cpp
 372     ${path_DesktopGui}/TagWidget.cpp
 373     ${path_DesktopGui}/TaskProgressIndicator.cpp
 374     ${path_DesktopGui}/UserAgentWebPage.cpp
 375     ${path_DesktopGui}/Util.cpp
 376     ${path_DesktopGui}/Window.cpp
 377     ${path_DesktopGui}/ShortcutHandler/ShortcutConfigDialog.cpp
 378     ${path_DesktopGui}/ShortcutHandler/ShortcutConfigWidget.cpp
 379     ${path_DesktopGui}/ShortcutHandler/ShortcutHandler.cpp
 380 )
 381 set(libDesktopGui_UI
 382     ${path_DesktopGui}/AboutDialog.ui
 383     ${path_DesktopGui}/ComposeWidget.ui
 384     ${path_DesktopGui}/CreateMailboxDialog.ui
 385     ${path_DesktopGui}/EditIdentity.ui
 386     ${path_DesktopGui}/PasswordDialog.ui
 387     ${path_DesktopGui}/ProgressPopUp.ui
 388     ${path_DesktopGui}/SettingsCachePage.ui
 389     ${path_DesktopGui}/SettingsGeneralPage.ui
 390     ${path_DesktopGui}/SettingsImapPage.ui
 391     ${path_DesktopGui}/SettingsOutgoingPage.ui
 392     ${path_DesktopGui}/ShortcutHandler/ShortcutConfigWidget.ui
 393 )
 394 set(libDesktopGui_RESOURCES
 395     ${CMAKE_CURRENT_SOURCE_DIR}/src/icons.qrc
 396     ${CMAKE_CURRENT_SOURCE_DIR}/src/license.qrc
 397 )
 398
 399 set(libqwwsmtpclient_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/src/qwwsmtpclient/qwwsmtpclient.cpp)
 400
 401 set(libAppVersion_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/src/AppVersion/SetCoreApplication.cpp)
 402
 403 set(path_Imap ${CMAKE_CURRENT_SOURCE_DIR}/src/Imap)
 404 set(libImap_SOURCES
 405     ${path_Imap}/ConnectionState.cpp
 406     ${path_Imap}/Encoders.cpp
 407     ${path_Imap}/Exceptions.cpp
 408     ${path_Imap}/Parser/3rdparty/kcodecs.cpp
 409     ${path_Imap}/Parser/3rdparty/rfccodecs.cpp
 410
 411     ${path_Imap}/Parser/Command.cpp
 412     ${path_Imap}/Parser/Data.cpp
 413     ${path_Imap}/Parser/LowLevelParser.cpp
 414     ${path_Imap}/Parser/MailAddress.cpp
 415     ${path_Imap}/Parser/Message.cpp
 416     ${path_Imap}/Parser/Parser.cpp
 417     ${path_Imap}/Parser/Response.cpp
 418     ${path_Imap}/Parser/Sequence.cpp
 419     ${path_Imap}/Parser/ThreadingNode.cpp
 420
 421     ${path_Imap}/Network/FileDownloadManager.cpp
 422     ${path_Imap}/Network/ForbiddenReply.cpp
 423     ${path_Imap}/Network/MsgPartNetAccessManager.cpp
 424     ${path_Imap}/Network/MsgPartNetworkReply.cpp
 425     ${path_Imap}/Network/QQuickNetworkReplyWrapper.cpp
 426
 427     ${path_Imap}/Model/Cache.cpp
 428     ${path_Imap}/Model/CombinedCache.cpp
 429     ${path_Imap}/Model/DragAndDrop.cpp
 430     ${path_Imap}/Model/DiskPartCache.cpp
 431     ${path_Imap}/Model/DummyNetworkWatcher.cpp
 432     ${path_Imap}/Model/FindInterestingPart.cpp
 433     ${path_Imap}/Model/FlagsOperation.cpp
 434     ${path_Imap}/Model/FullMessageCombiner.cpp
 435     ${path_Imap}/Model/ImapAccess.cpp
 436     ${path_Imap}/Model/MailboxFinder.cpp
 437     ${path_Imap}/Model/MailboxMetadata.cpp
 438     ${path_Imap}/Model/MailboxModel.cpp
 439     ${path_Imap}/Model/MailboxTree.cpp
 440     ${path_Imap}/Model/MemoryCache.cpp
 441     ${path_Imap}/Model/Model.cpp
 442     ${path_Imap}/Model/MsgListModel.cpp
 443     ${path_Imap}/Model/NetworkWatcher.cpp
 444     ${path_Imap}/Model/OneMessageModel.cpp
 445     ${path_Imap}/Model/ParserState.cpp
 446     ${path_Imap}/Model/PrettyMailboxModel.cpp
 447     ${path_Imap}/Model/PrettyMsgListModel.cpp
 448     ${path_Imap}/Model/SpecialFlagNames.cpp
 449     ${path_Imap}/Model/SQLCache.cpp
 450     ${path_Imap}/Model/SubtreeModel.cpp
 451     ${path_Imap}/Model/SystemNetworkWatcher.cpp
 452     ${path_Imap}/Model/TaskFactory.cpp
 453     ${path_Imap}/Model/TaskPresentationModel.cpp
 454     ${path_Imap}/Model/ThreadingMsgListModel.cpp
 455     ${path_Imap}/Model/Utils.cpp
 456     ${path_Imap}/Model/VisibleTasksModel.cpp
 457
 458     # The ModelTest is only needed when debugging manually
 459     #${path_Imap}/Model/ModelTest/modeltest.cpp
 460     # The ModelWatcher is another debugging aid
 461     ${path_Imap}/Model/ModelWatcher.cpp
 462
 463     ${path_Imap}/Model/kdeui-itemviews/kdescendantsproxymodel.cpp
 464
 465     ${path_Imap}/Tasks/AppendTask.cpp
 466     ${path_Imap}/Tasks/CopyMoveMessagesTask.cpp
 467     ${path_Imap}/Tasks/CreateMailboxTask.cpp
 468     ${path_Imap}/Tasks/DeleteMailboxTask.cpp
 469     ${path_Imap}/Tasks/EnableTask.cpp
 470     ${path_Imap}/Tasks/ExpungeMailboxTask.cpp
 471     ${path_Imap}/Tasks/ExpungeMessagesTask.cpp
 472     ${path_Imap}/Tasks/Fake_ListChildMailboxesTask.cpp
 473     ${path_Imap}/Tasks/Fake_OpenConnectionTask.cpp
 474     ${path_Imap}/Tasks/FetchMsgMetadataTask.cpp
 475     ${path_Imap}/Tasks/FetchMsgPartTask.cpp
 476     ${path_Imap}/Tasks/GenUrlAuthTask.cpp
 477     ${path_Imap}/Tasks/GetAnyConnectionTask.cpp
 478     ${path_Imap}/Tasks/IdTask.cpp
 479     ${path_Imap}/Tasks/IdleLauncher.cpp
 480     ${path_Imap}/Tasks/ImapTask.cpp
 481     ${path_Imap}/Tasks/KeepMailboxOpenTask.cpp
 482     ${path_Imap}/Tasks/ListChildMailboxesTask.cpp
 483     ${path_Imap}/Tasks/NoopTask.cpp
 484     ${path_Imap}/Tasks/NumberOfMessagesTask.cpp
 485     ${path_Imap}/Tasks/ObtainSynchronizedMailboxTask.cpp
 486     ${path_Imap}/Tasks/OfflineConnectionTask.cpp
 487     ${path_Imap}/Tasks/OpenConnectionTask.cpp
 488     ${path_Imap}/Tasks/SortTask.cpp
 489     ${path_Imap}/Tasks/SubscribeUnsubscribeTask.cpp
 490     ${path_Imap}/Tasks/ThreadTask.cpp
 491     ${path_Imap}/Tasks/UidSubmitTask.cpp
 492     ${path_Imap}/Tasks/UnSelectTask.cpp
 493     ${path_Imap}/Tasks/UpdateFlagsTask.cpp
 494     ${path_Imap}/Tasks/UpdateFlagsOfAllMessagesTask.cpp
 495 )
 496
 497 if(WITH_RAGEL)
 498     message(STATUS "Using Ragel for the RFC 5322 parser")
 499     ragel_parser(${path_Imap}/Parser/Rfc5322HeaderParser.cpp)
 500     set(libImap_SOURCES ${libImap_SOURCES}
 501         ${CMAKE_CURRENT_BINARY_DIR}/Rfc5322HeaderParser.generated.cpp)
 502 else()
 503     message(STATUS "Using pregenerated RFC 5322 parser")
 504     set(libImap_SOURCES ${libImap_SOURCES}
 505         ${path_Imap}/Parser/Rfc5322HeaderParser.generated.cpp)
 506 endif()
 507
 508 set(trojita_desktop_SOURCES
 509     ${path_DesktopGui}/main.cpp
 510 )
 511
 512 if(WIN32)
 513     list(APPEND trojita_desktop_SOURCES ${CMAKE_CURRENT_SOURCE_DIR}/src/trojita_win32.rc)
 514     set_property(SOURCE ${CMAKE_CURRENT_SOURCE_DIR}/src/trojita_win32.rc APPEND PROPERTY OBJECT_DEPENDS
 515         ${CMAKE_CURRENT_SOURCE_DIR}/src/icons/trojita.ico
 516         ${CMAKE_CURRENT_BINARY_DIR}/trojita-git-version.h
 517         ${CMAKE_CURRENT_BINARY_DIR}/trojita-version.h
 518     )
 519 endif()
 520
 521 if(Qt5LinguistForTrojita_FOUND)
 522     file(GLOB_RECURSE lang_PO "${CMAKE_CURRENT_SOURCE_DIR}/po/trojita_common_*.po")
 523     qt5_wrap_po(trojita_QM ${lang_PO})
 524     set(language_summary "")
 525     foreach(po ${lang_PO})
 526         string(REGEX REPLACE "^(.*)/trojita_common_(.*).po" "\\2" lang ${po})
 527         list(APPEND language_summary ${lang})
 528     endforeach()
 529     list(SORT language_summary)
 530     list(LENGTH language_summary num_languages)
 531     if(num_languages)
 532         message(STATUS "Available languages: ${language_summary}")
 533         if(WITH_DESKTOP)
 534             install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/locale/ DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/trojita/locale" REGEX "(x_test)|(.*\\.ts)" EXCLUDE)
 535         endif()
 536     else()
 537         message(STATUS "No .po files found, will not install any languages")
 538     endif()
 539 else()
 540     message(STATUS "Qt Linguist (lupdate/lrelease/lconvert) not found, disabling localization support")
 541 endif()
 542
 543 set(version_files ${CMAKE_CURRENT_BINARY_DIR}/trojita-version.h ${CMAKE_CURRENT_BINARY_DIR}/trojita-git-version.h)
 544 if(WITH_NSIS)
 545     set(version_files ${version_files} ${CMAKE_CURRENT_BINARY_DIR}/trojita-version.nsi)
 546     set(NSIS TRUE)
 547 endif()
 548
 549 add_custom_target(version DEPENDS version_fake_file)
 550 add_custom_command(OUTPUT version_fake_file ${version_files}
 551     COMMAND ${CMAKE_COMMAND} -DGIT_EXECUTABLE=${GIT_EXECUTABLE} -DNSIS=${NSIS} -DHOST_ARCH=${HOST_ARCH} -DSOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/TrojitaVersion.cmake)
 552 set_source_files_properties(${version_files}
 553     PROPERTIES GENERATED TRUE
 554     HEADER_FILE_ONLY TRUE)
 555
 556 add_library(Common STATIC ${libCommon_SOURCES})
 557 set_property(TARGET Common APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 558 add_dependencies(Common version)
 559 target_link_libraries(Common Qt5::Network)
 560
 561 add_library(AppVersion STATIC ${libAppVersion_SOURCES})
 562 set_property(TARGET AppVersion APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 563 add_dependencies(AppVersion version)
 564 target_link_libraries(AppVersion Common)
 565 target_link_libraries(AppVersion Qt5::Core)
 566
 567 if(WITH_SHARED_PLUGINS)
 568     add_library(Plugins SHARED ${libPlugins_SOURCES})
 569     set_property(TARGET Plugins APPEND PROPERTY COMPILE_DEFINITIONS BUILDING_LIBTROJITA_PLUGINS)
 570 else()
 571     add_library(Plugins STATIC ${libPlugins_SOURCES})
 572     set_property(TARGET Plugins APPEND PROPERTY COMPILE_DEFINITIONS QT_STATICPLUGIN)
 573 endif()
 574 set_target_properties(Plugins PROPERTIES OUTPUT_NAME trojita_plugins)
 575 set_property(TARGET Plugins APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 576 target_link_libraries(Plugins Qt5::Core)
 577
 578 add_library(UiUtils STATIC ${libUiUtils_SOURCES})
 579 set_property(TARGET UiUtils APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 580 target_link_libraries(UiUtils Plugins Common Qt5::Gui)
 581
 582 add_library(Streams STATIC ${libStreams_SOURCES})
 583 set_property(TARGET Streams APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 584 if(WITH_ZLIB)
 585     set_property(TARGET Streams APPEND PROPERTY INCLUDE_DIRECTORIES ${ZLIB_INCLUDE_DIR})
 586     target_link_libraries(Streams ${ZLIB_LIBRARIES})
 587 endif()
 588 target_link_libraries(Streams Qt5::Network)
 589
 590 add_library(IPC STATIC ${libIPC_SOURCES})
 591 set_property(TARGET IPC APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 592 if(WITH_DBUS)
 593     target_link_libraries(IPC Qt5::DBus Qt5::Widgets)
 594 else()
 595     target_link_libraries(IPC Qt5::Core)
 596 endif()
 597
 598 add_library(qwwsmtpclient STATIC ${libqwwsmtpclient_SOURCES})
 599 target_link_libraries(qwwsmtpclient Qt5::Network)
 600
 601 add_library(MSA STATIC ${libMSA_SOURCES})
 602 set_property(TARGET MSA APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 603 target_link_libraries(MSA Imap Streams qwwsmtpclient)
 604
 605 add_library(Composer STATIC ${libComposer_SOURCES})
 606 set_property(TARGET Composer APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 607 target_link_libraries(Composer Common MSA Streams UiUtils qwwsmtpclient)
 608
 609 add_library(Imap STATIC ${libImap_SOURCES})
 610 set_property(TARGET Imap APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 611 target_link_libraries(Imap Common Streams UiUtils Qt5::Sql)
 612
 613 add_library(Cryptography STATIC ${libCryptography_SOURCES})
 614 set_property(TARGET Cryptography APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 615 target_link_libraries(Cryptography Common Imap)
 616 if(WITH_MIMETIC)
 617     target_link_libraries(Cryptography ${MIMETIC_LIBRARIES})
 618     set_property(TARGET Cryptography APPEND PROPERTY INCLUDE_DIRECTORIES ${MIMETIC_INCLUDE_DIRS})
 619 endif()
 620 if(WITH_CRYPTO_MESSAGES)
 621     if(WITH_GPGMEPP)
 622         target_link_libraries(Cryptography Gpgmepp QGpgme)
 623     elseif(WITH_KF5_GPGMEPP)
 624         if(WIN32)
 625             target_link_libraries(Cryptography KF5::Gpgmepp KF5::QGpgme)
 626         else()
 627             target_link_libraries(Cryptography KF5::Gpgmepp-pthread KF5::QGpgme)
 628         endif()
 629     endif()
 630 endif()
 631
 632 ## ClearText password plugin
 633 if(WITH_CLEARTEXT_PLUGIN)
 634     trojita_add_plugin(trojita_plugin_ClearTextPasswordPlugin WITH_CLEARTEXT_PLUGIN src/Plugins/ClearTextPassword/ClearTextPassword.cpp)
 635 endif()
 636
 637 ## QtKeyChain plugin
 638 if(WITH_QTKEYCHAIN_PLUGIN)
 639     trojita_add_plugin(trojita_plugin_QtKeychainPasswordPlugin WITH_QTKEYCHAIN_PLUGIN src/Plugins/QtKeyChain/QtKeyChainPassword.cpp)
 640     target_link_libraries(trojita_plugin_QtKeychainPasswordPlugin ${QTKEYCHAIN_LIBRARIES} Qt5::DBus)
 641     set_property(TARGET trojita_plugin_QtKeychainPasswordPlugin APPEND PROPERTY INCLUDE_DIRECTORIES ${QTKEYCHAIN_INCLUDE_DIRS})
 642 endif()
 643
 644 ## AbookAddressbook plugin
 645 if(WITH_ABOOKADDRESSBOOK_PLUGIN)
 646     set(path_AbookAddressbook ${CMAKE_CURRENT_SOURCE_DIR}/src/Plugins/AbookAddressbook)
 647     set(libAbookAddressbook_HEADERS
 648         ${path_AbookAddressbook}/AbookAddressbook.h
 649         ${path_AbookAddressbook}/be-contacts.h
 650     )
 651     set(libAbookAddressbook_SOURCES
 652         ${path_AbookAddressbook}/AbookAddressbook.cpp
 653         ${path_AbookAddressbook}/be-contacts.cpp
 654     )
 655     set(libAbookAddressbook_UI
 656         ${path_AbookAddressbook}/be-contacts.ui
 657         ${path_AbookAddressbook}/onecontact.ui
 658     )
 659
 660     qt5_wrap_ui(libAbookAddressbook_UI_OUT ${libAbookAddressbook_UI})
 661
 662     trojita_add_plugin(trojita_plugin_AbookAddressbookPlugin WITH_ABOOKADDRESSBOOK_PLUGIN ${libAbookAddressbook_SOURCES} ${libAbookAddressbook_UI_OUT})
 663     set_property(TARGET trojita_plugin_AbookAddressbookPlugin APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 664
 665     target_link_libraries(trojita_plugin_AbookAddressbookPlugin Qt5::Widgets)
 666
 667     set(be_contacts_SOURCES
 668         ${path_AbookAddressbook}/main.cpp
 669     )
 670
 671     add_executable(be.contacts WIN32 ${be_contacts_SOURCES})
 672     set_property(TARGET be.contacts APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 673     target_link_libraries(be.contacts Plugins)
 674     if("${WITH_ABOOKADDRESSBOOK_PLUGIN}" STREQUAL "STATIC")
 675         set_property(TARGET be.contacts APPEND PROPERTY COMPILE_DEFINITIONS QT_STATICPLUGIN)
 676         target_link_libraries(be.contacts trojita_plugin_AbookAddressbookPlugin)
 677     endif()
 678     target_link_libraries(be.contacts Qt5::Widgets)
 679 endif()
 680
 681 # Generate file static_plugins.h.in
 682 get_property(STATIC_PLUGINS GLOBAL PROPERTY TROJITA_STATIC_PLUGINS)
 683 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h.in "#include <QtPlugin>\n")
 684 foreach(PLUGIN ${STATIC_PLUGINS})
 685     file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h.in "Q_IMPORT_PLUGIN(${PLUGIN})\n")
 686 endforeach()
 687 execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h.in ${CMAKE_CURRENT_BINARY_DIR}/static_plugins.h)
 688
 689 if(WITH_DESKTOP)
 690     qt5_wrap_ui(libDesktopGui_UI_OUT ${libDesktopGui_UI})
 691     qt5_add_resources(libDesktopGui_RESOURCES_OUT ${libDesktopGui_RESOURCES})
 692
 693     add_library(DesktopGui STATIC ${libDesktopGui_SOURCES} ${libDesktopGui_UI_OUT} ${libDesktopGui_RESOURCES_OUT})
 694     set_property(TARGET DesktopGui APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 695     # The following is needed for the LineEdit widget within the .ui files.
 696     # The ${path_DesktopGui} is needed so that the generated ui_*.h file can find the headers of the custom widgets
 697     set_property(TARGET DesktopGui APPEND PROPERTY INCLUDE_DIRECTORIES ${path_DesktopGui})
 698     target_link_libraries(DesktopGui Common UiUtils Composer Cryptography Imap IPC MSA Plugins Streams qwwsmtpclient Qt5::WebKitWidgets)
 699
 700     # On Windows build a real Win32 GUI application without console window
 701     # On other platforms WIN32 flag is ignored
 702     add_executable(trojita WIN32 ${trojita_desktop_SOURCES} ${trojita_QM})
 703     set_property(TARGET trojita APPEND PROPERTY COMPILE_DEFINITIONS QT_NO_CAST_FROM_ASCII QT_NO_CAST_TO_ASCII)
 704     target_link_libraries(trojita AppVersion Common UiUtils DesktopGui ${STATIC_PLUGINS})
 705 endif()
 706
 707
 708 if(WITH_SHARED_PLUGINS)
 709     install(TARGETS Plugins DESTINATION ${CMAKE_INSTALL_LIBDIR})
 710 endif()
 711
 712 include(SanitizedDesktopFile)
 713
 714 if(WITH_ABOOKADDRESSBOOK_PLUGIN)
 715     install(TARGETS be.contacts RUNTIME DESTINATION bin)
 716 endif()
 717
 718 if(WITH_DESKTOP)
 719     copy_desktop_file_without_cruft("${CMAKE_CURRENT_SOURCE_DIR}/src/Gui/org.kde.trojita.desktop" "${CMAKE_CURRENT_BINARY_DIR}/org.kde.trojita-DesktopGui.desktop")
 720     install(TARGETS trojita RUNTIME DESTINATION bin)
 721     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/org.kde.trojita-DesktopGui.desktop DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/applications/" RENAME org.kde.trojita.desktop)
 722     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/Gui/org.kde.trojita.appdata.xml DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/metainfo/")
 723     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/icons/trojita.png DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/32x32/apps/")
 724     install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/src/icons/trojita.svg DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/scalable/apps/")
 725 endif()
 726
 727 if(WITH_NSIS)
 728     include(TrojitaNSIS)
 729 endif()
 730
 731
 732 if(BUILD_TESTING)
 733     set(test_LibMailboxSync_SOURCES
 734         tests/Utils/ModelEvents.cpp
 735         tests/Utils/LibMailboxSync.cpp
 736     )
 737     add_library(test_LibMailboxSync STATIC ${test_LibMailboxSync_SOURCES})
 738     set_property(TARGET test_LibMailboxSync APPEND PROPERTY INCLUDE_DIRECTORIES
 739         ${CMAKE_CURRENT_SOURCE_DIR}/tests
 740         ${CMAKE_CURRENT_SOURCE_DIR}/tests/Utils)
 741     target_link_libraries(test_LibMailboxSync Imap MSA Streams Common Composer Qt5::Test)
 742
 743     macro(trojita_test dir fname)
 744         set(test_${fname}_SOURCES tests/${dir}/test_${fname}.cpp)
 745         add_executable(test_${fname} ${test_${fname}_SOURCES})
 746         target_link_libraries(test_${fname} Imap MSA Streams Common Composer Cryptography test_LibMailboxSync)
 747         set_property(TARGET test_${fname} APPEND PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_SOURCE_DIR}/tests)
 748         if(NOT CMAKE_CROSSCOMPILING)
 749             add_test(test_${fname} test_${fname})
 750         endif()
 751     endmacro()
 752
 753     set(UBSAN_ENV_SUPPRESSIONS "UBSAN_OPTIONS=suppressions=${CMAKE_CURRENT_SOURCE_DIR}/tests/ubsan.supp")
 754
 755     enable_testing()
 756     trojita_test(Composer Composer_Submission)
 757     trojita_test(Composer Composer_responses)
 758     target_link_libraries(test_Composer_responses Qt5::WebKitWidgets)
 759     trojita_test(Composer Html_formatting)
 760     target_link_libraries(test_Html_formatting Qt5::WebKitWidgets)
 761     trojita_test(Imap Imap_DisappearingMailboxes)
 762     trojita_test(Imap Imap_Idle)
 763     trojita_test(Imap Imap_LowLevelParser)
 764     trojita_test(Imap Imap_Message)
 765     trojita_test(Imap Imap_Model)
 766     trojita_test(Imap Imap_MsgPartNetAccessManager)
 767     set_property(TEST test_Imap_MsgPartNetAccessManager PROPERTY ENVIRONMENT "${UBSAN_ENV_SUPPRESSIONS}")
 768     trojita_test(Imap Imap_Parser_parse)
 769     trojita_test(Imap Imap_Parser_write)
 770     trojita_test(Imap Imap_Responses)
 771     trojita_test(Imap Imap_SelectedMailboxUpdates)
 772     trojita_test(Imap Imap_Tasks_CreateMailbox)
 773     trojita_test(Imap Imap_Tasks_DeleteMailbox)
 774     trojita_test(Imap Imap_Tasks_ListChildMailboxes)
 775     trojita_test(Imap Imap_Tasks_ObtainSynchronizedMailbox)
 776     trojita_test(Imap Imap_Tasks_OpenConnection)
 777     trojita_test(Imap Imap_Threading)
 778     trojita_test(Imap Imap_BodyParts)
 779     trojita_test(Imap Imap_Offline)
 780     trojita_test(Imap Imap_CopyAndFlagOperations)
 781     trojita_test(Cryptography Cryptography_MessageModel)
 782
 783     if(WITH_CRYPTO_MESSAGES)
 784       find_program(GPGCONF_BINARY NAMES gpgconf)
 785       if(GPGCONF_BINARY_NOTFOUND)
 786         message(SEND_ERROR "The `gpgconf` binary from GnuPG not found, this is needed for crypto tests.")
 787       endif()
 788
 789       if(NOT UNIX)
 790         message(SEND_ERROR "The Cryptography unit tests really need Unix. Patches welcome.")
 791       endif()
 792
 793       add_library(fake-dev-random SHARED ${CMAKE_CURRENT_SOURCE_DIR}/tests/Utils/fake-dev-random.c)
 794       set_target_properties(fake-dev-random PROPERTIES AUTOMOC off)
 795       target_link_libraries(fake-dev-random dl)
 796
 797       # FIXME: it would be nice to depend on the contents of keys/, but in my testing it produces Makefiles
 798       # which suffer from races (the keygen.sh is run multiple times in parallel within the CI environment).
 799       # I wasn't able to track down the root cause behind this; it affected all cmake versions within the CI
 800       # as of Feb 2016, which is 3.1.something up to 3.3.something.
 801       add_custom_command(OUTPUT crypto_test_data.h
 802         COMMAND bash ${CMAKE_CURRENT_SOURCE_DIR}/tests/Cryptography/keygen.sh ${CMAKE_CURRENT_SOURCE_DIR}
 803         DEPENDS fake-dev-random tests/Cryptography/keygen.sh tests/Cryptography/batch-keygen)
 804       add_custom_target(crypto_test_data DEPENDS crypto_test_data.h)
 805
 806       trojita_test(Cryptography Cryptography_PGP)
 807       set_property(TEST test_Cryptography_PGP PROPERTY ENVIRONMENT "${UBSAN_ENV_SUPPRESSIONS}")
 808       add_dependencies(test_Cryptography_PGP crypto_test_data)
 809     endif()
 810
 811     trojita_test(Misc Rfc5322)
 812     trojita_test(Misc RingBuffer)
 813     trojita_test(Misc SenderIdentitiesModel)
 814     trojita_test(Misc SqlCache)
 815     trojita_test(Misc algorithms)
 816     trojita_test(Misc rfccodecs)
 817     trojita_test(Misc prettySize)
 818     trojita_test(Misc Formatting)
 819
 820 endif()
 821
 822 if(WIN32) # Check if we are on Windows
 823     if(MSVC10) # Check if we are using the Visual Studio compiler 2010
 824         # Because of linker errors (see http://stackoverflow.com/questions/5625884/conversion-of-stdwstring-to-qstring-throws-linker-error)
 825         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Zc:wchar_t-")
 826     elseif(MINGW)
 827     else()
 828         message(WARNING "You are using a compiler which we have not tested yet (not MSVC10 or MINGW).")
 829         message(WARNING "Please let us know how well it works.")
 830     endif()
 831 endif()