configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.1.10-alpha-dev)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I../common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(buf-freelists,
  40    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  41 AC_ARG_ENABLE(openbsd-malloc,
  42    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  43 AC_ARG_ENABLE(instrument-downloads,
  44    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  45
  46 if test x$enable_buf_freelists != xno; then
  47   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  48             [Defined if we try to use freelists for buffer RAM chunks])
  49 fi
  50 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  51 if test x$enable_instrument_downloads == xyes; then
  52   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  53             [Defined if we want to keep track of how much of each kind of resource we download.])
  54 fi
  55
  56 AC_ARG_ENABLE(transparent,
  57      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  58      [case "${enableval}" in
  59         yes) transparent=true ;;
  60         no)  transparent=false ;;
  61         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  62       esac], [transparent=true])
  63
  64 AC_ARG_ENABLE(threads,
  65      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  66
  67 if test x$enable_threads = x; then
  68    case $host in
  69     *-*-solaris* )
  70      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  71      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  72 cpu workers lock up here, so I will disable threads.])
  73      enable_threads="no";;
  74     *)
  75      enable_threads="yes";;
  76    esac
  77 fi
  78
  79 if test "$enable_threads" = "yes"; then
  80   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  81 fi
  82
  83 case $host in
  84    *-*-solaris* )
  85      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  86      ;;
  87 esac
  88
  89 AC_ARG_ENABLE(geoip-stats,
  90      AS_HELP_STRING(--enable-geoip-stats, enable code for directories to collect per-country statistics))
  91
  92 if test "$enable_geoip_stats" = "yes"; then
  93   AC_DEFINE(ENABLE_GEOIP_STATS, 1, [Defined if we try to collect per-country statistics])
  94 fi
  95
  96 AC_ARG_ENABLE(gcc-warnings,
  97      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  98
  99 AC_PROG_CC
 100 AC_PROG_CPP
 101 AC_PROG_MAKE_SET
 102 AC_PROG_RANLIB
 103
 104 TORUSER=_tor
 105 AC_ARG_WITH(tor-user,
 106         [  --with-tor-user=NAME    Specify username for tor daemon ],
 107         [
 108            TORUSER=$withval
 109         ]
 110 )
 111 AC_SUBST(TORUSER)
 112
 113 TORGROUP=_tor
 114 AC_ARG_WITH(tor-group,
 115         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 116         [
 117            TORGROUP=$withval
 118         ]
 119 )
 120 AC_SUBST(TORGROUP)
 121
 122
 123 dnl If WIN32 is defined and non-zero, we are building for win32
 124 AC_MSG_CHECKING([for win32])
 125 AC_RUN_IFELSE([
 126 int main(int c, char **v) {
 127 #ifdef WIN32
 128 #if WIN32
 129   return 0;
 130 #else
 131   return 1;
 132 #endif
 133 #else
 134   return 2;
 135 #endif
 136 }],
 137 bwin32=true; AC_MSG_RESULT([yes]),
 138 bwin32=false; AC_MSG_RESULT([no]),
 139 bwin32=cross; AC_MSG_RESULT([cross])
 140 )
 141
 142 if test "$bwin32" = cross; then
 143 AC_MSG_CHECKING([for win32 (cross)])
 144 AC_COMPILE_IFELSE([
 145 #ifdef WIN32
 146 int main(int c, char **v) {return 0;}
 147 #else
 148 #error
 149 int main(int c, char **v) {return x(y);}
 150 #endif
 151 ],
 152 bwin32=true; AC_MSG_RESULT([yes]),
 153 bwin32=false; AC_MSG_RESULT([no]))
 154 fi
 155
 156 if test "$bwin32" = true; then
 157 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 158 fi
 159 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 160
 161 dnl Enable C99 when compiling with MIPSpro
 162 AC_MSG_CHECKING([for MIPSpro compiler])
 163 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 164 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 165 #error
 166   return x(y);
 167 #endif
 168 ]),
 169 bmipspro=false; AC_MSG_RESULT(no),
 170 bmipspro=true; AC_MSG_RESULT(yes))
 171
 172 if test "$bmipspro" = true; then
 173   CFLAGS="$CFLAGS -c99"
 174 fi
 175
 176 AC_C_BIGENDIAN
 177
 178 AC_SEARCH_LIBS(socket, [socket])
 179 AC_SEARCH_LIBS(gethostbyname, [nsl])
 180 AC_SEARCH_LIBS(dlopen, [dl])
 181 AC_SEARCH_LIBS(inet_aton, [resolv])
 182
 183 if test "$enable_threads" = "yes"; then
 184   AC_SEARCH_LIBS(pthread_create, [pthread])
 185   AC_SEARCH_LIBS(pthread_detach, [pthread])
 186 fi
 187
 188 dnl -------------------------------------------------------------------
 189 dnl Check for functions before libevent, since libevent-1.2 apparently
 190 dnl exports strlcpy without defining it in a header.
 191
 192 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull getaddrinfo localtime_r gmtime_r memmem strtok_r writev readv flock)
 193
 194 using_custom_malloc=no
 195 if test x$enable_openbsd_malloc = xyes ; then
 196    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 197    using_custom_malloc=yes
 198 fi
 199 if test x$tcmalloc = xyes ; then
 200    using_custom_malloc=yes
 201 fi
 202 if test $using_custom_malloc = no ; then
 203    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 204 fi
 205
 206 if test "$enable_threads" = "yes"; then
 207   AC_CHECK_HEADERS(pthread.h)
 208   AC_CHECK_FUNCS(pthread_create)
 209 fi
 210
 211 dnl ------------------------------------------------------
 212 dnl Where do you live, libevent?  And how do we call you?
 213
 214 if test "$bwin32" = true; then
 215   TOR_LIB_WS32=-lws2_32
 216   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 217   # think it's actually necessary.
 218   TOR_LIB_GDI=-lgdi32
 219 else
 220   TOR_LIB_WS32=
 221   TOR_LIB_GDI=
 222 fi
 223 AC_SUBST(TOR_LIB_WS32)
 224 AC_SUBST(TOR_LIB_GDI)
 225
 226 dnl We need to do this before we try our disgusting hack below.
 227 AC_CHECK_HEADERS([sys/types.h])
 228
 229 dnl This is a disgusting hack so we safely include older libevent headers.
 230 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 231 AC_CHECK_TYPE(u_int32_t, unsigned long)
 232 AC_CHECK_TYPE(u_int16_t, unsigned short)
 233 AC_CHECK_TYPE(u_int8_t, unsigned char)
 234
 235 tor_libevent_pkg_redhat="libevent"
 236 tor_libevent_pkg_debian="libevent-dev"
 237 tor_libevent_devpkg_redhat="libevent-devel"
 238 tor_libevent_devpkg_debian="libevent-dev"
 239
 240 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 241 #ifdef WIN32
 242 #include <winsock2.h>
 243 #endif
 244 #include <stdlib.h>
 245 #include <sys/time.h>
 246 #include <sys/types.h>
 247 #include <event.h>], [
 248 #ifdef WIN32
 249 #include <winsock2.h>
 250 #endif
 251 void exit(int); void *event_init(void);],
 252     [
 253 #ifdef WIN32
 254 {WSADATA d; WSAStartup(0x101,&d); }
 255 #endif
 256 event_init(); exit(0);
 257 ], [--with-libevent-dir], [/opt/libevent])
 258
 259 dnl Now check for particular libevent functions.
 260 save_LIBS="$LIBS"
 261 save_LDFLAGS="$LDFLAGS"
 262 save_CPPFLAGS="$CPPFLAGS"
 263 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 264 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 265 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 266 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 267 LIBS="$save_LIBS"
 268 LDFLAGS="$save_LDFLAGS"
 269 CPPFLAGS="$save_CPPFLAGS"
 270
 271 dnl ------------------------------------------------------
 272 dnl Where do you live, openssl?  And how do we call you?
 273
 274 tor_openssl_pkg_redhat="openssl"
 275 tor_openssl_pkg_debian="libssl"
 276 tor_openssl_devpkg_redhat="openssl-devel"
 277 tor_openssl_devpkg_debian="libssl-dev"
 278
 279 ALT_openssl_WITHVAL=""
 280 AC_ARG_WITH(ssl-dir,
 281   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 282   [
 283       if test "x$withval" != xno && test "x$withval" != "x" ; then
 284          ALT_openssl_WITHVAL="$withval"
 285       fi
 286   ])
 287
 288 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 289     [#include <openssl/rand.h>],
 290     [void RAND_add(const void *buf, int num, double entropy);],
 291     [RAND_add((void*)0,0,0); exit(0);], [],
 292     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 293
 294 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 295
 296 dnl ------------------------------------------------------
 297 dnl Where do you live, zlib?  And how do we call you?
 298
 299 tor_openssl_pkg_redhat="zlib"
 300 tor_openssl_pkg_debian="zlib1g"
 301 tor_openssl_devpkg_redhat="zlib-devel"
 302 tor_openssl_devpkg_debian="zlib1g-dev"
 303
 304 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 305     [#include <zlib.h>],
 306     [const char * zlibVersion(void);],
 307     [zlibVersion(); exit(0);], [--with-zlib-dir],
 308     [/opt/zlib])
 309
 310 dnl Make sure to enable support for large off_t if available.
 311
 312 AC_SYS_LARGEFILE
 313
 314 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 315
 316 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 317
 318 dnl These headers are not essential
 319
 320 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h sys/file.h malloc_np.h)
 321
 322 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 323 [#ifdef HAVE_MALLOC_H
 324 #include <malloc.h>
 325 #endif
 326 #ifdef HAVE_MALLOC_MALLOC_H
 327 #include <malloc/malloc.h>
 328 #endif])
 329
 330 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 331 [#ifdef HAVE_SYS_TYPES_H
 332 #include <sys/types.h>
 333 #endif
 334 #ifdef HAVE_SYS_SOCKET_H
 335 #include <sys/socket.h>
 336 #endif])
 337 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 338 [#ifdef HAVE_SYS_TYPES_H
 339 #include <sys/types.h>
 340 #endif
 341 #ifdef HAVE_SYS_SOCKET_H
 342 #include <sys/socket.h>
 343 #endif
 344 #ifdef HAVE_NET_IF_H
 345 #include <net/if.h>
 346 #endif])
 347 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 348         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 349 [#ifdef HAVE_SYS_TYPES_H
 350 #include <sys/types.h>
 351 #endif
 352 #ifdef HAVE_SYS_SOCKET_H
 353 #include <sys/socket.h>
 354 #endif
 355 #ifdef HAVE_LIMITS_H
 356 #include <limits.h>
 357 #endif
 358 #ifdef HAVE_LINUX_TYPES_H
 359 #include <linux/types.h>
 360 #endif
 361 #ifdef HAVE_NETINET_IN6_H
 362 #include <netinet/in6.h>
 363 #endif
 364 #ifdef HAVE_NETINET_IN_H
 365 #include <netinet/in.h>
 366 #endif])
 367
 368 if test x$transparent = xtrue ; then
 369    transparent_ok=0
 370    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 371      transparent_ok=1
 372    fi
 373    if test x$linux_netfilter_ipv4 = x1 ; then
 374      transparent_ok=1
 375    fi
 376    if test x$transparent_ok = x1 ; then
 377      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 378      case $host in
 379        *-*-openbsd*)
 380          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 381      esac
 382    else
 383      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 384    fi
 385 fi
 386
 387 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 388 [#ifdef HAVE_SYS_TYPES_H
 389 #include <sys/types.h>
 390 #endif
 391 #ifdef HAVE_SYS_TIME_H
 392 #include <sys/time.h>
 393 #endif])
 394
 395 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 396 dnl Watch out.
 397
 398 AC_CHECK_SIZEOF(int8_t)
 399 AC_CHECK_SIZEOF(int16_t)
 400 AC_CHECK_SIZEOF(int32_t)
 401 AC_CHECK_SIZEOF(int64_t)
 402 AC_CHECK_SIZEOF(uint8_t)
 403 AC_CHECK_SIZEOF(uint16_t)
 404 AC_CHECK_SIZEOF(uint32_t)
 405 AC_CHECK_SIZEOF(uint64_t)
 406 AC_CHECK_SIZEOF(intptr_t)
 407 AC_CHECK_SIZEOF(uintptr_t)
 408
 409 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 410
 411 AC_CHECK_SIZEOF(char)
 412 AC_CHECK_SIZEOF(short)
 413 AC_CHECK_SIZEOF(int)
 414 AC_CHECK_SIZEOF(long)
 415 AC_CHECK_SIZEOF(long long)
 416 AC_CHECK_SIZEOF(__int64)
 417 AC_CHECK_SIZEOF(void *)
 418 AC_CHECK_SIZEOF(time_t)
 419 AC_CHECK_SIZEOF(size_t)
 420
 421 AC_CHECK_TYPES([uint, u_char, ssize_t])
 422
 423 dnl used to include sockaddr_storage, but everybody has that.
 424 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 425 [#ifdef HAVE_SYS_TYPES_H
 426 #include <sys/types.h>
 427 #endif
 428 #ifdef HAVE_NETINET_IN_H
 429 #include <netinet/in.h>
 430 #endif
 431 #ifdef HAVE_NETINET_IN6_H
 432 #include <netinet/in6.h>
 433 #endif
 434 #ifdef HAVE_SYS_SOCKET_H
 435 #include <sys/socket.h>
 436 #endif
 437 #ifdef MS_WINDOWS
 438 #define WIN32_WINNT 0x400
 439 #define _WIN32_WINNT 0x400
 440 #define WIN32_LEAN_AND_MEAN
 441 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 442 #include <winsock.h>
 443 #else
 444 #include <winsock2.h>
 445 #include <ws2tcpip.h>
 446 #endif
 447 #endif
 448 ])
 449 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 450 [#ifdef HAVE_SYS_TYPES_H
 451 #include <sys/types.h>
 452 #endif
 453 #ifdef HAVE_NETINET_IN_H
 454 #include <netinet/in.h>
 455 #endif
 456 #ifdef HAVE_NETINET_IN6_H
 457 #include <netinet/in6.h>
 458 #endif
 459 #ifdef HAVE_SYS_SOCKET_H
 460 #include <sys/socket.h>
 461 #endif
 462 #ifdef MS_WINDOWS
 463 #define WIN32_WINNT 0x400
 464 #define _WIN32_WINNT 0x400
 465 #define WIN32_LEAN_AND_MEAN
 466 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 467 #include <winsock.h>
 468 #else
 469 #include <winsock2.h>
 470 #include <ws2tcpip.h>
 471 #endif
 472 #endif
 473 ])
 474
 475 AC_CHECK_TYPES([rlim_t], , ,
 476 [#ifdef HAVE_SYS_TYPES_H
 477 #include <sys/types.h>
 478 #endif
 479 #ifdef HAVE_SYS_TIME_H
 480 #include <sys/time.h>
 481 #endif
 482 #ifdef HAVE_SYS_RESOURCE_H
 483 #include <sys/resource.h>
 484 #endif
 485 ])
 486
 487 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 488 AC_RUN_IFELSE(AC_LANG_SOURCE([
 489 #ifdef HAVE_SYS_TYPES_H
 490 #include <sys/types.h>
 491 #endif
 492 #ifdef HAVE_SYS_TIME_H
 493 #include <sys/time.h>
 494 #endif
 495 #ifdef HAVE_TIME_H
 496 #include <time.h>
 497 #endif
 498 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 499   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 500 ])
 501
 502 if test "$tor_cv_time_t_signed" = cross; then
 503   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 504 fi
 505
 506 if test "$tor_cv_time_t_signed" != no; then
 507   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 508             [Define to 1 iff time_t is signed])
 509 fi
 510
 511 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 512 #ifdef HAVE_SYS_SOCKET_H
 513 #include <sys/socket.h>
 514 #endif
 515 ])
 516
 517 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 518
 519 AC_CHECK_SIZEOF(cell_t)
 520
 521 # Now make sure that NULL can be represented as zero bytes.
 522 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 523 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 524 [[#include <stdlib.h>
 525 #include <string.h>
 526 #include <stdio.h>
 527 #ifdef HAVE_STDDEF_H
 528 #include <stddef.h>
 529 #endif
 530 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 531 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 532        [tor_cv_null_is_zero=yes],
 533        [tor_cv_null_is_zero=no],
 534        [tor_cv_null_is_zero=cross])])
 535
 536 if test "$tor_cv_null_is_zero" = cross ; then
 537   # Cross-compiling; let's hope that the target isn't raving mad.
 538   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 539 fi
 540
 541 if test "$tor_cv_null_is_zero" != no; then
 542   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 543             [Define to 1 iff memset(0) sets pointers to NULL])
 544 fi
 545
 546 # And what happens when we malloc zero?
 547 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 548 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 549 [[#include <stdlib.h>
 550 #include <string.h>
 551 #include <stdio.h>
 552 #ifdef HAVE_STDDEF_H
 553 #include <stddef.h>
 554 #endif
 555 int main () { return malloc(0)?0:1; }]])],
 556        [tor_cv_malloc_zero_works=yes],
 557        [tor_cv_malloc_zero_works=no],
 558        [tor_cv_malloc_zero_works=cross])])
 559
 560 if test "$tor_cv_malloc_zero_works" = cross; then
 561   # Cross-compiling; let's hope that the target isn't raving mad.
 562   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 563 fi
 564
 565 if test "$tor_cv_malloc_zero_works" = yes; then
 566   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 567             [Define to 1 iff malloc(0) returns a pointer])
 568 fi
 569
 570 # whether we seem to be in a 2s-complement world.
 571 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 572 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 573 [[int main () { int problem = ((-99) != (~99)+1);
 574 return problem ? 1 : 0; }]])],
 575        [tor_cv_twos_complement=yes],
 576        [tor_cv_twos_complement=no],
 577        [tor_cv_twos_complement=cross])])
 578
 579 if test "$tor_cv_twos_complement" = cross ; then
 580   # Cross-compiling; let's hope that the target isn't raving mad.
 581   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 582 fi
 583
 584 if test "$tor_cv_twos_complement" != no ; then
 585   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 586             [Define to 1 iff we represent negative integers with two's complement])
 587 fi
 588
 589 # Whether we should use the dmalloc memory allocation debugging library.
 590 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 591 AC_ARG_WITH(dmalloc,
 592 [  --with-dmalloc          Use debug memory allocation library. ],
 593 [if [[ "$withval" = "yes" ]]; then
 594   dmalloc=1
 595   AC_MSG_RESULT(yes)
 596 else
 597   dmalloc=1
 598   AC_MSG_RESULT(no)
 599 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 600 )
 601
 602 if [[ $dmalloc -eq 1 ]]; then
 603   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 604   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 605   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 606   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 607   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 608 fi
 609
 610 AC_ARG_WITH(tcmalloc,
 611 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 612 [ tcmalloc=yes ], [ tcmalloc=no ])
 613
 614 if test x$tcmalloc = xyes ; then
 615    LDFLAGS="-ltcmalloc $LDFLAGS"
 616 fi
 617
 618 # Allow user to specify an alternate syslog facility
 619 AC_ARG_WITH(syslog-facility,
 620 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 621 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 622 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 623 AC_SUBST(LOGFACILITY)
 624
 625 # Check if we have getresuid and getresgid
 626 AC_CHECK_FUNCS(getresuid getresgid)
 627
 628 # Check for gethostbyname_r in all its glorious incompatible versions.
 629 #   (This logic is based on that in Python's configure.in)
 630 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 631   [Define this if you have any gethostbyname_r()])
 632
 633 AC_CHECK_FUNC(gethostbyname_r, [
 634   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 635   OLD_CFLAGS=$CFLAGS
 636   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 637   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 638 #include <netdb.h>
 639   ], [[
 640     char *cp1, *cp2;
 641     struct hostent *h1, *h2;
 642     int i1, i2;
 643     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 644   ]]),[
 645     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 646     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 647      [Define this if gethostbyname_r takes 6 arguments])
 648     AC_MSG_RESULT(6)
 649   ], [
 650     AC_TRY_COMPILE([
 651 #include <netdb.h>
 652     ], [
 653       char *cp1, *cp2;
 654       struct hostent *h1;
 655       int i1, i2;
 656       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 657     ], [
 658       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 659       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 660         [Define this if gethostbyname_r takes 5 arguments])
 661       AC_MSG_RESULT(5)
 662    ], [
 663       AC_TRY_COMPILE([
 664 #include <netdb.h>
 665      ], [
 666        char *cp1;
 667        struct hostent *h1;
 668        struct hostent_data hd;
 669        (void) gethostbyname_r(cp1,h1,&hd);
 670      ], [
 671        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 672        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 673          [Define this if gethostbyname_r takes 3 arguments])
 674        AC_MSG_RESULT(3)
 675      ], [
 676        AC_MSG_RESULT(0)
 677      ])
 678   ])
 679  ])
 680  CFLAGS=$OLD_CFLAGS
 681 ])
 682
 683 AC_CACHE_CHECK([whether the C compiler supports __func__],
 684   tor_cv_have_func_macro,
 685   AC_COMPILE_IFELSE([
 686 #include <stdio.h>
 687 int main(int c, char **v) { puts(__func__); }],
 688   tor_cv_have_func_macro=yes,
 689   tor_cv_have_func_macro=no))
 690
 691 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 692   tor_cv_have_FUNC_macro,
 693   AC_COMPILE_IFELSE([
 694 #include <stdio.h>
 695 int main(int c, char **v) { puts(__FUNC__); }],
 696   tor_cv_have_FUNC_macro=yes,
 697   tor_cv_have_FUNC_macro=no))
 698
 699 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 700   tor_cv_have_FUNCTION_macro,
 701   AC_COMPILE_IFELSE([
 702 #include <stdio.h>
 703 int main(int c, char **v) { puts(__FUNCTION__); }],
 704   tor_cv_have_FUNCTION_macro=yes,
 705   tor_cv_have_FUNCTION_macro=no))
 706
 707 if test "$tor_cv_have_func_macro" = 'yes'; then
 708   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 709 fi
 710
 711 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 712   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 713 fi
 714
 715 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 716   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 717            [Defined if the compiler supports __FUNCTION__])
 718 fi
 719
 720 # $prefix stores the value of the --prefix command line option, or
 721 # NONE if the option wasn't set.  In the case that it wasn't set, make
 722 # it be the default, so that we can use it to expand directories now.
 723 if test "x$prefix" = "xNONE"; then
 724   prefix=$ac_default_prefix
 725 fi
 726
 727 # and similarly for $exec_prefix
 728 if test "x$exec_prefix" = "xNONE"; then
 729   exec_prefix=$prefix
 730 fi
 731
 732 if test "x$CONFDIR" = "x"; then
 733   CONFDIR=`eval echo $sysconfdir/tor`
 734 fi
 735 AC_SUBST(CONFDIR)
 736 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 737 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 738
 739 BINDIR=`eval echo $bindir`
 740 AC_SUBST(BINDIR)
 741 LOCALSTATEDIR=`eval echo $localstatedir`
 742 AC_SUBST(LOCALSTATEDIR)
 743
 744 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 745 # than autoconf's macros like.
 746 if test "$ac_cv_c_compiler_gnu" = yes; then
 747   CFLAGS="$CFLAGS -Wall -g -O2"
 748 else
 749   CFLAGS="$CFLAGS -g -O"
 750   enable_gcc_warnings=no
 751 fi
 752
 753 # Add some more warnings which we use in development but not in the
 754 # released versions.  (Some relevant gcc versions can't handle these.)
 755 if test x$enable_gcc_warnings = xyes; then
 756
 757   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 758 #if !defined(__GNUC__) || (__GNUC__ < 4)
 759 #error
 760 #endif]), have_gcc4=yes, have_gcc4=no)
 761
 762   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 763 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 764 #error
 765 #endif]), have_gcc42=yes, have_gcc42=no)
 766
 767   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 768 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 769 #error
 770 #endif]), have_gcc43=yes, have_gcc43=no)
 771
 772   save_CFLAGS="$CFLAGS"
 773   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 774   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 775                     have_shorten64_flag=no)
 776   CFLAGS="$save_CFLAGS"
 777
 778   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 779
 780   # Disabled, so we can use mallinfo(): -Waggregate-return
 781
 782   if test x$have_gcc4 = xyes ; then
 783     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 784     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 785   fi
 786
 787   if test x$have_gcc42 = xyes ; then
 788     # These warnings break gcc 4.0.2 and work on gcc 4.2
 789     # XXXX020 Use -fstack-protector.
 790     # XXXX020 See if any of these work with earlier versions.
 791     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 792     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 793   fi
 794
 795   if test x$have_gcc43 = xyes ; then
 796     # These warnings break gcc 4.2 and work on gcc 4.3
 797     # XXXX020 See if any of these work with earlier versions.
 798     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 799   fi
 800
 801   if test x$have_shorten64_flag = xyes ; then
 802     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 803   fi
 804
 805 ##This will break the world on some 64-bit architectures
 806 # CFLAGS="$CFLAGS -Winline"
 807 fi
 808
 809
 810
 811 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 812
 813 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh contrib/tor.wxs])
 814 AC_OUTPUT
 815
 816 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 817   ./contrib/updateVersions.pl
 818 fi
 819