configure.in

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.2.0-alpha-dev)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13   if test -f /usr/kerberos/include ; then
  14     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  15   fi
  16 fi
  17
  18 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  19 # the += operator on it in src/or/Makefile.am
  20 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  21
  22 AC_ARG_ENABLE(debug,
  23  AS_HELP_STRING(--enable-debug, compile with debugging info),
  24 [if test x$enableval = xyes; then
  25     CFLAGS="$CFLAGS -g"
  26 fi])
  27
  28 #XXXX ideally, we should make this into a no-op, and detect whether we're
  29 #compiling for the iphone by using $target.
  30 AC_ARG_ENABLE(iphone,
  31  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  32  [if test x$enableval = xyes ; then
  33    tor_cv_iphone=true
  34    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  35   fi])
  36
  37 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  38 AC_ARG_ENABLE(buf-freelists,
  39    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  40 AC_ARG_ENABLE(openbsd-malloc,
  41    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  42 AC_ARG_ENABLE(instrument-downloads,
  43    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  44
  45 if test x$enable_buf_freelists != xno; then
  46   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  47             [Defined if we try to use freelists for buffer RAM chunks])
  48 fi
  49 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  50 if test x$enable_instrument_downloads = xyes; then
  51   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  52             [Defined if we want to keep track of how much of each kind of resource we download.])
  53 fi
  54
  55 AC_ARG_ENABLE(transparent,
  56      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  57      [case "${enableval}" in
  58         yes) transparent=true ;;
  59         no)  transparent=false ;;
  60         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  61       esac], [transparent=true])
  62
  63 AC_ARG_ENABLE(threads,
  64      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  65
  66 if test x$enable_threads = x; then
  67    case $host in
  68     *-*-solaris* )
  69      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  70      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  71 cpu workers lock up here, so I will disable threads.])
  72      enable_threads="no";;
  73     *)
  74      enable_threads="yes";;
  75    esac
  76 fi
  77
  78 if test "$enable_threads" = "yes"; then
  79   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  80 fi
  81
  82 case $host in
  83    *-*-solaris* )
  84      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  85      ;;
  86 esac
  87
  88 AC_ARG_ENABLE(exit-stats,
  89      AS_HELP_STRING(--enable-exit-stats, enable code for exits to collect per-port statistics))
  90
  91 if test "$enable_exit_stats" = "yes"; then
  92   AC_DEFINE(ENABLE_EXIT_STATS, 1, [Defined if we try to collect per-port statistics on exits])
  93 fi
  94
  95 AC_ARG_ENABLE(dirreq-stats,
  96      AS_HELP_STRING(--enable-dirreq-stats, enable code for directories to collect per-country statistics))
  97
  98 if test "$enable_dirreq_stats" = "yes"; then
  99   AC_DEFINE(ENABLE_DIRREQ_STATS, 1, [Defined if we try to collect per-country statistics])
 100 fi
 101
 102 AC_ARG_ENABLE(buffer-stats,
 103      AS_HELP_STRING(--enable-buffer-stats, enable code for relays to collect buffer statistics))
 104
 105 if test "$enable_buffer_stats" = "yes"; then
 106   AC_DEFINE(ENABLE_BUFFER_STATS, 1, [Defined if we try to collect buffer statistics])
 107 fi
 108
 109 AC_ARG_ENABLE(entry-stats,
 110      AS_HELP_STRING(--enable-entry-stats, enable code for entry guards to collect per-country statistics))
 111
 112 if test "$enable_entry_stats" = "yes"; then
 113   AC_DEFINE(ENABLE_ENTRY_STATS, 1, [Defined if we try to collect per-country statistics])
 114 fi
 115
 116 AC_ARG_ENABLE(gcc-warnings,
 117      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
 118
 119 AC_ARG_ENABLE(local-appdata,
 120    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
 121 if test "$enable_local_appdata" = "yes"; then
 122   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 123             [Defined if we default to host local appdata paths on Windows])
 124 fi
 125
 126 AC_PROG_CC
 127 AC_PROG_CPP
 128 AC_PROG_MAKE_SET
 129 AC_PROG_RANLIB
 130 AC_PROG_SED
 131
 132 AC_PATH_PROG([SHA1SUM], [sha1sum], none)
 133 AC_PATH_PROG([OPENSSL], [openssl], none)
 134
 135 TORUSER=_tor
 136 AC_ARG_WITH(tor-user,
 137         [  --with-tor-user=NAME    Specify username for tor daemon ],
 138         [
 139            TORUSER=$withval
 140         ]
 141 )
 142 AC_SUBST(TORUSER)
 143
 144 TORGROUP=_tor
 145 AC_ARG_WITH(tor-group,
 146         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 147         [
 148            TORGROUP=$withval
 149         ]
 150 )
 151 AC_SUBST(TORGROUP)
 152
 153
 154 dnl If WIN32 is defined and non-zero, we are building for win32
 155 AC_MSG_CHECKING([for win32])
 156 AC_RUN_IFELSE([
 157 int main(int c, char **v) {
 158 #ifdef WIN32
 159 #if WIN32
 160   return 0;
 161 #else
 162   return 1;
 163 #endif
 164 #else
 165   return 2;
 166 #endif
 167 }],
 168 bwin32=true; AC_MSG_RESULT([yes]),
 169 bwin32=false; AC_MSG_RESULT([no]),
 170 bwin32=cross; AC_MSG_RESULT([cross])
 171 )
 172
 173 if test "$bwin32" = cross; then
 174 AC_MSG_CHECKING([for win32 (cross)])
 175 AC_COMPILE_IFELSE([
 176 #ifdef WIN32
 177 int main(int c, char **v) {return 0;}
 178 #else
 179 #error
 180 int main(int c, char **v) {return x(y);}
 181 #endif
 182 ],
 183 bwin32=true; AC_MSG_RESULT([yes]),
 184 bwin32=false; AC_MSG_RESULT([no]))
 185 fi
 186
 187 if test "$bwin32" = true; then
 188 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 189 fi
 190 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 191
 192 dnl Enable C99 when compiling with MIPSpro
 193 AC_MSG_CHECKING([for MIPSpro compiler])
 194 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 195 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 196 #error
 197   return x(y);
 198 #endif
 199 ]),
 200 bmipspro=false; AC_MSG_RESULT(no),
 201 bmipspro=true; AC_MSG_RESULT(yes))
 202
 203 if test "$bmipspro" = true; then
 204   CFLAGS="$CFLAGS -c99"
 205 fi
 206
 207 AC_C_BIGENDIAN
 208
 209 AC_SEARCH_LIBS(socket, [socket])
 210 AC_SEARCH_LIBS(gethostbyname, [nsl])
 211 AC_SEARCH_LIBS(dlopen, [dl])
 212 AC_SEARCH_LIBS(inet_aton, [resolv])
 213
 214 if test "$enable_threads" = "yes"; then
 215   AC_SEARCH_LIBS(pthread_create, [pthread])
 216   AC_SEARCH_LIBS(pthread_detach, [pthread])
 217 fi
 218
 219 dnl -------------------------------------------------------------------
 220 dnl Check for functions before libevent, since libevent-1.2 apparently
 221 dnl exports strlcpy without defining it in a header.
 222
 223 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull getaddrinfo localtime_r gmtime_r memmem strtok_r writev readv flock prctl)
 224
 225 using_custom_malloc=no
 226 if test x$enable_openbsd_malloc = xyes ; then
 227    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 228    using_custom_malloc=yes
 229 fi
 230 if test x$tcmalloc = xyes ; then
 231    using_custom_malloc=yes
 232 fi
 233 if test $using_custom_malloc = no ; then
 234    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 235 fi
 236
 237 if test "$enable_threads" = "yes"; then
 238   AC_CHECK_HEADERS(pthread.h)
 239   AC_CHECK_FUNCS(pthread_create)
 240 fi
 241
 242 dnl ------------------------------------------------------
 243 dnl Where do you live, libevent?  And how do we call you?
 244
 245 if test "$bwin32" = true; then
 246   TOR_LIB_WS32=-lws2_32
 247   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 248   # think it's actually necessary.
 249   TOR_LIB_GDI=-lgdi32
 250 else
 251   TOR_LIB_WS32=
 252   TOR_LIB_GDI=
 253 fi
 254 AC_SUBST(TOR_LIB_WS32)
 255 AC_SUBST(TOR_LIB_GDI)
 256
 257 dnl We need to do this before we try our disgusting hack below.
 258 AC_CHECK_HEADERS([sys/types.h])
 259
 260 dnl This is a disgusting hack so we safely include older libevent headers.
 261 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 262 AC_CHECK_TYPE(u_int32_t, unsigned long)
 263 AC_CHECK_TYPE(u_int16_t, unsigned short)
 264 AC_CHECK_TYPE(u_int8_t, unsigned char)
 265
 266 tor_libevent_pkg_redhat="libevent"
 267 tor_libevent_pkg_debian="libevent-dev"
 268 tor_libevent_devpkg_redhat="libevent-devel"
 269 tor_libevent_devpkg_debian="libevent-dev"
 270
 271 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 272 #ifdef WIN32
 273 #include <winsock2.h>
 274 #endif
 275 #include <stdlib.h>
 276 #include <sys/time.h>
 277 #include <sys/types.h>
 278 #include <event.h>], [
 279 #ifdef WIN32
 280 #include <winsock2.h>
 281 #endif
 282 void exit(int); void *event_init(void);],
 283     [
 284 #ifdef WIN32
 285 {WSADATA d; WSAStartup(0x101,&d); }
 286 #endif
 287 event_init(); exit(0);
 288 ], [--with-libevent-dir], [/opt/libevent])
 289
 290 dnl Now check for particular libevent functions.
 291 save_LIBS="$LIBS"
 292 save_LDFLAGS="$LDFLAGS"
 293 save_CPPFLAGS="$CPPFLAGS"
 294 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 295 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 296 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 297 AC_CHECK_FUNCS(event_get_version event_get_version_number event_get_method event_set_log_callback evdns_set_outgoing_bind_address event_base_loopexit)
 298 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 299 [#include <event.h>
 300 ])
 301
 302 AC_CHECK_HEADERS(event2/event.h event2/dns.h)
 303
 304 LIBS="$save_LIBS"
 305 LDFLAGS="$save_LDFLAGS"
 306 CPPFLAGS="$save_CPPFLAGS"
 307
 308 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 309
 310 dnl ------------------------------------------------------
 311 dnl Where do you live, openssl?  And how do we call you?
 312
 313 tor_openssl_pkg_redhat="openssl"
 314 tor_openssl_pkg_debian="libssl"
 315 tor_openssl_devpkg_redhat="openssl-devel"
 316 tor_openssl_devpkg_debian="libssl-dev"
 317
 318 ALT_openssl_WITHVAL=""
 319 AC_ARG_WITH(ssl-dir,
 320   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 321   [
 322       if test "x$withval" != xno && test "x$withval" != "x" ; then
 323          ALT_openssl_WITHVAL="$withval"
 324       fi
 325   ])
 326
 327 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 328     [#include <openssl/rand.h>],
 329     [void RAND_add(const void *buf, int num, double entropy);],
 330     [RAND_add((void*)0,0,0); exit(0);], [],
 331     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 332
 333 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 334
 335 dnl ------------------------------------------------------
 336 dnl Where do you live, zlib?  And how do we call you?
 337
 338 tor_openssl_pkg_redhat="zlib"
 339 tor_openssl_pkg_debian="zlib1g"
 340 tor_openssl_devpkg_redhat="zlib-devel"
 341 tor_openssl_devpkg_debian="zlib1g-dev"
 342
 343 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 344     [#include <zlib.h>],
 345     [const char * zlibVersion(void);],
 346     [zlibVersion(); exit(0);], [--with-zlib-dir],
 347     [/opt/zlib])
 348
 349 dnl Make sure to enable support for large off_t if available.
 350
 351 AC_SYS_LARGEFILE
 352
 353 AC_CHECK_HEADERS(unistd.h string.h signal.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 354
 355 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 356
 357 dnl These headers are not essential
 358
 359 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h sys/file.h malloc_np.h sys/prctl.h)
 360
 361 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 362 [#ifdef HAVE_MALLOC_H
 363 #include <malloc.h>
 364 #endif
 365 #ifdef HAVE_MALLOC_MALLOC_H
 366 #include <malloc/malloc.h>
 367 #endif])
 368
 369 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 370 [#ifdef HAVE_SYS_TYPES_H
 371 #include <sys/types.h>
 372 #endif
 373 #ifdef HAVE_SYS_SOCKET_H
 374 #include <sys/socket.h>
 375 #endif])
 376 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 377 [#ifdef HAVE_SYS_TYPES_H
 378 #include <sys/types.h>
 379 #endif
 380 #ifdef HAVE_SYS_SOCKET_H
 381 #include <sys/socket.h>
 382 #endif
 383 #ifdef HAVE_NET_IF_H
 384 #include <net/if.h>
 385 #endif])
 386 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 387         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 388 [#ifdef HAVE_SYS_TYPES_H
 389 #include <sys/types.h>
 390 #endif
 391 #ifdef HAVE_SYS_SOCKET_H
 392 #include <sys/socket.h>
 393 #endif
 394 #ifdef HAVE_LIMITS_H
 395 #include <limits.h>
 396 #endif
 397 #ifdef HAVE_LINUX_TYPES_H
 398 #include <linux/types.h>
 399 #endif
 400 #ifdef HAVE_NETINET_IN6_H
 401 #include <netinet/in6.h>
 402 #endif
 403 #ifdef HAVE_NETINET_IN_H
 404 #include <netinet/in.h>
 405 #endif])
 406
 407 if test x$transparent = xtrue ; then
 408    transparent_ok=0
 409    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 410      transparent_ok=1
 411    fi
 412    if test x$linux_netfilter_ipv4 = x1 ; then
 413      transparent_ok=1
 414    fi
 415    if test x$transparent_ok = x1 ; then
 416      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 417      case $host in
 418        *-*-openbsd*)
 419          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 420      esac
 421    else
 422      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 423    fi
 424 fi
 425
 426 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 427 [#ifdef HAVE_SYS_TYPES_H
 428 #include <sys/types.h>
 429 #endif
 430 #ifdef HAVE_SYS_TIME_H
 431 #include <sys/time.h>
 432 #endif])
 433
 434 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 435 dnl Watch out.
 436
 437 AC_CHECK_SIZEOF(int8_t)
 438 AC_CHECK_SIZEOF(int16_t)
 439 AC_CHECK_SIZEOF(int32_t)
 440 AC_CHECK_SIZEOF(int64_t)
 441 AC_CHECK_SIZEOF(uint8_t)
 442 AC_CHECK_SIZEOF(uint16_t)
 443 AC_CHECK_SIZEOF(uint32_t)
 444 AC_CHECK_SIZEOF(uint64_t)
 445 AC_CHECK_SIZEOF(intptr_t)
 446 AC_CHECK_SIZEOF(uintptr_t)
 447
 448 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 449
 450 AC_CHECK_SIZEOF(char)
 451 AC_CHECK_SIZEOF(short)
 452 AC_CHECK_SIZEOF(int)
 453 AC_CHECK_SIZEOF(long)
 454 AC_CHECK_SIZEOF(long long)
 455 AC_CHECK_SIZEOF(__int64)
 456 AC_CHECK_SIZEOF(void *)
 457 AC_CHECK_SIZEOF(time_t)
 458 AC_CHECK_SIZEOF(size_t)
 459
 460 AC_CHECK_TYPES([uint, u_char, ssize_t])
 461
 462 dnl used to include sockaddr_storage, but everybody has that.
 463 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 464 [#ifdef HAVE_SYS_TYPES_H
 465 #include <sys/types.h>
 466 #endif
 467 #ifdef HAVE_NETINET_IN_H
 468 #include <netinet/in.h>
 469 #endif
 470 #ifdef HAVE_NETINET_IN6_H
 471 #include <netinet/in6.h>
 472 #endif
 473 #ifdef HAVE_SYS_SOCKET_H
 474 #include <sys/socket.h>
 475 #endif
 476 #ifdef MS_WINDOWS
 477 #define WIN32_WINNT 0x400
 478 #define _WIN32_WINNT 0x400
 479 #define WIN32_LEAN_AND_MEAN
 480 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 481 #include <winsock.h>
 482 #else
 483 #include <winsock2.h>
 484 #include <ws2tcpip.h>
 485 #endif
 486 #endif
 487 ])
 488 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 489 [#ifdef HAVE_SYS_TYPES_H
 490 #include <sys/types.h>
 491 #endif
 492 #ifdef HAVE_NETINET_IN_H
 493 #include <netinet/in.h>
 494 #endif
 495 #ifdef HAVE_NETINET_IN6_H
 496 #include <netinet/in6.h>
 497 #endif
 498 #ifdef HAVE_SYS_SOCKET_H
 499 #include <sys/socket.h>
 500 #endif
 501 #ifdef MS_WINDOWS
 502 #define WIN32_WINNT 0x400
 503 #define _WIN32_WINNT 0x400
 504 #define WIN32_LEAN_AND_MEAN
 505 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 506 #include <winsock.h>
 507 #else
 508 #include <winsock2.h>
 509 #include <ws2tcpip.h>
 510 #endif
 511 #endif
 512 ])
 513
 514 AC_CHECK_TYPES([rlim_t], , ,
 515 [#ifdef HAVE_SYS_TYPES_H
 516 #include <sys/types.h>
 517 #endif
 518 #ifdef HAVE_SYS_TIME_H
 519 #include <sys/time.h>
 520 #endif
 521 #ifdef HAVE_SYS_RESOURCE_H
 522 #include <sys/resource.h>
 523 #endif
 524 ])
 525
 526 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 527 AC_RUN_IFELSE(AC_LANG_SOURCE([
 528 #ifdef HAVE_SYS_TYPES_H
 529 #include <sys/types.h>
 530 #endif
 531 #ifdef HAVE_SYS_TIME_H
 532 #include <sys/time.h>
 533 #endif
 534 #ifdef HAVE_TIME_H
 535 #include <time.h>
 536 #endif
 537 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 538   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 539 ])
 540
 541 if test "$tor_cv_time_t_signed" = cross; then
 542   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 543 fi
 544
 545 if test "$tor_cv_time_t_signed" != no; then
 546   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 547             [Define to 1 iff time_t is signed])
 548 fi
 549
 550 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 551 #ifdef HAVE_SYS_SOCKET_H
 552 #include <sys/socket.h>
 553 #endif
 554 ])
 555
 556 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 557
 558 AC_CHECK_SIZEOF(cell_t)
 559
 560 # Now make sure that NULL can be represented as zero bytes.
 561 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 562 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 563 [[#include <stdlib.h>
 564 #include <string.h>
 565 #include <stdio.h>
 566 #ifdef HAVE_STDDEF_H
 567 #include <stddef.h>
 568 #endif
 569 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 570 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 571        [tor_cv_null_is_zero=yes],
 572        [tor_cv_null_is_zero=no],
 573        [tor_cv_null_is_zero=cross])])
 574
 575 if test "$tor_cv_null_is_zero" = cross ; then
 576   # Cross-compiling; let's hope that the target isn't raving mad.
 577   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 578 fi
 579
 580 if test "$tor_cv_null_is_zero" != no; then
 581   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 582             [Define to 1 iff memset(0) sets pointers to NULL])
 583 fi
 584
 585 # And what happens when we malloc zero?
 586 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 587 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 588 [[#include <stdlib.h>
 589 #include <string.h>
 590 #include <stdio.h>
 591 #ifdef HAVE_STDDEF_H
 592 #include <stddef.h>
 593 #endif
 594 int main () { return malloc(0)?0:1; }]])],
 595        [tor_cv_malloc_zero_works=yes],
 596        [tor_cv_malloc_zero_works=no],
 597        [tor_cv_malloc_zero_works=cross])])
 598
 599 if test "$tor_cv_malloc_zero_works" = cross; then
 600   # Cross-compiling; let's hope that the target isn't raving mad.
 601   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 602 fi
 603
 604 if test "$tor_cv_malloc_zero_works" = yes; then
 605   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 606             [Define to 1 iff malloc(0) returns a pointer])
 607 fi
 608
 609 # whether we seem to be in a 2s-complement world.
 610 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 611 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 612 [[int main () { int problem = ((-99) != (~99)+1);
 613 return problem ? 1 : 0; }]])],
 614        [tor_cv_twos_complement=yes],
 615        [tor_cv_twos_complement=no],
 616        [tor_cv_twos_complement=cross])])
 617
 618 if test "$tor_cv_twos_complement" = cross ; then
 619   # Cross-compiling; let's hope that the target isn't raving mad.
 620   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 621 fi
 622
 623 if test "$tor_cv_twos_complement" != no ; then
 624   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 625             [Define to 1 iff we represent negative integers with two's complement])
 626 fi
 627
 628 # Whether we should use the dmalloc memory allocation debugging library.
 629 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 630 AC_ARG_WITH(dmalloc,
 631 [  --with-dmalloc          Use debug memory allocation library. ],
 632 [if [[ "$withval" = "yes" ]]; then
 633   dmalloc=1
 634   AC_MSG_RESULT(yes)
 635 else
 636   dmalloc=1
 637   AC_MSG_RESULT(no)
 638 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 639 )
 640
 641 if [[ $dmalloc -eq 1 ]]; then
 642   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 643   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 644   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 645   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 646   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 647 fi
 648
 649 AC_ARG_WITH(tcmalloc,
 650 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 651 [ tcmalloc=yes ], [ tcmalloc=no ])
 652
 653 if test x$tcmalloc = xyes ; then
 654    LDFLAGS="-ltcmalloc $LDFLAGS"
 655 fi
 656
 657 # Allow user to specify an alternate syslog facility
 658 AC_ARG_WITH(syslog-facility,
 659 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 660 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 661 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 662 AC_SUBST(LOGFACILITY)
 663
 664 # Check if we have getresuid and getresgid
 665 AC_CHECK_FUNCS(getresuid getresgid)
 666
 667 # Check for gethostbyname_r in all its glorious incompatible versions.
 668 #   (This logic is based on that in Python's configure.in)
 669 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 670   [Define this if you have any gethostbyname_r()])
 671
 672 AC_CHECK_FUNC(gethostbyname_r, [
 673   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 674   OLD_CFLAGS=$CFLAGS
 675   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 676   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 677 #include <netdb.h>
 678   ], [[
 679     char *cp1, *cp2;
 680     struct hostent *h1, *h2;
 681     int i1, i2;
 682     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 683   ]]),[
 684     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 685     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 686      [Define this if gethostbyname_r takes 6 arguments])
 687     AC_MSG_RESULT(6)
 688   ], [
 689     AC_TRY_COMPILE([
 690 #include <netdb.h>
 691     ], [
 692       char *cp1, *cp2;
 693       struct hostent *h1;
 694       int i1, i2;
 695       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 696     ], [
 697       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 698       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 699         [Define this if gethostbyname_r takes 5 arguments])
 700       AC_MSG_RESULT(5)
 701    ], [
 702       AC_TRY_COMPILE([
 703 #include <netdb.h>
 704      ], [
 705        char *cp1;
 706        struct hostent *h1;
 707        struct hostent_data hd;
 708        (void) gethostbyname_r(cp1,h1,&hd);
 709      ], [
 710        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 711        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 712          [Define this if gethostbyname_r takes 3 arguments])
 713        AC_MSG_RESULT(3)
 714      ], [
 715        AC_MSG_RESULT(0)
 716      ])
 717   ])
 718  ])
 719  CFLAGS=$OLD_CFLAGS
 720 ])
 721
 722 AC_CACHE_CHECK([whether the C compiler supports __func__],
 723   tor_cv_have_func_macro,
 724   AC_COMPILE_IFELSE([
 725 #include <stdio.h>
 726 int main(int c, char **v) { puts(__func__); }],
 727   tor_cv_have_func_macro=yes,
 728   tor_cv_have_func_macro=no))
 729
 730 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 731   tor_cv_have_FUNC_macro,
 732   AC_COMPILE_IFELSE([
 733 #include <stdio.h>
 734 int main(int c, char **v) { puts(__FUNC__); }],
 735   tor_cv_have_FUNC_macro=yes,
 736   tor_cv_have_FUNC_macro=no))
 737
 738 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 739   tor_cv_have_FUNCTION_macro,
 740   AC_COMPILE_IFELSE([
 741 #include <stdio.h>
 742 int main(int c, char **v) { puts(__FUNCTION__); }],
 743   tor_cv_have_FUNCTION_macro=yes,
 744   tor_cv_have_FUNCTION_macro=no))
 745
 746 if test "$tor_cv_have_func_macro" = 'yes'; then
 747   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 748 fi
 749
 750 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 751   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 752 fi
 753
 754 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 755   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 756            [Defined if the compiler supports __FUNCTION__])
 757 fi
 758
 759 # $prefix stores the value of the --prefix command line option, or
 760 # NONE if the option wasn't set.  In the case that it wasn't set, make
 761 # it be the default, so that we can use it to expand directories now.
 762 if test "x$prefix" = "xNONE"; then
 763   prefix=$ac_default_prefix
 764 fi
 765
 766 # and similarly for $exec_prefix
 767 if test "x$exec_prefix" = "xNONE"; then
 768   exec_prefix=$prefix
 769 fi
 770
 771 if test "x$CONFDIR" = "x"; then
 772   CONFDIR=`eval echo $sysconfdir/tor`
 773 fi
 774 AC_SUBST(CONFDIR)
 775 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 776 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 777
 778 BINDIR=`eval echo $bindir`
 779 AC_SUBST(BINDIR)
 780 LOCALSTATEDIR=`eval echo $localstatedir`
 781 AC_SUBST(LOCALSTATEDIR)
 782
 783 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 784 # than autoconf's macros like.
 785 if test "$GCC" = yes; then
 786   CFLAGS="$CFLAGS -Wall -g -O2"
 787   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
 788   # accident waiting to happen.
 789   CFLAGS="$CFLAGS -fno-strict-aliasing"
 790 else
 791   CFLAGS="$CFLAGS -g -O"
 792   enable_gcc_warnings=no
 793 fi
 794
 795 # Add some more warnings which we use in development but not in the
 796 # released versions.  (Some relevant gcc versions can't handle these.)
 797 if test x$enable_gcc_warnings = xyes; then
 798
 799   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 800 #if !defined(__GNUC__) || (__GNUC__ < 4)
 801 #error
 802 #endif]), have_gcc4=yes, have_gcc4=no)
 803
 804   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 805 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 806 #error
 807 #endif]), have_gcc42=yes, have_gcc42=no)
 808
 809   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 810 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 811 #error
 812 #endif]), have_gcc43=yes, have_gcc43=no)
 813
 814   save_CFLAGS="$CFLAGS"
 815   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 816   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 817                     have_shorten64_flag=no)
 818   CFLAGS="$save_CFLAGS"
 819
 820   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 821
 822   # Disabled, so we can use mallinfo(): -Waggregate-return
 823
 824   if test x$have_gcc4 = xyes ; then
 825     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 826     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 827   fi
 828
 829   if test x$have_gcc42 = xyes ; then
 830     # These warnings break gcc 4.0.2 and work on gcc 4.2
 831     # XXXX020 Use -fstack-protector.
 832     # XXXX020 See if any of these work with earlier versions.
 833     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 834     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 835   fi
 836
 837   if test x$have_gcc43 = xyes ; then
 838     # These warnings break gcc 4.2 and work on gcc 4.3
 839     # XXXX020 See if any of these work with earlier versions.
 840     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 841   fi
 842
 843   if test x$have_shorten64_flag = xyes ; then
 844     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 845   fi
 846
 847 ##This will break the world on some 64-bit architectures
 848 # CFLAGS="$CFLAGS -Winline"
 849 fi
 850
 851
 852
 853 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 854
 855 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 856 AC_OUTPUT
 857
 858 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 859   ./contrib/updateVersions.pl
 860 fi
 861