configure.in

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.2.19-alpha)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13   if test -f /usr/kerberos/include ; then
  14     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  15   fi
  16 fi
  17
  18 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  19 # the += operator on it in src/or/Makefile.am
  20 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  21
  22 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  23 AC_ARG_ENABLE(buf-freelists,
  24    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  25 AC_ARG_ENABLE(openbsd-malloc,
  26    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  27 AC_ARG_ENABLE(instrument-downloads,
  28    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  29 AC_ARG_ENABLE(static-openssl,
  30    AS_HELP_STRING(--enable-static-openssl, Link against a static openssl library. Requires --with-openssl-dir))
  31 AC_ARG_ENABLE(static-libevent,
  32    AS_HELP_STRING(--enable-static-libevent, Link against a static libevent library. Requires --with-libevent-dir))
  33 AC_ARG_ENABLE(static-zlib,
  34    AS_HELP_STRING(--enable-static-zlib, Link against a static zlib library. Requires --with-zlib-dir))
  35
  36 if test x$enable_buf_freelists != xno; then
  37   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  38             [Defined if we try to use freelists for buffer RAM chunks])
  39 fi
  40 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  41 if test x$enable_instrument_downloads = xyes; then
  42   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  43             [Defined if we want to keep track of how much of each kind of resource we download.])
  44 fi
  45
  46 AC_ARG_ENABLE(transparent,
  47      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  48      [case "${enableval}" in
  49         yes) transparent=true ;;
  50         no)  transparent=false ;;
  51         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  52       esac], [transparent=true])
  53
  54 AC_ARG_ENABLE(asciidoc,
  55      AS_HELP_STRING(--disable-asciidoc, don't use asciidoc (disables building of manpages)),
  56      [case "${enableval}" in
  57         yes) asciidoc=true ;;
  58         no)  asciidoc=false ;;
  59         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  60       esac], [asciidoc=true])
  61
  62
  63 AC_ARG_ENABLE(threads,
  64      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  65
  66 if test x$enable_threads = x; then
  67    case $host in
  68     *-*-solaris* )
  69      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  70      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  71 cpu workers lock up here, so I will disable threads.])
  72      enable_threads="no";;
  73     *)
  74      enable_threads="yes";;
  75    esac
  76 fi
  77
  78 if test "$enable_threads" = "yes"; then
  79   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  80 fi
  81
  82 case $host in
  83    *-*-solaris* )
  84      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  85      ;;
  86 esac
  87
  88 AC_ARG_ENABLE(gcc-warnings,
  89      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  90 AC_ARG_ENABLE(gcc-warnings-advisory,
  91      AS_HELP_STRING(--enable-gcc-warnings-advisory, [enable verbose warnings, excluding -Werror]))
  92
  93 dnl Adam shostack suggests the following for Windows:
  94 dnl -D_FORTIFY_SOURCE=2 -fstack-protector-all
  95 dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
  96 dnl This requires that we use gcc and that we add -O2 to the CFLAGS.
  97 AC_ARG_ENABLE(gcc-hardening,
  98      AS_HELP_STRING(--enable-gcc-hardening, enable compiler security checks),
  99 [if test x$enableval = xyes; then
 100     CFLAGS="$CFLAGS -D_FORTIFY_SOURCE=2 -fstack-protector-all"
 101     CFLAGS="$CFLAGS -fwrapv -fPIE -Wstack-protector"
 102     CFLAGS="$CFLAGS --param ssp-buffer-size=1"
 103     LDFLAGS="$LDFLAGS -pie"
 104 fi])
 105
 106 dnl Linker hardening options
 107 dnl Currently these options are ELF specific - you can't use this with MacOSX
 108 AC_ARG_ENABLE(linker-hardening,
 109         AS_HELP_STRING(--enable-linker-hardening, enable linker security fixups),
 110 [if test x$enableval = xyes; then
 111     LDFLAGS="$LDFLAGS -z relro -z now"
 112 fi])
 113
 114 AC_ARG_ENABLE(local-appdata,
 115    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
 116 if test "$enable_local_appdata" = "yes"; then
 117   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
 118             [Defined if we default to host local appdata paths on Windows])
 119 fi
 120
 121 AC_PROG_CC
 122 AC_PROG_CPP
 123 AC_PROG_MAKE_SET
 124 AC_PROG_RANLIB
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 128
 129 dnl check for asciidoc and a2x
 130 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 131 AC_PATH_PROG([A2X], [a2x], none)
 132
 133 AM_CONDITIONAL(USE_ASCIIDOC, test x$asciidoc = xtrue)
 134
 135 AC_PATH_PROG([SHA1SUM], [sha1sum], none)
 136 AC_PATH_PROG([OPENSSL], [openssl], none)
 137
 138 TORUSER=_tor
 139 AC_ARG_WITH(tor-user,
 140         [  --with-tor-user=NAME    Specify username for tor daemon ],
 141         [
 142            TORUSER=$withval
 143         ]
 144 )
 145 AC_SUBST(TORUSER)
 146
 147 TORGROUP=_tor
 148 AC_ARG_WITH(tor-group,
 149         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 150         [
 151            TORGROUP=$withval
 152         ]
 153 )
 154 AC_SUBST(TORGROUP)
 155
 156
 157 dnl If WIN32 is defined and non-zero, we are building for win32
 158 AC_MSG_CHECKING([for win32])
 159 AC_RUN_IFELSE([AC_LANG_SOURCE([
 160 int main(int c, char **v) {
 161 #ifdef WIN32
 162 #if WIN32
 163   return 0;
 164 #else
 165   return 1;
 166 #endif
 167 #else
 168   return 2;
 169 #endif
 170 }])],
 171 bwin32=true; AC_MSG_RESULT([yes]),
 172 bwin32=false; AC_MSG_RESULT([no]),
 173 bwin32=cross; AC_MSG_RESULT([cross])
 174 )
 175
 176 if test "$bwin32" = cross; then
 177 AC_MSG_CHECKING([for win32 (cross)])
 178 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 179 #ifdef WIN32
 180 int main(int c, char **v) {return 0;}
 181 #else
 182 #error
 183 int main(int c, char **v) {return x(y);}
 184 #endif
 185 ])],
 186 bwin32=true; AC_MSG_RESULT([yes]),
 187 bwin32=false; AC_MSG_RESULT([no]))
 188 fi
 189
 190 if test "$bwin32" = true; then
 191 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 192 fi
 193 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 194
 195 dnl Enable C99 when compiling with MIPSpro
 196 AC_MSG_CHECKING([for MIPSpro compiler])
 197 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
 198 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 199 #error
 200   return x(y);
 201 #endif
 202 ])],
 203 bmipspro=false; AC_MSG_RESULT(no),
 204 bmipspro=true; AC_MSG_RESULT(yes))
 205
 206 if test "$bmipspro" = true; then
 207   CFLAGS="$CFLAGS -c99"
 208 fi
 209
 210 AC_C_BIGENDIAN
 211
 212 AC_SEARCH_LIBS(socket, [socket])
 213 AC_SEARCH_LIBS(gethostbyname, [nsl])
 214 AC_SEARCH_LIBS(dlopen, [dl])
 215 AC_SEARCH_LIBS(inet_aton, [resolv])
 216
 217 if test "$enable_threads" = "yes"; then
 218   AC_SEARCH_LIBS(pthread_create, [pthread])
 219   AC_SEARCH_LIBS(pthread_detach, [pthread])
 220 fi
 221
 222 dnl -------------------------------------------------------------------
 223 dnl Check for functions before libevent, since libevent-1.2 apparently
 224 dnl exports strlcpy without defining it in a header.
 225
 226 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull getaddrinfo localtime_r gmtime_r memmem strtok_r writev readv flock prctl vasprintf)
 227
 228 using_custom_malloc=no
 229 if test x$enable_openbsd_malloc = xyes ; then
 230    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 231    using_custom_malloc=yes
 232 fi
 233 if test x$tcmalloc = xyes ; then
 234    using_custom_malloc=yes
 235 fi
 236 if test $using_custom_malloc = no ; then
 237    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 238 fi
 239
 240 if test "$enable_threads" = "yes"; then
 241   AC_CHECK_HEADERS(pthread.h)
 242   AC_CHECK_FUNCS(pthread_create)
 243 fi
 244
 245 dnl ------------------------------------------------------
 246 dnl Where do you live, libevent?  And how do we call you?
 247
 248 if test "$bwin32" = true; then
 249   TOR_LIB_WS32=-lws2_32
 250   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 251   # think it's actually necessary.
 252   TOR_LIB_GDI=-lgdi32
 253 else
 254   TOR_LIB_WS32=
 255   TOR_LIB_GDI=
 256 fi
 257 AC_SUBST(TOR_LIB_WS32)
 258 AC_SUBST(TOR_LIB_GDI)
 259
 260 dnl We need to do this before we try our disgusting hack below.
 261 AC_CHECK_HEADERS([sys/types.h])
 262
 263 dnl This is a disgusting hack so we safely include older libevent headers.
 264 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 265 AC_CHECK_TYPE(u_int32_t, unsigned long)
 266 AC_CHECK_TYPE(u_int16_t, unsigned short)
 267 AC_CHECK_TYPE(u_int8_t, unsigned char)
 268
 269 tor_libevent_pkg_redhat="libevent"
 270 tor_libevent_pkg_debian="libevent-dev"
 271 tor_libevent_devpkg_redhat="libevent-devel"
 272 tor_libevent_devpkg_debian="libevent-dev"
 273
 274 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 275 #ifdef WIN32
 276 #include <winsock2.h>
 277 #endif
 278 #include <stdlib.h>
 279 #include <sys/time.h>
 280 #include <sys/types.h>
 281 #include <event.h>], [
 282 #ifdef WIN32
 283 #include <winsock2.h>
 284 #endif
 285 void exit(int); void *event_init(void);],
 286     [
 287 #ifdef WIN32
 288 {WSADATA d; WSAStartup(0x101,&d); }
 289 #endif
 290 event_init(); exit(0);
 291 ], [--with-libevent-dir], [/opt/libevent])
 292
 293 dnl Now check for particular libevent functions.
 294 save_LIBS="$LIBS"
 295 save_LDFLAGS="$LDFLAGS"
 296 save_CPPFLAGS="$CPPFLAGS"
 297 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 298 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 299 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 300 AC_CHECK_FUNCS(event_get_version event_get_version_number event_get_method event_set_log_callback evdns_set_outgoing_bind_address event_base_loopexit)
 301 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 302 [#include <event.h>
 303 ])
 304
 305 AC_CHECK_HEADERS(event2/event.h event2/dns.h)
 306
 307 LIBS="$save_LIBS"
 308 LDFLAGS="$save_LDFLAGS"
 309 CPPFLAGS="$save_CPPFLAGS"
 310
 311
 312 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 313
 314 if test "$enable_static_libevent" = "yes"; then
 315    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 316      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 317    else
 318      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a"
 319    fi
 320 else
 321      TOR_LIBEVENT_LIBS="-levent"
 322 fi
 323 AC_SUBST(TOR_LIBEVENT_LIBS)
 324
 325
 326 dnl ------------------------------------------------------
 327 dnl Where do you live, openssl?  And how do we call you?
 328
 329 tor_openssl_pkg_redhat="openssl"
 330 tor_openssl_pkg_debian="libssl"
 331 tor_openssl_devpkg_redhat="openssl-devel"
 332 tor_openssl_devpkg_debian="libssl-dev"
 333
 334 ALT_openssl_WITHVAL=""
 335 AC_ARG_WITH(ssl-dir,
 336   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 337   [
 338       if test "x$withval" != xno && test "x$withval" != "x" ; then
 339          ALT_openssl_WITHVAL="$withval"
 340       fi
 341   ])
 342
 343 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 344     [#include <openssl/rand.h>],
 345     [void RAND_add(const void *buf, int num, double entropy);],
 346     [RAND_add((void*)0,0,0); exit(0);], [],
 347     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 348
 349 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 350
 351 echo "tor_cv_library_openssl_dir is $tor_cv_library_openssl_dir"
 352 if test "$enable_static_openssl" = "yes"; then
 353    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 354      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 355    else
 356      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 357    fi
 358 else
 359      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 360 fi
 361 AC_SUBST(TOR_OPENSSL_LIBS)
 362
 363 dnl ------------------------------------------------------
 364 dnl Where do you live, zlib?  And how do we call you?
 365
 366 tor_openssl_pkg_redhat="zlib"
 367 tor_openssl_pkg_debian="zlib1g"
 368 tor_openssl_devpkg_redhat="zlib-devel"
 369 tor_openssl_devpkg_debian="zlib1g-dev"
 370
 371 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 372     [#include <zlib.h>],
 373     [const char * zlibVersion(void);],
 374     [zlibVersion(); exit(0);], [--with-zlib-dir],
 375     [/opt/zlib])
 376
 377 if test "$enable_static_zlib" = "yes"; then
 378    if test "$tor_cv_library_zlib_dir" = "(system)"; then
 379      AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
 380  using --enable-static-zlib")
 381    else
 382      TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
 383      echo "$TOR_LIBDIR_zlib/libz.a"
 384    fi
 385 else
 386      TOR_ZLIB_LIBS="-lz"
 387 fi
 388 AC_SUBST(TOR_ZLIB_LIBS)
 389
 390 dnl Make sure to enable support for large off_t if available.
 391
 392 AC_SYS_LARGEFILE
 393
 394 AC_CHECK_HEADERS(unistd.h string.h signal.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 395
 396 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 397
 398 dnl These headers are not essential
 399
 400 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h sys/file.h malloc_np.h sys/prctl.h)
 401
 402 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 403 [#ifdef HAVE_MALLOC_H
 404 #include <malloc.h>
 405 #endif
 406 #ifdef HAVE_MALLOC_MALLOC_H
 407 #include <malloc/malloc.h>
 408 #endif])
 409
 410 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 411 [#ifdef HAVE_SYS_TYPES_H
 412 #include <sys/types.h>
 413 #endif
 414 #ifdef HAVE_SYS_SOCKET_H
 415 #include <sys/socket.h>
 416 #endif])
 417 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 418 [#ifdef HAVE_SYS_TYPES_H
 419 #include <sys/types.h>
 420 #endif
 421 #ifdef HAVE_SYS_SOCKET_H
 422 #include <sys/socket.h>
 423 #endif
 424 #ifdef HAVE_NET_IF_H
 425 #include <net/if.h>
 426 #endif])
 427 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 428         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 429 [#ifdef HAVE_SYS_TYPES_H
 430 #include <sys/types.h>
 431 #endif
 432 #ifdef HAVE_SYS_SOCKET_H
 433 #include <sys/socket.h>
 434 #endif
 435 #ifdef HAVE_LIMITS_H
 436 #include <limits.h>
 437 #endif
 438 #ifdef HAVE_LINUX_TYPES_H
 439 #include <linux/types.h>
 440 #endif
 441 #ifdef HAVE_NETINET_IN6_H
 442 #include <netinet/in6.h>
 443 #endif
 444 #ifdef HAVE_NETINET_IN_H
 445 #include <netinet/in.h>
 446 #endif])
 447
 448 if test x$transparent = xtrue ; then
 449    transparent_ok=0
 450    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 451      transparent_ok=1
 452    fi
 453    if test x$linux_netfilter_ipv4 = x1 ; then
 454      transparent_ok=1
 455    fi
 456    if test x$transparent_ok = x1 ; then
 457      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 458      case $host in
 459        *-*-openbsd*)
 460          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 461      esac
 462    else
 463      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 464    fi
 465 fi
 466
 467 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 468 [#ifdef HAVE_SYS_TYPES_H
 469 #include <sys/types.h>
 470 #endif
 471 #ifdef HAVE_SYS_TIME_H
 472 #include <sys/time.h>
 473 #endif])
 474
 475 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 476 dnl Watch out.
 477
 478 AC_CHECK_SIZEOF(int8_t)
 479 AC_CHECK_SIZEOF(int16_t)
 480 AC_CHECK_SIZEOF(int32_t)
 481 AC_CHECK_SIZEOF(int64_t)
 482 AC_CHECK_SIZEOF(uint8_t)
 483 AC_CHECK_SIZEOF(uint16_t)
 484 AC_CHECK_SIZEOF(uint32_t)
 485 AC_CHECK_SIZEOF(uint64_t)
 486 AC_CHECK_SIZEOF(intptr_t)
 487 AC_CHECK_SIZEOF(uintptr_t)
 488
 489 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 490
 491 AC_CHECK_SIZEOF(char)
 492 AC_CHECK_SIZEOF(short)
 493 AC_CHECK_SIZEOF(int)
 494 AC_CHECK_SIZEOF(long)
 495 AC_CHECK_SIZEOF(long long)
 496 AC_CHECK_SIZEOF(__int64)
 497 AC_CHECK_SIZEOF(void *)
 498 AC_CHECK_SIZEOF(time_t)
 499 AC_CHECK_SIZEOF(size_t)
 500
 501 AC_CHECK_TYPES([uint, u_char, ssize_t])
 502
 503 dnl used to include sockaddr_storage, but everybody has that.
 504 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 505 [#ifdef HAVE_SYS_TYPES_H
 506 #include <sys/types.h>
 507 #endif
 508 #ifdef HAVE_NETINET_IN_H
 509 #include <netinet/in.h>
 510 #endif
 511 #ifdef HAVE_NETINET_IN6_H
 512 #include <netinet/in6.h>
 513 #endif
 514 #ifdef HAVE_SYS_SOCKET_H
 515 #include <sys/socket.h>
 516 #endif
 517 #ifdef MS_WINDOWS
 518 #define WIN32_WINNT 0x400
 519 #define _WIN32_WINNT 0x400
 520 #define WIN32_LEAN_AND_MEAN
 521 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 522 #include <winsock.h>
 523 #else
 524 #include <winsock2.h>
 525 #include <ws2tcpip.h>
 526 #endif
 527 #endif
 528 ])
 529 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 530 [#ifdef HAVE_SYS_TYPES_H
 531 #include <sys/types.h>
 532 #endif
 533 #ifdef HAVE_NETINET_IN_H
 534 #include <netinet/in.h>
 535 #endif
 536 #ifdef HAVE_NETINET_IN6_H
 537 #include <netinet/in6.h>
 538 #endif
 539 #ifdef HAVE_SYS_SOCKET_H
 540 #include <sys/socket.h>
 541 #endif
 542 #ifdef MS_WINDOWS
 543 #define WIN32_WINNT 0x400
 544 #define _WIN32_WINNT 0x400
 545 #define WIN32_LEAN_AND_MEAN
 546 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 547 #include <winsock.h>
 548 #else
 549 #include <winsock2.h>
 550 #include <ws2tcpip.h>
 551 #endif
 552 #endif
 553 ])
 554
 555 AC_CHECK_TYPES([rlim_t], , ,
 556 [#ifdef HAVE_SYS_TYPES_H
 557 #include <sys/types.h>
 558 #endif
 559 #ifdef HAVE_SYS_TIME_H
 560 #include <sys/time.h>
 561 #endif
 562 #ifdef HAVE_SYS_RESOURCE_H
 563 #include <sys/resource.h>
 564 #endif
 565 ])
 566
 567 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 568 AC_RUN_IFELSE([AC_LANG_SOURCE([
 569 #ifdef HAVE_SYS_TYPES_H
 570 #include <sys/types.h>
 571 #endif
 572 #ifdef HAVE_SYS_TIME_H
 573 #include <sys/time.h>
 574 #endif
 575 #ifdef HAVE_TIME_H
 576 #include <time.h>
 577 #endif
 578 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }])],
 579   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 580 ])
 581
 582 if test "$tor_cv_time_t_signed" = cross; then
 583   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 584 fi
 585
 586 if test "$tor_cv_time_t_signed" != no; then
 587   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 588             [Define to 1 iff time_t is signed])
 589 fi
 590
 591 AC_CACHE_CHECK([whether size_t is signed], tor_cv_size_t_signed, [
 592 AC_RUN_IFELSE([AC_LANG_SOURCE([
 593 #ifdef HAVE_SYS_TYPES_H
 594 #include <sys/types.h>
 595 #endif
 596 int main(int c, char**v) { if (((size_t)-1)<0) return 1; else return 0; }])],
 597   tor_cv_size_t_signed=no, tor_cv_size_t_signed=yes, tor_cv_size_t_signed=cross)
 598 ])
 599
 600 if test "$tor_cv_size_t_signed" = cross; then
 601   AC_MSG_NOTICE([Cross compiling: assuming that size_t is not signed.])
 602 fi
 603
 604 if test "$tor_cv_size_t_signed" = yes; then
 605   AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
 606 fi
 607
 608 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 609 #ifdef HAVE_SYS_SOCKET_H
 610 #include <sys/socket.h>
 611 #endif
 612 ])
 613
 614 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 615
 616 AC_CHECK_SIZEOF(cell_t)
 617
 618 # Now make sure that NULL can be represented as zero bytes.
 619 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 620 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 621 [[#include <stdlib.h>
 622 #include <string.h>
 623 #include <stdio.h>
 624 #ifdef HAVE_STDDEF_H
 625 #include <stddef.h>
 626 #endif
 627 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 628 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 629        [tor_cv_null_is_zero=yes],
 630        [tor_cv_null_is_zero=no],
 631        [tor_cv_null_is_zero=cross])])
 632
 633 if test "$tor_cv_null_is_zero" = cross ; then
 634   # Cross-compiling; let's hope that the target isn't raving mad.
 635   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 636 fi
 637
 638 if test "$tor_cv_null_is_zero" != no; then
 639   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 640             [Define to 1 iff memset(0) sets pointers to NULL])
 641 fi
 642
 643 # And what happens when we malloc zero?
 644 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 645 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 646 [[#include <stdlib.h>
 647 #include <string.h>
 648 #include <stdio.h>
 649 #ifdef HAVE_STDDEF_H
 650 #include <stddef.h>
 651 #endif
 652 int main () { return malloc(0)?0:1; }]])],
 653        [tor_cv_malloc_zero_works=yes],
 654        [tor_cv_malloc_zero_works=no],
 655        [tor_cv_malloc_zero_works=cross])])
 656
 657 if test "$tor_cv_malloc_zero_works" = cross; then
 658   # Cross-compiling; let's hope that the target isn't raving mad.
 659   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 660 fi
 661
 662 if test "$tor_cv_malloc_zero_works" = yes; then
 663   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 664             [Define to 1 iff malloc(0) returns a pointer])
 665 fi
 666
 667 # whether we seem to be in a 2s-complement world.
 668 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 669 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 670 [[int main () { int problem = ((-99) != (~99)+1);
 671 return problem ? 1 : 0; }]])],
 672        [tor_cv_twos_complement=yes],
 673        [tor_cv_twos_complement=no],
 674        [tor_cv_twos_complement=cross])])
 675
 676 if test "$tor_cv_twos_complement" = cross ; then
 677   # Cross-compiling; let's hope that the target isn't raving mad.
 678   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 679 fi
 680
 681 if test "$tor_cv_twos_complement" != no ; then
 682   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 683             [Define to 1 iff we represent negative integers with two's complement])
 684 fi
 685
 686 # Whether we should use the dmalloc memory allocation debugging library.
 687 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 688 AC_ARG_WITH(dmalloc,
 689 [  --with-dmalloc          Use debug memory allocation library. ],
 690 [if [[ "$withval" = "yes" ]]; then
 691   dmalloc=1
 692   AC_MSG_RESULT(yes)
 693 else
 694   dmalloc=1
 695   AC_MSG_RESULT(no)
 696 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 697 )
 698
 699 if [[ $dmalloc -eq 1 ]]; then
 700   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 701   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 702   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 703   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 704   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 705 fi
 706
 707 AC_ARG_WITH(tcmalloc,
 708 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 709 [ tcmalloc=yes ], [ tcmalloc=no ])
 710
 711 if test x$tcmalloc = xyes ; then
 712    LDFLAGS="-ltcmalloc $LDFLAGS"
 713 fi
 714
 715 # By default, we're going to assume we don't have mlockall()
 716 # bionic and other platforms have various broken mlockall subsystems.
 717 # Some systems don't have a working mlockall, some aren't linkable,
 718 # and some have it but don't declare it.
 719 AC_CHECK_FUNCS(mlockall)
 720 AC_CHECK_DECLS([mlockall], , , [
 721 #ifdef HAVE_SYS_MMAN_H
 722 #include <sys/mman.h>
 723 #endif])
 724
 725 # Allow user to specify an alternate syslog facility
 726 AC_ARG_WITH(syslog-facility,
 727 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 728 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 729 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 730 AC_SUBST(LOGFACILITY)
 731
 732 # Check if we have getresuid and getresgid
 733 AC_CHECK_FUNCS(getresuid getresgid)
 734
 735 # Check for gethostbyname_r in all its glorious incompatible versions.
 736 #   (This logic is based on that in Python's configure.in)
 737 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 738   [Define this if you have any gethostbyname_r()])
 739
 740 AC_CHECK_FUNC(gethostbyname_r, [
 741   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 742   OLD_CFLAGS=$CFLAGS
 743   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 744   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 745 #include <netdb.h>
 746   ], [[
 747     char *cp1, *cp2;
 748     struct hostent *h1, *h2;
 749     int i1, i2;
 750     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 751   ]])],[
 752     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 753     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 754      [Define this if gethostbyname_r takes 6 arguments])
 755     AC_MSG_RESULT(6)
 756   ], [
 757     AC_TRY_COMPILE([
 758 #include <netdb.h>
 759     ], [
 760       char *cp1, *cp2;
 761       struct hostent *h1;
 762       int i1, i2;
 763       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 764     ], [
 765       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 766       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 767         [Define this if gethostbyname_r takes 5 arguments])
 768       AC_MSG_RESULT(5)
 769    ], [
 770       AC_TRY_COMPILE([
 771 #include <netdb.h>
 772      ], [
 773        char *cp1;
 774        struct hostent *h1;
 775        struct hostent_data hd;
 776        (void) gethostbyname_r(cp1,h1,&hd);
 777      ], [
 778        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 779        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 780          [Define this if gethostbyname_r takes 3 arguments])
 781        AC_MSG_RESULT(3)
 782      ], [
 783        AC_MSG_RESULT(0)
 784      ])
 785   ])
 786  ])
 787  CFLAGS=$OLD_CFLAGS
 788 ])
 789
 790 AC_CACHE_CHECK([whether the C compiler supports __func__],
 791   tor_cv_have_func_macro,
 792   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 793 #include <stdio.h>
 794 int main(int c, char **v) { puts(__func__); }])],
 795   tor_cv_have_func_macro=yes,
 796   tor_cv_have_func_macro=no))
 797
 798 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 799   tor_cv_have_FUNC_macro,
 800   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 801 #include <stdio.h>
 802 int main(int c, char **v) { puts(__FUNC__); }])],
 803   tor_cv_have_FUNC_macro=yes,
 804   tor_cv_have_FUNC_macro=no))
 805
 806 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 807   tor_cv_have_FUNCTION_macro,
 808   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 809 #include <stdio.h>
 810 int main(int c, char **v) { puts(__FUNCTION__); }])],
 811   tor_cv_have_FUNCTION_macro=yes,
 812   tor_cv_have_FUNCTION_macro=no))
 813
 814 if test "$tor_cv_have_func_macro" = 'yes'; then
 815   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 816 fi
 817
 818 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 819   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 820 fi
 821
 822 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 823   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 824            [Defined if the compiler supports __FUNCTION__])
 825 fi
 826
 827 # $prefix stores the value of the --prefix command line option, or
 828 # NONE if the option wasn't set.  In the case that it wasn't set, make
 829 # it be the default, so that we can use it to expand directories now.
 830 if test "x$prefix" = "xNONE"; then
 831   prefix=$ac_default_prefix
 832 fi
 833
 834 # and similarly for $exec_prefix
 835 if test "x$exec_prefix" = "xNONE"; then
 836   exec_prefix=$prefix
 837 fi
 838
 839 if test "x$CONFDIR" = "x"; then
 840   CONFDIR=`eval echo $sysconfdir/tor`
 841 fi
 842 AC_SUBST(CONFDIR)
 843 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 844 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 845
 846 BINDIR=`eval echo $bindir`
 847 AC_SUBST(BINDIR)
 848 LOCALSTATEDIR=`eval echo $localstatedir`
 849 AC_SUBST(LOCALSTATEDIR)
 850
 851 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 852 # than autoconf's macros like.
 853 if test "$GCC" = yes; then
 854   CFLAGS="$CFLAGS -Wall -g -O2"
 855   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
 856   # accident waiting to happen.
 857   CFLAGS="$CFLAGS -fno-strict-aliasing"
 858 else
 859   CFLAGS="$CFLAGS -g -O"
 860   enable_gcc_warnings=no
 861   enable_gcc_warnings_advisory=no
 862 fi
 863
 864 # Add some more warnings which we use in development but not in the
 865 # released versions.  (Some relevant gcc versions can't handle these.)
 866 if test x$enable_gcc_warnings = xyes || test x$enable_gcc_warnings_advisory = xyes; then
 867
 868   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 869 #if !defined(__GNUC__) || (__GNUC__ < 4)
 870 #error
 871 #endif])], have_gcc4=yes, have_gcc4=no)
 872
 873   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 874 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 875 #error
 876 #endif])], have_gcc42=yes, have_gcc42=no)
 877
 878   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 879 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 880 #error
 881 #endif])], have_gcc43=yes, have_gcc43=no)
 882
 883   save_CFLAGS="$CFLAGS"
 884   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 885   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], have_shorten64_flag=yes,
 886                     have_shorten64_flag=no)
 887   CFLAGS="$save_CFLAGS"
 888
 889   case $host in
 890     *-*-openbsd*)
 891       # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
 892       # That's fine, except that the headers don't pass -Wredundant-decls.
 893       # Therefore, let's disable -Wsystem-headers when we're building
 894       # with maximal warnings on OpenBSD.
 895       CFLAGS="$CFLAGS -Wno-system-headers" ;;
 896   esac
 897
 898   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum"
 899   if test x$enable_gcc_warnings = xyes; then
 900     CFLAGS="$CFLAGS -Werror"
 901   fi
 902
 903   # Disabled, so we can use mallinfo(): -Waggregate-return
 904
 905   if test x$have_gcc4 = xyes ; then
 906     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 907     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 908   fi
 909
 910   if test x$have_gcc42 = xyes ; then
 911     # These warnings break gcc 4.0.2 and work on gcc 4.2
 912     # XXXX020 See if any of these work with earlier versions.
 913     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 914     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 915   fi
 916
 917   if test x$have_gcc43 = xyes ; then
 918     # These warnings break gcc 4.2 and work on gcc 4.3
 919     # XXXX020 See if any of these work with earlier versions.
 920     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 921   fi
 922
 923   if test x$have_shorten64_flag = xyes ; then
 924     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 925   fi
 926
 927 ##This will break the world on some 64-bit architectures
 928 # CFLAGS="$CFLAGS -Winline"
 929 fi
 930
 931
 932
 933 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 934
 935 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile src/config/torrc.sample src/Makefile doc/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/test/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 936 AC_OUTPUT
 937
 938 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 939   ./contrib/updateVersions.pl
 940 fi
 941