configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.1.4-alpha-dev)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I../common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(cell-pool,
  40      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  41 AC_ARG_ENABLE(buf-freelists,
  42    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  43 AC_ARG_ENABLE(openbsd-malloc,
  44    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  45 AC_ARG_ENABLE(instrument-downloads,
  46    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  47
  48
  49 if test x$enable_cell_pool != xno; then
  50   AC_DEFINE(ENABLE_CELL_POOL, 1,
  51             [Defined if we try to use the pool allocator for queued cells])
  52 fi
  53 if test x$enable_buf_freelists != xno; then
  54   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  55             [Defined if we try to use freelists for buffer RAM chunks])
  56 fi
  57 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  58 if test x$enable_instrument_downloads == xyes; then
  59   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  60             [Defined if we want to keep track of how much of each kind of resource we download.])
  61 fi
  62
  63 AC_ARG_ENABLE(transparent,
  64      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  65      [case "${enableval}" in
  66         yes) transparent=true ;;
  67         no)  transparent=false ;;
  68         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  69       esac], [transparent=true])
  70
  71 AC_ARG_ENABLE(threads,
  72      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  73
  74 if test x$enable_threads = x; then
  75    case $host in
  76     *-*-solaris* )
  77      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  78      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  79 cpu workers lock up here, so I will disable threads.])
  80      enable_threads="no";;
  81     *)
  82      enable_threads="yes";;
  83    esac
  84 fi
  85
  86 if test "$enable_threads" = "yes"; then
  87   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  88 fi
  89
  90 case $host in
  91    *-*-solaris* )
  92      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  93      ;;
  94 esac
  95
  96 AC_ARG_ENABLE(geoip-stats,
  97      AS_HELP_STRING(--enable-geoip-stats, enable code for directories to collect per-country statistics))
  98
  99 if test "$enable_geoip_stats" = "yes"; then
 100   AC_DEFINE(ENABLE_GEOIP_STATS, 1, [Defined if we try to collect per-country statistics])
 101 fi
 102
 103 AC_ARG_ENABLE(gcc-warnings,
 104      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
 105
 106 AC_PROG_CC
 107 AC_PROG_CPP
 108 AC_PROG_MAKE_SET
 109 AC_PROG_RANLIB
 110
 111 TORUSER=_tor
 112 AC_ARG_WITH(tor-user,
 113         [  --with-tor-user=NAME    Specify username for tor daemon ],
 114         [
 115            TORUSER=$withval
 116         ]
 117 )
 118 AC_SUBST(TORUSER)
 119
 120 TORGROUP=_tor
 121 AC_ARG_WITH(tor-group,
 122         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 123         [
 124            TORGROUP=$withval
 125         ]
 126 )
 127 AC_SUBST(TORGROUP)
 128
 129
 130 dnl If WIN32 is defined and non-zero, we are building for win32
 131 AC_MSG_CHECKING([for win32])
 132 AC_RUN_IFELSE([
 133 int main(int c, char **v) {
 134 #ifdef WIN32
 135 #if WIN32
 136   return 0;
 137 #else
 138   return 1;
 139 #endif
 140 #else
 141   return 2;
 142 #endif
 143 }],
 144 bwin32=true; AC_MSG_RESULT([yes]),
 145 bwin32=false; AC_MSG_RESULT([no]),
 146 bwin32=cross; AC_MSG_RESULT([cross])
 147 )
 148
 149 if test "$bwin32" = cross; then
 150 AC_MSG_CHECKING([for win32 (cross)])
 151 AC_COMPILE_IFELSE([
 152 #ifdef WIN32
 153 int main(int c, char **v) {return 0;}
 154 #else
 155 #error
 156 int main(int c, char **v) {return x(y);}
 157 #endif
 158 ],
 159 bwin32=true; AC_MSG_RESULT([yes]),
 160 bwin32=false; AC_MSG_RESULT([no]))
 161 fi
 162
 163 if test "$bwin32" = true; then
 164 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 165 fi
 166 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 167
 168 dnl Enable C99 when compiling with MIPSpro
 169 AC_MSG_CHECKING([for MIPSpro compiler])
 170 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 171 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 172 #error
 173   return x(y);
 174 #endif
 175 ]),
 176 bmipspro=false; AC_MSG_RESULT(no),
 177 bmipspro=true; AC_MSG_RESULT(yes))
 178
 179 if test "$bmipspro" = true; then
 180   CFLAGS="$CFLAGS -c99"
 181 fi
 182
 183 AC_C_BIGENDIAN
 184
 185 AC_SEARCH_LIBS(socket, [socket])
 186 AC_SEARCH_LIBS(gethostbyname, [nsl])
 187 AC_SEARCH_LIBS(dlopen, [dl])
 188 AC_SEARCH_LIBS(inet_aton, [resolv])
 189
 190 if test "$enable_threads" = "yes"; then
 191   AC_SEARCH_LIBS(pthread_create, [pthread])
 192   AC_SEARCH_LIBS(pthread_detach, [pthread])
 193 fi
 194
 195 dnl -------------------------------------------------------------------
 196 dnl Check for functions before libevent, since libevent-1.2 apparently
 197 dnl exports strlcpy without defining it in a header.
 198
 199 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop writev readv)
 200
 201 using_custom_malloc=no
 202 if test x$enable_openbsd_malloc = xyes ; then
 203    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 204    using_custom_malloc=yes
 205 fi
 206 if test x$tcmalloc = xyes ; then
 207    using_custom_malloc=yes
 208 fi
 209 if test $using_custom_malloc = no ; then
 210    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 211 fi
 212
 213 if test "$enable_threads" = "yes"; then
 214   AC_CHECK_HEADERS(pthread.h)
 215   AC_CHECK_FUNCS(pthread_create)
 216 fi
 217
 218 dnl ------------------------------------------------------
 219 dnl Where do you live, libevent?  And how do we call you?
 220
 221 if test "$bwin32" = true; then
 222   TOR_LIB_WS32=-lws2_32
 223   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 224   # think it's actually necessary.
 225   TOR_LIB_GDI=-lgdi32
 226 else
 227   TOR_LIB_WS32=
 228   TOR_LIB_GDI=
 229 fi
 230 AC_SUBST(TOR_LIB_WS32)
 231 AC_SUBST(TOR_LIB_GDI)
 232
 233 dnl We need to do this before we try our disgusting hack below.
 234 AC_CHECK_HEADERS([sys/types.h])
 235
 236 dnl This is a disgusting hack so we safely include older libevent headers.
 237 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 238 AC_CHECK_TYPE(u_int32_t, unsigned long)
 239 AC_CHECK_TYPE(u_int16_t, unsigned short)
 240 AC_CHECK_TYPE(u_int8_t, unsigned char)
 241
 242 tor_libevent_pkg_redhat="libevent"
 243 tor_libevent_pkg_debian="libevent-dev"
 244 tor_libevent_devpkg_redhat="libevent-devel"
 245 tor_libevent_devpkg_debian="libevent-dev"
 246
 247 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 248 #ifdef WIN32
 249 #include <winsock2.h>
 250 #endif
 251 #include <stdlib.h>
 252 #include <sys/time.h>
 253 #include <sys/types.h>
 254 #include <event.h>], [
 255 #ifdef WIN32
 256 #include <winsock2.h>
 257 #endif
 258 void exit(int); void *event_init(void);],
 259     [
 260 #ifdef WIN32
 261 {WSADATA d; WSAStartup(0x101,&d); }
 262 #endif
 263 event_init(); exit(0);
 264 ], [--with-libevent-dir], [/opt/libevent])
 265
 266 dnl Now check for particular libevent functions.
 267 save_LIBS="$LIBS"
 268 save_LDFLAGS="$LDFLAGS"
 269 save_CPPFLAGS="$CPPFLAGS"
 270 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 271 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 272 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 273 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 274 LIBS="$save_LIBS"
 275 LDFLAGS="$save_LDFLAGS"
 276 CPPFLAGS="$save_CPPFLAGS"
 277
 278 dnl ------------------------------------------------------
 279 dnl Where do you live, openssl?  And how do we call you?
 280
 281 tor_openssl_pkg_redhat="openssl"
 282 tor_openssl_pkg_debian="libssl"
 283 tor_openssl_devpkg_redhat="openssl-devel"
 284 tor_openssl_devpkg_debian="libssl-dev"
 285
 286 ALT_openssl_WITHVAL=""
 287 AC_ARG_WITH(ssl-dir,
 288   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 289   [
 290       if test "x$withval" != xno && test "x$withval" != "x" ; then
 291          ALT_openssl_WITHVAL="$withval"
 292       fi
 293   ])
 294
 295 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 296     [#include <openssl/rand.h>],
 297     [void RAND_add(const void *buf, int num, double entropy);],
 298     [RAND_add((void*)0,0,0); exit(0);], [],
 299     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 300
 301 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 302
 303 dnl ------------------------------------------------------
 304 dnl Where do you live, zlib?  And how do we call you?
 305
 306 tor_openssl_pkg_redhat="zlib"
 307 tor_openssl_pkg_debian="zlib1g"
 308 tor_openssl_devpkg_redhat="zlib-devel"
 309 tor_openssl_devpkg_debian="zlib1g-dev"
 310
 311 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 312     [#include <zlib.h>],
 313     [const char * zlibVersion(void);],
 314     [zlibVersion(); exit(0);], [--with-zlib-dir],
 315     [/opt/zlib])
 316
 317 dnl Make sure to enable support for large off_t if available.
 318
 319 AC_SYS_LARGEFILE
 320
 321 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 322
 323 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 324
 325 dnl These headers are not essential
 326
 327 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h)
 328
 329 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 330 [#ifdef HAVE_MALLOC_H
 331 #include <malloc.h>
 332 #endif
 333 #ifdef HAVE_MALLOC_MALLOC_H
 334 #include <malloc/malloc.h>
 335 #endif])
 336
 337 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 338 [#ifdef HAVE_SYS_TYPES_H
 339 #include <sys/types.h>
 340 #endif
 341 #ifdef HAVE_SYS_SOCKET_H
 342 #include <sys/socket.h>
 343 #endif])
 344 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 345 [#ifdef HAVE_SYS_TYPES_H
 346 #include <sys/types.h>
 347 #endif
 348 #ifdef HAVE_SYS_SOCKET_H
 349 #include <sys/socket.h>
 350 #endif
 351 #ifdef HAVE_NET_IF_H
 352 #include <net/if.h>
 353 #endif])
 354 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 355         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 356 [#ifdef HAVE_SYS_TYPES_H
 357 #include <sys/types.h>
 358 #endif
 359 #ifdef HAVE_SYS_SOCKET_H
 360 #include <sys/socket.h>
 361 #endif
 362 #ifdef HAVE_LIMITS_H
 363 #include <limits.h>
 364 #endif
 365 #ifdef HAVE_LINUX_TYPES_H
 366 #include <linux/types.h>
 367 #endif
 368 #ifdef HAVE_NETINET_IN6_H
 369 #include <netinet/in6.h>
 370 #endif
 371 #ifdef HAVE_NETINET_IN_H
 372 #include <netinet/in.h>
 373 #endif])
 374
 375 if test x$transparent = xtrue ; then
 376    transparent_ok=0
 377    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 378      transparent_ok=1
 379    fi
 380    if test x$linux_netfilter_ipv4 = x1 ; then
 381      transparent_ok=1
 382    fi
 383    if test x$transparent_ok = x1 ; then
 384      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 385      case $host in
 386        *-*-openbsd*)
 387          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 388      esac
 389    else
 390      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 391    fi
 392 fi
 393
 394 AC_FUNC_FSEEKO
 395
 396 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 397 [#ifdef HAVE_SYS_TYPES_H
 398 #include <sys/types.h>
 399 #endif
 400 #ifdef HAVE_SYS_TIME_H
 401 #include <sys/time.h>
 402 #endif])
 403
 404 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 405 dnl Watch out.
 406
 407 AC_CHECK_SIZEOF(int8_t)
 408 AC_CHECK_SIZEOF(int16_t)
 409 AC_CHECK_SIZEOF(int32_t)
 410 AC_CHECK_SIZEOF(int64_t)
 411 AC_CHECK_SIZEOF(uint8_t)
 412 AC_CHECK_SIZEOF(uint16_t)
 413 AC_CHECK_SIZEOF(uint32_t)
 414 AC_CHECK_SIZEOF(uint64_t)
 415 AC_CHECK_SIZEOF(intptr_t)
 416 AC_CHECK_SIZEOF(uintptr_t)
 417
 418 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 419
 420 AC_CHECK_SIZEOF(char)
 421 AC_CHECK_SIZEOF(short)
 422 AC_CHECK_SIZEOF(int)
 423 AC_CHECK_SIZEOF(long)
 424 AC_CHECK_SIZEOF(long long)
 425 AC_CHECK_SIZEOF(__int64)
 426 AC_CHECK_SIZEOF(void *)
 427 AC_CHECK_SIZEOF(time_t)
 428 AC_CHECK_SIZEOF(size_t)
 429
 430 AC_CHECK_TYPES([uint, u_char, ssize_t])
 431
 432 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 433 [#ifdef HAVE_SYS_TYPES_H
 434 #include <sys/types.h>
 435 #endif
 436 #ifdef HAVE_NETINET_IN_H
 437 #include <netinet/in.h>
 438 #endif
 439 #ifdef HAVE_NETINET_IN6_H
 440 #include <netinet/in6.h>
 441 #endif
 442 #ifdef HAVE_SYS_SOCKET_H
 443 #include <sys/socket.h>
 444 #endif
 445 #ifdef MS_WINDOWS
 446 #define WIN32_WINNT 0x400
 447 #define _WIN32_WINNT 0x400
 448 #define WIN32_LEAN_AND_MEAN
 449 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 450 #include <winsock.h>
 451 #else
 452 #include <winsock2.h>
 453 #include <ws2tcpip.h>
 454 #endif
 455 #endif
 456 ])
 457 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16], , ,
 458 [#ifdef HAVE_SYS_TYPES_H
 459 #include <sys/types.h>
 460 #endif
 461 #ifdef HAVE_NETINET_IN_H
 462 #include <netinet/in.h>
 463 #endif
 464 #ifdef HAVE_NETINET_IN6_H
 465 #include <netinet/in6.h>
 466 #endif
 467 #ifdef HAVE_SYS_SOCKET_H
 468 #include <sys/socket.h>
 469 #endif
 470 #ifdef MS_WINDOWS
 471 #define WIN32_WINNT 0x400
 472 #define _WIN32_WINNT 0x400
 473 #define WIN32_LEAN_AND_MEAN
 474 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 475 #include <winsock.h>
 476 #else
 477 #include <winsock2.h>
 478 #include <ws2tcpip.h>
 479 #endif
 480 #endif
 481 ])
 482
 483 AC_CHECK_TYPES([rlim_t], , ,
 484 [#ifdef HAVE_SYS_TYPES_H
 485 #include <sys/types.h>
 486 #endif
 487 #ifdef HAVE_SYS_TIME_H
 488 #include <sys/time.h>
 489 #endif
 490 #ifdef HAVE_SYS_RESOURCE_H
 491 #include <sys/resource.h>
 492 #endif
 493 ])
 494
 495 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 496 AC_RUN_IFELSE(AC_LANG_SOURCE([
 497 #ifdef HAVE_SYS_TYPES_H
 498 #include <sys/types.h>
 499 #endif
 500 #ifdef HAVE_SYS_TIME_H
 501 #include <sys/time.h>
 502 #endif
 503 #ifdef HAVE_TIME_H
 504 #include <time.h>
 505 #endif
 506 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 507   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 508 ])
 509
 510 if test "$tor_cv_time_t_signed" = cross; then
 511   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 512 fi
 513
 514 if test "$tor_cv_time_t_signed" != no; then
 515   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 516             [Define to 1 iff time_t is signed])
 517 fi
 518
 519 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 520 #ifdef HAVE_SYS_SOCKET_H
 521 #include <sys/socket.h>
 522 #endif
 523 ])
 524
 525 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 526
 527 AC_CHECK_SIZEOF(cell_t)
 528
 529 # Now make sure that NULL can be represented as zero bytes.
 530 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 531 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 532 [[#include <stdlib.h>
 533 #include <string.h>
 534 #include <stdio.h>
 535 #ifdef HAVE_STDDEF_H
 536 #include <stddef.h>
 537 #endif
 538 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 539 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 540        [tor_cv_null_is_zero=yes],
 541        [tor_cv_null_is_zero=no],
 542        [tor_cv_null_is_zero=cross])])
 543
 544 if test "$tor_cv_null_is_zero" = cross ; then
 545   # Cross-compiling; let's hope that the target isn't raving mad.
 546   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 547 fi
 548
 549 if test "$tor_cv_null_is_zero" != no; then
 550   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 551             [Define to 1 iff memset(0) sets pointers to NULL])
 552 fi
 553
 554 # And what happens when we malloc zero?
 555 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 556 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 557 [[#include <stdlib.h>
 558 #include <string.h>
 559 #include <stdio.h>
 560 #ifdef HAVE_STDDEF_H
 561 #include <stddef.h>
 562 #endif
 563 int main () { return malloc(0)?0:1; }]])],
 564        [tor_cv_malloc_zero_works=yes],
 565        [tor_cv_malloc_zero_works=no],
 566        [tor_cv_malloc_zero_works=cross])])
 567
 568 if test "$tor_cv_malloc_zero_works" = cross; then
 569   # Cross-compiling; let's hope that the target isn't raving mad.
 570   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 571 fi
 572
 573 if test "$tor_cv_malloc_zero_works" = yes; then
 574   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 575             [Define to 1 iff malloc(0) returns a pointer])
 576 fi
 577
 578 # whether we seem to be in a 2s-complement world.
 579 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 580 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 581 [[int main () { int problem = ((-99) != (~99)+1);
 582 return problem ? 1 : 0; }]])],
 583        [tor_cv_twos_complement=yes],
 584        [tor_cv_twos_complement=no],
 585        [tor_cv_twos_complement=cross])])
 586
 587 if test "$tor_cv_twos_complement" = cross ; then
 588   # Cross-compiling; let's hope that the target isn't raving mad.
 589   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 590 fi
 591
 592 if test "$tor_cv_twos_complement" != no ; then
 593   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 594             [Define to 1 iff we represent negative integers with two's complement])
 595 fi
 596
 597 # Whether we should use the dmalloc memory allocation debugging library.
 598 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 599 AC_ARG_WITH(dmalloc,
 600 [  --with-dmalloc          Use debug memory allocation library. ],
 601 [if [[ "$withval" = "yes" ]]; then
 602   dmalloc=1
 603   AC_MSG_RESULT(yes)
 604 else
 605   dmalloc=1
 606   AC_MSG_RESULT(no)
 607 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 608 )
 609
 610 if [[ $dmalloc -eq 1 ]]; then
 611   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 612   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 613   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 614   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 615   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 616 fi
 617
 618 AC_ARG_WITH(tcmalloc,
 619 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 620 [ tcmalloc=yes ], [ tcmalloc=no ])
 621
 622 if test x$tcmalloc = xyes ; then
 623    LDFLAGS="-ltcmalloc $LDFLAGS"
 624 fi
 625
 626 # Allow user to specify an alternate syslog facility
 627 AC_ARG_WITH(syslog-facility,
 628 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 629 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 630 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 631 AC_SUBST(LOGFACILITY)
 632
 633 # Check for gethostbyname_r in all its glorious incompatible versions.
 634 #   (This logic is based on that in Python's configure.in)
 635 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 636   [Define this if you have any gethostbyname_r()])
 637
 638 AC_CHECK_FUNC(gethostbyname_r, [
 639   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 640   OLD_CFLAGS=$CFLAGS
 641   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 642   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 643 #include <netdb.h>
 644   ], [[
 645     char *cp1, *cp2;
 646     struct hostent *h1, *h2;
 647     int i1, i2;
 648     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 649   ]]),[
 650     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 651     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 652      [Define this if gethostbyname_r takes 6 arguments])
 653     AC_MSG_RESULT(6)
 654   ], [
 655     AC_TRY_COMPILE([
 656 #include <netdb.h>
 657     ], [
 658       char *cp1, *cp2;
 659       struct hostent *h1;
 660       int i1, i2;
 661       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 662     ], [
 663       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 664       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 665         [Define this if gethostbyname_r takes 5 arguments])
 666       AC_MSG_RESULT(5)
 667    ], [
 668       AC_TRY_COMPILE([
 669 #include <netdb.h>
 670      ], [
 671        char *cp1;
 672        struct hostent *h1;
 673        struct hostent_data hd;
 674        (void) gethostbyname_r(cp1,h1,&hd);
 675      ], [
 676        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 677        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 678          [Define this if gethostbyname_r takes 3 arguments])
 679        AC_MSG_RESULT(3)
 680      ], [
 681        AC_MSG_RESULT(0)
 682      ])
 683   ])
 684  ])
 685  CFLAGS=$OLD_CFLAGS
 686 ])
 687
 688 AC_CACHE_CHECK([whether the C compiler supports __func__],
 689   tor_cv_have_func_macro,
 690   AC_COMPILE_IFELSE([
 691 #include <stdio.h>
 692 int main(int c, char **v) { puts(__func__); }],
 693   tor_cv_have_func_macro=yes,
 694   tor_cv_have_func_macro=no))
 695
 696 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 697   tor_cv_have_FUNC_macro,
 698   AC_COMPILE_IFELSE([
 699 #include <stdio.h>
 700 int main(int c, char **v) { puts(__FUNC__); }],
 701   tor_cv_have_FUNC_macro=yes,
 702   tor_cv_have_FUNC_macro=no))
 703
 704 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 705   tor_cv_have_FUNCTION_macro,
 706   AC_COMPILE_IFELSE([
 707 #include <stdio.h>
 708 int main(int c, char **v) { puts(__FUNCTION__); }],
 709   tor_cv_have_FUNCTION_macro=yes,
 710   tor_cv_have_FUNCTION_macro=no))
 711
 712 if test "$tor_cv_have_func_macro" = 'yes'; then
 713   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 714 fi
 715
 716 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 717   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 718 fi
 719
 720 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 721   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 722            [Defined if the compiler supports __FUNCTION__])
 723 fi
 724
 725 # $prefix stores the value of the --prefix command line option, or
 726 # NONE if the option wasn't set.  In the case that it wasn't set, make
 727 # it be the default, so that we can use it to expand directories now.
 728 if test "x$prefix" = "xNONE"; then
 729   prefix=$ac_default_prefix
 730 fi
 731
 732 # and similarly for $exec_prefix
 733 if test "x$exec_prefix" = "xNONE"; then
 734   exec_prefix=$prefix
 735 fi
 736
 737 if test "x$CONFDIR" = "x"; then
 738   CONFDIR=`eval echo $sysconfdir/tor`
 739 fi
 740 AC_SUBST(CONFDIR)
 741 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 742 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 743
 744 BINDIR=`eval echo $bindir`
 745 AC_SUBST(BINDIR)
 746 LOCALSTATEDIR=`eval echo $localstatedir`
 747 AC_SUBST(LOCALSTATEDIR)
 748
 749 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 750 # than autoconf's macros like.
 751 if test "$ac_cv_c_compiler_gnu" = yes; then
 752   CFLAGS="$CFLAGS -Wall -g -O2"
 753 else
 754   CFLAGS="$CFLAGS -g -O"
 755   enable_gcc_warnings=no
 756 fi
 757
 758 # Add some more warnings which we use in development but not in the
 759 # released versions.  (Some relevant gcc versions can't handle these.)
 760 if test x$enable_gcc_warnings = xyes; then
 761
 762   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 763 #if !defined(__GNUC__) || (__GNUC__ < 4)
 764 #error
 765 #endif]), have_gcc4=yes, have_gcc4=no)
 766
 767   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 768 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 769 #error
 770 #endif]), have_gcc42=yes, have_gcc42=no)
 771
 772   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 773 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 774 #error
 775 #endif]), have_gcc43=yes, have_gcc43=no)
 776
 777   save_CFLAGS="$CFLAGS"
 778   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 779   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 780                     have_shorten64_flag=no)
 781   CFLAGS="$save_CFLAGS"
 782
 783   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 784
 785   # Disabled, so we can use mallinfo(): -Waggregate-return
 786
 787   if test x$have_gcc4 = xyes ; then
 788     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 789     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 790   fi
 791
 792   if test x$have_gcc42 = xyes ; then
 793     # These warnings break gcc 4.0.2 and work on gcc 4.2
 794     # XXXX020 Use -fstack-protector.
 795     # XXXX020 See if any of these work with earlier versions.
 796     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 797     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 798   fi
 799
 800   if test x$have_gcc43 = xyes ; then
 801     # These warnings break gcc 4.2 and work on gcc 4.3
 802     # XXXX020 See if any of these work with earlier versions.
 803     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 804   fi
 805
 806   if test x$have_shorten64_flag = xyes ; then
 807     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 808   fi
 809
 810 ##This will break the world on some 64-bit architectures
 811 # CFLAGS="$CFLAGS -Winline"
 812 fi
 813
 814
 815
 816 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 817
 818 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 819 AC_OUTPUT
 820
 821 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 822   ./contrib/updateVersions.pl
 823 fi
 824