configure.in

   1 dnl Copyright (c) 2001-2004, Roger Dingledine
   2 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   3 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   4 dnl See LICENSE for licensing information
   5
   6 AC_INIT
   7 AM_INIT_AUTOMAKE(tor, 0.2.2.9-alpha-dev)
   8 AM_CONFIG_HEADER(orconfig.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 if test -f /etc/redhat-release ; then
  13   if test -f /usr/kerberos/include ; then
  14     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  15   fi
  16 fi
  17
  18 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  19 # the += operator on it in src/or/Makefile.am
  20 CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  21
  22 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  23 AC_ARG_ENABLE(buf-freelists,
  24    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  25 AC_ARG_ENABLE(openbsd-malloc,
  26    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  27 AC_ARG_ENABLE(instrument-downloads,
  28    AS_HELP_STRING(--enable-instrument-downloads, Instrument downloads of directory resources etc.))
  29 AC_ARG_ENABLE(static-openssl,
  30    AS_HELP_STRING(--enable-static-openssl, Link against a static openssl library. Requires --with-openssl-dir))
  31 AC_ARG_ENABLE(static-libevent,
  32    AS_HELP_STRING(--enable-static-libevent, Link against a static libevent library. Requires --with-libevent-dir))
  33
  34 if test x$enable_buf_freelists != xno; then
  35   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  36             [Defined if we try to use freelists for buffer RAM chunks])
  37 fi
  38 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  39 if test x$enable_instrument_downloads = xyes; then
  40   AC_DEFINE(INSTRUMENT_DOWNLOADS, 1,
  41             [Defined if we want to keep track of how much of each kind of resource we download.])
  42 fi
  43
  44 AC_ARG_ENABLE(transparent,
  45      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  46      [case "${enableval}" in
  47         yes) transparent=true ;;
  48         no)  transparent=false ;;
  49         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  50       esac], [transparent=true])
  51
  52 AC_ARG_ENABLE(asciidoc,
  53      AS_HELP_STRING(--disable-asciidoc, don't use asciidoc (disables building of manpages)),
  54      [case "${enableval}" in
  55         yes) asciidoc=true ;;
  56         no)  asciidoc=false ;;
  57         *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  58       esac], [asciidoc=true])
  59
  60
  61 AC_ARG_ENABLE(threads,
  62      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  63
  64 if test x$enable_threads = x; then
  65    case $host in
  66     *-*-solaris* )
  67      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  68      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  69 cpu workers lock up here, so I will disable threads.])
  70      enable_threads="no";;
  71     *)
  72      enable_threads="yes";;
  73    esac
  74 fi
  75
  76 if test "$enable_threads" = "yes"; then
  77   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  78 fi
  79
  80 case $host in
  81    *-*-solaris* )
  82      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  83      ;;
  84 esac
  85
  86 AC_ARG_ENABLE(gcc-warnings,
  87      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  88 AC_ARG_ENABLE(gcc-warnings-advisory,
  89      AS_HELP_STRING(--enable-gcc-warnings-advisory, [enable verbose warnings, excluding -Werror]))
  90
  91 AC_ARG_ENABLE(local-appdata,
  92    AS_HELP_STRING(--enable-local-appdata, default to host local application data paths on Windows))
  93 if test "$enable_local_appdata" = "yes"; then
  94   AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
  95             [Defined if we default to host local appdata paths on Windows])
  96 fi
  97
  98 AC_PROG_CC
  99 AC_PROG_CPP
 100 AC_PROG_MAKE_SET
 101 AC_PROG_RANLIB
 102
 103 dnl autoconf 2.59 appears not to support AC_PROG_SED
 104 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 105
 106 dnl check for asciidoc and a2x
 107 AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
 108 AC_PATH_PROG([A2X], [a2x], none)
 109 AC_PATH_PROG([XSLTPROC], [xsltproc], none)
 110 if test x$asciidoc = xtrue ; then
 111    if test x$ASCIIDOC = xnone ; then
 112        AC_MSG_ERROR("Couldn't find asciidoc. reconfigure with --disable-asciidoc to build without asciidoc.")
 113    fi
 114    if test x$A2X = xnone ; then
 115        AC_MSG_ERROR("Couldn't find a2x. reconfigure with --disable-asciidoc to build without a2x.")
 116    fi
 117    if test x$XSLTPROC = xnone ; then
 118        AC_MSG_ERROR("Couldn't find xsltproc. reconfigure with --disable-asciidoc to build without xsltproc.")
 119    fi
 120 fi
 121
 122 AM_CONDITIONAL(USE_ASCIIDOC, test x$asciidoc = xtrue)
 123
 124 AC_PATH_PROG([SHA1SUM], [sha1sum], none)
 125 AC_PATH_PROG([OPENSSL], [openssl], none)
 126
 127 TORUSER=_tor
 128 AC_ARG_WITH(tor-user,
 129         [  --with-tor-user=NAME    Specify username for tor daemon ],
 130         [
 131            TORUSER=$withval
 132         ]
 133 )
 134 AC_SUBST(TORUSER)
 135
 136 TORGROUP=_tor
 137 AC_ARG_WITH(tor-group,
 138         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 139         [
 140            TORGROUP=$withval
 141         ]
 142 )
 143 AC_SUBST(TORGROUP)
 144
 145
 146 dnl If WIN32 is defined and non-zero, we are building for win32
 147 AC_MSG_CHECKING([for win32])
 148 AC_RUN_IFELSE([
 149 int main(int c, char **v) {
 150 #ifdef WIN32
 151 #if WIN32
 152   return 0;
 153 #else
 154   return 1;
 155 #endif
 156 #else
 157   return 2;
 158 #endif
 159 }],
 160 bwin32=true; AC_MSG_RESULT([yes]),
 161 bwin32=false; AC_MSG_RESULT([no]),
 162 bwin32=cross; AC_MSG_RESULT([cross])
 163 )
 164
 165 if test "$bwin32" = cross; then
 166 AC_MSG_CHECKING([for win32 (cross)])
 167 AC_COMPILE_IFELSE([
 168 #ifdef WIN32
 169 int main(int c, char **v) {return 0;}
 170 #else
 171 #error
 172 int main(int c, char **v) {return x(y);}
 173 #endif
 174 ],
 175 bwin32=true; AC_MSG_RESULT([yes]),
 176 bwin32=false; AC_MSG_RESULT([no]))
 177 fi
 178
 179 if test "$bwin32" = true; then
 180 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 181 fi
 182 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 183
 184 dnl Enable C99 when compiling with MIPSpro
 185 AC_MSG_CHECKING([for MIPSpro compiler])
 186 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 187 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 188 #error
 189   return x(y);
 190 #endif
 191 ]),
 192 bmipspro=false; AC_MSG_RESULT(no),
 193 bmipspro=true; AC_MSG_RESULT(yes))
 194
 195 if test "$bmipspro" = true; then
 196   CFLAGS="$CFLAGS -c99"
 197 fi
 198
 199 AC_C_BIGENDIAN
 200
 201 AC_SEARCH_LIBS(socket, [socket])
 202 AC_SEARCH_LIBS(gethostbyname, [nsl])
 203 AC_SEARCH_LIBS(dlopen, [dl])
 204 AC_SEARCH_LIBS(inet_aton, [resolv])
 205
 206 if test "$enable_threads" = "yes"; then
 207   AC_SEARCH_LIBS(pthread_create, [pthread])
 208   AC_SEARCH_LIBS(pthread_detach, [pthread])
 209 fi
 210
 211 dnl -------------------------------------------------------------------
 212 dnl Check for functions before libevent, since libevent-1.2 apparently
 213 dnl exports strlcpy without defining it in a header.
 214
 215 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull getaddrinfo localtime_r gmtime_r memmem strtok_r writev readv flock prctl)
 216
 217 using_custom_malloc=no
 218 if test x$enable_openbsd_malloc = xyes ; then
 219    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 220    using_custom_malloc=yes
 221 fi
 222 if test x$tcmalloc = xyes ; then
 223    using_custom_malloc=yes
 224 fi
 225 if test $using_custom_malloc = no ; then
 226    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 227 fi
 228
 229 if test "$enable_threads" = "yes"; then
 230   AC_CHECK_HEADERS(pthread.h)
 231   AC_CHECK_FUNCS(pthread_create)
 232 fi
 233
 234 dnl ------------------------------------------------------
 235 dnl Where do you live, libevent?  And how do we call you?
 236
 237 if test "$bwin32" = true; then
 238   TOR_LIB_WS32=-lws2_32
 239   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 240   # think it's actually necessary.
 241   TOR_LIB_GDI=-lgdi32
 242 else
 243   TOR_LIB_WS32=
 244   TOR_LIB_GDI=
 245 fi
 246 AC_SUBST(TOR_LIB_WS32)
 247 AC_SUBST(TOR_LIB_GDI)
 248
 249 dnl We need to do this before we try our disgusting hack below.
 250 AC_CHECK_HEADERS([sys/types.h])
 251
 252 dnl This is a disgusting hack so we safely include older libevent headers.
 253 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 254 AC_CHECK_TYPE(u_int32_t, unsigned long)
 255 AC_CHECK_TYPE(u_int16_t, unsigned short)
 256 AC_CHECK_TYPE(u_int8_t, unsigned char)
 257
 258 tor_libevent_pkg_redhat="libevent"
 259 tor_libevent_pkg_debian="libevent-dev"
 260 tor_libevent_devpkg_redhat="libevent-devel"
 261 tor_libevent_devpkg_debian="libevent-dev"
 262
 263 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 264 #ifdef WIN32
 265 #include <winsock2.h>
 266 #endif
 267 #include <stdlib.h>
 268 #include <sys/time.h>
 269 #include <sys/types.h>
 270 #include <event.h>], [
 271 #ifdef WIN32
 272 #include <winsock2.h>
 273 #endif
 274 void exit(int); void *event_init(void);],
 275     [
 276 #ifdef WIN32
 277 {WSADATA d; WSAStartup(0x101,&d); }
 278 #endif
 279 event_init(); exit(0);
 280 ], [--with-libevent-dir], [/opt/libevent])
 281
 282 dnl Now check for particular libevent functions.
 283 save_LIBS="$LIBS"
 284 save_LDFLAGS="$LDFLAGS"
 285 save_CPPFLAGS="$CPPFLAGS"
 286 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 287 LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
 288 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 289 AC_CHECK_FUNCS(event_get_version event_get_version_number event_get_method event_set_log_callback evdns_set_outgoing_bind_address event_base_loopexit)
 290 AC_CHECK_MEMBERS([struct event.min_heap_idx], , ,
 291 [#include <event.h>
 292 ])
 293
 294 AC_CHECK_HEADERS(event2/event.h event2/dns.h)
 295
 296 LIBS="$save_LIBS"
 297 LDFLAGS="$save_LDFLAGS"
 298 CPPFLAGS="$save_CPPFLAGS"
 299
 300
 301 AM_CONDITIONAL(USE_EXTERNAL_EVDNS, test x$ac_cv_header_event2_dns_h = xyes)
 302
 303 if test "$enable_static_libevent" = "yes"; then
 304    if test "$tor_cv_library_libevent_dir" = "(system)"; then
 305      AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
 306    else
 307      TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a"
 308    fi
 309 else
 310      TOR_LIBEVENT_LIBS="-levent"
 311 fi
 312 AC_SUBST(TOR_LIBEVENT_LIBS)
 313
 314
 315 dnl ------------------------------------------------------
 316 dnl Where do you live, openssl?  And how do we call you?
 317
 318 tor_openssl_pkg_redhat="openssl"
 319 tor_openssl_pkg_debian="libssl"
 320 tor_openssl_devpkg_redhat="openssl-devel"
 321 tor_openssl_devpkg_debian="libssl-dev"
 322
 323 ALT_openssl_WITHVAL=""
 324 AC_ARG_WITH(ssl-dir,
 325   [  --with-ssl-dir=PATH    Obsolete alias for --with-openssl-dir ],
 326   [
 327       if test "x$withval" != xno && test "x$withval" != "x" ; then
 328          ALT_openssl_WITHVAL="$withval"
 329       fi
 330   ])
 331
 332 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 333     [#include <openssl/rand.h>],
 334     [void RAND_add(const void *buf, int num, double entropy);],
 335     [RAND_add((void*)0,0,0); exit(0);], [],
 336     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 337
 338 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 339
 340 echo "tor_cv_library_openssl_dir is $tor_cv_library_openssl_dir"
 341 if test "$enable_static_openssl" = "yes"; then
 342    if test "$tor_cv_library_openssl_dir" = "(system)"; then
 343      AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
 344    else
 345      TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
 346    fi
 347 else
 348      TOR_OPENSSL_LIBS="-lssl -lcrypto"
 349 fi
 350 AC_SUBST(TOR_OPENSSL_LIBS)
 351
 352 dnl ------------------------------------------------------
 353 dnl Where do you live, zlib?  And how do we call you?
 354
 355 tor_openssl_pkg_redhat="zlib"
 356 tor_openssl_pkg_debian="zlib1g"
 357 tor_openssl_devpkg_redhat="zlib-devel"
 358 tor_openssl_devpkg_debian="zlib1g-dev"
 359
 360 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 361     [#include <zlib.h>],
 362     [const char * zlibVersion(void);],
 363     [zlibVersion(); exit(0);], [--with-zlib-dir],
 364     [/opt/zlib])
 365
 366 dnl Make sure to enable support for large off_t if available.
 367
 368 AC_SYS_LARGEFILE
 369
 370 AC_CHECK_HEADERS(unistd.h string.h signal.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 371
 372 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h sys/uio.h)
 373
 374 dnl These headers are not essential
 375
 376 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h linux/types.h sys/file.h malloc_np.h sys/prctl.h)
 377
 378 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 379 [#ifdef HAVE_MALLOC_H
 380 #include <malloc.h>
 381 #endif
 382 #ifdef HAVE_MALLOC_MALLOC_H
 383 #include <malloc/malloc.h>
 384 #endif])
 385
 386 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 387 [#ifdef HAVE_SYS_TYPES_H
 388 #include <sys/types.h>
 389 #endif
 390 #ifdef HAVE_SYS_SOCKET_H
 391 #include <sys/socket.h>
 392 #endif])
 393 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 394 [#ifdef HAVE_SYS_TYPES_H
 395 #include <sys/types.h>
 396 #endif
 397 #ifdef HAVE_SYS_SOCKET_H
 398 #include <sys/socket.h>
 399 #endif
 400 #ifdef HAVE_NET_IF_H
 401 #include <net/if.h>
 402 #endif])
 403 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 404         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 405 [#ifdef HAVE_SYS_TYPES_H
 406 #include <sys/types.h>
 407 #endif
 408 #ifdef HAVE_SYS_SOCKET_H
 409 #include <sys/socket.h>
 410 #endif
 411 #ifdef HAVE_LIMITS_H
 412 #include <limits.h>
 413 #endif
 414 #ifdef HAVE_LINUX_TYPES_H
 415 #include <linux/types.h>
 416 #endif
 417 #ifdef HAVE_NETINET_IN6_H
 418 #include <netinet/in6.h>
 419 #endif
 420 #ifdef HAVE_NETINET_IN_H
 421 #include <netinet/in.h>
 422 #endif])
 423
 424 if test x$transparent = xtrue ; then
 425    transparent_ok=0
 426    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 427      transparent_ok=1
 428    fi
 429    if test x$linux_netfilter_ipv4 = x1 ; then
 430      transparent_ok=1
 431    fi
 432    if test x$transparent_ok = x1 ; then
 433      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 434      case $host in
 435        *-*-openbsd*)
 436          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 437      esac
 438    else
 439      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 440    fi
 441 fi
 442
 443 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 444 [#ifdef HAVE_SYS_TYPES_H
 445 #include <sys/types.h>
 446 #endif
 447 #ifdef HAVE_SYS_TIME_H
 448 #include <sys/time.h>
 449 #endif])
 450
 451 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 452 dnl Watch out.
 453
 454 AC_CHECK_SIZEOF(int8_t)
 455 AC_CHECK_SIZEOF(int16_t)
 456 AC_CHECK_SIZEOF(int32_t)
 457 AC_CHECK_SIZEOF(int64_t)
 458 AC_CHECK_SIZEOF(uint8_t)
 459 AC_CHECK_SIZEOF(uint16_t)
 460 AC_CHECK_SIZEOF(uint32_t)
 461 AC_CHECK_SIZEOF(uint64_t)
 462 AC_CHECK_SIZEOF(intptr_t)
 463 AC_CHECK_SIZEOF(uintptr_t)
 464
 465 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 466
 467 AC_CHECK_SIZEOF(char)
 468 AC_CHECK_SIZEOF(short)
 469 AC_CHECK_SIZEOF(int)
 470 AC_CHECK_SIZEOF(long)
 471 AC_CHECK_SIZEOF(long long)
 472 AC_CHECK_SIZEOF(__int64)
 473 AC_CHECK_SIZEOF(void *)
 474 AC_CHECK_SIZEOF(time_t)
 475 AC_CHECK_SIZEOF(size_t)
 476
 477 AC_CHECK_TYPES([uint, u_char, ssize_t])
 478
 479 dnl used to include sockaddr_storage, but everybody has that.
 480 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
 481 [#ifdef HAVE_SYS_TYPES_H
 482 #include <sys/types.h>
 483 #endif
 484 #ifdef HAVE_NETINET_IN_H
 485 #include <netinet/in.h>
 486 #endif
 487 #ifdef HAVE_NETINET_IN6_H
 488 #include <netinet/in6.h>
 489 #endif
 490 #ifdef HAVE_SYS_SOCKET_H
 491 #include <sys/socket.h>
 492 #endif
 493 #ifdef MS_WINDOWS
 494 #define WIN32_WINNT 0x400
 495 #define _WIN32_WINNT 0x400
 496 #define WIN32_LEAN_AND_MEAN
 497 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 498 #include <winsock.h>
 499 #else
 500 #include <winsock2.h>
 501 #include <ws2tcpip.h>
 502 #endif
 503 #endif
 504 ])
 505 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
 506 [#ifdef HAVE_SYS_TYPES_H
 507 #include <sys/types.h>
 508 #endif
 509 #ifdef HAVE_NETINET_IN_H
 510 #include <netinet/in.h>
 511 #endif
 512 #ifdef HAVE_NETINET_IN6_H
 513 #include <netinet/in6.h>
 514 #endif
 515 #ifdef HAVE_SYS_SOCKET_H
 516 #include <sys/socket.h>
 517 #endif
 518 #ifdef MS_WINDOWS
 519 #define WIN32_WINNT 0x400
 520 #define _WIN32_WINNT 0x400
 521 #define WIN32_LEAN_AND_MEAN
 522 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 523 #include <winsock.h>
 524 #else
 525 #include <winsock2.h>
 526 #include <ws2tcpip.h>
 527 #endif
 528 #endif
 529 ])
 530
 531 AC_CHECK_TYPES([rlim_t], , ,
 532 [#ifdef HAVE_SYS_TYPES_H
 533 #include <sys/types.h>
 534 #endif
 535 #ifdef HAVE_SYS_TIME_H
 536 #include <sys/time.h>
 537 #endif
 538 #ifdef HAVE_SYS_RESOURCE_H
 539 #include <sys/resource.h>
 540 #endif
 541 ])
 542
 543 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 544 AC_RUN_IFELSE(AC_LANG_SOURCE([
 545 #ifdef HAVE_SYS_TYPES_H
 546 #include <sys/types.h>
 547 #endif
 548 #ifdef HAVE_SYS_TIME_H
 549 #include <sys/time.h>
 550 #endif
 551 #ifdef HAVE_TIME_H
 552 #include <time.h>
 553 #endif
 554 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 555   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 556 ])
 557
 558 if test "$tor_cv_time_t_signed" = cross; then
 559   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 560 fi
 561
 562 if test "$tor_cv_time_t_signed" != no; then
 563   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 564             [Define to 1 iff time_t is signed])
 565 fi
 566
 567 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 568 #ifdef HAVE_SYS_SOCKET_H
 569 #include <sys/socket.h>
 570 #endif
 571 ])
 572
 573 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 574
 575 AC_CHECK_SIZEOF(cell_t)
 576
 577 # Now make sure that NULL can be represented as zero bytes.
 578 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 579 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 580 [[#include <stdlib.h>
 581 #include <string.h>
 582 #include <stdio.h>
 583 #ifdef HAVE_STDDEF_H
 584 #include <stddef.h>
 585 #endif
 586 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 587 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 588        [tor_cv_null_is_zero=yes],
 589        [tor_cv_null_is_zero=no],
 590        [tor_cv_null_is_zero=cross])])
 591
 592 if test "$tor_cv_null_is_zero" = cross ; then
 593   # Cross-compiling; let's hope that the target isn't raving mad.
 594   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 595 fi
 596
 597 if test "$tor_cv_null_is_zero" != no; then
 598   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 599             [Define to 1 iff memset(0) sets pointers to NULL])
 600 fi
 601
 602 # And what happens when we malloc zero?
 603 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 604 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 605 [[#include <stdlib.h>
 606 #include <string.h>
 607 #include <stdio.h>
 608 #ifdef HAVE_STDDEF_H
 609 #include <stddef.h>
 610 #endif
 611 int main () { return malloc(0)?0:1; }]])],
 612        [tor_cv_malloc_zero_works=yes],
 613        [tor_cv_malloc_zero_works=no],
 614        [tor_cv_malloc_zero_works=cross])])
 615
 616 if test "$tor_cv_malloc_zero_works" = cross; then
 617   # Cross-compiling; let's hope that the target isn't raving mad.
 618   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 619 fi
 620
 621 if test "$tor_cv_malloc_zero_works" = yes; then
 622   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 623             [Define to 1 iff malloc(0) returns a pointer])
 624 fi
 625
 626 # whether we seem to be in a 2s-complement world.
 627 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 628 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 629 [[int main () { int problem = ((-99) != (~99)+1);
 630 return problem ? 1 : 0; }]])],
 631        [tor_cv_twos_complement=yes],
 632        [tor_cv_twos_complement=no],
 633        [tor_cv_twos_complement=cross])])
 634
 635 if test "$tor_cv_twos_complement" = cross ; then
 636   # Cross-compiling; let's hope that the target isn't raving mad.
 637   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 638 fi
 639
 640 if test "$tor_cv_twos_complement" != no ; then
 641   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 642             [Define to 1 iff we represent negative integers with two's complement])
 643 fi
 644
 645 # Whether we should use the dmalloc memory allocation debugging library.
 646 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 647 AC_ARG_WITH(dmalloc,
 648 [  --with-dmalloc          Use debug memory allocation library. ],
 649 [if [[ "$withval" = "yes" ]]; then
 650   dmalloc=1
 651   AC_MSG_RESULT(yes)
 652 else
 653   dmalloc=1
 654   AC_MSG_RESULT(no)
 655 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 656 )
 657
 658 if [[ $dmalloc -eq 1 ]]; then
 659   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 660   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 661   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 662   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 663   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 664 fi
 665
 666 AC_ARG_WITH(tcmalloc,
 667 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 668 [ tcmalloc=yes ], [ tcmalloc=no ])
 669
 670 if test x$tcmalloc = xyes ; then
 671    LDFLAGS="-ltcmalloc $LDFLAGS"
 672 fi
 673
 674 # By default, we're going to assume we don't have mlockall()
 675 # bionic and other platforms have various broken mlockall subsystems.
 676 # Some systems don't have a working mlockall, some aren't linkable,
 677 # and some have it but don't declare it.
 678 AC_CHECK_FUNCS(mlockall)
 679 AC_CHECK_DECLS([mlockall], , , [
 680 #ifdef HAVE_SYS_MMAN_H
 681 #include <sys/mman.h>
 682 #endif])
 683
 684 # Allow user to specify an alternate syslog facility
 685 AC_ARG_WITH(syslog-facility,
 686 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 687 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 688 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 689 AC_SUBST(LOGFACILITY)
 690
 691 # Check if we have getresuid and getresgid
 692 AC_CHECK_FUNCS(getresuid getresgid)
 693
 694 # Check for gethostbyname_r in all its glorious incompatible versions.
 695 #   (This logic is based on that in Python's configure.in)
 696 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 697   [Define this if you have any gethostbyname_r()])
 698
 699 AC_CHECK_FUNC(gethostbyname_r, [
 700   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 701   OLD_CFLAGS=$CFLAGS
 702   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 703   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 704 #include <netdb.h>
 705   ], [[
 706     char *cp1, *cp2;
 707     struct hostent *h1, *h2;
 708     int i1, i2;
 709     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 710   ]]),[
 711     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 712     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 713      [Define this if gethostbyname_r takes 6 arguments])
 714     AC_MSG_RESULT(6)
 715   ], [
 716     AC_TRY_COMPILE([
 717 #include <netdb.h>
 718     ], [
 719       char *cp1, *cp2;
 720       struct hostent *h1;
 721       int i1, i2;
 722       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 723     ], [
 724       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 725       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 726         [Define this if gethostbyname_r takes 5 arguments])
 727       AC_MSG_RESULT(5)
 728    ], [
 729       AC_TRY_COMPILE([
 730 #include <netdb.h>
 731      ], [
 732        char *cp1;
 733        struct hostent *h1;
 734        struct hostent_data hd;
 735        (void) gethostbyname_r(cp1,h1,&hd);
 736      ], [
 737        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 738        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 739          [Define this if gethostbyname_r takes 3 arguments])
 740        AC_MSG_RESULT(3)
 741      ], [
 742        AC_MSG_RESULT(0)
 743      ])
 744   ])
 745  ])
 746  CFLAGS=$OLD_CFLAGS
 747 ])
 748
 749 AC_CACHE_CHECK([whether the C compiler supports __func__],
 750   tor_cv_have_func_macro,
 751   AC_COMPILE_IFELSE([
 752 #include <stdio.h>
 753 int main(int c, char **v) { puts(__func__); }],
 754   tor_cv_have_func_macro=yes,
 755   tor_cv_have_func_macro=no))
 756
 757 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 758   tor_cv_have_FUNC_macro,
 759   AC_COMPILE_IFELSE([
 760 #include <stdio.h>
 761 int main(int c, char **v) { puts(__FUNC__); }],
 762   tor_cv_have_FUNC_macro=yes,
 763   tor_cv_have_FUNC_macro=no))
 764
 765 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 766   tor_cv_have_FUNCTION_macro,
 767   AC_COMPILE_IFELSE([
 768 #include <stdio.h>
 769 int main(int c, char **v) { puts(__FUNCTION__); }],
 770   tor_cv_have_FUNCTION_macro=yes,
 771   tor_cv_have_FUNCTION_macro=no))
 772
 773 if test "$tor_cv_have_func_macro" = 'yes'; then
 774   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 775 fi
 776
 777 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 778   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 779 fi
 780
 781 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 782   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 783            [Defined if the compiler supports __FUNCTION__])
 784 fi
 785
 786 # $prefix stores the value of the --prefix command line option, or
 787 # NONE if the option wasn't set.  In the case that it wasn't set, make
 788 # it be the default, so that we can use it to expand directories now.
 789 if test "x$prefix" = "xNONE"; then
 790   prefix=$ac_default_prefix
 791 fi
 792
 793 # and similarly for $exec_prefix
 794 if test "x$exec_prefix" = "xNONE"; then
 795   exec_prefix=$prefix
 796 fi
 797
 798 if test "x$CONFDIR" = "x"; then
 799   CONFDIR=`eval echo $sysconfdir/tor`
 800 fi
 801 AC_SUBST(CONFDIR)
 802 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 803 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 804
 805 BINDIR=`eval echo $bindir`
 806 AC_SUBST(BINDIR)
 807 LOCALSTATEDIR=`eval echo $localstatedir`
 808 AC_SUBST(LOCALSTATEDIR)
 809
 810 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 811 # than autoconf's macros like.
 812 if test "$GCC" = yes; then
 813   CFLAGS="$CFLAGS -Wall -g -O2"
 814   # Disable GCC's strict aliasing checks.  They are an hours-to-debug
 815   # accident waiting to happen.
 816   CFLAGS="$CFLAGS -fno-strict-aliasing"
 817 else
 818   CFLAGS="$CFLAGS -g -O"
 819   enable_gcc_warnings=no
 820   enable_gcc_warnings_advisory=no
 821 fi
 822
 823 # Add some more warnings which we use in development but not in the
 824 # released versions.  (Some relevant gcc versions can't handle these.)
 825 if test x$enable_gcc_warnings = xyes || test x$enable_gcc_warnings_advisory = xyes; then
 826
 827   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 828 #if !defined(__GNUC__) || (__GNUC__ < 4)
 829 #error
 830 #endif]), have_gcc4=yes, have_gcc4=no)
 831
 832   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 833 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 834 #error
 835 #endif]), have_gcc42=yes, have_gcc42=no)
 836
 837   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 838 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 839 #error
 840 #endif]), have_gcc43=yes, have_gcc43=no)
 841
 842   save_CFLAGS="$CFLAGS"
 843   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 844   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 845                     have_shorten64_flag=no)
 846   CFLAGS="$save_CFLAGS"
 847
 848   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum"
 849   if test x$enable_gcc_warnings = xyes; then
 850     CFLAGS="$CFLAGS -Werror"
 851   fi
 852
 853   # Disabled, so we can use mallinfo(): -Waggregate-return
 854
 855   if test x$have_gcc4 = xyes ; then
 856     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 857     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 858   fi
 859
 860   if test x$have_gcc42 = xyes ; then
 861     # These warnings break gcc 4.0.2 and work on gcc 4.2
 862     # XXXX020 Use -fstack-protector.
 863     # XXXX020 See if any of these work with earlier versions.
 864     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 865     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 866   fi
 867
 868   if test x$have_gcc43 = xyes ; then
 869     # These warnings break gcc 4.2 and work on gcc 4.3
 870     # XXXX020 See if any of these work with earlier versions.
 871     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 872   fi
 873
 874   if test x$have_shorten64_flag = xyes ; then
 875     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 876   fi
 877
 878 ##This will break the world on some 64-bit architectures
 879 # CFLAGS="$CFLAGS -Winline"
 880 fi
 881
 882
 883
 884 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 885
 886 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample src/Makefile doc/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/test/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 887 AC_OUTPUT
 888
 889 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 890   ./contrib/updateVersions.pl
 891 fi
 892