configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.1.4-alpha-dev)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I../common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(cell-pool,
  40      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  41 AC_ARG_ENABLE(buf-freelists,
  42    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  43 AC_ARG_ENABLE(openbsd-malloc,
  44    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  45 AC_ARG_ENABLE(instrument-downloads,
  46    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  47
  48
  49 if test x$enable_cell_pool != xno; then
  50   AC_DEFINE(ENABLE_CELL_POOL, 1,
  51             [Defined if we try to use the pool allocator for queued cells])
  52 fi
  53 if test x$enable_buf_freelists != xno; then
  54   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  55             [Defined if we try to use freelists for buffer RAM chunks])
  56 fi
  57 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  58 if test x$enable_instrument_downloads == xyes; then
  59   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  60             [Defined if we want to keep track of how much of each kind of resource we download.])
  61 fi
  62
  63 AC_ARG_ENABLE(transparent,
  64      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  65      [case "${enableval}" in
  66         yes) transparent=true ;;
  67         no)  transparent=false ;;
  68         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  69       esac], [transparent=true])
  70
  71 AC_ARG_ENABLE(threads,
  72      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  73
  74 if test x$enable_threads = x; then
  75    case $host in
  76     *-*-solaris* )
  77      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  78      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  79 cpu workers lock up here, so I will disable threads.])
  80      enable_threads="no";;
  81     *)
  82      enable_threads="yes";;
  83    esac
  84 fi
  85
  86 if test "$enable_threads" = "yes"; then
  87   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  88 fi
  89
  90 case $host in
  91    *-*-solaris* )
  92      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  93      ;;
  94 esac
  95
  96 AC_ARG_ENABLE(geoip-stats,
  97      AS_HELP_STRING(--enable-geoip-stats, enable code for directories to collect per-country statistics))
  98
  99 if test "$enable_geoip_stats" = "yes"; then
 100   AC_DEFINE(ENABLE_GEOIP_STATS, 1, [Defined if we try to collect per-country statistics])
 101 fi
 102
 103 AC_ARG_ENABLE(gcc-warnings,
 104      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
 105
 106 AC_PROG_CC
 107 AC_PROG_CPP
 108 AC_PROG_MAKE_SET
 109 AC_PROG_RANLIB
 110
 111 TORUSER=_tor
 112 AC_ARG_WITH(tor-user,
 113         [  --with-tor-user=NAME    Specify username for tor daemon ],
 114         [
 115            TORUSER=$withval
 116         ]
 117 )
 118 AC_SUBST(TORUSER)
 119
 120 TORGROUP=_tor
 121 AC_ARG_WITH(tor-group,
 122         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 123         [
 124            TORGROUP=$withval
 125         ]
 126 )
 127 AC_SUBST(TORGROUP)
 128
 129
 130 dnl If WIN32 is defined and non-zero, we are building for win32
 131 AC_MSG_CHECKING([for win32])
 132 AC_RUN_IFELSE([
 133 int main(int c, char **v) {
 134 #ifdef WIN32
 135 #if WIN32
 136   return 0;
 137 #else
 138   return 1;
 139 #endif
 140 #else
 141   return 2;
 142 #endif
 143 }],
 144 bwin32=true; AC_MSG_RESULT([yes]),
 145 bwin32=false; AC_MSG_RESULT([no]),
 146 bwin32=cross; AC_MSG_RESULT([cross])
 147 )
 148
 149 if test "$bwin32" = cross; then
 150 AC_MSG_CHECKING([for win32 (cross)])
 151 AC_COMPILE_IFELSE([
 152 #ifdef WIN32
 153 int main(int c, char **v) {return 0;}
 154 #else
 155 #error
 156 int main(int c, char **v) {return x(y);}
 157 #endif
 158 ],
 159 bwin32=true; AC_MSG_RESULT([yes]),
 160 bwin32=false; AC_MSG_RESULT([no]))
 161 fi
 162
 163 if test "$bwin32" = true; then
 164 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 165 fi
 166 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 167
 168 dnl Enable C99 when compiling with MIPSpro
 169 AC_MSG_CHECKING([for MIPSpro compiler])
 170 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 171 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 172 #error
 173   return x(y);
 174 #endif
 175 ]),
 176 bmipspro=false; AC_MSG_RESULT(no),
 177 bmipspro=true; AC_MSG_RESULT(yes))
 178
 179 if test "$bmipspro" = true; then
 180   CFLAGS="$CFLAGS -c99"
 181 fi
 182
 183 AC_C_BIGENDIAN
 184
 185 AC_SEARCH_LIBS(socket, [socket])
 186 AC_SEARCH_LIBS(gethostbyname, [nsl])
 187 AC_SEARCH_LIBS(dlopen, [dl])
 188 AC_SEARCH_LIBS(inet_aton, [resolv])
 189
 190 if test "$enable_threads" = "yes"; then
 191   AC_SEARCH_LIBS(pthread_create, [pthread])
 192   AC_SEARCH_LIBS(pthread_detach, [pthread])
 193 fi
 194
 195 dnl -------------------------------------------------------------------
 196 dnl Check for functions before libevent, since libevent-1.2 apparently
 197 dnl exports strlcpy without defining it in a header.
 198
 199 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop writev readv)
 200
 201 using_custom_malloc=no
 202 if test x$enable_openbsd_malloc = xyes ; then
 203    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 204    using_custom_malloc=yes
 205 fi
 206 if test x$tcmalloc = xyes ; then
 207    using_custom_malloc=yes
 208 fi
 209 if test $using_custom_malloc = no ; then
 210    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 211 fi
 212
 213 if test "$enable_threads" = "yes"; then
 214   AC_CHECK_HEADERS(pthread.h)
 215   AC_CHECK_FUNCS(pthread_create)
 216 fi
 217
 218 dnl ------------------------------------------------------
 219 dnl Where do you live, libevent?  And how do we call you?
 220
 221 if test "$bwin32" = true; then
 222   TOR_LIB_WS32=-lws2_32
 223   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 224   # think it's actually necessary.
 225   TOR_LIB_GDI=-lgdi32
 226 else
 227   TOR_LIB_WS32=
 228   TOR_LIB_GDI=
 229 fi
 230 AC_SUBST(TOR_LIB_WS32)
 231 AC_SUBST(TOR_LIB_GDI)
 232
 233 dnl We need to do this before we try our disgusting hack below.
 234 AC_CHECK_HEADERS([sys/types.h])
 235
 236 dnl This is a disgusting hack so we safely include older libevent headers.
 237 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 238 AC_CHECK_TYPE(u_int32_t, unsigned long)
 239 AC_CHECK_TYPE(u_int16_t, unsigned short)
 240 AC_CHECK_TYPE(u_int8_t, unsigned char)
 241
 242 tor_libevent_pkg_redhat="libevent"
 243 tor_libevent_pkg_debian="libevent-dev"
 244 tor_libevent_devpkg_redhat="libevent-devel"
 245 tor_libevent_devpkg_debian="libevent-dev"
 246
 247 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 248 #ifdef WIN32
 249 #include <winsock2.h>
 250 #endif
 251 #include <stdlib.h>
 252 #include <sys/time.h>
 253 #include <sys/types.h>
 254 #include <event.h>], [
 255 #ifdef WIN32
 256 #include <winsock2.h>
 257 #endif
 258 void exit(int); void *event_init(void);],
 259     [
 260 #ifdef WIN32
 261 {WSADATA d; WSAStartup(0x101,&d); }
 262 #endif
 263 event_init(); exit(0);
 264 ], [--with-libevent-dir], [/opt/libevent])
 265
 266 dnl Now check for particular libevent functions.
 267 save_LIBS="$LIBS"
 268 save_LDFLAGS="$LDFLAGS"
 269 save_CPPFLAGS="$CPPFLAGS"
 270 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 271 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 272 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 273 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 274 LIBS="$save_LIBS"
 275 LDFLAGS="$save_LDFLAGS"
 276 CPPFLAGS="$save_CPPFLAGS"
 277
 278 dnl ------------------------------------------------------
 279 dnl Where do you live, openssl?  And how do we call you?
 280
 281 tor_openssl_pkg_redhat="openssl"
 282 tor_openssl_pkg_debian="libssl"
 283 tor_openssl_devpkg_redhat="openssl-devel"
 284 tor_openssl_devpkg_debian="libssl-dev"
 285
 286 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 287     [#include <openssl/rand.h>],
 288     [void RAND_add(const void *buf, int num, double entropy);],
 289     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 290     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 291
 292 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 293
 294 dnl ------------------------------------------------------
 295 dnl Where do you live, zlib?  And how do we call you?
 296
 297 tor_openssl_pkg_redhat="zlib"
 298 tor_openssl_pkg_debian="zlib1g"
 299 tor_openssl_devpkg_redhat="zlib-devel"
 300 tor_openssl_devpkg_debian="zlib1g-dev"
 301
 302 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 303     [#include <zlib.h>],
 304     [const char * zlibVersion(void);],
 305     [zlibVersion(); exit(0);], [--with-zlib-dir],
 306     [/opt/zlib])
 307
 308 dnl Make sure to enable support for large off_t if available.
 309
 310 AC_SYS_LARGEFILE
 311
 312 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 313
 314 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 315
 316 dnl These headers are not essential
 317
 318 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h)
 319
 320 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 321 [#ifdef HAVE_MALLOC_H
 322 #include <malloc.h>
 323 #endif
 324 #ifdef HAVE_MALLOC_MALLOC_H
 325 #include <malloc/malloc.h>
 326 #endif])
 327
 328 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 329 [#ifdef HAVE_SYS_TYPES_H
 330 #include <sys/types.h>
 331 #endif
 332 #ifdef HAVE_SYS_SOCKET_H
 333 #include <sys/socket.h>
 334 #endif])
 335 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 336 [#ifdef HAVE_SYS_TYPES_H
 337 #include <sys/types.h>
 338 #endif
 339 #ifdef HAVE_SYS_SOCKET_H
 340 #include <sys/socket.h>
 341 #endif
 342 #ifdef HAVE_NET_IF_H
 343 #include <net/if.h>
 344 #endif])
 345 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 346         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 347 [#ifdef HAVE_SYS_TYPES_H
 348 #include <sys/types.h>
 349 #endif
 350 #ifdef HAVE_SYS_SOCKET_H
 351 #include <sys/socket.h>
 352 #endif
 353 #ifdef HAVE_LIMITS_H
 354 #include <limits.h>
 355 #endif
 356 #ifdef HAVE_LINUX_TYPES_H
 357 #include <linux/types.h>
 358 #endif
 359 #ifdef HAVE_NETINET_IN6_H
 360 #include <netinet/in6.h>
 361 #endif
 362 #ifdef HAVE_NETINET_IN_H
 363 #include <netinet/in.h>
 364 #endif])
 365
 366 if test x$transparent = xtrue ; then
 367    transparent_ok=0
 368    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 369      transparent_ok=1
 370    fi
 371    if test x$linux_netfilter_ipv4 = x1 ; then
 372      transparent_ok=1
 373    fi
 374    if test x$transparent_ok = x1 ; then
 375      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 376      case $host in
 377        *-*-openbsd*)
 378          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 379      esac
 380    else
 381      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 382    fi
 383 fi
 384
 385 AC_FUNC_FSEEKO
 386
 387 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 388 [#ifdef HAVE_SYS_TYPES_H
 389 #include <sys/types.h>
 390 #endif
 391 #ifdef HAVE_SYS_TIME_H
 392 #include <sys/time.h>
 393 #endif])
 394
 395 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 396 dnl Watch out.
 397
 398 AC_CHECK_SIZEOF(int8_t)
 399 AC_CHECK_SIZEOF(int16_t)
 400 AC_CHECK_SIZEOF(int32_t)
 401 AC_CHECK_SIZEOF(int64_t)
 402 AC_CHECK_SIZEOF(uint8_t)
 403 AC_CHECK_SIZEOF(uint16_t)
 404 AC_CHECK_SIZEOF(uint32_t)
 405 AC_CHECK_SIZEOF(uint64_t)
 406 AC_CHECK_SIZEOF(intptr_t)
 407 AC_CHECK_SIZEOF(uintptr_t)
 408
 409 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 410
 411 AC_CHECK_SIZEOF(char)
 412 AC_CHECK_SIZEOF(short)
 413 AC_CHECK_SIZEOF(int)
 414 AC_CHECK_SIZEOF(long)
 415 AC_CHECK_SIZEOF(long long)
 416 AC_CHECK_SIZEOF(__int64)
 417 AC_CHECK_SIZEOF(void *)
 418 AC_CHECK_SIZEOF(time_t)
 419 AC_CHECK_SIZEOF(size_t)
 420
 421 AC_CHECK_TYPES([uint, u_char, ssize_t])
 422
 423 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 424 [#ifdef HAVE_SYS_TYPES_H
 425 #include <sys/types.h>
 426 #endif
 427 #ifdef HAVE_NETINET_IN_H
 428 #include <netinet/in.h>
 429 #endif
 430 #ifdef HAVE_NETINET_IN6_H
 431 #include <netinet/in6.h>
 432 #endif
 433 #ifdef HAVE_SYS_SOCKET_H
 434 #include <sys/socket.h>
 435 #endif
 436 #ifdef MS_WINDOWS
 437 #define WIN32_WINNT 0x400
 438 #define _WIN32_WINNT 0x400
 439 #define WIN32_LEAN_AND_MEAN
 440 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 441 #include <winsock.h>
 442 #else
 443 #include <winsock2.h>
 444 #include <ws2tcpip.h>
 445 #endif
 446 #endif
 447 ])
 448 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16], , ,
 449 [#ifdef HAVE_SYS_TYPES_H
 450 #include <sys/types.h>
 451 #endif
 452 #ifdef HAVE_NETINET_IN_H
 453 #include <netinet/in.h>
 454 #endif
 455 #ifdef HAVE_NETINET_IN6_H
 456 #include <netinet/in6.h>
 457 #endif
 458 #ifdef HAVE_SYS_SOCKET_H
 459 #include <sys/socket.h>
 460 #endif
 461 #ifdef MS_WINDOWS
 462 #define WIN32_WINNT 0x400
 463 #define _WIN32_WINNT 0x400
 464 #define WIN32_LEAN_AND_MEAN
 465 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 466 #include <winsock.h>
 467 #else
 468 #include <winsock2.h>
 469 #include <ws2tcpip.h>
 470 #endif
 471 #endif
 472 ])
 473
 474 AC_CHECK_TYPES([rlim_t], , ,
 475 [#ifdef HAVE_SYS_TYPES_H
 476 #include <sys/types.h>
 477 #endif
 478 #ifdef HAVE_SYS_TIME_H
 479 #include <sys/time.h>
 480 #endif
 481 #ifdef HAVE_SYS_RESOURCE_H
 482 #include <sys/resource.h>
 483 #endif
 484 ])
 485
 486 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 487 AC_RUN_IFELSE(AC_LANG_SOURCE([
 488 #ifdef HAVE_SYS_TYPES_H
 489 #include <sys/types.h>
 490 #endif
 491 #ifdef HAVE_SYS_TIME_H
 492 #include <sys/time.h>
 493 #endif
 494 #ifdef HAVE_TIME_H
 495 #include <time.h>
 496 #endif
 497 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 498   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 499 ])
 500
 501 if test "$tor_cv_time_t_signed" = cross; then
 502   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 503 fi
 504
 505 if test "$tor_cv_time_t_signed" != no; then
 506   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 507             [Define to 1 iff time_t is signed])
 508 fi
 509
 510 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 511 #ifdef HAVE_SYS_SOCKET_H
 512 #include <sys/socket.h>
 513 #endif
 514 ])
 515
 516 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 517
 518 AC_CHECK_SIZEOF(cell_t)
 519
 520 # Now make sure that NULL can be represented as zero bytes.
 521 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 522 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 523 [[#include <stdlib.h>
 524 #include <string.h>
 525 #include <stdio.h>
 526 #ifdef HAVE_STDDEF_H
 527 #include <stddef.h>
 528 #endif
 529 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 530 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 531        [tor_cv_null_is_zero=yes],
 532        [tor_cv_null_is_zero=no],
 533        [tor_cv_null_is_zero=cross])])
 534
 535 if test "$tor_cv_null_is_zero" = cross ; then
 536   # Cross-compiling; let's hope that the target isn't raving mad.
 537   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 538 fi
 539
 540 if test "$tor_cv_null_is_zero" != no; then
 541   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 542             [Define to 1 iff memset(0) sets pointers to NULL])
 543 fi
 544
 545 # And what happens when we malloc zero?
 546 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 547 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 548 [[#include <stdlib.h>
 549 #include <string.h>
 550 #include <stdio.h>
 551 #ifdef HAVE_STDDEF_H
 552 #include <stddef.h>
 553 #endif
 554 int main () { return malloc(0)?0:1; }]])],
 555        [tor_cv_malloc_zero_works=yes],
 556        [tor_cv_malloc_zero_works=no],
 557        [tor_cv_malloc_zero_works=cross])])
 558
 559 if test "$tor_cv_malloc_zero_works" = cross; then
 560   # Cross-compiling; let's hope that the target isn't raving mad.
 561   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 562 fi
 563
 564 if test "$tor_cv_malloc_zero_works" = yes; then
 565   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 566             [Define to 1 iff malloc(0) returns a pointer])
 567 fi
 568
 569 # whether we seem to be in a 2s-complement world.
 570 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 571 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 572 [[int main () { int problem = ((-99) != (~99)+1);
 573 return problem ? 1 : 0; }]])],
 574        [tor_cv_twos_complement=yes],
 575        [tor_cv_twos_complement=no],
 576        [tor_cv_twos_complement=cross])])
 577
 578 if test "$tor_cv_twos_complement" = cross ; then
 579   # Cross-compiling; let's hope that the target isn't raving mad.
 580   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 581 fi
 582
 583 if test "$tor_cv_twos_complement" != no ; then
 584   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 585             [Define to 1 iff we represent negative integers with two's complement])
 586 fi
 587
 588 # Whether we should use the dmalloc memory allocation debugging library.
 589 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 590 AC_ARG_WITH(dmalloc,
 591 [  --with-dmalloc          Use debug memory allocation library. ],
 592 [if [[ "$withval" = "yes" ]]; then
 593   dmalloc=1
 594   AC_MSG_RESULT(yes)
 595 else
 596   dmalloc=1
 597   AC_MSG_RESULT(no)
 598 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 599 )
 600
 601 if [[ $dmalloc -eq 1 ]]; then
 602   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 603   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 604   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 605   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 606   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 607 fi
 608
 609 AC_ARG_WITH(tcmalloc,
 610 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 611 [ tcmalloc=yes ], [ tcmalloc=no ])
 612
 613 if test x$tcmalloc = xyes ; then
 614    LDFLAGS="-ltcmalloc $LDFLAGS"
 615 fi
 616
 617 # Allow user to specify an alternate syslog facility
 618 AC_ARG_WITH(syslog-facility,
 619 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 620 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 621 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 622 AC_SUBST(LOGFACILITY)
 623
 624 # Check for gethostbyname_r in all its glorious incompatible versions.
 625 #   (This logic is based on that in Python's configure.in)
 626 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 627   [Define this if you have any gethostbyname_r()])
 628
 629 AC_CHECK_FUNC(gethostbyname_r, [
 630   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 631   OLD_CFLAGS=$CFLAGS
 632   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 633   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 634 #include <netdb.h>
 635   ], [[
 636     char *cp1, *cp2;
 637     struct hostent *h1, *h2;
 638     int i1, i2;
 639     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 640   ]]),[
 641     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 642     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 643      [Define this if gethostbyname_r takes 6 arguments])
 644     AC_MSG_RESULT(6)
 645   ], [
 646     AC_TRY_COMPILE([
 647 #include <netdb.h>
 648     ], [
 649       char *cp1, *cp2;
 650       struct hostent *h1;
 651       int i1, i2;
 652       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 653     ], [
 654       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 655       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 656         [Define this if gethostbyname_r takes 5 arguments])
 657       AC_MSG_RESULT(5)
 658    ], [
 659       AC_TRY_COMPILE([
 660 #include <netdb.h>
 661      ], [
 662        char *cp1;
 663        struct hostent *h1;
 664        struct hostent_data hd;
 665        (void) gethostbyname_r(cp1,h1,&hd);
 666      ], [
 667        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 668        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 669          [Define this if gethostbyname_r takes 3 arguments])
 670        AC_MSG_RESULT(3)
 671      ], [
 672        AC_MSG_RESULT(0)
 673      ])
 674   ])
 675  ])
 676  CFLAGS=$OLD_CFLAGS
 677 ])
 678
 679 AC_CACHE_CHECK([whether the C compiler supports __func__],
 680   tor_cv_have_func_macro,
 681   AC_COMPILE_IFELSE([
 682 #include <stdio.h>
 683 int main(int c, char **v) { puts(__func__); }],
 684   tor_cv_have_func_macro=yes,
 685   tor_cv_have_func_macro=no))
 686
 687 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 688   tor_cv_have_FUNC_macro,
 689   AC_COMPILE_IFELSE([
 690 #include <stdio.h>
 691 int main(int c, char **v) { puts(__FUNC__); }],
 692   tor_cv_have_FUNC_macro=yes,
 693   tor_cv_have_FUNC_macro=no))
 694
 695 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 696   tor_cv_have_FUNCTION_macro,
 697   AC_COMPILE_IFELSE([
 698 #include <stdio.h>
 699 int main(int c, char **v) { puts(__FUNCTION__); }],
 700   tor_cv_have_FUNCTION_macro=yes,
 701   tor_cv_have_FUNCTION_macro=no))
 702
 703 if test "$tor_cv_have_func_macro" = 'yes'; then
 704   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 705 fi
 706
 707 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 708   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 709 fi
 710
 711 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 712   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 713            [Defined if the compiler supports __FUNCTION__])
 714 fi
 715
 716 # $prefix stores the value of the --prefix command line option, or
 717 # NONE if the option wasn't set.  In the case that it wasn't set, make
 718 # it be the default, so that we can use it to expand directories now.
 719 if test "x$prefix" = "xNONE"; then
 720   prefix=$ac_default_prefix
 721 fi
 722
 723 # and similarly for $exec_prefix
 724 if test "x$exec_prefix" = "xNONE"; then
 725   exec_prefix=$prefix
 726 fi
 727
 728 if test "x$CONFDIR" = "x"; then
 729   CONFDIR=`eval echo $sysconfdir/tor`
 730 fi
 731 AC_SUBST(CONFDIR)
 732 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 733 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 734
 735 BINDIR=`eval echo $bindir`
 736 AC_SUBST(BINDIR)
 737 LOCALSTATEDIR=`eval echo $localstatedir`
 738 AC_SUBST(LOCALSTATEDIR)
 739
 740 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 741 # than autoconf's macros like.
 742 if test "$ac_cv_c_compiler_gnu" = yes; then
 743   CFLAGS="$CFLAGS -Wall -g -O2"
 744 else
 745   CFLAGS="$CFLAGS -g -O"
 746   enable_gcc_warnings=no
 747 fi
 748
 749 # Add some more warnings which we use in development but not in the
 750 # released versions.  (Some relevant gcc versions can't handle these.)
 751 if test x$enable_gcc_warnings = xyes; then
 752
 753   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 754 #if !defined(__GNUC__) || (__GNUC__ < 4)
 755 #error
 756 #endif]), have_gcc4=yes, have_gcc4=no)
 757
 758   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 759 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 760 #error
 761 #endif]), have_gcc42=yes, have_gcc42=no)
 762
 763   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 764 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 765 #error
 766 #endif]), have_gcc43=yes, have_gcc43=no)
 767
 768   save_CFLAGS="$CFLAGS"
 769   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 770   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 771                     have_shorten64_flag=no)
 772   CFLAGS="$save_CFLAGS"
 773
 774   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 775
 776   # Disabled, so we can use mallinfo(): -Waggregate-return
 777
 778   if test x$have_gcc4 = xyes ; then
 779     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 780     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 781   fi
 782
 783   if test x$have_gcc42 = xyes ; then
 784     # These warnings break gcc 4.0.2 and work on gcc 4.2
 785     # XXXX020 Use -fstack-protector.
 786     # XXXX020 See if any of these work with earlier versions.
 787     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 788     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 789   fi
 790
 791   if test x$have_gcc43 = xyes ; then
 792     # These warnings break gcc 4.2 and work on gcc 4.3
 793     # XXXX020 See if any of these work with earlier versions.
 794     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 795   fi
 796
 797   if test x$have_shorten64_flag = xyes ; then
 798     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 799   fi
 800
 801 ##This will break the world on some 64-bit architectures
 802 # CFLAGS="$CFLAGS -Winline"
 803 fi
 804
 805
 806
 807 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 808
 809 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 810 AC_OUTPUT
 811
 812 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 813   ./contrib/updateVersions.pl
 814 fi
 815