configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2007, Roger Dingledine, Nick Mathewson
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.0.9-alpha-dev)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  14 fi
  15
  16 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  17 # the += operator on it in src/or/Makefile.am
  18 CPPFLAGS="$CPPFLAGS -I../common"
  19
  20 AC_ARG_ENABLE(debug,
  21  AS_HELP_STRING(--enable-debug, compile with debugging info),
  22 [if test x$enableval = xyes; then
  23     CFLAGS="$CFLAGS -g"
  24 fi])
  25
  26 AC_ARG_ENABLE(cell-pool,
  27      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  28
  29 if test x$enable_cell_pool != xno; then
  30   AC_DEFINE(ENABLE_CELL_POOL, 1,
  31             [Defined if we try to use the pool allocator for queued cells])
  32 fi
  33
  34 AC_ARG_ENABLE(transparent,
  35      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  36      [case "${enableval}" in
  37         yes) transparent=true ;;
  38         no)  transparent=false ;;
  39         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  40       esac], [transparent=true])
  41
  42 AC_ARG_ENABLE(threads,
  43      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  44
  45 if test x$enable_threads = x; then
  46    case $host in
  47     *-*-solaris* )
  48      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  49      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  50 cpu workers lock up here, so I will disable threads.])
  51      enable_threads="no";;
  52     *)
  53      enable_threads="yes";;
  54    esac
  55 fi
  56
  57 if test $enable_threads = "yes"; then
  58   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  59 fi
  60
  61 case $host in
  62    *-*-solaris* )
  63      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  64      ;;
  65 esac
  66
  67 AC_ARG_ENABLE(gcc-warnings,
  68      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  69
  70 AC_PROG_CC
  71 AC_PROG_MAKE_SET
  72 AC_PROG_RANLIB
  73
  74 TORUSER=_tor
  75 AC_ARG_WITH(tor-user,
  76         [  --with-tor-user=NAME    Specify username for tor daemon ],
  77         [
  78            TORUSER=$withval
  79         ]
  80 )
  81 AC_SUBST(TORUSER)
  82
  83 TORGROUP=_tor
  84 AC_ARG_WITH(tor-group,
  85         [  --with-tor-group=NAME   Specify group name for tor daemon ],
  86         [
  87            TORGROUP=$withval
  88         ]
  89 )
  90 AC_SUBST(TORGROUP)
  91
  92
  93 dnl If WIN32 is defined and non-zero, we are building for win32
  94 AC_MSG_CHECKING([for win32])
  95 AC_RUN_IFELSE([
  96 int main(int c, char **v) {
  97 #ifdef WIN32
  98 #if WIN32
  99   return 0;
 100 #else
 101   return 1;
 102 #endif
 103 #else
 104   return 2;
 105 #endif
 106 }],
 107 bwin32=true; AC_MSG_RESULT([yes]),
 108 bwin32=false; AC_MSG_RESULT([no]),
 109 bwin32=cross; AC_MSG_RESULT([cross])
 110 )
 111
 112 if test $bwin32 = cross; then
 113 AC_MSG_CHECKING([for win32 (cross)])
 114 AC_COMPILE_IFELSE([
 115 #ifdef WIN32
 116 int main(int c, char **v) {return 0;}
 117 #else
 118 #error
 119 int main(int c, char **v) {return x(y);}
 120 #endif
 121 ],
 122 bwin32=true; AC_MSG_RESULT([yes]),
 123 bwin32=false; AC_MSG_RESULT([no]))
 124 fi
 125
 126 if test $bwin32 = true; then
 127 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 128 fi
 129 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 130
 131 dnl Enable C99 when compiling with MIPSpro
 132 AC_MSG_CHECKING([for MIPSpro compiler])
 133 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 134 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 135 #error
 136   return x(y);
 137 #endif
 138 ]),
 139 bmipspro=false; AC_MSG_RESULT(no),
 140 bmipspro=true; AC_MSG_RESULT(yes))
 141
 142 if test $bmipspro = true; then
 143   CFLAGS="$CFLAGS -c99"
 144 fi
 145
 146 AC_C_BIGENDIAN
 147
 148 AC_SEARCH_LIBS(socket, [socket])
 149 AC_SEARCH_LIBS(gethostbyname, [nsl])
 150 AC_SEARCH_LIBS(dlopen, [dl])
 151 AC_SEARCH_LIBS(inet_aton, [resolv])
 152
 153 if test $enable_threads = "yes"; then
 154   AC_SEARCH_LIBS(pthread_create, [pthread])
 155   AC_SEARCH_LIBS(pthread_detach, [pthread])
 156 fi
 157
 158 dnl -------------------------------------------------------------------
 159 dnl Check for functions before libevent, since libevent-1.2 apparently
 160 dnl exports strlcpy without defining it in a header.
 161
 162 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop mallinfo)
 163
 164 if test $enable_threads = "yes"; then
 165   AC_CHECK_HEADERS(pthread.h)
 166   AC_CHECK_FUNCS(pthread_create)
 167 fi
 168
 169 dnl ------------------------------------------------------
 170 dnl Where do you live, libevent?  And how do we call you?
 171
 172 if test $bwin32 = true; then
 173   TOR_LIB_WS32=-lws2_32
 174   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 175   # think it's actually necessary.
 176   TOR_LIB_GDI=-lgdi32
 177 else
 178   TOR_LIB_WS32=
 179   TOR_LIB_GDI=
 180 fi
 181 AC_SUBST(TOR_LIB_WS32)
 182 AC_SUBST(TOR_LIB_GDI)
 183
 184 dnl This is a disgusting hack so we safely include recent libevent headers.
 185 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 186 AC_CHECK_TYPE(u_int32_t, unsigned long)
 187 AC_CHECK_TYPE(u_int16_t, unsigned short)
 188 AC_CHECK_TYPE(u_int8_t, unsigned char)
 189
 190 tor_libevent_pkg_redhat="libevent"
 191 tor_libevent_pkg_debian="libevent-dev"
 192 tor_libevent_devpkg_redhat="libevent-devel"
 193 tor_libevent_devpkg_debian="libevent-dev"
 194
 195 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 196 #include <stdlib.h>
 197 #include <sys/time.h>
 198 #include <sys/types.h>
 199 #include <event.h>], [void exit(int); void *event_init(void);],
 200     [event_init(); exit(0);], [--with-libevent-dir], [/opt/libevent])
 201
 202 dnl Now check for particular libevent functions.
 203 save_LIBS="$LIBS"
 204 save_LDFLAGS="$LDFLAGS"
 205 save_CPPFLAGS="$CPPFLAGS"
 206 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 207 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 208 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 209 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 210 LIBS="$save_LIBS"
 211 LDFLAGS="$save_LDFLAGS"
 212 CPPFLAGS="$save_CPPFLAGS"
 213
 214 dnl ------------------------------------------------------
 215 dnl Where do you live, openssl?  And how do we call you?
 216
 217 tor_openssl_pkg_redhat="openssl"
 218 tor_openssl_pkg_debian="libssl"
 219 tor_openssl_devpkg_redhat="openssl-devel"
 220 tor_openssl_devpkg_debian="libssl-dev"
 221
 222 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 223     [#include <openssl/rand.h>],
 224     [void RAND_add(const void *buf, int num, double entropy);],
 225     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 226     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 227
 228 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 229
 230 dnl ------------------------------------------------------
 231 dnl Where do you live, zlib?  And how do we call you?
 232
 233 tor_openssl_pkg_redhat="zlib"
 234 tor_openssl_pkg_debian="zlib1g"
 235 tor_openssl_devpkg_redhat="zlib-devel"
 236 tor_openssl_devpkg_debian="zlib1g-dev"
 237
 238 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 239     [#include <zlib.h>],
 240     [const char * zlibVersion(void);],
 241     [zlibVersion(); exit(0);], [--with-zlib-dir],
 242     [/opt/zlib])
 243
 244 dnl Make sure to enable support for large off_t if avalable.
 245
 246 AC_SYS_LARGEFILE
 247
 248 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 249
 250 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h)
 251
 252 dnl These headers are not essential
 253
 254 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h malloc.h)
 255
 256 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 257 [#ifdef HAVE_SYS_TYPES_H
 258 #include <sys/types.h>
 259 #endif
 260 #ifdef HAVE_SYS_SOCKET_H
 261 #include <sys/socket.h>
 262 #endif])
 263 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 264 [#ifdef HAVE_SYS_TYPES_H
 265 #include <sys/types.h>
 266 #endif
 267 #ifdef HAVE_SYS_SOCKET_H
 268 #include <sys/socket.h>
 269 #endif
 270 #ifdef HAVE_NET_IF_H
 271 #include <net/if.h>
 272 #endif])
 273 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 274         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 275 [#ifdef HAVE_SYS_TYPES_H
 276 #include <sys/types.h>
 277 #endif
 278 #ifdef HAVE_SYS_SOCKET_H
 279 #include <sys/socket.h>
 280 #endif])
 281
 282 if test x$transparent = xtrue ; then
 283    transparent_ok=0
 284    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 285      transparent_ok=1
 286    fi
 287    if test x$linux_netfilter_ipv4 = x1 ; then
 288      transparent_ok=1
 289    fi
 290    if test x$transparent_ok = x1 ; then
 291      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 292      case $host in
 293        *-*-openbsd*)
 294          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 295      esac
 296    else
 297      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 298    fi
 299 fi
 300
 301 AC_FUNC_FSEEKO
 302
 303 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 304 [#ifdef HAVE_SYS_TYPES_H
 305 #include <sys/types.h>
 306 #endif
 307 #ifdef HAVE_SYS_TIME_H
 308 #include <sys/time.h>
 309 #endif])
 310
 311 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 312 dnl Watch out.
 313
 314 AC_CHECK_SIZEOF(int8_t)
 315 AC_CHECK_SIZEOF(int16_t)
 316 AC_CHECK_SIZEOF(int32_t)
 317 AC_CHECK_SIZEOF(int64_t)
 318 AC_CHECK_SIZEOF(uint8_t)
 319 AC_CHECK_SIZEOF(uint16_t)
 320 AC_CHECK_SIZEOF(uint32_t)
 321 AC_CHECK_SIZEOF(uint64_t)
 322 AC_CHECK_SIZEOF(intptr_t)
 323 AC_CHECK_SIZEOF(uintptr_t)
 324
 325 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 326
 327 AC_CHECK_SIZEOF(char)
 328 AC_CHECK_SIZEOF(short)
 329 AC_CHECK_SIZEOF(int)
 330 AC_CHECK_SIZEOF(long)
 331 AC_CHECK_SIZEOF(long long)
 332 AC_CHECK_SIZEOF(__int64)
 333 AC_CHECK_SIZEOF(void *)
 334 AC_CHECK_SIZEOF(time_t)
 335 AC_CHECK_SIZEOF(size_t)
 336
 337 AC_CHECK_TYPES([uint, u_char])
 338
 339 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 340 [#ifdef HAVE_SYS_TYPES_H
 341 #include <sys/types.h>
 342 #endif
 343 #ifdef HAVE_NETINET_IN_H
 344 #include <netinet/in.h>
 345 #endif
 346 #ifdef HAVE_NETINET_IN6_H
 347 #include <netinet/in6.h>
 348 #endif
 349 #ifdef HAVE_SYS_SOCKET_H
 350 #include <sys/socket.h>
 351 #endif
 352 #ifdef MS_WINDOWS
 353 #define WIN32_WINNT 0x400
 354 #define _WIN32_WINNT 0x400
 355 #define WIN32_LEAN_AND_MEAN
 356 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 357 #include <winsock.h>
 358 #else
 359 #include <winsock2.h>
 360 #include <ws2tcpip.h>
 361 #endif
 362 #endif
 363 ])
 364
 365 if test -z "$CROSS_COMPILE"; then
 366 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 367 AC_RUN_IFELSE(AC_LANG_SOURCE([
 368 #ifdef HAVE_SYS_TYPES_H
 369 #include <sys/types.h>
 370 #endif
 371 #ifdef HAVE_SYS_TIME_H
 372 #include <sys/time.h>
 373 #endif
 374 #ifdef HAVE_TIME_H
 375 #include <time.h>
 376 #endif
 377 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 378   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes)
 379 ])
 380 else
 381   # Cross-compiling; let's hope the target platform isn't loony.
 382   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 383   tor_cv_time_t_signed=yes
 384 fi
 385
 386 if test $tor_cv_time_t_signed = yes; then
 387   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 388             [Define to 1 iff time_t is signed])
 389 fi
 390
 391 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 392 #ifdef HAVE_SYS_SOCKET_H
 393 #include <sys/socket.h>
 394 #endif
 395 ])
 396
 397 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 398
 399 AC_CHECK_SIZEOF(cell_t)
 400
 401 # Now make sure that NULL can be represented as zero bytes.
 402 if test -z "$CROSS_COMPILE"; then
 403 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 404 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 405 [[#include <stdlib.h>
 406 #include <string.h>
 407 #include <stdio.h>
 408 #ifdef HAVE_STDDEF_H
 409 #include <stddef.h>
 410 #endif
 411 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 412 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 413        [tor_cv_null_is_zero=yes],
 414        [tor_cv_null_is_zero=no],
 415        [tor_cv_null_is_zero=cross])])
 416
 417 else
 418   # Cross-compiling; let's hope that the target isn't raving mad.
 419   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 420   tor_cv_null_is_zero=yes
 421 fi
 422
 423 if test $tor_cv_null_is_zero = yes; then
 424   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 425             [Define to 1 iff memset(0) sets pointers to NULL])
 426 fi
 427
 428 # And what happens when we malloc zero?
 429
 430 if test -z "$CROSS_COMPILE"; then
 431 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 432 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 433 [[#include <stdlib.h>
 434 #include <string.h>
 435 #include <stdio.h>
 436 #ifdef HAVE_STDDEF_H
 437 #include <stddef.h>
 438 #endif
 439 int main () { return malloc(0)?0:1; }]])],
 440        [tor_cv_malloc_zero_works=yes],
 441        [tor_cv_malloc_zero_works=no],
 442        [tor_cv_malloc_zero_works=cross])])
 443
 444 else
 445   # Cross-compiling; let's hope that the target isn't raving mad.
 446   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 447   tor_cv_malloc_zero_works=no
 448 fi
 449
 450 if test $tor_cv_malloc_zero_works = yes; then
 451   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 452             [Define to 1 iff malloc(0) returns a pointer])
 453 fi
 454
 455 # whether we seem to be in a 2s-complement world.
 456 if test -z "$CROSS_COMPILE"; then
 457 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 458 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 459 [[int main () { int problem = ((-99) != (~99)+1);
 460 return problem ? 1 : 0; }]])],
 461        [tor_cv_twos_complement=yes],
 462        [tor_cv_twos_complement=no],
 463        [tor_cv_twos_complement=cross])])
 464
 465 else
 466   # Cross-compiling; let's hope that the target isn't raving mad.
 467   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 468   tor_cv_twos_complement=yes
 469 fi
 470
 471 if test $tor_cv_twos_complement = yes; then
 472   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 473             [Define to 1 iff we represent negative integers with two's complement])
 474 fi
 475
 476 # Whether we should use the dmalloc memory allocation debugging library.
 477 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 478 AC_ARG_WITH(dmalloc,
 479 [  --with-dmalloc          Use debug memory allocation library. ],
 480 [if [[ "$withval" = "yes" ]]; then
 481   dmalloc=1
 482   AC_MSG_RESULT(yes)
 483 else
 484   dmalloc=1
 485   AC_MSG_RESULT(no)
 486 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 487 )
 488
 489 if [[ $dmalloc -eq 1 ]]; then
 490   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 491   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 492   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 493   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 494 fi
 495
 496 # Allow user to specify an alternate syslog facility
 497 AC_ARG_WITH(syslog-facility,
 498 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 499 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 500 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 501 AC_SUBST(LOGFACILITY)
 502
 503 # Check for gethostbyname_r in all its glorious incompatible versions.
 504 #   (This logic is based on that in Python's configure.in)
 505 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 506   [Define this if you have any gethostbyname_r()])
 507
 508 AC_CHECK_FUNC(gethostbyname_r, [
 509   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 510   OLD_CFLAGS=$CFLAGS
 511   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 512   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 513 #include <netdb.h>
 514   ], [[
 515     char *cp1, *cp2;
 516     struct hostent *h1, *h2;
 517     int i1, i2;
 518     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 519   ]]),[
 520     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 521     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 522      [Define this if gethostbyname_r takes 6 arguments])
 523     AC_MSG_RESULT(6)
 524   ], [
 525     AC_TRY_COMPILE([
 526 #include <netdb.h>
 527     ], [
 528       char *cp1, *cp2;
 529       struct hostent *h1;
 530       int i1, i2;
 531       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 532     ], [
 533       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 534       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 535         [Define this if gethostbyname_r takes 5 arguments])
 536       AC_MSG_RESULT(5)
 537    ], [
 538       AC_TRY_COMPILE([
 539 #include <netdb.h>
 540      ], [
 541        char *cp1;
 542        struct hostent *h1;
 543        struct hostent_data hd;
 544        (void) gethostbyname_r(cp1,h1,&hd);
 545      ], [
 546        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 547        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 548          [Define this if gethostbyname_r takes 3 arguments])
 549        AC_MSG_RESULT(3)
 550      ], [
 551        AC_MSG_RESULT(0)
 552      ])
 553   ])
 554  ])
 555  CFLAGS=$OLD_CFLAGS
 556 ])
 557
 558 AC_CACHE_CHECK([whether the C compiler supports __func__],
 559   tor_cv_have_func_macro,
 560   AC_COMPILE_IFELSE([
 561 #include <stdio.h>
 562 int main(int c, char **v) { puts(__func__); }],
 563   tor_cv_have_func_macro=yes,
 564   tor_cv_have_func_macro=no))
 565
 566 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 567   tor_cv_have_FUNC_macro,
 568   AC_COMPILE_IFELSE([
 569 #include <stdio.h>
 570 int main(int c, char **v) { puts(__FUNC__); }],
 571   tor_cv_have_FUNC_macro=yes,
 572   tor_cv_have_FUNC_macro=no))
 573
 574 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 575   tor_cv_have_FUNCTION_macro,
 576   AC_COMPILE_IFELSE([
 577 #include <stdio.h>
 578 int main(int c, char **v) { puts(__FUNCTION__); }],
 579   tor_cv_have_FUNCTION_macro=yes,
 580   tor_cv_have_FUNCTION_macro=no))
 581
 582 if test $tor_cv_have_func_macro = 'yes'; then
 583   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 584 fi
 585
 586 if test $tor_cv_have_FUNC_macro = 'yes'; then
 587   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 588 fi
 589
 590 if test $tor_cv_have_FUNCTION_macro = 'yes'; then
 591   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 592            [Defined if the compiler supports __FUNCTION__])
 593 fi
 594
 595 # $prefix stores the value of the --prefix command line option, or
 596 # NONE if the option wasn't set.  In the case that it wasn't set, make
 597 # it be the default, so that we can use it to expand directories now.
 598 if test "x$prefix" = "xNONE"; then
 599   prefix=$ac_default_prefix
 600 fi
 601
 602 # and similarly for $exec_prefix
 603 if test "x$exec_prefix" = "xNONE"; then
 604   exec_prefix=$prefix
 605 fi
 606
 607 if test "x$CONFDIR" = "x"; then
 608   CONFDIR=`eval echo $sysconfdir/tor`
 609 fi
 610 AC_SUBST(CONFDIR)
 611 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 612 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 613
 614 BINDIR=`eval echo $bindir`
 615 AC_SUBST(BINDIR)
 616
 617 LOCALSTATEDIR=`eval echo $localstatedir`
 618 AC_SUBST(LOCALSTATEDIR)
 619 AH_TEMPLATE([LOCALSTATEDIR], [Default location to store state files.])
 620 AC_DEFINE_UNQUOTED(LOCALSTATEDIR,"$LOCALSTATEDIR")
 621
 622 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 623 # than autoconf's macros like.
 624 if test $ac_cv_c_compiler_gnu = yes; then
 625   CFLAGS="$CFLAGS -Wall -g -O2"
 626 else
 627   CFLAGS="$CFLAGS -g -O"
 628   enable_gcc_warnings=no
 629 fi
 630
 631 # Add some more warnings which we use in development but not in the
 632 # released versions.  (Some relevant gcc versions can't handle these.)
 633 if test x$enable_gcc_warnings = xyes; then
 634
 635   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 636 #if !defined(__GNUC__) || (__GNUC__ < 4)
 637 #error
 638 #endif]), have_gcc4=yes, have_gcc4=no)
 639
 640   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 641 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 642 #error
 643 #endif]), have_gcc42=yes, have_gcc42=no)
 644
 645   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 646   # Disabled, so we can use mallinfo(): -Waggregate-return
 647
 648   if test x$have_gcc4 = xyes ; then
 649     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 650     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 651   fi
 652
 653   if test x$have_gcc42 = xyes ; then
 654     # These warnings break gcc 4.0.2 and work on gcc 4.2
 655     # XXXX020 Use -fstack-protector.
 656     # XXXX020 See if any of these work with earlier versions.
 657     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=5"
 658   fi
 659
 660 ##This will break the world on some 64-bit architectures
 661 # CFLAGS="$CFLAGS -Winline"
 662
 663 fi
 664
 665 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 666
 667 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 668 AC_OUTPUT
 669
 670 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 671   ./contrib/updateVersions.pl
 672 fi
 673