configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.1.19)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(buf-freelists,
  40    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  41 AC_ARG_ENABLE(openbsd-malloc,
  42    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  43 AC_ARG_ENABLE(instrument-downloads,
  44    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  45
  46 if test x$enable_buf_freelists != xno; then
  47   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  48             [Defined if we try to use freelists for buffer RAM chunks])
  49 fi
  50 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  51 if test x$enable_instrument_downloads = xyes; then
  52   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  53             [Defined if we want to keep track of how much of each kind of resource we download.])
  54 fi
  55
  56 AC_ARG_ENABLE(transparent,
  57      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  58      [case "${enableval}" in
  59         yes) transparent=true ;;
  60         no)  transparent=false ;;
  61         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  62       esac], [transparent=true])
  63
  64 AC_ARG_ENABLE(threads,
  65      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  66
  67 if test x$enable_threads = x; then
  68    case $host in
  69     *-*-solaris* )
  70      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  71      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  72 cpu workers lock up here, so I will disable threads.])
  73      enable_threads="no";;
  74     *)
  75      enable_threads="yes";;
  76    esac
  77 fi
  78
  79 if test "$enable_threads" = "yes"; then
  80   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  81 fi
  82
  83 case $host in
  84    *-*-solaris* )
  85      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  86      ;;
  87 esac
  88
  89 AC_ARG_ENABLE(geoip-stats,
  90      AS_HELP_STRING(--enable-geoip-stats, enable code for directories to collect per-country statistics))
  91
  92 if test "$enable_geoip_stats" = "yes"; then
  93   AC_DEFINE(ENABLE_GEOIP_STATS, 1, [Defined if we try to collect per-country statistics])
  94 fi
  95
  96 AC_ARG_ENABLE(gcc-warnings,
  97      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  98
  99 AC_ARG_ENABLE(local-appdata,
 100    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
 101 if test "$enable_local_appdata" = "yes"; then
 102   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 103             [Defined if we default to host local appdata paths on Windows])
 104 fi
 105
 106 AC_PROG_CC
 107 AC_PROG_CPP
 108 AC_PROG_MAKE_SET
 109 AC_PROG_RANLIB
 110
 111 TORUSER=_tor
 112 AC_ARG_WITH(tor-user,
 113         [  --with-tor-user=NAME    Specify username for tor daemon ],
 114         [
 115            TORUSER=$withval
 116         ]
 117 )
 118 AC_SUBST(TORUSER)
 119
 120 TORGROUP=_tor
 121 AC_ARG_WITH(tor-group,
 122         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 123         [
 124            TORGROUP=$withval
 125         ]
 126 )
 127 AC_SUBST(TORGROUP)
 128
 129
 130 dnl If WIN32 is defined and non-zero, we are building for win32
 131 AC_MSG_CHECKING([for win32])
 132 AC_RUN_IFELSE([
 133 int main(int c, char **v) {
 134 #ifdef WIN32
 135 #if WIN32
 136   return 0;
 137 #else
 138   return 1;
 139 #endif
 140 #else
 141   return 2;
 142 #endif
 143 }],
 144 bwin32=true; AC_MSG_RESULT([yes]),
 145 bwin32=false; AC_MSG_RESULT([no]),
 146 bwin32=cross; AC_MSG_RESULT([cross])
 147 )
 148
 149 if test "$bwin32" = cross; then
 150 AC_MSG_CHECKING([for win32 (cross)])
 151 AC_COMPILE_IFELSE([
 152 #ifdef WIN32
 153 int main(int c, char **v) {return 0;}
 154 #else
 155 #error
 156 int main(int c, char **v) {return x(y);}
 157 #endif
 158 ],
 159 bwin32=true; AC_MSG_RESULT([yes]),
 160 bwin32=false; AC_MSG_RESULT([no]))
 161 fi
 162
 163 if test "$bwin32" = true; then
 164 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 165 fi
 166 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 167
 168 dnl Enable C99 when compiling with MIPSpro
 169 AC_MSG_CHECKING([for MIPSpro compiler])
 170 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 171 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 172 #error
 173   return x(y);
 174 #endif
 175 ]),
 176 bmipspro=false; AC_MSG_RESULT(no),
 177 bmipspro=true; AC_MSG_RESULT(yes))
 178
 179 if test "$bmipspro" = true; then
 180   CFLAGS="$CFLAGS -c99"
 181 fi
 182
 183 AC_C_BIGENDIAN
 184
 185 AC_SEARCH_LIBS(socket, [socket])
 186 AC_SEARCH_LIBS(gethostbyname, [nsl])
 187 AC_SEARCH_LIBS(dlopen, [dl])
 188 AC_SEARCH_LIBS(inet_aton, [resolv])
 189
 190 if test "$enable_threads" = "yes"; then
 191   AC_SEARCH_LIBS(pthread_create, [pthread])
 192   AC_SEARCH_LIBS(pthread_detach, [pthread])
 193 fi
 194
 195 dnl -------------------------------------------------------------------
 196 dnl Check for functions before libevent, since libevent-1.2 apparently
 197 dnl exports strlcpy without defining it in a header.
 198
 199 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull getaddrinfo localtime_r gmtime_r memmem strtok_r writev readv flock prctl)
 200
 201 using_custom_malloc=no
 202 if test x$enable_openbsd_malloc = xyes ; then
 203    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 204    using_custom_malloc=yes
 205 fi
 206 if test x$tcmalloc = xyes ; then
 207    using_custom_malloc=yes
 208 fi
 209 if test $using_custom_malloc = no ; then
 210    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 211 fi
 212
 213 if test "$enable_threads" = "yes"; then
 214   AC_CHECK_HEADERS(pthread.h)
 215   AC_CHECK_FUNCS(pthread_create)
 216 fi
 217
 218 dnl ------------------------------------------------------
 219 dnl Where do you live, libevent?  And how do we call you?
 220
 221 if test "$bwin32" = true; then
 222   TOR_LIB_WS32=-lws2_32
 223   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 224   # think it's actually necessary.
 225   TOR_LIB_GDI=-lgdi32
 226 else
 227   TOR_LIB_WS32=
 228   TOR_LIB_GDI=
 229 fi
 230 AC_SUBST(TOR_LIB_WS32)
 231 AC_SUBST(TOR_LIB_GDI)
 232
 233 dnl We need to do this before we try our disgusting hack below.
 234 AC_CHECK_HEADERS([sys/types.h])
 235
 236 dnl This is a disgusting hack so we safely include older libevent headers.
 237 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 238 AC_CHECK_TYPE(u_int32_t, unsigned long)
 239 AC_CHECK_TYPE(u_int16_t, unsigned short)
 240 AC_CHECK_TYPE(u_int8_t, unsigned char)
 241
 242 tor_libevent_pkg_redhat="libevent"
 243 tor_libevent_pkg_debian="libevent-dev"
 244 tor_libevent_devpkg_redhat="libevent-devel"
 245 tor_libevent_devpkg_debian="libevent-dev"
 246
 247 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 248 #ifdef WIN32
 249 #include <winsock2.h>
 250 #endif
 251 #include <stdlib.h>
 252 #include <sys/time.h>
 253 #include <sys/types.h>
 254 #include <event.h>], [
 255 #ifdef WIN32
 256 #include <winsock2.h>
 257 #endif
 258 void exit(int); void *event_init(void);],
 259     [
 260 #ifdef WIN32
 261 {WSADATA d; WSAStartup(0x101,&d); }
 262 #endif
 263 event_init(); exit(0);
 264 ], [--with-libevent-dir], [/opt/libevent])
 265
 266 dnl Now check for particular libevent functions.
 267 save_LIBS="$LIBS"
 268 save_LDFLAGS="$LDFLAGS"
 269 save_CPPFLAGS="$CPPFLAGS"
 270 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 271 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 272 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 273 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 274 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 275 [#include <event.h>
 276 ])
 277
 278 LIBS="$save_LIBS"
 279 LDFLAGS="$save_LDFLAGS"
 280 CPPFLAGS="$save_CPPFLAGS"
 281
 282 dnl ------------------------------------------------------
 283 dnl Where do you live, openssl?  And how do we call you?
 284
 285 tor_openssl_pkg_redhat="openssl"
 286 tor_openssl_pkg_debian="libssl"
 287 tor_openssl_devpkg_redhat="openssl-devel"
 288 tor_openssl_devpkg_debian="libssl-dev"
 289
 290 ALT_openssl_WITHVAL=""
 291 AC_ARG_WITH(ssl-dir,
 292   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 293   [
 294       if test "x$withval" != xno && test "x$withval" != "x" ; then
 295          ALT_openssl_WITHVAL="$withval"
 296       fi
 297   ])
 298
 299 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 300     [#include <openssl/rand.h>],
 301     [void RAND_add(const void *buf, int num, double entropy);],
 302     [RAND_add((void*)0,0,0); exit(0);], [],
 303     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 304
 305 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 306
 307 dnl ------------------------------------------------------
 308 dnl Where do you live, zlib?  And how do we call you?
 309
 310 tor_openssl_pkg_redhat="zlib"
 311 tor_openssl_pkg_debian="zlib1g"
 312 tor_openssl_devpkg_redhat="zlib-devel"
 313 tor_openssl_devpkg_debian="zlib1g-dev"
 314
 315 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 316     [#include <zlib.h>],
 317     [const char * zlibVersion(void);],
 318     [zlibVersion(); exit(0);], [--with-zlib-dir],
 319     [/opt/zlib])
 320
 321 dnl Make sure to enable support for large off_t if available.
 322
 323 AC_SYS_LARGEFILE
 324
 325 AC_CHECK_HEADERS(unistd.h string.h signal.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 326
 327 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 328
 329 dnl These headers are not essential
 330
 331 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h sys/file.h malloc_np.h sys/prctl.h)
 332
 333 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 334 [#ifdef HAVE_MALLOC_H
 335 #include <malloc.h>
 336 #endif
 337 #ifdef HAVE_MALLOC_MALLOC_H
 338 #include <malloc/malloc.h>
 339 #endif])
 340
 341 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 342 [#ifdef HAVE_SYS_TYPES_H
 343 #include <sys/types.h>
 344 #endif
 345 #ifdef HAVE_SYS_SOCKET_H
 346 #include <sys/socket.h>
 347 #endif])
 348 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 349 [#ifdef HAVE_SYS_TYPES_H
 350 #include <sys/types.h>
 351 #endif
 352 #ifdef HAVE_SYS_SOCKET_H
 353 #include <sys/socket.h>
 354 #endif
 355 #ifdef HAVE_NET_IF_H
 356 #include <net/if.h>
 357 #endif])
 358 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 359         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 360 [#ifdef HAVE_SYS_TYPES_H
 361 #include <sys/types.h>
 362 #endif
 363 #ifdef HAVE_SYS_SOCKET_H
 364 #include <sys/socket.h>
 365 #endif
 366 #ifdef HAVE_LIMITS_H
 367 #include <limits.h>
 368 #endif
 369 #ifdef HAVE_LINUX_TYPES_H
 370 #include <linux/types.h>
 371 #endif
 372 #ifdef HAVE_NETINET_IN6_H
 373 #include <netinet/in6.h>
 374 #endif
 375 #ifdef HAVE_NETINET_IN_H
 376 #include <netinet/in.h>
 377 #endif])
 378
 379 if test x$transparent = xtrue ; then
 380    transparent_ok=0
 381    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 382      transparent_ok=1
 383    fi
 384    if test x$linux_netfilter_ipv4 = x1 ; then
 385      transparent_ok=1
 386    fi
 387    if test x$transparent_ok = x1 ; then
 388      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 389      case $host in
 390        *-*-openbsd*)
 391          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 392      esac
 393    else
 394      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 395    fi
 396 fi
 397
 398 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 399 [#ifdef HAVE_SYS_TYPES_H
 400 #include <sys/types.h>
 401 #endif
 402 #ifdef HAVE_SYS_TIME_H
 403 #include <sys/time.h>
 404 #endif])
 405
 406 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 407 dnl Watch out.
 408
 409 AC_CHECK_SIZEOF(int8_t)
 410 AC_CHECK_SIZEOF(int16_t)
 411 AC_CHECK_SIZEOF(int32_t)
 412 AC_CHECK_SIZEOF(int64_t)
 413 AC_CHECK_SIZEOF(uint8_t)
 414 AC_CHECK_SIZEOF(uint16_t)
 415 AC_CHECK_SIZEOF(uint32_t)
 416 AC_CHECK_SIZEOF(uint64_t)
 417 AC_CHECK_SIZEOF(intptr_t)
 418 AC_CHECK_SIZEOF(uintptr_t)
 419
 420 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 421
 422 AC_CHECK_SIZEOF(char)
 423 AC_CHECK_SIZEOF(short)
 424 AC_CHECK_SIZEOF(int)
 425 AC_CHECK_SIZEOF(long)
 426 AC_CHECK_SIZEOF(long long)
 427 AC_CHECK_SIZEOF(__int64)
 428 AC_CHECK_SIZEOF(void *)
 429 AC_CHECK_SIZEOF(time_t)
 430 AC_CHECK_SIZEOF(size_t)
 431
 432 AC_CHECK_TYPES([uint, u_char, ssize_t])
 433
 434 dnl used to include sockaddr_storage, but everybody has that.
 435 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 436 [#ifdef HAVE_SYS_TYPES_H
 437 #include <sys/types.h>
 438 #endif
 439 #ifdef HAVE_NETINET_IN_H
 440 #include <netinet/in.h>
 441 #endif
 442 #ifdef HAVE_NETINET_IN6_H
 443 #include <netinet/in6.h>
 444 #endif
 445 #ifdef HAVE_SYS_SOCKET_H
 446 #include <sys/socket.h>
 447 #endif
 448 #ifdef MS_WINDOWS
 449 #define WIN32_WINNT 0x400
 450 #define _WIN32_WINNT 0x400
 451 #define WIN32_LEAN_AND_MEAN
 452 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 453 #include <winsock.h>
 454 #else
 455 #include <winsock2.h>
 456 #include <ws2tcpip.h>
 457 #endif
 458 #endif
 459 ])
 460 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 461 [#ifdef HAVE_SYS_TYPES_H
 462 #include <sys/types.h>
 463 #endif
 464 #ifdef HAVE_NETINET_IN_H
 465 #include <netinet/in.h>
 466 #endif
 467 #ifdef HAVE_NETINET_IN6_H
 468 #include <netinet/in6.h>
 469 #endif
 470 #ifdef HAVE_SYS_SOCKET_H
 471 #include <sys/socket.h>
 472 #endif
 473 #ifdef MS_WINDOWS
 474 #define WIN32_WINNT 0x400
 475 #define _WIN32_WINNT 0x400
 476 #define WIN32_LEAN_AND_MEAN
 477 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 478 #include <winsock.h>
 479 #else
 480 #include <winsock2.h>
 481 #include <ws2tcpip.h>
 482 #endif
 483 #endif
 484 ])
 485
 486 AC_CHECK_TYPES([rlim_t], , ,
 487 [#ifdef HAVE_SYS_TYPES_H
 488 #include <sys/types.h>
 489 #endif
 490 #ifdef HAVE_SYS_TIME_H
 491 #include <sys/time.h>
 492 #endif
 493 #ifdef HAVE_SYS_RESOURCE_H
 494 #include <sys/resource.h>
 495 #endif
 496 ])
 497
 498 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 499 AC_RUN_IFELSE(AC_LANG_SOURCE([
 500 #ifdef HAVE_SYS_TYPES_H
 501 #include <sys/types.h>
 502 #endif
 503 #ifdef HAVE_SYS_TIME_H
 504 #include <sys/time.h>
 505 #endif
 506 #ifdef HAVE_TIME_H
 507 #include <time.h>
 508 #endif
 509 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 510   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 511 ])
 512
 513 if test "$tor_cv_time_t_signed" = cross; then
 514   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 515 fi
 516
 517 if test "$tor_cv_time_t_signed" != no; then
 518   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 519             [Define to 1 iff time_t is signed])
 520 fi
 521
 522 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 523 #ifdef HAVE_SYS_SOCKET_H
 524 #include <sys/socket.h>
 525 #endif
 526 ])
 527
 528 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 529
 530 AC_CHECK_SIZEOF(cell_t)
 531
 532 # Now make sure that NULL can be represented as zero bytes.
 533 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 534 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 535 [[#include <stdlib.h>
 536 #include <string.h>
 537 #include <stdio.h>
 538 #ifdef HAVE_STDDEF_H
 539 #include <stddef.h>
 540 #endif
 541 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 542 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 543        [tor_cv_null_is_zero=yes],
 544        [tor_cv_null_is_zero=no],
 545        [tor_cv_null_is_zero=cross])])
 546
 547 if test "$tor_cv_null_is_zero" = cross ; then
 548   # Cross-compiling; let's hope that the target isn't raving mad.
 549   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 550 fi
 551
 552 if test "$tor_cv_null_is_zero" != no; then
 553   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 554             [Define to 1 iff memset(0) sets pointers to NULL])
 555 fi
 556
 557 # And what happens when we malloc zero?
 558 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 559 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 560 [[#include <stdlib.h>
 561 #include <string.h>
 562 #include <stdio.h>
 563 #ifdef HAVE_STDDEF_H
 564 #include <stddef.h>
 565 #endif
 566 int main () { return malloc(0)?0:1; }]])],
 567        [tor_cv_malloc_zero_works=yes],
 568        [tor_cv_malloc_zero_works=no],
 569        [tor_cv_malloc_zero_works=cross])])
 570
 571 if test "$tor_cv_malloc_zero_works" = cross; then
 572   # Cross-compiling; let's hope that the target isn't raving mad.
 573   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 574 fi
 575
 576 if test "$tor_cv_malloc_zero_works" = yes; then
 577   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 578             [Define to 1 iff malloc(0) returns a pointer])
 579 fi
 580
 581 # whether we seem to be in a 2s-complement world.
 582 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 583 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 584 [[int main () { int problem = ((-99) != (~99)+1);
 585 return problem ? 1 : 0; }]])],
 586        [tor_cv_twos_complement=yes],
 587        [tor_cv_twos_complement=no],
 588        [tor_cv_twos_complement=cross])])
 589
 590 if test "$tor_cv_twos_complement" = cross ; then
 591   # Cross-compiling; let's hope that the target isn't raving mad.
 592   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 593 fi
 594
 595 if test "$tor_cv_twos_complement" != no ; then
 596   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 597             [Define to 1 iff we represent negative integers with two's complement])
 598 fi
 599
 600 # Whether we should use the dmalloc memory allocation debugging library.
 601 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 602 AC_ARG_WITH(dmalloc,
 603 [  --with-dmalloc          Use debug memory allocation library. ],
 604 [if [[ "$withval" = "yes" ]]; then
 605   dmalloc=1
 606   AC_MSG_RESULT(yes)
 607 else
 608   dmalloc=1
 609   AC_MSG_RESULT(no)
 610 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 611 )
 612
 613 if [[ $dmalloc -eq 1 ]]; then
 614   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 615   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 616   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 617   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 618   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 619 fi
 620
 621 AC_ARG_WITH(tcmalloc,
 622 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 623 [ tcmalloc=yes ], [ tcmalloc=no ])
 624
 625 if test x$tcmalloc = xyes ; then
 626    LDFLAGS="-ltcmalloc $LDFLAGS"
 627 fi
 628
 629 # Allow user to specify an alternate syslog facility
 630 AC_ARG_WITH(syslog-facility,
 631 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 632 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 633 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 634 AC_SUBST(LOGFACILITY)
 635
 636 # Check if we have getresuid and getresgid
 637 AC_CHECK_FUNCS(getresuid getresgid)
 638
 639 # Check for gethostbyname_r in all its glorious incompatible versions.
 640 #   (This logic is based on that in Python's configure.in)
 641 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 642   [Define this if you have any gethostbyname_r()])
 643
 644 AC_CHECK_FUNC(gethostbyname_r, [
 645   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 646   OLD_CFLAGS=$CFLAGS
 647   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 648   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 649 #include <netdb.h>
 650   ], [[
 651     char *cp1, *cp2;
 652     struct hostent *h1, *h2;
 653     int i1, i2;
 654     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 655   ]]),[
 656     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 657     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 658      [Define this if gethostbyname_r takes 6 arguments])
 659     AC_MSG_RESULT(6)
 660   ], [
 661     AC_TRY_COMPILE([
 662 #include <netdb.h>
 663     ], [
 664       char *cp1, *cp2;
 665       struct hostent *h1;
 666       int i1, i2;
 667       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 668     ], [
 669       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 670       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 671         [Define this if gethostbyname_r takes 5 arguments])
 672       AC_MSG_RESULT(5)
 673    ], [
 674       AC_TRY_COMPILE([
 675 #include <netdb.h>
 676      ], [
 677        char *cp1;
 678        struct hostent *h1;
 679        struct hostent_data hd;
 680        (void) gethostbyname_r(cp1,h1,&hd);
 681      ], [
 682        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 683        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 684          [Define this if gethostbyname_r takes 3 arguments])
 685        AC_MSG_RESULT(3)
 686      ], [
 687        AC_MSG_RESULT(0)
 688      ])
 689   ])
 690  ])
 691  CFLAGS=$OLD_CFLAGS
 692 ])
 693
 694 AC_CACHE_CHECK([whether the C compiler supports __func__],
 695   tor_cv_have_func_macro,
 696   AC_COMPILE_IFELSE([
 697 #include <stdio.h>
 698 int main(int c, char **v) { puts(__func__); }],
 699   tor_cv_have_func_macro=yes,
 700   tor_cv_have_func_macro=no))
 701
 702 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 703   tor_cv_have_FUNC_macro,
 704   AC_COMPILE_IFELSE([
 705 #include <stdio.h>
 706 int main(int c, char **v) { puts(__FUNC__); }],
 707   tor_cv_have_FUNC_macro=yes,
 708   tor_cv_have_FUNC_macro=no))
 709
 710 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 711   tor_cv_have_FUNCTION_macro,
 712   AC_COMPILE_IFELSE([
 713 #include <stdio.h>
 714 int main(int c, char **v) { puts(__FUNCTION__); }],
 715   tor_cv_have_FUNCTION_macro=yes,
 716   tor_cv_have_FUNCTION_macro=no))
 717
 718 if test "$tor_cv_have_func_macro" = 'yes'; then
 719   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 720 fi
 721
 722 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 723   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 724 fi
 725
 726 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 727   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 728            [Defined if the compiler supports __FUNCTION__])
 729 fi
 730
 731 # $prefix stores the value of the --prefix command line option, or
 732 # NONE if the option wasn't set.  In the case that it wasn't set, make
 733 # it be the default, so that we can use it to expand directories now.
 734 if test "x$prefix" = "xNONE"; then
 735   prefix=$ac_default_prefix
 736 fi
 737
 738 # and similarly for $exec_prefix
 739 if test "x$exec_prefix" = "xNONE"; then
 740   exec_prefix=$prefix
 741 fi
 742
 743 if test "x$CONFDIR" = "x"; then
 744   CONFDIR=`eval echo $sysconfdir/tor`
 745 fi
 746 AC_SUBST(CONFDIR)
 747 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 748 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 749
 750 BINDIR=`eval echo $bindir`
 751 AC_SUBST(BINDIR)
 752 LOCALSTATEDIR=`eval echo $localstatedir`
 753 AC_SUBST(LOCALSTATEDIR)
 754
 755 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 756 # than autoconf's macros like.
 757 if test "$GCC" = yes; then
 758   CFLAGS="$CFLAGS -Wall -g -O2"
 759   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
 760   # accident waiting to happen.
 761   CFLAGS="$CFLAGS -fno-strict-aliasing"
 762 else
 763   CFLAGS="$CFLAGS -g -O"
 764   enable_gcc_warnings=no
 765 fi
 766
 767 # Add some more warnings which we use in development but not in the
 768 # released versions.  (Some relevant gcc versions can't handle these.)
 769 if test x$enable_gcc_warnings = xyes; then
 770
 771   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 772 #if !defined(__GNUC__) || (__GNUC__ < 4)
 773 #error
 774 #endif]), have_gcc4=yes, have_gcc4=no)
 775
 776   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 777 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 778 #error
 779 #endif]), have_gcc42=yes, have_gcc42=no)
 780
 781   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 782 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 783 #error
 784 #endif]), have_gcc43=yes, have_gcc43=no)
 785
 786   save_CFLAGS="$CFLAGS"
 787   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 788   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 789                     have_shorten64_flag=no)
 790   CFLAGS="$save_CFLAGS"
 791
 792   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 793
 794   # Disabled, so we can use mallinfo(): -Waggregate-return
 795
 796   if test x$have_gcc4 = xyes ; then
 797     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 798     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 799   fi
 800
 801   if test x$have_gcc42 = xyes ; then
 802     # These warnings break gcc 4.0.2 and work on gcc 4.2
 803     # XXXX020 Use -fstack-protector.
 804     # XXXX020 See if any of these work with earlier versions.
 805     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 806     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 807   fi
 808
 809   if test x$have_gcc43 = xyes ; then
 810     # These warnings break gcc 4.2 and work on gcc 4.3
 811     # XXXX020 See if any of these work with earlier versions.
 812     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 813   fi
 814
 815   if test x$have_shorten64_flag = xyes ; then
 816     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 817   fi
 818
 819 ##This will break the world on some 64-bit architectures
 820 # CFLAGS="$CFLAGS -Winline"
 821 fi
 822
 823
 824
 825 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 826
 827 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 828 AC_OUTPUT
 829
 830 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 831   ./contrib/updateVersions.pl
 832 fi
 833