configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2007, Roger Dingledine, Nick Mathewson
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.0.0-alpha-dev)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13     CFLAGS="$CFLAGS -I/usr/kerberos/include"
  14 fi
  15
  16 AC_ARG_ENABLE(debug,
  17  AS_HELP_STRING(--enable-debug, compile with debugging info),
  18 [if test x$enableval = xyes; then
  19     CFLAGS="$CFLAGS -g"
  20 fi])
  21
  22 AC_ARG_ENABLE(transparent,
  23      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  24      [case "${enableval}" in
  25         yes) transparent=true ;;
  26         no)  transparent=false ;;
  27         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  28       esac], [transparent=true])
  29
  30 AC_ARG_ENABLE(threads,
  31      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  32
  33 if test x$enable_threads = x; then
  34    case $host in
  35     *-*-solaris* )
  36      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  37      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  38 cpu workers lock up here, so I will disable threads.])
  39      enable_threads="no";;
  40     *)
  41      enable_threads="yes";;
  42    esac
  43 fi
  44
  45 if test $enable_threads = "yes"; then
  46   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  47 fi
  48
  49 case $host in
  50    *-*-solaris* )
  51      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  52      ;;
  53 esac
  54
  55 AC_ARG_ENABLE(gcc-warnings,
  56      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  57
  58 AC_PROG_CC
  59 AC_PROG_MAKE_SET
  60 AC_PROG_RANLIB
  61
  62 # The big search for OpenSSL
  63 # copied from openssh's configure.ac
  64 tryssldir=""
  65 AC_ARG_WITH(ssl-dir,
  66         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
  67         [
  68                 if test "x$withval" != "xno" ; then
  69                         tryssldir=$withval
  70                 fi
  71         ]
  72 )
  73
  74 trylibeventdir=""
  75 AC_ARG_WITH(libevent-dir,
  76        [  --with-libevent-dir=PATH     Specify path to Libevent installation ],
  77        [
  78                 if test "x$withval" != "xno" ; then
  79                         trylibeventdir=$withval
  80                 fi
  81        ]
  82 )
  83
  84 TORUSER=_tor
  85 AC_ARG_WITH(tor-user,
  86         [  --with-tor-user=NAME    Specify username for tor daemon ],
  87         [
  88            TORUSER=$withval
  89         ]
  90 )
  91 AC_SUBST(TORUSER)
  92
  93 TORGROUP=_tor
  94 AC_ARG_WITH(tor-group,
  95         [  --with-tor-group=NAME   Specify group name for tor daemon ],
  96         [
  97            TORGROUP=$withval
  98         ]
  99 )
 100 AC_SUBST(TORGROUP)
 101
 102
 103 dnl If WIN32 is defined and non-zero, we are building for win32
 104 AC_MSG_CHECKING([for win32])
 105 AC_RUN_IFELSE([
 106 int main(int c, char **v) {
 107 #ifdef WIN32
 108 #if WIN32
 109   return 0;
 110 #else
 111   return 1;
 112 #endif
 113 #else
 114   return 2;
 115 #endif
 116 }],
 117 bwin32=true; AC_MSG_RESULT([yes]),
 118 bwin32=false; AC_MSG_RESULT([no]),
 119 bwin32=cross; AC_MSG_RESULT([cross])
 120 )
 121
 122 if test $bwin32 = cross; then
 123 AC_MSG_CHECKING([for win32 (cross)])
 124 AC_COMPILE_IFELSE([
 125 #ifdef WIN32
 126 int main(int c, char **v) {return 0;}
 127 #else
 128 #error
 129 int main(int c, char **v) {return x(y);}
 130 #endif
 131 ],
 132 bwin32=true; AC_MSG_RESULT([yes]),
 133 bwin32=false; AC_MSG_RESULT([no]))
 134 fi
 135
 136 if test $bwin32 = true; then
 137 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 138 fi
 139
 140 dnl Enable C99 when compiling with MIPSpro
 141 AC_MSG_CHECKING([for MIPSpro compiler])
 142 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 143 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 144 #error
 145   return x(y);
 146 #endif
 147 ]),
 148 bmipspro=false; AC_MSG_RESULT(no),
 149 bmipspro=true; AC_MSG_RESULT(yes))
 150
 151 if test $bmipspro = true; then
 152   CFLAGS="$CFLAGS -c99"
 153 fi
 154
 155 AC_SEARCH_LIBS(socket, [socket])
 156 AC_SEARCH_LIBS(gethostbyname, [nsl])
 157 AC_SEARCH_LIBS(dlopen, [dl])
 158 AC_SEARCH_LIBS(inet_aton, [resolv])
 159
 160 if test $enable_threads = "yes"; then
 161   AC_SEARCH_LIBS(pthread_create, [pthread])
 162   AC_SEARCH_LIBS(pthread_detach, [pthread])
 163 fi
 164
 165 dnl -------------------------------------------------------------------
 166 dnl Check for functions before libevent, since libevent-1.2 apparently
 167 dnl exports strlcpy without defining it in a header.
 168
 169 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r)
 170
 171 if test $enable_threads = "yes"; then
 172   AC_CHECK_HEADERS(pthread.h)
 173   AC_CHECK_FUNCS(pthread_create)
 174 fi
 175
 176 dnl ------------------------------------------------------
 177 dnl Where do you live, libevent?  And how do we call you?
 178
 179 if test $bwin32 = true; then
 180   WS32lib=-lws2_32
 181   GDIlib=-lgdi32
 182 else
 183   W32lib=
 184   GDIlib=
 185 fi
 186
 187 dnl This is a disgusting hack so we safely include recent libevent headers.
 188 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 189 AC_CHECK_TYPE(u_int32_t, unsigned long)
 190 AC_CHECK_TYPE(u_int16_t, unsigned short)
 191 AC_CHECK_TYPE(u_int8_t, unsigned char)
 192
 193 if test $bwin32 = true; then
 194   WS32lib=-lws2_32
 195   GDIlib=-lgdi32
 196 else
 197   W32lib=
 198   GDIlib=
 199 fi
 200
 201 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $WS32lib], [
 202 #include <sys/time.h>
 203 #include <sys/types.h>
 204 #include <event.h>], [void *event_init(void);],
 205     [event_init(); exit(0);], [--with-libevent-dir], [/opt/libevent])
 206
 207 dnl Now check for particular libevent functions.
 208 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 209
 210 dnl ------------------------------------------------------
 211 dnl Where do you live, openssl?  And how do we call you?
 212
 213 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $GDIlib],
 214     [#include <openssl/rand.h>],
 215     [void RAND_add(const void *buf, int num, double entropy);],
 216     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 217     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 218
 219 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 220
 221 dnl Make sure to enable support for large off_t if avalable.
 222
 223 AC_SYS_LARGEFILE
 224
 225 dnl The warning message here is no longer strictly accurate.
 226
 227 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(some headers were not found, compilation may fail))
 228
 229 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h)
 230
 231 AC_CHECK_HEADERS(event.h, , AC_MSG_ERROR(Libevent header (event.h) not found. Tor requires libevent to build.),
 232 [#ifdef HAVE_SYS_TYPES_H
 233 #include <sys/types.h>
 234 #endif
 235 #ifdef HAVE_SYS_TIME_H
 236 #include <sys/time.h>
 237 #else
 238   struct timeval {
 239     long tv_sec;
 240     long tv_usec;
 241  };
 242 #endif])
 243
 244 AC_CHECK_HEADERS(zlib.h, , AC_MSG_ERROR(Zlib header (zlib.h) not found. Tor requires zlib to build. You may need to install a zlib development package.))
 245
 246 dnl These headers are not essential
 247
 248 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h)
 249
 250 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 251 [#ifdef HAVE_SYS_TYPES_H
 252 #include <sys/types.h>
 253 #endif
 254 #ifdef HAVE_SYS_SOCKET_H
 255 #include <sys/socket.h>
 256 #endif])
 257 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 258 [#ifdef HAVE_SYS_TYPES_H
 259 #include <sys/types.h>
 260 #endif
 261 #ifdef HAVE_SYS_SOCKET_H
 262 #include <sys/socket.h>
 263 #endif
 264 #ifdef HAVE_NET_IF_H
 265 #include <net/if.h>
 266 #endif])
 267 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 268         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 269 [#ifdef HAVE_SYS_TYPES_H
 270 #include <sys/types.h>
 271 #endif
 272 #ifdef HAVE_SYS_SOCKET_H
 273 #include <sys/socket.h>
 274 #endif])
 275
 276 if test x$transparent = xtrue ; then
 277    transparent_ok=0
 278    if test x$net_if_found = x1 -a x$net_pfvar_found = x1 ; then
 279      transparent_ok=1
 280    fi
 281    if test x$linux_netfilter_ipv4 = x1 ; then
 282      transparent_ok=1
 283    fi
 284    if test x$transparent_ok = x1 ; then
 285      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 286      case $host in
 287        *-*-openbsd*)
 288          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 289      esac
 290    else
 291      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 292    fi
 293 fi
 294
 295 AC_FUNC_FSEEKO
 296
 297 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 298 [#ifdef HAVE_SYS_TYPES_H
 299 #include <sys/types.h>
 300 #endif
 301 #ifdef HAVE_SYS_TIME_H
 302 #include <sys/time.h>
 303 #endif])
 304
 305 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 306 dnl Watch out.
 307
 308 AC_CHECK_SIZEOF(int8_t)
 309 AC_CHECK_SIZEOF(int16_t)
 310 AC_CHECK_SIZEOF(int32_t)
 311 AC_CHECK_SIZEOF(int64_t)
 312 AC_CHECK_SIZEOF(uint8_t)
 313 AC_CHECK_SIZEOF(uint16_t)
 314 AC_CHECK_SIZEOF(uint32_t)
 315 AC_CHECK_SIZEOF(uint64_t)
 316 AC_CHECK_SIZEOF(intptr_t)
 317 AC_CHECK_SIZEOF(uintptr_t)
 318
 319 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 320
 321 AC_CHECK_SIZEOF(char)
 322 AC_CHECK_SIZEOF(short)
 323 AC_CHECK_SIZEOF(int)
 324 AC_CHECK_SIZEOF(long)
 325 AC_CHECK_SIZEOF(long long)
 326 AC_CHECK_SIZEOF(__int64)
 327 AC_CHECK_SIZEOF(void *)
 328 AC_CHECK_SIZEOF(time_t)
 329 AC_CHECK_SIZEOF(size_t)
 330
 331 AC_CHECK_TYPES([uint, u_char])
 332
 333 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_storage], , ,
 334 [#ifdef HAVE_SYS_TYPES_H
 335 #include <sys/types.h>
 336 #endif
 337 #ifdef HAVE_NETINET_IN_H
 338 #include <netinet/in.h>
 339 #endif
 340 #ifdef HAVE_NETINET_IN6_H
 341 #include <netinet/in6.h>
 342 #endif
 343 #ifdef HAVE_SYS_SOCKET_H
 344 #include <sys/socket.h>
 345 #endif])
 346
 347 if test -z "$CROSS_COMPILE"; then
 348 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 349 AC_RUN_IFELSE(AC_LANG_SOURCE([
 350 #ifdef HAVE_SYS_TYPES_H
 351 #include <sys/types.h>
 352 #endif
 353 #ifdef HAVE_SYS_TIME_H
 354 #include <sys/time.h>
 355 #endif
 356 #ifdef HAVE_TIME_H
 357 #include <time.h>
 358 #endif
 359 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 360   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes)
 361 ])
 362 else
 363   # Cross-compiling; let's hope the target platform isn't loony.
 364   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 365   tor_cv_time_t_signed=yes
 366 fi
 367
 368 if test $tor_cv_time_t_signed = yes; then
 369   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 370             [Define to 1 iff time_t is signed])
 371 fi
 372
 373 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 374 #ifdef HAVE_SYS_SOCKET_H
 375 #include <sys/socket.h>
 376 #endif
 377 ])
 378
 379 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 380
 381 AC_CHECK_SIZEOF(cell_t)
 382
 383 # Now make sure that NULL can be represented as zero bytes.
 384 if test -z "$CROSS_COMPILE"; then
 385 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 386 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 387 [[#include <stdlib.h>
 388 #include <string.h>
 389 #include <stdio.h>
 390 #ifdef HAVE_STDDEF_H
 391 #include <stddef.h>
 392 #endif
 393 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 394 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 395        [tor_cv_null_is_zero=yes],
 396        [tor_cv_null_is_zero=no],
 397        [tor_cv_null_is_zero=cross])])
 398
 399 else
 400   # Cross-compiling; let's hope that the target isn't raving mad.
 401   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 402   tor_cv_null_is_zero=yes
 403 fi
 404
 405 if test $tor_cv_null_is_zero = yes; then
 406   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 407             [Define to 1 iff memset(0) sets pointers to NULL])
 408 fi
 409
 410 # And what happens when we malloc zero?
 411
 412 if test -z "$CROSS_COMPILE"; then
 413 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 414 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 415 [[#include <stdlib.h>
 416 #include <string.h>
 417 #include <stdio.h>
 418 #ifdef HAVE_STDDEF_H
 419 #include <stddef.h>
 420 #endif
 421 int main () { return malloc(0)?0:1; }]])],
 422        [tor_cv_malloc_zero_works=yes],
 423        [tor_cv_malloc_zero_works=no],
 424        [tor_cv_malloc_zero_works=cross])])
 425
 426 else
 427   # Cross-compiling; let's hope that the target isn't raving mad.
 428   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 429   tor_cv_malloc_zero_works=no
 430 fi
 431
 432 if test $tor_cv_malloc_zero_works = yes; then
 433   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 434             [Define to 1 iff malloc(0) returns a pointer])
 435 fi
 436
 437 # whether we seem to be in a 2s-complement world.
 438 if test -z "$CROSS_COMPILE"; then
 439 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 440 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 441 [[int main () { int problem = ((-99) != (~99)+1);
 442 return problem ? 1 : 0; }]])],
 443        [tor_cv_twos_complement=yes],
 444        [tor_cv_twos_complement=no],
 445        [tor_cv_twos_complement=cross])])
 446
 447 else
 448   # Cross-compiling; let's hope that the target isn't raving mad.
 449   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 450   tor_cv_twos_complement=yes
 451 fi
 452
 453 if test $tor_cv_twos_complement = yes; then
 454   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 455             [Define to 1 iff we represent negative integers with two's complement])
 456 fi
 457
 458 # Whether we should use the dmalloc memory allocation debugging library.
 459 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 460 AC_ARG_WITH(dmalloc,
 461 [  --with-dmalloc          Use debug memory allocation library. ],
 462 [if [[ "$withval" = "yes" ]]; then
 463   dmalloc=1
 464   AC_MSG_RESULT(yes)
 465 else
 466   dmalloc=1
 467   AC_MSG_RESULT(no)
 468 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 469 )
 470
 471 if [[ $dmalloc -eq 1 ]]; then
 472   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 473   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 474   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 475   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 476 fi
 477
 478 # Allow user to specify an alternate syslog facility
 479 AC_ARG_WITH(syslog-facility,
 480 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 481 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 482 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 483 AC_SUBST(LOGFACILITY)
 484
 485 # Check for gethostbyname_r in all its glorious incompatible versions.
 486 #   (This logic is based on that in Python's configure.in)
 487 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 488   [Define this if you have any gethostbyname_r()])
 489
 490 AC_CHECK_FUNC(gethostbyname_r, [
 491   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 492   OLD_CFLAGS=$CFLAGS
 493   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 494   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 495 #include <netdb.h>
 496   ], [[
 497     char *cp1, *cp2;
 498     struct hostent *h1, *h2;
 499     int i1, i2;
 500     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 501   ]]),[
 502     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 503     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 504      [Define this if gethostbyname_r takes 6 arguments])
 505     AC_MSG_RESULT(6)
 506   ], [
 507     AC_TRY_COMPILE([
 508 #include <netdb.h>
 509     ], [
 510       char *cp1, *cp2;
 511       struct hostent *h1;
 512       int i1, i2;
 513       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 514     ], [
 515       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 516       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 517         [Define this if gethostbyname_r takes 5 arguments])
 518       AC_MSG_RESULT(5)
 519    ], [
 520       AC_TRY_COMPILE([
 521 #include <netdb.h>
 522      ], [
 523        char *cp1;
 524        struct hostent *h1;
 525        struct hostent_data hd;
 526        (void) gethostbyname_r(cp1,h1,&hd);
 527      ], [
 528        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 529        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 530          [Define this if gethostbyname_r takes 3 arguments])
 531        AC_MSG_RESULT(3)
 532      ], [
 533        AC_MSG_RESULT(0)
 534      ])
 535   ])
 536  ])
 537  CFLAGS=$OLD_CFLAGS
 538 ])
 539
 540 AC_CACHE_CHECK([whether the C compiler supports __func__],
 541   tor_cv_have_func_macro,
 542   AC_COMPILE_IFELSE([
 543 #include <stdio.h>
 544 int main(int c, char **v) { puts(__func__); }],
 545   tor_cv_have_func_macro=yes,
 546   tor_cv_have_func_macro=no))
 547
 548 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 549   tor_cv_have_FUNC_macro,
 550   AC_COMPILE_IFELSE([
 551 #include <stdio.h>
 552 int main(int c, char **v) { puts(__FUNC__); }],
 553   tor_cv_have_FUNC_macro=yes,
 554   tor_cv_have_FUNC_macro=no))
 555
 556 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 557   tor_cv_have_FUNCTION_macro,
 558   AC_COMPILE_IFELSE([
 559 #include <stdio.h>
 560 int main(int c, char **v) { puts(__FUNCTION__); }],
 561   tor_cv_have_FUNCTION_macro=yes,
 562   tor_cv_have_FUNCTION_macro=no))
 563
 564 if test $tor_cv_have_func_macro = 'yes'; then
 565   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 566 fi
 567
 568 if test $tor_cv_have_FUNC_macro = 'yes'; then
 569   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 570 fi
 571
 572 if test $tor_cv_have_FUNCTION_macro = 'yes'; then
 573   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 574            [Defined if the compiler supports __FUNCTION__])
 575 fi
 576
 577 # $prefix stores the value of the --prefix command line option, or
 578 # NONE if the option wasn't set.  In the case that it wasn't set, make
 579 # it be the default, so that we can use it to expand directories now.
 580 if test "x$prefix" = "xNONE"; then
 581   prefix=$ac_default_prefix
 582 fi
 583
 584 # and similarly for $exec_prefix
 585 if test "x$exec_prefix" = "xNONE"; then
 586   exec_prefix=$prefix
 587 fi
 588
 589 if test "x$CONFDIR" = "x"; then
 590   CONFDIR=`eval echo $sysconfdir/tor`
 591 fi
 592 AC_SUBST(CONFDIR)
 593 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 594 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 595
 596 BINDIR=`eval echo $bindir`
 597 AC_SUBST(BINDIR)
 598
 599 LOCALSTATEDIR=`eval echo $localstatedir`
 600 AC_SUBST(LOCALSTATEDIR)
 601 AH_TEMPLATE([LOCALSTATEDIR], [Default location to store state files.])
 602 AC_DEFINE_UNQUOTED(LOCALSTATEDIR,"$LOCALSTATEDIR")
 603
 604 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 605 # than autoconf's macros like.
 606 if test $ac_cv_c_compiler_gnu = yes; then
 607   CFLAGS="$CFLAGS -Wall -g -O2"
 608 else
 609   CFLAGS="$CFLAGS -g -O"
 610   enable_gcc_warnings=no
 611 fi
 612
 613 # Add some more warnings which we use in the cvs version but not in the
 614 # released versions.  (Some relevant gcc versions can't handle these.)
 615 if test x$enable_gcc_warnings = xyes; then
 616
 617   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 618 #if !defined(__GNUC__) || (__GNUC__ < 4)
 619 #error
 620 #endif]), have_gcc4=yes, have_gcc4=no)
 621
 622   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Waggregate-return -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 623
 624   if test x$have_gcc4 = xyes ; then
 625     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 626     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 627   fi
 628
 629 ##This will break the world on some 64-bit architectures
 630 # CFLAGS="$CFLAGS -Winline"
 631
 632 fi
 633
 634 AC_CONFIG_FILES([Makefile tor.spec contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 635 AC_OUTPUT
 636
 637 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 638   ./contrib/updateVersions.pl
 639 fi
 640