configure.in

   1 dnl $Id$
   2 dnl Copyright (c) 2001-2004, Roger Dingledine
   3 dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
   4 dnl Copyright (c) 2007-2008, The Tor Project, Inc.
   5 dnl See LICENSE for licensing information
   6
   7 AC_INIT
   8 AM_INIT_AUTOMAKE(tor, 0.2.1.0-alpha-dev)
   9 AM_CONFIG_HEADER(orconfig.h)
  10
  11 AC_CANONICAL_HOST
  12
  13 if test -f /etc/redhat-release ; then
  14   if test -f /usr/kerberos/include ; then
  15     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  16   fi
  17 fi
  18
  19 # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  20 # the += operator on it in src/or/Makefile.am
  21 CPPFLAGS="$CPPFLAGS -I../common"
  22
  23 AC_ARG_ENABLE(debug,
  24  AS_HELP_STRING(--enable-debug, compile with debugging info),
  25 [if test x$enableval = xyes; then
  26     CFLAGS="$CFLAGS -g"
  27 fi])
  28
  29 #XXXX ideally, we should make this into a no-op, and detect whether we're
  30 #compiling for the iphone by using $target.
  31 AC_ARG_ENABLE(iphone,
  32  AS_HELP_STRING(--enable-iphone, compile with iPhone support),
  33  [if test x$enableval = xyes ; then
  34    tor_cv_iphone=true
  35    CFLAGS="$CFLAGS -D__DARWIN_UNIX03 -DIPHONE"
  36   fi])
  37
  38 #XXXX020 We should make these enabled or not, before 0.2.0.x-final
  39 AC_ARG_ENABLE(cell-pool,
  40      AS_HELP_STRING(--disable-cell-pool, disable pool allocator for cells))
  41 AC_ARG_ENABLE(buf-freelists,
  42    AS_HELP_STRING(--disable-buf-freelists, disable freelists for buffer RAM))
  43 AC_ARG_ENABLE(openbsd-malloc,
  44    AS_HELP_STRING(--enable-openbsd-malloc, Use malloc code from openbsd.  Linux only))
  45
  46
  47 if test x$enable_cell_pool != xno; then
  48   AC_DEFINE(ENABLE_CELL_POOL, 1,
  49             [Defined if we try to use the pool allocator for queued cells])
  50 fi
  51 if test x$enable_buf_freelists != xno; then
  52   AC_DEFINE(ENABLE_BUF_FREELISTS, 1,
  53             [Defined if we try to use freelists for buffer RAM chunks])
  54 fi
  55 AM_CONDITIONAL(USE_OPENBSD_MALLOC, test x$enable_openbsd_malloc = xyes)
  56
  57 AC_ARG_ENABLE(transparent,
  58      AS_HELP_STRING(--disable-transparent, disable transparent proxy support),
  59      [case "${enableval}" in
  60         yes) transparent=true ;;
  61         no)  transparent=false ;;
  62         *) AC_MSG_ERROR(bad value for --enable-transparent) ;;
  63       esac], [transparent=true])
  64
  65 AC_ARG_ENABLE(threads,
  66      AS_HELP_STRING(--disable-threads, disable multi-threading support))
  67
  68 if test x$enable_threads = x; then
  69    case $host in
  70     *-*-solaris* )
  71      # Don't try multithreading on solaris -- cpuworkers seem to lock.
  72      AC_MSG_NOTICE([You are running Solaris; Sometimes threading makes
  73 cpu workers lock up here, so I will disable threads.])
  74      enable_threads="no";;
  75     *)
  76      enable_threads="yes";;
  77    esac
  78 fi
  79
  80 if test "$enable_threads" = "yes"; then
  81   AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  82 fi
  83
  84 case $host in
  85    *-*-solaris* )
  86      AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  87      ;;
  88 esac
  89
  90 AC_ARG_ENABLE(gcc-warnings,
  91      AS_HELP_STRING(--enable-gcc-warnings, enable verbose warnings))
  92
  93 AC_PROG_CC
  94 AC_PROG_CPP
  95 AC_PROG_MAKE_SET
  96 AC_PROG_RANLIB
  97
  98 TORUSER=_tor
  99 AC_ARG_WITH(tor-user,
 100         [  --with-tor-user=NAME    Specify username for tor daemon ],
 101         [
 102            TORUSER=$withval
 103         ]
 104 )
 105 AC_SUBST(TORUSER)
 106
 107 TORGROUP=_tor
 108 AC_ARG_WITH(tor-group,
 109         [  --with-tor-group=NAME   Specify group name for tor daemon ],
 110         [
 111            TORGROUP=$withval
 112         ]
 113 )
 114 AC_SUBST(TORGROUP)
 115
 116
 117 dnl If WIN32 is defined and non-zero, we are building for win32
 118 AC_MSG_CHECKING([for win32])
 119 AC_RUN_IFELSE([
 120 int main(int c, char **v) {
 121 #ifdef WIN32
 122 #if WIN32
 123   return 0;
 124 #else
 125   return 1;
 126 #endif
 127 #else
 128   return 2;
 129 #endif
 130 }],
 131 bwin32=true; AC_MSG_RESULT([yes]),
 132 bwin32=false; AC_MSG_RESULT([no]),
 133 bwin32=cross; AC_MSG_RESULT([cross])
 134 )
 135
 136 if test "$bwin32" = cross; then
 137 AC_MSG_CHECKING([for win32 (cross)])
 138 AC_COMPILE_IFELSE([
 139 #ifdef WIN32
 140 int main(int c, char **v) {return 0;}
 141 #else
 142 #error
 143 int main(int c, char **v) {return x(y);}
 144 #endif
 145 ],
 146 bwin32=true; AC_MSG_RESULT([yes]),
 147 bwin32=false; AC_MSG_RESULT([no]))
 148 fi
 149
 150 if test "$bwin32" = true; then
 151 AC_DEFINE(MS_WINDOWS, 1, [Define to 1 if we are building for Windows.])
 152 fi
 153 AM_CONDITIONAL(BUILD_NT_SERVICES, test x$bwin32 = xtrue)
 154
 155 dnl Enable C99 when compiling with MIPSpro
 156 AC_MSG_CHECKING([for MIPSpro compiler])
 157 AC_COMPILE_IFELSE(AC_LANG_PROGRAM(, [
 158 #if (defined(__sgi) && defined(_COMPILER_VERSION))
 159 #error
 160   return x(y);
 161 #endif
 162 ]),
 163 bmipspro=false; AC_MSG_RESULT(no),
 164 bmipspro=true; AC_MSG_RESULT(yes))
 165
 166 if test "$bmipspro" = true; then
 167   CFLAGS="$CFLAGS -c99"
 168 fi
 169
 170 AC_C_BIGENDIAN
 171
 172 AC_SEARCH_LIBS(socket, [socket])
 173 AC_SEARCH_LIBS(gethostbyname, [nsl])
 174 AC_SEARCH_LIBS(dlopen, [dl])
 175 AC_SEARCH_LIBS(inet_aton, [resolv])
 176
 177 if test "$enable_threads" = "yes"; then
 178   AC_SEARCH_LIBS(pthread_create, [pthread])
 179   AC_SEARCH_LIBS(pthread_detach, [pthread])
 180 fi
 181
 182 dnl -------------------------------------------------------------------
 183 dnl Check for functions before libevent, since libevent-1.2 apparently
 184 dnl exports strlcpy without defining it in a header.
 185
 186 AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit strlcat strlcpy strtoull ftello getaddrinfo localtime_r gmtime_r memmem strtok_r inet_pton inet_ntop)
 187
 188 using_custom_malloc=no
 189 if test x$enable_openbsd_malloc = xyes ; then
 190    AC_DEFINE(HAVE_MALLOC_GOOD_SIZE, 1, [Defined if we have the malloc_good_size function])
 191    using_custom_malloc=yes
 192 fi
 193 if test x$tcmalloc = xyes ; then
 194    using_custom_malloc=yes
 195 fi
 196 if test $using_custom_malloc = no ; then
 197    AC_CHECK_FUNCS(mallinfo malloc_good_size malloc_usable_size)
 198 fi
 199
 200 if test "$enable_threads" = "yes"; then
 201   AC_CHECK_HEADERS(pthread.h)
 202   AC_CHECK_FUNCS(pthread_create)
 203 fi
 204
 205 dnl ------------------------------------------------------
 206 dnl Where do you live, libevent?  And how do we call you?
 207
 208 if test "$bwin32" = true; then
 209   TOR_LIB_WS32=-lws2_32
 210   # Some of the cargo-cults recommend -lwsock32 as well, but I don't
 211   # think it's actually necessary.
 212   TOR_LIB_GDI=-lgdi32
 213 else
 214   TOR_LIB_WS32=
 215   TOR_LIB_GDI=
 216 fi
 217 AC_SUBST(TOR_LIB_WS32)
 218 AC_SUBST(TOR_LIB_GDI)
 219
 220 dnl We need to do this before we try our disgusting hack below.
 221 AC_CHECK_HEADERS([sys/types.h])
 222
 223 dnl This is a disgusting hack so we safely include older libevent headers.
 224 AC_CHECK_TYPE(u_int64_t, unsigned long long)
 225 AC_CHECK_TYPE(u_int32_t, unsigned long)
 226 AC_CHECK_TYPE(u_int16_t, unsigned short)
 227 AC_CHECK_TYPE(u_int8_t, unsigned char)
 228
 229 tor_libevent_pkg_redhat="libevent"
 230 tor_libevent_pkg_debian="libevent-dev"
 231 tor_libevent_devpkg_redhat="libevent-devel"
 232 tor_libevent_devpkg_debian="libevent-dev"
 233
 234 TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $TOR_LIB_WS32], [
 235 #include <stdlib.h>
 236 #include <sys/time.h>
 237 #include <sys/types.h>
 238 #include <event.h>], [void exit(int); void *event_init(void);],
 239     [event_init(); exit(0);], [--with-libevent-dir], [/opt/libevent])
 240
 241 dnl Now check for particular libevent functions.
 242 save_LIBS="$LIBS"
 243 save_LDFLAGS="$LDFLAGS"
 244 save_CPPFLAGS="$CPPFLAGS"
 245 LIBS="-levent $TOR_LIB_WS32 $LIBS"
 246 LDFLAGS="$TOR_LDFLAGS_libevent $LIBS"
 247 CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
 248 AC_CHECK_FUNCS(event_get_version event_get_method event_set_log_callback)
 249 LIBS="$save_LIBS"
 250 LDFLAGS="$save_LDFLAGS"
 251 CPPFLAGS="$save_CPPFLAGS"
 252
 253 dnl ------------------------------------------------------
 254 dnl Where do you live, openssl?  And how do we call you?
 255
 256 tor_openssl_pkg_redhat="openssl"
 257 tor_openssl_pkg_debian="libssl"
 258 tor_openssl_devpkg_redhat="openssl-devel"
 259 tor_openssl_devpkg_debian="libssl-dev"
 260
 261 TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
 262     [#include <openssl/rand.h>],
 263     [void RAND_add(const void *buf, int num, double entropy);],
 264     [RAND_add((void*)0,0,0); exit(0);], [--with-ssl-dir],
 265     [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
 266
 267 dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
 268
 269 dnl ------------------------------------------------------
 270 dnl Where do you live, zlib?  And how do we call you?
 271
 272 tor_openssl_pkg_redhat="zlib"
 273 tor_openssl_pkg_debian="zlib1g"
 274 tor_openssl_devpkg_redhat="zlib-devel"
 275 tor_openssl_devpkg_debian="zlib1g-dev"
 276
 277 TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
 278     [#include <zlib.h>],
 279     [const char * zlibVersion(void);],
 280     [zlibVersion(); exit(0);], [--with-zlib-dir],
 281     [/opt/zlib])
 282
 283 dnl Make sure to enable support for large off_t if available.
 284
 285 AC_SYS_LARGEFILE
 286
 287 AC_CHECK_HEADERS(unistd.h string.h signal.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/time.h errno.h assert.h time.h, , AC_MSG_WARN(Some headers were not found, compilation may fail.  If compilation succeeds, please send your orconfig.h to the developers so we can fix this warning.))
 288
 289 AC_CHECK_HEADERS(netdb.h sys/ioctl.h sys/socket.h arpa/inet.h netinet/in.h pwd.h grp.h sys/un.h)
 290
 291 dnl These headers are not essential
 292
 293 AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h limits.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h inttypes.h utime.h sys/utime.h sys/mman.h netintet/in.h netinet/in6.h malloc.h sys/syslimits.h malloc/malloc.h)
 294
 295 TOR_CHECK_PROTOTYPE(malloc_good_size, HAVE_MALLOC_GOOD_SIZE_PROTOTYPE,
 296 [#ifdef HAVE_MALLOC_H
 297 #include <malloc.h>
 298 #endif
 299 #ifdef HAVE_MALLOC_MALLOC_H
 300 #include <malloc/malloc.h>
 301 #endif])
 302
 303 AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
 304 [#ifdef HAVE_SYS_TYPES_H
 305 #include <sys/types.h>
 306 #endif
 307 #ifdef HAVE_SYS_SOCKET_H
 308 #include <sys/socket.h>
 309 #endif])
 310 AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
 311 [#ifdef HAVE_SYS_TYPES_H
 312 #include <sys/types.h>
 313 #endif
 314 #ifdef HAVE_SYS_SOCKET_H
 315 #include <sys/socket.h>
 316 #endif
 317 #ifdef HAVE_NET_IF_H
 318 #include <net/if.h>
 319 #endif])
 320 AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
 321         linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
 322 [#ifdef HAVE_SYS_TYPES_H
 323 #include <sys/types.h>
 324 #endif
 325 #ifdef HAVE_SYS_SOCKET_H
 326 #include <sys/socket.h>
 327 #endif])
 328
 329 if test x$transparent = xtrue ; then
 330    transparent_ok=0
 331    if test x$net_if_found = x1 && test x$net_pfvar_found = x1 ; then
 332      transparent_ok=1
 333    fi
 334    if test x$linux_netfilter_ipv4 = x1 ; then
 335      transparent_ok=1
 336    fi
 337    if test x$transparent_ok = x1 ; then
 338      AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
 339      case $host in
 340        *-*-openbsd*)
 341          AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
 342      esac
 343    else
 344      AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
 345    fi
 346 fi
 347
 348 AC_FUNC_FSEEKO
 349
 350 AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
 351 [#ifdef HAVE_SYS_TYPES_H
 352 #include <sys/types.h>
 353 #endif
 354 #ifdef HAVE_SYS_TIME_H
 355 #include <sys/time.h>
 356 #endif])
 357
 358 dnl In case we aren't given a working stdint.h, we'll need to grow our own.
 359 dnl Watch out.
 360
 361 AC_CHECK_SIZEOF(int8_t)
 362 AC_CHECK_SIZEOF(int16_t)
 363 AC_CHECK_SIZEOF(int32_t)
 364 AC_CHECK_SIZEOF(int64_t)
 365 AC_CHECK_SIZEOF(uint8_t)
 366 AC_CHECK_SIZEOF(uint16_t)
 367 AC_CHECK_SIZEOF(uint32_t)
 368 AC_CHECK_SIZEOF(uint64_t)
 369 AC_CHECK_SIZEOF(intptr_t)
 370 AC_CHECK_SIZEOF(uintptr_t)
 371
 372 dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
 373
 374 AC_CHECK_SIZEOF(char)
 375 AC_CHECK_SIZEOF(short)
 376 AC_CHECK_SIZEOF(int)
 377 AC_CHECK_SIZEOF(long)
 378 AC_CHECK_SIZEOF(long long)
 379 AC_CHECK_SIZEOF(__int64)
 380 AC_CHECK_SIZEOF(void *)
 381 AC_CHECK_SIZEOF(time_t)
 382 AC_CHECK_SIZEOF(size_t)
 383
 384 AC_CHECK_TYPES([uint, u_char, ssize_t])
 385
 386 AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, struct sockaddr_storage, sa_family_t], , ,
 387 [#ifdef HAVE_SYS_TYPES_H
 388 #include <sys/types.h>
 389 #endif
 390 #ifdef HAVE_NETINET_IN_H
 391 #include <netinet/in.h>
 392 #endif
 393 #ifdef HAVE_NETINET_IN6_H
 394 #include <netinet/in6.h>
 395 #endif
 396 #ifdef HAVE_SYS_SOCKET_H
 397 #include <sys/socket.h>
 398 #endif
 399 #ifdef MS_WINDOWS
 400 #define WIN32_WINNT 0x400
 401 #define _WIN32_WINNT 0x400
 402 #define WIN32_LEAN_AND_MEAN
 403 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 404 #include <winsock.h>
 405 #else
 406 #include <winsock2.h>
 407 #include <ws2tcpip.h>
 408 #endif
 409 #endif
 410 ])
 411 AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16], , ,
 412 [#ifdef HAVE_SYS_TYPES_H
 413 #include <sys/types.h>
 414 #endif
 415 #ifdef HAVE_NETINET_IN_H
 416 #include <netinet/in.h>
 417 #endif
 418 #ifdef HAVE_NETINET_IN6_H
 419 #include <netinet/in6.h>
 420 #endif
 421 #ifdef HAVE_SYS_SOCKET_H
 422 #include <sys/socket.h>
 423 #endif
 424 #ifdef MS_WINDOWS
 425 #define WIN32_WINNT 0x400
 426 #define _WIN32_WINNT 0x400
 427 #define WIN32_LEAN_AND_MEAN
 428 #if defined(_MSC_VER) && (_MSC_VER < 1300)
 429 #include <winsock.h>
 430 #else
 431 #include <winsock2.h>
 432 #include <ws2tcpip.h>
 433 #endif
 434 #endif
 435 ])
 436
 437 AC_CHECK_TYPES([rlim_t], , ,
 438 [#ifdef HAVE_SYS_TYPES_H
 439 #include <sys/types.h>
 440 #endif
 441 #ifdef HAVE_SYS_TIME_H
 442 #include <sys/time.h>
 443 #endif
 444 #ifdef HAVE_SYS_RESOURCE_H
 445 #include <sys/resource.h>
 446 #endif
 447 ])
 448
 449 AC_CACHE_CHECK([whether time_t is signed], tor_cv_time_t_signed, [
 450 AC_RUN_IFELSE(AC_LANG_SOURCE([
 451 #ifdef HAVE_SYS_TYPES_H
 452 #include <sys/types.h>
 453 #endif
 454 #ifdef HAVE_SYS_TIME_H
 455 #include <sys/time.h>
 456 #endif
 457 #ifdef HAVE_TIME_H
 458 #include <time.h>
 459 #endif
 460 int main(int c, char**v) { if (((time_t)-1)<0) return 1; else return 0; }]),
 461   tor_cv_time_t_signed=no, tor_cv_time_t_signed=yes, tor_cv_time_t_signed=cross)
 462 ])
 463
 464 if test "$tor_cv_time_t_signed" = cross; then
 465   AC_MSG_NOTICE([Cross compiling: assuming that time_t is signed.])
 466 fi
 467
 468 if test "$tor_cv_time_t_signed" != no; then
 469   AC_DEFINE([TIME_T_IS_SIGNED], 1,
 470             [Define to 1 iff time_t is signed])
 471 fi
 472
 473 AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
 474 #ifdef HAVE_SYS_SOCKET_H
 475 #include <sys/socket.h>
 476 #endif
 477 ])
 478
 479 # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
 480
 481 AC_CHECK_SIZEOF(cell_t)
 482
 483 # Now make sure that NULL can be represented as zero bytes.
 484 AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
 485 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 486 [[#include <stdlib.h>
 487 #include <string.h>
 488 #include <stdio.h>
 489 #ifdef HAVE_STDDEF_H
 490 #include <stddef.h>
 491 #endif
 492 int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
 493 return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
 494        [tor_cv_null_is_zero=yes],
 495        [tor_cv_null_is_zero=no],
 496        [tor_cv_null_is_zero=cross])])
 497
 498 if test "$tor_cv_null_is_zero" = cross ; then
 499   # Cross-compiling; let's hope that the target isn't raving mad.
 500   AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
 501 fi
 502
 503 if test "$tor_cv_null_is_zero" != no; then
 504   AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
 505             [Define to 1 iff memset(0) sets pointers to NULL])
 506 fi
 507
 508 # And what happens when we malloc zero?
 509 AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
 510 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 511 [[#include <stdlib.h>
 512 #include <string.h>
 513 #include <stdio.h>
 514 #ifdef HAVE_STDDEF_H
 515 #include <stddef.h>
 516 #endif
 517 int main () { return malloc(0)?0:1; }]])],
 518        [tor_cv_malloc_zero_works=yes],
 519        [tor_cv_malloc_zero_works=no],
 520        [tor_cv_malloc_zero_works=cross])])
 521
 522 if test "$tor_cv_malloc_zero_works" = cross; then
 523   # Cross-compiling; let's hope that the target isn't raving mad.
 524   AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
 525 fi
 526
 527 if test "$tor_cv_malloc_zero_works" = yes; then
 528   AC_DEFINE([MALLOC_ZERO_WORKS], 1,
 529             [Define to 1 iff malloc(0) returns a pointer])
 530 fi
 531
 532 # whether we seem to be in a 2s-complement world.
 533 AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
 534 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 535 [[int main () { int problem = ((-99) != (~99)+1);
 536 return problem ? 1 : 0; }]])],
 537        [tor_cv_twos_complement=yes],
 538        [tor_cv_twos_complement=no],
 539        [tor_cv_twos_complement=cross])])
 540
 541 if test "$tor_cv_twos_complement" = cross ; then
 542   # Cross-compiling; let's hope that the target isn't raving mad.
 543   AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
 544 fi
 545
 546 if test "$tor_cv_twos_complement" != no ; then
 547   AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
 548             [Define to 1 iff we represent negative integers with two's complement])
 549 fi
 550
 551 # Whether we should use the dmalloc memory allocation debugging library.
 552 AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
 553 AC_ARG_WITH(dmalloc,
 554 [  --with-dmalloc          Use debug memory allocation library. ],
 555 [if [[ "$withval" = "yes" ]]; then
 556   dmalloc=1
 557   AC_MSG_RESULT(yes)
 558 else
 559   dmalloc=1
 560   AC_MSG_RESULT(no)
 561 fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
 562 )
 563
 564 if [[ $dmalloc -eq 1 ]]; then
 565   AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
 566   AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
 567   AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
 568   AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
 569   AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
 570 fi
 571
 572 AC_ARG_WITH(tcmalloc,
 573 [  --with-tcmalloc         Use tcmalloc memory allocation library. ],
 574 [ tcmalloc=yes ], [ tcmalloc=no ])
 575
 576 if test x$tcmalloc = xyes ; then
 577    LDFLAGS="-ltcmalloc $LDFLAGS"
 578 fi
 579
 580 # Allow user to specify an alternate syslog facility
 581 AC_ARG_WITH(syslog-facility,
 582 [  --with-syslog-facility=LOG syslog facility to use (default=LOG_DAEMON)],
 583 syslog_facility="$withval", syslog_facility="LOG_DAEMON")
 584 AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
 585 AC_SUBST(LOGFACILITY)
 586
 587 # Check for gethostbyname_r in all its glorious incompatible versions.
 588 #   (This logic is based on that in Python's configure.in)
 589 AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
 590   [Define this if you have any gethostbyname_r()])
 591
 592 AC_CHECK_FUNC(gethostbyname_r, [
 593   AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
 594   OLD_CFLAGS=$CFLAGS
 595   CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
 596   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 597 #include <netdb.h>
 598   ], [[
 599     char *cp1, *cp2;
 600     struct hostent *h1, *h2;
 601     int i1, i2;
 602     (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
 603   ]]),[
 604     AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 605     AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
 606      [Define this if gethostbyname_r takes 6 arguments])
 607     AC_MSG_RESULT(6)
 608   ], [
 609     AC_TRY_COMPILE([
 610 #include <netdb.h>
 611     ], [
 612       char *cp1, *cp2;
 613       struct hostent *h1;
 614       int i1, i2;
 615       (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
 616     ], [
 617       AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 618       AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
 619         [Define this if gethostbyname_r takes 5 arguments])
 620       AC_MSG_RESULT(5)
 621    ], [
 622       AC_TRY_COMPILE([
 623 #include <netdb.h>
 624      ], [
 625        char *cp1;
 626        struct hostent *h1;
 627        struct hostent_data hd;
 628        (void) gethostbyname_r(cp1,h1,&hd);
 629      ], [
 630        AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 631        AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
 632          [Define this if gethostbyname_r takes 3 arguments])
 633        AC_MSG_RESULT(3)
 634      ], [
 635        AC_MSG_RESULT(0)
 636      ])
 637   ])
 638  ])
 639  CFLAGS=$OLD_CFLAGS
 640 ])
 641
 642 AC_CACHE_CHECK([whether the C compiler supports __func__],
 643   tor_cv_have_func_macro,
 644   AC_COMPILE_IFELSE([
 645 #include <stdio.h>
 646 int main(int c, char **v) { puts(__func__); }],
 647   tor_cv_have_func_macro=yes,
 648   tor_cv_have_func_macro=no))
 649
 650 AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
 651   tor_cv_have_FUNC_macro,
 652   AC_COMPILE_IFELSE([
 653 #include <stdio.h>
 654 int main(int c, char **v) { puts(__FUNC__); }],
 655   tor_cv_have_FUNC_macro=yes,
 656   tor_cv_have_FUNC_macro=no))
 657
 658 AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
 659   tor_cv_have_FUNCTION_macro,
 660   AC_COMPILE_IFELSE([
 661 #include <stdio.h>
 662 int main(int c, char **v) { puts(__FUNCTION__); }],
 663   tor_cv_have_FUNCTION_macro=yes,
 664   tor_cv_have_FUNCTION_macro=no))
 665
 666 if test "$tor_cv_have_func_macro" = 'yes'; then
 667   AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
 668 fi
 669
 670 if test "$tor_cv_have_FUNC_macro" = 'yes'; then
 671   AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
 672 fi
 673
 674 if test "$tor_cv_have_FUNCTION_macro" = 'yes'; then
 675   AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
 676            [Defined if the compiler supports __FUNCTION__])
 677 fi
 678
 679 # $prefix stores the value of the --prefix command line option, or
 680 # NONE if the option wasn't set.  In the case that it wasn't set, make
 681 # it be the default, so that we can use it to expand directories now.
 682 if test "x$prefix" = "xNONE"; then
 683   prefix=$ac_default_prefix
 684 fi
 685
 686 # and similarly for $exec_prefix
 687 if test "x$exec_prefix" = "xNONE"; then
 688   exec_prefix=$prefix
 689 fi
 690
 691 if test "x$CONFDIR" = "x"; then
 692   CONFDIR=`eval echo $sysconfdir/tor`
 693 fi
 694 AC_SUBST(CONFDIR)
 695 AH_TEMPLATE([CONFDIR],[tor's configuration directory])
 696 AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
 697
 698 BINDIR=`eval echo $bindir`
 699 AC_SUBST(BINDIR)
 700 LOCALSTATEDIR=`eval echo $localstatedir`
 701 AC_SUBST(LOCALSTATEDIR)
 702
 703 # Set CFLAGS _after_ all the above checks, since our warnings are stricter
 704 # than autoconf's macros like.
 705 if test "$ac_cv_c_compiler_gnu" = yes; then
 706   CFLAGS="$CFLAGS -Wall -g -O2"
 707 else
 708   CFLAGS="$CFLAGS -g -O"
 709   enable_gcc_warnings=no
 710 fi
 711
 712 # Add some more warnings which we use in development but not in the
 713 # released versions.  (Some relevant gcc versions can't handle these.)
 714 if test x$enable_gcc_warnings = xyes; then
 715
 716   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 717 #if !defined(__GNUC__) || (__GNUC__ < 4)
 718 #error
 719 #endif]), have_gcc4=yes, have_gcc4=no)
 720
 721   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 722 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 2)
 723 #error
 724 #endif]), have_gcc42=yes, have_gcc42=no)
 725
 726   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], [
 727 #if !defined(__GNUC__) || (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 3)
 728 #error
 729 #endif]), have_gcc43=yes, have_gcc43=no)
 730
 731   save_CFLAGS="$CFLAGS"
 732   CFLAGS="$CFLAGS -Wshorten-64-to-32"
 733   AC_COMPILE_IFELSE(AC_LANG_PROGRAM([], []), have_shorten64_flag=yes,
 734                     have_shorten64_flag=no)
 735   CFLAGS="$save_CFLAGS"
 736
 737   CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2 -Wwrite-strings -Wmissing-declarations -Wredundant-decls -Wnested-externs -Wbad-function-cast -Wswitch-enum -Werror"
 738
 739   # Disabled, so we can use mallinfo(): -Waggregate-return
 740
 741   if test x$have_gcc4 = xyes ; then
 742     # These warnings break gcc 3.3.5 and work on gcc 4.0.2
 743     CFLAGS="$CFLAGS -Winit-self -Wmissing-field-initializers -Wdeclaration-after-statement -Wold-style-definition"
 744   fi
 745
 746   if test x$have_gcc42 = xyes ; then
 747     # These warnings break gcc 4.0.2 and work on gcc 4.2
 748     # XXXX020 Use -fstack-protector.
 749     # XXXX020 See if any of these work with earlier versions.
 750     CFLAGS="$CFLAGS -Waddress -Wmissing-noreturn -Wnormalized=id -Woverride-init -Wstrict-overflow=1"
 751     # We used to use -Wstrict-overflow=5, but that breaks us heavily under 4.3.
 752   fi
 753
 754   if test x$have_gcc43 = xyes ; then
 755     # These warnings break gcc 4.2 and work on gcc 4.3
 756     # XXXX020 See if any of these work with earlier versions.
 757     CFLAGS="$CFLAGS -Wextra -Warray-bounds"
 758   fi
 759
 760   if test x$have_shorten64_flag = xyes ; then
 761     CFLAGS="$CFLAGS -Wshorten-64-to-32"
 762   fi
 763
 764 ##This will break the world on some 64-bit architectures
 765 # CFLAGS="$CFLAGS -Winline"
 766 fi
 767
 768
 769
 770 CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
 771
 772 AC_CONFIG_FILES([Makefile tor.spec Doxyfile contrib/tor.sh contrib/torctl contrib/torify contrib/tor.logrotate contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist contrib/osx/TorStartupDesc.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile doc/spec/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile contrib/suse/Makefile contrib/suse/tor.sh])
 773 AC_OUTPUT
 774
 775 if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
 776   ./contrib/updateVersions.pl
 777 fi
 778