configure.in

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.2.9-alpha-dev)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13   if test -f /usr/kerberos/include ; then
  14     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  15   fi
  16 fi
  17
  18 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  19 # the += operator on it in src/or/Makefile.am
  20 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  21
  22 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  23 AC_ARG_ENABLE(buf-freelists,
  24    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  25 AC_ARG_ENABLE(openbsd-malloc,
  26    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  27 AC_ARG_ENABLE(instrument-downloads,
  28    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  29 AC_ARG_ENABLE(static-openssl,
  30    AS_HELP_STRING(--enable-static-openssl, Link against a static openssl library. Requires --with-openssl-dir))
  31 AC_ARG_ENABLE(static-libevent,
  32    AS_HELP_STRING(--enable-static-libevent, Link against a static libevent library. Requires --with-libevent-dir))
  33
  34 if test x$enable_buf_freelists != xno; then
  35   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  36             [Defined if we try to use freelists for buffer RAM chunks])
  37 fi
  38 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  39 if test x$enable_instrument_downloads = xyes; then
  40   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  41             [Defined if we want to keep track of how much of each kind of resource we download.])
  42 fi
  43
  44 AC_ARG_ENABLE(transparent,
  45      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  46      [case "${enableval}" in
  47         yes) transparent=true ;;
  48         no)  transparent=false ;;
  49         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  50       esac], [transparent=true])
  51
  52 AC_ARG_ENABLE(threads,
  53      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  54
  55 if test x$enable_threads = x; then
  56    case $host in
  57     *-*-solaris* )
  58      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  59      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  60 cpu workers lock up here, so I will disable threads.])
  61      enable_threads="no";;
  62     *)
  63      enable_threads="yes";;
  64    esac
  65 fi
  66
  67 if test "$enable_threads" = "yes"; then
  68   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  69 fi
  70
  71 case $host in
  72    *-*-solaris* )
  73      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  74      ;;
  75 esac
  76
  77 AC_ARG_ENABLE(gcc-warnings,
  78      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  79 AC_ARG_ENABLE(gcc-warnings-advisory,
  80      AS_HELP_STRING(--enable-gcc-warnings-advisory, [enable verbose warnings, excluding -Werror]))
  81
  82 AC_ARG_ENABLE(local-appdata,
  83    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
  84 if test "$enable_local_appdata" = "yes"; then
  85   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
  86             [Defined if we default to host local appdata paths on Windows])
  87 fi
  88
  89 AC_PROG_CC
  90 AC_PROG_CPP
  91 AC_PROG_MAKE_SET
  92 AC_PROG_RANLIB
  93
  94 dnl autoconf 2.59 appears not to support AC_PROG_SED
  95 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
  96
  97 dnl check for asciidoc and a2x
  98 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
  99 AC_PATH_PROG([A2X], [a2x], none)
 100
 101 AC_PATH_PROG([SHA1SUM], [sha1sum], none)
 102 AC_PATH_PROG([OPENSSL], [openssl], none)
 103
 104 TORUSER=_tor
 105 AC_ARG_WITH(tor-user,
 106         [  --with-tor-user=NAME    Specify username for tor daemon ],
 107         [
 108            TORUSER=$withval
 109         ]
 110 )
 111 AC_SUBST(TORUSER)
 112
 113 TORGROUP=_tor
 114 AC_ARG_WITH(tor-group,
 115         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 116         [
 117            TORGROUP=$withval
 118         ]
 119 )
 120 AC_SUBST(TORGROUP)
 121
 122
 123 dnl If WIN32 is defined and non-zero, we are building for win32
 124 AC_MSG_CHECKING([for win32])
 125 AC_RUN_IFELSE([
 126 int main(int c, char **v) {
 127 #ifdef WIN32
 128 #if WIN32
 129   return 0;
 130 #else
 131   return 1;
 132 #endif
 133 #else
 134   return 2;
 135 #endif
 136 }],
 137 bwin32=true; AC_MSG_RESULT([yes]),
 138 bwin32=false; AC_MSG_RESULT([no]),
 139 bwin32=cross; AC_MSG_RESULT([cross])
 140 )
 141
 142 if test "$bwin32" = cross; then
 143 AC_MSG_CHECKING([for win32 (cross)])
 144 AC_COMPILE_IFELSE([
 145 #ifdef WIN32
 146 int main(int c, char **v) {return 0;}
 147 #else
 148 #error
 149 int main(int c, char **v) {return x(y);}
 150 #endif
 151 ],
 152 bwin32=true; AC_MSG_RESULT([yes]),
 153 bwin32=false; AC_MSG_RESULT([no]))
 154 fi
 155
 156 if test "$bwin32" = true; then
 157 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 158 fi
 159 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 160
 161 dnl Enable C99 when compiling with MIPSpro
 162 AC_MSG_CHECKING([for MIPSpro compiler])
 163 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 164 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 165 #error
 166   return x(y);
 167 #endif
 168 ]),
 169 bmipspro=false; AC_MSG_RESULT(no),
 170 bmipspro=true; AC_MSG_RESULT(yes))
 171
 172 if test "$bmipspro" = true; then
 173   CFLAGS="$CFLAGS -c99"
 174 fi
 175
 176 AC_C_BIGENDIAN
 177
 178 AC_SEARCH_LIBS(socket, [socket])
 179 AC_SEARCH_LIBS(gethostbyname, [nsl])
 180 AC_SEARCH_LIBS(dlopen, [dl])
 181 AC_SEARCH_LIBS(inet_aton, [resolv])
 182
 183 if test "$enable_threads" = "yes"; then
 184   AC_SEARCH_LIBS(pthread_create, [pthread])
 185   AC_SEARCH_LIBS(pthread_detach, [pthread])
 186 fi
 187
 188 dnl -------------------------------------------------------------------
 189 dnl Check for functions before libevent, since libevent-1.2 apparently
 190 dnl exports strlcpy without defining it in a header.
 191
 192 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull getaddrinfo localtime_r gmtime_r memmem strtok_r writev readv flock prctl)
 193
 194 using_custom_malloc=no
 195 if test x$enable_openbsd_malloc = xyes ; then
 196    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 197    using_custom_malloc=yes
 198 fi
 199 if test x$tcmalloc = xyes ; then
 200    using_custom_malloc=yes
 201 fi
 202 if test $using_custom_malloc = no ; then
 203    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 204 fi
 205
 206 if test "$enable_threads" = "yes"; then
 207   AC_CHECK_HEADERS(pthread.h)
 208   AC_CHECK_FUNCS(pthread_create)
 209 fi
 210
 211 dnl ------------------------------------------------------
 212 dnl Where do you live, libevent?  And how do we call you?
 213
 214 if test "$bwin32" = true; then
 215   TOR_LIB_WS32=-lws2_32
 216   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 217   # think it's actually necessary.
 218   TOR_LIB_GDI=-lgdi32
 219 else
 220   TOR_LIB_WS32=
 221   TOR_LIB_GDI=
 222 fi
 223 AC_SUBST(TOR_LIB_WS32)
 224 AC_SUBST(TOR_LIB_GDI)
 225
 226 dnl We need to do this before we try our disgusting hack below.
 227 AC_CHECK_HEADERS([sys/types.h])
 228
 229 dnl This is a disgusting hack so we safely include older libevent headers.
 230 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 231 AC_CHECK_TYPE(u_int32_t, unsigned long)
 232 AC_CHECK_TYPE(u_int16_t, unsigned short)
 233 AC_CHECK_TYPE(u_int8_t, unsigned char)
 234
 235 tor_libevent_pkg_redhat="libevent"
 236 tor_libevent_pkg_debian="libevent-dev"
 237 tor_libevent_devpkg_redhat="libevent-devel"
 238 tor_libevent_devpkg_debian="libevent-dev"
 239
 240 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 241 #ifdef WIN32
 242 #include <winsock2.h>
 243 #endif
 244 #include <stdlib.h>
 245 #include <sys/time.h>
 246 #include <sys/types.h>
 247 #include <event.h>], [
 248 #ifdef WIN32
 249 #include <winsock2.h>
 250 #endif
 251 void exit(int); void *event_init(void);],
 252     [
 253 #ifdef WIN32
 254 {WSADATA d; WSAStartup(0x101,&d); }
 255 #endif
 256 event_init(); exit(0);
 257 ], [--with-libevent-dir], [/opt/libevent])
 258
 259 dnl Now check for particular libevent functions.
 260 save_LIBS="$LIBS"
 261 save_LDFLAGS="$LDFLAGS"
 262 save_CPPFLAGS="$CPPFLAGS"
 263 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 264 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 265 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 266 AC_CHECK_FUNCS(event_get_version event_get_version_number event_get_method event_set_log_callback evdns_set_outgoing_bind_address event_base_loopexit)
 267 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 268 [#include <event.h>
 269 ])
 270
 271 AC_CHECK_HEADERS(event2/event.h event2/dns.h)
 272
 273 LIBS="$save_LIBS"
 274 LDFLAGS="$save_LDFLAGS"
 275 CPPFLAGS="$save_CPPFLAGS"
 276
 277
 278 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 279
 280 if test "$enable_static_libevent" = "yes"; then
 281    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 282      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 283    else
 284      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a"
 285    fi
 286 else
 287      TOR_LIBEVENT_LIBS="-levent"
 288 fi
 289 AC_SUBST(TOR_LIBEVENT_LIBS)
 290
 291
 292 dnl ------------------------------------------------------
 293 dnl Where do you live, openssl?  And how do we call you?
 294
 295 tor_openssl_pkg_redhat="openssl"
 296 tor_openssl_pkg_debian="libssl"
 297 tor_openssl_devpkg_redhat="openssl-devel"
 298 tor_openssl_devpkg_debian="libssl-dev"
 299
 300 ALT_openssl_WITHVAL=""
 301 AC_ARG_WITH(ssl-dir,
 302   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 303   [
 304       if test "x$withval" != xno && test "x$withval" != "x" ; then
 305          ALT_openssl_WITHVAL="$withval"
 306       fi
 307   ])
 308
 309 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 310     [#include <openssl/rand.h>],
 311     [void RAND_add(const void *buf, int num, double entropy);],
 312     [RAND_add((void*)0,0,0); exit(0);], [],
 313     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 314
 315 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 316
 317 echo "tor_cv_library_openssl_dir is $tor_cv_library_openssl_dir"
 318 if test "$enable_static_openssl" = "yes"; then
 319    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 320      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 321    else
 322      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 323    fi
 324 else
 325      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 326 fi
 327 AC_SUBST(TOR_OPENSSL_LIBS)
 328
 329 dnl ------------------------------------------------------
 330 dnl Where do you live, zlib?  And how do we call you?
 331
 332 tor_openssl_pkg_redhat="zlib"
 333 tor_openssl_pkg_debian="zlib1g"
 334 tor_openssl_devpkg_redhat="zlib-devel"
 335 tor_openssl_devpkg_debian="zlib1g-dev"
 336
 337 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 338     [#include <zlib.h>],
 339     [const char * zlibVersion(void);],
 340     [zlibVersion(); exit(0);], [--with-zlib-dir],
 341     [/opt/zlib])
 342
 343 dnl Make sure to enable support for large off_t if available.
 344
 345 AC_SYS_LARGEFILE
 346
 347 AC_CHECK_HEADERS(unistd.h string.h signal.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 348
 349 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 350
 351 dnl These headers are not essential
 352
 353 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h sys/file.h malloc_np.h sys/prctl.h)
 354
 355 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 356 [#ifdef HAVE_MALLOC_H
 357 #include <malloc.h>
 358 #endif
 359 #ifdef HAVE_MALLOC_MALLOC_H
 360 #include <malloc/malloc.h>
 361 #endif])
 362
 363 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 364 [#ifdef HAVE_SYS_TYPES_H
 365 #include <sys/types.h>
 366 #endif
 367 #ifdef HAVE_SYS_SOCKET_H
 368 #include <sys/socket.h>
 369 #endif])
 370 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 371 [#ifdef HAVE_SYS_TYPES_H
 372 #include <sys/types.h>
 373 #endif
 374 #ifdef HAVE_SYS_SOCKET_H
 375 #include <sys/socket.h>
 376 #endif
 377 #ifdef HAVE_NET_IF_H
 378 #include <net/if.h>
 379 #endif])
 380 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 381         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 382 [#ifdef HAVE_SYS_TYPES_H
 383 #include <sys/types.h>
 384 #endif
 385 #ifdef HAVE_SYS_SOCKET_H
 386 #include <sys/socket.h>
 387 #endif
 388 #ifdef HAVE_LIMITS_H
 389 #include <limits.h>
 390 #endif
 391 #ifdef HAVE_LINUX_TYPES_H
 392 #include <linux/types.h>
 393 #endif
 394 #ifdef HAVE_NETINET_IN6_H
 395 #include <netinet/in6.h>
 396 #endif
 397 #ifdef HAVE_NETINET_IN_H
 398 #include <netinet/in.h>
 399 #endif])
 400
 401 if test x$transparent = xtrue ; then
 402    transparent_ok=0
 403    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 404      transparent_ok=1
 405    fi
 406    if test x$linux_netfilter_ipv4 = x1 ; then
 407      transparent_ok=1
 408    fi
 409    if test x$transparent_ok = x1 ; then
 410      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 411      case $host in
 412        *-*-openbsd*)
 413          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 414      esac
 415    else
 416      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 417    fi
 418 fi
 419
 420 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 421 [#ifdef HAVE_SYS_TYPES_H
 422 #include <sys/types.h>
 423 #endif
 424 #ifdef HAVE_SYS_TIME_H
 425 #include <sys/time.h>
 426 #endif])
 427
 428 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 429 dnl Watch out.
 430
 431 AC_CHECK_SIZEOF(int8_t)
 432 AC_CHECK_SIZEOF(int16_t)
 433 AC_CHECK_SIZEOF(int32_t)
 434 AC_CHECK_SIZEOF(int64_t)
 435 AC_CHECK_SIZEOF(uint8_t)
 436 AC_CHECK_SIZEOF(uint16_t)
 437 AC_CHECK_SIZEOF(uint32_t)
 438 AC_CHECK_SIZEOF(uint64_t)
 439 AC_CHECK_SIZEOF(intptr_t)
 440 AC_CHECK_SIZEOF(uintptr_t)
 441
 442 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 443
 444 AC_CHECK_SIZEOF(char)
 445 AC_CHECK_SIZEOF(short)
 446 AC_CHECK_SIZEOF(int)
 447 AC_CHECK_SIZEOF(long)
 448 AC_CHECK_SIZEOF(long long)
 449 AC_CHECK_SIZEOF(__int64)
 450 AC_CHECK_SIZEOF(void *)
 451 AC_CHECK_SIZEOF(time_t)
 452 AC_CHECK_SIZEOF(size_t)
 453
 454 AC_CHECK_TYPES([uint, u_char, ssize_t])
 455
 456 dnl used to include sockaddr_storage, but everybody has that.
 457 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 458 [#ifdef HAVE_SYS_TYPES_H
 459 #include <sys/types.h>
 460 #endif
 461 #ifdef HAVE_NETINET_IN_H
 462 #include <netinet/in.h>
 463 #endif
 464 #ifdef HAVE_NETINET_IN6_H
 465 #include <netinet/in6.h>
 466 #endif
 467 #ifdef HAVE_SYS_SOCKET_H
 468 #include <sys/socket.h>
 469 #endif
 470 #ifdef MS_WINDOWS
 471 #define WIN32_WINNT 0x400
 472 #define _WIN32_WINNT 0x400
 473 #define WIN32_LEAN_AND_MEAN
 474 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 475 #include <winsock.h>
 476 #else
 477 #include <winsock2.h>
 478 #include <ws2tcpip.h>
 479 #endif
 480 #endif
 481 ])
 482 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 483 [#ifdef HAVE_SYS_TYPES_H
 484 #include <sys/types.h>
 485 #endif
 486 #ifdef HAVE_NETINET_IN_H
 487 #include <netinet/in.h>
 488 #endif
 489 #ifdef HAVE_NETINET_IN6_H
 490 #include <netinet/in6.h>
 491 #endif
 492 #ifdef HAVE_SYS_SOCKET_H
 493 #include <sys/socket.h>
 494 #endif
 495 #ifdef MS_WINDOWS
 496 #define WIN32_WINNT 0x400
 497 #define _WIN32_WINNT 0x400
 498 #define WIN32_LEAN_AND_MEAN
 499 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 500 #include <winsock.h>
 501 #else
 502 #include <winsock2.h>
 503 #include <ws2tcpip.h>
 504 #endif
 505 #endif
 506 ])
 507
 508 AC_CHECK_TYPES([rlim_t], , ,
 509 [#ifdef HAVE_SYS_TYPES_H
 510 #include <sys/types.h>
 511 #endif
 512 #ifdef HAVE_SYS_TIME_H
 513 #include <sys/time.h>
 514 #endif
 515 #ifdef HAVE_SYS_RESOURCE_H
 516 #include <sys/resource.h>
 517 #endif
 518 ])
 519
 520 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 521 AC_RUN_IFELSE(AC_LANG_SOURCE([
 522 #ifdef HAVE_SYS_TYPES_H
 523 #include <sys/types.h>
 524 #endif
 525 #ifdef HAVE_SYS_TIME_H
 526 #include <sys/time.h>
 527 #endif
 528 #ifdef HAVE_TIME_H
 529 #include <time.h>
 530 #endif
 531 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 532   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 533 ])
 534
 535 if test "$tor_cv_time_t_signed" = cross; then
 536   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 537 fi
 538
 539 if test "$tor_cv_time_t_signed" != no; then
 540   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 541             [Define to 1 iff time_t is signed])
 542 fi
 543
 544 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 545 #ifdef HAVE_SYS_SOCKET_H
 546 #include <sys/socket.h>
 547 #endif
 548 ])
 549
 550 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 551
 552 AC_CHECK_SIZEOF(cell_t)
 553
 554 # Now make sure that NULL can be represented as zero bytes.
 555 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 556 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 557 [[#include <stdlib.h>
 558 #include <string.h>
 559 #include <stdio.h>
 560 #ifdef HAVE_STDDEF_H
 561 #include <stddef.h>
 562 #endif
 563 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 564 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 565        [tor_cv_null_is_zero=yes],
 566        [tor_cv_null_is_zero=no],
 567        [tor_cv_null_is_zero=cross])])
 568
 569 if test "$tor_cv_null_is_zero" = cross ; then
 570   # Cross-compiling; let's hope that the target isn't raving mad.
 571   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 572 fi
 573
 574 if test "$tor_cv_null_is_zero" != no; then
 575   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 576             [Define to 1 iff memset(0) sets pointers to NULL])
 577 fi
 578
 579 # And what happens when we malloc zero?
 580 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 581 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 582 [[#include <stdlib.h>
 583 #include <string.h>
 584 #include <stdio.h>
 585 #ifdef HAVE_STDDEF_H
 586 #include <stddef.h>
 587 #endif
 588 int main () { return malloc(0)?0:1; }]])],
 589        [tor_cv_malloc_zero_works=yes],
 590        [tor_cv_malloc_zero_works=no],
 591        [tor_cv_malloc_zero_works=cross])])
 592
 593 if test "$tor_cv_malloc_zero_works" = cross; then
 594   # Cross-compiling; let's hope that the target isn't raving mad.
 595   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 596 fi
 597
 598 if test "$tor_cv_malloc_zero_works" = yes; then
 599   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 600             [Define to 1 iff malloc(0) returns a pointer])
 601 fi
 602
 603 # whether we seem to be in a 2s-complement world.
 604 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 605 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 606 [[int main () { int problem = ((-99) != (~99)+1);
 607 return problem ? 1 : 0; }]])],
 608        [tor_cv_twos_complement=yes],
 609        [tor_cv_twos_complement=no],
 610        [tor_cv_twos_complement=cross])])
 611
 612 if test "$tor_cv_twos_complement" = cross ; then
 613   # Cross-compiling; let's hope that the target isn't raving mad.
 614   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 615 fi
 616
 617 if test "$tor_cv_twos_complement" != no ; then
 618   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 619             [Define to 1 iff we represent negative integers with two's complement])
 620 fi
 621
 622 # Whether we should use the dmalloc memory allocation debugging library.
 623 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 624 AC_ARG_WITH(dmalloc,
 625 [  --with-dmalloc          Use debug memory allocation library. ],
 626 [if [[ "$withval" = "yes" ]]; then
 627   dmalloc=1
 628   AC_MSG_RESULT(yes)
 629 else
 630   dmalloc=1
 631   AC_MSG_RESULT(no)
 632 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 633 )
 634
 635 if [[ $dmalloc -eq 1 ]]; then
 636   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 637   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 638   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 639   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 640   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 641 fi
 642
 643 AC_ARG_WITH(tcmalloc,
 644 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 645 [ tcmalloc=yes ], [ tcmalloc=no ])
 646
 647 if test x$tcmalloc = xyes ; then
 648    LDFLAGS="-ltcmalloc $LDFLAGS"
 649 fi
 650
 651 # By default, we're going to assume we don't have mlockall()
 652 # bionic and other platforms have various broken mlockall subsystems.
 653 # Some systems don't have a working mlockall, some aren't linkable,
 654 # and some have it but don't declare it.
 655 AC_CHECK_FUNCS(mlockall)
 656 AC_CHECK_DECLS([mlockall], , , [
 657 #ifdef HAVE_SYS_MMAN_H
 658 #include <sys/mman.h>
 659 #endif])
 660
 661 # Allow user to specify an alternate syslog facility
 662 AC_ARG_WITH(syslog-facility,
 663 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 664 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 665 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 666 AC_SUBST(LOGFACILITY)
 667
 668 # Check if we have getresuid and getresgid
 669 AC_CHECK_FUNCS(getresuid getresgid)
 670
 671 # Check for gethostbyname_r in all its glorious incompatible versions.
 672 #   (This logic is based on that in Python's configure.in)
 673 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 674   [Define this if you have any gethostbyname_r()])
 675
 676 AC_CHECK_FUNC(gethostbyname_r, [
 677   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 678   OLD_CFLAGS=$CFLAGS
 679   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 680   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 681 #include <netdb.h>
 682   ], [[
 683     char *cp1, *cp2;
 684     struct hostent *h1, *h2;
 685     int i1, i2;
 686     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 687   ]]),[
 688     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 689     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 690      [Define this if gethostbyname_r takes 6 arguments])
 691     AC_MSG_RESULT(6)
 692   ], [
 693     AC_TRY_COMPILE([
 694 #include <netdb.h>
 695     ], [
 696       char *cp1, *cp2;
 697       struct hostent *h1;
 698       int i1, i2;
 699       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 700     ], [
 701       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 702       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 703         [Define this if gethostbyname_r takes 5 arguments])
 704       AC_MSG_RESULT(5)
 705    ], [
 706       AC_TRY_COMPILE([
 707 #include <netdb.h>
 708      ], [
 709        char *cp1;
 710        struct hostent *h1;
 711        struct hostent_data hd;
 712        (void) gethostbyname_r(cp1,h1,&hd);
 713      ], [
 714        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 715        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 716          [Define this if gethostbyname_r takes 3 arguments])
 717        AC_MSG_RESULT(3)
 718      ], [
 719        AC_MSG_RESULT(0)
 720      ])
 721   ])
 722  ])
 723  CFLAGS=$OLD_CFLAGS
 724 ])
 725
 726 AC_CACHE_CHECK([whether the C compiler supports __func__],
 727   tor_cv_have_func_macro,
 728   AC_COMPILE_IFELSE([
 729 #include <stdio.h>
 730 int main(int c, char **v) { puts(__func__); }],
 731   tor_cv_have_func_macro=yes,
 732   tor_cv_have_func_macro=no))
 733
 734 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 735   tor_cv_have_FUNC_macro,
 736   AC_COMPILE_IFELSE([
 737 #include <stdio.h>
 738 int main(int c, char **v) { puts(__FUNC__); }],
 739   tor_cv_have_FUNC_macro=yes,
 740   tor_cv_have_FUNC_macro=no))
 741
 742 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 743   tor_cv_have_FUNCTION_macro,
 744   AC_COMPILE_IFELSE([
 745 #include <stdio.h>
 746 int main(int c, char **v) { puts(__FUNCTION__); }],
 747   tor_cv_have_FUNCTION_macro=yes,
 748   tor_cv_have_FUNCTION_macro=no))
 749
 750 if test "$tor_cv_have_func_macro" = 'yes'; then
 751   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 752 fi
 753
 754 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 755   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 756 fi
 757
 758 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 759   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 760            [Defined if the compiler supports __FUNCTION__])
 761 fi
 762
 763 # $prefix stores the value of the --prefix command line option, or
 764 # NONE if the option wasn't set.  In the case that it wasn't set, make
 765 # it be the default, so that we can use it to expand directories now.
 766 if test "x$prefix" = "xNONE"; then
 767   prefix=$ac_default_prefix
 768 fi
 769
 770 # and similarly for $exec_prefix
 771 if test "x$exec_prefix" = "xNONE"; then
 772   exec_prefix=$prefix
 773 fi
 774
 775 if test "x$CONFDIR" = "x"; then
 776   CONFDIR=`eval echo $sysconfdir/tor`
 777 fi
 778 AC_SUBST(CONFDIR)
 779 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 780 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 781
 782 BINDIR=`eval echo $bindir`
 783 AC_SUBST(BINDIR)
 784 LOCALSTATEDIR=`eval echo $localstatedir`
 785 AC_SUBST(LOCALSTATEDIR)
 786
 787 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 788 # than autoconf's macros like.
 789 if test "$GCC" = yes; then
 790   CFLAGS="$CFLAGS -Wall -g -O2"
 791   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
 792   # accident waiting to happen.
 793   CFLAGS="$CFLAGS -fno-strict-aliasing"
 794 else
 795   CFLAGS="$CFLAGS -g -O"
 796   enable_gcc_warnings=no
 797   enable_gcc_warnings_advisory=no
 798 fi
 799
 800 # Add some more warnings which we use in development but not in the
 801 # released versions.  (Some relevant gcc versions can't handle these.)
 802 if test x$enable_gcc_warnings = xyes || test x$enable_gcc_warnings_advisory = xyes; then
 803
 804   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 805 #if !defined(__GNUC__) || (__GNUC__ < 4)
 806 #error
 807 #endif]), have_gcc4=yes, have_gcc4=no)
 808
 809   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 810 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 811 #error
 812 #endif]), have_gcc42=yes, have_gcc42=no)
 813
 814   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 815 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 816 #error
 817 #endif]), have_gcc43=yes, have_gcc43=no)
 818
 819   save_CFLAGS="$CFLAGS"
 820   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 821   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 822                     have_shorten64_flag=no)
 823   CFLAGS="$save_CFLAGS"
 824
 825   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum"
 826   if test x$enable_gcc_warnings = xyes; then
 827     CFLAGS="$CFLAGS -Werror"
 828   fi
 829
 830   # Disabled, so we can use mallinfo(): -Waggregate-return
 831
 832   if test x$have_gcc4 = xyes ; then
 833     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 834     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 835   fi
 836
 837   if test x$have_gcc42 = xyes ; then
 838     # These warnings break gcc 4.0.2 and work on gcc 4.2
 839     # XXXX020 Use -fstack-protector.
 840     # XXXX020 See if any of these work with earlier versions.
 841     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 842     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 843   fi
 844
 845   if test x$have_gcc43 = xyes ; then
 846     # These warnings break gcc 4.2 and work on gcc 4.3
 847     # XXXX020 See if any of these work with earlier versions.
 848     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 849   fi
 850
 851   if test x$have_shorten64_flag = xyes ; then
 852     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 853   fi
 854
 855 ##This will break the world on some 64-bit architectures
 856 # CFLAGS="$CFLAGS -Winline"
 857 fi
 858
 859
 860
 861 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 862
 863 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample src/Makefile doc/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/test/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 864 AC_OUTPUT
 865
 866 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 867   ./contrib/updateVersions.pl
 868 fi
 869